src/Pure/proofterm.ML
author wenzelm
Thu May 13 17:25:53 2010 +0200 (2010-05-13 ago)
changeset 36877 7699f7fafde7
parent 36742 6f8bbe9ca8a2
child 36878 5caff17a28cd
permissions -rw-r--r--
added Proofterm.get_name variants according to krauss/schropp;
tuned signature;
     1 (*  Title:      Pure/proofterm.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 LF style proof terms.
     5 *)
     6 
     7 infix 8 % %% %>;
     8 
     9 signature BASIC_PROOFTERM =
    10 sig
    11   val proofs: int Unsynchronized.ref
    12 
    13   datatype proof =
    14      MinProof
    15    | PBound of int
    16    | Abst of string * typ option * proof
    17    | AbsP of string * term option * proof
    18    | op % of proof * term option
    19    | op %% of proof * proof
    20    | Hyp of term
    21    | PAxm of string * term * typ list option
    22    | OfClass of typ * class
    23    | Oracle of string * term * typ list option
    24    | Promise of serial * term * typ list
    25    | PThm of serial * ((string * term * typ list option) * proof_body future)
    26   and proof_body = PBody of
    27     {oracles: (string * term) OrdList.T,
    28      thms: (serial * (string * term * proof_body future)) OrdList.T,
    29      proof: proof}
    30 
    31   val %> : proof * term -> proof
    32 end;
    33 
    34 signature PROOFTERM =
    35 sig
    36   include BASIC_PROOFTERM
    37 
    38   type oracle = string * term
    39   type pthm = serial * (string * term * proof_body future)
    40   val proof_of: proof_body -> proof
    41   val join_proof: proof_body future -> proof
    42   val fold_proof_atoms: bool -> (proof -> 'a -> 'a) -> proof list -> 'a -> 'a
    43   val fold_body_thms: (string * term * proof_body -> 'a -> 'a) -> proof_body list -> 'a -> 'a
    44   val join_bodies: proof_body list -> unit
    45   val status_of: proof_body list -> {failed: bool, oracle: bool, unfinished: bool}
    46 
    47   val oracle_ord: oracle * oracle -> order
    48   val thm_ord: pthm * pthm -> order
    49   val merge_oracles: oracle OrdList.T -> oracle OrdList.T -> oracle OrdList.T
    50   val merge_thms: pthm OrdList.T -> pthm OrdList.T -> pthm OrdList.T
    51   val all_oracles_of: proof_body -> oracle OrdList.T
    52   val approximate_proof_body: proof -> proof_body
    53 
    54   (** primitive operations **)
    55   val proof_combt: proof * term list -> proof
    56   val proof_combt': proof * term option list -> proof
    57   val proof_combP: proof * proof list -> proof
    58   val strip_combt: proof -> proof * term option list
    59   val strip_combP: proof -> proof * proof list
    60   val strip_thm: proof_body -> proof_body
    61   val map_proof_terms_same: term Same.operation -> typ Same.operation -> proof Same.operation
    62   val map_proof_types_same: typ Same.operation -> proof Same.operation
    63   val map_proof_terms: (term -> term) -> (typ -> typ) -> proof -> proof
    64   val map_proof_types: (typ -> typ) -> proof -> proof
    65   val fold_proof_terms: (term -> 'a -> 'a) -> (typ -> 'a -> 'a) -> proof -> 'a -> 'a
    66   val maxidx_proof: proof -> int -> int
    67   val size_of_proof: proof -> int
    68   val change_type: typ list option -> proof -> proof
    69   val prf_abstract_over: term -> proof -> proof
    70   val prf_incr_bv: int -> int -> int -> int -> proof -> proof
    71   val incr_pboundvars: int -> int -> proof -> proof
    72   val prf_loose_bvar1: proof -> int -> bool
    73   val prf_loose_Pbvar1: proof -> int -> bool
    74   val prf_add_loose_bnos: int -> int -> proof -> int list * int list -> int list * int list
    75   val norm_proof: Envir.env -> proof -> proof
    76   val norm_proof': Envir.env -> proof -> proof
    77   val prf_subst_bounds: term list -> proof -> proof
    78   val prf_subst_pbounds: proof list -> proof -> proof
    79   val freeze_thaw_prf: proof -> proof * (proof -> proof)
    80 
    81   (** proof terms for specific inference rules **)
    82   val implies_intr_proof: term -> proof -> proof
    83   val forall_intr_proof: term -> string -> proof -> proof
    84   val varify_proof: term -> (string * sort) list -> proof -> proof
    85   val legacy_freezeT: term -> proof -> proof
    86   val rotate_proof: term list -> term -> int -> proof -> proof
    87   val permute_prems_proof: term list -> int -> int -> proof -> proof
    88   val generalize: string list * string list -> int -> proof -> proof
    89   val instantiate: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
    90     -> proof -> proof
    91   val lift_proof: term -> int -> term -> proof -> proof
    92   val incr_indexes: int -> proof -> proof
    93   val assumption_proof: term list -> term -> int -> proof -> proof
    94   val bicompose_proof: bool -> term list -> term list -> term list -> term option ->
    95     int -> int -> proof -> proof -> proof
    96   val equality_axms: (string * term) list
    97   val reflexive_axm: proof
    98   val symmetric_axm: proof
    99   val transitive_axm: proof
   100   val equal_intr_axm: proof
   101   val equal_elim_axm: proof
   102   val abstract_rule_axm: proof
   103   val combination_axm: proof
   104   val reflexive: proof
   105   val symmetric: proof -> proof
   106   val transitive: term -> typ -> proof -> proof -> proof
   107   val abstract_rule: term -> string -> proof -> proof
   108   val combination: term -> term -> term -> term -> typ -> proof -> proof -> proof
   109   val equal_intr: term -> term -> proof -> proof -> proof
   110   val equal_elim: term -> term -> proof -> proof -> proof
   111   val strip_shyps_proof: Sorts.algebra -> (typ * sort) list -> (typ * sort) list ->
   112     sort list -> proof -> proof
   113   val classrel_proof: theory -> class * class -> proof
   114   val arity_proof: theory -> string * sort list * class -> proof
   115   val of_sort_proof: theory -> (typ * class -> proof) -> typ * sort -> proof list
   116   val install_axclass_proofs:
   117    {classrel_proof: theory -> class * class -> proof,
   118     arity_proof: theory -> string * sort list * class -> proof} -> unit
   119   val axm_proof: string -> term -> proof
   120   val oracle_proof: string -> term -> oracle * proof
   121 
   122   (** rewriting on proof terms **)
   123   val add_prf_rrule: proof * proof -> theory -> theory
   124   val add_prf_rproc: (typ list -> proof -> (proof * proof) option) -> theory -> theory
   125   val no_skel: proof
   126   val normal_skel: proof
   127   val rewrite_proof: theory -> (proof * proof) list *
   128     (typ list -> proof -> (proof * proof) option) list -> proof -> proof
   129   val rewrite_proof_notypes: (proof * proof) list *
   130     (typ list -> proof -> (proof * proof) option) list -> proof -> proof
   131   val rew_proof: theory -> proof -> proof
   132 
   133   val promise_proof: theory -> serial -> term -> proof
   134   val fulfill_norm_proof: theory -> (serial * proof_body) list -> proof_body -> proof_body
   135   val thm_proof: theory -> string -> term list -> term ->
   136     (serial * proof_body future) list -> proof_body -> pthm * proof
   137   val get_name: term list -> term -> proof -> string
   138   val get_name_unconstrained: sort list -> term list -> term -> proof -> string
   139   val guess_name: proof -> string
   140 end
   141 
   142 structure Proofterm : PROOFTERM =
   143 struct
   144 
   145 (***** datatype proof *****)
   146 
   147 datatype proof =
   148    MinProof
   149  | PBound of int
   150  | Abst of string * typ option * proof
   151  | AbsP of string * term option * proof
   152  | op % of proof * term option
   153  | op %% of proof * proof
   154  | Hyp of term
   155  | PAxm of string * term * typ list option
   156  | OfClass of typ * class
   157  | Oracle of string * term * typ list option
   158  | Promise of serial * term * typ list
   159  | PThm of serial * ((string * term * typ list option) * proof_body future)
   160 and proof_body = PBody of
   161   {oracles: (string * term) OrdList.T,
   162    thms: (serial * (string * term * proof_body future)) OrdList.T,
   163    proof: proof};
   164 
   165 type oracle = string * term;
   166 type pthm = serial * (string * term * proof_body future);
   167 
   168 fun proof_of (PBody {proof, ...}) = proof;
   169 val join_proof = Future.join #> proof_of;
   170 
   171 
   172 (***** proof atoms *****)
   173 
   174 fun fold_proof_atoms all f =
   175   let
   176     fun app (Abst (_, _, prf)) = app prf
   177       | app (AbsP (_, _, prf)) = app prf
   178       | app (prf % _) = app prf
   179       | app (prf1 %% prf2) = app prf1 #> app prf2
   180       | app (prf as PThm (i, (_, body))) = (fn (x, seen) =>
   181           if Inttab.defined seen i then (x, seen)
   182           else
   183             let val (x', seen') =
   184               (if all then app (join_proof body) else I) (x, Inttab.update (i, ()) seen)
   185             in (f prf x', seen') end)
   186       | app prf = (fn (x, seen) => (f prf x, seen));
   187   in fn prfs => fn x => #1 (fold app prfs (x, Inttab.empty)) end;
   188 
   189 fun fold_body_thms f =
   190   let
   191     fun app (PBody {thms, ...}) =
   192      (Future.join_results (map (#3 o #2) thms);
   193       thms |> fold (fn (i, (name, prop, body)) => fn (x, seen) =>
   194         if Inttab.defined seen i then (x, seen)
   195         else
   196           let
   197             val body' = Future.join body;
   198             val (x', seen') = app body' (x, Inttab.update (i, ()) seen);
   199           in (f (name, prop, body') x', seen') end));
   200   in fn bodies => fn x => #1 (fold app bodies (x, Inttab.empty)) end;
   201 
   202 fun join_bodies bodies = fold_body_thms (fn _ => fn () => ()) bodies ();
   203 
   204 fun status_of bodies =
   205   let
   206     fun status (PBody {oracles, thms, ...}) x =
   207       let
   208         val ((oracle, unfinished, failed), seen) =
   209           (thms, x) |-> fold (fn (i, (_, _, body)) => fn (st, seen) =>
   210             if Inttab.defined seen i then (st, seen)
   211             else
   212               let val seen' = Inttab.update (i, ()) seen in
   213                 (case Future.peek body of
   214                   SOME (Exn.Result body') => status body' (st, seen')
   215                 | SOME (Exn.Exn _) =>
   216                     let val (oracle, unfinished, _) = st
   217                     in ((oracle, unfinished, true), seen') end
   218                 | NONE =>
   219                     let val (oracle, _, failed) = st
   220                     in ((oracle, true, failed), seen') end)
   221               end);
   222       in ((oracle orelse not (null oracles), unfinished, failed), seen) end;
   223     val (oracle, unfinished, failed) =
   224       #1 (fold status bodies ((false, false, false), Inttab.empty));
   225   in {oracle = oracle, unfinished = unfinished, failed = failed} end;
   226 
   227 
   228 (* proof body *)
   229 
   230 val oracle_ord = prod_ord fast_string_ord Term_Ord.fast_term_ord;
   231 fun thm_ord ((i, _): pthm, (j, _)) = int_ord (j, i);
   232 
   233 val merge_oracles = OrdList.union oracle_ord;
   234 val merge_thms = OrdList.union thm_ord;
   235 
   236 val all_oracles_of =
   237   let
   238     fun collect (PBody {oracles, thms, ...}) =
   239      (Future.join_results (map (#3 o #2) thms);
   240       thms |> fold (fn (i, (_, _, body)) => fn (x, seen) =>
   241         if Inttab.defined seen i then (x, seen)
   242         else
   243           let
   244             val body' = Future.join body;
   245             val (x', seen') = collect body' (x, Inttab.update (i, ()) seen);
   246           in (merge_oracles oracles x', seen') end));
   247   in fn body => #1 (collect body ([], Inttab.empty)) end;
   248 
   249 fun approximate_proof_body prf =
   250   let
   251     val (oracles, thms) = fold_proof_atoms false
   252       (fn Oracle (s, prop, _) => apfst (cons (s, prop))
   253         | PThm (i, ((name, prop, _), body)) => apsnd (cons (i, (name, prop, body)))
   254         | _ => I) [prf] ([], []);
   255   in
   256     PBody
   257      {oracles = OrdList.make oracle_ord oracles,
   258       thms = OrdList.make thm_ord thms,
   259       proof = prf}
   260   end;
   261 
   262 
   263 (***** proof objects with different levels of detail *****)
   264 
   265 fun (prf %> t) = prf % SOME t;
   266 
   267 val proof_combt = Library.foldl (op %>);
   268 val proof_combt' = Library.foldl (op %);
   269 val proof_combP = Library.foldl (op %%);
   270 
   271 fun strip_combt prf =
   272     let fun stripc (prf % t, ts) = stripc (prf, t::ts)
   273           | stripc  x =  x
   274     in  stripc (prf, [])  end;
   275 
   276 fun strip_combP prf =
   277     let fun stripc (prf %% prf', prfs) = stripc (prf, prf'::prfs)
   278           | stripc  x =  x
   279     in  stripc (prf, [])  end;
   280 
   281 fun strip_thm (body as PBody {proof, ...}) =
   282   (case strip_combt (fst (strip_combP proof)) of
   283     (PThm (_, (_, body')), _) => Future.join body'
   284   | _ => body);
   285 
   286 val mk_Abst = fold_rev (fn (s, T:typ) => fn prf => Abst (s, NONE, prf));
   287 fun mk_AbsP (i, prf) = funpow i (fn prf => AbsP ("H", NONE, prf)) prf;
   288 
   289 fun map_proof_same term typ ofclass =
   290   let
   291     val typs = Same.map typ;
   292 
   293     fun proof (Abst (s, T, prf)) =
   294           (Abst (s, Same.map_option typ T, Same.commit proof prf)
   295             handle Same.SAME => Abst (s, T, proof prf))
   296       | proof (AbsP (s, t, prf)) =
   297           (AbsP (s, Same.map_option term t, Same.commit proof prf)
   298             handle Same.SAME => AbsP (s, t, proof prf))
   299       | proof (prf % t) =
   300           (proof prf % Same.commit (Same.map_option term) t
   301             handle Same.SAME => prf % Same.map_option term t)
   302       | proof (prf1 %% prf2) =
   303           (proof prf1 %% Same.commit proof prf2
   304             handle Same.SAME => prf1 %% proof prf2)
   305       | proof (PAxm (a, prop, SOME Ts)) = PAxm (a, prop, SOME (typs Ts))
   306       | proof (OfClass T_c) = ofclass T_c
   307       | proof (Oracle (a, prop, SOME Ts)) = Oracle (a, prop, SOME (typs Ts))
   308       | proof (Promise (i, prop, Ts)) = Promise (i, prop, typs Ts)
   309       | proof (PThm (i, ((a, prop, SOME Ts), body))) =
   310           PThm (i, ((a, prop, SOME (typs Ts)), body))
   311       | proof _ = raise Same.SAME;
   312   in proof end;
   313 
   314 fun map_proof_terms_same term typ = map_proof_same term typ (fn (T, c) => OfClass (typ T, c));
   315 fun map_proof_types_same typ = map_proof_terms_same (Term_Subst.map_types_same typ) typ;
   316 
   317 fun same eq f x =
   318   let val x' = f x
   319   in if eq (x, x') then raise Same.SAME else x' end;
   320 
   321 fun map_proof_terms f g = Same.commit (map_proof_terms_same (same (op =) f) (same (op =) g));
   322 fun map_proof_types f = Same.commit (map_proof_types_same (same (op =) f));
   323 
   324 fun fold_proof_terms f g (Abst (_, SOME T, prf)) = g T #> fold_proof_terms f g prf
   325   | fold_proof_terms f g (Abst (_, NONE, prf)) = fold_proof_terms f g prf
   326   | fold_proof_terms f g (AbsP (_, SOME t, prf)) = f t #> fold_proof_terms f g prf
   327   | fold_proof_terms f g (AbsP (_, NONE, prf)) = fold_proof_terms f g prf
   328   | fold_proof_terms f g (prf % SOME t) = fold_proof_terms f g prf #> f t
   329   | fold_proof_terms f g (prf % NONE) = fold_proof_terms f g prf
   330   | fold_proof_terms f g (prf1 %% prf2) =
   331       fold_proof_terms f g prf1 #> fold_proof_terms f g prf2
   332   | fold_proof_terms _ g (PAxm (_, _, SOME Ts)) = fold g Ts
   333   | fold_proof_terms _ g (OfClass (T, _)) = g T
   334   | fold_proof_terms _ g (Oracle (_, _, SOME Ts)) = fold g Ts
   335   | fold_proof_terms _ g (Promise (_, _, Ts)) = fold g Ts
   336   | fold_proof_terms _ g (PThm (_, ((_, _, SOME Ts), _))) = fold g Ts
   337   | fold_proof_terms _ _ _ = I;
   338 
   339 fun maxidx_proof prf = fold_proof_terms Term.maxidx_term Term.maxidx_typ prf;
   340 
   341 fun size_of_proof (Abst (_, _, prf)) = 1 + size_of_proof prf
   342   | size_of_proof (AbsP (_, t, prf)) = 1 + size_of_proof prf
   343   | size_of_proof (prf % _) = 1 + size_of_proof prf
   344   | size_of_proof (prf1 %% prf2) = size_of_proof prf1 + size_of_proof prf2
   345   | size_of_proof _ = 1;
   346 
   347 fun change_type opTs (PAxm (name, prop, _)) = PAxm (name, prop, opTs)
   348   | change_type (SOME [T]) (OfClass (_, c)) = OfClass (T, c)
   349   | change_type opTs (Oracle (name, prop, _)) = Oracle (name, prop, opTs)
   350   | change_type opTs (Promise _) = error "change_type: unexpected promise"
   351   | change_type opTs (PThm (i, ((name, prop, _), body))) =
   352       PThm (i, ((name, prop, opTs), body))
   353   | change_type _ prf = prf;
   354 
   355 
   356 (***** utilities *****)
   357 
   358 fun strip_abs (_::Ts) (Abs (_, _, t)) = strip_abs Ts t
   359   | strip_abs _ t = t;
   360 
   361 fun mk_abs Ts t = Library.foldl (fn (t', T) => Abs ("", T, t')) (t, Ts);
   362 
   363 
   364 (*Abstraction of a proof term over its occurrences of v,
   365     which must contain no loose bound variables.
   366   The resulting proof term is ready to become the body of an Abst.*)
   367 
   368 fun prf_abstract_over v =
   369   let
   370     fun abst' lev u = if v aconv u then Bound lev else
   371       (case u of
   372          Abs (a, T, t) => Abs (a, T, abst' (lev + 1) t)
   373        | f $ t => (abst' lev f $ absth' lev t handle Same.SAME => f $ abst' lev t)
   374        | _ => raise Same.SAME)
   375     and absth' lev t = (abst' lev t handle Same.SAME => t);
   376 
   377     fun abst lev (AbsP (a, t, prf)) =
   378           (AbsP (a, Same.map_option (abst' lev) t, absth lev prf)
   379            handle Same.SAME => AbsP (a, t, abst lev prf))
   380       | abst lev (Abst (a, T, prf)) = Abst (a, T, abst (lev + 1) prf)
   381       | abst lev (prf1 %% prf2) = (abst lev prf1 %% absth lev prf2
   382           handle Same.SAME => prf1 %% abst lev prf2)
   383       | abst lev (prf % t) = (abst lev prf % Option.map (absth' lev) t
   384           handle Same.SAME => prf % Same.map_option (abst' lev) t)
   385       | abst _ _ = raise Same.SAME
   386     and absth lev prf = (abst lev prf handle Same.SAME => prf);
   387 
   388   in absth 0 end;
   389 
   390 
   391 (*increments a proof term's non-local bound variables
   392   required when moving a proof term within abstractions
   393      inc is  increment for bound variables
   394      lev is  level at which a bound variable is considered 'loose'*)
   395 
   396 fun incr_bv' inct tlev t = incr_bv (inct, tlev, t);
   397 
   398 fun prf_incr_bv' incP inct Plev tlev (PBound i) =
   399       if i >= Plev then PBound (i+incP) else raise Same.SAME
   400   | prf_incr_bv' incP inct Plev tlev (AbsP (a, t, body)) =
   401       (AbsP (a, Same.map_option (same (op =) (incr_bv' inct tlev)) t,
   402          prf_incr_bv incP inct (Plev+1) tlev body) handle Same.SAME =>
   403            AbsP (a, t, prf_incr_bv' incP inct (Plev+1) tlev body))
   404   | prf_incr_bv' incP inct Plev tlev (Abst (a, T, body)) =
   405       Abst (a, T, prf_incr_bv' incP inct Plev (tlev+1) body)
   406   | prf_incr_bv' incP inct Plev tlev (prf %% prf') =
   407       (prf_incr_bv' incP inct Plev tlev prf %% prf_incr_bv incP inct Plev tlev prf'
   408        handle Same.SAME => prf %% prf_incr_bv' incP inct Plev tlev prf')
   409   | prf_incr_bv' incP inct Plev tlev (prf % t) =
   410       (prf_incr_bv' incP inct Plev tlev prf % Option.map (incr_bv' inct tlev) t
   411        handle Same.SAME => prf % Same.map_option (same (op =) (incr_bv' inct tlev)) t)
   412   | prf_incr_bv' _ _ _ _ _ = raise Same.SAME
   413 and prf_incr_bv incP inct Plev tlev prf =
   414       (prf_incr_bv' incP inct Plev tlev prf handle Same.SAME => prf);
   415 
   416 fun incr_pboundvars  0 0 prf = prf
   417   | incr_pboundvars incP inct prf = prf_incr_bv incP inct 0 0 prf;
   418 
   419 
   420 fun prf_loose_bvar1 (prf1 %% prf2) k = prf_loose_bvar1 prf1 k orelse prf_loose_bvar1 prf2 k
   421   | prf_loose_bvar1 (prf % SOME t) k = prf_loose_bvar1 prf k orelse loose_bvar1 (t, k)
   422   | prf_loose_bvar1 (_ % NONE) _ = true
   423   | prf_loose_bvar1 (AbsP (_, SOME t, prf)) k = loose_bvar1 (t, k) orelse prf_loose_bvar1 prf k
   424   | prf_loose_bvar1 (AbsP (_, NONE, _)) k = true
   425   | prf_loose_bvar1 (Abst (_, _, prf)) k = prf_loose_bvar1 prf (k+1)
   426   | prf_loose_bvar1 _ _ = false;
   427 
   428 fun prf_loose_Pbvar1 (PBound i) k = i = k
   429   | prf_loose_Pbvar1 (prf1 %% prf2) k = prf_loose_Pbvar1 prf1 k orelse prf_loose_Pbvar1 prf2 k
   430   | prf_loose_Pbvar1 (prf % _) k = prf_loose_Pbvar1 prf k
   431   | prf_loose_Pbvar1 (AbsP (_, _, prf)) k = prf_loose_Pbvar1 prf (k+1)
   432   | prf_loose_Pbvar1 (Abst (_, _, prf)) k = prf_loose_Pbvar1 prf k
   433   | prf_loose_Pbvar1 _ _ = false;
   434 
   435 fun prf_add_loose_bnos plev tlev (PBound i) (is, js) =
   436       if i < plev then (is, js) else (insert (op =) (i-plev) is, js)
   437   | prf_add_loose_bnos plev tlev (prf1 %% prf2) p =
   438       prf_add_loose_bnos plev tlev prf2
   439         (prf_add_loose_bnos plev tlev prf1 p)
   440   | prf_add_loose_bnos plev tlev (prf % opt) (is, js) =
   441       prf_add_loose_bnos plev tlev prf (case opt of
   442           NONE => (is, insert (op =) ~1 js)
   443         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   444   | prf_add_loose_bnos plev tlev (AbsP (_, opt, prf)) (is, js) =
   445       prf_add_loose_bnos (plev+1) tlev prf (case opt of
   446           NONE => (is, insert (op =) ~1 js)
   447         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   448   | prf_add_loose_bnos plev tlev (Abst (_, _, prf)) p =
   449       prf_add_loose_bnos plev (tlev+1) prf p
   450   | prf_add_loose_bnos _ _ _ _ = ([], []);
   451 
   452 
   453 (**** substitutions ****)
   454 
   455 fun del_conflicting_tvars envT T = Term_Subst.instantiateT
   456   (map_filter (fn ixnS as (_, S) =>
   457      (Type.lookup envT ixnS; NONE) handle TYPE _ =>
   458         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.typ_tvars T)) T;
   459 
   460 fun del_conflicting_vars env t = Term_Subst.instantiate
   461   (map_filter (fn ixnS as (_, S) =>
   462      (Type.lookup (Envir.type_env env) ixnS; NONE) handle TYPE _ =>
   463         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.term_tvars t),
   464    map_filter (fn Var (ixnT as (_, T)) =>
   465      (Envir.lookup (env, ixnT); NONE) handle TYPE _ =>
   466         SOME (ixnT, Free ("dummy", T))) (OldTerm.term_vars t)) t;
   467 
   468 fun norm_proof env =
   469   let
   470     val envT = Envir.type_env env;
   471     fun msg s = warning ("type conflict in norm_proof:\n" ^ s);
   472     fun htype f t = f env t handle TYPE (s, _, _) =>
   473       (msg s; f env (del_conflicting_vars env t));
   474     fun htypeT f T = f envT T handle TYPE (s, _, _) =>
   475       (msg s; f envT (del_conflicting_tvars envT T));
   476     fun htypeTs f Ts = f envT Ts handle TYPE (s, _, _) =>
   477       (msg s; f envT (map (del_conflicting_tvars envT) Ts));
   478 
   479     fun norm (Abst (s, T, prf)) =
   480           (Abst (s, Same.map_option (htypeT Envir.norm_type_same) T, Same.commit norm prf)
   481             handle Same.SAME => Abst (s, T, norm prf))
   482       | norm (AbsP (s, t, prf)) =
   483           (AbsP (s, Same.map_option (htype Envir.norm_term_same) t, Same.commit norm prf)
   484             handle Same.SAME => AbsP (s, t, norm prf))
   485       | norm (prf % t) =
   486           (norm prf % Option.map (htype Envir.norm_term) t
   487             handle Same.SAME => prf % Same.map_option (htype Envir.norm_term_same) t)
   488       | norm (prf1 %% prf2) =
   489           (norm prf1 %% Same.commit norm prf2
   490             handle Same.SAME => prf1 %% norm prf2)
   491       | norm (PAxm (s, prop, Ts)) =
   492           PAxm (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   493       | norm (OfClass (T, c)) =
   494           OfClass (htypeT Envir.norm_type_same T, c)
   495       | norm (Oracle (s, prop, Ts)) =
   496           Oracle (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   497       | norm (Promise (i, prop, Ts)) =
   498           Promise (i, prop, htypeTs Envir.norm_types_same Ts)
   499       | norm (PThm (i, ((s, t, Ts), body))) =
   500           PThm (i, ((s, t, Same.map_option (htypeTs Envir.norm_types_same) Ts), body))
   501       | norm _ = raise Same.SAME;
   502   in Same.commit norm end;
   503 
   504 
   505 (***** Remove some types in proof term (to save space) *****)
   506 
   507 fun remove_types (Abs (s, _, t)) = Abs (s, dummyT, remove_types t)
   508   | remove_types (t $ u) = remove_types t $ remove_types u
   509   | remove_types (Const (s, _)) = Const (s, dummyT)
   510   | remove_types t = t;
   511 
   512 fun remove_types_env (Envir.Envir {maxidx, tenv, tyenv}) =
   513   Envir.Envir {maxidx = maxidx, tenv = Vartab.map (apsnd remove_types) tenv, tyenv = tyenv};
   514 
   515 fun norm_proof' env prf = norm_proof (remove_types_env env) prf;
   516 
   517 
   518 (**** substitution of bound variables ****)
   519 
   520 fun prf_subst_bounds args prf =
   521   let
   522     val n = length args;
   523     fun subst' lev (Bound i) =
   524          (if i<lev then raise Same.SAME    (*var is locally bound*)
   525           else  incr_boundvars lev (nth args (i-lev))
   526                   handle Subscript => Bound (i-n))  (*loose: change it*)
   527       | subst' lev (Abs (a, T, body)) = Abs (a, T,  subst' (lev+1) body)
   528       | subst' lev (f $ t) = (subst' lev f $ substh' lev t
   529           handle Same.SAME => f $ subst' lev t)
   530       | subst' _ _ = raise Same.SAME
   531     and substh' lev t = (subst' lev t handle Same.SAME => t);
   532 
   533     fun subst lev (AbsP (a, t, body)) =
   534         (AbsP (a, Same.map_option (subst' lev) t, substh lev body)
   535           handle Same.SAME => AbsP (a, t, subst lev body))
   536       | subst lev (Abst (a, T, body)) = Abst (a, T, subst (lev+1) body)
   537       | subst lev (prf %% prf') = (subst lev prf %% substh lev prf'
   538           handle Same.SAME => prf %% subst lev prf')
   539       | subst lev (prf % t) = (subst lev prf % Option.map (substh' lev) t
   540           handle Same.SAME => prf % Same.map_option (subst' lev) t)
   541       | subst _ _ = raise Same.SAME
   542     and substh lev prf = (subst lev prf handle Same.SAME => prf);
   543   in case args of [] => prf | _ => substh 0 prf end;
   544 
   545 fun prf_subst_pbounds args prf =
   546   let
   547     val n = length args;
   548     fun subst (PBound i) Plev tlev =
   549          (if i < Plev then raise Same.SAME    (*var is locally bound*)
   550           else incr_pboundvars Plev tlev (nth args (i-Plev))
   551                  handle Subscript => PBound (i-n)  (*loose: change it*))
   552       | subst (AbsP (a, t, body)) Plev tlev = AbsP (a, t, subst body (Plev+1) tlev)
   553       | subst (Abst (a, T, body)) Plev tlev = Abst (a, T, subst body Plev (tlev+1))
   554       | subst (prf %% prf') Plev tlev = (subst prf Plev tlev %% substh prf' Plev tlev
   555           handle Same.SAME => prf %% subst prf' Plev tlev)
   556       | subst (prf % t) Plev tlev = subst prf Plev tlev % t
   557       | subst  prf _ _ = raise Same.SAME
   558     and substh prf Plev tlev = (subst prf Plev tlev handle Same.SAME => prf)
   559   in case args of [] => prf | _ => substh prf 0 0 end;
   560 
   561 
   562 (**** Freezing and thawing of variables in proof terms ****)
   563 
   564 fun frzT names =
   565   map_type_tvar (fn (ixn, xs) => TFree ((the o AList.lookup (op =) names) ixn, xs));
   566 
   567 fun thawT names =
   568   map_type_tfree (fn (s, xs) => case AList.lookup (op =) names s of
   569       NONE => TFree (s, xs)
   570     | SOME ixn => TVar (ixn, xs));
   571 
   572 fun freeze names names' (t $ u) =
   573       freeze names names' t $ freeze names names' u
   574   | freeze names names' (Abs (s, T, t)) =
   575       Abs (s, frzT names' T, freeze names names' t)
   576   | freeze names names' (Const (s, T)) = Const (s, frzT names' T)
   577   | freeze names names' (Free (s, T)) = Free (s, frzT names' T)
   578   | freeze names names' (Var (ixn, T)) =
   579       Free ((the o AList.lookup (op =) names) ixn, frzT names' T)
   580   | freeze names names' t = t;
   581 
   582 fun thaw names names' (t $ u) =
   583       thaw names names' t $ thaw names names' u
   584   | thaw names names' (Abs (s, T, t)) =
   585       Abs (s, thawT names' T, thaw names names' t)
   586   | thaw names names' (Const (s, T)) = Const (s, thawT names' T)
   587   | thaw names names' (Free (s, T)) =
   588       let val T' = thawT names' T
   589       in case AList.lookup (op =) names s of
   590           NONE => Free (s, T')
   591         | SOME ixn => Var (ixn, T')
   592       end
   593   | thaw names names' (Var (ixn, T)) = Var (ixn, thawT names' T)
   594   | thaw names names' t = t;
   595 
   596 fun freeze_thaw_prf prf =
   597   let
   598     val (fs, Tfs, vs, Tvs) = fold_proof_terms
   599       (fn t => fn (fs, Tfs, vs, Tvs) =>
   600          (Term.add_free_names t fs, Term.add_tfree_names t Tfs,
   601           Term.add_var_names t vs, Term.add_tvar_names t Tvs))
   602       (fn T => fn (fs, Tfs, vs, Tvs) =>
   603          (fs, Term.add_tfree_namesT T Tfs,
   604           vs, Term.add_tvar_namesT T Tvs))
   605       prf ([], [], [], []);
   606     val names = vs ~~ Name.variant_list fs (map fst vs);
   607     val names' = Tvs ~~ Name.variant_list Tfs (map fst Tvs);
   608     val rnames = map swap names;
   609     val rnames' = map swap names';
   610   in
   611     (map_proof_terms (freeze names names') (frzT names') prf,
   612      map_proof_terms (thaw rnames rnames') (thawT rnames'))
   613   end;
   614 
   615 
   616 (***** implication introduction *****)
   617 
   618 fun implies_intr_proof h prf =
   619   let
   620     fun abshyp i (Hyp t) = if h aconv t then PBound i else raise Same.SAME
   621       | abshyp i (Abst (s, T, prf)) = Abst (s, T, abshyp i prf)
   622       | abshyp i (AbsP (s, t, prf)) = AbsP (s, t, abshyp (i + 1) prf)
   623       | abshyp i (prf % t) = abshyp i prf % t
   624       | abshyp i (prf1 %% prf2) =
   625           (abshyp i prf1 %% abshyph i prf2
   626             handle Same.SAME => prf1 %% abshyp i prf2)
   627       | abshyp _ _ = raise Same.SAME
   628     and abshyph i prf = (abshyp i prf handle Same.SAME => prf);
   629   in
   630     AbsP ("H", NONE (*h*), abshyph 0 prf)
   631   end;
   632 
   633 
   634 (***** forall introduction *****)
   635 
   636 fun forall_intr_proof x a prf = Abst (a, NONE, prf_abstract_over x prf);
   637 
   638 
   639 (***** varify *****)
   640 
   641 fun varify_proof t fixed prf =
   642   let
   643     val fs = Term.fold_types (Term.fold_atyps
   644       (fn TFree v => if member (op =) fixed v then I else insert (op =) v | _ => I)) t [];
   645     val used = Name.context
   646       |> fold_types (fold_atyps (fn TVar ((a, _), _) => Name.declare a | _ => I)) t;
   647     val fmap = fs ~~ #1 (Name.variants (map fst fs) used);
   648     fun thaw (f as (a, S)) =
   649       (case AList.lookup (op =) fmap f of
   650         NONE => TFree f
   651       | SOME b => TVar ((b, 0), S));
   652   in map_proof_terms (map_types (map_type_tfree thaw)) (map_type_tfree thaw) prf end;
   653 
   654 
   655 local
   656 
   657 fun new_name (ix, (pairs,used)) =
   658   let val v = Name.variant used (string_of_indexname ix)
   659   in  ((ix, v) :: pairs, v :: used)  end;
   660 
   661 fun freeze_one alist (ix, sort) = (case AList.lookup (op =) alist ix of
   662     NONE => TVar (ix, sort)
   663   | SOME name => TFree (name, sort));
   664 
   665 in
   666 
   667 fun legacy_freezeT t prf =
   668   let
   669     val used = OldTerm.it_term_types OldTerm.add_typ_tfree_names (t, [])
   670     and tvars = map #1 (OldTerm.it_term_types OldTerm.add_typ_tvars (t, []));
   671     val (alist, _) = List.foldr new_name ([], used) tvars;
   672   in
   673     (case alist of
   674       [] => prf (*nothing to do!*)
   675     | _ =>
   676       let val frzT = map_type_tvar (freeze_one alist)
   677       in map_proof_terms (map_types frzT) frzT prf end)
   678   end;
   679 
   680 end;
   681 
   682 
   683 (***** rotate assumptions *****)
   684 
   685 fun rotate_proof Bs Bi m prf =
   686   let
   687     val params = Term.strip_all_vars Bi;
   688     val asms = Logic.strip_imp_prems (Term.strip_all_body Bi);
   689     val i = length asms;
   690     val j = length Bs;
   691   in
   692     mk_AbsP (j+1, proof_combP (prf, map PBound
   693       (j downto 1) @ [mk_Abst params (mk_AbsP (i,
   694         proof_combP (proof_combt (PBound i, map Bound ((length params - 1) downto 0)),
   695           map PBound (((i-m-1) downto 0) @ ((i-1) downto (i-m))))))]))
   696   end;
   697 
   698 
   699 (***** permute premises *****)
   700 
   701 fun permute_prems_proof prems j k prf =
   702   let val n = length prems
   703   in mk_AbsP (n, proof_combP (prf,
   704     map PBound ((n-1 downto n-j) @ (k-1 downto 0) @ (n-j-1 downto k))))
   705   end;
   706 
   707 
   708 (***** generalization *****)
   709 
   710 fun generalize (tfrees, frees) idx =
   711   Same.commit (map_proof_terms_same
   712     (Term_Subst.generalize_same (tfrees, frees) idx)
   713     (Term_Subst.generalizeT_same tfrees idx));
   714 
   715 
   716 (***** instantiation *****)
   717 
   718 fun instantiate (instT, inst) =
   719   Same.commit (map_proof_terms_same
   720     (Term_Subst.instantiate_same (instT, map (apsnd remove_types) inst))
   721     (Term_Subst.instantiateT_same instT));
   722 
   723 
   724 (***** lifting *****)
   725 
   726 fun lift_proof Bi inc prop prf =
   727   let
   728     fun lift'' Us Ts t =
   729       strip_abs Ts (Logic.incr_indexes (Us, inc) (mk_abs Ts t));
   730 
   731     fun lift' Us Ts (Abst (s, T, prf)) =
   732           (Abst (s, Same.map_option (Logic.incr_tvar_same inc) T, lifth' Us (dummyT::Ts) prf)
   733            handle Same.SAME => Abst (s, T, lift' Us (dummyT::Ts) prf))
   734       | lift' Us Ts (AbsP (s, t, prf)) =
   735           (AbsP (s, Same.map_option (same (op =) (lift'' Us Ts)) t, lifth' Us Ts prf)
   736            handle Same.SAME => AbsP (s, t, lift' Us Ts prf))
   737       | lift' Us Ts (prf % t) = (lift' Us Ts prf % Option.map (lift'' Us Ts) t
   738           handle Same.SAME => prf % Same.map_option (same (op =) (lift'' Us Ts)) t)
   739       | lift' Us Ts (prf1 %% prf2) = (lift' Us Ts prf1 %% lifth' Us Ts prf2
   740           handle Same.SAME => prf1 %% lift' Us Ts prf2)
   741       | lift' _ _ (PAxm (s, prop, Ts)) =
   742           PAxm (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   743       | lift' _ _ (OfClass (T, c)) =
   744           OfClass (Logic.incr_tvar_same inc T, c)
   745       | lift' _ _ (Oracle (s, prop, Ts)) =
   746           Oracle (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   747       | lift' _ _ (Promise (i, prop, Ts)) =
   748           Promise (i, prop, Same.map (Logic.incr_tvar_same inc) Ts)
   749       | lift' _ _ (PThm (i, ((s, prop, Ts), body))) =
   750           PThm (i, ((s, prop, (Same.map_option o Same.map) (Logic.incr_tvar inc) Ts), body))
   751       | lift' _ _ _ = raise Same.SAME
   752     and lifth' Us Ts prf = (lift' Us Ts prf handle Same.SAME => prf);
   753 
   754     val ps = map (Logic.lift_all inc Bi) (Logic.strip_imp_prems prop);
   755     val k = length ps;
   756 
   757     fun mk_app b (i, j, prf) =
   758           if b then (i-1, j, prf %% PBound i) else (i, j-1, prf %> Bound j);
   759 
   760     fun lift Us bs i j (Const ("==>", _) $ A $ B) =
   761             AbsP ("H", NONE (*A*), lift Us (true::bs) (i+1) j B)
   762       | lift Us bs i j (Const ("all", _) $ Abs (a, T, t)) =
   763             Abst (a, NONE (*T*), lift (T::Us) (false::bs) i (j+1) t)
   764       | lift Us bs i j _ = proof_combP (lifth' (rev Us) [] prf,
   765             map (fn k => (#3 (fold_rev mk_app bs (i-1, j-1, PBound k))))
   766               (i + k - 1 downto i));
   767   in
   768     mk_AbsP (k, lift [] [] 0 0 Bi)
   769   end;
   770 
   771 fun incr_indexes i =
   772   Same.commit (map_proof_terms_same
   773     (Logic.incr_indexes_same ([], i)) (Logic.incr_tvar_same i));
   774 
   775 
   776 (***** proof by assumption *****)
   777 
   778 fun mk_asm_prf t i m =
   779   let
   780     fun imp_prf _ i 0 = PBound i
   781       | imp_prf (Const ("==>", _) $ A $ B) i m = AbsP ("H", NONE (*A*), imp_prf B (i+1) (m-1))
   782       | imp_prf _ i _ = PBound i;
   783     fun all_prf (Const ("all", _) $ Abs (a, T, t)) = Abst (a, NONE (*T*), all_prf t)
   784       | all_prf t = imp_prf t (~i) m
   785   in all_prf t end;
   786 
   787 fun assumption_proof Bs Bi n prf =
   788   mk_AbsP (length Bs, proof_combP (prf,
   789     map PBound (length Bs - 1 downto 0) @ [mk_asm_prf Bi n ~1]));
   790 
   791 
   792 (***** Composition of object rule with proof state *****)
   793 
   794 fun flatten_params_proof i j n (Const ("==>", _) $ A $ B, k) =
   795       AbsP ("H", NONE (*A*), flatten_params_proof (i+1) j n (B, k))
   796   | flatten_params_proof i j n (Const ("all", _) $ Abs (a, T, t), k) =
   797       Abst (a, NONE (*T*), flatten_params_proof i (j+1) n (t, k))
   798   | flatten_params_proof i j n (_, k) = proof_combP (proof_combt (PBound (k+i),
   799       map Bound (j-1 downto 0)), map PBound (remove (op =) (i-n) (i-1 downto 0)));
   800 
   801 fun bicompose_proof flatten Bs oldAs newAs A n m rprf sprf =
   802   let
   803     val la = length newAs;
   804     val lb = length Bs;
   805   in
   806     mk_AbsP (lb+la, proof_combP (sprf,
   807       map PBound (lb + la - 1 downto la)) %%
   808         proof_combP (rprf, (if n>0 then [mk_asm_prf (the A) n m] else []) @
   809           map (if flatten then flatten_params_proof 0 0 n else PBound o snd)
   810             (oldAs ~~ (la - 1 downto 0))))
   811   end;
   812 
   813 
   814 (***** axioms for equality *****)
   815 
   816 val aT = TFree ("'a", []);
   817 val bT = TFree ("'b", []);
   818 val x = Free ("x", aT);
   819 val y = Free ("y", aT);
   820 val z = Free ("z", aT);
   821 val A = Free ("A", propT);
   822 val B = Free ("B", propT);
   823 val f = Free ("f", aT --> bT);
   824 val g = Free ("g", aT --> bT);
   825 
   826 val equality_axms =
   827  [("reflexive", Logic.mk_equals (x, x)),
   828   ("symmetric", Logic.mk_implies (Logic.mk_equals (x, y), Logic.mk_equals (y, x))),
   829   ("transitive",
   830     Logic.list_implies ([Logic.mk_equals (x, y), Logic.mk_equals (y, z)], Logic.mk_equals (x, z))),
   831   ("equal_intr",
   832     Logic.list_implies ([Logic.mk_implies (A, B), Logic.mk_implies (B, A)], Logic.mk_equals (A, B))),
   833   ("equal_elim", Logic.list_implies ([Logic.mk_equals (A, B), A], B)),
   834   ("abstract_rule",
   835     Logic.mk_implies
   836       (Logic.all x
   837         (Logic.mk_equals (f $ x, g $ x)), Logic.mk_equals (lambda x (f $ x), lambda x (g $ x)))),
   838   ("combination", Logic.list_implies
   839     ([Logic.mk_equals (f, g), Logic.mk_equals (x, y)], Logic.mk_equals (f $ x, g $ y)))];
   840 
   841 val [reflexive_axm, symmetric_axm, transitive_axm, equal_intr_axm,
   842   equal_elim_axm, abstract_rule_axm, combination_axm] =
   843     map (fn (s, t) => PAxm ("Pure." ^ s, Logic.varify_global t, NONE)) equality_axms;
   844 
   845 val reflexive = reflexive_axm % NONE;
   846 
   847 fun symmetric (prf as PAxm ("Pure.reflexive", _, _) % _) = prf
   848   | symmetric prf = symmetric_axm % NONE % NONE %% prf;
   849 
   850 fun transitive _ _ (PAxm ("Pure.reflexive", _, _) % _) prf2 = prf2
   851   | transitive _ _ prf1 (PAxm ("Pure.reflexive", _, _) % _) = prf1
   852   | transitive u (Type ("prop", [])) prf1 prf2 =
   853       transitive_axm % NONE % SOME (remove_types u) % NONE %% prf1 %% prf2
   854   | transitive u T prf1 prf2 =
   855       transitive_axm % NONE % NONE % NONE %% prf1 %% prf2;
   856 
   857 fun abstract_rule x a prf =
   858   abstract_rule_axm % NONE % NONE %% forall_intr_proof x a prf;
   859 
   860 fun check_comb (PAxm ("Pure.combination", _, _) % f % g % _ % _ %% prf %% _) =
   861       is_some f orelse check_comb prf
   862   | check_comb (PAxm ("Pure.transitive", _, _) % _ % _ % _ %% prf1 %% prf2) =
   863       check_comb prf1 andalso check_comb prf2
   864   | check_comb (PAxm ("Pure.symmetric", _, _) % _ % _ %% prf) = check_comb prf
   865   | check_comb _ = false;
   866 
   867 fun combination f g t u (Type (_, [T, U])) prf1 prf2 =
   868   let
   869     val f = Envir.beta_norm f;
   870     val g = Envir.beta_norm g;
   871     val prf =  if check_comb prf1 then
   872         combination_axm % NONE % NONE
   873       else (case prf1 of
   874           PAxm ("Pure.reflexive", _, _) % _ =>
   875             combination_axm %> remove_types f % NONE
   876         | _ => combination_axm %> remove_types f %> remove_types g)
   877   in
   878     (case T of
   879        Type ("fun", _) => prf %
   880          (case head_of f of
   881             Abs _ => SOME (remove_types t)
   882           | Var _ => SOME (remove_types t)
   883           | _ => NONE) %
   884          (case head_of g of
   885             Abs _ => SOME (remove_types u)
   886           | Var _ => SOME (remove_types u)
   887           | _ => NONE) %% prf1 %% prf2
   888      | _ => prf % NONE % NONE %% prf1 %% prf2)
   889   end;
   890 
   891 fun equal_intr A B prf1 prf2 =
   892   equal_intr_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   893 
   894 fun equal_elim A B prf1 prf2 =
   895   equal_elim_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   896 
   897 
   898 (**** type classes ****)
   899 
   900 fun strip_shyps_proof algebra present witnessed extra_sorts prf =
   901   let
   902     fun get S2 (T, S1) = if Sorts.sort_le algebra (S1, S2) then SOME T else NONE;
   903     val extra = map (fn S => (TFree ("'dummy", S), S)) extra_sorts;
   904     val replacements = present @ extra @ witnessed;
   905     fun replace T =
   906       if exists (fn (T', _) => T' = T) present then raise Same.SAME
   907       else
   908         (case get_first (get (Type.sort_of_atyp T)) replacements of
   909           SOME T' => T'
   910         | NONE => raise Fail "strip_shyps_proof: bad type variable in proof term");
   911   in Same.commit (map_proof_types_same (Term_Subst.map_atypsT_same replace)) prf end;
   912 
   913 
   914 local
   915 
   916 type axclass_proofs =
   917  {classrel_proof: theory -> class * class -> proof,
   918   arity_proof: theory -> string * sort list * class -> proof};
   919 
   920 val axclass_proofs: axclass_proofs Single_Assignment.var =
   921   Single_Assignment.var "Proofterm.axclass_proofs";
   922 
   923 fun axclass_proof which thy x =
   924   (case Single_Assignment.peek axclass_proofs of
   925     NONE => raise Fail "Axclass proof operations not installed"
   926   | SOME prfs => which prfs thy x);
   927 
   928 in
   929 
   930 val classrel_proof = axclass_proof #classrel_proof;
   931 val arity_proof = axclass_proof #arity_proof;
   932 
   933 fun install_axclass_proofs prfs = Single_Assignment.assign axclass_proofs prfs;
   934 
   935 end;
   936 
   937 
   938 local
   939 
   940 fun canonical_instance typs =
   941   let
   942     val names = Name.invents Name.context Name.aT (length typs);
   943     val instT = map2 (fn a => fn T => (((a, 0), []), Type.strip_sorts T)) names typs;
   944   in instantiate (instT, []) end;
   945 
   946 in
   947 
   948 fun of_sort_proof thy hyps =
   949   Sorts.of_sort_derivation (Sign.classes_of thy)
   950    {class_relation = fn typ => fn (prf, c1) => fn c2 =>
   951       if c1 = c2 then prf
   952       else canonical_instance [typ] (classrel_proof thy (c1, c2)) %% prf,
   953     type_constructor = fn (a, typs) => fn dom => fn c =>
   954       let val Ss = map (map snd) dom and prfs = maps (map fst) dom
   955       in proof_combP (canonical_instance typs (arity_proof thy (a, Ss, c)), prfs) end,
   956     type_variable = fn typ => map (fn c => (hyps (typ, c), c)) (Type.sort_of_atyp typ)};
   957 
   958 end;
   959 
   960 
   961 (***** axioms and theorems *****)
   962 
   963 val proofs = Unsynchronized.ref 2;
   964 
   965 fun vars_of t = map Var (rev (Term.add_vars t []));
   966 fun frees_of t = map Free (rev (Term.add_frees t []));
   967 
   968 fun test_args _ [] = true
   969   | test_args is (Bound i :: ts) =
   970       not (member (op =) is i) andalso test_args (i :: is) ts
   971   | test_args _ _ = false;
   972 
   973 fun is_fun (Type ("fun", _)) = true
   974   | is_fun (TVar _) = true
   975   | is_fun _ = false;
   976 
   977 fun add_funvars Ts (vs, t) =
   978   if is_fun (fastype_of1 (Ts, t)) then
   979     union (op =) vs (map_filter (fn Var (ixn, T) =>
   980       if is_fun T then SOME ixn else NONE | _ => NONE) (vars_of t))
   981   else vs;
   982 
   983 fun add_npvars q p Ts (vs, Const ("==>", _) $ t $ u) =
   984       add_npvars q p Ts (add_npvars q (not p) Ts (vs, t), u)
   985   | add_npvars q p Ts (vs, Const ("all", Type (_, [Type (_, [T, _]), _])) $ t) =
   986       add_npvars q p Ts (vs, if p andalso q then betapply (t, Var (("",0), T)) else t)
   987   | add_npvars q p Ts (vs, Abs (_, T, t)) = add_npvars q p (T::Ts) (vs, t)
   988   | add_npvars _ _ Ts (vs, t) = add_npvars' Ts (vs, t)
   989 and add_npvars' Ts (vs, t) = (case strip_comb t of
   990     (Var (ixn, _), ts) => if test_args [] ts then vs
   991       else Library.foldl (add_npvars' Ts)
   992         (AList.update (op =) (ixn,
   993           Library.foldl (add_funvars Ts) ((these ooo AList.lookup) (op =) vs ixn, ts)) vs, ts)
   994   | (Abs (_, T, u), ts) => Library.foldl (add_npvars' (T::Ts)) (vs, u :: ts)
   995   | (_, ts) => Library.foldl (add_npvars' Ts) (vs, ts));
   996 
   997 fun prop_vars (Const ("==>", _) $ P $ Q) = union (op =) (prop_vars P) (prop_vars Q)
   998   | prop_vars (Const ("all", _) $ Abs (_, _, t)) = prop_vars t
   999   | prop_vars t = (case strip_comb t of
  1000       (Var (ixn, _), _) => [ixn] | _ => []);
  1001 
  1002 fun is_proj t =
  1003   let
  1004     fun is_p i t = (case strip_comb t of
  1005         (Bound j, []) => false
  1006       | (Bound j, ts) => j >= i orelse exists (is_p i) ts
  1007       | (Abs (_, _, u), _) => is_p (i+1) u
  1008       | (_, ts) => exists (is_p i) ts)
  1009   in (case strip_abs_body t of
  1010         Bound _ => true
  1011       | t' => is_p 0 t')
  1012   end;
  1013 
  1014 fun needed_vars prop =
  1015   union (op =) (Library.foldl (uncurry (union (op =)))
  1016     ([], map (uncurry (insert (op =))) (add_npvars true true [] ([], prop))))
  1017   (prop_vars prop);
  1018 
  1019 fun gen_axm_proof c name prop =
  1020   let
  1021     val nvs = needed_vars prop;
  1022     val args = map (fn (v as Var (ixn, _)) =>
  1023         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1024       map SOME (frees_of prop);
  1025   in
  1026     proof_combt' (c (name, prop, NONE), args)
  1027   end;
  1028 
  1029 val axm_proof = gen_axm_proof PAxm;
  1030 
  1031 val dummy = Const (Term.dummy_patternN, dummyT);
  1032 
  1033 fun oracle_proof name prop =
  1034   if ! proofs = 0 then ((name, dummy), Oracle (name, dummy, NONE))
  1035   else ((name, prop), gen_axm_proof Oracle name prop);
  1036 
  1037 val shrink_proof =
  1038   let
  1039     fun shrink ls lev (prf as Abst (a, T, body)) =
  1040           let val (b, is, ch, body') = shrink ls (lev+1) body
  1041           in (b, is, ch, if ch then Abst (a, T, body') else prf) end
  1042       | shrink ls lev (prf as AbsP (a, t, body)) =
  1043           let val (b, is, ch, body') = shrink (lev::ls) lev body
  1044           in (b orelse member (op =) is 0, map_filter (fn 0 => NONE | i => SOME (i-1)) is,
  1045             ch, if ch then AbsP (a, t, body') else prf)
  1046           end
  1047       | shrink ls lev prf =
  1048           let val (is, ch, _, prf') = shrink' ls lev [] [] prf
  1049           in (false, is, ch, prf') end
  1050     and shrink' ls lev ts prfs (prf as prf1 %% prf2) =
  1051           let
  1052             val p as (_, is', ch', prf') = shrink ls lev prf2;
  1053             val (is, ch, ts', prf'') = shrink' ls lev ts (p::prfs) prf1
  1054           in (union (op =) is is', ch orelse ch', ts',
  1055               if ch orelse ch' then prf'' %% prf' else prf)
  1056           end
  1057       | shrink' ls lev ts prfs (prf as prf1 % t) =
  1058           let val (is, ch, (ch', t')::ts', prf') = shrink' ls lev (t::ts) prfs prf1
  1059           in (is, ch orelse ch', ts',
  1060               if ch orelse ch' then prf' % t' else prf) end
  1061       | shrink' ls lev ts prfs (prf as PBound i) =
  1062           (if exists (fn SOME (Bound j) => lev-j <= nth ls i | _ => true) ts
  1063              orelse has_duplicates (op =)
  1064                (Library.foldl (fn (js, SOME (Bound j)) => j :: js | (js, _) => js) ([], ts))
  1065              orelse exists #1 prfs then [i] else [], false, map (pair false) ts, prf)
  1066       | shrink' ls lev ts prfs (prf as Hyp _) = ([], false, map (pair false) ts, prf)
  1067       | shrink' ls lev ts prfs (prf as MinProof) = ([], false, map (pair false) ts, prf)
  1068       | shrink' ls lev ts prfs (prf as OfClass _) = ([], false, map (pair false) ts, prf)
  1069       | shrink' ls lev ts prfs prf =
  1070           let
  1071             val prop =
  1072               (case prf of
  1073                 PAxm (_, prop, _) => prop
  1074               | Oracle (_, prop, _) => prop
  1075               | Promise (_, prop, _) => prop
  1076               | PThm (_, ((_, prop, _), _)) => prop
  1077               | _ => error "shrink: proof not in normal form");
  1078             val vs = vars_of prop;
  1079             val (ts', ts'') = chop (length vs) ts;
  1080             val insts = take (length ts') (map (fst o dest_Var) vs) ~~ ts';
  1081             val nvs = Library.foldl (fn (ixns', (ixn, ixns)) =>
  1082               insert (op =) ixn (case AList.lookup (op =) insts ixn of
  1083                   SOME (SOME t) => if is_proj t then union (op =) ixns ixns' else ixns'
  1084                 | _ => union (op =) ixns ixns'))
  1085                   (needed prop ts'' prfs, add_npvars false true [] ([], prop));
  1086             val insts' = map
  1087               (fn (ixn, x as SOME _) => if member (op =) nvs ixn then (false, x) else (true, NONE)
  1088                 | (_, x) => (false, x)) insts
  1089           in ([], false, insts' @ map (pair false) ts'', prf) end
  1090     and needed (Const ("==>", _) $ t $ u) ts ((b, _, _, _)::prfs) =
  1091           union (op =) (if b then map (fst o dest_Var) (vars_of t) else []) (needed u ts prfs)
  1092       | needed (Var (ixn, _)) (_::_) _ = [ixn]
  1093       | needed _ _ _ = [];
  1094   in shrink end;
  1095 
  1096 
  1097 (**** Simple first order matching functions for terms and proofs ****)
  1098 
  1099 exception PMatch;
  1100 
  1101 (** see pattern.ML **)
  1102 
  1103 fun flt (i: int) = filter (fn n => n < i);
  1104 
  1105 fun fomatch Ts tymatch j =
  1106   let
  1107     fun mtch (instsp as (tyinsts, insts)) = fn
  1108         (Var (ixn, T), t)  =>
  1109           if j>0 andalso not (null (flt j (loose_bnos t)))
  1110           then raise PMatch
  1111           else (tymatch (tyinsts, fn () => (T, fastype_of1 (Ts, t))),
  1112             (ixn, t) :: insts)
  1113       | (Free (a, T), Free (b, U)) =>
  1114           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1115       | (Const (a, T), Const (b, U))  =>
  1116           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1117       | (f $ t, g $ u) => mtch (mtch instsp (f, g)) (t, u)
  1118       | (Bound i, Bound j) => if i=j then instsp else raise PMatch
  1119       | _ => raise PMatch
  1120   in mtch end;
  1121 
  1122 fun match_proof Ts tymatch =
  1123   let
  1124     fun optmatch _ inst (NONE, _) = inst
  1125       | optmatch _ _ (SOME _, NONE) = raise PMatch
  1126       | optmatch mtch inst (SOME x, SOME y) = mtch inst (x, y)
  1127 
  1128     fun matcht Ts j (pinst, tinst) (t, u) =
  1129       (pinst, fomatch Ts tymatch j tinst (t, Envir.beta_norm u));
  1130     fun matchT (pinst, (tyinsts, insts)) p =
  1131       (pinst, (tymatch (tyinsts, K p), insts));
  1132     fun matchTs inst (Ts, Us) = Library.foldl (uncurry matchT) (inst, Ts ~~ Us);
  1133 
  1134     fun mtch Ts i j (pinst, tinst) (Hyp (Var (ixn, _)), prf) =
  1135           if i = 0 andalso j = 0 then ((ixn, prf) :: pinst, tinst)
  1136           else (case apfst (flt i) (apsnd (flt j)
  1137                   (prf_add_loose_bnos 0 0 prf ([], []))) of
  1138               ([], []) => ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1139             | ([], _) => if j = 0 then
  1140                    ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1141                  else raise PMatch
  1142             | _ => raise PMatch)
  1143       | mtch Ts i j inst (prf1 % opt1, prf2 % opt2) =
  1144           optmatch (matcht Ts j) (mtch Ts i j inst (prf1, prf2)) (opt1, opt2)
  1145       | mtch Ts i j inst (prf1 %% prf2, prf1' %% prf2') =
  1146           mtch Ts i j (mtch Ts i j inst (prf1, prf1')) (prf2, prf2')
  1147       | mtch Ts i j inst (Abst (_, opT, prf1), Abst (_, opU, prf2)) =
  1148           mtch (the_default dummyT opU :: Ts) i (j+1)
  1149             (optmatch matchT inst (opT, opU)) (prf1, prf2)
  1150       | mtch Ts i j inst (prf1, Abst (_, opU, prf2)) =
  1151           mtch (the_default dummyT opU :: Ts) i (j+1) inst
  1152             (incr_pboundvars 0 1 prf1 %> Bound 0, prf2)
  1153       | mtch Ts i j inst (AbsP (_, opt, prf1), AbsP (_, opu, prf2)) =
  1154           mtch Ts (i+1) j (optmatch (matcht Ts j) inst (opt, opu)) (prf1, prf2)
  1155       | mtch Ts i j inst (prf1, AbsP (_, _, prf2)) =
  1156           mtch Ts (i+1) j inst (incr_pboundvars 1 0 prf1 %% PBound 0, prf2)
  1157       | mtch Ts i j inst (PAxm (s1, _, opTs), PAxm (s2, _, opUs)) =
  1158           if s1 = s2 then optmatch matchTs inst (opTs, opUs)
  1159           else raise PMatch
  1160       | mtch Ts i j inst (OfClass (T1, c1), OfClass (T2, c2)) =
  1161           if c1 = c2 then matchT inst (T1, T2)
  1162           else raise PMatch
  1163       | mtch Ts i j inst (PThm (_, ((name1, prop1, opTs), _)), PThm (_, ((name2, prop2, opUs), _))) =
  1164           if name1 = name2 andalso prop1 = prop2 then
  1165             optmatch matchTs inst (opTs, opUs)
  1166           else raise PMatch
  1167       | mtch _ _ _ inst (PBound i, PBound j) = if i = j then inst else raise PMatch
  1168       | mtch _ _ _ _ _ = raise PMatch
  1169   in mtch Ts 0 0 end;
  1170 
  1171 fun prf_subst (pinst, (tyinsts, insts)) =
  1172   let
  1173     val substT = Envir.subst_type_same tyinsts;
  1174     val substTs = Same.map substT;
  1175 
  1176     fun subst' lev (Var (xi, _)) =
  1177         (case AList.lookup (op =) insts xi of
  1178           NONE => raise Same.SAME
  1179         | SOME u => incr_boundvars lev u)
  1180       | subst' _ (Const (s, T)) = Const (s, substT T)
  1181       | subst' _ (Free (s, T)) = Free (s, substT T)
  1182       | subst' lev (Abs (a, T, body)) =
  1183           (Abs (a, substT T, Same.commit (subst' (lev + 1)) body)
  1184             handle Same.SAME => Abs (a, T, subst' (lev + 1) body))
  1185       | subst' lev (f $ t) =
  1186           (subst' lev f $ Same.commit (subst' lev) t
  1187             handle Same.SAME => f $ subst' lev t)
  1188       | subst' _ _ = raise Same.SAME;
  1189 
  1190     fun subst plev tlev (AbsP (a, t, body)) =
  1191           (AbsP (a, Same.map_option (subst' tlev) t, Same.commit (subst (plev + 1) tlev) body)
  1192             handle Same.SAME => AbsP (a, t, subst (plev + 1) tlev body))
  1193       | subst plev tlev (Abst (a, T, body)) =
  1194           (Abst (a, Same.map_option substT T, Same.commit (subst plev (tlev + 1)) body)
  1195             handle Same.SAME => Abst (a, T, subst plev (tlev + 1) body))
  1196       | subst plev tlev (prf %% prf') =
  1197           (subst plev tlev prf %% Same.commit (subst plev tlev) prf'
  1198             handle Same.SAME => prf %% subst plev tlev prf')
  1199       | subst plev tlev (prf % t) =
  1200           (subst plev tlev prf % Same.commit (Same.map_option (subst' tlev)) t
  1201             handle Same.SAME => prf % Same.map_option (subst' tlev) t)
  1202       | subst plev tlev (Hyp (Var (xi, _))) =
  1203           (case AList.lookup (op =) pinst xi of
  1204             NONE => raise Same.SAME
  1205           | SOME prf' => incr_pboundvars plev tlev prf')
  1206       | subst _ _ (PAxm (id, prop, Ts)) = PAxm (id, prop, Same.map_option substTs Ts)
  1207       | subst _ _ (OfClass (T, c)) = OfClass (substT T, c)
  1208       | subst _ _ (Oracle (id, prop, Ts)) = Oracle (id, prop, Same.map_option substTs Ts)
  1209       | subst _ _ (Promise (i, prop, Ts)) = Promise (i, prop, substTs Ts)
  1210       | subst _ _ (PThm (i, ((id, prop, Ts), body))) =
  1211           PThm (i, ((id, prop, Same.map_option substTs Ts), body))
  1212       | subst _ _ _ = raise Same.SAME;
  1213   in fn t => subst 0 0 t handle Same.SAME => t end;
  1214 
  1215 (*A fast unification filter: true unless the two terms cannot be unified.
  1216   Terms must be NORMAL.  Treats all Vars as distinct. *)
  1217 fun could_unify prf1 prf2 =
  1218   let
  1219     fun matchrands (prf1 %% prf2) (prf1' %% prf2') =
  1220           could_unify prf2 prf2' andalso matchrands prf1 prf1'
  1221       | matchrands (prf % SOME t) (prf' % SOME t') =
  1222           Term.could_unify (t, t') andalso matchrands prf prf'
  1223       | matchrands (prf % _) (prf' % _) = matchrands prf prf'
  1224       | matchrands _ _ = true
  1225 
  1226     fun head_of (prf %% _) = head_of prf
  1227       | head_of (prf % _) = head_of prf
  1228       | head_of prf = prf
  1229 
  1230   in case (head_of prf1, head_of prf2) of
  1231         (_, Hyp (Var _)) => true
  1232       | (Hyp (Var _), _) => true
  1233       | (PAxm (a, _, _), PAxm (b, _, _)) => a = b andalso matchrands prf1 prf2
  1234       | (OfClass (_, c), OfClass (_, d)) => c = d andalso matchrands prf1 prf2
  1235       | (PThm (_, ((a, propa, _), _)), PThm (_, ((b, propb, _), _))) =>
  1236           a = b andalso propa = propb andalso matchrands prf1 prf2
  1237       | (PBound i, PBound j) => i = j andalso matchrands prf1 prf2
  1238       | (AbsP _, _) =>  true   (*because of possible eta equality*)
  1239       | (Abst _, _) =>  true
  1240       | (_, AbsP _) =>  true
  1241       | (_, Abst _) =>  true
  1242       | _ => false
  1243   end;
  1244 
  1245 
  1246 (**** rewriting on proof terms ****)
  1247 
  1248 val no_skel = PBound 0;
  1249 val normal_skel = Hyp (Var ((Name.uu, 0), propT));
  1250 
  1251 fun rewrite_prf tymatch (rules, procs) prf =
  1252   let
  1253     fun rew _ (Abst (_, _, body) % SOME t) = SOME (prf_subst_bounds [t] body, no_skel)
  1254       | rew _ (AbsP (_, _, body) %% prf) = SOME (prf_subst_pbounds [prf] body, no_skel)
  1255       | rew Ts prf =
  1256           (case get_first (fn r => r Ts prf) procs of
  1257             NONE => get_first (fn (prf1, prf2) => SOME (prf_subst
  1258               (match_proof Ts tymatch ([], (Vartab.empty, [])) (prf1, prf)) prf2, prf2)
  1259                  handle PMatch => NONE) (filter (could_unify prf o fst) rules)
  1260           | some => some);
  1261 
  1262     fun rew0 Ts (prf as AbsP (_, _, prf' %% PBound 0)) =
  1263           if prf_loose_Pbvar1 prf' 0 then rew Ts prf
  1264           else
  1265             let val prf'' = incr_pboundvars (~1) 0 prf'
  1266             in SOME (the_default (prf'', no_skel) (rew Ts prf'')) end
  1267       | rew0 Ts (prf as Abst (_, _, prf' % SOME (Bound 0))) =
  1268           if prf_loose_bvar1 prf' 0 then rew Ts prf
  1269           else
  1270             let val prf'' = incr_pboundvars 0 (~1) prf'
  1271             in SOME (the_default (prf'', no_skel) (rew Ts prf'')) end
  1272       | rew0 Ts prf = rew Ts prf;
  1273 
  1274     fun rew1 _ (Hyp (Var _)) _ = NONE
  1275       | rew1 Ts skel prf = (case rew2 Ts skel prf of
  1276           SOME prf1 => (case rew0 Ts prf1 of
  1277               SOME (prf2, skel') => SOME (the_default prf2 (rew1 Ts skel' prf2))
  1278             | NONE => SOME prf1)
  1279         | NONE => (case rew0 Ts prf of
  1280               SOME (prf1, skel') => SOME (the_default prf1 (rew1 Ts skel' prf1))
  1281             | NONE => NONE))
  1282 
  1283     and rew2 Ts skel (prf % SOME t) = (case prf of
  1284             Abst (_, _, body) =>
  1285               let val prf' = prf_subst_bounds [t] body
  1286               in SOME (the_default prf' (rew2 Ts no_skel prf')) end
  1287           | _ => (case rew1 Ts (case skel of skel' % _ => skel' | _ => no_skel) prf of
  1288               SOME prf' => SOME (prf' % SOME t)
  1289             | NONE => NONE))
  1290       | rew2 Ts skel (prf % NONE) = Option.map (fn prf' => prf' % NONE)
  1291           (rew1 Ts (case skel of skel' % _ => skel' | _ => no_skel) prf)
  1292       | rew2 Ts skel (prf1 %% prf2) = (case prf1 of
  1293             AbsP (_, _, body) =>
  1294               let val prf' = prf_subst_pbounds [prf2] body
  1295               in SOME (the_default prf' (rew2 Ts no_skel prf')) end
  1296           | _ =>
  1297             let val (skel1, skel2) = (case skel of
  1298                 skel1 %% skel2 => (skel1, skel2)
  1299               | _ => (no_skel, no_skel))
  1300             in case rew1 Ts skel1 prf1 of
  1301                 SOME prf1' => (case rew1 Ts skel2 prf2 of
  1302                     SOME prf2' => SOME (prf1' %% prf2')
  1303                   | NONE => SOME (prf1' %% prf2))
  1304               | NONE => (case rew1 Ts skel2 prf2 of
  1305                     SOME prf2' => SOME (prf1 %% prf2')
  1306                   | NONE => NONE)
  1307             end)
  1308       | rew2 Ts skel (Abst (s, T, prf)) = (case rew1 (the_default dummyT T :: Ts)
  1309               (case skel of Abst (_, _, skel') => skel' | _ => no_skel) prf of
  1310             SOME prf' => SOME (Abst (s, T, prf'))
  1311           | NONE => NONE)
  1312       | rew2 Ts skel (AbsP (s, t, prf)) = (case rew1 Ts
  1313               (case skel of AbsP (_, _, skel') => skel' | _ => no_skel) prf of
  1314             SOME prf' => SOME (AbsP (s, t, prf'))
  1315           | NONE => NONE)
  1316       | rew2 _ _ _ = NONE;
  1317 
  1318   in the_default prf (rew1 [] no_skel prf) end;
  1319 
  1320 fun rewrite_proof thy = rewrite_prf (fn (tyenv, f) =>
  1321   Sign.typ_match thy (f ()) tyenv handle Type.TYPE_MATCH => raise PMatch);
  1322 
  1323 fun rewrite_proof_notypes rews = rewrite_prf fst rews;
  1324 
  1325 
  1326 (**** theory data ****)
  1327 
  1328 structure ProofData = Theory_Data
  1329 (
  1330   type T =
  1331     (stamp * (proof * proof)) list *
  1332     (stamp * (typ list -> proof -> (proof * proof) option)) list;
  1333 
  1334   val empty = ([], []);
  1335   val extend = I;
  1336   fun merge ((rules1, procs1), (rules2, procs2)) : T =
  1337     (AList.merge (op =) (K true) (rules1, rules2),
  1338       AList.merge (op =) (K true) (procs1, procs2));
  1339 );
  1340 
  1341 fun get_data thy = let val (rules, procs) = ProofData.get thy in (map #2 rules, map #2 procs) end;
  1342 fun rew_proof thy = rewrite_prf fst (get_data thy);
  1343 
  1344 fun add_prf_rrule r = (ProofData.map o apfst) (cons (stamp (), r));
  1345 fun add_prf_rproc p = (ProofData.map o apsnd) (cons (stamp (), p));
  1346 
  1347 
  1348 (***** promises *****)
  1349 
  1350 fun promise_proof thy i prop =
  1351   let
  1352     val _ = prop |> Term.exists_subterm (fn t =>
  1353       (Term.is_Free t orelse Term.is_Var t) andalso
  1354         error ("promise_proof: illegal variable " ^ Syntax.string_of_term_global thy t));
  1355     val _ = prop |> Term.exists_type (Term.exists_subtype
  1356       (fn TFree (a, _) => error ("promise_proof: illegal type variable " ^ quote a)
  1357         | _ => false));
  1358   in Promise (i, prop, map TVar (Term.add_tvars prop [])) end;
  1359 
  1360 fun fulfill_norm_proof thy ps body0 =
  1361   let
  1362     val PBody {oracles = oracles0, thms = thms0, proof = proof0} = body0;
  1363     val oracles = fold (fn (_, PBody {oracles, ...}) => merge_oracles oracles) ps oracles0;
  1364     val thms = fold (fn (_, PBody {thms, ...}) => merge_thms thms) ps thms0;
  1365     val proofs = fold (fn (i, PBody {proof, ...}) => Inttab.update (i, proof)) ps Inttab.empty;
  1366 
  1367     fun fill (Promise (i, prop, Ts)) =
  1368           (case Inttab.lookup proofs i of
  1369             NONE => NONE
  1370           | SOME prf => SOME (instantiate (Term.add_tvars prop [] ~~ Ts, []) prf, normal_skel))
  1371       | fill _ = NONE;
  1372     val (rules, procs) = get_data thy;
  1373     val proof = rewrite_prf fst (rules, K fill :: procs) proof0;
  1374   in PBody {oracles = oracles, thms = thms, proof = proof} end;
  1375 
  1376 fun fulfill_proof_future _ [] body = Future.value body
  1377   | fulfill_proof_future thy promises body =
  1378       Future.fork_deps (map snd promises) (fn () =>
  1379         fulfill_norm_proof thy (map (apsnd Future.join) promises) body);
  1380 
  1381 
  1382 (***** theorems *****)
  1383 
  1384 fun thm_proof thy name hyps concl promises body =
  1385   let
  1386     val PBody {oracles = oracles0, thms = thms0, proof = prf} = body;
  1387     val prop = Logic.list_implies (hyps, concl);
  1388     val nvs = needed_vars prop;
  1389     val args = map (fn (v as Var (ixn, _)) =>
  1390         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1391       map SOME (frees_of prop);
  1392 
  1393     val proof0 =
  1394       if ! proofs = 2 then
  1395         #4 (shrink_proof [] 0 (rew_proof thy (fold_rev implies_intr_proof hyps prf)))
  1396       else MinProof;
  1397     val body0 = PBody {oracles = oracles0, thms = thms0, proof = proof0};
  1398 
  1399     fun new_prf () = (serial (), name, prop, fulfill_proof_future thy promises body0);
  1400     val (i, name, prop, body') =
  1401       (case strip_combt (fst (strip_combP prf)) of
  1402         (PThm (i, ((old_name, prop', NONE), body')), args') =>
  1403           if (old_name = "" orelse old_name = name) andalso prop = prop' andalso args = args'
  1404           then (i, name, prop, body')
  1405           else new_prf ()
  1406       | _ => new_prf ());
  1407     val head = PThm (i, ((name, prop, NONE), body'));
  1408   in
  1409     ((i, (name, prop, body')), proof_combP (proof_combt' (head, args), map Hyp hyps))
  1410   end;
  1411 
  1412 fun get_name hyps prop prf =
  1413   let val prop = Logic.list_implies (hyps, prop) in
  1414     (case strip_combt (fst (strip_combP prf)) of
  1415       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1416     | _ => "")
  1417   end;
  1418 
  1419 fun get_name_unconstrained shyps hyps prop prf =
  1420   let val (_, prop) = Logic.unconstrainT shyps (Logic.list_implies (hyps, prop)) in
  1421     (case strip_combt (fst (strip_combP prf)) of
  1422       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1423     | _ => "")
  1424   end;
  1425 
  1426 fun guess_name (PThm (_, ((name, _, _), _))) = name
  1427   | guess_name (prf %% Hyp _) = guess_name prf
  1428   | guess_name (prf %% OfClass _) = guess_name prf
  1429   | guess_name (prf % NONE) = guess_name prf
  1430   | guess_name (prf % SOME (Var _)) = guess_name prf
  1431   | guess_name _ = "";
  1432 
  1433 end;
  1434 
  1435 structure Basic_Proofterm : BASIC_PROOFTERM = Proofterm;
  1436 open Basic_Proofterm;