src/Pure/PIDE/command.ML
author wenzelm
Mon Jul 29 16:52:04 2013 +0200 (2013-07-29 ago)
changeset 52774 627fb639a2d9
parent 52772 7764c90680f0
child 52775 e0169f13bd37
permissions -rw-r--r--
maintain explicit execution frontier: avoid conflict with former task via static dependency;
start execution immediate after assignment, to keep frontier simple;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   val read: (unit -> theory) -> Token.T list -> Toplevel.transition
    10   type eval
    11   val eval_eq: eval * eval -> bool
    12   val eval_finished: eval -> bool
    13   val eval_result_state: eval -> Toplevel.state
    14   val eval: (unit -> theory) -> Token.T list -> eval -> eval
    15   type print
    16   val print: bool -> string -> eval -> print list -> print list option
    17   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    18   val print_function: string ->
    19     ({command_name: string} ->
    20       {delay: Time.time option, pri: int, persistent: bool, print_fn: print_fn} option) -> unit
    21   val no_print_function: string -> unit
    22   type exec = eval * print list
    23   val no_exec: exec
    24   val exec_ids: exec option -> Document_ID.exec list
    25   val exec: Document_ID.execution -> exec -> unit
    26 end;
    27 
    28 structure Command: COMMAND =
    29 struct
    30 
    31 (** memo results -- including physical interrupts **)
    32 
    33 datatype 'a expr =
    34   Expr of Document_ID.exec * (unit -> 'a) |
    35   Result of 'a Exn.result;
    36 
    37 abstype 'a memo = Memo of 'a expr Synchronized.var
    38 with
    39 
    40 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    41 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    42 
    43 fun memo_result (Memo v) =
    44   (case Synchronized.value v of
    45     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    46   | Result res => Exn.release res);
    47 
    48 fun memo_finished (Memo v) =
    49   (case Synchronized.value v of
    50    Expr _ => false
    51  | Result res => not (Exn.is_interrupt_exn res));
    52 
    53 fun memo_exec execution_id (Memo v) =
    54   Synchronized.timed_access v (K (SOME Time.zeroTime))
    55     (fn expr =>
    56       (case expr of
    57         Expr (exec_id, e) =>
    58           uninterruptible (fn restore_attributes => fn () =>
    59             if Execution.running execution_id exec_id then
    60               let
    61                 val res = Exn.capture (restore_attributes e) ();
    62                 val _ = Execution.finished exec_id;
    63               in SOME (Exn.is_interrupt_exn res, Result res) end
    64             else SOME (true, expr)) ()
    65       | Result _ => SOME (false, expr)))
    66   |> (fn SOME false => ()
    67        | SOME true => Exn.interrupt ()
    68        | NONE => error "Conflicting command execution");
    69 
    70 fun memo_fork params execution_id (Memo v) =
    71   (case Synchronized.value v of
    72     Result _ => ()
    73   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    74 
    75 end;
    76 
    77 
    78 
    79 (** main phases of execution **)
    80 
    81 (* read *)
    82 
    83 fun read init span =
    84   let
    85     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
    86     val command_reports = Outer_Syntax.command_reports outer_syntax;
    87 
    88     val proper_range =
    89       Position.set_range (Token.position_range_of (#1 (take_suffix Token.is_improper span)));
    90     val pos =
    91       (case find_first Token.is_command span of
    92         SOME tok => Token.position_of tok
    93       | NONE => proper_range);
    94 
    95     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
    96     val _ = Position.reports_text (token_reports @ maps command_reports span);
    97   in
    98     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
    99     else
   100       (case Outer_Syntax.read_spans outer_syntax span of
   101         [tr] =>
   102           if Keyword.is_control (Toplevel.name_of tr) then
   103             Toplevel.malformed pos "Illegal control command"
   104           else Toplevel.modify_init init tr
   105       | [] => Toplevel.ignored (Position.set_range (Token.position_range_of span))
   106       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   107       handle ERROR msg => Toplevel.malformed proper_range msg
   108   end;
   109 
   110 
   111 (* eval *)
   112 
   113 type eval_state =
   114   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   115 val init_eval_state =
   116   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   117 
   118 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   119 
   120 fun eval_eq (Eval {exec_id, ...}, Eval {exec_id = exec_id', ...}) = exec_id = exec_id';
   121 
   122 fun eval_finished (Eval {eval_process, ...}) = memo_finished eval_process;
   123 
   124 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   125 val eval_result_state = #state o eval_result;
   126 
   127 local
   128 
   129 fun run int tr st =
   130   if Goal.future_enabled () andalso Keyword.is_diag (Toplevel.name_of tr) then
   131     (Goal.fork_params {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   132       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   133   else Toplevel.command_errors int tr st;
   134 
   135 fun check_cmts span tr st' =
   136   Toplevel.setmp_thread_position tr
   137     (fn () =>
   138       Outer_Syntax.side_comments span |> maps (fn cmt =>
   139         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   140           handle exn =>
   141             if Exn.is_interrupt exn then reraise exn
   142             else ML_Compiler.exn_messages_ids exn)) ();
   143 
   144 fun proof_status tr st =
   145   (case try Toplevel.proof_of st of
   146     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   147   | NONE => ());
   148 
   149 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   150   if malformed then
   151     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   152   else
   153     let
   154       val malformed' = Toplevel.is_malformed tr;
   155       val is_init = Toplevel.is_init tr;
   156       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   157 
   158       val _ = Multithreading.interrupted ();
   159       val _ = Toplevel.status tr Markup.running;
   160       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   161       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   162       val errs = errs1 @ errs2;
   163       val _ = Toplevel.status tr Markup.finished;
   164       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   165     in
   166       (case result of
   167         NONE =>
   168           let
   169             val _ = if null errs then Exn.interrupt () else ();
   170             val _ = Toplevel.status tr Markup.failed;
   171           in {failed = true, malformed = malformed', command = tr, state = st} end
   172       | SOME st' =>
   173           let
   174             val _ = proof_status tr st';
   175           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   176     end;
   177 
   178 in
   179 
   180 fun eval init span eval0 =
   181   let
   182     val exec_id = Document_ID.make ();
   183     fun process () =
   184       let
   185         val tr =
   186           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   187             (fn () => read init span |> Toplevel.exec_id exec_id) ();
   188       in eval_state span tr (eval_result eval0) end;
   189   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   190 
   191 end;
   192 
   193 
   194 (* print *)
   195 
   196 datatype print = Print of
   197  {name: string, delay: Time.time option, pri: int, persistent: bool,
   198   exec_id: Document_ID.exec, print_process: unit memo};
   199 
   200 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   201 
   202 type print_function =
   203   {command_name: string} ->
   204     {delay: Time.time option, pri: int, persistent: bool, print_fn: print_fn} option;
   205 
   206 local
   207 
   208 val print_functions =
   209   Synchronized.var "Command.print_functions" ([]: (string * print_function) list);
   210 
   211 fun print_error tr e =
   212   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution) e ()
   213     handle exn =>
   214       if Exn.is_interrupt exn then reraise exn
   215       else List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   216 
   217 fun print_eq (Print {exec_id, ...}, Print {exec_id = exec_id', ...}) = exec_id = exec_id';
   218 
   219 fun print_finished (Print {exec_id, print_process, ...}) = memo_finished print_process;
   220 
   221 fun print_persistent (Print {persistent, ...}) = persistent;
   222 
   223 in
   224 
   225 fun print command_visible command_name eval old_prints =
   226   let
   227     fun new_print (name, get_pr) =
   228       let
   229         fun make_print strict {delay, pri, persistent, print_fn} =
   230           let
   231             val exec_id = Document_ID.make ();
   232             fun process () =
   233               let
   234                 val {failed, command, state = st', ...} = eval_result eval;
   235                 val tr = Toplevel.exec_id exec_id command;
   236               in
   237                 if failed andalso not strict then ()
   238                 else print_error tr (fn () => print_fn tr st')
   239               end;
   240           in
   241            Print {
   242              name = name, delay = delay, pri = pri, persistent = persistent,
   243              exec_id = exec_id, print_process = memo exec_id process}
   244           end;
   245       in
   246         (case Exn.capture (Runtime.controlled_execution get_pr) {command_name = command_name} of
   247           Exn.Res NONE => NONE
   248         | Exn.Res (SOME pr) => SOME (make_print false pr)
   249         | Exn.Exn exn =>
   250             SOME (make_print true
   251               {delay = NONE, pri = 0, persistent = false, print_fn = fn _ => fn _ => reraise exn}))
   252       end;
   253 
   254     val new_prints =
   255       if command_visible then
   256         rev (Synchronized.value print_functions) |> map_filter (fn pr =>
   257           (case find_first (fn Print {name, ...} => name = fst pr) old_prints of
   258             NONE => new_print pr
   259           | some => some))
   260       else filter (fn print => print_finished print andalso print_persistent print) old_prints;
   261   in
   262     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   263   end;
   264 
   265 fun print_function name f =
   266   Synchronized.change print_functions (fn funs =>
   267    (if not (AList.defined (op =) funs name) then ()
   268     else warning ("Redefining command print function: " ^ quote name);
   269     AList.update (op =) (name, f) funs));
   270 
   271 fun no_print_function name =
   272   Synchronized.change print_functions (filter_out (equal name o #1));
   273 
   274 end;
   275 
   276 val _ =
   277   print_function "print_state"
   278     (fn {command_name} =>
   279       SOME {delay = NONE, pri = 1, persistent = true,
   280         print_fn = fn tr => fn st' =>
   281           let
   282             val is_init = Keyword.is_theory_begin command_name;
   283             val is_proof = Keyword.is_proof command_name;
   284             val do_print =
   285               not is_init andalso
   286                 (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   287           in if do_print then Toplevel.print_state false st' else () end});
   288 
   289 
   290 (* combined execution *)
   291 
   292 type exec = eval * print list;
   293 val no_exec: exec =
   294   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   295 
   296 fun exec_ids NONE = []
   297   | exec_ids (SOME (Eval {exec_id, ...}, prints)) =
   298       exec_id :: map (fn Print {exec_id, ...} => exec_id) prints;
   299 
   300 local
   301 
   302 fun run_print execution_id (Print {name, delay, pri, print_process, ...}) =
   303   if Multithreading.enabled () then
   304     let
   305       val group = Future.worker_subgroup ();
   306       fun fork () =
   307         memo_fork {name = name, group = SOME group, deps = [], pri = pri, interrupts = true}
   308           execution_id print_process;
   309     in
   310       (case delay of
   311         NONE => fork ()
   312       | SOME d => ignore (Event_Timer.request (Time.+ (Time.now (), d)) fork))
   313     end
   314   else memo_exec execution_id print_process;
   315 
   316 in
   317 
   318 fun exec execution_id (Eval {eval_process, ...}, prints) =
   319   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   320 
   321 end;
   322 
   323 end;
   324