src/Pure/PIDE/command.ML
author wenzelm
Tue Nov 19 19:33:27 2013 +0100 (2013-11-19 ago)
changeset 54519 5fed81762406
parent 53976 da610b507799
child 54520 cee77d2e9582
permissions -rw-r--r--
maintain blobs within document state: digest + text in ML, digest-only in Scala;
resolve files for command span, based on defined blobs;
tuned;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   type blob = (string * string) Exn.result
    10   val read: (unit -> theory) -> blob list -> Token.T list -> Toplevel.transition
    11   type eval
    12   val eval_eq: eval * eval -> bool
    13   val eval_running: eval -> bool
    14   val eval_finished: eval -> bool
    15   val eval_result_state: eval -> Toplevel.state
    16   val eval: (unit -> theory) -> blob list -> Token.T list -> eval -> eval
    17   type print
    18   val print: bool -> (string * string list) list -> string ->
    19     eval -> print list -> print list option
    20   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    21   type print_function =
    22     {command_name: string, args: string list} ->
    23       {delay: Time.time option, pri: int, persistent: bool, strict: bool, print_fn: print_fn} option
    24   val print_function: string -> print_function -> unit
    25   val no_print_function: string -> unit
    26   type exec = eval * print list
    27   val no_exec: exec
    28   val exec_ids: exec option -> Document_ID.exec list
    29   val exec: Document_ID.execution -> exec -> unit
    30 end;
    31 
    32 structure Command: COMMAND =
    33 struct
    34 
    35 (** memo results **)
    36 
    37 datatype 'a expr =
    38   Expr of Document_ID.exec * (unit -> 'a) |
    39   Result of 'a Exn.result;
    40 
    41 abstype 'a memo = Memo of 'a expr Synchronized.var
    42 with
    43 
    44 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    45 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    46 
    47 fun memo_result (Memo v) =
    48   (case Synchronized.value v of
    49     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    50   | Result res => Exn.release res);
    51 
    52 fun memo_finished (Memo v) =
    53   (case Synchronized.value v of Expr _ => false | Result _ => true);
    54 
    55 fun memo_exec execution_id (Memo v) =
    56   Synchronized.timed_access v (K (SOME Time.zeroTime))
    57     (fn expr =>
    58       (case expr of
    59         Expr (exec_id, body) =>
    60           uninterruptible (fn restore_attributes => fn () =>
    61             if Execution.running execution_id exec_id [Future.the_worker_group ()] then
    62               let
    63                 val res =
    64                   (body
    65                     |> restore_attributes
    66                     |> Future.worker_nest "Command.memo_exec"
    67                     |> Exn.interruptible_capture) ();
    68               in SOME ((), Result res) end
    69             else SOME ((), expr)) ()
    70       | Result _ => SOME ((), expr)))
    71   |> (fn NONE => error "Conflicting command execution" | _ => ());
    72 
    73 fun memo_fork params execution_id (Memo v) =
    74   (case Synchronized.value v of
    75     Result _ => ()
    76   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    77 
    78 end;
    79 
    80 
    81 
    82 (** main phases of execution **)
    83 
    84 (* read *)
    85 
    86 type blob = (string * string) Exn.result;  (*file node name, digest or text*)
    87 
    88 fun resolve_files blobs toks =
    89   (case Thy_Syntax.parse_spans toks of
    90     [span] => span
    91       |> Thy_Syntax.resolve_files (fn _ => fn (path, pos) =>
    92         blobs |> map (Exn.release #> (fn (file, text) =>
    93           let val _ = Position.report pos (Markup.path file);
    94           in {src_path = path (* FIXME *), text = text, pos = Position.file file} end)))
    95       |> Thy_Syntax.span_content
    96   | _ => toks);
    97 
    98 fun read init blobs span =
    99   let
   100     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
   101     val command_reports = Outer_Syntax.command_reports outer_syntax;
   102 
   103     val proper_range =
   104       Position.set_range (Token.position_range_of (#1 (take_suffix Token.is_improper span)));
   105     val pos =
   106       (case find_first Token.is_command span of
   107         SOME tok => Token.position_of tok
   108       | NONE => proper_range);
   109 
   110     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
   111     val _ = Position.reports_text (token_reports @ maps command_reports span);
   112   in
   113     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
   114     else
   115       (case Outer_Syntax.read_spans outer_syntax (resolve_files blobs span) of
   116         [tr] =>
   117           if Keyword.is_control (Toplevel.name_of tr) then
   118             Toplevel.malformed pos "Illegal control command"
   119           else Toplevel.modify_init init tr
   120       | [] => Toplevel.ignored (Position.set_range (Token.position_range_of span))
   121       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   122       handle ERROR msg => Toplevel.malformed proper_range msg
   123   end;
   124 
   125 
   126 (* eval *)
   127 
   128 type eval_state =
   129   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   130 val init_eval_state =
   131   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   132 
   133 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   134 
   135 fun eval_eq (Eval {exec_id, ...}, Eval {exec_id = exec_id', ...}) = exec_id = exec_id';
   136 
   137 fun eval_running (Eval {exec_id, ...}) = Execution.is_running_exec exec_id;
   138 fun eval_finished (Eval {eval_process, ...}) = memo_finished eval_process;
   139 
   140 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   141 val eval_result_state = #state o eval_result;
   142 
   143 local
   144 
   145 fun run int tr st =
   146   if Goal.future_enabled 1 andalso Keyword.is_diag (Toplevel.name_of tr) then
   147     (Execution.fork {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   148       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   149   else Toplevel.command_errors int tr st;
   150 
   151 fun check_cmts span tr st' =
   152   Toplevel.setmp_thread_position tr
   153     (fn () =>
   154       Outer_Syntax.side_comments span |> maps (fn cmt =>
   155         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   156           handle exn =>
   157             if Exn.is_interrupt exn then reraise exn
   158             else ML_Compiler.exn_messages_ids exn)) ();
   159 
   160 fun proof_status tr st =
   161   (case try Toplevel.proof_of st of
   162     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   163   | NONE => ());
   164 
   165 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   166   if malformed then
   167     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   168   else
   169     let
   170       val malformed' = Toplevel.is_malformed tr;
   171       val is_init = Toplevel.is_init tr;
   172       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   173 
   174       val _ = Multithreading.interrupted ();
   175       val _ = Toplevel.status tr Markup.running;
   176       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   177       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   178       val errs = errs1 @ errs2;
   179       val _ = Toplevel.status tr Markup.finished;
   180       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   181     in
   182       (case result of
   183         NONE =>
   184           let
   185             val _ = if null errs then Exn.interrupt () else ();
   186             val _ = Toplevel.status tr Markup.failed;
   187           in {failed = true, malformed = malformed', command = tr, state = st} end
   188       | SOME st' =>
   189           let
   190             val _ = proof_status tr st';
   191           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   192     end;
   193 
   194 in
   195 
   196 fun eval init blobs span eval0 =
   197   let
   198     val exec_id = Document_ID.make ();
   199     fun process () =
   200       let
   201         val tr =
   202           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   203             (fn () => read init blobs span |> Toplevel.exec_id exec_id) ();
   204       in eval_state span tr (eval_result eval0) end;
   205   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   206 
   207 end;
   208 
   209 
   210 (* print *)
   211 
   212 datatype print = Print of
   213  {name: string, args: string list, delay: Time.time option, pri: int, persistent: bool,
   214   exec_id: Document_ID.exec, print_process: unit memo};
   215 
   216 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   217 
   218 type print_function =
   219   {command_name: string, args: string list} ->
   220     {delay: Time.time option, pri: int, persistent: bool, strict: bool, print_fn: print_fn} option;
   221 
   222 local
   223 
   224 val print_functions =
   225   Synchronized.var "Command.print_functions" ([]: (string * print_function) list);
   226 
   227 fun print_error tr e =
   228   (Toplevel.setmp_thread_position tr o Toplevel.controlled_execution) e ()
   229     handle exn =>
   230       if Exn.is_interrupt exn then reraise exn
   231       else List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   232 
   233 fun print_eq (Print {exec_id, ...}, Print {exec_id = exec_id', ...}) = exec_id = exec_id';
   234 
   235 fun print_finished (Print {print_process, ...}) = memo_finished print_process;
   236 
   237 fun print_persistent (Print {persistent, ...}) = persistent;
   238 
   239 val overlay_ord = prod_ord string_ord (list_ord string_ord);
   240 
   241 in
   242 
   243 fun print command_visible command_overlays command_name eval old_prints =
   244   let
   245     val print_functions = Synchronized.value print_functions;
   246 
   247     fun make_print name args {delay, pri, persistent, strict, print_fn} =
   248       let
   249         val exec_id = Document_ID.make ();
   250         fun process () =
   251           let
   252             val {failed, command, state = st', ...} = eval_result eval;
   253             val tr = Toplevel.exec_id exec_id command;
   254           in
   255             if failed andalso strict then ()
   256             else print_error tr (fn () => print_fn tr st')
   257           end;
   258       in
   259         Print {
   260           name = name, args = args, delay = delay, pri = pri, persistent = persistent,
   261           exec_id = exec_id, print_process = memo exec_id process}
   262       end;
   263 
   264     fun bad_print name args exn =
   265       make_print name args {delay = NONE, pri = 0, persistent = false,
   266         strict = false, print_fn = fn _ => fn _ => reraise exn};
   267 
   268     fun new_print name args get_pr =
   269       let
   270         val params = {command_name = command_name, args = args};
   271       in
   272         (case Exn.capture (Toplevel.controlled_execution get_pr) params of
   273           Exn.Res NONE => NONE
   274         | Exn.Res (SOME pr) => SOME (make_print name args pr)
   275         | Exn.Exn exn => SOME (bad_print name args exn))
   276       end;
   277 
   278     fun get_print (a, b) =
   279       (case find_first (fn Print {name, args, ...} => name = a andalso args = b) old_prints of
   280         NONE =>
   281           (case AList.lookup (op =) print_functions a of
   282             NONE => SOME (bad_print a b (ERROR ("Missing print function " ^ quote a)))
   283           | SOME get_pr => new_print a b get_pr)
   284       | some => some);
   285 
   286     val new_prints =
   287       if command_visible then
   288         fold (fn (a, _) => cons (a, [])) print_functions command_overlays
   289         |> sort_distinct overlay_ord
   290         |> map_filter get_print
   291       else filter (fn print => print_finished print andalso print_persistent print) old_prints;
   292   in
   293     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   294   end;
   295 
   296 fun print_function name f =
   297   Synchronized.change print_functions (fn funs =>
   298    (if not (AList.defined (op =) funs name) then ()
   299     else warning ("Redefining command print function: " ^ quote name);
   300     AList.update (op =) (name, f) funs));
   301 
   302 fun no_print_function name =
   303   Synchronized.change print_functions (filter_out (equal name o #1));
   304 
   305 end;
   306 
   307 val _ =
   308   print_function "print_state"
   309     (fn {command_name, ...} =>
   310       SOME {delay = NONE, pri = 1, persistent = false, strict = true,
   311         print_fn = fn tr => fn st' =>
   312           let
   313             val is_init = Keyword.is_theory_begin command_name;
   314             val is_proof = Keyword.is_proof command_name;
   315             val do_print =
   316               not is_init andalso
   317                 (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   318           in if do_print then Toplevel.print_state false st' else () end});
   319 
   320 
   321 (* combined execution *)
   322 
   323 type exec = eval * print list;
   324 val no_exec: exec =
   325   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   326 
   327 fun exec_ids NONE = []
   328   | exec_ids (SOME (Eval {exec_id, ...}, prints)) =
   329       exec_id :: map (fn Print {exec_id, ...} => exec_id) prints;
   330 
   331 local
   332 
   333 fun run_print execution_id (Print {name, delay, pri, print_process, ...}) =
   334   if Multithreading.enabled () orelse pri <= 0 then
   335     let
   336       val group = Future.worker_subgroup ();
   337       fun fork () =
   338         memo_fork {name = name, group = SOME group, deps = [], pri = pri, interrupts = true}
   339           execution_id print_process;
   340     in
   341       (case delay of
   342         NONE => fork ()
   343       | SOME d => ignore (Event_Timer.request (Time.+ (Time.now (), d)) fork))
   344     end
   345   else memo_exec execution_id print_process;
   346 
   347 in
   348 
   349 fun exec execution_id (Eval {eval_process, ...}, prints) =
   350   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   351 
   352 end;
   353 
   354 end;
   355