src/Pure/Isar/class_declaration.ML
author wenzelm
Mon Nov 14 16:52:19 2011 +0100 (2011-11-14 ago)
changeset 45488 6d71d9e52369
parent 45433 4283f3a57cf5
child 46856 28909eecdf5b
permissions -rw-r--r--
pass positions for named targets, for formal links in the document model;
     1 (*  Title:      Pure/Isar/class_declaration.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Declaring classes and subclass relations.
     5 *)
     6 
     7 signature CLASS_DECLARATION =
     8 sig
     9   val class: (local_theory -> local_theory) -> binding -> class list ->
    10     Element.context_i list -> theory -> string * local_theory
    11   val class_cmd: (local_theory -> local_theory) -> binding -> xstring list ->
    12     Element.context list -> theory -> string * local_theory
    13   val prove_subclass: (local_theory -> local_theory) -> tactic -> class ->
    14     local_theory -> local_theory
    15   val subclass: (local_theory -> local_theory) -> class -> local_theory -> Proof.state
    16   val subclass_cmd: (local_theory -> local_theory) -> xstring -> local_theory -> Proof.state
    17 end;
    18 
    19 structure Class_Declaration: CLASS_DECLARATION =
    20 struct
    21 
    22 (** class definitions **)
    23 
    24 local
    25 
    26 (* calculating class-related rules including canonical interpretation *)
    27 
    28 fun calculate thy class sups base_sort param_map assm_axiom =
    29   let
    30     val empty_ctxt = Proof_Context.init_global thy;
    31 
    32     (* instantiation of canonical interpretation *)
    33     val aT = TFree (Name.aT, base_sort);
    34     val param_map_const = (map o apsnd) Const param_map;
    35     val param_map_inst = (map o apsnd)
    36       (Const o apsnd (map_atyps (K aT))) param_map;
    37     val const_morph = Element.inst_morphism thy
    38       (Symtab.empty, Symtab.make param_map_inst);
    39     val typ_morph = Element.inst_morphism thy
    40       (Symtab.empty |> Symtab.update (Name.aT, TFree (Name.aT, [class])), Symtab.empty);
    41     val (([raw_props], [(_, raw_inst_morph)], export_morph), _) = empty_ctxt
    42       |> Expression.cert_goal_expression ([(class, (("", false),
    43            Expression.Named param_map_const))], []);
    44     val (props, inst_morph) =
    45       if null param_map
    46       then (raw_props |> map (Morphism.term typ_morph),
    47         raw_inst_morph $> typ_morph)
    48       else (raw_props, raw_inst_morph); (*FIXME proper handling in
    49         locale.ML / expression.ML would be desirable*)
    50 
    51     (* witness for canonical interpretation *)
    52     val prop = try the_single props;
    53     val wit = Option.map (fn prop =>
    54       let
    55         val sup_axioms = map_filter (fst o Class.rules thy) sups;
    56         val loc_intro_tac =
    57           (case Locale.intros_of thy class of
    58             (_, NONE) => all_tac
    59           | (_, SOME intro) => ALLGOALS (Tactic.rtac intro));
    60         val tac = loc_intro_tac
    61           THEN ALLGOALS (Proof_Context.fact_tac (sup_axioms @ the_list assm_axiom));
    62       in Element.prove_witness empty_ctxt prop tac end) prop;
    63     val axiom = Option.map Element.conclude_witness wit;
    64 
    65     (* canonical interpretation *)
    66     val base_morph = inst_morph
    67       $> Morphism.binding_morphism (Binding.prefix false (Class.class_prefix class))
    68       $> Element.satisfy_morphism (the_list wit);
    69     val eq_morph = Element.eq_morphism thy (Class.these_defs thy sups);
    70 
    71     (* assm_intro *)
    72     fun prove_assm_intro thm =
    73       let
    74         val ((_, [thm']), _) = Variable.import true [thm] empty_ctxt;
    75         val const_eq_morph =
    76           (case eq_morph of
    77              SOME eq_morph => const_morph $> eq_morph
    78           | NONE => const_morph);
    79         val thm'' = Morphism.thm const_eq_morph thm';
    80         val tac = ALLGOALS (Proof_Context.fact_tac [thm'']);
    81       in Skip_Proof.prove_global thy [] [] (Thm.prop_of thm'') (K tac) end;
    82     val assm_intro = Option.map prove_assm_intro
    83       (fst (Locale.intros_of thy class));
    84 
    85     (* of_class *)
    86     val of_class_prop_concl = Logic.mk_of_class (aT, class);
    87     val of_class_prop =
    88       (case prop of
    89         NONE => of_class_prop_concl
    90       | SOME prop => Logic.mk_implies (Morphism.term const_morph
    91           ((map_types o map_atyps) (K aT) prop), of_class_prop_concl));
    92     val sup_of_classes = map (snd o Class.rules thy) sups;
    93     val loc_axiom_intros = map Drule.export_without_context_open (Locale.axioms_of thy class);
    94     val axclass_intro = #intro (AxClass.get_info thy class);
    95     val base_sort_trivs = Thm.of_sort (Thm.ctyp_of thy aT, base_sort);
    96     val tac =
    97       REPEAT (SOMEGOAL
    98         (Tactic.match_tac (axclass_intro :: sup_of_classes @ loc_axiom_intros @ base_sort_trivs)
    99           ORELSE' Tactic.assume_tac));
   100     val of_class = Skip_Proof.prove_global thy [] [] of_class_prop (K tac);
   101 
   102   in (base_morph, eq_morph, export_morph, axiom, assm_intro, of_class) end;
   103 
   104 
   105 (* reading and processing class specifications *)
   106 
   107 fun prep_class_elems prep_decl thy sups raw_elems =
   108   let
   109 
   110     (* user space type system: only permits 'a type variable, improves towards 'a *)
   111     val algebra = Sign.classes_of thy;
   112     val inter_sort = curry (Sorts.inter_sort algebra);
   113     val proto_base_sort =
   114       if null sups then Sign.defaultS thy
   115       else fold inter_sort (map (Class.base_sort thy) sups) [];
   116     val base_constraints = (map o apsnd)
   117       (map_type_tfree (K (TVar ((Name.aT, 0), proto_base_sort))) o fst o snd)
   118         (Class.these_operations thy sups);
   119     fun singleton_fixate tms =
   120       let
   121         val tfrees = fold Term.add_tfrees tms [];
   122         val inferred_sort =
   123           (fold o fold_types o fold_atyps) (fn TVar (_, S) => inter_sort S | _ => I) tms [];
   124         val fixate_sort =
   125           (case tfrees of
   126             [] => inferred_sort
   127           | [(a, S)] =>
   128               if a <> Name.aT then
   129                 error ("No type variable other than " ^ Name.aT ^ " allowed in class specification")
   130               else if Sorts.sort_le algebra (S, inferred_sort) then S
   131               else
   132                 error ("Type inference imposes additional sort constraint " ^
   133                   Syntax.string_of_sort_global thy inferred_sort ^
   134                   " of type parameter " ^ Name.aT ^ " of sort " ^
   135                   Syntax.string_of_sort_global thy S)
   136           | _ => error "Multiple type variables in class specification");
   137         val fixateT = TFree (Name.aT, fixate_sort);
   138       in
   139         (map o map_types o map_atyps)
   140           (fn T as TVar (xi, _) => if Type_Infer.is_param xi then fixateT else T | T => T) tms
   141       end;
   142     fun after_infer_fixate tms =
   143       let
   144         val fixate_sort =
   145           (fold o fold_types o fold_atyps)
   146             (fn TVar (xi, S) => if Type_Infer.is_param xi then inter_sort S else I | _ => I) tms [];
   147       in
   148         (map o map_types o map_atyps)
   149           (fn T as TVar (xi, _) =>
   150               if Type_Infer.is_param xi then Type_Infer.param 0 (Name.aT, fixate_sort) else T
   151             | T => T) tms
   152       end;
   153 
   154     (* preprocessing elements, retrieving base sort from type-checked elements *)
   155     val raw_supexpr =
   156       (map (fn sup => (sup, (("", false), Expression.Positional []))) sups, []);
   157     val init_class_body =
   158       fold (Proof_Context.add_const_constraint o apsnd SOME) base_constraints
   159       #> Class.redeclare_operations thy sups
   160       #> Context.proof_map (Syntax_Phases.term_check 0 "singleton_fixate" (K singleton_fixate));
   161     val ((raw_supparams, _, raw_inferred_elems), _) =
   162       Proof_Context.init_global thy
   163       |> Context.proof_map (Syntax_Phases.term_check 0 "after_infer_fixate" (K after_infer_fixate))
   164       |> prep_decl raw_supexpr init_class_body raw_elems;
   165     fun filter_element (Element.Fixes []) = NONE
   166       | filter_element (e as Element.Fixes _) = SOME e
   167       | filter_element (Element.Constrains []) = NONE
   168       | filter_element (e as Element.Constrains _) = SOME e
   169       | filter_element (Element.Assumes []) = NONE
   170       | filter_element (e as Element.Assumes _) = SOME e
   171       | filter_element (Element.Defines _) =
   172           error ("\"defines\" element not allowed in class specification.")
   173       | filter_element (Element.Notes _) =
   174           error ("\"notes\" element not allowed in class specification.");
   175     val inferred_elems = map_filter filter_element raw_inferred_elems;
   176     fun fold_element_types f (Element.Fixes fxs) = fold (fn (_, SOME T, _) => f T) fxs
   177       | fold_element_types f (Element.Constrains cnstrs) = fold (f o snd) cnstrs
   178       | fold_element_types f (Element.Assumes assms) = fold (fold (fn (t, ts) =>
   179           fold_types f t #> (fold o fold_types) f ts) o snd) assms;
   180     val base_sort =
   181       if null inferred_elems then proto_base_sort
   182       else
   183         (case (fold o fold_element_types) Term.add_tfreesT inferred_elems [] of
   184           [] => error "No type variable in class specification"
   185         | [(_, sort)] => sort
   186         | _ => error "Multiple type variables in class specification");
   187     val supparams = map (fn ((c, T), _) =>
   188       (c, map_atyps (K (TFree (Name.aT, base_sort))) T)) raw_supparams;
   189     val supparam_names = map fst supparams;
   190     fun mk_param ((c, _), _) = Free (c, (the o AList.lookup (op =) supparams) c);
   191     val supexpr = (map (fn sup => (sup, (("", false),
   192       Expression.Positional (map (SOME o mk_param) (Locale.params_of thy sup))))) sups,
   193         map (fn (c, T) => (Binding.name c, SOME T, NoSyn)) supparams);
   194 
   195   in (base_sort, supparam_names, supexpr, inferred_elems) end;
   196 
   197 val cert_class_elems = prep_class_elems Expression.cert_declaration;
   198 val read_class_elems = prep_class_elems Expression.cert_read_declaration;
   199 
   200 fun prep_class_spec prep_class prep_class_elems thy raw_supclasses raw_elems =
   201   let
   202 
   203     (* prepare import *)
   204     val inter_sort = curry (Sorts.inter_sort (Sign.classes_of thy));
   205     val sups = Sign.minimize_sort thy (map (prep_class thy) raw_supclasses);
   206     val _ =
   207       (case filter_out (Class.is_class thy) sups of
   208         [] => ()
   209       | no_classes => error ("No (proper) classes: " ^ commas_quote no_classes));
   210     val raw_supparams = (map o apsnd) (snd o snd) (Class.these_params thy sups);
   211     val raw_supparam_names = map fst raw_supparams;
   212     val _ =
   213       if has_duplicates (op =) raw_supparam_names then
   214         error ("Duplicate parameter(s) in superclasses: " ^
   215           (commas_quote (duplicates (op =) raw_supparam_names)))
   216       else ();
   217 
   218     (* infer types and base sort *)
   219     val (base_sort, supparam_names, supexpr, inferred_elems) = prep_class_elems thy sups raw_elems;
   220     val sup_sort = inter_sort base_sort sups;
   221 
   222     (* process elements as class specification *)
   223     val class_ctxt = Class.begin sups base_sort (Proof_Context.init_global thy);
   224     val ((_, _, syntax_elems), _) = class_ctxt
   225       |> Expression.cert_declaration supexpr I inferred_elems;
   226     fun check_vars e vs =
   227       if null vs then
   228         error ("No type variable in part of specification element " ^
   229           Pretty.string_of (Pretty.chunks (Element.pretty_ctxt class_ctxt e)))
   230       else ();
   231     fun check_element (e as Element.Fixes fxs) =
   232           List.app (fn (_, SOME T, _) => check_vars e (Term.add_tfreesT T [])) fxs
   233       | check_element (e as Element.Assumes assms) =
   234           List.app (fn (_, ts_pss) =>
   235             List.app (fn (t, _) => check_vars e (Term.add_tfrees t [])) ts_pss) assms
   236       | check_element _ = ();
   237     val _ = List.app check_element syntax_elems;
   238     fun fork_syn (Element.Fixes xs) =
   239           fold_map (fn (c, ty, syn) => cons (c, syn) #> pair (c, ty, NoSyn)) xs
   240           #>> Element.Fixes
   241       | fork_syn x = pair x;
   242     val (elems, global_syntax) = fold_map fork_syn syntax_elems [];
   243 
   244   in (((sups, supparam_names), (sup_sort, base_sort, supexpr)), (elems, global_syntax)) end;
   245 
   246 val cert_class_spec = prep_class_spec (K I) cert_class_elems;
   247 val read_class_spec = prep_class_spec Sign.intern_class read_class_elems;
   248 
   249 
   250 (* class establishment *)
   251 
   252 fun add_consts class base_sort sups supparam_names global_syntax thy =
   253   let
   254     (*FIXME simplify*)
   255     val supconsts = supparam_names
   256       |> AList.make (snd o the o AList.lookup (op =) (Class.these_params thy sups))
   257       |> (map o apsnd o apsnd o map_atyps o K o TFree) (Name.aT, [class]);
   258     val all_params = Locale.params_of thy class;
   259     val raw_params = (snd o chop (length supparam_names)) all_params;
   260     fun add_const ((raw_c, raw_ty), _) thy =
   261       let
   262         val b = Binding.name raw_c;
   263         val c = Sign.full_name thy b;
   264         val ty = map_atyps (K (TFree (Name.aT, base_sort))) raw_ty;
   265         val ty0 = Type.strip_sorts ty;
   266         val ty' = map_atyps (K (TFree (Name.aT, [class]))) ty0;
   267         val syn = (the_default NoSyn o AList.lookup Binding.eq_name global_syntax) b;
   268       in
   269         thy
   270         |> Sign.declare_const_global ((b, ty0), syn)
   271         |> snd
   272         |> pair ((Variable.check_name b, ty), (c, ty'))
   273       end;
   274   in
   275     thy
   276     |> Sign.add_path (Class.class_prefix class)
   277     |> fold_map add_const raw_params
   278     ||> Sign.restore_naming thy
   279     |-> (fn params => pair (supconsts @ (map o apfst) fst params, params))
   280   end;
   281 
   282 fun adjungate_axclass bname class base_sort sups supsort supparam_names global_syntax thy =
   283   let
   284     (*FIXME simplify*)
   285     fun globalize param_map = map_aterms
   286       (fn Free (v, ty) => Const ((fst o the o AList.lookup (op =) param_map) v, ty)
   287         | t => t);
   288     val raw_pred = Locale.intros_of thy class
   289       |> fst
   290       |> Option.map (Logic.unvarify_global o Logic.strip_imp_concl o Thm.prop_of);
   291     fun get_axiom thy =
   292       (case #axioms (AxClass.get_info thy class) of
   293          [] => NONE
   294       | [thm] => SOME thm);
   295   in
   296     thy
   297     |> add_consts class base_sort sups supparam_names global_syntax
   298     |-> (fn (param_map, params) => AxClass.define_class (bname, supsort)
   299           (map (fst o snd) params)
   300           [(Thm.empty_binding, Option.map (globalize param_map) raw_pred |> the_list)]
   301     #> snd
   302     #> `get_axiom
   303     #-> (fn assm_axiom => fold (Sign.add_const_constraint o apsnd SOME o snd) params
   304     #> pair (param_map, params, assm_axiom)))
   305   end;
   306 
   307 fun gen_class prep_class_spec before_exit b raw_supclasses raw_elems thy =
   308   let
   309     val class = Sign.full_name thy b;
   310     val (((sups, supparam_names), (supsort, base_sort, supexpr)), (elems, global_syntax)) =
   311       prep_class_spec thy raw_supclasses raw_elems;
   312   in
   313     thy
   314     |> Expression.add_locale I b (Binding.qualify true "class" b) supexpr elems
   315     |> snd |> Local_Theory.exit_global
   316     |> adjungate_axclass b class base_sort sups supsort supparam_names global_syntax
   317     ||> Theory.checkpoint
   318     |-> (fn (param_map, params, assm_axiom) =>
   319        `(fn thy => calculate thy class sups base_sort param_map assm_axiom)
   320     #-> (fn (base_morph, eq_morph, export_morph, axiom, assm_intro, of_class) =>
   321        Context.theory_map (Locale.add_registration (class, base_morph)
   322          (Option.map (rpair true) eq_morph) export_morph)
   323     #> Class.register class sups params base_sort base_morph export_morph axiom assm_intro of_class))
   324     |> Named_Target.init before_exit class
   325     |> pair class
   326   end;
   327 
   328 in
   329 
   330 val class = gen_class cert_class_spec;
   331 val class_cmd = gen_class read_class_spec;
   332 
   333 end; (*local*)
   334 
   335 
   336 
   337 (** subclass relations **)
   338 
   339 local
   340 
   341 fun gen_subclass prep_class do_proof before_exit raw_sup lthy =
   342   let
   343     val thy = Proof_Context.theory_of lthy;
   344     val proto_sup = prep_class thy raw_sup;
   345     val proto_sub =
   346       (case Named_Target.peek lthy of
   347          SOME {target, is_class = true, ...} => target
   348       | _ => error "Not in a class target");
   349     val (sub, sup) = AxClass.cert_classrel thy (proto_sub, proto_sup);
   350 
   351     val expr = ([(sup, (("", false), Expression.Positional []))], []);
   352     val (([props], deps, export), goal_ctxt) =
   353       Expression.cert_goal_expression expr lthy;
   354     val some_prop = try the_single props;
   355     val some_dep_morph = try the_single (map snd deps);
   356     fun after_qed some_wit =
   357       Proof_Context.background_theory (Class.register_subclass (sub, sup)
   358         some_dep_morph some_wit export)
   359       #> Proof_Context.theory_of #> Named_Target.init before_exit sub;
   360   in do_proof after_qed some_prop goal_ctxt end;
   361 
   362 fun user_proof after_qed some_prop =
   363   Element.witness_proof (after_qed o try the_single o the_single)
   364     [the_list some_prop];
   365 
   366 fun tactic_proof tac after_qed some_prop ctxt =
   367   after_qed (Option.map
   368     (fn prop => Element.prove_witness ctxt prop tac) some_prop) ctxt;
   369 
   370 in
   371 
   372 val subclass = gen_subclass (K I) user_proof;
   373 fun prove_subclass before_exit tac = gen_subclass (K I) (tactic_proof tac) before_exit;
   374 val subclass_cmd = gen_subclass (Proof_Context.read_class o Proof_Context.init_global) user_proof;
   375 
   376 end; (*local*)
   377 
   378 end;