src/Pure/proofterm.ML
author wenzelm
Wed Jun 02 11:09:26 2010 +0200 (2010-06-02 ago)
changeset 37251 72c7e636067b
parent 37236 739d8b9c59da
child 37297 a1acd424645a
permissions -rw-r--r--
normalize and postprocess proof body in a separate future, taking care of platforms without multithreading (greately improves parallelization in general without the overhead of promised proofs, cf. usedir -q 0);
     1 (*  Title:      Pure/proofterm.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 LF style proof terms.
     5 *)
     6 
     7 infix 8 % %% %>;
     8 
     9 signature BASIC_PROOFTERM =
    10 sig
    11   val proofs: int Unsynchronized.ref
    12 
    13   datatype proof =
    14      MinProof
    15    | PBound of int
    16    | Abst of string * typ option * proof
    17    | AbsP of string * term option * proof
    18    | op % of proof * term option
    19    | op %% of proof * proof
    20    | Hyp of term
    21    | PAxm of string * term * typ list option
    22    | OfClass of typ * class
    23    | Oracle of string * term * typ list option
    24    | Promise of serial * term * typ list
    25    | PThm of serial * ((string * term * typ list option) * proof_body future)
    26   and proof_body = PBody of
    27     {oracles: (string * term) OrdList.T,
    28      thms: (serial * (string * term * proof_body future)) OrdList.T,
    29      proof: proof}
    30 
    31   val %> : proof * term -> proof
    32 end;
    33 
    34 signature PROOFTERM =
    35 sig
    36   include BASIC_PROOFTERM
    37 
    38   type oracle = string * term
    39   type pthm = serial * (string * term * proof_body future)
    40   val proof_of: proof_body -> proof
    41   val join_proof: proof_body future -> proof
    42   val fold_proof_atoms: bool -> (proof -> 'a -> 'a) -> proof list -> 'a -> 'a
    43   val fold_body_thms: (string * term * proof_body -> 'a -> 'a) -> proof_body list -> 'a -> 'a
    44   val join_bodies: proof_body list -> unit
    45   val status_of: proof_body list -> {failed: bool, oracle: bool, unfinished: bool}
    46 
    47   val oracle_ord: oracle * oracle -> order
    48   val thm_ord: pthm * pthm -> order
    49   val merge_oracles: oracle OrdList.T -> oracle OrdList.T -> oracle OrdList.T
    50   val merge_thms: pthm OrdList.T -> pthm OrdList.T -> pthm OrdList.T
    51   val all_oracles_of: proof_body -> oracle OrdList.T
    52   val approximate_proof_body: proof -> proof_body
    53 
    54   (** primitive operations **)
    55   val proof_combt: proof * term list -> proof
    56   val proof_combt': proof * term option list -> proof
    57   val proof_combP: proof * proof list -> proof
    58   val strip_combt: proof -> proof * term option list
    59   val strip_combP: proof -> proof * proof list
    60   val strip_thm: proof_body -> proof_body
    61   val map_proof_same: term Same.operation -> typ Same.operation
    62     -> (typ * class -> proof) -> proof Same.operation
    63   val map_proof_terms_same: term Same.operation -> typ Same.operation -> proof Same.operation
    64   val map_proof_types_same: typ Same.operation -> proof Same.operation
    65   val map_proof_terms: (term -> term) -> (typ -> typ) -> proof -> proof
    66   val map_proof_types: (typ -> typ) -> proof -> proof
    67   val fold_proof_terms: (term -> 'a -> 'a) -> (typ -> 'a -> 'a) -> proof -> 'a -> 'a
    68   val maxidx_proof: proof -> int -> int
    69   val size_of_proof: proof -> int
    70   val change_type: typ list option -> proof -> proof
    71   val prf_abstract_over: term -> proof -> proof
    72   val prf_incr_bv: int -> int -> int -> int -> proof -> proof
    73   val incr_pboundvars: int -> int -> proof -> proof
    74   val prf_loose_bvar1: proof -> int -> bool
    75   val prf_loose_Pbvar1: proof -> int -> bool
    76   val prf_add_loose_bnos: int -> int -> proof -> int list * int list -> int list * int list
    77   val norm_proof: Envir.env -> proof -> proof
    78   val norm_proof': Envir.env -> proof -> proof
    79   val prf_subst_bounds: term list -> proof -> proof
    80   val prf_subst_pbounds: proof list -> proof -> proof
    81   val freeze_thaw_prf: proof -> proof * (proof -> proof)
    82 
    83   (** proof terms for specific inference rules **)
    84   val implies_intr_proof: term -> proof -> proof
    85   val implies_intr_proof': term -> proof -> proof
    86   val forall_intr_proof: term -> string -> proof -> proof
    87   val forall_intr_proof': term -> proof -> proof
    88   val varify_proof: term -> (string * sort) list -> proof -> proof
    89   val legacy_freezeT: term -> proof -> proof
    90   val rotate_proof: term list -> term -> int -> proof -> proof
    91   val permute_prems_proof: term list -> int -> int -> proof -> proof
    92   val generalize: string list * string list -> int -> proof -> proof
    93   val instantiate: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
    94     -> proof -> proof
    95   val lift_proof: term -> int -> term -> proof -> proof
    96   val incr_indexes: int -> proof -> proof
    97   val assumption_proof: term list -> term -> int -> proof -> proof
    98   val bicompose_proof: bool -> term list -> term list -> term list -> term option ->
    99     int -> int -> proof -> proof -> proof
   100   val equality_axms: (string * term) list
   101   val reflexive_axm: proof
   102   val symmetric_axm: proof
   103   val transitive_axm: proof
   104   val equal_intr_axm: proof
   105   val equal_elim_axm: proof
   106   val abstract_rule_axm: proof
   107   val combination_axm: proof
   108   val reflexive: proof
   109   val symmetric: proof -> proof
   110   val transitive: term -> typ -> proof -> proof -> proof
   111   val abstract_rule: term -> string -> proof -> proof
   112   val combination: term -> term -> term -> term -> typ -> proof -> proof -> proof
   113   val equal_intr: term -> term -> proof -> proof -> proof
   114   val equal_elim: term -> term -> proof -> proof -> proof
   115   val strip_shyps_proof: Sorts.algebra -> (typ * sort) list -> (typ * sort) list ->
   116     sort list -> proof -> proof
   117   val classrel_proof: theory -> class * class -> proof
   118   val arity_proof: theory -> string * sort list * class -> proof
   119   val of_sort_proof: theory -> (typ * class -> proof) -> typ * sort -> proof list
   120   val install_axclass_proofs:
   121    {classrel_proof: theory -> class * class -> proof,
   122     arity_proof: theory -> string * sort list * class -> proof} -> unit
   123   val axm_proof: string -> term -> proof
   124   val oracle_proof: string -> term -> oracle * proof
   125 
   126   (** rewriting on proof terms **)
   127   val add_prf_rrule: proof * proof -> theory -> theory
   128   val add_prf_rproc: (typ list -> term option list -> proof -> (proof * proof) option) -> theory -> theory
   129   val no_skel: proof
   130   val normal_skel: proof
   131   val rewrite_proof: theory -> (proof * proof) list *
   132     (typ list -> term option list -> proof -> (proof * proof) option) list -> proof -> proof
   133   val rewrite_proof_notypes: (proof * proof) list *
   134     (typ list -> term option list -> proof -> (proof * proof) option) list -> proof -> proof
   135   val rew_proof: theory -> proof -> proof
   136 
   137   val promise_proof: theory -> serial -> term -> proof
   138   val fulfill_norm_proof: theory -> (serial * proof_body) list -> proof_body -> proof_body
   139   val unconstrain_thm_proofs: bool Unsynchronized.ref
   140   val thm_proof: theory -> string -> sort list -> term list -> term ->
   141     (serial * proof_body future) list -> proof_body -> pthm * proof
   142   val unconstrain_thm_proof: theory -> sort list -> term ->
   143     (serial * proof_body future) list -> proof_body -> pthm * proof
   144   val get_name: term list -> term -> proof -> string
   145   val get_name_unconstrained: sort list -> term list -> term -> proof -> string
   146   val guess_name: proof -> string
   147 end
   148 
   149 structure Proofterm : PROOFTERM =
   150 struct
   151 
   152 (***** datatype proof *****)
   153 
   154 datatype proof =
   155    MinProof
   156  | PBound of int
   157  | Abst of string * typ option * proof
   158  | AbsP of string * term option * proof
   159  | op % of proof * term option
   160  | op %% of proof * proof
   161  | Hyp of term
   162  | PAxm of string * term * typ list option
   163  | OfClass of typ * class
   164  | Oracle of string * term * typ list option
   165  | Promise of serial * term * typ list
   166  | PThm of serial * ((string * term * typ list option) * proof_body future)
   167 and proof_body = PBody of
   168   {oracles: (string * term) OrdList.T,
   169    thms: (serial * (string * term * proof_body future)) OrdList.T,
   170    proof: proof};
   171 
   172 type oracle = string * term;
   173 type pthm = serial * (string * term * proof_body future);
   174 
   175 fun proof_of (PBody {proof, ...}) = proof;
   176 val join_proof = Future.join #> proof_of;
   177 
   178 
   179 (***** proof atoms *****)
   180 
   181 fun fold_proof_atoms all f =
   182   let
   183     fun app (Abst (_, _, prf)) = app prf
   184       | app (AbsP (_, _, prf)) = app prf
   185       | app (prf % _) = app prf
   186       | app (prf1 %% prf2) = app prf1 #> app prf2
   187       | app (prf as PThm (i, (_, body))) = (fn (x, seen) =>
   188           if Inttab.defined seen i then (x, seen)
   189           else
   190             let val (x', seen') =
   191               (if all then app (join_proof body) else I) (x, Inttab.update (i, ()) seen)
   192             in (f prf x', seen') end)
   193       | app prf = (fn (x, seen) => (f prf x, seen));
   194   in fn prfs => fn x => #1 (fold app prfs (x, Inttab.empty)) end;
   195 
   196 fun fold_body_thms f =
   197   let
   198     fun app (PBody {thms, ...}) =
   199      (Future.join_results (map (#3 o #2) thms);
   200       thms |> fold (fn (i, (name, prop, body)) => fn (x, seen) =>
   201         if Inttab.defined seen i then (x, seen)
   202         else
   203           let
   204             val body' = Future.join body;
   205             val (x', seen') = app body' (x, Inttab.update (i, ()) seen);
   206           in (f (name, prop, body') x', seen') end));
   207   in fn bodies => fn x => #1 (fold app bodies (x, Inttab.empty)) end;
   208 
   209 fun join_bodies bodies = fold_body_thms (fn _ => fn () => ()) bodies ();
   210 
   211 fun status_of bodies =
   212   let
   213     fun status (PBody {oracles, thms, ...}) x =
   214       let
   215         val ((oracle, unfinished, failed), seen) =
   216           (thms, x) |-> fold (fn (i, (_, _, body)) => fn (st, seen) =>
   217             if Inttab.defined seen i then (st, seen)
   218             else
   219               let val seen' = Inttab.update (i, ()) seen in
   220                 (case Future.peek body of
   221                   SOME (Exn.Result body') => status body' (st, seen')
   222                 | SOME (Exn.Exn _) =>
   223                     let val (oracle, unfinished, _) = st
   224                     in ((oracle, unfinished, true), seen') end
   225                 | NONE =>
   226                     let val (oracle, _, failed) = st
   227                     in ((oracle, true, failed), seen') end)
   228               end);
   229       in ((oracle orelse not (null oracles), unfinished, failed), seen) end;
   230     val (oracle, unfinished, failed) =
   231       #1 (fold status bodies ((false, false, false), Inttab.empty));
   232   in {oracle = oracle, unfinished = unfinished, failed = failed} end;
   233 
   234 
   235 (* proof body *)
   236 
   237 val oracle_ord = prod_ord fast_string_ord Term_Ord.fast_term_ord;
   238 fun thm_ord ((i, _): pthm, (j, _)) = int_ord (j, i);
   239 
   240 val merge_oracles = OrdList.union oracle_ord;
   241 val merge_thms = OrdList.union thm_ord;
   242 
   243 val all_oracles_of =
   244   let
   245     fun collect (PBody {oracles, thms, ...}) =
   246      (Future.join_results (map (#3 o #2) thms);
   247       thms |> fold (fn (i, (_, _, body)) => fn (x, seen) =>
   248         if Inttab.defined seen i then (x, seen)
   249         else
   250           let
   251             val body' = Future.join body;
   252             val (x', seen') = collect body' (x, Inttab.update (i, ()) seen);
   253           in (merge_oracles oracles x', seen') end));
   254   in fn body => #1 (collect body ([], Inttab.empty)) end;
   255 
   256 fun approximate_proof_body prf =
   257   let
   258     val (oracles, thms) = fold_proof_atoms false
   259       (fn Oracle (s, prop, _) => apfst (cons (s, prop))
   260         | PThm (i, ((name, prop, _), body)) => apsnd (cons (i, (name, prop, body)))
   261         | _ => I) [prf] ([], []);
   262   in
   263     PBody
   264      {oracles = OrdList.make oracle_ord oracles,
   265       thms = OrdList.make thm_ord thms,
   266       proof = prf}
   267   end;
   268 
   269 
   270 (***** proof objects with different levels of detail *****)
   271 
   272 fun (prf %> t) = prf % SOME t;
   273 
   274 val proof_combt = Library.foldl (op %>);
   275 val proof_combt' = Library.foldl (op %);
   276 val proof_combP = Library.foldl (op %%);
   277 
   278 fun strip_combt prf =
   279     let fun stripc (prf % t, ts) = stripc (prf, t::ts)
   280           | stripc  x =  x
   281     in  stripc (prf, [])  end;
   282 
   283 fun strip_combP prf =
   284     let fun stripc (prf %% prf', prfs) = stripc (prf, prf'::prfs)
   285           | stripc  x =  x
   286     in  stripc (prf, [])  end;
   287 
   288 fun strip_thm (body as PBody {proof, ...}) =
   289   (case strip_combt (fst (strip_combP proof)) of
   290     (PThm (_, (_, body')), _) => Future.join body'
   291   | _ => body);
   292 
   293 val mk_Abst = fold_rev (fn (s, T:typ) => fn prf => Abst (s, NONE, prf));
   294 fun mk_AbsP (i, prf) = funpow i (fn prf => AbsP ("H", NONE, prf)) prf;
   295 
   296 fun map_proof_same term typ ofclass =
   297   let
   298     val typs = Same.map typ;
   299 
   300     fun proof (Abst (s, T, prf)) =
   301           (Abst (s, Same.map_option typ T, Same.commit proof prf)
   302             handle Same.SAME => Abst (s, T, proof prf))
   303       | proof (AbsP (s, t, prf)) =
   304           (AbsP (s, Same.map_option term t, Same.commit proof prf)
   305             handle Same.SAME => AbsP (s, t, proof prf))
   306       | proof (prf % t) =
   307           (proof prf % Same.commit (Same.map_option term) t
   308             handle Same.SAME => prf % Same.map_option term t)
   309       | proof (prf1 %% prf2) =
   310           (proof prf1 %% Same.commit proof prf2
   311             handle Same.SAME => prf1 %% proof prf2)
   312       | proof (PAxm (a, prop, SOME Ts)) = PAxm (a, prop, SOME (typs Ts))
   313       | proof (OfClass T_c) = ofclass T_c
   314       | proof (Oracle (a, prop, SOME Ts)) = Oracle (a, prop, SOME (typs Ts))
   315       | proof (Promise (i, prop, Ts)) = Promise (i, prop, typs Ts)
   316       | proof (PThm (i, ((a, prop, SOME Ts), body))) =
   317           PThm (i, ((a, prop, SOME (typs Ts)), body))
   318       | proof _ = raise Same.SAME;
   319   in proof end;
   320 
   321 fun map_proof_terms_same term typ = map_proof_same term typ (fn (T, c) => OfClass (typ T, c));
   322 fun map_proof_types_same typ = map_proof_terms_same (Term_Subst.map_types_same typ) typ;
   323 
   324 fun same eq f x =
   325   let val x' = f x
   326   in if eq (x, x') then raise Same.SAME else x' end;
   327 
   328 fun map_proof_terms f g = Same.commit (map_proof_terms_same (same (op =) f) (same (op =) g));
   329 fun map_proof_types f = Same.commit (map_proof_types_same (same (op =) f));
   330 
   331 fun fold_proof_terms f g (Abst (_, SOME T, prf)) = g T #> fold_proof_terms f g prf
   332   | fold_proof_terms f g (Abst (_, NONE, prf)) = fold_proof_terms f g prf
   333   | fold_proof_terms f g (AbsP (_, SOME t, prf)) = f t #> fold_proof_terms f g prf
   334   | fold_proof_terms f g (AbsP (_, NONE, prf)) = fold_proof_terms f g prf
   335   | fold_proof_terms f g (prf % SOME t) = fold_proof_terms f g prf #> f t
   336   | fold_proof_terms f g (prf % NONE) = fold_proof_terms f g prf
   337   | fold_proof_terms f g (prf1 %% prf2) =
   338       fold_proof_terms f g prf1 #> fold_proof_terms f g prf2
   339   | fold_proof_terms _ g (PAxm (_, _, SOME Ts)) = fold g Ts
   340   | fold_proof_terms _ g (OfClass (T, _)) = g T
   341   | fold_proof_terms _ g (Oracle (_, _, SOME Ts)) = fold g Ts
   342   | fold_proof_terms _ g (Promise (_, _, Ts)) = fold g Ts
   343   | fold_proof_terms _ g (PThm (_, ((_, _, SOME Ts), _))) = fold g Ts
   344   | fold_proof_terms _ _ _ = I;
   345 
   346 fun maxidx_proof prf = fold_proof_terms Term.maxidx_term Term.maxidx_typ prf;
   347 
   348 fun size_of_proof (Abst (_, _, prf)) = 1 + size_of_proof prf
   349   | size_of_proof (AbsP (_, t, prf)) = 1 + size_of_proof prf
   350   | size_of_proof (prf % _) = 1 + size_of_proof prf
   351   | size_of_proof (prf1 %% prf2) = size_of_proof prf1 + size_of_proof prf2
   352   | size_of_proof _ = 1;
   353 
   354 fun change_type opTs (PAxm (name, prop, _)) = PAxm (name, prop, opTs)
   355   | change_type (SOME [T]) (OfClass (_, c)) = OfClass (T, c)
   356   | change_type opTs (Oracle (name, prop, _)) = Oracle (name, prop, opTs)
   357   | change_type opTs (Promise _) = raise Fail "change_type: unexpected promise"
   358   | change_type opTs (PThm (i, ((name, prop, _), body))) =
   359       PThm (i, ((name, prop, opTs), body))
   360   | change_type _ prf = prf;
   361 
   362 
   363 (***** utilities *****)
   364 
   365 fun strip_abs (_::Ts) (Abs (_, _, t)) = strip_abs Ts t
   366   | strip_abs _ t = t;
   367 
   368 fun mk_abs Ts t = Library.foldl (fn (t', T) => Abs ("", T, t')) (t, Ts);
   369 
   370 
   371 (*Abstraction of a proof term over its occurrences of v,
   372     which must contain no loose bound variables.
   373   The resulting proof term is ready to become the body of an Abst.*)
   374 
   375 fun prf_abstract_over v =
   376   let
   377     fun abst' lev u = if v aconv u then Bound lev else
   378       (case u of
   379          Abs (a, T, t) => Abs (a, T, abst' (lev + 1) t)
   380        | f $ t => (abst' lev f $ absth' lev t handle Same.SAME => f $ abst' lev t)
   381        | _ => raise Same.SAME)
   382     and absth' lev t = (abst' lev t handle Same.SAME => t);
   383 
   384     fun abst lev (AbsP (a, t, prf)) =
   385           (AbsP (a, Same.map_option (abst' lev) t, absth lev prf)
   386            handle Same.SAME => AbsP (a, t, abst lev prf))
   387       | abst lev (Abst (a, T, prf)) = Abst (a, T, abst (lev + 1) prf)
   388       | abst lev (prf1 %% prf2) = (abst lev prf1 %% absth lev prf2
   389           handle Same.SAME => prf1 %% abst lev prf2)
   390       | abst lev (prf % t) = (abst lev prf % Option.map (absth' lev) t
   391           handle Same.SAME => prf % Same.map_option (abst' lev) t)
   392       | abst _ _ = raise Same.SAME
   393     and absth lev prf = (abst lev prf handle Same.SAME => prf);
   394 
   395   in absth 0 end;
   396 
   397 
   398 (*increments a proof term's non-local bound variables
   399   required when moving a proof term within abstractions
   400      inc is  increment for bound variables
   401      lev is  level at which a bound variable is considered 'loose'*)
   402 
   403 fun incr_bv' inct tlev t = incr_bv (inct, tlev, t);
   404 
   405 fun prf_incr_bv' incP inct Plev tlev (PBound i) =
   406       if i >= Plev then PBound (i+incP) else raise Same.SAME
   407   | prf_incr_bv' incP inct Plev tlev (AbsP (a, t, body)) =
   408       (AbsP (a, Same.map_option (same (op =) (incr_bv' inct tlev)) t,
   409          prf_incr_bv incP inct (Plev+1) tlev body) handle Same.SAME =>
   410            AbsP (a, t, prf_incr_bv' incP inct (Plev+1) tlev body))
   411   | prf_incr_bv' incP inct Plev tlev (Abst (a, T, body)) =
   412       Abst (a, T, prf_incr_bv' incP inct Plev (tlev+1) body)
   413   | prf_incr_bv' incP inct Plev tlev (prf %% prf') =
   414       (prf_incr_bv' incP inct Plev tlev prf %% prf_incr_bv incP inct Plev tlev prf'
   415        handle Same.SAME => prf %% prf_incr_bv' incP inct Plev tlev prf')
   416   | prf_incr_bv' incP inct Plev tlev (prf % t) =
   417       (prf_incr_bv' incP inct Plev tlev prf % Option.map (incr_bv' inct tlev) t
   418        handle Same.SAME => prf % Same.map_option (same (op =) (incr_bv' inct tlev)) t)
   419   | prf_incr_bv' _ _ _ _ _ = raise Same.SAME
   420 and prf_incr_bv incP inct Plev tlev prf =
   421       (prf_incr_bv' incP inct Plev tlev prf handle Same.SAME => prf);
   422 
   423 fun incr_pboundvars  0 0 prf = prf
   424   | incr_pboundvars incP inct prf = prf_incr_bv incP inct 0 0 prf;
   425 
   426 
   427 fun prf_loose_bvar1 (prf1 %% prf2) k = prf_loose_bvar1 prf1 k orelse prf_loose_bvar1 prf2 k
   428   | prf_loose_bvar1 (prf % SOME t) k = prf_loose_bvar1 prf k orelse loose_bvar1 (t, k)
   429   | prf_loose_bvar1 (_ % NONE) _ = true
   430   | prf_loose_bvar1 (AbsP (_, SOME t, prf)) k = loose_bvar1 (t, k) orelse prf_loose_bvar1 prf k
   431   | prf_loose_bvar1 (AbsP (_, NONE, _)) k = true
   432   | prf_loose_bvar1 (Abst (_, _, prf)) k = prf_loose_bvar1 prf (k+1)
   433   | prf_loose_bvar1 _ _ = false;
   434 
   435 fun prf_loose_Pbvar1 (PBound i) k = i = k
   436   | prf_loose_Pbvar1 (prf1 %% prf2) k = prf_loose_Pbvar1 prf1 k orelse prf_loose_Pbvar1 prf2 k
   437   | prf_loose_Pbvar1 (prf % _) k = prf_loose_Pbvar1 prf k
   438   | prf_loose_Pbvar1 (AbsP (_, _, prf)) k = prf_loose_Pbvar1 prf (k+1)
   439   | prf_loose_Pbvar1 (Abst (_, _, prf)) k = prf_loose_Pbvar1 prf k
   440   | prf_loose_Pbvar1 _ _ = false;
   441 
   442 fun prf_add_loose_bnos plev tlev (PBound i) (is, js) =
   443       if i < plev then (is, js) else (insert (op =) (i-plev) is, js)
   444   | prf_add_loose_bnos plev tlev (prf1 %% prf2) p =
   445       prf_add_loose_bnos plev tlev prf2
   446         (prf_add_loose_bnos plev tlev prf1 p)
   447   | prf_add_loose_bnos plev tlev (prf % opt) (is, js) =
   448       prf_add_loose_bnos plev tlev prf (case opt of
   449           NONE => (is, insert (op =) ~1 js)
   450         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   451   | prf_add_loose_bnos plev tlev (AbsP (_, opt, prf)) (is, js) =
   452       prf_add_loose_bnos (plev+1) tlev prf (case opt of
   453           NONE => (is, insert (op =) ~1 js)
   454         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   455   | prf_add_loose_bnos plev tlev (Abst (_, _, prf)) p =
   456       prf_add_loose_bnos plev (tlev+1) prf p
   457   | prf_add_loose_bnos _ _ _ _ = ([], []);
   458 
   459 
   460 (**** substitutions ****)
   461 
   462 fun del_conflicting_tvars envT T = Term_Subst.instantiateT
   463   (map_filter (fn ixnS as (_, S) =>
   464      (Type.lookup envT ixnS; NONE) handle TYPE _ =>
   465         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.typ_tvars T)) T;
   466 
   467 fun del_conflicting_vars env t = Term_Subst.instantiate
   468   (map_filter (fn ixnS as (_, S) =>
   469      (Type.lookup (Envir.type_env env) ixnS; NONE) handle TYPE _ =>
   470         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.term_tvars t),
   471    map_filter (fn Var (ixnT as (_, T)) =>
   472      (Envir.lookup (env, ixnT); NONE) handle TYPE _ =>
   473         SOME (ixnT, Free ("dummy", T))) (OldTerm.term_vars t)) t;
   474 
   475 fun norm_proof env =
   476   let
   477     val envT = Envir.type_env env;
   478     fun msg s = warning ("type conflict in norm_proof:\n" ^ s);
   479     fun htype f t = f env t handle TYPE (s, _, _) =>
   480       (msg s; f env (del_conflicting_vars env t));
   481     fun htypeT f T = f envT T handle TYPE (s, _, _) =>
   482       (msg s; f envT (del_conflicting_tvars envT T));
   483     fun htypeTs f Ts = f envT Ts handle TYPE (s, _, _) =>
   484       (msg s; f envT (map (del_conflicting_tvars envT) Ts));
   485 
   486     fun norm (Abst (s, T, prf)) =
   487           (Abst (s, Same.map_option (htypeT Envir.norm_type_same) T, Same.commit norm prf)
   488             handle Same.SAME => Abst (s, T, norm prf))
   489       | norm (AbsP (s, t, prf)) =
   490           (AbsP (s, Same.map_option (htype Envir.norm_term_same) t, Same.commit norm prf)
   491             handle Same.SAME => AbsP (s, t, norm prf))
   492       | norm (prf % t) =
   493           (norm prf % Option.map (htype Envir.norm_term) t
   494             handle Same.SAME => prf % Same.map_option (htype Envir.norm_term_same) t)
   495       | norm (prf1 %% prf2) =
   496           (norm prf1 %% Same.commit norm prf2
   497             handle Same.SAME => prf1 %% norm prf2)
   498       | norm (PAxm (s, prop, Ts)) =
   499           PAxm (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   500       | norm (OfClass (T, c)) =
   501           OfClass (htypeT Envir.norm_type_same T, c)
   502       | norm (Oracle (s, prop, Ts)) =
   503           Oracle (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   504       | norm (Promise (i, prop, Ts)) =
   505           Promise (i, prop, htypeTs Envir.norm_types_same Ts)
   506       | norm (PThm (i, ((s, t, Ts), body))) =
   507           PThm (i, ((s, t, Same.map_option (htypeTs Envir.norm_types_same) Ts), body))
   508       | norm _ = raise Same.SAME;
   509   in Same.commit norm end;
   510 
   511 
   512 (***** Remove some types in proof term (to save space) *****)
   513 
   514 fun remove_types (Abs (s, _, t)) = Abs (s, dummyT, remove_types t)
   515   | remove_types (t $ u) = remove_types t $ remove_types u
   516   | remove_types (Const (s, _)) = Const (s, dummyT)
   517   | remove_types t = t;
   518 
   519 fun remove_types_env (Envir.Envir {maxidx, tenv, tyenv}) =
   520   Envir.Envir {maxidx = maxidx, tenv = Vartab.map (apsnd remove_types) tenv, tyenv = tyenv};
   521 
   522 fun norm_proof' env prf = norm_proof (remove_types_env env) prf;
   523 
   524 
   525 (**** substitution of bound variables ****)
   526 
   527 fun prf_subst_bounds args prf =
   528   let
   529     val n = length args;
   530     fun subst' lev (Bound i) =
   531          (if i<lev then raise Same.SAME    (*var is locally bound*)
   532           else  incr_boundvars lev (nth args (i-lev))
   533                   handle Subscript => Bound (i-n))  (*loose: change it*)
   534       | subst' lev (Abs (a, T, body)) = Abs (a, T,  subst' (lev+1) body)
   535       | subst' lev (f $ t) = (subst' lev f $ substh' lev t
   536           handle Same.SAME => f $ subst' lev t)
   537       | subst' _ _ = raise Same.SAME
   538     and substh' lev t = (subst' lev t handle Same.SAME => t);
   539 
   540     fun subst lev (AbsP (a, t, body)) =
   541         (AbsP (a, Same.map_option (subst' lev) t, substh lev body)
   542           handle Same.SAME => AbsP (a, t, subst lev body))
   543       | subst lev (Abst (a, T, body)) = Abst (a, T, subst (lev+1) body)
   544       | subst lev (prf %% prf') = (subst lev prf %% substh lev prf'
   545           handle Same.SAME => prf %% subst lev prf')
   546       | subst lev (prf % t) = (subst lev prf % Option.map (substh' lev) t
   547           handle Same.SAME => prf % Same.map_option (subst' lev) t)
   548       | subst _ _ = raise Same.SAME
   549     and substh lev prf = (subst lev prf handle Same.SAME => prf);
   550   in case args of [] => prf | _ => substh 0 prf end;
   551 
   552 fun prf_subst_pbounds args prf =
   553   let
   554     val n = length args;
   555     fun subst (PBound i) Plev tlev =
   556          (if i < Plev then raise Same.SAME    (*var is locally bound*)
   557           else incr_pboundvars Plev tlev (nth args (i-Plev))
   558                  handle Subscript => PBound (i-n)  (*loose: change it*))
   559       | subst (AbsP (a, t, body)) Plev tlev = AbsP (a, t, subst body (Plev+1) tlev)
   560       | subst (Abst (a, T, body)) Plev tlev = Abst (a, T, subst body Plev (tlev+1))
   561       | subst (prf %% prf') Plev tlev = (subst prf Plev tlev %% substh prf' Plev tlev
   562           handle Same.SAME => prf %% subst prf' Plev tlev)
   563       | subst (prf % t) Plev tlev = subst prf Plev tlev % t
   564       | subst  prf _ _ = raise Same.SAME
   565     and substh prf Plev tlev = (subst prf Plev tlev handle Same.SAME => prf)
   566   in case args of [] => prf | _ => substh prf 0 0 end;
   567 
   568 
   569 (**** Freezing and thawing of variables in proof terms ****)
   570 
   571 fun frzT names =
   572   map_type_tvar (fn (ixn, xs) => TFree ((the o AList.lookup (op =) names) ixn, xs));
   573 
   574 fun thawT names =
   575   map_type_tfree (fn (s, xs) => case AList.lookup (op =) names s of
   576       NONE => TFree (s, xs)
   577     | SOME ixn => TVar (ixn, xs));
   578 
   579 fun freeze names names' (t $ u) =
   580       freeze names names' t $ freeze names names' u
   581   | freeze names names' (Abs (s, T, t)) =
   582       Abs (s, frzT names' T, freeze names names' t)
   583   | freeze names names' (Const (s, T)) = Const (s, frzT names' T)
   584   | freeze names names' (Free (s, T)) = Free (s, frzT names' T)
   585   | freeze names names' (Var (ixn, T)) =
   586       Free ((the o AList.lookup (op =) names) ixn, frzT names' T)
   587   | freeze names names' t = t;
   588 
   589 fun thaw names names' (t $ u) =
   590       thaw names names' t $ thaw names names' u
   591   | thaw names names' (Abs (s, T, t)) =
   592       Abs (s, thawT names' T, thaw names names' t)
   593   | thaw names names' (Const (s, T)) = Const (s, thawT names' T)
   594   | thaw names names' (Free (s, T)) =
   595       let val T' = thawT names' T
   596       in case AList.lookup (op =) names s of
   597           NONE => Free (s, T')
   598         | SOME ixn => Var (ixn, T')
   599       end
   600   | thaw names names' (Var (ixn, T)) = Var (ixn, thawT names' T)
   601   | thaw names names' t = t;
   602 
   603 fun freeze_thaw_prf prf =
   604   let
   605     val (fs, Tfs, vs, Tvs) = fold_proof_terms
   606       (fn t => fn (fs, Tfs, vs, Tvs) =>
   607          (Term.add_free_names t fs, Term.add_tfree_names t Tfs,
   608           Term.add_var_names t vs, Term.add_tvar_names t Tvs))
   609       (fn T => fn (fs, Tfs, vs, Tvs) =>
   610          (fs, Term.add_tfree_namesT T Tfs,
   611           vs, Term.add_tvar_namesT T Tvs))
   612       prf ([], [], [], []);
   613     val names = vs ~~ Name.variant_list fs (map fst vs);
   614     val names' = Tvs ~~ Name.variant_list Tfs (map fst Tvs);
   615     val rnames = map swap names;
   616     val rnames' = map swap names';
   617   in
   618     (map_proof_terms (freeze names names') (frzT names') prf,
   619      map_proof_terms (thaw rnames rnames') (thawT rnames'))
   620   end;
   621 
   622 
   623 (***** implication introduction *****)
   624 
   625 fun gen_implies_intr_proof f h prf =
   626   let
   627     fun abshyp i (Hyp t) = if h aconv t then PBound i else raise Same.SAME
   628       | abshyp i (Abst (s, T, prf)) = Abst (s, T, abshyp i prf)
   629       | abshyp i (AbsP (s, t, prf)) = AbsP (s, t, abshyp (i + 1) prf)
   630       | abshyp i (prf % t) = abshyp i prf % t
   631       | abshyp i (prf1 %% prf2) =
   632           (abshyp i prf1 %% abshyph i prf2
   633             handle Same.SAME => prf1 %% abshyp i prf2)
   634       | abshyp _ _ = raise Same.SAME
   635     and abshyph i prf = (abshyp i prf handle Same.SAME => prf);
   636   in
   637     AbsP ("H", f h, abshyph 0 prf)
   638   end;
   639 
   640 val implies_intr_proof = gen_implies_intr_proof (K NONE);
   641 val implies_intr_proof' = gen_implies_intr_proof SOME;
   642 
   643 
   644 (***** forall introduction *****)
   645 
   646 fun forall_intr_proof x a prf = Abst (a, NONE, prf_abstract_over x prf);
   647 
   648 fun forall_intr_proof' t prf =
   649   let val (a, T) = (case t of Var ((a, _), T) => (a, T) | Free p => p)
   650   in Abst (a, SOME T, prf_abstract_over t prf) end;
   651 
   652 
   653 (***** varify *****)
   654 
   655 fun varify_proof t fixed prf =
   656   let
   657     val fs = Term.fold_types (Term.fold_atyps
   658       (fn TFree v => if member (op =) fixed v then I else insert (op =) v | _ => I)) t [];
   659     val used = Name.context
   660       |> fold_types (fold_atyps (fn TVar ((a, _), _) => Name.declare a | _ => I)) t;
   661     val fmap = fs ~~ #1 (Name.variants (map fst fs) used);
   662     fun thaw (f as (a, S)) =
   663       (case AList.lookup (op =) fmap f of
   664         NONE => TFree f
   665       | SOME b => TVar ((b, 0), S));
   666   in map_proof_terms (map_types (map_type_tfree thaw)) (map_type_tfree thaw) prf end;
   667 
   668 
   669 local
   670 
   671 fun new_name (ix, (pairs,used)) =
   672   let val v = Name.variant used (string_of_indexname ix)
   673   in  ((ix, v) :: pairs, v :: used)  end;
   674 
   675 fun freeze_one alist (ix, sort) = (case AList.lookup (op =) alist ix of
   676     NONE => TVar (ix, sort)
   677   | SOME name => TFree (name, sort));
   678 
   679 in
   680 
   681 fun legacy_freezeT t prf =
   682   let
   683     val used = OldTerm.it_term_types OldTerm.add_typ_tfree_names (t, [])
   684     and tvars = map #1 (OldTerm.it_term_types OldTerm.add_typ_tvars (t, []));
   685     val (alist, _) = List.foldr new_name ([], used) tvars;
   686   in
   687     (case alist of
   688       [] => prf (*nothing to do!*)
   689     | _ =>
   690       let val frzT = map_type_tvar (freeze_one alist)
   691       in map_proof_terms (map_types frzT) frzT prf end)
   692   end;
   693 
   694 end;
   695 
   696 
   697 (***** rotate assumptions *****)
   698 
   699 fun rotate_proof Bs Bi m prf =
   700   let
   701     val params = Term.strip_all_vars Bi;
   702     val asms = Logic.strip_imp_prems (Term.strip_all_body Bi);
   703     val i = length asms;
   704     val j = length Bs;
   705   in
   706     mk_AbsP (j+1, proof_combP (prf, map PBound
   707       (j downto 1) @ [mk_Abst params (mk_AbsP (i,
   708         proof_combP (proof_combt (PBound i, map Bound ((length params - 1) downto 0)),
   709           map PBound (((i-m-1) downto 0) @ ((i-1) downto (i-m))))))]))
   710   end;
   711 
   712 
   713 (***** permute premises *****)
   714 
   715 fun permute_prems_proof prems j k prf =
   716   let val n = length prems
   717   in mk_AbsP (n, proof_combP (prf,
   718     map PBound ((n-1 downto n-j) @ (k-1 downto 0) @ (n-j-1 downto k))))
   719   end;
   720 
   721 
   722 (***** generalization *****)
   723 
   724 fun generalize (tfrees, frees) idx =
   725   Same.commit (map_proof_terms_same
   726     (Term_Subst.generalize_same (tfrees, frees) idx)
   727     (Term_Subst.generalizeT_same tfrees idx));
   728 
   729 
   730 (***** instantiation *****)
   731 
   732 fun instantiate (instT, inst) =
   733   Same.commit (map_proof_terms_same
   734     (Term_Subst.instantiate_same (instT, map (apsnd remove_types) inst))
   735     (Term_Subst.instantiateT_same instT));
   736 
   737 
   738 (***** lifting *****)
   739 
   740 fun lift_proof Bi inc prop prf =
   741   let
   742     fun lift'' Us Ts t =
   743       strip_abs Ts (Logic.incr_indexes (Us, inc) (mk_abs Ts t));
   744 
   745     fun lift' Us Ts (Abst (s, T, prf)) =
   746           (Abst (s, Same.map_option (Logic.incr_tvar_same inc) T, lifth' Us (dummyT::Ts) prf)
   747            handle Same.SAME => Abst (s, T, lift' Us (dummyT::Ts) prf))
   748       | lift' Us Ts (AbsP (s, t, prf)) =
   749           (AbsP (s, Same.map_option (same (op =) (lift'' Us Ts)) t, lifth' Us Ts prf)
   750            handle Same.SAME => AbsP (s, t, lift' Us Ts prf))
   751       | lift' Us Ts (prf % t) = (lift' Us Ts prf % Option.map (lift'' Us Ts) t
   752           handle Same.SAME => prf % Same.map_option (same (op =) (lift'' Us Ts)) t)
   753       | lift' Us Ts (prf1 %% prf2) = (lift' Us Ts prf1 %% lifth' Us Ts prf2
   754           handle Same.SAME => prf1 %% lift' Us Ts prf2)
   755       | lift' _ _ (PAxm (s, prop, Ts)) =
   756           PAxm (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   757       | lift' _ _ (OfClass (T, c)) =
   758           OfClass (Logic.incr_tvar_same inc T, c)
   759       | lift' _ _ (Oracle (s, prop, Ts)) =
   760           Oracle (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   761       | lift' _ _ (Promise (i, prop, Ts)) =
   762           Promise (i, prop, Same.map (Logic.incr_tvar_same inc) Ts)
   763       | lift' _ _ (PThm (i, ((s, prop, Ts), body))) =
   764           PThm (i, ((s, prop, (Same.map_option o Same.map) (Logic.incr_tvar inc) Ts), body))
   765       | lift' _ _ _ = raise Same.SAME
   766     and lifth' Us Ts prf = (lift' Us Ts prf handle Same.SAME => prf);
   767 
   768     val ps = map (Logic.lift_all inc Bi) (Logic.strip_imp_prems prop);
   769     val k = length ps;
   770 
   771     fun mk_app b (i, j, prf) =
   772           if b then (i-1, j, prf %% PBound i) else (i, j-1, prf %> Bound j);
   773 
   774     fun lift Us bs i j (Const ("==>", _) $ A $ B) =
   775             AbsP ("H", NONE (*A*), lift Us (true::bs) (i+1) j B)
   776       | lift Us bs i j (Const ("all", _) $ Abs (a, T, t)) =
   777             Abst (a, NONE (*T*), lift (T::Us) (false::bs) i (j+1) t)
   778       | lift Us bs i j _ = proof_combP (lifth' (rev Us) [] prf,
   779             map (fn k => (#3 (fold_rev mk_app bs (i-1, j-1, PBound k))))
   780               (i + k - 1 downto i));
   781   in
   782     mk_AbsP (k, lift [] [] 0 0 Bi)
   783   end;
   784 
   785 fun incr_indexes i =
   786   Same.commit (map_proof_terms_same
   787     (Logic.incr_indexes_same ([], i)) (Logic.incr_tvar_same i));
   788 
   789 
   790 (***** proof by assumption *****)
   791 
   792 fun mk_asm_prf t i m =
   793   let
   794     fun imp_prf _ i 0 = PBound i
   795       | imp_prf (Const ("==>", _) $ A $ B) i m = AbsP ("H", NONE (*A*), imp_prf B (i+1) (m-1))
   796       | imp_prf _ i _ = PBound i;
   797     fun all_prf (Const ("all", _) $ Abs (a, T, t)) = Abst (a, NONE (*T*), all_prf t)
   798       | all_prf t = imp_prf t (~i) m
   799   in all_prf t end;
   800 
   801 fun assumption_proof Bs Bi n prf =
   802   mk_AbsP (length Bs, proof_combP (prf,
   803     map PBound (length Bs - 1 downto 0) @ [mk_asm_prf Bi n ~1]));
   804 
   805 
   806 (***** Composition of object rule with proof state *****)
   807 
   808 fun flatten_params_proof i j n (Const ("==>", _) $ A $ B, k) =
   809       AbsP ("H", NONE (*A*), flatten_params_proof (i+1) j n (B, k))
   810   | flatten_params_proof i j n (Const ("all", _) $ Abs (a, T, t), k) =
   811       Abst (a, NONE (*T*), flatten_params_proof i (j+1) n (t, k))
   812   | flatten_params_proof i j n (_, k) = proof_combP (proof_combt (PBound (k+i),
   813       map Bound (j-1 downto 0)), map PBound (remove (op =) (i-n) (i-1 downto 0)));
   814 
   815 fun bicompose_proof flatten Bs oldAs newAs A n m rprf sprf =
   816   let
   817     val la = length newAs;
   818     val lb = length Bs;
   819   in
   820     mk_AbsP (lb+la, proof_combP (sprf,
   821       map PBound (lb + la - 1 downto la)) %%
   822         proof_combP (rprf, (if n>0 then [mk_asm_prf (the A) n m] else []) @
   823           map (if flatten then flatten_params_proof 0 0 n else PBound o snd)
   824             (oldAs ~~ (la - 1 downto 0))))
   825   end;
   826 
   827 
   828 (***** axioms for equality *****)
   829 
   830 val aT = TFree ("'a", []);
   831 val bT = TFree ("'b", []);
   832 val x = Free ("x", aT);
   833 val y = Free ("y", aT);
   834 val z = Free ("z", aT);
   835 val A = Free ("A", propT);
   836 val B = Free ("B", propT);
   837 val f = Free ("f", aT --> bT);
   838 val g = Free ("g", aT --> bT);
   839 
   840 val equality_axms =
   841  [("reflexive", Logic.mk_equals (x, x)),
   842   ("symmetric", Logic.mk_implies (Logic.mk_equals (x, y), Logic.mk_equals (y, x))),
   843   ("transitive",
   844     Logic.list_implies ([Logic.mk_equals (x, y), Logic.mk_equals (y, z)], Logic.mk_equals (x, z))),
   845   ("equal_intr",
   846     Logic.list_implies ([Logic.mk_implies (A, B), Logic.mk_implies (B, A)], Logic.mk_equals (A, B))),
   847   ("equal_elim", Logic.list_implies ([Logic.mk_equals (A, B), A], B)),
   848   ("abstract_rule",
   849     Logic.mk_implies
   850       (Logic.all x
   851         (Logic.mk_equals (f $ x, g $ x)), Logic.mk_equals (lambda x (f $ x), lambda x (g $ x)))),
   852   ("combination", Logic.list_implies
   853     ([Logic.mk_equals (f, g), Logic.mk_equals (x, y)], Logic.mk_equals (f $ x, g $ y)))];
   854 
   855 val [reflexive_axm, symmetric_axm, transitive_axm, equal_intr_axm,
   856   equal_elim_axm, abstract_rule_axm, combination_axm] =
   857     map (fn (s, t) => PAxm ("Pure." ^ s, Logic.varify_global t, NONE)) equality_axms;
   858 
   859 val reflexive = reflexive_axm % NONE;
   860 
   861 fun symmetric (prf as PAxm ("Pure.reflexive", _, _) % _) = prf
   862   | symmetric prf = symmetric_axm % NONE % NONE %% prf;
   863 
   864 fun transitive _ _ (PAxm ("Pure.reflexive", _, _) % _) prf2 = prf2
   865   | transitive _ _ prf1 (PAxm ("Pure.reflexive", _, _) % _) = prf1
   866   | transitive u (Type ("prop", [])) prf1 prf2 =
   867       transitive_axm % NONE % SOME (remove_types u) % NONE %% prf1 %% prf2
   868   | transitive u T prf1 prf2 =
   869       transitive_axm % NONE % NONE % NONE %% prf1 %% prf2;
   870 
   871 fun abstract_rule x a prf =
   872   abstract_rule_axm % NONE % NONE %% forall_intr_proof x a prf;
   873 
   874 fun check_comb (PAxm ("Pure.combination", _, _) % f % g % _ % _ %% prf %% _) =
   875       is_some f orelse check_comb prf
   876   | check_comb (PAxm ("Pure.transitive", _, _) % _ % _ % _ %% prf1 %% prf2) =
   877       check_comb prf1 andalso check_comb prf2
   878   | check_comb (PAxm ("Pure.symmetric", _, _) % _ % _ %% prf) = check_comb prf
   879   | check_comb _ = false;
   880 
   881 fun combination f g t u (Type (_, [T, U])) prf1 prf2 =
   882   let
   883     val f = Envir.beta_norm f;
   884     val g = Envir.beta_norm g;
   885     val prf =  if check_comb prf1 then
   886         combination_axm % NONE % NONE
   887       else (case prf1 of
   888           PAxm ("Pure.reflexive", _, _) % _ =>
   889             combination_axm %> remove_types f % NONE
   890         | _ => combination_axm %> remove_types f %> remove_types g)
   891   in
   892     (case T of
   893        Type ("fun", _) => prf %
   894          (case head_of f of
   895             Abs _ => SOME (remove_types t)
   896           | Var _ => SOME (remove_types t)
   897           | _ => NONE) %
   898          (case head_of g of
   899             Abs _ => SOME (remove_types u)
   900           | Var _ => SOME (remove_types u)
   901           | _ => NONE) %% prf1 %% prf2
   902      | _ => prf % NONE % NONE %% prf1 %% prf2)
   903   end;
   904 
   905 fun equal_intr A B prf1 prf2 =
   906   equal_intr_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   907 
   908 fun equal_elim A B prf1 prf2 =
   909   equal_elim_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   910 
   911 
   912 (**** type classes ****)
   913 
   914 fun strip_shyps_proof algebra present witnessed extra_sorts prf =
   915   let
   916     fun get S2 (T, S1) = if Sorts.sort_le algebra (S1, S2) then SOME T else NONE;
   917     val extra = map (fn S => (TFree ("'dummy", S), S)) extra_sorts;
   918     val replacements = present @ extra @ witnessed;
   919     fun replace T =
   920       if exists (fn (T', _) => T' = T) present then raise Same.SAME
   921       else
   922         (case get_first (get (Type.sort_of_atyp T)) replacements of
   923           SOME T' => T'
   924         | NONE => raise Fail "strip_shyps_proof: bad type variable in proof term");
   925   in Same.commit (map_proof_types_same (Term_Subst.map_atypsT_same replace)) prf end;
   926 
   927 
   928 local
   929 
   930 type axclass_proofs =
   931  {classrel_proof: theory -> class * class -> proof,
   932   arity_proof: theory -> string * sort list * class -> proof};
   933 
   934 val axclass_proofs: axclass_proofs Single_Assignment.var =
   935   Single_Assignment.var "Proofterm.axclass_proofs";
   936 
   937 fun axclass_proof which thy x =
   938   (case Single_Assignment.peek axclass_proofs of
   939     NONE => raise Fail "Axclass proof operations not installed"
   940   | SOME prfs => which prfs thy x);
   941 
   942 in
   943 
   944 val classrel_proof = axclass_proof #classrel_proof;
   945 val arity_proof = axclass_proof #arity_proof;
   946 
   947 fun install_axclass_proofs prfs = Single_Assignment.assign axclass_proofs prfs;
   948 
   949 end;
   950 
   951 
   952 local
   953 
   954 fun canonical_instance typs =
   955   let
   956     val names = Name.invents Name.context Name.aT (length typs);
   957     val instT = map2 (fn a => fn T => (((a, 0), []), Type.strip_sorts T)) names typs;
   958   in instantiate (instT, []) end;
   959 
   960 in
   961 
   962 fun of_sort_proof thy hyps =
   963   Sorts.of_sort_derivation (Sign.classes_of thy)
   964    {class_relation = fn typ => fn (prf, c1) => fn c2 =>
   965       if c1 = c2 then prf
   966       else canonical_instance [typ] (classrel_proof thy (c1, c2)) %% prf,
   967     type_constructor = fn (a, typs) => fn dom => fn c =>
   968       let val Ss = map (map snd) dom and prfs = maps (map fst) dom
   969       in proof_combP (canonical_instance typs (arity_proof thy (a, Ss, c)), prfs) end,
   970     type_variable = fn typ => map (fn c => (hyps (typ, c), c)) (Type.sort_of_atyp typ)};
   971 
   972 end;
   973 
   974 
   975 (***** axioms and theorems *****)
   976 
   977 val proofs = Unsynchronized.ref 2;
   978 
   979 fun vars_of t = map Var (rev (Term.add_vars t []));
   980 fun frees_of t = map Free (rev (Term.add_frees t []));
   981 
   982 fun test_args _ [] = true
   983   | test_args is (Bound i :: ts) =
   984       not (member (op =) is i) andalso test_args (i :: is) ts
   985   | test_args _ _ = false;
   986 
   987 fun is_fun (Type ("fun", _)) = true
   988   | is_fun (TVar _) = true
   989   | is_fun _ = false;
   990 
   991 fun add_funvars Ts (vs, t) =
   992   if is_fun (fastype_of1 (Ts, t)) then
   993     union (op =) vs (map_filter (fn Var (ixn, T) =>
   994       if is_fun T then SOME ixn else NONE | _ => NONE) (vars_of t))
   995   else vs;
   996 
   997 fun add_npvars q p Ts (vs, Const ("==>", _) $ t $ u) =
   998       add_npvars q p Ts (add_npvars q (not p) Ts (vs, t), u)
   999   | add_npvars q p Ts (vs, Const ("all", Type (_, [Type (_, [T, _]), _])) $ t) =
  1000       add_npvars q p Ts (vs, if p andalso q then betapply (t, Var (("",0), T)) else t)
  1001   | add_npvars q p Ts (vs, Abs (_, T, t)) = add_npvars q p (T::Ts) (vs, t)
  1002   | add_npvars _ _ Ts (vs, t) = add_npvars' Ts (vs, t)
  1003 and add_npvars' Ts (vs, t) = (case strip_comb t of
  1004     (Var (ixn, _), ts) => if test_args [] ts then vs
  1005       else Library.foldl (add_npvars' Ts)
  1006         (AList.update (op =) (ixn,
  1007           Library.foldl (add_funvars Ts) ((these ooo AList.lookup) (op =) vs ixn, ts)) vs, ts)
  1008   | (Abs (_, T, u), ts) => Library.foldl (add_npvars' (T::Ts)) (vs, u :: ts)
  1009   | (_, ts) => Library.foldl (add_npvars' Ts) (vs, ts));
  1010 
  1011 fun prop_vars (Const ("==>", _) $ P $ Q) = union (op =) (prop_vars P) (prop_vars Q)
  1012   | prop_vars (Const ("all", _) $ Abs (_, _, t)) = prop_vars t
  1013   | prop_vars t = (case strip_comb t of
  1014       (Var (ixn, _), _) => [ixn] | _ => []);
  1015 
  1016 fun is_proj t =
  1017   let
  1018     fun is_p i t = (case strip_comb t of
  1019         (Bound j, []) => false
  1020       | (Bound j, ts) => j >= i orelse exists (is_p i) ts
  1021       | (Abs (_, _, u), _) => is_p (i+1) u
  1022       | (_, ts) => exists (is_p i) ts)
  1023   in (case strip_abs_body t of
  1024         Bound _ => true
  1025       | t' => is_p 0 t')
  1026   end;
  1027 
  1028 fun needed_vars prop =
  1029   union (op =) (Library.foldl (uncurry (union (op =)))
  1030     ([], map (uncurry (insert (op =))) (add_npvars true true [] ([], prop))))
  1031   (prop_vars prop);
  1032 
  1033 fun gen_axm_proof c name prop =
  1034   let
  1035     val nvs = needed_vars prop;
  1036     val args = map (fn (v as Var (ixn, _)) =>
  1037         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1038       map SOME (frees_of prop);
  1039   in
  1040     proof_combt' (c (name, prop, NONE), args)
  1041   end;
  1042 
  1043 val axm_proof = gen_axm_proof PAxm;
  1044 
  1045 val dummy = Const (Term.dummy_patternN, dummyT);
  1046 
  1047 fun oracle_proof name prop =
  1048   if ! proofs = 0 then ((name, dummy), Oracle (name, dummy, NONE))
  1049   else ((name, prop), gen_axm_proof Oracle name prop);
  1050 
  1051 val shrink_proof =
  1052   let
  1053     fun shrink ls lev (prf as Abst (a, T, body)) =
  1054           let val (b, is, ch, body') = shrink ls (lev+1) body
  1055           in (b, is, ch, if ch then Abst (a, T, body') else prf) end
  1056       | shrink ls lev (prf as AbsP (a, t, body)) =
  1057           let val (b, is, ch, body') = shrink (lev::ls) lev body
  1058           in (b orelse member (op =) is 0, map_filter (fn 0 => NONE | i => SOME (i-1)) is,
  1059             ch, if ch then AbsP (a, t, body') else prf)
  1060           end
  1061       | shrink ls lev prf =
  1062           let val (is, ch, _, prf') = shrink' ls lev [] [] prf
  1063           in (false, is, ch, prf') end
  1064     and shrink' ls lev ts prfs (prf as prf1 %% prf2) =
  1065           let
  1066             val p as (_, is', ch', prf') = shrink ls lev prf2;
  1067             val (is, ch, ts', prf'') = shrink' ls lev ts (p::prfs) prf1
  1068           in (union (op =) is is', ch orelse ch', ts',
  1069               if ch orelse ch' then prf'' %% prf' else prf)
  1070           end
  1071       | shrink' ls lev ts prfs (prf as prf1 % t) =
  1072           let val (is, ch, (ch', t')::ts', prf') = shrink' ls lev (t::ts) prfs prf1
  1073           in (is, ch orelse ch', ts',
  1074               if ch orelse ch' then prf' % t' else prf) end
  1075       | shrink' ls lev ts prfs (prf as PBound i) =
  1076           (if exists (fn SOME (Bound j) => lev-j <= nth ls i | _ => true) ts
  1077              orelse has_duplicates (op =)
  1078                (Library.foldl (fn (js, SOME (Bound j)) => j :: js | (js, _) => js) ([], ts))
  1079              orelse exists #1 prfs then [i] else [], false, map (pair false) ts, prf)
  1080       | shrink' ls lev ts prfs (prf as Hyp _) = ([], false, map (pair false) ts, prf)
  1081       | shrink' ls lev ts prfs (prf as MinProof) = ([], false, map (pair false) ts, prf)
  1082       | shrink' ls lev ts prfs (prf as OfClass _) = ([], false, map (pair false) ts, prf)
  1083       | shrink' ls lev ts prfs prf =
  1084           let
  1085             val prop =
  1086               (case prf of
  1087                 PAxm (_, prop, _) => prop
  1088               | Oracle (_, prop, _) => prop
  1089               | Promise (_, prop, _) => prop
  1090               | PThm (_, ((_, prop, _), _)) => prop
  1091               | _ => raise Fail "shrink: proof not in normal form");
  1092             val vs = vars_of prop;
  1093             val (ts', ts'') = chop (length vs) ts;
  1094             val insts = take (length ts') (map (fst o dest_Var) vs) ~~ ts';
  1095             val nvs = Library.foldl (fn (ixns', (ixn, ixns)) =>
  1096               insert (op =) ixn (case AList.lookup (op =) insts ixn of
  1097                   SOME (SOME t) => if is_proj t then union (op =) ixns ixns' else ixns'
  1098                 | _ => union (op =) ixns ixns'))
  1099                   (needed prop ts'' prfs, add_npvars false true [] ([], prop));
  1100             val insts' = map
  1101               (fn (ixn, x as SOME _) => if member (op =) nvs ixn then (false, x) else (true, NONE)
  1102                 | (_, x) => (false, x)) insts
  1103           in ([], false, insts' @ map (pair false) ts'', prf) end
  1104     and needed (Const ("==>", _) $ t $ u) ts ((b, _, _, _)::prfs) =
  1105           union (op =) (if b then map (fst o dest_Var) (vars_of t) else []) (needed u ts prfs)
  1106       | needed (Var (ixn, _)) (_::_) _ = [ixn]
  1107       | needed _ _ _ = [];
  1108   in shrink end;
  1109 
  1110 
  1111 (**** Simple first order matching functions for terms and proofs ****)
  1112 
  1113 exception PMatch;
  1114 
  1115 (** see pattern.ML **)
  1116 
  1117 fun flt (i: int) = filter (fn n => n < i);
  1118 
  1119 fun fomatch Ts tymatch j instsp p =
  1120   let
  1121     fun mtch (instsp as (tyinsts, insts)) = fn
  1122         (Var (ixn, T), t)  =>
  1123           if j>0 andalso not (null (flt j (loose_bnos t)))
  1124           then raise PMatch
  1125           else (tymatch (tyinsts, fn () => (T, fastype_of1 (Ts, t))),
  1126             (ixn, t) :: insts)
  1127       | (Free (a, T), Free (b, U)) =>
  1128           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1129       | (Const (a, T), Const (b, U))  =>
  1130           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1131       | (f $ t, g $ u) => mtch (mtch instsp (f, g)) (t, u)
  1132       | (Bound i, Bound j) => if i=j then instsp else raise PMatch
  1133       | _ => raise PMatch
  1134   in mtch instsp (pairself Envir.beta_eta_contract p) end;
  1135 
  1136 fun match_proof Ts tymatch =
  1137   let
  1138     fun optmatch _ inst (NONE, _) = inst
  1139       | optmatch _ _ (SOME _, NONE) = raise PMatch
  1140       | optmatch mtch inst (SOME x, SOME y) = mtch inst (x, y)
  1141 
  1142     fun matcht Ts j (pinst, tinst) (t, u) =
  1143       (pinst, fomatch Ts tymatch j tinst (t, Envir.beta_norm u));
  1144     fun matchT (pinst, (tyinsts, insts)) p =
  1145       (pinst, (tymatch (tyinsts, K p), insts));
  1146     fun matchTs inst (Ts, Us) = Library.foldl (uncurry matchT) (inst, Ts ~~ Us);
  1147 
  1148     fun mtch Ts i j (pinst, tinst) (Hyp (Var (ixn, _)), prf) =
  1149           if i = 0 andalso j = 0 then ((ixn, prf) :: pinst, tinst)
  1150           else (case apfst (flt i) (apsnd (flt j)
  1151                   (prf_add_loose_bnos 0 0 prf ([], []))) of
  1152               ([], []) => ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1153             | ([], _) => if j = 0 then
  1154                    ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1155                  else raise PMatch
  1156             | _ => raise PMatch)
  1157       | mtch Ts i j inst (prf1 % opt1, prf2 % opt2) =
  1158           optmatch (matcht Ts j) (mtch Ts i j inst (prf1, prf2)) (opt1, opt2)
  1159       | mtch Ts i j inst (prf1 %% prf2, prf1' %% prf2') =
  1160           mtch Ts i j (mtch Ts i j inst (prf1, prf1')) (prf2, prf2')
  1161       | mtch Ts i j inst (Abst (_, opT, prf1), Abst (_, opU, prf2)) =
  1162           mtch (the_default dummyT opU :: Ts) i (j+1)
  1163             (optmatch matchT inst (opT, opU)) (prf1, prf2)
  1164       | mtch Ts i j inst (prf1, Abst (_, opU, prf2)) =
  1165           mtch (the_default dummyT opU :: Ts) i (j+1) inst
  1166             (incr_pboundvars 0 1 prf1 %> Bound 0, prf2)
  1167       | mtch Ts i j inst (AbsP (_, opt, prf1), AbsP (_, opu, prf2)) =
  1168           mtch Ts (i+1) j (optmatch (matcht Ts j) inst (opt, opu)) (prf1, prf2)
  1169       | mtch Ts i j inst (prf1, AbsP (_, _, prf2)) =
  1170           mtch Ts (i+1) j inst (incr_pboundvars 1 0 prf1 %% PBound 0, prf2)
  1171       | mtch Ts i j inst (PAxm (s1, _, opTs), PAxm (s2, _, opUs)) =
  1172           if s1 = s2 then optmatch matchTs inst (opTs, opUs)
  1173           else raise PMatch
  1174       | mtch Ts i j inst (OfClass (T1, c1), OfClass (T2, c2)) =
  1175           if c1 = c2 then matchT inst (T1, T2)
  1176           else raise PMatch
  1177       | mtch Ts i j inst (PThm (_, ((name1, prop1, opTs), _)), PThm (_, ((name2, prop2, opUs), _))) =
  1178           if name1 = name2 andalso prop1 = prop2 then
  1179             optmatch matchTs inst (opTs, opUs)
  1180           else raise PMatch
  1181       | mtch _ _ _ inst (PBound i, PBound j) = if i = j then inst else raise PMatch
  1182       | mtch _ _ _ _ _ = raise PMatch
  1183   in mtch Ts 0 0 end;
  1184 
  1185 fun prf_subst (pinst, (tyinsts, insts)) =
  1186   let
  1187     val substT = Envir.subst_type_same tyinsts;
  1188     val substTs = Same.map substT;
  1189 
  1190     fun subst' lev (Var (xi, _)) =
  1191         (case AList.lookup (op =) insts xi of
  1192           NONE => raise Same.SAME
  1193         | SOME u => incr_boundvars lev u)
  1194       | subst' _ (Const (s, T)) = Const (s, substT T)
  1195       | subst' _ (Free (s, T)) = Free (s, substT T)
  1196       | subst' lev (Abs (a, T, body)) =
  1197           (Abs (a, substT T, Same.commit (subst' (lev + 1)) body)
  1198             handle Same.SAME => Abs (a, T, subst' (lev + 1) body))
  1199       | subst' lev (f $ t) =
  1200           (subst' lev f $ Same.commit (subst' lev) t
  1201             handle Same.SAME => f $ subst' lev t)
  1202       | subst' _ _ = raise Same.SAME;
  1203 
  1204     fun subst plev tlev (AbsP (a, t, body)) =
  1205           (AbsP (a, Same.map_option (subst' tlev) t, Same.commit (subst (plev + 1) tlev) body)
  1206             handle Same.SAME => AbsP (a, t, subst (plev + 1) tlev body))
  1207       | subst plev tlev (Abst (a, T, body)) =
  1208           (Abst (a, Same.map_option substT T, Same.commit (subst plev (tlev + 1)) body)
  1209             handle Same.SAME => Abst (a, T, subst plev (tlev + 1) body))
  1210       | subst plev tlev (prf %% prf') =
  1211           (subst plev tlev prf %% Same.commit (subst plev tlev) prf'
  1212             handle Same.SAME => prf %% subst plev tlev prf')
  1213       | subst plev tlev (prf % t) =
  1214           (subst plev tlev prf % Same.commit (Same.map_option (subst' tlev)) t
  1215             handle Same.SAME => prf % Same.map_option (subst' tlev) t)
  1216       | subst plev tlev (Hyp (Var (xi, _))) =
  1217           (case AList.lookup (op =) pinst xi of
  1218             NONE => raise Same.SAME
  1219           | SOME prf' => incr_pboundvars plev tlev prf')
  1220       | subst _ _ (PAxm (id, prop, Ts)) = PAxm (id, prop, Same.map_option substTs Ts)
  1221       | subst _ _ (OfClass (T, c)) = OfClass (substT T, c)
  1222       | subst _ _ (Oracle (id, prop, Ts)) = Oracle (id, prop, Same.map_option substTs Ts)
  1223       | subst _ _ (Promise (i, prop, Ts)) = Promise (i, prop, substTs Ts)
  1224       | subst _ _ (PThm (i, ((id, prop, Ts), body))) =
  1225           PThm (i, ((id, prop, Same.map_option substTs Ts), body))
  1226       | subst _ _ _ = raise Same.SAME;
  1227   in fn t => subst 0 0 t handle Same.SAME => t end;
  1228 
  1229 (*A fast unification filter: true unless the two terms cannot be unified.
  1230   Terms must be NORMAL.  Treats all Vars as distinct. *)
  1231 fun could_unify prf1 prf2 =
  1232   let
  1233     fun matchrands (prf1 %% prf2) (prf1' %% prf2') =
  1234           could_unify prf2 prf2' andalso matchrands prf1 prf1'
  1235       | matchrands (prf % SOME t) (prf' % SOME t') =
  1236           Term.could_unify (t, t') andalso matchrands prf prf'
  1237       | matchrands (prf % _) (prf' % _) = matchrands prf prf'
  1238       | matchrands _ _ = true
  1239 
  1240     fun head_of (prf %% _) = head_of prf
  1241       | head_of (prf % _) = head_of prf
  1242       | head_of prf = prf
  1243 
  1244   in case (head_of prf1, head_of prf2) of
  1245         (_, Hyp (Var _)) => true
  1246       | (Hyp (Var _), _) => true
  1247       | (PAxm (a, _, _), PAxm (b, _, _)) => a = b andalso matchrands prf1 prf2
  1248       | (OfClass (_, c), OfClass (_, d)) => c = d andalso matchrands prf1 prf2
  1249       | (PThm (_, ((a, propa, _), _)), PThm (_, ((b, propb, _), _))) =>
  1250           a = b andalso propa = propb andalso matchrands prf1 prf2
  1251       | (PBound i, PBound j) => i = j andalso matchrands prf1 prf2
  1252       | (AbsP _, _) =>  true   (*because of possible eta equality*)
  1253       | (Abst _, _) =>  true
  1254       | (_, AbsP _) =>  true
  1255       | (_, Abst _) =>  true
  1256       | _ => false
  1257   end;
  1258 
  1259 
  1260 (**** rewriting on proof terms ****)
  1261 
  1262 val no_skel = PBound 0;
  1263 val normal_skel = Hyp (Var ((Name.uu, 0), propT));
  1264 
  1265 fun rewrite_prf tymatch (rules, procs) prf =
  1266   let
  1267     fun rew _ _ (Abst (_, _, body) % SOME t) = SOME (prf_subst_bounds [t] body, no_skel)
  1268       | rew _ _ (AbsP (_, _, body) %% prf) = SOME (prf_subst_pbounds [prf] body, no_skel)
  1269       | rew Ts hs prf =
  1270           (case get_first (fn r => r Ts hs prf) procs of
  1271             NONE => get_first (fn (prf1, prf2) => SOME (prf_subst
  1272               (match_proof Ts tymatch ([], (Vartab.empty, [])) (prf1, prf)) prf2, prf2)
  1273                  handle PMatch => NONE) (filter (could_unify prf o fst) rules)
  1274           | some => some);
  1275 
  1276     fun rew0 Ts hs (prf as AbsP (_, _, prf' %% PBound 0)) =
  1277           if prf_loose_Pbvar1 prf' 0 then rew Ts hs prf
  1278           else
  1279             let val prf'' = incr_pboundvars (~1) 0 prf'
  1280             in SOME (the_default (prf'', no_skel) (rew Ts hs prf'')) end
  1281       | rew0 Ts hs (prf as Abst (_, _, prf' % SOME (Bound 0))) =
  1282           if prf_loose_bvar1 prf' 0 then rew Ts hs prf
  1283           else
  1284             let val prf'' = incr_pboundvars 0 (~1) prf'
  1285             in SOME (the_default (prf'', no_skel) (rew Ts hs prf'')) end
  1286       | rew0 Ts hs prf = rew Ts hs prf;
  1287 
  1288     fun rew1 _ _ (Hyp (Var _)) _ = NONE
  1289       | rew1 Ts hs skel prf = (case rew2 Ts hs skel prf of
  1290           SOME prf1 => (case rew0 Ts hs prf1 of
  1291               SOME (prf2, skel') => SOME (the_default prf2 (rew1 Ts hs skel' prf2))
  1292             | NONE => SOME prf1)
  1293         | NONE => (case rew0 Ts hs prf of
  1294               SOME (prf1, skel') => SOME (the_default prf1 (rew1 Ts hs skel' prf1))
  1295             | NONE => NONE))
  1296 
  1297     and rew2 Ts hs skel (prf % SOME t) = (case prf of
  1298             Abst (_, _, body) =>
  1299               let val prf' = prf_subst_bounds [t] body
  1300               in SOME (the_default prf' (rew2 Ts hs no_skel prf')) end
  1301           | _ => (case rew1 Ts hs (case skel of skel' % _ => skel' | _ => no_skel) prf of
  1302               SOME prf' => SOME (prf' % SOME t)
  1303             | NONE => NONE))
  1304       | rew2 Ts hs skel (prf % NONE) = Option.map (fn prf' => prf' % NONE)
  1305           (rew1 Ts hs (case skel of skel' % _ => skel' | _ => no_skel) prf)
  1306       | rew2 Ts hs skel (prf1 %% prf2) = (case prf1 of
  1307             AbsP (_, _, body) =>
  1308               let val prf' = prf_subst_pbounds [prf2] body
  1309               in SOME (the_default prf' (rew2 Ts hs no_skel prf')) end
  1310           | _ =>
  1311             let val (skel1, skel2) = (case skel of
  1312                 skel1 %% skel2 => (skel1, skel2)
  1313               | _ => (no_skel, no_skel))
  1314             in case rew1 Ts hs skel1 prf1 of
  1315                 SOME prf1' => (case rew1 Ts hs skel2 prf2 of
  1316                     SOME prf2' => SOME (prf1' %% prf2')
  1317                   | NONE => SOME (prf1' %% prf2))
  1318               | NONE => (case rew1 Ts hs skel2 prf2 of
  1319                     SOME prf2' => SOME (prf1 %% prf2')
  1320                   | NONE => NONE)
  1321             end)
  1322       | rew2 Ts hs skel (Abst (s, T, prf)) = (case rew1 (the_default dummyT T :: Ts) hs
  1323               (case skel of Abst (_, _, skel') => skel' | _ => no_skel) prf of
  1324             SOME prf' => SOME (Abst (s, T, prf'))
  1325           | NONE => NONE)
  1326       | rew2 Ts hs skel (AbsP (s, t, prf)) = (case rew1 Ts (t :: hs)
  1327               (case skel of AbsP (_, _, skel') => skel' | _ => no_skel) prf of
  1328             SOME prf' => SOME (AbsP (s, t, prf'))
  1329           | NONE => NONE)
  1330       | rew2 _ _ _ _ = NONE;
  1331 
  1332   in the_default prf (rew1 [] [] no_skel prf) end;
  1333 
  1334 fun rewrite_proof thy = rewrite_prf (fn (tyenv, f) =>
  1335   Sign.typ_match thy (f ()) tyenv handle Type.TYPE_MATCH => raise PMatch);
  1336 
  1337 fun rewrite_proof_notypes rews = rewrite_prf fst rews;
  1338 
  1339 
  1340 (**** theory data ****)
  1341 
  1342 structure Data = Theory_Data
  1343 (
  1344   type T =
  1345     (stamp * (proof * proof)) list *
  1346     (stamp * (typ list -> term option list -> proof -> (proof * proof) option)) list;
  1347 
  1348   val empty = ([], []);
  1349   val extend = I;
  1350   fun merge ((rules1, procs1), (rules2, procs2)) : T =
  1351     (AList.merge (op =) (K true) (rules1, rules2),
  1352       AList.merge (op =) (K true) (procs1, procs2));
  1353 );
  1354 
  1355 fun get_data thy = let val (rules, procs) = Data.get thy in (map #2 rules, map #2 procs) end;
  1356 fun rew_proof thy = rewrite_prf fst (get_data thy);
  1357 
  1358 fun add_prf_rrule r = (Data.map o apfst) (cons (stamp (), r));
  1359 fun add_prf_rproc p = (Data.map o apsnd) (cons (stamp (), p));
  1360 
  1361 
  1362 (***** promises *****)
  1363 
  1364 fun promise_proof thy i prop =
  1365   let
  1366     val _ = prop |> Term.exists_subterm (fn t =>
  1367       (Term.is_Free t orelse Term.is_Var t) andalso
  1368         raise Fail ("promise_proof: illegal variable " ^ Syntax.string_of_term_global thy t));
  1369     val _ = prop |> Term.exists_type (Term.exists_subtype
  1370       (fn TFree (a, _) => raise Fail ("promise_proof: illegal type variable " ^ quote a)
  1371         | _ => false));
  1372   in Promise (i, prop, map TVar (Term.add_tvars prop [])) end;
  1373 
  1374 fun fulfill_norm_proof thy ps body0 =
  1375   let
  1376     val PBody {oracles = oracles0, thms = thms0, proof = proof0} = body0;
  1377     val oracles = fold (fn (_, PBody {oracles, ...}) => merge_oracles oracles) ps oracles0;
  1378     val thms = fold (fn (_, PBody {thms, ...}) => merge_thms thms) ps thms0;
  1379     val proofs = fold (fn (i, PBody {proof, ...}) => Inttab.update (i, proof)) ps Inttab.empty;
  1380 
  1381     fun fill (Promise (i, prop, Ts)) =
  1382           (case Inttab.lookup proofs i of
  1383             NONE => NONE
  1384           | SOME prf => SOME (instantiate (Term.add_tvars prop [] ~~ Ts, []) prf, normal_skel))
  1385       | fill _ = NONE;
  1386     val (rules, procs) = get_data thy;
  1387     val proof = rewrite_prf fst (rules, K (K fill) :: procs) proof0;
  1388   in PBody {oracles = oracles, thms = thms, proof = proof} end;
  1389 
  1390 fun fulfill_proof_future _ [] postproc body =
  1391       if not (Multithreading.enabled ()) then Future.value (postproc (Future.join body))
  1392       else Future.map postproc body
  1393   | fulfill_proof_future thy promises postproc body =
  1394       Future.fork_deps (body :: map snd promises) (fn () =>
  1395         postproc (fulfill_norm_proof thy (map (apsnd Future.join) promises) (Future.join body)));
  1396 
  1397 
  1398 (***** abstraction over sort constraints *****)
  1399 
  1400 fun unconstrainT_prf thy (atyp_map, constraints) =
  1401   let
  1402     fun hyp_map hyp =
  1403       (case AList.lookup (op =) constraints hyp of
  1404         SOME t => Hyp t
  1405       | NONE => raise Fail "unconstrainT_prf: missing constraint");
  1406 
  1407     val typ = Term_Subst.map_atypsT_same (Type.strip_sorts o atyp_map);
  1408     fun ofclass (ty, c) =
  1409       let val ty' = Term.map_atyps atyp_map ty;
  1410       in the_single (of_sort_proof thy hyp_map (ty', [c])) end;
  1411   in
  1412     Same.commit (map_proof_same (Term_Subst.map_types_same typ) typ ofclass)
  1413     #> fold_rev (implies_intr_proof o snd) constraints
  1414   end;
  1415 
  1416 fun unconstrainT_body thy constrs (PBody {oracles, thms, proof}) =
  1417   PBody
  1418    {oracles = oracles,  (* FIXME merge (!), unconstrain (!?!) *)
  1419     thms = thms,  (* FIXME merge (!) *)
  1420     proof = unconstrainT_prf thy constrs proof};
  1421 
  1422 
  1423 (***** theorems *****)
  1424 
  1425 fun prepare_thm_proof do_unconstrain thy name shyps hyps concl promises body =
  1426   let
  1427     val PBody {oracles = oracles0, thms = thms0, proof = prf} = body;
  1428     val prop = Logic.list_implies (hyps, concl);
  1429     val nvs = needed_vars prop;
  1430     val args = map (fn (v as Var (ixn, _)) =>
  1431         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1432       map SOME (frees_of prop);
  1433 
  1434     val (postproc, ofclasses, prop1, args1) =
  1435       if do_unconstrain then
  1436         let
  1437           val ((atyp_map, constraints, outer_constraints), prop1) =
  1438             Logic.unconstrainT shyps prop;
  1439           val postproc = unconstrainT_body thy (atyp_map, constraints);
  1440           val args1 =
  1441             (map o Option.map o Term.map_types o Term.map_atyps)
  1442               (Type.strip_sorts o atyp_map) args;
  1443         in (postproc, map OfClass outer_constraints, prop1, args1) end
  1444       else (I, [], prop, args);
  1445     val argsP = ofclasses @ map Hyp hyps;
  1446 
  1447     fun full_proof0 () =
  1448       #4 (shrink_proof [] 0 (rew_proof thy (fold_rev implies_intr_proof hyps prf)));
  1449 
  1450     fun make_body0 proof0 = PBody {oracles = oracles0, thms = thms0, proof = proof0};
  1451     val body0 =
  1452       if ! proofs <> 2 then Future.value (make_body0 MinProof)
  1453       else if not (Multithreading.enabled ()) then Future.value (make_body0 (full_proof0 ()))
  1454       else Future.fork_pri ~1 (make_body0 o full_proof0);
  1455 
  1456     fun new_prf () = (serial (), fulfill_proof_future thy promises postproc body0);
  1457     val (i, body') =
  1458       (case strip_combt (fst (strip_combP prf)) of
  1459         (PThm (i, ((old_name, prop', NONE), body')), args') =>
  1460           if (old_name = "" orelse old_name = name) andalso prop1 = prop' andalso args = args'
  1461           then (i, body')
  1462           else new_prf ()
  1463       | _ => new_prf ());
  1464     val head = PThm (i, ((name, prop1, NONE), body'));
  1465   in ((i, (name, prop1, body')), head, args, argsP, args1) end;
  1466 
  1467 val unconstrain_thm_proofs = Unsynchronized.ref true;
  1468 
  1469 fun thm_proof thy name shyps hyps concl promises body =
  1470   let val (pthm, head, args, argsP, _) =
  1471     prepare_thm_proof (! unconstrain_thm_proofs) thy name shyps hyps concl promises body
  1472   in (pthm, proof_combP (proof_combt' (head, args), argsP)) end;
  1473 
  1474 fun unconstrain_thm_proof thy shyps concl promises body =
  1475   let
  1476     val (pthm, head, _, _, args) =
  1477       prepare_thm_proof true thy "" shyps [] concl promises body
  1478   in (pthm, proof_combt' (head, args)) end;
  1479 
  1480 
  1481 fun get_name hyps prop prf =
  1482   let val prop = Logic.list_implies (hyps, prop) in
  1483     (case strip_combt (fst (strip_combP prf)) of
  1484       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1485     | _ => "")
  1486   end;
  1487 
  1488 fun get_name_unconstrained shyps hyps prop prf =
  1489   let val (_, prop) = Logic.unconstrainT shyps (Logic.list_implies (hyps, prop)) in
  1490     (case strip_combt (fst (strip_combP prf)) of
  1491       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1492     | _ => "")
  1493   end;
  1494 
  1495 fun guess_name (PThm (_, ((name, _, _), _))) = name
  1496   | guess_name (prf %% Hyp _) = guess_name prf
  1497   | guess_name (prf %% OfClass _) = guess_name prf
  1498   | guess_name (prf % NONE) = guess_name prf
  1499   | guess_name (prf % SOME (Var _)) = guess_name prf
  1500   | guess_name _ = "";
  1501 
  1502 end;
  1503 
  1504 structure Basic_Proofterm : BASIC_PROOFTERM = Proofterm;
  1505 open Basic_Proofterm;