src/Pure/Isar/proof.ML
author wenzelm
Thu Sep 09 17:20:27 2010 +0200 (2010-09-09 ago)
changeset 39232 69c6d3e87660
parent 39129 976af4e27cde
child 39616 8052101883c3
permissions -rw-r--r--
more abstract treatment of interrupts in structure Exn -- hardly ever need to mention Interrupt literally;
     1 (*  Title:      Pure/Isar/proof.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The Isar/VM proof language interpreter: maintains a structured flow of
     5 context elements, goals, refinements, and facts.
     6 *)
     7 
     8 signature PROOF =
     9 sig
    10   type context = Proof.context
    11   type method = Method.method
    12   type state
    13   val init: context -> state
    14   val level: state -> int
    15   val assert_bottom: bool -> state -> state
    16   val context_of: state -> context
    17   val theory_of: state -> theory
    18   val map_context: (context -> context) -> state -> state
    19   val map_contexts: (context -> context) -> state -> state
    20   val propagate_ml_env: state -> state
    21   val bind_terms: (indexname * term option) list -> state -> state
    22   val put_thms: bool -> string * thm list option -> state -> state
    23   val the_facts: state -> thm list
    24   val the_fact: state -> thm
    25   val put_facts: thm list option -> state -> state
    26   val assert_forward: state -> state
    27   val assert_chain: state -> state
    28   val assert_forward_or_chain: state -> state
    29   val assert_backward: state -> state
    30   val assert_no_chain: state -> state
    31   val enter_forward: state -> state
    32   val goal_message: (unit -> Pretty.T) -> state -> state
    33   val verbose: bool Unsynchronized.ref
    34   val pretty_state: int -> state -> Pretty.T list
    35   val pretty_goals: bool -> state -> Pretty.T list
    36   val refine: Method.text -> state -> state Seq.seq
    37   val refine_end: Method.text -> state -> state Seq.seq
    38   val refine_insert: thm list -> state -> state
    39   val goal_tac: thm -> int -> tactic
    40   val refine_goals: (context -> thm -> unit) -> context -> thm list -> state -> state Seq.seq
    41   val raw_goal: state -> {context: context, facts: thm list, goal: thm}
    42   val goal: state -> {context: context, facts: thm list, goal: thm}
    43   val simple_goal: state -> {context: context, goal: thm}
    44   val status_markup: state -> Markup.T
    45   val let_bind: (term list * term) list -> state -> state
    46   val let_bind_cmd: (string list * string) list -> state -> state
    47   val write: Syntax.mode -> (term * mixfix) list -> state -> state
    48   val write_cmd: Syntax.mode -> (string * mixfix) list -> state -> state
    49   val fix: (binding * typ option * mixfix) list -> state -> state
    50   val fix_cmd: (binding * string option * mixfix) list -> state -> state
    51   val assm: Assumption.export ->
    52     (Thm.binding * (term * term list) list) list -> state -> state
    53   val assm_cmd: Assumption.export ->
    54     (Attrib.binding * (string * string list) list) list -> state -> state
    55   val assume: (Thm.binding * (term * term list) list) list -> state -> state
    56   val assume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    57   val presume: (Thm.binding * (term * term list) list) list -> state -> state
    58   val presume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    59   val def: (Thm.binding * ((binding * mixfix) * (term * term list))) list -> state -> state
    60   val def_cmd: (Attrib.binding * ((binding * mixfix) * (string * string list))) list -> state -> state
    61   val chain: state -> state
    62   val chain_facts: thm list -> state -> state
    63   val note_thmss: (Thm.binding * (thm list * attribute list) list) list -> state -> state
    64   val note_thmss_cmd: (Attrib.binding * (Facts.ref * Attrib.src list) list) list -> state -> state
    65   val from_thmss: ((thm list * attribute list) list) list -> state -> state
    66   val from_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    67   val with_thmss: ((thm list * attribute list) list) list -> state -> state
    68   val with_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    69   val using: ((thm list * attribute list) list) list -> state -> state
    70   val using_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    71   val unfolding: ((thm list * attribute list) list) list -> state -> state
    72   val unfolding_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    73   val invoke_case: string * string option list * attribute list -> state -> state
    74   val invoke_case_cmd: string * string option list * Attrib.src list -> state -> state
    75   val begin_block: state -> state
    76   val next_block: state -> state
    77   val end_block: state -> state
    78   val proof: Method.text option -> state -> state Seq.seq
    79   val defer: int option -> state -> state Seq.seq
    80   val prefer: int -> state -> state Seq.seq
    81   val apply: Method.text -> state -> state Seq.seq
    82   val apply_end: Method.text -> state -> state Seq.seq
    83   val local_goal: (context -> ((string * string) * (string * thm list) list) -> unit) ->
    84     (theory -> 'a -> attribute) ->
    85     (context * 'b list -> context * (term list list * (context -> context))) ->
    86     string -> Method.text option -> (thm list list -> state -> state) ->
    87     ((binding * 'a list) * 'b) list -> state -> state
    88   val local_qed: Method.text option * bool -> state -> state
    89   val theorem: Method.text option -> (thm list list -> context -> context) ->
    90     (term * term list) list list -> context -> state
    91   val theorem_cmd: Method.text option -> (thm list list -> context -> context) ->
    92     (string * string list) list list -> context -> state
    93   val global_qed: Method.text option * bool -> state -> context
    94   val local_terminal_proof: Method.text * Method.text option -> state -> state
    95   val local_default_proof: state -> state
    96   val local_immediate_proof: state -> state
    97   val local_skip_proof: bool -> state -> state
    98   val local_done_proof: state -> state
    99   val global_terminal_proof: Method.text * Method.text option -> state -> context
   100   val global_default_proof: state -> context
   101   val global_immediate_proof: state -> context
   102   val global_skip_proof: bool -> state -> context
   103   val global_done_proof: state -> context
   104   val have: Method.text option -> (thm list list -> state -> state) ->
   105     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   106   val have_cmd: Method.text option -> (thm list list -> state -> state) ->
   107     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   108   val show: Method.text option -> (thm list list -> state -> state) ->
   109     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   110   val show_cmd: Method.text option -> (thm list list -> state -> state) ->
   111     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   112   val schematic_goal: state -> bool
   113   val is_relevant: state -> bool
   114   val local_future_proof: (state -> ('a * state) Future.future) ->
   115     state -> 'a Future.future * state
   116   val global_future_proof: (state -> ('a * Proof.context) Future.future) ->
   117     state -> 'a Future.future * context
   118   val local_future_terminal_proof: Method.text * Method.text option -> bool -> state -> state
   119   val global_future_terminal_proof: Method.text * Method.text option -> bool -> state -> context
   120 end;
   121 
   122 structure Proof: PROOF =
   123 struct
   124 
   125 type context = Proof.context;
   126 type method = Method.method;
   127 
   128 
   129 (** proof state **)
   130 
   131 (* datatype state *)
   132 
   133 datatype mode = Forward | Chain | Backward;
   134 
   135 datatype state =
   136   State of node Stack.T
   137 and node =
   138   Node of
   139    {context: context,
   140     facts: thm list option,
   141     mode: mode,
   142     goal: goal option}
   143 and goal =
   144   Goal of
   145    {statement: (string * Position.T) * term list list * term,
   146       (*goal kind and statement (starting with vars), initial proposition*)
   147     messages: (unit -> Pretty.T) list,    (*persistent messages (hints etc.)*)
   148     using: thm list,                      (*goal facts*)
   149     goal: thm,                            (*subgoals ==> statement*)
   150     before_qed: Method.text option,
   151     after_qed:
   152       (thm list list -> state -> state) *
   153       (thm list list -> context -> context)};
   154 
   155 fun make_goal (statement, messages, using, goal, before_qed, after_qed) =
   156   Goal {statement = statement, messages = messages, using = using, goal = goal,
   157     before_qed = before_qed, after_qed = after_qed};
   158 
   159 fun make_node (context, facts, mode, goal) =
   160   Node {context = context, facts = facts, mode = mode, goal = goal};
   161 
   162 fun map_node f (Node {context, facts, mode, goal}) =
   163   make_node (f (context, facts, mode, goal));
   164 
   165 val init_context =
   166   ProofContext.set_stmt true #>
   167   ProofContext.map_naming (K ProofContext.local_naming);
   168 
   169 fun init ctxt =
   170   State (Stack.init (make_node (init_context ctxt, NONE, Forward, NONE)));
   171 
   172 fun current (State st) = Stack.top st |> (fn Node node => node);
   173 fun map_current f (State st) = State (Stack.map_top (map_node f) st);
   174 fun map_all f (State st) = State (Stack.map_all (map_node f) st);
   175 
   176 
   177 
   178 (** basic proof state operations **)
   179 
   180 (* block structure *)
   181 
   182 fun open_block (State st) = State (Stack.push st);
   183 
   184 fun close_block (State st) = State (Stack.pop st)
   185   handle Empty => error "Unbalanced block parentheses";
   186 
   187 fun level (State st) = Stack.level st;
   188 
   189 fun assert_bottom b state =
   190   let val b' = (level state <= 2) in
   191     if b andalso not b' then error "Not at bottom of proof!"
   192     else if not b andalso b' then error "Already at bottom of proof!"
   193     else state
   194   end;
   195 
   196 
   197 (* context *)
   198 
   199 val context_of = #context o current;
   200 val theory_of = ProofContext.theory_of o context_of;
   201 
   202 fun map_context f =
   203   map_current (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   204 
   205 fun map_context_result f state =
   206   f (context_of state) ||> (fn ctxt => map_context (K ctxt) state);
   207 
   208 fun map_contexts f = map_all (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   209 
   210 fun propagate_ml_env state = map_contexts
   211   (Context.proof_map (ML_Env.inherit (Context.Proof (context_of state)))) state;
   212 
   213 val bind_terms = map_context o ProofContext.bind_terms;
   214 val put_thms = map_context oo ProofContext.put_thms;
   215 
   216 
   217 (* facts *)
   218 
   219 val get_facts = #facts o current;
   220 
   221 fun the_facts state =
   222   (case get_facts state of SOME facts => facts
   223   | NONE => error "No current facts available");
   224 
   225 fun the_fact state =
   226   (case the_facts state of [thm] => thm
   227   | _ => error "Single theorem expected");
   228 
   229 fun put_facts facts =
   230   map_current (fn (ctxt, _, mode, goal) => (ctxt, facts, mode, goal)) #>
   231   put_thms true (Auto_Bind.thisN, facts);
   232 
   233 fun these_factss more_facts (named_factss, state) =
   234   (named_factss, state |> put_facts (SOME (maps snd named_factss @ more_facts)));
   235 
   236 fun export_facts inner outer =
   237   (case get_facts inner of
   238     NONE => put_facts NONE outer
   239   | SOME thms =>
   240       thms
   241       |> ProofContext.export (context_of inner) (context_of outer)
   242       |> (fn ths => put_facts (SOME ths) outer));
   243 
   244 
   245 (* mode *)
   246 
   247 val get_mode = #mode o current;
   248 fun put_mode mode = map_current (fn (ctxt, facts, _, goal) => (ctxt, facts, mode, goal));
   249 
   250 val mode_name = (fn Forward => "state" | Chain => "chain" | Backward => "prove");
   251 
   252 fun assert_mode pred state =
   253   let val mode = get_mode state in
   254     if pred mode then state
   255     else error ("Illegal application of proof command in " ^ quote (mode_name mode) ^ " mode")
   256   end;
   257 
   258 val assert_forward = assert_mode (fn mode => mode = Forward);
   259 val assert_chain = assert_mode (fn mode => mode = Chain);
   260 val assert_forward_or_chain = assert_mode (fn mode => mode = Forward orelse mode = Chain);
   261 val assert_backward = assert_mode (fn mode => mode = Backward);
   262 val assert_no_chain = assert_mode (fn mode => mode <> Chain);
   263 
   264 val enter_forward = put_mode Forward;
   265 val enter_chain = put_mode Chain;
   266 val enter_backward = put_mode Backward;
   267 
   268 
   269 (* current goal *)
   270 
   271 fun current_goal state =
   272   (case current state of
   273     {context, goal = SOME (Goal goal), ...} => (context, goal)
   274   | _ => error "No current goal!");
   275 
   276 fun assert_current_goal g state =
   277   let val g' = can current_goal state in
   278     if g andalso not g' then error "No goal in this block!"
   279     else if not g andalso g' then error "Goal present in this block!"
   280     else state
   281   end;
   282 
   283 fun put_goal goal = map_current (fn (ctxt, using, mode, _) => (ctxt, using, mode, goal));
   284 
   285 val before_qed = #before_qed o #2 o current_goal;
   286 
   287 
   288 (* nested goal *)
   289 
   290 fun map_goal f g (State (Node {context, facts, mode, goal = SOME goal}, nodes)) =
   291       let
   292         val Goal {statement, messages, using, goal, before_qed, after_qed} = goal;
   293         val goal' = make_goal (g (statement, messages, using, goal, before_qed, after_qed));
   294       in State (make_node (f context, facts, mode, SOME goal'), nodes) end
   295   | map_goal f g (State (nd, node :: nodes)) =
   296       let val State (node', nodes') = map_goal f g (State (node, nodes))
   297       in map_context f (State (nd, node' :: nodes')) end
   298   | map_goal _ _ state = state;
   299 
   300 fun set_goal goal = map_goal I (fn (statement, _, using, _, before_qed, after_qed) =>
   301   (statement, [], using, goal, before_qed, after_qed));
   302 
   303 fun goal_message msg = map_goal I (fn (statement, messages, using, goal, before_qed, after_qed) =>
   304   (statement, msg :: messages, using, goal, before_qed, after_qed));
   305 
   306 fun using_facts using = map_goal I (fn (statement, _, _, goal, before_qed, after_qed) =>
   307   (statement, [], using, goal, before_qed, after_qed));
   308 
   309 local
   310   fun find i state =
   311     (case try current_goal state of
   312       SOME (ctxt, goal) => (ctxt, (i, goal))
   313     | NONE => find (i + 1) (close_block state handle ERROR _ => error "No goal present"));
   314 in val find_goal = find 0 end;
   315 
   316 fun get_goal state =
   317   let val (ctxt, (_, {using, goal, ...})) = find_goal state
   318   in (ctxt, (using, goal)) end;
   319 
   320 
   321 
   322 (** pretty_state **)
   323 
   324 val verbose = ProofContext.verbose;
   325 
   326 fun pretty_facts _ _ NONE = []
   327   | pretty_facts s ctxt (SOME ths) =
   328       [Pretty.big_list (s ^ "this:") (map (Display.pretty_thm ctxt) ths), Pretty.str ""];
   329 
   330 fun pretty_state nr state =
   331   let
   332     val {context = ctxt, facts, mode, goal = _} = current state;
   333 
   334     fun levels_up 0 = ""
   335       | levels_up 1 = "1 level up"
   336       | levels_up i = string_of_int i ^ " levels up";
   337 
   338     fun subgoals 0 = ""
   339       | subgoals 1 = "1 subgoal"
   340       | subgoals n = string_of_int n ^ " subgoals";
   341 
   342     fun description strs =
   343       (case filter_out (fn s => s = "") strs of [] => ""
   344       | strs' => enclose " (" ")" (commas strs'));
   345 
   346     fun prt_goal (SOME (_, (i,
   347       {statement = ((_, pos), _, _), messages, using, goal, before_qed = _, after_qed = _}))) =
   348           pretty_facts "using " ctxt
   349             (if mode <> Backward orelse null using then NONE else SOME using) @
   350           [Pretty.str ("goal" ^
   351             description [levels_up (i div 2), subgoals (Thm.nprems_of goal)] ^ ":")] @
   352           Goal_Display.pretty_goals ctxt goal @
   353           (map (fn msg => Position.setmp_thread_data pos msg ()) (rev messages))
   354       | prt_goal NONE = [];
   355 
   356     val prt_ctxt =
   357       if ! verbose orelse mode = Forward then ProofContext.pretty_context ctxt
   358       else if mode = Backward then ProofContext.pretty_ctxt ctxt
   359       else [];
   360   in
   361     [Pretty.str ("proof (" ^ mode_name mode ^ "): step " ^ string_of_int nr ^
   362       (if ! verbose then ", depth " ^ string_of_int (level state div 2 - 1) else "")),
   363       Pretty.str ""] @
   364     (if null prt_ctxt then [] else prt_ctxt @ [Pretty.str ""]) @
   365     (if ! verbose orelse mode = Forward then
   366        pretty_facts "" ctxt facts @ prt_goal (try find_goal state)
   367      else if mode = Chain then pretty_facts "picking " ctxt facts
   368      else prt_goal (try find_goal state))
   369   end;
   370 
   371 fun pretty_goals main state =
   372   let
   373     val (_, (_, goal)) = get_goal state;
   374     val ctxt = context_of state
   375       |> Config.put Goal_Display.show_main_goal main
   376       |> Config.put Goal_Display.goals_total false;
   377   in Goal_Display.pretty_goals ctxt goal end;
   378 
   379 
   380 
   381 (** proof steps **)
   382 
   383 (* refine via method *)
   384 
   385 local
   386 
   387 fun goalN i = "goal" ^ string_of_int i;
   388 fun goals st = map goalN (1 upto Thm.nprems_of st);
   389 
   390 fun no_goal_cases st = map (rpair NONE) (goals st);
   391 
   392 fun goal_cases st =
   393   Rule_Cases.make_common (Thm.theory_of_thm st, Thm.prop_of st) (map (rpair []) (goals st));
   394 
   395 fun apply_method current_context meth state =
   396   let
   397     val (goal_ctxt, (_, {statement, messages = _, using, goal, before_qed, after_qed})) =
   398       find_goal state;
   399     val ctxt = if current_context then context_of state else goal_ctxt;
   400   in
   401     Method.apply meth ctxt using goal |> Seq.map (fn (meth_cases, goal') =>
   402       state
   403       |> map_goal
   404           (ProofContext.add_cases false (no_goal_cases goal @ goal_cases goal') #>
   405            ProofContext.add_cases true meth_cases)
   406           (K (statement, [], using, goal', before_qed, after_qed)))
   407   end;
   408 
   409 fun select_goals n meth state =
   410   state
   411   |> (#2 o #2 o get_goal)
   412   |> ALLGOALS Goal.conjunction_tac
   413   |> Seq.maps (fn goal =>
   414     state
   415     |> Seq.lift set_goal (Goal.extract 1 n goal |> Seq.maps (Goal.conjunction_tac 1))
   416     |> Seq.maps meth
   417     |> Seq.maps (fn state' => state'
   418       |> Seq.lift set_goal (Goal.retrofit 1 n (#2 (#2 (get_goal state'))) goal))
   419     |> Seq.maps (apply_method true (K Method.succeed)));
   420 
   421 fun apply_text cc text state =
   422   let
   423     val thy = theory_of state;
   424 
   425     fun eval (Method.Basic m) = apply_method cc m
   426       | eval (Method.Source src) = apply_method cc (Method.method thy src)
   427       | eval (Method.Source_i src) = apply_method cc (Method.method_i thy src)
   428       | eval (Method.Then txts) = Seq.EVERY (map eval txts)
   429       | eval (Method.Orelse txts) = Seq.FIRST (map eval txts)
   430       | eval (Method.Try txt) = Seq.TRY (eval txt)
   431       | eval (Method.Repeat1 txt) = Seq.REPEAT1 (eval txt)
   432       | eval (Method.SelectGoals (n, txt)) = select_goals n (eval txt);
   433   in eval text state end;
   434 
   435 in
   436 
   437 val refine = apply_text true;
   438 val refine_end = apply_text false;
   439 fun refine_insert ths = Seq.hd o refine (Method.Basic (K (Method.insert ths)));
   440 
   441 end;
   442 
   443 
   444 (* refine via sub-proof *)
   445 
   446 fun finish_tac 0 = K all_tac
   447   | finish_tac n =
   448       Goal.norm_hhf_tac THEN'
   449       SUBGOAL (fn (goal, i) =>
   450         if can Logic.unprotect (Logic.strip_assums_concl goal) then
   451           Tactic.etac Drule.protectI i THEN finish_tac (n - 1) i
   452         else finish_tac (n - 1) (i + 1));
   453 
   454 fun goal_tac rule =
   455   Goal.norm_hhf_tac THEN'
   456   Tactic.rtac rule THEN'
   457   finish_tac (Thm.nprems_of rule);
   458 
   459 fun refine_goals print_rule inner raw_rules state =
   460   let
   461     val (outer, (_, goal)) = get_goal state;
   462     fun refine rule st = (print_rule outer rule; FINDGOAL (goal_tac rule) st);
   463   in
   464     raw_rules
   465     |> ProofContext.goal_export inner outer
   466     |> (fn rules => Seq.lift set_goal (EVERY (map refine rules) goal) state)
   467   end;
   468 
   469 
   470 (* conclude_goal *)
   471 
   472 fun conclude_goal ctxt goal propss =
   473   let
   474     val thy = ProofContext.theory_of ctxt;
   475     val string_of_term = Syntax.string_of_term ctxt;
   476     val string_of_thm = Display.string_of_thm ctxt;
   477 
   478     val ngoals = Thm.nprems_of goal;
   479     val _ = ngoals = 0 orelse error (Pretty.string_of (Pretty.chunks
   480       (Goal_Display.pretty_goals ctxt goal @
   481         [Pretty.str (string_of_int ngoals ^ " unsolved goal(s)!")])));
   482 
   483     val extra_hyps = Assumption.extra_hyps ctxt goal;
   484     val _ = null extra_hyps orelse
   485       error ("Additional hypotheses:\n" ^ cat_lines (map string_of_term extra_hyps));
   486 
   487     fun lost_structure () = error ("Lost goal structure:\n" ^ string_of_thm goal);
   488 
   489     val th = Goal.conclude
   490       (if length (flat propss) > 1 then Thm.norm_proof goal else goal)
   491       handle THM _ => lost_structure ();
   492     val goal_propss = filter_out null propss;
   493     val results =
   494       Conjunction.elim_balanced (length goal_propss) th
   495       |> map2 Conjunction.elim_balanced (map length goal_propss)
   496       handle THM _ => lost_structure ();
   497     val _ = Unify.matches_list thy (flat goal_propss) (map Thm.prop_of (flat results)) orelse
   498       error ("Proved a different theorem:\n" ^ string_of_thm th);
   499     val _ = Thm.check_shyps (Variable.sorts_of ctxt) th;
   500 
   501     fun recover_result ([] :: pss) thss = [] :: recover_result pss thss
   502       | recover_result (_ :: pss) (ths :: thss) = ths :: recover_result pss thss
   503       | recover_result [] [] = []
   504       | recover_result _ _ = lost_structure ();
   505   in recover_result propss results end;
   506 
   507 
   508 (* goal views -- corresponding to methods *)
   509 
   510 fun raw_goal state =
   511   let val (ctxt, (facts, goal)) = get_goal state
   512   in {context = ctxt, facts = facts, goal = goal} end;
   513 
   514 val goal = raw_goal o refine_insert [];
   515 
   516 fun simple_goal state =
   517   let
   518     val (_, (facts, _)) = get_goal state;
   519     val (ctxt, (_, goal)) = get_goal (refine_insert facts state);
   520   in {context = ctxt, goal = goal} end;
   521 
   522 fun status_markup state =
   523   (case try goal state of
   524     SOME {goal, ...} => Markup.proof_state (Thm.nprems_of goal)
   525   | NONE => Markup.empty);
   526 
   527 
   528 
   529 (*** structured proof commands ***)
   530 
   531 (** context elements **)
   532 
   533 (* let bindings *)
   534 
   535 local
   536 
   537 fun gen_bind bind args state =
   538   state
   539   |> assert_forward
   540   |> map_context (bind true args #> snd)
   541   |> put_facts NONE;
   542 
   543 in
   544 
   545 val let_bind = gen_bind ProofContext.match_bind_i;
   546 val let_bind_cmd = gen_bind ProofContext.match_bind;
   547 
   548 end;
   549 
   550 
   551 (* concrete syntax *)
   552 
   553 local
   554 
   555 fun gen_write prep_arg mode args =
   556   assert_forward
   557   #> map_context (fn ctxt => ctxt |> ProofContext.notation true mode (map (prep_arg ctxt) args))
   558   #> put_facts NONE;
   559 
   560 in
   561 
   562 val write = gen_write (K I);
   563 
   564 val write_cmd =
   565   gen_write (fn ctxt => fn (c, mx) =>
   566     (ProofContext.read_const ctxt false (Syntax.mixfixT mx) c, mx));
   567 
   568 end;
   569 
   570 
   571 (* fix *)
   572 
   573 local
   574 
   575 fun gen_fix prep_vars args =
   576   assert_forward
   577   #> map_context (fn ctxt => snd (ProofContext.add_fixes (prep_vars ctxt args) ctxt))
   578   #> put_facts NONE;
   579 
   580 in
   581 
   582 val fix = gen_fix (K I);
   583 val fix_cmd = gen_fix (fn ctxt => fn args => fst (ProofContext.read_vars args ctxt));
   584 
   585 end;
   586 
   587 
   588 (* assume etc. *)
   589 
   590 local
   591 
   592 fun gen_assume asm prep_att exp args state =
   593   state
   594   |> assert_forward
   595   |> map_context_result (asm exp (Attrib.map_specs (prep_att (theory_of state)) args))
   596   |> these_factss [] |> #2;
   597 
   598 in
   599 
   600 val assm = gen_assume ProofContext.add_assms_i (K I);
   601 val assm_cmd = gen_assume ProofContext.add_assms Attrib.attribute;
   602 val assume = assm Assumption.assume_export;
   603 val assume_cmd = assm_cmd Assumption.assume_export;
   604 val presume = assm Assumption.presume_export;
   605 val presume_cmd = assm_cmd Assumption.presume_export;
   606 
   607 end;
   608 
   609 
   610 (* def *)
   611 
   612 local
   613 
   614 fun gen_def prep_att prep_vars prep_binds args state =
   615   let
   616     val _ = assert_forward state;
   617     val thy = theory_of state;
   618 
   619     val (raw_name_atts, (raw_vars, raw_rhss)) = args |> split_list ||> split_list;
   620     val name_atts = map (apsnd (map (prep_att thy))) raw_name_atts;
   621   in
   622     state
   623     |> map_context_result (prep_vars (map (fn (x, mx) => (x, NONE, mx)) raw_vars))
   624     |>> map (fn (x, _, mx) => (x, mx))
   625     |-> (fn vars =>
   626       map_context_result (prep_binds false (map swap raw_rhss))
   627       #-> (fn rhss => map_context_result (Local_Defs.add_defs (vars ~~ (name_atts ~~ rhss)))))
   628     |-> (put_facts o SOME o map (#2 o #2))
   629   end;
   630 
   631 in
   632 
   633 val def = gen_def (K I) ProofContext.cert_vars ProofContext.match_bind_i;
   634 val def_cmd = gen_def Attrib.attribute ProofContext.read_vars ProofContext.match_bind;
   635 
   636 end;
   637 
   638 
   639 
   640 (** facts **)
   641 
   642 (* chain *)
   643 
   644 fun clean_facts ctxt =
   645   put_facts (SOME (filter_out Thm.is_dummy (the_facts ctxt))) ctxt;
   646 
   647 val chain =
   648   assert_forward
   649   #> clean_facts
   650   #> enter_chain;
   651 
   652 fun chain_facts facts =
   653   put_facts (SOME facts)
   654   #> chain;
   655 
   656 
   657 (* note etc. *)
   658 
   659 fun no_binding args = map (pair (Binding.empty, [])) args;
   660 
   661 local
   662 
   663 fun gen_thmss more_facts opt_chain opt_result prep_atts prep_fact args state =
   664   state
   665   |> assert_forward
   666   |> map_context_result (ProofContext.note_thmss ""
   667     (Attrib.map_facts_refs (prep_atts (theory_of state)) (prep_fact (context_of state)) args))
   668   |> these_factss (more_facts state)
   669   ||> opt_chain
   670   |> opt_result;
   671 
   672 in
   673 
   674 val note_thmss = gen_thmss (K []) I #2 (K I) (K I);
   675 val note_thmss_cmd = gen_thmss (K []) I #2 Attrib.attribute ProofContext.get_fact;
   676 
   677 val from_thmss = gen_thmss (K []) chain #2 (K I) (K I) o no_binding;
   678 val from_thmss_cmd = gen_thmss (K []) chain #2 Attrib.attribute ProofContext.get_fact o no_binding;
   679 
   680 val with_thmss = gen_thmss the_facts chain #2 (K I) (K I) o no_binding;
   681 val with_thmss_cmd = gen_thmss the_facts chain #2 Attrib.attribute ProofContext.get_fact o no_binding;
   682 
   683 val local_results = gen_thmss (K []) I I (K I) (K I) o map (apsnd Thm.simple_fact);
   684 
   685 end;
   686 
   687 
   688 (* using/unfolding *)
   689 
   690 local
   691 
   692 fun gen_using f g prep_atts prep_fact args state =
   693   state
   694   |> assert_backward
   695   |> map_context_result
   696     (ProofContext.note_thmss ""
   697       (Attrib.map_facts_refs (prep_atts (theory_of state)) (prep_fact (context_of state))
   698         (no_binding args)))
   699   |> (fn (named_facts, state') =>
   700     state' |> map_goal I (fn (statement, _, using, goal, before_qed, after_qed) =>
   701       let
   702         val ctxt = context_of state';
   703         val ths = maps snd named_facts;
   704       in (statement, [], f ctxt ths using, g ctxt ths goal, before_qed, after_qed) end));
   705 
   706 fun append_using _ ths using = using @ filter_out Thm.is_dummy ths;
   707 fun unfold_using ctxt ths = map (Local_Defs.unfold ctxt ths);
   708 val unfold_goals = Local_Defs.unfold_goals;
   709 
   710 in
   711 
   712 val using = gen_using append_using (K (K I)) (K I) (K I);
   713 val using_cmd = gen_using append_using (K (K I)) Attrib.attribute ProofContext.get_fact;
   714 val unfolding = gen_using unfold_using unfold_goals (K I) (K I);
   715 val unfolding_cmd = gen_using unfold_using unfold_goals Attrib.attribute ProofContext.get_fact;
   716 
   717 end;
   718 
   719 
   720 (* case *)
   721 
   722 local
   723 
   724 fun qualified_binding a =
   725   Binding.qualify true (Long_Name.qualifier a) (Binding.name (Long_Name.base_name a));
   726 
   727 fun gen_invoke_case prep_att (name, xs, raw_atts) state =
   728   let
   729     val atts = map (prep_att (theory_of state)) raw_atts;
   730     val (asms, state') = state |> map_context_result (fn ctxt =>
   731       ctxt |> ProofContext.apply_case (ProofContext.get_case ctxt name xs));
   732     val assumptions = asms |> map (fn (a, ts) => ((qualified_binding a, atts), map (rpair []) ts));
   733   in
   734     state'
   735     |> assume assumptions
   736     |> bind_terms Auto_Bind.no_facts
   737     |> `the_facts |-> (fn thms => note_thmss [((Binding.name name, []), [(thms, [])])])
   738   end;
   739 
   740 in
   741 
   742 val invoke_case = gen_invoke_case (K I);
   743 val invoke_case_cmd = gen_invoke_case Attrib.attribute;
   744 
   745 end;
   746 
   747 
   748 
   749 (** proof structure **)
   750 
   751 (* blocks *)
   752 
   753 val begin_block =
   754   assert_forward
   755   #> open_block
   756   #> put_goal NONE
   757   #> open_block;
   758 
   759 val next_block =
   760   assert_forward
   761   #> close_block
   762   #> open_block
   763   #> put_goal NONE
   764   #> put_facts NONE;
   765 
   766 fun end_block state =
   767   state
   768   |> assert_forward
   769   |> close_block
   770   |> assert_current_goal false
   771   |> close_block
   772   |> export_facts state;
   773 
   774 
   775 (* sub-proofs *)
   776 
   777 fun proof opt_text =
   778   assert_backward
   779   #> refine (the_default Method.default_text opt_text)
   780   #> Seq.map (using_facts [] #> enter_forward);
   781 
   782 fun end_proof bot txt state =
   783   state
   784   |> assert_forward
   785   |> assert_bottom bot
   786   |> close_block
   787   |> assert_current_goal true
   788   |> using_facts []
   789   |> `before_qed |-> (refine o the_default Method.succeed_text)
   790   |> Seq.maps (refine (Method.finish_text txt));
   791 
   792 fun check_result msg sq =
   793   (case Seq.pull sq of
   794     NONE => error msg
   795   | SOME (s, _) => s);
   796 
   797 fun check_finish sq = check_result "Failed to finish proof" sq;
   798 
   799 
   800 (* unstructured refinement *)
   801 
   802 fun defer i = assert_no_chain #> refine (Method.Basic (K (Method.defer i)));
   803 fun prefer i = assert_no_chain #> refine (Method.Basic (K (Method.prefer i)));
   804 
   805 fun apply text = assert_backward #> refine text #> Seq.map (using_facts []);
   806 fun apply_end text = assert_forward #> refine_end text;
   807 
   808 
   809 
   810 (** goals **)
   811 
   812 (* generic goals *)
   813 
   814 local
   815 
   816 val is_var =
   817   can (dest_TVar o Logic.dest_type o Logic.dest_term) orf
   818   can (dest_Var o Logic.dest_term);
   819 
   820 fun implicit_vars props =
   821   let
   822     val (var_props, _) = take_prefix is_var props;
   823     val explicit_vars = fold Term.add_vars var_props [];
   824     val vars = filter_out (member (op =) explicit_vars) (fold Term.add_vars props []);
   825   in map (Logic.mk_term o Var) vars end;
   826 
   827 fun refine_terms n =
   828   refine (Method.Basic (K (RAW_METHOD
   829     (K (HEADGOAL (PRECISE_CONJUNCTS n
   830       (HEADGOAL (CONJUNCTS (ALLGOALS (rtac Drule.termI))))))))))
   831   #> Seq.hd;
   832 
   833 in
   834 
   835 fun generic_goal prepp kind before_qed after_qed raw_propp state =
   836   let
   837     val thy = theory_of state;
   838     val cert = Thm.cterm_of thy;
   839     val chaining = can assert_chain state;
   840     val pos = Position.thread_data ();
   841 
   842     val ((propss, after_ctxt), goal_state) =
   843       state
   844       |> assert_forward_or_chain
   845       |> enter_forward
   846       |> open_block
   847       |> map_context_result (fn ctxt => swap (prepp (ctxt, raw_propp)));
   848     val props = flat propss;
   849 
   850     val vars = implicit_vars props;
   851     val propss' = vars :: propss;
   852     val goal_propss = filter_out null propss';
   853     val goal =
   854       cert (Logic.mk_conjunction_balanced (map Logic.mk_conjunction_balanced goal_propss))
   855       |> Thm.weaken_sorts (Variable.sorts_of (context_of goal_state));
   856     val statement = ((kind, pos), propss', Thm.term_of goal);
   857     val after_qed' = after_qed |>> (fn after_local =>
   858       fn results => map_context after_ctxt #> after_local results);
   859   in
   860     goal_state
   861     |> map_context (init_context #> Variable.set_body true)
   862     |> put_goal (SOME (make_goal (statement, [], [], Goal.init goal, before_qed, after_qed')))
   863     |> map_context (ProofContext.auto_bind_goal props)
   864     |> chaining ? (`the_facts #-> using_facts)
   865     |> put_facts NONE
   866     |> open_block
   867     |> put_goal NONE
   868     |> enter_backward
   869     |> not (null vars) ? refine_terms (length goal_propss)
   870     |> null props ? (refine (Method.Basic Method.assumption) #> Seq.hd)
   871   end;
   872 
   873 fun generic_qed after_ctxt state =
   874   let
   875     val (goal_ctxt, {statement = (_, stmt, _), goal, after_qed, ...}) = current_goal state;
   876     val outer_state = state |> close_block;
   877     val outer_ctxt = context_of outer_state;
   878 
   879     val props =
   880       flat (tl stmt)
   881       |> Variable.exportT_terms goal_ctxt outer_ctxt;
   882     val results =
   883       tl (conclude_goal goal_ctxt goal stmt)
   884       |> burrow (ProofContext.export goal_ctxt outer_ctxt);
   885   in
   886     outer_state
   887     |> map_context (after_ctxt props)
   888     |> pair (after_qed, results)
   889   end;
   890 
   891 end;
   892 
   893 
   894 (* local goals *)
   895 
   896 fun local_goal print_results prep_att prepp kind before_qed after_qed stmt state =
   897   let
   898     val thy = theory_of state;
   899     val ((names, attss), propp) =
   900       Attrib.map_specs (prep_att thy) stmt |> split_list |>> split_list;
   901 
   902     fun after_qed' results =
   903       local_results ((names ~~ attss) ~~ results)
   904       #-> (fn res => tap (fn st => print_results (context_of st) ((kind, ""), res) : unit))
   905       #> after_qed results;
   906   in
   907     state
   908     |> generic_goal prepp kind before_qed (after_qed', K I) propp
   909     |> tap (Variable.warn_extra_tfrees (context_of state) o context_of)
   910   end;
   911 
   912 fun local_qeds txt =
   913   end_proof false txt
   914   #> Seq.map (generic_qed ProofContext.auto_bind_facts #->
   915     (fn ((after_qed, _), results) => after_qed results));
   916 
   917 fun local_qed txt = local_qeds txt #> check_finish;
   918 
   919 
   920 (* global goals *)
   921 
   922 fun global_goal prepp before_qed after_qed propp ctxt =
   923   init ctxt
   924   |> generic_goal (prepp #> ProofContext.auto_fixes) "" before_qed (K I, after_qed) propp;
   925 
   926 val theorem = global_goal ProofContext.bind_propp_schematic_i;
   927 val theorem_cmd = global_goal ProofContext.bind_propp_schematic;
   928 
   929 fun global_qeds txt =
   930   end_proof true txt
   931   #> Seq.map (generic_qed (K I) #> (fn (((_, after_qed), results), state) =>
   932     after_qed results (context_of state)));
   933 
   934 fun global_qed txt = global_qeds txt #> check_finish;
   935 
   936 
   937 (* concluding steps *)
   938 
   939 fun terminal_proof qed initial terminal =
   940   proof (SOME initial) #> Seq.maps (qed terminal) #> check_finish;
   941 
   942 fun local_terminal_proof (text, opt_text) = terminal_proof local_qeds text (opt_text, true);
   943 val local_default_proof = local_terminal_proof (Method.default_text, NONE);
   944 val local_immediate_proof = local_terminal_proof (Method.this_text, NONE);
   945 fun local_skip_proof int = local_terminal_proof (Method.sorry_text int, NONE);
   946 val local_done_proof = terminal_proof local_qeds Method.done_text (NONE, false);
   947 
   948 fun global_terminal_proof (text, opt_text) = terminal_proof global_qeds text (opt_text, true);
   949 val global_default_proof = global_terminal_proof (Method.default_text, NONE);
   950 val global_immediate_proof = global_terminal_proof (Method.this_text, NONE);
   951 fun global_skip_proof int = global_terminal_proof (Method.sorry_text int, NONE);
   952 val global_done_proof = terminal_proof global_qeds Method.done_text (NONE, false);
   953 
   954 
   955 (* common goal statements *)
   956 
   957 local
   958 
   959 fun gen_have prep_att prepp before_qed after_qed stmt int =
   960   local_goal (Proof_Display.print_results int) prep_att prepp "have" before_qed after_qed stmt;
   961 
   962 fun gen_show prep_att prepp before_qed after_qed stmt int state =
   963   let
   964     val testing = Unsynchronized.ref false;
   965     val rule = Unsynchronized.ref (NONE: thm option);
   966     fun fail_msg ctxt =
   967       "Local statement will fail to refine any pending goal" ::
   968       (case ! rule of NONE => [] | SOME th => [Proof_Display.string_of_rule ctxt "Failed" th])
   969       |> cat_lines;
   970 
   971     fun print_results ctxt res =
   972       if ! testing then () else Proof_Display.print_results int ctxt res;
   973     fun print_rule ctxt th =
   974       if ! testing then rule := SOME th
   975       else if int then priority (Proof_Display.string_of_rule ctxt "Successful" th)
   976       else ();
   977     val test_proof =
   978       try (local_skip_proof true)
   979       |> setmp_noncritical testing true
   980       |> Exn.capture;
   981 
   982     fun after_qed' results =
   983       refine_goals print_rule (context_of state) (flat results)
   984       #> check_result "Failed to refine any pending goal"
   985       #> after_qed results;
   986   in
   987     state
   988     |> local_goal print_results prep_att prepp "show" before_qed after_qed' stmt
   989     |> int ? (fn goal_state =>
   990       (case test_proof goal_state of
   991         Exn.Result (SOME _) => goal_state
   992       | Exn.Result NONE => error (fail_msg (context_of goal_state))
   993       | Exn.Exn exn =>
   994           if Exn.is_interrupt exn then reraise exn
   995           else raise Exn.EXCEPTIONS ([exn, ERROR (fail_msg (context_of goal_state))])))
   996   end;
   997 
   998 in
   999 
  1000 val have = gen_have (K I) ProofContext.bind_propp_i;
  1001 val have_cmd = gen_have Attrib.attribute ProofContext.bind_propp;
  1002 val show = gen_show (K I) ProofContext.bind_propp_i;
  1003 val show_cmd = gen_show Attrib.attribute ProofContext.bind_propp;
  1004 
  1005 end;
  1006 
  1007 
  1008 
  1009 (** future proofs **)
  1010 
  1011 (* relevant proof states *)
  1012 
  1013 fun is_schematic t =
  1014   Term.exists_subterm Term.is_Var t orelse
  1015   Term.exists_type (Term.exists_subtype Term.is_TVar) t;
  1016 
  1017 fun schematic_goal state =
  1018   let val (_, (_, {statement = (_, _, prop), ...})) = find_goal state
  1019   in is_schematic prop end;
  1020 
  1021 fun is_relevant state =
  1022   (case try find_goal state of
  1023     NONE => true
  1024   | SOME (_, (_, {statement = (_, _, prop), goal, ...})) =>
  1025       is_schematic prop orelse not (Logic.protect prop aconv Thm.concl_of goal));
  1026 
  1027 
  1028 (* full proofs *)
  1029 
  1030 local
  1031 
  1032 fun future_proof done get_context fork_proof state =
  1033   let
  1034     val _ = assert_backward state;
  1035     val (goal_ctxt, (_, goal)) = find_goal state;
  1036     val {statement as (kind, _, prop), messages, using, goal, before_qed, after_qed} = goal;
  1037     val goal_txt = prop :: map Thm.term_of (Assumption.all_assms_of goal_ctxt);
  1038 
  1039     val _ = is_relevant state andalso error "Cannot fork relevant proof";
  1040 
  1041     val prop' = Logic.protect prop;
  1042     val statement' = (kind, [[], [prop']], prop');
  1043     val goal' = Thm.adjust_maxidx_thm (Thm.maxidx_of goal)
  1044       (Drule.comp_no_flatten (goal, Thm.nprems_of goal) 1 Drule.protectI);
  1045 
  1046     fun after_local' [[th]] = put_thms false (Auto_Bind.thisN, SOME [th]);
  1047     fun after_global' [[th]] = ProofContext.put_thms false (Auto_Bind.thisN, SOME [th]);
  1048     val after_qed' = (after_local', after_global');
  1049     val this_name = ProofContext.full_name goal_ctxt (Binding.name Auto_Bind.thisN);
  1050 
  1051     val result_ctxt =
  1052       state
  1053       |> map_contexts (fold Variable.declare_term goal_txt)
  1054       |> map_goal I (K (statement', messages, using, goal', before_qed, after_qed'))
  1055       |> fork_proof;
  1056 
  1057     val future_thm = result_ctxt |> Future.map (fn (_, x) =>
  1058       ProofContext.get_fact_single (get_context x) (Facts.named this_name));
  1059     val finished_goal = Goal.future_result goal_ctxt future_thm prop';
  1060     val state' =
  1061       state
  1062       |> map_goal I (K (statement, messages, using, finished_goal, NONE, after_qed))
  1063       |> done;
  1064   in (Future.map #1 result_ctxt, state') end;
  1065 
  1066 in
  1067 
  1068 fun local_future_proof x = future_proof local_done_proof context_of x;
  1069 fun global_future_proof x = future_proof global_done_proof I x;
  1070 
  1071 end;
  1072 
  1073 
  1074 (* terminal proofs *)
  1075 
  1076 local
  1077 
  1078 fun future_terminal_proof proof1 proof2 meths int state =
  1079   if int orelse is_relevant state orelse not (Goal.local_future_enabled ())
  1080   then proof1 meths state
  1081   else snd (proof2 (fn state' => Goal.fork (fn () => ((), proof1 meths state'))) state);
  1082 
  1083 in
  1084 
  1085 fun local_future_terminal_proof x =
  1086   future_terminal_proof local_terminal_proof local_future_proof x;
  1087 
  1088 fun global_future_terminal_proof x =
  1089   future_terminal_proof global_terminal_proof global_future_proof x;
  1090 
  1091 end;
  1092 
  1093 end;
  1094