src/Pure/Isar/local_theory.ML
author wenzelm
Wed Oct 10 17:31:56 2007 +0200 (2007-10-10 ago)
changeset 24949 5f00e3532418
parent 24933 5471b164813b
child 24984 952045a8dcf2
permissions -rw-r--r--
generalized notation interface (add or del);
     1 (*  Title:      Pure/Isar/local_theory.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Local theory operations, with abstract target context.
     6 *)
     7 
     8 type local_theory = Proof.context;
     9 
    10 signature LOCAL_THEORY =
    11 sig
    12   type operations
    13   val target_of: local_theory -> Proof.context
    14   val raw_theory_result: (theory -> 'a * theory) -> local_theory -> 'a * local_theory
    15   val raw_theory: (theory -> theory) -> local_theory -> local_theory
    16   val full_naming: local_theory -> NameSpace.naming
    17   val full_name: local_theory -> bstring -> string
    18   val theory_result: (theory -> 'a * theory) -> local_theory -> 'a * local_theory
    19   val theory: (theory -> theory) -> local_theory -> local_theory
    20   val target_result: (Proof.context -> 'a * Proof.context) -> local_theory -> 'a * local_theory
    21   val target: (Proof.context -> Proof.context) -> local_theory -> local_theory
    22   val affirm: local_theory -> local_theory
    23   val pretty: local_theory -> Pretty.T list
    24   val consts: (string * typ -> bool) ->
    25     ((bstring * typ) * mixfix) list -> local_theory -> (term * thm) list * local_theory
    26   val axioms: string -> ((bstring * Attrib.src list) * term list) list -> local_theory ->
    27     (bstring * thm list) list * local_theory
    28   val abbrev: Syntax.mode -> (bstring * mixfix) * term -> local_theory ->
    29     (term * term) * local_theory
    30   val def: string -> (bstring * mixfix) * ((bstring * Attrib.src list) * term) ->
    31     local_theory -> (term * (bstring * thm)) * local_theory
    32   val notes: string -> ((bstring * Attrib.src list) * (thm list * Attrib.src list) list) list ->
    33     local_theory -> (bstring * thm list) list * local_theory
    34   val type_syntax: declaration -> local_theory -> local_theory
    35   val term_syntax: declaration -> local_theory -> local_theory
    36   val declaration: declaration -> local_theory -> local_theory
    37   val note: string -> (bstring * Attrib.src list) * thm list ->
    38     local_theory -> (bstring * thm list) * local_theory
    39   val notation: bool -> Syntax.mode -> (term * mixfix) list -> local_theory -> local_theory
    40   val target_morphism: local_theory -> morphism
    41   val target_naming: local_theory -> NameSpace.naming
    42   val target_name: local_theory -> bstring -> string
    43   val init: string -> operations -> Proof.context -> local_theory
    44   val restore: local_theory -> local_theory
    45   val reinit: local_theory -> theory -> local_theory
    46   val exit: local_theory -> Proof.context
    47 end;
    48 
    49 structure LocalTheory: LOCAL_THEORY =
    50 struct
    51 
    52 (** local theory data **)
    53 
    54 (* type lthy *)
    55 
    56 type operations =
    57  {pretty: local_theory -> Pretty.T list,
    58   consts: (string * typ -> bool) -> ((bstring * typ) * mixfix) list -> local_theory ->
    59     (term * thm) list * local_theory,
    60   axioms: string -> ((bstring * Attrib.src list) * term list) list -> local_theory ->
    61     (bstring * thm list) list * local_theory,
    62   abbrev: Syntax.mode -> (bstring * mixfix) * term -> local_theory -> (term * term) * local_theory,
    63   def: string -> (bstring * mixfix) * ((bstring * Attrib.src list) * term) ->
    64     local_theory -> (term * (bstring * thm)) * local_theory,
    65   notes: string ->
    66     ((bstring * Attrib.src list) * (thm list * Attrib.src list) list) list ->
    67     local_theory -> (bstring * thm list) list * local_theory,
    68   type_syntax: declaration -> local_theory -> local_theory,
    69   term_syntax: declaration -> local_theory -> local_theory,
    70   declaration: declaration -> local_theory -> local_theory,
    71   target_naming: local_theory -> NameSpace.naming,
    72   reinit: local_theory -> theory -> local_theory,
    73   exit: local_theory -> Proof.context};
    74 
    75 datatype lthy = LThy of
    76  {theory_prefix: string,
    77   operations: operations,
    78   target: Proof.context};
    79 
    80 fun make_lthy (theory_prefix, operations, target) =
    81   LThy {theory_prefix = theory_prefix, operations = operations, target = target};
    82 
    83 
    84 (* context data *)
    85 
    86 structure Data = ProofDataFun
    87 (
    88   type T = lthy option;
    89   fun init _ = NONE;
    90 );
    91 
    92 fun get_lthy lthy =
    93   (case Data.get lthy of
    94     NONE => error "No local theory context"
    95   | SOME (LThy data) => data);
    96 
    97 fun map_lthy f lthy =
    98   let val {theory_prefix, operations, target} = get_lthy lthy
    99   in Data.put (SOME (make_lthy (f (theory_prefix, operations, target)))) lthy end;
   100 
   101 val target_of = #target o get_lthy;
   102 val affirm = tap target_of;
   103 
   104 fun map_target f = map_lthy (fn (theory_prefix, operations, target) =>
   105   (theory_prefix, operations, f target));
   106 
   107 
   108 (* substructure mappings *)
   109 
   110 fun raw_theory_result f lthy =
   111   let
   112     val (res, thy') = f (ProofContext.theory_of lthy);
   113     val lthy' = lthy
   114       |> map_target (ProofContext.transfer thy')
   115       |> ProofContext.transfer thy';
   116   in (res, lthy') end;
   117 
   118 fun raw_theory f = #2 o raw_theory_result (f #> pair ());
   119 
   120 fun full_naming lthy =
   121   Sign.naming_of (ProofContext.theory_of lthy)
   122   |> NameSpace.sticky_prefix (#theory_prefix (get_lthy lthy))
   123   |> NameSpace.qualified_names;
   124 
   125 val full_name = NameSpace.full o full_naming;
   126 
   127 fun theory_result f lthy = lthy |> raw_theory_result (fn thy => thy
   128   |> Sign.sticky_prefix (#theory_prefix (get_lthy lthy))
   129   |> Sign.qualified_names
   130   |> f
   131   ||> Sign.restore_naming thy);
   132 
   133 fun theory f = #2 o theory_result (f #> pair ());
   134 
   135 fun target_result f lthy =
   136   let
   137     val (res, ctxt') = f (#target (get_lthy lthy));
   138     val thy' = ProofContext.theory_of ctxt';
   139     val lthy' = lthy
   140       |> map_target (K ctxt')
   141       |> ProofContext.transfer thy';
   142   in (res, lthy') end;
   143 
   144 fun target f = #2 o target_result (f #> pair ());
   145 
   146 
   147 (* basic operations *)
   148 
   149 fun operation f lthy = f (#operations (get_lthy lthy)) lthy;
   150 fun operation1 f x = operation (fn ops => f ops x);
   151 fun operation2 f x y = operation (fn ops => f ops x y);
   152 
   153 val pretty = operation #pretty;
   154 val consts = operation2 #consts;
   155 val axioms = operation2 #axioms;
   156 val abbrev = operation2 #abbrev;
   157 val def = operation2 #def;
   158 val notes = operation2 #notes;
   159 val type_syntax = operation1 #type_syntax;
   160 val term_syntax = operation1 #term_syntax;
   161 val declaration = operation1 #declaration;
   162 val target_naming = operation #target_naming;
   163 
   164 fun note kind (a, ths) lthy = lthy |> notes kind [(a, [(ths, [])])] |>> hd;
   165 
   166 fun target_morphism lthy =
   167   ProofContext.export_morphism lthy (target_of lthy) $>
   168   Morphism.thm_morphism Goal.norm_result;
   169 
   170 fun notation add mode raw_args lthy =
   171   let val args = map (apfst (Morphism.term (target_morphism lthy))) raw_args
   172   in term_syntax (ProofContext.target_notation add mode args) lthy end;
   173 
   174 val target_name = NameSpace.full o target_naming;
   175 
   176 
   177 (* init -- exit *)
   178 
   179 fun init theory_prefix operations target = target |> Data.map
   180   (fn NONE => SOME (make_lthy (theory_prefix, operations, target))
   181     | SOME _ => error "Local theory already initialized");
   182 
   183 fun restore lthy =
   184   let val {theory_prefix, operations, target} = get_lthy lthy
   185   in init theory_prefix operations target end;
   186 
   187 val reinit = operation #reinit;
   188 val exit = operation #exit;
   189 
   190 end;