src/Pure/Isar/isar_cmd.ML
author wenzelm
Wed Dec 31 14:13:11 2014 +0100 (2014-12-31 ago)
changeset 59207 6b030dc97a4f
parent 59206 36808125e00f
child 59208 2486d625878b
permissions -rw-r--r--
more explict and generic field names
     1 (*  Title:      Pure/Isar/isar_cmd.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Miscellaneous Isar commands.
     5 *)
     6 
     7 signature ISAR_CMD =
     8 sig
     9   val global_setup: Input.source -> theory -> theory
    10   val local_setup: Input.source -> Proof.context -> Proof.context
    11   val parse_ast_translation: Input.source -> theory -> theory
    12   val parse_translation: Input.source -> theory -> theory
    13   val print_translation: Input.source -> theory -> theory
    14   val typed_print_translation: Input.source -> theory -> theory
    15   val print_ast_translation: Input.source -> theory -> theory
    16   val translations: (xstring * string) Syntax.trrule list -> theory -> theory
    17   val no_translations: (xstring * string) Syntax.trrule list -> theory -> theory
    18   val oracle: bstring * Position.range -> Input.source -> theory -> theory
    19   val add_defs: (bool * bool) * ((binding * string) * Token.src list) list -> theory -> theory
    20   val declaration: {syntax: bool, pervasive: bool} -> Input.source -> local_theory -> local_theory
    21   val simproc_setup: string * Position.T -> string list -> Input.source ->
    22     string list -> local_theory -> local_theory
    23   val have: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    24   val hence: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    25   val show: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    26   val thus: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    27   val qed: Method.text_range option -> Toplevel.transition -> Toplevel.transition
    28   val terminal_proof: Method.text_range * Method.text_range option ->
    29     Toplevel.transition -> Toplevel.transition
    30   val default_proof: Toplevel.transition -> Toplevel.transition
    31   val immediate_proof: Toplevel.transition -> Toplevel.transition
    32   val done_proof: Toplevel.transition -> Toplevel.transition
    33   val skip_proof: Toplevel.transition -> Toplevel.transition
    34   val ml_diag: bool -> Input.source -> Toplevel.transition -> Toplevel.transition
    35   val diag_state: Proof.context -> Toplevel.state
    36   val diag_goal: Proof.context -> {context: Proof.context, facts: thm list, goal: thm}
    37   val pretty_theorems: bool -> Toplevel.state -> Pretty.T list
    38   val thy_deps: Toplevel.transition -> Toplevel.transition
    39   val locale_deps: Toplevel.transition -> Toplevel.transition
    40   val print_stmts: string list * (Facts.ref * Token.src list) list
    41     -> Toplevel.transition -> Toplevel.transition
    42   val print_thms: string list * (Facts.ref * Token.src list) list
    43     -> Toplevel.transition -> Toplevel.transition
    44   val print_prfs: bool -> string list * (Facts.ref * Token.src list) list option
    45     -> Toplevel.transition -> Toplevel.transition
    46   val print_prop: (string list * string) -> Toplevel.transition -> Toplevel.transition
    47   val print_term: (string list * string) -> Toplevel.transition -> Toplevel.transition
    48   val print_type: (string list * (string * string option)) ->
    49     Toplevel.transition -> Toplevel.transition
    50 end;
    51 
    52 structure Isar_Cmd: ISAR_CMD =
    53 struct
    54 
    55 
    56 (** theory declarations **)
    57 
    58 (* generic setup *)
    59 
    60 fun global_setup source =
    61   ML_Lex.read_source false source
    62   |> ML_Context.expression (Input.range_of source) "setup" "theory -> theory"
    63     "Context.map_theory setup"
    64   |> Context.theory_map;
    65 
    66 fun local_setup source =
    67   ML_Lex.read_source false source
    68   |> ML_Context.expression (Input.range_of source) "local_setup" "local_theory -> local_theory"
    69     "Context.map_proof local_setup"
    70   |> Context.proof_map;
    71 
    72 
    73 (* translation functions *)
    74 
    75 fun parse_ast_translation source =
    76   ML_Lex.read_source false source
    77   |> ML_Context.expression (Input.range_of source) "parse_ast_translation"
    78     "(string * (Proof.context -> Ast.ast list -> Ast.ast)) list"
    79     "Context.map_theory (Sign.parse_ast_translation parse_ast_translation)"
    80   |> Context.theory_map;
    81 
    82 fun parse_translation source =
    83   ML_Lex.read_source false source
    84   |> ML_Context.expression (Input.range_of source) "parse_translation"
    85     "(string * (Proof.context -> term list -> term)) list"
    86     "Context.map_theory (Sign.parse_translation parse_translation)"
    87   |> Context.theory_map;
    88 
    89 fun print_translation source =
    90   ML_Lex.read_source false source
    91   |> ML_Context.expression (Input.range_of source) "print_translation"
    92     "(string * (Proof.context -> term list -> term)) list"
    93     "Context.map_theory (Sign.print_translation print_translation)"
    94   |> Context.theory_map;
    95 
    96 fun typed_print_translation source =
    97   ML_Lex.read_source false source
    98   |> ML_Context.expression (Input.range_of source) "typed_print_translation"
    99     "(string * (Proof.context -> typ -> term list -> term)) list"
   100     "Context.map_theory (Sign.typed_print_translation typed_print_translation)"
   101   |> Context.theory_map;
   102 
   103 fun print_ast_translation source =
   104   ML_Lex.read_source false source
   105   |> ML_Context.expression (Input.range_of source) "print_ast_translation"
   106     "(string * (Proof.context -> Ast.ast list -> Ast.ast)) list"
   107     "Context.map_theory (Sign.print_ast_translation print_ast_translation)"
   108   |> Context.theory_map;
   109 
   110 
   111 (* translation rules *)
   112 
   113 fun read_trrules thy raw_rules =
   114   let
   115     val ctxt = Proof_Context.init_global thy;
   116     val read_root =
   117       #1 o dest_Type o Proof_Context.read_type_name {proper = true, strict = false} ctxt;
   118   in
   119     raw_rules
   120     |> map (Syntax.map_trrule (fn (r, s) => Syntax_Phases.parse_ast_pattern ctxt (read_root r, s)))
   121   end;
   122 
   123 fun translations args thy = Sign.add_trrules (read_trrules thy args) thy;
   124 fun no_translations args thy = Sign.del_trrules (read_trrules thy args) thy;
   125 
   126 
   127 (* oracles *)
   128 
   129 fun oracle (name, range) source =
   130   let
   131     val body_range = Input.range_of source;
   132     val body = ML_Lex.read_source false source;
   133 
   134     val ants =
   135       ML_Lex.read
   136        ("local\n\
   137         \  val binding = " ^ ML_Syntax.make_binding (name, #1 range) ^ ";\n\
   138         \  val") @ ML_Lex.read_set_range body_range "oracle" @ ML_Lex.read "=" @ body @
   139         ML_Lex.read (";\nin\n\
   140         \  val") @ ML_Lex.read_set_range range name @ ML_Lex.read "=\
   141         \ snd (Context.>>> (Context.map_theory_result (Thm.add_oracle (binding, oracle))));\n\
   142         \end;\n";
   143   in
   144     Context.theory_map
   145       (ML_Context.exec (fn () => ML_Context.eval ML_Compiler.flags (#1 body_range) ants))
   146   end;
   147 
   148 
   149 (* old-style defs *)
   150 
   151 fun add_defs ((unchecked, overloaded), args) thy =
   152  (legacy_feature "Old 'defs' command -- use 'definition' (with 'overloading') instead";
   153   thy |>
   154     (if unchecked then Global_Theory.add_defs_unchecked_cmd else Global_Theory.add_defs_cmd)
   155       overloaded
   156       (map (fn ((b, ax), srcs) => ((b, ax), map (Attrib.attribute_cmd_global thy) srcs)) args)
   157   |> snd);
   158 
   159 
   160 (* declarations *)
   161 
   162 fun declaration {syntax, pervasive} source =
   163   ML_Lex.read_source false source
   164   |> ML_Context.expression (Input.range_of source) "declaration" "Morphism.declaration"
   165     ("Context.map_proof (Local_Theory.declaration {syntax = " ^ Bool.toString syntax ^ ", \
   166       \pervasive = " ^ Bool.toString pervasive ^ "} declaration)")
   167   |> Context.proof_map;
   168 
   169 
   170 (* simprocs *)
   171 
   172 fun simproc_setup name lhss source identifier =
   173   ML_Lex.read_source false source
   174   |> ML_Context.expression (Input.range_of source) "proc"
   175     "Morphism.morphism -> Proof.context -> cterm -> thm option"
   176     ("Context.map_proof (Simplifier.def_simproc_cmd {name = " ^ ML_Syntax.make_binding name ^ ", \
   177       \lhss = " ^ ML_Syntax.print_strings lhss ^ ", proc = proc, \
   178       \identifier = Library.maps ML_Context.thms " ^ ML_Syntax.print_strings identifier ^ "})")
   179   |> Context.proof_map;
   180 
   181 
   182 (* goals *)
   183 
   184 fun goal opt_chain goal stmt int =
   185   opt_chain #> goal NONE (K I) stmt int;
   186 
   187 val have = goal I Proof.have_cmd;
   188 val hence = goal Proof.chain Proof.have_cmd;
   189 val show = goal I Proof.show_cmd;
   190 val thus = goal Proof.chain Proof.show_cmd;
   191 
   192 
   193 (* local endings *)
   194 
   195 fun local_qed m = Toplevel.proof (Proof.local_qed (m, true));
   196 val local_terminal_proof = Toplevel.proof' o Proof.local_future_terminal_proof;
   197 val local_default_proof = Toplevel.proof Proof.local_default_proof;
   198 val local_immediate_proof = Toplevel.proof Proof.local_immediate_proof;
   199 val local_done_proof = Toplevel.proof Proof.local_done_proof;
   200 val local_skip_proof = Toplevel.proof' Proof.local_skip_proof;
   201 
   202 val skip_local_qed = Toplevel.skip_proof (fn i => if i > 1 then i - 1 else raise Toplevel.UNDEF);
   203 
   204 
   205 (* global endings *)
   206 
   207 fun global_qed m = Toplevel.end_proof (K (Proof.global_qed (m, true)));
   208 val global_terminal_proof = Toplevel.end_proof o Proof.global_future_terminal_proof;
   209 val global_default_proof = Toplevel.end_proof (K Proof.global_default_proof);
   210 val global_immediate_proof = Toplevel.end_proof (K Proof.global_immediate_proof);
   211 val global_skip_proof = Toplevel.end_proof Proof.global_skip_proof;
   212 val global_done_proof = Toplevel.end_proof (K Proof.global_done_proof);
   213 
   214 val skip_global_qed = Toplevel.skip_proof_to_theory (fn n => n = 1);
   215 
   216 
   217 (* common endings *)
   218 
   219 fun qed m = local_qed m o global_qed m o skip_local_qed o skip_global_qed;
   220 fun terminal_proof m = local_terminal_proof m o global_terminal_proof m;
   221 val default_proof = local_default_proof o global_default_proof;
   222 val immediate_proof = local_immediate_proof o global_immediate_proof;
   223 val done_proof = local_done_proof o global_done_proof;
   224 val skip_proof = local_skip_proof o global_skip_proof;
   225 
   226 
   227 (* diagnostic ML evaluation *)
   228 
   229 structure Diag_State = Proof_Data
   230 (
   231   type T = Toplevel.state;
   232   fun init _ = Toplevel.toplevel;
   233 );
   234 
   235 fun ml_diag verbose source = Toplevel.keep (fn state =>
   236   let
   237     val opt_ctxt =
   238       try Toplevel.generic_theory_of state
   239       |> Option.map (Context.proof_of #> Diag_State.put state);
   240     val flags = ML_Compiler.verbose verbose ML_Compiler.flags;
   241   in ML_Context.eval_source_in opt_ctxt flags source end);
   242 
   243 val diag_state = Diag_State.get;
   244 
   245 fun diag_goal ctxt =
   246   Proof.goal (Toplevel.proof_of (diag_state ctxt))
   247     handle Toplevel.UNDEF => error "No goal present";
   248 
   249 val _ = Theory.setup
   250   (ML_Antiquotation.value (Binding.qualify true "Isar" @{binding state})
   251     (Scan.succeed "Isar_Cmd.diag_state ML_context") #>
   252    ML_Antiquotation.value (Binding.qualify true "Isar" @{binding goal})
   253     (Scan.succeed "Isar_Cmd.diag_goal ML_context"));
   254 
   255 
   256 (* theorems of theory or proof context *)
   257 
   258 fun pretty_theorems verbose st =
   259   if Toplevel.is_proof st then
   260     Proof_Context.pretty_local_facts (Toplevel.context_of st) verbose
   261   else
   262     let
   263       val thy = Toplevel.theory_of st;
   264       val prev_thys =
   265         (case Toplevel.previous_context_of st of
   266           SOME prev => [Proof_Context.theory_of prev]
   267         | NONE => Theory.parents_of thy);
   268     in Proof_Display.pretty_theorems_diff verbose prev_thys thy end;
   269 
   270 
   271 (* display dependencies *)
   272 
   273 val thy_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   274   let
   275     val thy = Toplevel.theory_of state;
   276     val thy_session = Present.session_name thy;
   277 
   278     val graph = rev (Theory.nodes_of thy) |> map (fn node =>
   279       let
   280         val name = Context.theory_name node;
   281         val parents = map Context.theory_name (Theory.parents_of node);
   282         val session = Present.session_name node;
   283         val unfold = (session = thy_session);
   284       in
   285        {name = name, ident = name, parents = parents, directory = session,
   286         unfold = unfold, path = "", content = []}
   287       end);
   288   in Graph_Display.display_graph graph end);
   289 
   290 val locale_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   291   let
   292     val thy = Toplevel.theory_of state;
   293     val graph = Locale.pretty_locale_deps thy |> map (fn {name, parents, body} =>
   294      {name = Locale.extern thy name, ident = name, parents = parents,
   295       directory = "", unfold = true, path = "", content = [body]});
   296   in Graph_Display.display_graph graph end);
   297 
   298 
   299 (* print theorems, terms, types etc. *)
   300 
   301 local
   302 
   303 fun string_of_stmts ctxt args =
   304   Attrib.eval_thms ctxt args
   305   |> map (Element.pretty_statement ctxt Thm.theoremK)
   306   |> Pretty.chunks2 |> Pretty.string_of;
   307 
   308 fun string_of_thms ctxt args =
   309   Pretty.string_of (Proof_Context.pretty_fact ctxt ("", Attrib.eval_thms ctxt args));
   310 
   311 fun string_of_prfs full state arg =
   312   Pretty.string_of
   313     (case arg of
   314       NONE =>
   315         let
   316           val {context = ctxt, goal = thm} = Proof.simple_goal (Toplevel.proof_of state);
   317           val thy = Proof_Context.theory_of ctxt;
   318           val prf = Thm.proof_of thm;
   319           val prop = Thm.full_prop_of thm;
   320           val prf' = Proofterm.rewrite_proof_notypes ([], []) prf;
   321         in
   322           Proof_Syntax.pretty_proof ctxt
   323             (if full then Reconstruct.reconstruct_proof thy prop prf' else prf')
   324         end
   325     | SOME srcs =>
   326         let val ctxt = Toplevel.context_of state
   327         in map (Proof_Syntax.pretty_proof_of ctxt full) (Attrib.eval_thms ctxt srcs) end
   328         |> Pretty.chunks);
   329 
   330 fun string_of_prop ctxt s =
   331   let
   332     val prop = Syntax.read_prop ctxt s;
   333     val ctxt' = Variable.auto_fixes prop ctxt;
   334   in Pretty.string_of (Pretty.quote (Syntax.pretty_term ctxt' prop)) end;
   335 
   336 fun string_of_term ctxt s =
   337   let
   338     val t = Syntax.read_term ctxt s;
   339     val T = Term.type_of t;
   340     val ctxt' = Variable.auto_fixes t ctxt;
   341   in
   342     Pretty.string_of
   343       (Pretty.block [Pretty.quote (Syntax.pretty_term ctxt' t), Pretty.fbrk,
   344         Pretty.str "::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ ctxt' T)])
   345   end;
   346 
   347 fun string_of_type ctxt (s, NONE) =
   348       let val T = Syntax.read_typ ctxt s
   349       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt T)) end
   350   | string_of_type ctxt (s1, SOME s2) =
   351       let
   352         val ctxt' = Config.put show_sorts true ctxt;
   353         val raw_T = Syntax.parse_typ ctxt' s1;
   354         val S = Syntax.read_sort ctxt' s2;
   355         val T =
   356           Syntax.check_term ctxt'
   357             (Logic.mk_type raw_T |> Type.constraint (Term.itselfT (Type_Infer.anyT S)))
   358           |> Logic.dest_type;
   359       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt' T)) end;
   360 
   361 fun print_item string_of (modes, arg) = Toplevel.keep (fn state =>
   362   Print_Mode.with_modes modes (fn () => writeln (string_of state arg)) ());
   363 
   364 in
   365 
   366 val print_stmts = print_item (string_of_stmts o Toplevel.context_of);
   367 val print_thms = print_item (string_of_thms o Toplevel.context_of);
   368 val print_prfs = print_item o string_of_prfs;
   369 val print_prop = print_item (string_of_prop o Toplevel.context_of);
   370 val print_term = print_item (string_of_term o Toplevel.context_of);
   371 val print_type = print_item (string_of_type o Toplevel.context_of);
   372 
   373 end;
   374 
   375 end;