src/Pure/Syntax/syn_ext.ML
author wenzelm
Wed Jun 02 11:09:26 2010 +0200 (2010-06-02 ago)
changeset 37251 72c7e636067b
parent 37216 3165bc303f66
child 40959 49765c1104d4
permissions -rw-r--r--
normalize and postprocess proof body in a separate future, taking care of platforms without multithreading (greately improves parallelization in general without the overhead of promised proofs, cf. usedir -q 0);
     1 (*  Title:      Pure/Syntax/syn_ext.ML
     2     Author:     Markus Wenzel and Carsten Clasohm, TU Muenchen
     3 
     4 Syntax extension (internal interface).
     5 *)
     6 
     7 signature SYN_EXT0 =
     8 sig
     9   val dddot_indexname: indexname
    10   val constrainC: string
    11   val typeT: typ
    12   val spropT: typ
    13   val max_pri: int
    14   val stamp_trfun: stamp -> string * 'a -> string * ('a * stamp)
    15   val mk_trfun: string * 'a -> string * ('a * stamp)
    16   val eq_trfun: ('a * stamp) * ('a * stamp) -> bool
    17   val escape: string -> string
    18   val tokentrans_mode:
    19     string -> (string * (Proof.context -> string -> Pretty.T)) list ->
    20     (string * string * (Proof.context -> string -> Pretty.T)) list
    21   val standard_token_classes: string list
    22 end;
    23 
    24 signature SYN_EXT =
    25 sig
    26   include SYN_EXT0
    27   val logic: string
    28   val args: string
    29   val cargs: string
    30   val any: string
    31   val sprop: string
    32   datatype mfix = Mfix of string * typ * string * int list * int
    33   val err_in_mfix: string -> mfix -> 'a
    34   val typ_to_nonterm: typ -> string
    35   datatype xsymb =
    36     Delim of string |
    37     Argument of string * int |
    38     Space of string |
    39     Bg of int | Brk of int | En
    40   datatype xprod = XProd of string * xsymb list * string * int
    41   val chain_pri: int
    42   val delims_of: xprod list -> string list list
    43   datatype syn_ext =
    44     Syn_Ext of {
    45       xprods: xprod list,
    46       consts: string list,
    47       prmodes: string list,
    48       parse_ast_translation: (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list,
    49       parse_rules: (Ast.ast * Ast.ast) list,
    50       parse_translation: (string * ((Proof.context -> term list -> term) * stamp)) list,
    51       print_translation:
    52         (string * ((Proof.context -> bool -> typ -> term list -> term) * stamp)) list,
    53       print_rules: (Ast.ast * Ast.ast) list,
    54       print_ast_translation: (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list,
    55       token_translation: (string * string * (Proof.context -> string -> Pretty.T)) list}
    56   val mfix_delims: string -> string list
    57   val mfix_args: string -> int
    58   val syn_ext': bool -> (string -> bool) -> mfix list ->
    59     string list -> (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list *
    60     (string * ((Proof.context -> term list -> term) * stamp)) list *
    61     (string * ((Proof.context -> bool -> typ -> term list -> term) * stamp)) list *
    62     (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list
    63     -> (string * string * (Proof.context -> string -> Pretty.T)) list
    64     -> (Ast.ast * Ast.ast) list * (Ast.ast * Ast.ast) list -> syn_ext
    65   val syn_ext: mfix list -> string list ->
    66     (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list *
    67     (string * ((Proof.context -> term list -> term) * stamp)) list *
    68     (string * ((Proof.context -> bool -> typ -> term list -> term) * stamp)) list *
    69     (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list
    70     -> (string * string * (Proof.context -> string -> Pretty.T)) list
    71     -> (Ast.ast * Ast.ast) list * (Ast.ast * Ast.ast) list -> syn_ext
    72   val syn_ext_const_names: string list -> syn_ext
    73   val syn_ext_rules: (Ast.ast * Ast.ast) list * (Ast.ast * Ast.ast) list -> syn_ext
    74   val syn_ext_trfuns:
    75     (string * ((Ast.ast list -> Ast.ast) * stamp)) list *
    76     (string * ((term list -> term) * stamp)) list *
    77     (string * ((bool -> typ -> term list -> term) * stamp)) list *
    78     (string * ((Ast.ast list -> Ast.ast) * stamp)) list -> syn_ext
    79   val syn_ext_advanced_trfuns:
    80     (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list *
    81     (string * ((Proof.context -> term list -> term) * stamp)) list *
    82     (string * ((Proof.context -> bool -> typ -> term list -> term) * stamp)) list *
    83     (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list -> syn_ext
    84   val syn_ext_tokentrfuns: (string * string * (Proof.context -> string -> Pretty.T)) list -> syn_ext
    85   val standard_token_markers: string list
    86   val pure_ext: syn_ext
    87 end;
    88 
    89 structure Syn_Ext: SYN_EXT =
    90 struct
    91 
    92 
    93 (** misc definitions **)
    94 
    95 val dddot_indexname = ("dddot", 0);
    96 val constrainC = "_constrain";
    97 
    98 
    99 (* syntactic categories *)
   100 
   101 val logic = "logic";
   102 val logicT = Type (logic, []);
   103 
   104 val args = "args";
   105 val cargs = "cargs";
   106 
   107 val typeT = Type ("type", []);
   108 
   109 val sprop = "#prop";
   110 val spropT = Type (sprop, []);
   111 
   112 val any = "any";
   113 val anyT = Type (any, []);
   114 
   115 
   116 
   117 (** datatype xprod **)
   118 
   119 (*Delim s: delimiter s
   120   Argument (s, p): nonterminal s requiring priority >= p, or valued token
   121   Space s: some white space for printing
   122   Bg, Brk, En: blocks and breaks for pretty printing*)
   123 
   124 datatype xsymb =
   125   Delim of string |
   126   Argument of string * int |
   127   Space of string |
   128   Bg of int | Brk of int | En;
   129 
   130 fun is_delim (Delim _) = true
   131   | is_delim _ = false;
   132 
   133 fun is_terminal (Delim _) = true
   134   | is_terminal (Argument (s, _)) = Lexicon.is_terminal s
   135   | is_terminal _ = false;
   136 
   137 fun is_argument (Argument _) = true
   138   | is_argument _ = false;
   139 
   140 fun is_index (Argument ("index", _)) = true
   141   | is_index _ = false;
   142 
   143 val index = Argument ("index", 1000);
   144 
   145 
   146 (*XProd (lhs, syms, c, p):
   147     lhs: name of nonterminal on the lhs of the production
   148     syms: list of symbols on the rhs of the production
   149     c: head of parse tree
   150     p: priority of this production*)
   151 
   152 datatype xprod = XProd of string * xsymb list * string * int;
   153 
   154 val max_pri = 1000;   (*maximum legal priority*)
   155 val chain_pri = ~1;   (*dummy for chain productions*)
   156 
   157 fun delims_of xprods =
   158   fold (fn XProd (_, xsymbs, _, _) =>
   159     fold (fn Delim s => insert (op =) s | _ => I) xsymbs) xprods []
   160   |> map Symbol.explode;
   161 
   162 
   163 
   164 (** datatype mfix **)
   165 
   166 (*Mfix (sy, ty, c, ps, p):
   167     sy: rhs of production as symbolic string
   168     ty: type description of production
   169     c: head of parse tree
   170     ps: priorities of arguments in sy
   171     p: priority of production*)
   172 
   173 datatype mfix = Mfix of string * typ * string * int list * int;
   174 
   175 fun err_in_mfix msg (Mfix (sy, _, const, _, _)) =
   176   cat_error msg ("in mixfix annotation " ^ quote sy ^ " for " ^ quote const);
   177 
   178 
   179 (* typ_to_nonterm *)
   180 
   181 fun typ_to_nt _ (Type (c, _)) = c
   182   | typ_to_nt default _ = default;
   183 
   184 (*get nonterminal for rhs*)
   185 val typ_to_nonterm = typ_to_nt any;
   186 
   187 (*get nonterminal for lhs*)
   188 val typ_to_nonterm1 = typ_to_nt logic;
   189 
   190 
   191 (* read mixfix annotations *)
   192 
   193 local
   194 
   195 val is_meta = member (op =) ["(", ")", "/", "_", "\\<index>"];
   196 
   197 val scan_delim_char =
   198   $$ "'" |-- Scan.one ((not o Symbol.is_blank) andf Symbol.is_regular) ||
   199   Scan.one ((not o is_meta) andf (not o Symbol.is_blank) andf Symbol.is_regular);
   200 
   201 fun read_int ["0", "0"] = ~1
   202   | read_int cs = #1 (Library.read_int cs);
   203 
   204 val scan_sym =
   205   $$ "_" >> K (Argument ("", 0)) ||
   206   $$ "\\<index>" >> K index ||
   207   $$ "(" |-- Scan.many Symbol.is_digit >> (Bg o read_int) ||
   208   $$ ")" >> K En ||
   209   $$ "/" -- $$ "/" >> K (Brk ~1) ||
   210   $$ "/" |-- Scan.many Symbol.is_blank >> (Brk o length) ||
   211   Scan.many1 Symbol.is_blank >> (Space o implode) ||
   212   Scan.repeat1 scan_delim_char >> (Delim o implode);
   213 
   214 val scan_symb =
   215   scan_sym >> SOME ||
   216   $$ "'" -- Scan.one Symbol.is_blank >> K NONE;
   217 
   218 val scan_symbs = Scan.repeat scan_symb --| Scan.ahead (~$$ "'");
   219 val read_symbs = map_filter I o the o Scan.read Symbol.stopper scan_symbs;
   220 
   221 fun unique_index xsymbs =
   222   if length (filter is_index xsymbs) <= 1 then xsymbs
   223   else error "Duplicate index arguments (\\<index>)";
   224 
   225 in
   226 
   227 val read_mfix = unique_index o read_symbs o Symbol.explode;
   228 
   229 fun mfix_delims sy = fold_rev (fn Delim s => cons s | _ => I) (read_mfix sy) [];
   230 val mfix_args = length o filter is_argument o read_mfix;
   231 
   232 val escape = implode o map (fn s => if is_meta s then "'" ^ s else s) o Symbol.explode;
   233 
   234 end;
   235 
   236 
   237 (* mfix_to_xprod *)
   238 
   239 fun mfix_to_xprod convert is_logtype (mfix as Mfix (sy, typ, const, pris, pri)) =
   240   let
   241     fun check_pri p =
   242       if p >= 0 andalso p <= max_pri then ()
   243       else err_in_mfix ("Precedence out of range: " ^ string_of_int p) mfix;
   244 
   245     fun blocks_ok [] 0 = true
   246       | blocks_ok [] _ = false
   247       | blocks_ok (Bg _ :: syms) n = blocks_ok syms (n + 1)
   248       | blocks_ok (En :: _) 0 = false
   249       | blocks_ok (En :: syms) n = blocks_ok syms (n - 1)
   250       | blocks_ok (_ :: syms) n = blocks_ok syms n;
   251 
   252     fun check_blocks syms =
   253       if blocks_ok syms 0 then ()
   254       else err_in_mfix "Unbalanced block parentheses" mfix;
   255 
   256 
   257     val cons_fst = apfst o cons;
   258 
   259     fun add_args [] ty [] = ([], typ_to_nonterm1 ty)
   260       | add_args [] _ _ = err_in_mfix "Too many precedences" mfix
   261       | add_args ((arg as Argument ("index", _)) :: syms) ty ps =
   262           cons_fst arg (add_args syms ty ps)
   263       | add_args (Argument _ :: syms) (Type ("fun", [ty, tys])) [] =
   264           cons_fst (Argument (typ_to_nonterm ty, 0)) (add_args syms tys [])
   265       | add_args (Argument _ :: syms) (Type ("fun", [ty, tys])) (p :: ps) =
   266           cons_fst (Argument (typ_to_nonterm ty, p)) (add_args syms tys ps)
   267       | add_args (Argument _ :: _) _ _ =
   268           err_in_mfix "More arguments than in corresponding type" mfix
   269       | add_args (sym :: syms) ty ps = cons_fst sym (add_args syms ty ps);
   270 
   271     fun rem_pri (Argument (s, _)) = Argument (s, chain_pri)
   272       | rem_pri sym = sym;
   273 
   274     fun logify_types (a as (Argument (s, p))) =
   275           if s <> "prop" andalso is_logtype s then Argument (logic, p) else a
   276       | logify_types a = a;
   277 
   278 
   279     val raw_symbs = read_mfix sy handle ERROR msg => err_in_mfix msg mfix;
   280     val args = filter (fn Argument _ => true | _ => false) raw_symbs;
   281     val (const', typ', parse_rules) =
   282       if not (exists is_index args) then (const, typ, [])
   283       else
   284         let
   285           val indexed_const =
   286             if const <> "" then const ^ "_indexed"
   287             else err_in_mfix "Missing constant name for indexed syntax" mfix;
   288           val rangeT = Term.range_type typ handle Match =>
   289             err_in_mfix "Missing structure argument for indexed syntax" mfix;
   290 
   291           val xs = map Ast.Variable (Name.invent_list [] "xa" (length args - 1));
   292           val (xs1, xs2) = chop (find_index is_index args) xs;
   293           val i = Ast.Variable "i";
   294           val lhs = Ast.mk_appl (Ast.Constant indexed_const)
   295             (xs1 @ [Ast.mk_appl (Ast.Constant "_index") [i]] @ xs2);
   296           val rhs = Ast.mk_appl (Ast.Constant const) (i :: xs);
   297         in (indexed_const, rangeT, [(lhs, rhs)]) end;
   298 
   299     val (symbs, lhs) = add_args raw_symbs typ' pris;
   300 
   301     val copy_prod =
   302       (lhs = "prop" orelse lhs = "logic")
   303         andalso const <> ""
   304         andalso not (null symbs)
   305         andalso not (exists is_delim symbs);
   306     val lhs' =
   307       if convert andalso not copy_prod then
   308        (if lhs = "prop" then sprop else if is_logtype lhs then logic else lhs)
   309       else lhs;
   310     val symbs' = map logify_types symbs;
   311     val xprod = XProd (lhs', symbs', const', pri);
   312 
   313     val _ = (List.app check_pri pris; check_pri pri; check_blocks symbs');
   314     val xprod' =
   315       if Lexicon.is_terminal lhs' then err_in_mfix ("Illegal lhs: " ^ lhs') mfix
   316       else if const <> "" then xprod
   317       else if length (filter is_argument symbs') <> 1 then
   318         err_in_mfix "Copy production must have exactly one argument" mfix
   319       else if exists is_terminal symbs' then xprod
   320       else XProd (lhs', map rem_pri symbs', "", chain_pri);
   321 
   322   in (xprod', parse_rules) end;
   323 
   324 
   325 
   326 (** datatype syn_ext **)
   327 
   328 datatype syn_ext =
   329   Syn_Ext of {
   330     xprods: xprod list,
   331     consts: string list,
   332     prmodes: string list,
   333     parse_ast_translation: (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list,
   334     parse_rules: (Ast.ast * Ast.ast) list,
   335     parse_translation: (string * ((Proof.context -> term list -> term) * stamp)) list,
   336     print_translation:
   337       (string * ((Proof.context -> bool -> typ -> term list -> term) * stamp)) list,
   338     print_rules: (Ast.ast * Ast.ast) list,
   339     print_ast_translation: (string * ((Proof.context -> Ast.ast list -> Ast.ast) * stamp)) list,
   340     token_translation: (string * string * (Proof.context -> string -> Pretty.T)) list};
   341 
   342 
   343 (* syn_ext *)
   344 
   345 fun syn_ext' convert is_logtype mfixes consts trfuns tokentrfuns (parse_rules, print_rules) =
   346   let
   347     val (parse_ast_translation, parse_translation, print_translation,
   348       print_ast_translation) = trfuns;
   349 
   350     val (xprods, parse_rules') = map (mfix_to_xprod convert is_logtype) mfixes
   351       |> split_list |> apsnd (rev o flat);
   352     val mfix_consts =
   353       distinct (op =) (map (fn Mfix x => #3 x) mfixes @ map (fn XProd x => #3 x) xprods);
   354   in
   355     Syn_Ext {
   356       xprods = xprods,
   357       consts = union (op =) consts mfix_consts,
   358       prmodes = distinct (op =) (map (fn (m, _, _) => m) tokentrfuns),
   359       parse_ast_translation = parse_ast_translation,
   360       parse_rules = parse_rules' @ parse_rules,
   361       parse_translation = parse_translation,
   362       print_translation = print_translation,
   363       print_rules = map swap parse_rules' @ print_rules,
   364       print_ast_translation = print_ast_translation,
   365       token_translation = tokentrfuns}
   366   end;
   367 
   368 
   369 val syn_ext = syn_ext' true (K false);
   370 
   371 fun syn_ext_const_names cs = syn_ext [] cs ([], [], [], []) [] ([], []);
   372 fun syn_ext_rules rules = syn_ext [] [] ([], [], [], []) [] rules;
   373 fun syn_ext_advanced_trfuns trfuns = syn_ext [] [] trfuns [] ([], []);
   374 fun syn_ext_tokentrfuns trfuns = syn_ext [] [] ([], [], [], []) trfuns ([], []);
   375 
   376 fun syn_ext_trfuns (atrs, trs, tr's, atr's) =
   377   let fun simple (name, (f, s)) = (name, (K f, s)) in
   378     syn_ext_advanced_trfuns (map simple atrs, map simple trs, map simple tr's, map simple atr's)
   379   end;
   380 
   381 fun stamp_trfun s (c, f) = (c, (f, s));
   382 fun mk_trfun tr = stamp_trfun (stamp ()) tr;
   383 fun eq_trfun ((_, s1: stamp), (_, s2)) = s1 = s2;
   384 
   385 
   386 (* token translations *)
   387 
   388 fun tokentrans_mode m trs = map (fn (s, f) => (m, s, f)) trs;
   389 
   390 val standard_token_classes =
   391   ["tfree", "tvar", "free", "bound", "var", "numeral", "inner_string"];
   392 
   393 val standard_token_markers = map (fn s => "_" ^ s) standard_token_classes;
   394 
   395 
   396 (* pure_ext *)
   397 
   398 val pure_ext = syn_ext' false (K false)
   399   [Mfix ("_", spropT --> propT, "", [0], 0),
   400    Mfix ("_", logicT --> anyT, "", [0], 0),
   401    Mfix ("_", spropT --> anyT, "", [0], 0),
   402    Mfix ("'(_')", logicT --> logicT, "", [0], max_pri),
   403    Mfix ("'(_')", spropT --> spropT, "", [0], max_pri),
   404    Mfix ("_::_",  [logicT, typeT] ---> logicT, "_constrain", [4, 0], 3),
   405    Mfix ("_::_",  [spropT, typeT] ---> spropT, "_constrain", [4, 0], 3)]
   406   standard_token_markers
   407   ([], [], [], [])
   408   []
   409   ([], []);
   410 
   411 end;