src/Pure/PIDE/command.ML
author wenzelm
Thu Jul 11 10:43:53 2013 +0200 (2013-07-11 ago)
changeset 52586 7a0935571a23
parent 52572 2fb1f9cf80d3
child 52596 40298d383463
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   type eval_process
    10   type eval = {exec_id: Document_ID.exec, eval_process: eval_process}
    11   val eval_result_state: eval -> Toplevel.state
    12   type print_process
    13   type print =
    14    {name: string, pri: int, persistent: bool,
    15     exec_id: Document_ID.exec, print_process: print_process}
    16   type exec = eval * print list
    17   val no_exec: exec
    18   val exec_ids: exec option -> Document_ID.exec list
    19   val stable_eval: eval -> bool
    20   val stable_print: print -> bool
    21   val same_eval: eval * eval -> bool
    22   val read: (unit -> theory) -> Token.T list -> Toplevel.transition
    23   val eval: (unit -> theory) -> Token.T list -> eval -> eval
    24   val print: bool -> string -> eval -> print list -> print list option
    25   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    26   val print_function: {name: string, pri: int, persistent: bool} ->
    27     ({command_name: string} -> print_fn option) -> unit
    28   val no_print_function: string -> unit
    29   val execute: exec -> unit
    30 end;
    31 
    32 structure Command: COMMAND =
    33 struct
    34 
    35 (** memo results -- including physical interrupts! **)
    36 
    37 datatype 'a expr =
    38   Expr of unit -> 'a |
    39   Result of 'a Exn.result;
    40 
    41 abstype 'a memo = Memo of 'a expr Synchronized.var
    42 with
    43 
    44 fun memo e = Memo (Synchronized.var "Command.memo" (Expr e));
    45 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    46 
    47 fun memo_eval (Memo v) =
    48   (case Synchronized.value v of
    49     Result res => res
    50   | _ =>
    51       Synchronized.guarded_access v
    52         (fn Result res => SOME (res, Result res)
    53           | Expr e =>
    54               let val res = Exn.capture e ();  (*sic!*)
    55               in SOME (res, Result res) end))
    56   |> Exn.release;
    57 
    58 fun memo_fork params (Memo v) =
    59   (case Synchronized.value v of
    60     Result _ => ()
    61   | _ => ignore ((singleton o Future.forks) params (fn () => memo_eval (Memo v))));
    62 
    63 fun memo_result (Memo v) =
    64   (case Synchronized.value v of
    65     Result res => Exn.release res
    66   | _ => raise Fail "Unfinished memo result");
    67 
    68 fun memo_stable (Memo v) =
    69   (case Synchronized.value v of
    70     Expr _ => true
    71   | Result res => not (Exn.is_interrupt_exn res));
    72 
    73 end;
    74 
    75 
    76 
    77 (** main phases of execution **)
    78 
    79 (* basic type definitions *)
    80 
    81 type eval_state =
    82   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
    83 val init_eval_state =
    84   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
    85 
    86 type eval_process = eval_state memo;
    87 type eval = {exec_id: Document_ID.exec, eval_process: eval_process};
    88 
    89 fun eval_result ({eval_process, ...}: eval) = memo_result eval_process;
    90 val eval_result_state = #state o eval_result;
    91 
    92 type print_process = unit memo;
    93 type print =
    94  {name: string, pri: int, persistent: bool,
    95   exec_id: Document_ID.exec, print_process: print_process};
    96 
    97 type exec = eval * print list;
    98 val no_exec: exec = ({exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
    99 
   100 fun exec_ids (NONE: exec option) = []
   101   | exec_ids (SOME ({exec_id, ...}, prints)) = exec_id :: map #exec_id prints;
   102 
   103 
   104 (* stable results *)
   105 
   106 fun stable_goals exec_id =
   107   not (Par_Exn.is_interrupted (Future.join_results (Goal.peek_futures exec_id)));
   108 
   109 fun stable_eval ({exec_id, eval_process}: eval) =
   110   stable_goals exec_id andalso memo_stable eval_process;
   111 
   112 fun stable_print ({exec_id, print_process, ...}: print) =
   113   stable_goals exec_id andalso memo_stable print_process;
   114 
   115 fun same_eval (eval: eval, eval': eval) =
   116   #exec_id eval = #exec_id eval' andalso stable_eval eval';
   117 
   118 
   119 (* read *)
   120 
   121 fun read init span =
   122   let
   123     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
   124     val command_reports = Outer_Syntax.command_reports outer_syntax;
   125 
   126     val proper_range =
   127       Position.set_range (Token.position_range_of (#1 (take_suffix Token.is_improper span)));
   128     val pos =
   129       (case find_first Token.is_command span of
   130         SOME tok => Token.position_of tok
   131       | NONE => proper_range);
   132 
   133     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
   134     val _ = Position.reports_text (token_reports @ maps command_reports span);
   135   in
   136     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
   137     else
   138       (case Outer_Syntax.read_spans outer_syntax span of
   139         [tr] =>
   140           if Keyword.is_control (Toplevel.name_of tr) then
   141             Toplevel.malformed pos "Illegal control command"
   142           else Toplevel.modify_init init tr
   143       | [] => Toplevel.ignored (Position.set_range (Token.position_range_of span))
   144       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   145       handle ERROR msg => Toplevel.malformed proper_range msg
   146   end;
   147 
   148 
   149 (* eval *)
   150 
   151 local
   152 
   153 fun run int tr st =
   154   if Goal.future_enabled () andalso Keyword.is_diag (Toplevel.name_of tr) then
   155     (Goal.fork_params {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   156       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   157   else Toplevel.command_errors int tr st;
   158 
   159 fun check_cmts span tr st' =
   160   Toplevel.setmp_thread_position tr
   161     (fn () =>
   162       Outer_Syntax.side_comments span |> maps (fn cmt =>
   163         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   164           handle exn => ML_Compiler.exn_messages_ids exn)) ();
   165 
   166 fun proof_status tr st =
   167   (case try Toplevel.proof_of st of
   168     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   169   | NONE => ());
   170 
   171 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   172   if malformed then
   173     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   174   else
   175     let
   176       val malformed' = Toplevel.is_malformed tr;
   177       val is_init = Toplevel.is_init tr;
   178       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   179 
   180       val _ = Multithreading.interrupted ();
   181       val _ = Toplevel.status tr Markup.running;
   182       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   183       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   184       val errs = errs1 @ errs2;
   185       val _ = Toplevel.status tr Markup.finished;
   186       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   187     in
   188       (case result of
   189         NONE =>
   190           let
   191             val _ = if null errs then Exn.interrupt () else ();
   192             val _ = Toplevel.status tr Markup.failed;
   193           in {failed = true, malformed = malformed', command = tr, state = st} end
   194       | SOME st' =>
   195           let
   196             val _ = proof_status tr st';
   197           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   198     end;
   199 
   200 in
   201 
   202 fun eval init span eval0 =
   203   let
   204     val exec_id = Document_ID.make ();
   205     fun process () =
   206       let
   207         val tr =
   208           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   209             (fn () => read init span |> Toplevel.exec_id exec_id) ();
   210       in eval_state span tr (eval_result eval0) end;
   211   in {exec_id = exec_id, eval_process = memo process} end;
   212 
   213 end;
   214 
   215 
   216 (* print *)
   217 
   218 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   219 
   220 local
   221 
   222 type print_function = string * (int * bool * ({command_name: string} -> print_fn option));
   223 val print_functions = Synchronized.var "Command.print_functions" ([]: print_function list);
   224 
   225 fun print_error tr e =
   226   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution) e () handle exn =>
   227     List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   228 
   229 in
   230 
   231 fun print command_visible command_name eval old_prints =
   232   let
   233     fun new_print (name, (pri, persistent, get_fn)) =
   234       let
   235         fun make_print strict print_fn =
   236           let
   237             val exec_id = Document_ID.make ();
   238             fun process () =
   239               let
   240                 val {failed, command, state = st', ...} = eval_result eval;
   241                 val tr = Toplevel.exec_id exec_id command;
   242               in
   243                 if failed andalso not strict then ()
   244                 else print_error tr (fn () => print_fn tr st')
   245               end;
   246           in
   247            {name = name, pri = pri, persistent = persistent,
   248             exec_id = exec_id, print_process = memo process}
   249           end;
   250       in
   251         (case Exn.capture (Runtime.controlled_execution get_fn) {command_name = command_name} of
   252           Exn.Res NONE => NONE
   253         | Exn.Res (SOME print_fn) => SOME (make_print false print_fn)
   254         | Exn.Exn exn => SOME (make_print true (fn _ => fn _ => reraise exn)))
   255       end;
   256 
   257     val new_prints =
   258       if command_visible then
   259         rev (Synchronized.value print_functions) |> map_filter (fn pr =>
   260           (case find_first (equal (fst pr) o #name) old_prints of
   261             SOME print => if stable_print print then SOME print else new_print pr
   262           | NONE => new_print pr))
   263       else filter (fn print => #persistent print andalso stable_print print) old_prints;
   264   in
   265     if eq_list (op = o pairself #exec_id) (old_prints, new_prints) then NONE
   266     else SOME new_prints
   267   end;
   268 
   269 fun print_function {name, pri, persistent} f =
   270   Synchronized.change print_functions (fn funs =>
   271    (if not (AList.defined (op =) funs name) then ()
   272     else warning ("Redefining command print function: " ^ quote name);
   273     AList.update (op =) (name, (pri, persistent, f)) funs));
   274 
   275 fun no_print_function name =
   276   Synchronized.change print_functions (filter_out (equal name o #1));
   277 
   278 end;
   279 
   280 val _ =
   281   print_function {name = "print_state", pri = 0, persistent = true}
   282     (fn {command_name} => SOME (fn tr => fn st' =>
   283       let
   284         val is_init = Keyword.is_theory_begin command_name;
   285         val is_proof = Keyword.is_proof command_name;
   286         val do_print =
   287           not is_init andalso
   288             (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   289       in if do_print then Toplevel.print_state false st' else () end));
   290 
   291 
   292 (* overall execution process *)
   293 
   294 fun run_print ({name, pri, print_process, ...}: print) =
   295   (if Multithreading.enabled () then
   296     memo_fork {name = name, group = NONE, deps = [], pri = pri, interrupts = true}
   297   else memo_eval) print_process;
   298 
   299 fun execute (({eval_process, ...}, prints): exec) =
   300   (memo_eval eval_process; List.app run_print prints);
   301 
   302 end;
   303