src/Pure/Isar/calculation.ML
author wenzelm
Sun Nov 06 21:51:46 2011 +0100 (2011-11-06 ago)
changeset 45375 7fe19930dfc9
parent 42360 da8817d01e7c
child 49868 3039922ffd8d
permissions -rw-r--r--
more explicit representation of rule_attribute vs. declaration_attribute vs. mixed_attribute;
misc tuning;
     1 (*  Title:      Pure/Isar/calculation.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Generic calculational proofs.
     5 *)
     6 
     7 signature CALCULATION =
     8 sig
     9   val print_rules: Proof.context -> unit
    10   val get_calculation: Proof.state -> thm list option
    11   val trans_add: attribute
    12   val trans_del: attribute
    13   val sym_add: attribute
    14   val sym_del: attribute
    15   val symmetric: attribute
    16   val also: thm list option -> bool -> Proof.state -> Proof.state Seq.seq
    17   val also_cmd: (Facts.ref * Attrib.src list) list option ->
    18     bool -> Proof.state -> Proof.state Seq.seq
    19   val finally: thm list option -> bool -> Proof.state -> Proof.state Seq.seq
    20   val finally_cmd: (Facts.ref * Attrib.src list) list option -> bool ->
    21     Proof.state -> Proof.state Seq.seq
    22   val moreover: bool -> Proof.state -> Proof.state
    23   val ultimately: bool -> Proof.state -> Proof.state
    24 end;
    25 
    26 structure Calculation: CALCULATION =
    27 struct
    28 
    29 (** calculation data **)
    30 
    31 structure Data = Generic_Data
    32 (
    33   type T = (thm Item_Net.T * thm list) * (thm list * int) option;
    34   val empty = ((Thm.elim_rules, []), NONE);
    35   val extend = I;
    36   fun merge (((trans1, sym1), _), ((trans2, sym2), _)) =
    37     ((Item_Net.merge (trans1, trans2), Thm.merge_thms (sym1, sym2)), NONE);
    38 );
    39 
    40 val get_rules = #1 o Data.get o Context.Proof;
    41 
    42 fun print_rules ctxt =
    43   let val (trans, sym) = get_rules ctxt in
    44     [Pretty.big_list "transitivity rules:"
    45         (map (Display.pretty_thm ctxt) (Item_Net.content trans)),
    46       Pretty.big_list "symmetry rules:" (map (Display.pretty_thm ctxt) sym)]
    47     |> Pretty.chunks |> Pretty.writeln
    48   end;
    49 
    50 
    51 (* access calculation *)
    52 
    53 fun get_calculation state =
    54   (case #2 (Data.get (Context.Proof (Proof.context_of state))) of
    55     NONE => NONE
    56   | SOME (thms, lev) => if lev = Proof.level state then SOME thms else NONE);
    57 
    58 val calculationN = "calculation";
    59 
    60 fun put_calculation calc =
    61   `Proof.level #-> (fn lev => Proof.map_context (Context.proof_map
    62      (Data.map (apsnd (K (Option.map (rpair lev) calc))))))
    63   #> Proof.put_thms false (calculationN, calc);
    64 
    65 
    66 
    67 (** attributes **)
    68 
    69 (* add/del rules *)
    70 
    71 val trans_add = Thm.declaration_attribute (Data.map o apfst o apfst o Item_Net.update);
    72 val trans_del = Thm.declaration_attribute (Data.map o apfst o apfst o Item_Net.remove);
    73 
    74 val sym_add =
    75   Thm.declaration_attribute (fn th =>
    76     (Data.map o apfst o apsnd) (Thm.add_thm th) #>
    77     Thm.attribute_declaration (Context_Rules.elim_query NONE) th);
    78 
    79 val sym_del =
    80   Thm.declaration_attribute (fn th =>
    81     (Data.map o apfst o apsnd) (Thm.del_thm th) #>
    82     Thm.attribute_declaration Context_Rules.rule_del th);
    83 
    84 
    85 (* symmetric *)
    86 
    87 val symmetric = Thm.rule_attribute (fn x => fn th =>
    88   (case Seq.chop 2 (Drule.multi_resolves [th] (#2 (#1 (Data.get x)))) of
    89     ([th'], _) => Drule.zero_var_indexes th'
    90   | ([], _) => raise THM ("symmetric: no unifiers", 1, [th])
    91   | _ => raise THM ("symmetric: multiple unifiers", 1, [th])));
    92 
    93 
    94 (* concrete syntax *)
    95 
    96 val _ = Context.>> (Context.map_theory
    97  (Attrib.setup (Binding.name "trans") (Attrib.add_del trans_add trans_del)
    98     "declaration of transitivity rule" #>
    99   Attrib.setup (Binding.name "sym") (Attrib.add_del sym_add sym_del)
   100     "declaration of symmetry rule" #>
   101   Attrib.setup (Binding.name "symmetric") (Scan.succeed symmetric)
   102     "resolution with symmetry rule" #>
   103   Global_Theory.add_thms
   104    [((Binding.empty, transitive_thm), [trans_add]),
   105     ((Binding.empty, symmetric_thm), [sym_add])] #> snd));
   106 
   107 
   108 
   109 (** proof commands **)
   110 
   111 fun assert_sane final =
   112   if final then Proof.assert_forward else Proof.assert_forward_or_chain;
   113 
   114 fun maintain_calculation int final calc state =
   115   let
   116     val state' = put_calculation (SOME calc) state;
   117     val ctxt' = Proof.context_of state';
   118     val _ =
   119       if int then
   120         Pretty.writeln
   121           (Proof_Context.pretty_fact ctxt'
   122             (Proof_Context.full_name ctxt' (Binding.name calculationN), calc))
   123       else ();
   124   in state' |> final ? (put_calculation NONE #> Proof.chain_facts calc) end;
   125 
   126 
   127 (* also and finally *)
   128 
   129 fun calculate prep_rules final raw_rules int state =
   130   let
   131     val ctxt = Proof.context_of state;
   132 
   133     val strip_assums_concl = Logic.strip_assums_concl o Thm.prop_of;
   134     val eq_prop = op aconv o pairself (Envir.beta_eta_contract o strip_assums_concl);
   135     fun projection ths th = exists (curry eq_prop th) ths;
   136 
   137     val opt_rules = Option.map (prep_rules ctxt) raw_rules;
   138     fun combine ths =
   139       (case opt_rules of SOME rules => rules
   140       | NONE =>
   141           (case ths of
   142             [] => Item_Net.content (#1 (get_rules ctxt))
   143           | th :: _ => Item_Net.retrieve (#1 (get_rules ctxt)) (strip_assums_concl th)))
   144       |> Seq.of_list |> Seq.maps (Drule.multi_resolve ths)
   145       |> Seq.filter (not o projection ths);
   146 
   147     val facts = Proof.the_facts (assert_sane final state);
   148     val (initial, calculations) =
   149       (case get_calculation state of
   150         NONE => (true, Seq.single facts)
   151       | SOME calc => (false, Seq.map single (combine (calc @ facts))));
   152 
   153     val _ = initial andalso final andalso error "No calculation yet";
   154     val _ = initial andalso is_some opt_rules andalso
   155       error "Initial calculation -- no rules to be given";
   156   in
   157     calculations |> Seq.map (fn calc => maintain_calculation int final calc state)
   158   end;
   159 
   160 val also = calculate (K I) false;
   161 val also_cmd = calculate Attrib.eval_thms false;
   162 val finally = calculate (K I) true;
   163 val finally_cmd = calculate Attrib.eval_thms true;
   164 
   165 
   166 (* moreover and ultimately *)
   167 
   168 fun collect final int state =
   169   let
   170     val facts = Proof.the_facts (assert_sane final state);
   171     val (initial, thms) =
   172       (case get_calculation state of
   173         NONE => (true, [])
   174       | SOME thms => (false, thms));
   175     val calc = thms @ facts;
   176     val _ = initial andalso final andalso error "No calculation yet";
   177   in maintain_calculation int final calc state end;
   178 
   179 val moreover = collect false;
   180 val ultimately = collect true;
   181 
   182 end;