src/Pure/Isar/generic_target.ML
author wenzelm
Mon Nov 14 16:52:19 2011 +0100 (2011-11-14 ago)
changeset 45488 6d71d9e52369
parent 45413 117ff038f8f7
child 46916 e7ea35b41e2d
permissions -rw-r--r--
pass positions for named targets, for formal links in the document model;
     1 (*  Title:      Pure/Isar/generic_target.ML
     2     Author:     Makarius
     3     Author:     Florian Haftmann, TU Muenchen
     4 
     5 Common target infrastructure.
     6 *)
     7 
     8 signature GENERIC_TARGET =
     9 sig
    10   val define: (((binding * typ) * mixfix) * (binding * term) ->
    11       term list * term list -> local_theory -> (term * thm) * local_theory) ->
    12     (binding * mixfix) * (Attrib.binding * term) -> local_theory ->
    13     (term * (string * thm)) * local_theory
    14   val notes: (string -> (Attrib.binding * (thm list * Args.src list) list) list ->
    15       (Attrib.binding * (thm list * Args.src list) list) list -> local_theory -> local_theory) ->
    16     string -> (Attrib.binding * (thm list * Args.src list) list) list -> local_theory ->
    17     (string * thm list) list * local_theory
    18   val abbrev: (string * bool -> binding * mixfix -> term * term ->
    19       term list -> local_theory -> local_theory) ->
    20     string * bool -> (binding * mixfix) * term -> local_theory ->
    21     (term * term) * local_theory
    22 
    23   val theory_declaration: declaration -> local_theory -> local_theory
    24   val theory_foundation: ((binding * typ) * mixfix) * (binding * term) ->
    25     term list * term list -> local_theory -> (term * thm) * local_theory
    26   val theory_notes: string -> (Attrib.binding * (thm list * Args.src list) list) list ->
    27     local_theory -> local_theory
    28   val theory_abbrev: Syntax.mode -> (binding * mixfix) * term -> local_theory -> local_theory
    29 end
    30 
    31 structure Generic_Target: GENERIC_TARGET =
    32 struct
    33 
    34 (** lifting primitive to target operations **)
    35 
    36 (* mixfix syntax *)
    37 
    38 fun check_mixfix ctxt (b, extra_tfrees) mx =
    39   if null extra_tfrees then mx
    40   else
    41     (Context_Position.if_visible ctxt warning
    42       ("Additional type variable(s) in specification of " ^ Binding.print b ^ ": " ^
    43         commas (map (Syntax.string_of_typ ctxt o TFree) (sort_wrt #1 extra_tfrees)) ^
    44         (if mx = NoSyn then ""
    45          else "\nDropping mixfix syntax " ^ Pretty.string_of (Mixfix.pretty_mixfix mx)));
    46       NoSyn);
    47 
    48 
    49 (* define *)
    50 
    51 fun define foundation ((b, mx), ((proto_b_def, atts), rhs)) lthy =
    52   let
    53     val thy = Proof_Context.theory_of lthy;
    54     val thy_ctxt = Proof_Context.init_global thy;
    55 
    56     val b_def = Thm.def_binding_optional b proto_b_def;
    57 
    58     (*term and type parameters*)
    59     val crhs = Thm.cterm_of thy rhs;
    60     val ((defs, _), rhs') = Local_Defs.export_cterm lthy thy_ctxt crhs ||> Thm.term_of;
    61     val rhs_conv = Raw_Simplifier.rewrite true defs crhs;
    62 
    63     val xs = Variable.add_fixed (Local_Theory.target_of lthy) rhs' [];
    64     val T = Term.fastype_of rhs;
    65     val tfreesT = Term.add_tfreesT T (fold (Term.add_tfreesT o #2) xs []);
    66     val extra_tfrees = rev (subtract (op =) tfreesT (Term.add_tfrees rhs []));
    67     val mx' = check_mixfix lthy (b, extra_tfrees) mx;
    68 
    69     val type_params = map (Logic.mk_type o TFree) extra_tfrees;
    70     val target_ctxt = Local_Theory.target_of lthy;
    71     val term_params =
    72       filter (Variable.is_fixed target_ctxt o #1) xs
    73       |> sort (Variable.fixed_ord target_ctxt o pairself #1)
    74       |> map Free;
    75     val params = type_params @ term_params;
    76 
    77     val U = map Term.fastype_of params ---> T;
    78 
    79     (*foundation*)
    80     val ((lhs', global_def), lthy2) = lthy
    81       |> foundation (((b, U), mx'), (b_def, rhs')) (type_params, term_params);
    82 
    83     (*local definition*)
    84     val ((lhs, local_def), lthy3) = lthy2
    85       |> Local_Defs.add_def ((b, NoSyn), lhs');
    86     val def = Local_Defs.trans_terms lthy3
    87       [(*c == global.c xs*)     local_def,
    88        (*global.c xs == rhs'*)  global_def,
    89        (*rhs' == rhs*)          Thm.symmetric rhs_conv];
    90 
    91     (*note*)
    92     val ([(res_name, [res])], lthy4) = lthy3
    93       |> Local_Theory.notes_kind "" [((b_def, atts), [([def], [])])];
    94   in ((lhs, (res_name, res)), lthy4) end;
    95 
    96 
    97 (* notes *)
    98 
    99 fun import_export_proof ctxt (name, raw_th) =
   100   let
   101     val thy = Proof_Context.theory_of ctxt;
   102     val thy_ctxt = Proof_Context.init_global thy;
   103     val certT = Thm.ctyp_of thy;
   104     val cert = Thm.cterm_of thy;
   105 
   106     (*export assumes/defines*)
   107     val th = Goal.norm_result raw_th;
   108     val ((defs, asms), th') = Local_Defs.export ctxt thy_ctxt th;
   109     val asms' = map (Raw_Simplifier.rewrite_rule defs) asms;
   110 
   111     (*export fixes*)
   112     val tfrees = map TFree (Thm.fold_terms Term.add_tfrees th' []);
   113     val frees = map Free (Thm.fold_terms Term.add_frees th' []);
   114     val (th'' :: vs) =
   115       (th' :: map (Drule.mk_term o cert) (map Logic.mk_type tfrees @ frees))
   116       |> Variable.export ctxt thy_ctxt
   117       |> Drule.zero_var_indexes_list;
   118 
   119     (*thm definition*)
   120     val result = Global_Theory.name_thm true true name th'';
   121 
   122     (*import fixes*)
   123     val (tvars, vars) =
   124       chop (length tfrees) (map (Thm.term_of o Drule.dest_term) vs)
   125       |>> map Logic.dest_type;
   126 
   127     val instT = map_filter (fn (TVar v, T) => SOME (v, T) | _ => NONE) (tvars ~~ tfrees);
   128     val inst = filter (is_Var o fst) (vars ~~ frees);
   129     val cinstT = map (pairself certT o apfst TVar) instT;
   130     val cinst = map (pairself (cert o Term.map_types (Term_Subst.instantiateT instT))) inst;
   131     val result' = Thm.instantiate (cinstT, cinst) result;
   132 
   133     (*import assumes/defines*)
   134     val result'' =
   135       (fold (curry op COMP) asms' result'
   136         handle THM _ => raise THM ("Failed to re-import result", 0, result' :: asms'))
   137       |> Local_Defs.contract ctxt defs (Thm.cprop_of th)
   138       |> Goal.norm_result
   139       |> Global_Theory.name_thm false false name;
   140 
   141   in (result'', result) end;
   142 
   143 fun notes target_notes kind facts lthy =
   144   let
   145     val thy = Proof_Context.theory_of lthy;
   146     val facts' = facts
   147       |> map (fn (a, bs) => (a, Global_Theory.burrow_fact (Global_Theory.name_multi
   148           (Local_Theory.full_name lthy (fst a))) bs))
   149       |> Global_Theory.map_facts (import_export_proof lthy);
   150     val local_facts = Global_Theory.map_facts #1 facts';
   151     val global_facts = Global_Theory.map_facts #2 facts';
   152   in
   153     lthy
   154     |> target_notes kind global_facts local_facts
   155     |> Proof_Context.note_thmss kind (Attrib.map_facts (map (Attrib.attribute_i thy)) local_facts)
   156   end;
   157 
   158 
   159 (* abbrev *)
   160 
   161 fun abbrev target_abbrev prmode ((b, mx), t) lthy =
   162   let
   163     val thy_ctxt = Proof_Context.init_global (Proof_Context.theory_of lthy);
   164     val target_ctxt = Local_Theory.target_of lthy;
   165 
   166     val t' = Assumption.export_term lthy target_ctxt t;
   167     val xs = map Free (rev (Variable.add_fixed target_ctxt t' []));
   168     val u = fold_rev lambda xs t';
   169 
   170     val extra_tfrees =
   171       subtract (op =) (Term.add_tfreesT (Term.fastype_of u) []) (Term.add_tfrees u []);
   172     val mx' = check_mixfix lthy (b, extra_tfrees) mx;
   173 
   174     val global_rhs =
   175       singleton (Variable.export_terms (Variable.declare_term u target_ctxt) thy_ctxt) u;
   176   in
   177     lthy
   178     |> target_abbrev prmode (b, mx') (global_rhs, t') xs
   179     |> Proof_Context.add_abbrev Print_Mode.internal (b, t) |> snd
   180     |> Local_Defs.fixed_abbrev ((b, NoSyn), t)
   181   end;
   182 
   183 
   184 
   185 (** primitive theory operations **)
   186 
   187 fun theory_declaration decl lthy =
   188   let
   189     val global_decl = Morphism.form
   190       (Morphism.transform (Local_Theory.global_morphism lthy) decl);
   191   in
   192     lthy
   193     |> Local_Theory.background_theory (Context.theory_map global_decl)
   194     |> Local_Theory.target (Context.proof_map global_decl)
   195     |> Context.proof_map (Morphism.form decl)
   196   end;
   197 
   198 fun theory_foundation (((b, U), mx), (b_def, rhs)) (type_params, term_params) lthy =
   199   let
   200     val (const, lthy2) = lthy
   201       |> Local_Theory.background_theory_result (Sign.declare_const lthy ((b, U), mx));
   202     val lhs = list_comb (const, type_params @ term_params);
   203     val ((_, def), lthy3) = lthy2
   204       |> Local_Theory.background_theory_result
   205         (Thm.add_def lthy2 false false (b_def, Logic.mk_equals (lhs, rhs)));
   206   in ((lhs, def), lthy3) end;
   207 
   208 fun theory_notes kind global_facts lthy =
   209   let
   210     val thy = Proof_Context.theory_of lthy;
   211     val global_facts' = Attrib.map_facts (map (Attrib.attribute_i thy)) global_facts;
   212   in
   213     lthy
   214     |> Local_Theory.background_theory (Global_Theory.note_thmss kind global_facts' #> snd)
   215     |> Local_Theory.target (Proof_Context.note_thmss kind global_facts' #> snd)
   216   end;
   217 
   218 fun theory_abbrev prmode ((b, mx), t) =
   219   Local_Theory.background_theory
   220     (Sign.add_abbrev (#1 prmode) (b, t) #->
   221       (fn (lhs, _) => Sign.notation true prmode [(lhs, mx)]));
   222 
   223 end;