src/Pure/axclass.ML
author wenzelm
Fri Nov 09 00:19:20 2001 +0100 (2001-11-09 ago)
changeset 12123 739eba13e2cd
parent 12043 8c86683597a8
child 12311 ce5f9e61c037
permissions -rw-r--r--
theory data: finish method;
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 
     6 Axiomatic type class package.
     7 *)
     8 
     9 signature AX_CLASS =
    10 sig
    11   val quiet_mode: bool ref
    12   val print_axclasses: theory -> unit
    13   val add_classrel_thms: thm list -> theory -> theory
    14   val add_arity_thms: thm list -> theory -> theory
    15   val add_axclass: bclass * xclass list -> ((bstring * string) * Args.src list) list
    16     -> theory -> theory * {intro: thm, axioms: thm list}
    17   val add_axclass_i: bclass * class list -> ((bstring * term) * theory attribute list) list
    18     -> theory -> theory * {intro: thm, axioms: thm list}
    19   val add_inst_subclass_x: xclass * xclass -> string list -> thm list
    20     -> tactic option -> theory -> theory
    21   val add_inst_subclass: xclass * xclass -> tactic -> theory -> theory
    22   val add_inst_subclass_i: class * class -> tactic -> theory -> theory
    23   val add_inst_arity_x: xstring * string list * string -> string list
    24     -> thm list -> tactic option -> theory -> theory
    25   val add_inst_arity: xstring * string list * string -> tactic -> theory -> theory
    26   val add_inst_arity_i: string * sort list * sort -> tactic -> theory -> theory
    27   val default_intro_classes_tac: thm list -> int -> tactic
    28   val axclass_tac: thm list -> tactic
    29   val instance_subclass_proof: (xclass * xclass) * Comment.text -> bool -> theory -> ProofHistory.T
    30   val instance_subclass_proof_i: (class * class) * Comment.text -> bool -> theory -> ProofHistory.T
    31   val instance_arity_proof: (xstring * string list * xclass) * Comment.text
    32     -> bool -> theory -> ProofHistory.T
    33   val instance_arity_proof_i: (string * sort list * class) * Comment.text
    34     -> bool -> theory -> ProofHistory.T
    35   val setup: (theory -> theory) list
    36 end;
    37 
    38 structure AxClass : AX_CLASS =
    39 struct
    40 
    41 
    42 (** utilities **)
    43 
    44 (* messages *)
    45 
    46 val quiet_mode = ref false;
    47 fun message s = if ! quiet_mode then () else writeln s;
    48 
    49 
    50 (* type vars *)
    51 
    52 fun map_typ_frees f (Type (t, tys)) = Type (t, map (map_typ_frees f) tys)
    53   | map_typ_frees f (TFree a) = f a
    54   | map_typ_frees _ a = a;
    55 
    56 val map_term_tfrees = map_term_types o map_typ_frees;
    57 
    58 fun aT S = TFree ("'a", S);
    59 
    60 fun dest_varT (TFree (x, S)) = ((x, ~1), S)
    61   | dest_varT (TVar xi_S) = xi_S
    62   | dest_varT T = raise TYPE ("dest_varT", [T], []);
    63 
    64 
    65 (* get axioms and theorems *)
    66 
    67 val is_def = Logic.is_equals o #prop o rep_thm;
    68 
    69 fun witnesses thy names thms =
    70   PureThy.get_thmss thy names @ thms @ filter is_def (map snd (axioms_of thy));
    71 
    72 
    73 
    74 (** abstract syntax operations **)
    75 
    76 (* names *)
    77 
    78 fun intro_name c = c ^ "I";
    79 val introN = "intro";
    80 val axiomsN = "axioms";
    81 
    82 
    83 (* subclass relations as terms *)
    84 
    85 fun mk_classrel (c1, c2) = Logic.mk_inclass (aT [c1], c2);
    86 
    87 fun dest_classrel tm =
    88   let
    89     fun err () = raise TERM ("dest_classrel", [tm]);
    90 
    91     val (ty, c2) = Logic.dest_inclass tm handle TERM _ => err ();
    92     val c1 = (case dest_varT ty of (_, [c]) => c | _ => err ())
    93       handle TYPE _ => err ();
    94   in (c1, c2) end;
    95 
    96 
    97 (* arities as terms *)
    98 
    99 fun mk_arity (t, ss, c) =
   100   let
   101     val tfrees = ListPair.map TFree (Term.invent_names (length ss) "'", ss);
   102   in Logic.mk_inclass (Type (t, tfrees), c) end;
   103 
   104 fun dest_arity tm =
   105   let
   106     fun err () = raise TERM ("dest_arity", [tm]);
   107 
   108     val (ty, c) = Logic.dest_inclass tm handle TERM _ => err ();
   109     val (t, tvars) =
   110       (case ty of
   111         Type (t, tys) => (t, map dest_varT tys handle TYPE _ => err ())
   112       | _ => err ());
   113     val ss =
   114       if null (gen_duplicates eq_fst tvars)
   115       then map snd tvars else err ();
   116   in (t, ss, c) end;
   117 
   118 
   119 
   120 (** add theorems as axioms **)
   121 
   122 fun prep_thm_axm thy thm =
   123   let
   124     fun err msg = raise THM ("prep_thm_axm: " ^ msg, 0, [thm]);
   125 
   126     val {sign, hyps, prop, ...} = rep_thm thm;
   127   in
   128     if not (Sign.subsig (sign, Theory.sign_of thy)) then
   129       err "theorem not of same theory"
   130     else if not (null (extra_shyps thm)) orelse not (null hyps) then
   131       err "theorem may not contain hypotheses"
   132     else prop
   133   end;
   134 
   135 (*theorems expressing class relations*)
   136 fun add_classrel_thms thms thy =
   137   let
   138     fun prep_thm thm =
   139       let
   140         val prop = prep_thm_axm thy thm;
   141         val (c1, c2) = dest_classrel prop handle TERM _ =>
   142           raise THM ("add_classrel_thms: theorem is not a class relation", 0, [thm]);
   143       in (c1, c2) end;
   144   in Theory.add_classrel_i (map prep_thm thms) thy end;
   145 
   146 (*theorems expressing arities*)
   147 fun add_arity_thms thms thy =
   148   let
   149     fun prep_thm thm =
   150       let
   151         val prop = prep_thm_axm thy thm;
   152         val (t, ss, c) = dest_arity prop handle TERM _ =>
   153           raise THM ("add_arity_thms: theorem is not an arity", 0, [thm]);
   154       in (t, ss, [c]) end;
   155   in Theory.add_arities_i (map prep_thm thms) thy end;
   156 
   157 
   158 
   159 (** axclass info **)
   160 
   161 (* data kind 'Pure/axclasses' *)
   162 
   163 type axclass_info =
   164   {super_classes: class list,
   165     intro: thm,
   166     axioms: thm list};
   167 
   168 structure AxclassesArgs =
   169 struct
   170   val name = "Pure/axclasses";
   171   type T = axclass_info Symtab.table;
   172 
   173   val empty = Symtab.empty;
   174   val copy = I;
   175   val finish = I;
   176   val prep_ext = I;
   177   fun merge (tab1, tab2) = Symtab.merge (K true) (tab1, tab2);
   178 
   179   fun print sg tab =
   180     let
   181       val ext_class = Sign.cond_extern sg Sign.classK;
   182       val ext_thm = PureThy.cond_extern_thm_sg sg;
   183 
   184       fun pretty_class c cs = Pretty.block
   185         (Pretty.str (ext_class c) :: Pretty.str " <" :: Pretty.brk 1 ::
   186           Pretty.breaks (map (Pretty.str o ext_class) cs));
   187 
   188       fun pretty_thms name thms = Pretty.big_list (name ^ ":")
   189         (map (Display.pretty_thm_sg sg) thms);
   190 
   191       fun pretty_axclass (name, {super_classes, intro, axioms}) = Pretty.block (Pretty.fbreaks
   192         [pretty_class name super_classes, pretty_thms introN [intro], pretty_thms axiomsN axioms]);
   193     in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest tab))) end;
   194 end;
   195 
   196 structure AxclassesData = TheoryDataFun(AxclassesArgs);
   197 val print_axclasses = AxclassesData.print;
   198 
   199 
   200 (* get and put data *)
   201 
   202 fun lookup_axclass_info_sg sg c = Symtab.lookup (AxclassesData.get_sg sg, c);
   203 
   204 fun get_axclass_info thy c =
   205   (case lookup_axclass_info_sg (Theory.sign_of thy) c of
   206     None => error ("Unknown axclass " ^ quote c)
   207   | Some info => info);
   208 
   209 fun put_axclass_info c info thy =
   210   thy |> AxclassesData.put (Symtab.update ((c, info), AxclassesData.get thy));
   211 
   212 
   213 
   214 (** add axiomatic type classes **)
   215 
   216 (* errors *)
   217 
   218 fun err_not_logic c =
   219   error ("Axiomatic class " ^ quote c ^ " not subclass of " ^ quote logicC);
   220 
   221 fun err_bad_axsort ax c =
   222   error ("Sort constraint in axiom " ^ quote ax ^ " not supersort of " ^ quote c);
   223 
   224 fun err_bad_tfrees ax =
   225   error ("More than one type variable in axiom " ^ quote ax);
   226 
   227 
   228 (* ext_axclass *)
   229 
   230 fun ext_axclass prep_class prep_axm prep_att (bclass, raw_super_classes) raw_axioms_atts thy =
   231   let
   232     val sign = Theory.sign_of thy;
   233 
   234     val class = Sign.full_name sign bclass;
   235     val super_classes = map (prep_class sign) raw_super_classes;
   236     val axms = map (prep_axm sign o fst) raw_axioms_atts;
   237     val atts = map (map (prep_att thy) o snd) raw_axioms_atts;
   238 
   239     (*declare class*)
   240     val class_thy =
   241       thy |> Theory.add_classes_i [(bclass, super_classes)];
   242     val class_sign = Theory.sign_of class_thy;
   243 
   244     (*prepare abstract axioms*)
   245     fun abs_axm ax =
   246       if null (term_tfrees ax) then
   247         Logic.mk_implies (Logic.mk_inclass (aT logicS, class), ax)
   248       else map_term_tfrees (K (aT [class])) ax;
   249     val abs_axms = map (abs_axm o #2) axms;
   250 
   251     (*prepare introduction rule*)
   252     val _ = if Sign.subsort class_sign ([class], logicS) then () else err_not_logic class;
   253 
   254     fun axm_sort (name, ax) =
   255       (case term_tfrees ax of
   256         [] => []
   257       | [(_, S)] => if Sign.subsort class_sign ([class], S) then S else err_bad_axsort name class
   258       | _ => err_bad_tfrees name);
   259     val axS = Sign.norm_sort class_sign (logicC :: flat (map axm_sort axms));
   260 
   261     val int_axm = Logic.close_form o map_term_tfrees (K (aT axS));
   262     fun inclass c = Logic.mk_inclass (aT axS, c);
   263 
   264     val intro_axm = Logic.list_implies
   265       (map inclass super_classes @ map (int_axm o #2) axms, inclass class);
   266 
   267     (*declare axioms and rule*)
   268     val (axms_thy, ([intro], [axioms])) =
   269       class_thy
   270       |> Theory.add_path bclass
   271       |> PureThy.add_axioms_i [Thm.no_attributes (introN, intro_axm)]
   272       |>>> PureThy.add_axiomss_i [Thm.no_attributes (axiomsN, abs_axms)];
   273     val info = {super_classes = super_classes, intro = intro, axioms = axioms};
   274 
   275     (*store info*)
   276     val final_thy =
   277       axms_thy
   278       |> (#1 o PureThy.add_thms ((map #1 axms ~~ axioms) ~~ atts))
   279       |> Theory.parent_path
   280       |> (#1 o PureThy.add_thms [Thm.no_attributes (intro_name bclass, intro)])
   281       |> put_axclass_info class info;
   282   in (final_thy, {intro = intro, axioms = axioms}) end;
   283 
   284 
   285 (* external interfaces *)
   286 
   287 val add_axclass = ext_axclass Sign.intern_class Theory.read_axm Attrib.global_attribute;
   288 val add_axclass_i = ext_axclass (K I) Theory.cert_axm (K I);
   289 
   290 
   291 
   292 (** prove class relations and type arities **)
   293 
   294 (* class_axms *)
   295 
   296 fun class_axms sign =
   297   let val classes = Sign.classes sign in
   298     map (Thm.class_triv sign) classes @
   299     mapfilter (apsome #intro o lookup_axclass_info_sg sign) classes
   300   end;
   301 
   302 
   303 (* intro_classes *)
   304 
   305 fun intro_classes_tac facts i st =
   306   ((Method.insert_tac facts THEN'
   307     REPEAT_ALL_NEW (resolve_tac (class_axms (Thm.sign_of_thm st)))) i
   308     THEN Tactic.distinct_subgoals_tac) st;    (*affects all subgoals!?*)
   309 
   310 val intro_classes_method =
   311   ("intro_classes", Method.no_args (Method.METHOD (HEADGOAL o intro_classes_tac)),
   312     "back-chain introduction rules of axiomatic type classes");
   313 
   314 
   315 (* default method *)
   316 
   317 fun default_intro_classes_tac [] i = intro_classes_tac [] i
   318   | default_intro_classes_tac _ _ = Tactical.no_tac;    (*no error message!*)
   319 
   320 fun default_tac rules ctxt facts =
   321   HEADGOAL (Method.some_rule_tac rules ctxt facts ORELSE' default_intro_classes_tac facts);
   322 
   323 val default_method =
   324   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac), "apply some rule")
   325 
   326 
   327 (* axclass_tac *)
   328 
   329 (*(1) repeatedly resolve goals of form "OFCLASS(ty, c_class)",
   330       try class_trivs first, then "cI" axioms
   331   (2) rewrite goals using user supplied definitions
   332   (3) repeatedly resolve goals with user supplied non-definitions*)
   333 
   334 fun axclass_tac thms =
   335   let
   336     val defs = filter is_def thms;
   337     val non_defs = filter_out is_def thms;
   338   in
   339     HEADGOAL (intro_classes_tac []) THEN
   340     TRY (rewrite_goals_tac defs) THEN
   341     TRY (REPEAT_FIRST (fn i => assume_tac i ORELSE resolve_tac non_defs i))
   342   end;
   343 
   344 
   345 (* provers *)
   346 
   347 fun prove mk_prop str_of sign prop thms usr_tac =
   348   (Tactic.prove sign [] [] (mk_prop prop) (K (axclass_tac thms THEN (if_none usr_tac all_tac)))
   349     handle ERROR => error ("The error(s) above occurred while trying to prove " ^
   350      quote (str_of sign prop))) |> Drule.standard;
   351 
   352 val prove_subclass =
   353   prove mk_classrel (fn sg => fn c1_c2 => Sign.str_of_classrel sg c1_c2);
   354 
   355 val prove_arity =
   356   prove mk_arity (fn sg => fn (t, Ss, c) => Sign.str_of_arity sg (t, Ss, [c]));
   357 
   358 
   359 
   360 (** add proved subclass relations and arities **)
   361 
   362 (* prepare classes and arities *)
   363 
   364 fun read_class sg c = Sign.certify_class sg (Sign.intern_class sg c);
   365 
   366 fun cert_classrel sg cc = Library.pairself (Sign.certify_class sg) cc;
   367 fun read_classrel sg cc = Library.pairself (read_class sg) cc;
   368 
   369 fun check_tycon sg t =
   370   let val {tycons, abbrs, ...} = Type.rep_tsig (Sign.tsig_of sg) in
   371     if is_some (Symtab.lookup (abbrs, t)) then
   372       error ("Illegal type abbreviation: " ^ quote t)
   373     else if is_none (Symtab.lookup (tycons, t)) then
   374       error ("Undeclared type constructor: " ^ quote t)
   375     else t
   376   end;
   377 
   378 fun prep_arity prep_tycon prep_sort prep_x sg (t, Ss, x) =
   379   (check_tycon sg (prep_tycon sg t), map (prep_sort sg) Ss, prep_x sg x);
   380 
   381 val read_arity = prep_arity Sign.intern_tycon Sign.read_sort Sign.read_sort;
   382 val cert_arity = prep_arity (K I) Sign.certify_sort Sign.certify_sort;
   383 val read_simple_arity = prep_arity Sign.intern_tycon Sign.read_sort Sign.intern_class;
   384 fun cert_simple_arity arg = prep_arity (K I) Sign.certify_sort (K I) arg;
   385 
   386 
   387 (* old-style instance declarations *)
   388 
   389 fun ext_inst_subclass prep_classrel raw_c1_c2 names thms usr_tac thy =
   390   let
   391     val sign = Theory.sign_of thy;
   392     val c1_c2 = prep_classrel sign raw_c1_c2;
   393   in
   394     message ("Proving class inclusion " ^ quote (Sign.str_of_classrel sign c1_c2) ^ " ...");
   395     thy |> add_classrel_thms [prove_subclass sign c1_c2 (witnesses thy names thms) usr_tac]
   396   end;
   397 
   398 fun ext_inst_arity prep_arity (raw_t, raw_Ss, raw_cs) names thms usr_tac thy =
   399   let
   400     val sign = Theory.sign_of thy;
   401     val (t, Ss, cs) = prep_arity sign (raw_t, raw_Ss, raw_cs);
   402     val wthms = witnesses thy names thms;
   403     fun prove c =
   404      (message ("Proving type arity " ^
   405         quote (Sign.str_of_arity sign (t, Ss, [c])) ^ " ...");
   406         prove_arity sign (t, Ss, c) wthms usr_tac);
   407   in add_arity_thms (map prove cs) thy end;
   408 
   409 fun sane_inst_subclass prep sub tac = ext_inst_subclass prep sub [] [] (Some tac);
   410 fun sane_inst_arity prep arity tac = ext_inst_arity prep arity [] [] (Some tac);
   411 
   412 val add_inst_subclass_x = ext_inst_subclass read_classrel;
   413 val add_inst_subclass = sane_inst_subclass read_classrel;
   414 val add_inst_subclass_i = sane_inst_subclass cert_classrel;
   415 val add_inst_arity_x = ext_inst_arity read_arity;
   416 val add_inst_arity = sane_inst_arity read_arity;
   417 val add_inst_arity_i = sane_inst_arity cert_arity;
   418 
   419 
   420 
   421 (** instance proof interfaces **)
   422 
   423 fun inst_attribute add_thms (thy, thm) = (add_thms [thm] thy, thm);
   424 
   425 fun inst_proof mk_prop add_thms (sig_prop, comment) int thy =
   426   thy
   427   |> IsarThy.theorem_i Drule.internalK (None, []) ((("", [inst_attribute add_thms]),
   428     (mk_prop (Theory.sign_of thy) sig_prop, ([], []))), comment) int;
   429 
   430 val instance_subclass_proof = inst_proof (mk_classrel oo read_classrel) add_classrel_thms;
   431 val instance_subclass_proof_i = inst_proof (mk_classrel oo cert_classrel) add_classrel_thms;
   432 val instance_arity_proof = inst_proof (mk_arity oo read_simple_arity) add_arity_thms;
   433 val instance_arity_proof_i = inst_proof (mk_arity oo cert_simple_arity) add_arity_thms;
   434 
   435 
   436 
   437 (** package setup **)
   438 
   439 (* setup theory *)
   440 
   441 val setup =
   442  [AxclassesData.init,
   443   Method.add_methods [intro_classes_method, default_method]];
   444 
   445 
   446 (* outer syntax *)
   447 
   448 local structure P = OuterParse and K = OuterSyntax.Keyword in
   449 
   450 val axclassP =
   451   OuterSyntax.command "axclass" "define axiomatic type class" K.thy_decl
   452     (((P.name -- Scan.optional ((P.$$$ "\\<subseteq>" || P.$$$ "<") |--
   453         P.!!! (P.list1 P.xname)) []) --| P.marg_comment)
   454       -- Scan.repeat (P.spec_name --| P.marg_comment)
   455       >> (fn (cls, axs) => Toplevel.theory (#1 o add_axclass cls axs)));
   456 
   457 val instanceP =
   458   OuterSyntax.command "instance" "prove type arity or subclass relation" K.thy_goal
   459     ((P.xname -- ((P.$$$ "\\<subseteq>" || P.$$$ "<") |-- P.xname)
   460         -- P.marg_comment >> instance_subclass_proof ||
   461       (P.xname -- (P.$$$ "::" |-- P.simple_arity) >> P.triple2) -- P.marg_comment
   462         >> instance_arity_proof)
   463       >> (Toplevel.print oo Toplevel.theory_to_proof));
   464 
   465 val _ = OuterSyntax.add_parsers [axclassP, instanceP];
   466 
   467 end;
   468 
   469 end;