src/Pure/Isar/proof_context.ML
author wenzelm
Wed Jun 18 22:32:03 2008 +0200 (2008-06-18 ago)
changeset 27264 843472ae2116
parent 27259 6e71abb8c994
child 27286 2ea20e5fdf16
permissions -rw-r--r--
simplified TypeInfer.infer_types;
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The key concept of Isar proof contexts: elevates primitive local
     6 reasoning Gamma |- phi to a structured concept, with generic context
     7 elements.  See also structure Variable and Assumption.
     8 *)
     9 
    10 signature PROOF_CONTEXT =
    11 sig
    12   val theory_of: Proof.context -> theory
    13   val init: theory -> Proof.context
    14   type mode
    15   val mode_default: mode
    16   val mode_stmt: mode
    17   val mode_pattern: mode
    18   val mode_schematic: mode
    19   val mode_abbrev: mode
    20   val set_mode: mode -> Proof.context -> Proof.context
    21   val get_mode: Proof.context -> mode
    22   val restore_mode: Proof.context -> Proof.context -> Proof.context
    23   val is_abbrev_mode: Proof.context -> bool
    24   val set_stmt: bool -> Proof.context -> Proof.context
    25   val naming_of: Proof.context -> NameSpace.naming
    26   val full_name: Proof.context -> bstring -> string
    27   val consts_of: Proof.context -> Consts.T
    28   val const_syntax_name: Proof.context -> string -> string
    29   val the_const_constraint: Proof.context -> string -> typ
    30   val mk_const: Proof.context -> string * typ list -> term
    31   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    32   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    33   val facts_of: Proof.context -> Facts.T
    34   val transfer_syntax: theory -> Proof.context -> Proof.context
    35   val transfer: theory -> Proof.context -> Proof.context
    36   val theory: (theory -> theory) -> Proof.context -> Proof.context
    37   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    38   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    39   val pretty_thm_legacy: thm -> Pretty.T
    40   val pretty_thm: Proof.context -> thm -> Pretty.T
    41   val pretty_thms: Proof.context -> thm list -> Pretty.T
    42   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    43   val string_of_thm: Proof.context -> thm -> string
    44   val read_typ: Proof.context -> string -> typ
    45   val read_typ_syntax: Proof.context -> string -> typ
    46   val read_typ_abbrev: Proof.context -> string -> typ
    47   val cert_typ: Proof.context -> typ -> typ
    48   val cert_typ_syntax: Proof.context -> typ -> typ
    49   val cert_typ_abbrev: Proof.context -> typ -> typ
    50   val get_skolem: Proof.context -> string -> string
    51   val revert_skolem: Proof.context -> string -> string
    52   val infer_type: Proof.context -> string -> typ
    53   val inferred_param: string -> Proof.context -> (string * typ) * Proof.context
    54   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    55   val read_tyname: Proof.context -> string -> typ
    56   val read_const_proper: Proof.context -> string -> term
    57   val read_const: Proof.context -> string -> term
    58   val allow_dummies: Proof.context -> Proof.context
    59   val decode_term: Proof.context -> term -> term
    60   val standard_infer_types: Proof.context -> term list -> term list
    61   val read_term_pattern: Proof.context -> string -> term
    62   val read_term_schematic: Proof.context -> string -> term
    63   val read_term_abbrev: Proof.context -> string -> term
    64   val expand_abbrevs: Proof.context -> term -> term
    65   val cert_term: Proof.context -> term -> term
    66   val cert_prop: Proof.context -> term -> term
    67   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    68   val export: Proof.context -> Proof.context -> thm list -> thm list
    69   val export_morphism: Proof.context -> Proof.context -> morphism
    70   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    71   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    72   val auto_bind_goal: term list -> Proof.context -> Proof.context
    73   val auto_bind_facts: term list -> Proof.context -> Proof.context
    74   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    75   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    76   val read_propp: Proof.context * (string * string list) list list
    77     -> Proof.context * (term * term list) list list
    78   val cert_propp: Proof.context * (term * term list) list list
    79     -> Proof.context * (term * term list) list list
    80   val read_propp_schematic: Proof.context * (string * string list) list list
    81     -> Proof.context * (term * term list) list list
    82   val cert_propp_schematic: Proof.context * (term * term list) list list
    83     -> Proof.context * (term * term list) list list
    84   val bind_propp: Proof.context * (string * string list) list list
    85     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    86   val bind_propp_i: Proof.context * (term * term list) list list
    87     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    88   val bind_propp_schematic: Proof.context * (string * string list) list list
    89     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    90   val bind_propp_schematic_i: Proof.context * (term * term list) list list
    91     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    92   val fact_tac: thm list -> int -> tactic
    93   val some_fact_tac: Proof.context -> int -> tactic
    94   val get_fact: Proof.context -> Facts.ref -> thm list
    95   val get_fact_single: Proof.context -> Facts.ref -> thm
    96   val get_thms: Proof.context -> xstring -> thm list
    97   val get_thm: Proof.context -> xstring -> thm
    98   val add_path: string -> Proof.context -> Proof.context
    99   val no_base_names: Proof.context -> Proof.context
   100   val qualified_names: Proof.context -> Proof.context
   101   val sticky_prefix: string -> Proof.context -> Proof.context
   102   val restore_naming: Proof.context -> Proof.context -> Proof.context
   103   val reset_naming: Proof.context -> Proof.context
   104   val put_thms: bool -> string * thm list option -> Proof.context -> Proof.context
   105   val note_thmss: string ->
   106     ((bstring * attribute list) * (Facts.ref * attribute list) list) list ->
   107       Proof.context -> (bstring * thm list) list * Proof.context
   108   val note_thmss_i: string ->
   109     ((bstring * attribute list) * (thm list * attribute list) list) list ->
   110       Proof.context -> (bstring * thm list) list * Proof.context
   111   val read_vars: (string * string option * mixfix) list -> Proof.context ->
   112     (string * typ option * mixfix) list * Proof.context
   113   val cert_vars: (string * typ option * mixfix) list -> Proof.context ->
   114     (string * typ option * mixfix) list * Proof.context
   115   val add_fixes: (string * string option * mixfix) list ->
   116     Proof.context -> string list * Proof.context
   117   val add_fixes_i: (string * typ option * mixfix) list ->
   118     Proof.context -> string list * Proof.context
   119   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   120   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   121   val add_assms: Assumption.export ->
   122     ((string * attribute list) * (string * string list) list) list ->
   123     Proof.context -> (bstring * thm list) list * Proof.context
   124   val add_assms_i: Assumption.export ->
   125     ((string * attribute list) * (term * term list) list) list ->
   126     Proof.context -> (bstring * thm list) list * Proof.context
   127   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   128   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   129   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   130   val notation: bool -> Syntax.mode -> (term * mixfix) list -> Proof.context -> Proof.context
   131   val target_notation: bool -> Syntax.mode -> (term * mixfix) list -> morphism ->
   132     Context.generic -> Context.generic
   133   val add_const_constraint: string * typ option -> Proof.context -> Proof.context
   134   val add_abbrev: string -> Markup.property list ->
   135     bstring * term -> Proof.context -> (term * term) * Proof.context
   136   val revert_abbrev: string -> string -> Proof.context -> Proof.context
   137   val verbose: bool ref
   138   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   139   val print_syntax: Proof.context -> unit
   140   val print_abbrevs: Proof.context -> unit
   141   val print_binds: Proof.context -> unit
   142   val print_lthms: Proof.context -> unit
   143   val print_cases: Proof.context -> unit
   144   val debug: bool ref
   145   val prems_limit: int ref
   146   val pretty_ctxt: Proof.context -> Pretty.T list
   147   val pretty_context: Proof.context -> Pretty.T list
   148 end;
   149 
   150 structure ProofContext: PROOF_CONTEXT =
   151 struct
   152 
   153 val theory_of = Context.theory_of_proof;
   154 val init = Context.init_proof;
   155 
   156 
   157 (** inner syntax mode **)
   158 
   159 datatype mode =
   160   Mode of
   161    {stmt: bool,                (*inner statement mode*)
   162     pattern: bool,             (*pattern binding schematic variables*)
   163     schematic: bool,           (*term referencing loose schematic variables*)
   164     abbrev: bool};             (*abbrev mode -- no normalization*)
   165 
   166 fun make_mode (stmt, pattern, schematic, abbrev) =
   167   Mode {stmt = stmt, pattern = pattern, schematic = schematic, abbrev = abbrev};
   168 
   169 fun dest_mode (Mode mode) = mode;
   170 
   171 val mode_default   = make_mode (false, false, false, false);
   172 val mode_stmt      = make_mode (true, false, false, false);
   173 val mode_pattern   = make_mode (false, true, false, false);
   174 val mode_schematic = make_mode (false, false, true, false);
   175 val mode_abbrev    = make_mode (false, false, false, true);
   176 
   177 
   178 
   179 (** Isar proof context information **)
   180 
   181 datatype ctxt =
   182   Ctxt of
   183    {mode: mode,                                       (*inner syntax mode*)
   184     naming: NameSpace.naming,                         (*local naming conventions*)
   185     syntax: LocalSyntax.T,                            (*local syntax*)
   186     consts: Consts.T * Consts.T,                      (*local/global consts*)
   187     facts: Facts.T,                                   (*local facts*)
   188     cases: (string * (RuleCases.T * bool)) list};     (*named case contexts*)
   189 
   190 fun make_ctxt (mode, naming, syntax, consts, facts, cases) =
   191   Ctxt {mode = mode, naming = naming, syntax = syntax,
   192     consts = consts, facts = facts, cases = cases};
   193 
   194 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   195 
   196 structure ContextData = ProofDataFun
   197 (
   198   type T = ctxt;
   199   fun init thy =
   200     make_ctxt (mode_default, local_naming, LocalSyntax.init thy,
   201       (Sign.consts_of thy, Sign.consts_of thy), Facts.empty, []);
   202 );
   203 
   204 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   205 
   206 fun map_context f =
   207   ContextData.map (fn Ctxt {mode, naming, syntax, consts, facts, cases} =>
   208     make_ctxt (f (mode, naming, syntax, consts, facts, cases)));
   209 
   210 fun set_mode mode = map_context (fn (_, naming, syntax, consts, facts, cases) =>
   211   (mode, naming, syntax, consts, facts, cases));
   212 
   213 fun map_mode f =
   214   map_context (fn (Mode {stmt, pattern, schematic, abbrev}, naming, syntax, consts, facts, cases) =>
   215     (make_mode (f (stmt, pattern, schematic, abbrev)), naming, syntax, consts, facts, cases));
   216 
   217 fun map_naming f =
   218   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   219     (mode, f naming, syntax, consts, facts, cases));
   220 
   221 fun map_syntax f =
   222   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   223     (mode, naming, f syntax, consts, facts, cases));
   224 
   225 fun map_consts f =
   226   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   227     (mode, naming, syntax, f consts, facts, cases));
   228 
   229 fun map_facts f =
   230   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   231     (mode, naming, syntax, consts, f facts, cases));
   232 
   233 fun map_cases f =
   234   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   235     (mode, naming, syntax, consts, facts, f cases));
   236 
   237 val get_mode = #mode o rep_context;
   238 fun restore_mode ctxt = set_mode (get_mode ctxt);
   239 
   240 fun set_stmt stmt =
   241   map_mode (fn (_, pattern, schematic, abbrev) => (stmt, pattern, schematic, abbrev));
   242 
   243 val naming_of = #naming o rep_context;
   244 val full_name = NameSpace.full o naming_of;
   245 
   246 val syntax_of = #syntax o rep_context;
   247 val syn_of = LocalSyntax.syn_of o syntax_of;
   248 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   249 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   250 
   251 val consts_of = #1 o #consts o rep_context;
   252 val const_syntax_name = Consts.syntax_name o consts_of;
   253 val the_const_constraint = Consts.the_constraint o consts_of;
   254 
   255 fun mk_const ctxt (c, Ts) = Const (c, Consts.instance (consts_of ctxt) (c, Ts));
   256 
   257 val facts_of = #facts o rep_context;
   258 val cases_of = #cases o rep_context;
   259 
   260 
   261 (* theory transfer *)
   262 
   263 fun transfer_syntax thy =
   264   map_syntax (LocalSyntax.rebuild thy) #>
   265   map_consts (fn consts as (local_consts, global_consts) =>
   266     let val thy_consts = Sign.consts_of thy in
   267       if Consts.eq_consts (thy_consts, global_consts) then consts
   268       else (Consts.merge (local_consts, thy_consts), thy_consts)
   269     end);
   270 
   271 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   272 
   273 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   274 
   275 fun theory_result f ctxt =
   276   let val (res, thy') = f (theory_of ctxt)
   277   in (res, ctxt |> transfer thy') end;
   278 
   279 
   280 
   281 (** pretty printing **)
   282 
   283 fun pretty_term_abbrev ctxt = Syntax.pretty_term (set_mode mode_abbrev ctxt);
   284 
   285 fun pretty_thm_legacy th =
   286   let val thy = Thm.theory_of_thm th
   287   in Display.pretty_thm_aux (Syntax.pp_global thy) true false [] th end;
   288 
   289 fun pretty_thm ctxt th =
   290   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   291   in Display.pretty_thm_aux (Syntax.pp ctxt) false true asms th end;
   292 
   293 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   294   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   295 
   296 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   297   | pretty_fact ctxt (a, [th]) =
   298       Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, pretty_thm ctxt th]
   299   | pretty_fact ctxt (a, ths) =
   300       Pretty.block (Pretty.fbreaks (Pretty.str (a ^ ":") :: map (pretty_thm ctxt) ths));
   301 
   302 val string_of_thm = Pretty.string_of oo pretty_thm;
   303 
   304 
   305 
   306 (** prepare types **)
   307 
   308 (* read_typ *)
   309 
   310 fun read_typ_mode mode ctxt s =
   311   Syntax.read_typ (Type.set_mode mode ctxt) s;
   312 
   313 val read_typ        = read_typ_mode Type.mode_default;
   314 val read_typ_syntax = read_typ_mode Type.mode_syntax;
   315 val read_typ_abbrev = read_typ_mode Type.mode_abbrev;
   316 
   317 
   318 (* cert_typ *)
   319 
   320 fun cert_typ_mode mode ctxt T =
   321   Sign.certify_typ_mode mode (theory_of ctxt) T
   322     handle TYPE (msg, _, _) => error msg;
   323 
   324 val cert_typ        = cert_typ_mode Type.mode_default;
   325 val cert_typ_syntax = cert_typ_mode Type.mode_syntax;
   326 val cert_typ_abbrev = cert_typ_mode Type.mode_abbrev;
   327 
   328 
   329 
   330 (** prepare variables **)
   331 
   332 (* internalize Skolem constants *)
   333 
   334 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   335 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   336 
   337 fun no_skolem internal x =
   338   if can Name.dest_skolem x then
   339     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   340   else if not internal andalso can Name.dest_internal x then
   341     error ("Illegal reference to internal variable: " ^ quote x)
   342   else x;
   343 
   344 
   345 (* revert Skolem constants -- if possible *)
   346 
   347 fun revert_skolem ctxt x =
   348   (case find_first (fn (_, y) => y = x) (Variable.fixes_of ctxt) of
   349     SOME (x', _) => if lookup_skolem ctxt x' = SOME x then x' else x
   350   | NONE => x);
   351 
   352 
   353 (* default token translations *)
   354 
   355 local
   356 
   357 fun free_or_skolem ctxt x =
   358   (if can Name.dest_skolem x then Pretty.mark Markup.skolem (Pretty.str (revert_skolem ctxt x))
   359    else Pretty.mark Markup.free (Pretty.str x))
   360   |> Pretty.mark
   361     (if Variable.is_fixed ctxt x orelse Syntax.is_pretty_global ctxt then Markup.fixed x
   362      else Markup.hilite);
   363 
   364 fun var_or_skolem _ s =
   365   (case Lexicon.read_variable s of
   366     SOME (x, i) =>
   367       (case try Name.dest_skolem x of
   368         NONE => Pretty.mark Markup.var (Pretty.str s)
   369       | SOME x' => Pretty.mark Markup.skolem
   370           (Pretty.str (setmp show_question_marks true Term.string_of_vname (x', i))))
   371   | NONE => Pretty.mark Markup.var (Pretty.str s));
   372 
   373 fun class_markup _ c =    (* FIXME authentic name *)
   374   Pretty.mark (Markup.classN, []) (Pretty.str c);
   375 
   376 fun plain_markup m _ s = Pretty.mark m (Pretty.str s);
   377 
   378 val token_trans =
   379  Syntax.tokentrans_mode ""
   380   [("class", class_markup),
   381    ("tfree", plain_markup Markup.tfree),
   382    ("tvar", plain_markup Markup.tvar),
   383    ("free", free_or_skolem),
   384    ("bound", plain_markup Markup.bound),
   385    ("var", var_or_skolem),
   386    ("num", plain_markup Markup.num),
   387    ("xnum", plain_markup Markup.xnum),
   388    ("xstr", plain_markup Markup.xstr)];
   389 
   390 in val _ = Context.>> (Context.map_theory (Sign.add_tokentrfuns token_trans)) end;
   391 
   392 
   393 
   394 (** prepare terms and propositions **)
   395 
   396 (* inferred types of parameters *)
   397 
   398 fun infer_type ctxt x =
   399   Term.fastype_of (singleton (Syntax.check_terms (set_mode mode_schematic ctxt))
   400     (Free (x, dummyT)));
   401 
   402 fun inferred_param x ctxt =
   403   let val T = infer_type ctxt x
   404   in ((x, T), ctxt |> Variable.declare_term (Free (x, T))) end;
   405 
   406 fun inferred_fixes ctxt =
   407   fold_map inferred_param (rev (map #2 (Variable.fixes_of ctxt))) ctxt;
   408 
   409 
   410 (* type and constant names *)
   411 
   412 fun read_tyname ctxt c =
   413   if Syntax.is_tid c then
   414     TFree (c, the_default (Sign.defaultS (theory_of ctxt)) (Variable.def_sort ctxt (c, ~1)))
   415   else
   416     let
   417       val thy = theory_of ctxt;
   418       val d = Sign.intern_type thy c;
   419     in Type (d, replicate (Sign.arity_number thy d) dummyT) end;
   420 
   421 fun read_const_proper ctxt c =
   422   (case Variable.lookup_const ctxt c of
   423     SOME d => Const (d, Consts.type_scheme (consts_of ctxt) d handle TYPE (msg, _, _) => error msg)
   424   | NONE => Consts.read_const (consts_of ctxt) c);
   425 
   426 fun read_const ctxt c =
   427   (case (lookup_skolem ctxt c, Variable.is_const ctxt c) of
   428     (SOME x, false) => Free (x, infer_type ctxt x)
   429   | _ => read_const_proper ctxt c);
   430 
   431 
   432 (* read_term *)
   433 
   434 fun read_term_mode mode ctxt = Syntax.read_term (set_mode mode ctxt);
   435 
   436 val read_term_pattern   = read_term_mode mode_pattern;
   437 val read_term_schematic = read_term_mode mode_schematic;
   438 val read_term_abbrev    = read_term_mode mode_abbrev;
   439 
   440 
   441 (* local abbreviations *)
   442 
   443 val tsig_of = Sign.tsig_of o ProofContext.theory_of;
   444 
   445 val is_abbrev_mode = #abbrev o dest_mode o get_mode;
   446 
   447 local
   448 
   449 fun certify_consts ctxt = Consts.certify (Syntax.pp ctxt) (tsig_of ctxt)
   450   (not (is_abbrev_mode ctxt)) (consts_of ctxt);
   451 
   452 fun reject_schematic (Var (xi, _)) =
   453       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   454   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   455   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   456   | reject_schematic _ = ();
   457 
   458 fun expand_binds ctxt =
   459   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   460     if pattern then I
   461     else Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic)
   462   end;
   463 
   464 in
   465 
   466 fun expand_abbrevs ctxt = certify_consts ctxt #> expand_binds ctxt;
   467 
   468 end;
   469 
   470 
   471 fun contract_abbrevs ctxt t =
   472   let
   473     val thy = theory_of ctxt;
   474     val consts = consts_of ctxt;
   475     val Mode {abbrev, ...} = get_mode ctxt;
   476   in
   477     if abbrev orelse print_mode_active "no_abbrevs" orelse not (can Term.type_of t) then t
   478     else t |> Pattern.rewrite_term thy (Consts.abbrevs_of consts (print_mode_value () @ [""])) []
   479   end;
   480 
   481 
   482 (* patterns *)
   483 
   484 fun prepare_patternT ctxt =
   485   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   486     if pattern orelse schematic then I
   487     else Term.map_atyps
   488       (fn T as TVar (xi, _) =>
   489             if not (TypeInfer.is_param xi)
   490             then error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   491             else T
   492         | T => T)
   493   end;
   494 
   495 
   496 local
   497 
   498 structure AllowDummies = ProofDataFun(type T = bool fun init _ = false);
   499 
   500 fun check_dummies ctxt t =
   501   if AllowDummies.get ctxt then t
   502   else Term.no_dummy_patterns t handle TERM _ => error "Illegal dummy pattern(s) in term";
   503 
   504 fun prepare_dummies ts = #1 (fold_map Term.replace_dummy_patterns ts 1);
   505 
   506 in
   507 
   508 val allow_dummies = AllowDummies.put true;
   509 
   510 fun prepare_patterns ctxt =
   511   let val Mode {pattern, ...} = get_mode ctxt in
   512     TypeInfer.fixate_params (Variable.names_of ctxt) #>
   513     pattern ? Variable.polymorphic ctxt #>
   514     (map o Term.map_types) (prepare_patternT ctxt) #>
   515     (if pattern then prepare_dummies else map (check_dummies ctxt))
   516   end;
   517 
   518 end;
   519 
   520 
   521 (* decoding raw terms (syntax trees) *)
   522 
   523 local
   524 
   525 fun intern_skolem ctxt def_type x =
   526   let
   527     val _ = no_skolem false x;
   528     val sko = lookup_skolem ctxt x;
   529     val is_const = can (read_const_proper ctxt) x orelse NameSpace.is_qualified x;
   530     val is_declared = is_some (def_type (x, ~1));
   531   in
   532     if Variable.is_const ctxt x then NONE
   533     else if is_some sko then sko
   534     else if not is_const orelse is_declared then SOME x
   535     else NONE
   536   end;
   537 
   538 in
   539 
   540 fun term_context ctxt =
   541   let val thy = theory_of ctxt in
   542    {get_sort = Sign.get_sort thy (Variable.def_sort ctxt),
   543     map_const = fn a => ((true, #1 (Term.dest_Const (read_const_proper ctxt a)))
   544       handle ERROR _ => (false, Consts.intern (consts_of ctxt) a)),
   545     map_free = intern_skolem ctxt (Variable.def_type ctxt false),
   546     map_type = Sign.intern_tycons thy,
   547     map_sort = Sign.intern_sort thy}
   548   end;
   549 
   550 fun decode_term ctxt =
   551   let val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt
   552   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   553 
   554 end;
   555 
   556 
   557 (* certify terms *)
   558 
   559 local
   560 
   561 fun gen_cert prop ctxt t =
   562   t
   563   |> expand_abbrevs ctxt
   564   |> (fn t' => #1 (Sign.certify' prop (Syntax.pp ctxt) false (consts_of ctxt) (theory_of ctxt) t')
   565     handle TYPE (msg, _, _) => error msg
   566       | TERM (msg, _) => error msg);
   567 
   568 in
   569 
   570 val cert_term = gen_cert false;
   571 val cert_prop = gen_cert true;
   572 
   573 end;
   574 
   575 
   576 (* type checking/inference *)
   577 
   578 fun standard_infer_types ctxt ts =
   579   let val Mode {pattern, ...} = get_mode ctxt in
   580     TypeInfer.infer_types (Syntax.pp ctxt) (tsig_of ctxt) (Syntax.check_typs ctxt)
   581       (try (Consts.the_constraint (consts_of ctxt))) (Variable.def_type ctxt pattern)
   582       (Variable.names_of ctxt) (Variable.maxidx_of ctxt) ts
   583     handle TYPE (msg, _, _) => error msg
   584   end;
   585 
   586 local
   587 
   588 fun standard_typ_check ctxt =
   589   map (cert_typ_mode (Type.get_mode ctxt) ctxt) #>
   590   map (prepare_patternT ctxt);
   591 
   592 fun standard_term_check ctxt =
   593   standard_infer_types ctxt #>
   594   map (expand_abbrevs ctxt);
   595 
   596 fun standard_term_uncheck ctxt =
   597   map (contract_abbrevs ctxt);
   598 
   599 fun add eq what f = Context.>> (what (fn xs => fn ctxt =>
   600   let val xs' = f ctxt xs in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end));
   601 
   602 in
   603 
   604 val _ = add (op =) (Syntax.add_typ_check 0 "standard") standard_typ_check;
   605 val _ = add (op aconv) (Syntax.add_term_check 0 "standard") standard_term_check;
   606 val _ = add (op aconv) (Syntax.add_term_check 100 "fixate") prepare_patterns;
   607 
   608 val _ = add (op aconv) (Syntax.add_term_uncheck 0 "standard") standard_term_uncheck;
   609 
   610 end;
   611 
   612 
   613 
   614 (** inner syntax operations **)
   615 
   616 local
   617 
   618 fun parse_sort ctxt str =
   619   Syntax.standard_parse_sort ctxt (syn_of ctxt) (Sign.intern_sort (theory_of ctxt)) str;
   620 
   621 fun parse_typ ctxt str =
   622   let
   623     val thy = ProofContext.theory_of ctxt;
   624     val get_sort = Sign.get_sort thy (Variable.def_sort ctxt);
   625     val T = Sign.intern_tycons thy
   626       (Syntax.standard_parse_typ ctxt (syn_of ctxt) get_sort (Sign.intern_sort thy) str);
   627   in T end
   628   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   629 
   630 fun parse_term T ctxt str =
   631   let
   632     val thy = theory_of ctxt;
   633     val (T', _) = TypeInfer.paramify_dummies T 0;
   634     fun check t = (Syntax.check_term ctxt (TypeInfer.constrain T' t); NONE)
   635       handle ERROR msg => SOME msg;
   636     val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt;
   637     val read = Syntax.standard_parse_term (Syntax.pp ctxt) check get_sort
   638       map_const map_free map_type map_sort ctxt (Sign.is_logtype thy) (syn_of ctxt) T';
   639   in read str end;
   640 
   641 
   642 fun unparse_sort ctxt S =
   643   Syntax.standard_unparse_sort ctxt (syn_of ctxt) (Sign.extern_sort (theory_of ctxt) S);
   644 
   645 fun unparse_typ ctxt T =
   646   Syntax.standard_unparse_typ ctxt (syn_of ctxt) (Sign.extern_typ (theory_of ctxt) T);
   647 
   648 fun unparse_term ctxt t =
   649   let
   650     val thy = theory_of ctxt;
   651     val syntax = syntax_of ctxt;
   652     val consts = consts_of ctxt;
   653   in
   654     t
   655     |> Sign.extern_term (Consts.extern_early consts) thy
   656     |> LocalSyntax.extern_term syntax
   657     |> Syntax.standard_unparse_term (Consts.extern consts) ctxt (LocalSyntax.syn_of syntax)
   658         (not (PureThy.old_appl_syntax thy))
   659   end;
   660 
   661 in
   662 
   663 val _ = Syntax.install_operations
   664   {parse_sort = parse_sort,
   665    parse_typ = parse_typ,
   666    parse_term = parse_term dummyT,
   667    parse_prop = parse_term propT,
   668    unparse_sort = unparse_sort,
   669    unparse_typ = unparse_typ,
   670    unparse_term = unparse_term};
   671 
   672 end;
   673 
   674 
   675 
   676 (** export results **)
   677 
   678 fun common_export is_goal inner outer =
   679   map (Assumption.export is_goal inner outer) #>
   680   Variable.export inner outer;
   681 
   682 val goal_export = common_export true;
   683 val export = common_export false;
   684 
   685 fun export_morphism inner outer =
   686   Assumption.export_morphism inner outer $>
   687   Variable.export_morphism inner outer;
   688 
   689 
   690 
   691 (** bindings **)
   692 
   693 (* simult_matches *)
   694 
   695 fun simult_matches ctxt (t, pats) =
   696   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   697     NONE => error "Pattern match failed!"
   698   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   699 
   700 
   701 (* add_binds(_i) *)
   702 
   703 local
   704 
   705 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   706   ctxt
   707   |> Variable.add_binds [(xi, Option.map (prep (set_mode mode_default ctxt)) raw_t)];
   708 
   709 in
   710 
   711 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   712   | drop_schematic b = b;
   713 
   714 val add_binds = fold (gen_bind Syntax.read_term);
   715 val add_binds_i = fold (gen_bind cert_term);
   716 
   717 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   718 val auto_bind_goal = auto_bind AutoBind.goal;
   719 val auto_bind_facts = auto_bind AutoBind.facts;
   720 
   721 end;
   722 
   723 
   724 (* match_bind(_i) *)
   725 
   726 local
   727 
   728 fun gen_bind prep_terms gen raw_binds ctxt =
   729   let
   730     fun prep_bind (raw_pats, t) ctxt1 =
   731       let
   732         val T = Term.fastype_of t;
   733         val ctxt2 = Variable.declare_term t ctxt1;
   734         val pats = prep_terms (set_mode mode_pattern ctxt2) T raw_pats;
   735         val binds = simult_matches ctxt2 (t, pats);
   736       in (binds, ctxt2) end;
   737 
   738     val ts = prep_terms ctxt dummyT (map snd raw_binds);
   739     val (binds, ctxt') = apfst flat (fold_map prep_bind (map fst raw_binds ~~ ts) ctxt);
   740     val binds' =
   741       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   742       else binds;
   743     val binds'' = map (apsnd SOME) binds';
   744     val ctxt'' =
   745       tap (Variable.warn_extra_tfrees ctxt)
   746        (if gen then
   747           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   748         else ctxt' |> add_binds_i binds'');
   749   in (ts, ctxt'') end;
   750 
   751 in
   752 
   753 fun read_terms ctxt T =
   754   map (Syntax.parse_term ctxt #> TypeInfer.constrain T) #> Syntax.check_terms ctxt;
   755 
   756 val match_bind = gen_bind read_terms;
   757 val match_bind_i = gen_bind (fn ctxt => fn _ => map (cert_term ctxt));
   758 
   759 end;
   760 
   761 
   762 (* propositions with patterns *)
   763 
   764 local
   765 
   766 fun prep_propp mode prep_props (context, args) =
   767   let
   768     fun prep (_, raw_pats) (ctxt, prop :: props) =
   769       let val ctxt' = Variable.declare_term prop ctxt
   770       in ((prop, prep_props (set_mode mode_pattern ctxt') raw_pats), (ctxt', props)) end;
   771 
   772     val (propp, (context', _)) = (fold_map o fold_map) prep args
   773       (context, prep_props (set_mode mode context) (maps (map fst) args));
   774   in (context', propp) end;
   775 
   776 fun gen_bind_propp mode parse_prop (ctxt, raw_args) =
   777   let
   778     val (ctxt', args) = prep_propp mode parse_prop (ctxt, raw_args);
   779     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   780     val propss = map (map #1) args;
   781 
   782     (*generalize result: context evaluated now, binds added later*)
   783     val gen = Variable.exportT_terms ctxt' ctxt;
   784     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   785   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   786 
   787 in
   788 
   789 val read_propp           = prep_propp mode_default Syntax.read_props;
   790 val cert_propp           = prep_propp mode_default (map o cert_prop);
   791 val read_propp_schematic = prep_propp mode_schematic Syntax.read_props;
   792 val cert_propp_schematic = prep_propp mode_schematic (map o cert_prop);
   793 
   794 val bind_propp             = gen_bind_propp mode_default Syntax.read_props;
   795 val bind_propp_i           = gen_bind_propp mode_default (map o cert_prop);
   796 val bind_propp_schematic   = gen_bind_propp mode_schematic Syntax.read_props;
   797 val bind_propp_schematic_i = gen_bind_propp mode_schematic (map o cert_prop);
   798 
   799 end;
   800 
   801 
   802 
   803 (** theorems **)
   804 
   805 (* fact_tac *)
   806 
   807 fun comp_incr_tac [] _ st = no_tac st
   808   | comp_incr_tac (th :: ths) i st =
   809       (Goal.compose_hhf_tac (Drule.incr_indexes st th) i APPEND comp_incr_tac ths i) st;
   810 
   811 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   812 
   813 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) =>
   814   fact_tac (Facts.could_unify (facts_of ctxt) (Term.strip_all_body goal)) i);
   815 
   816 
   817 (* get_thm(s) *)
   818 
   819 local
   820 
   821 fun retrieve_thms pick ctxt (Facts.Fact s) =
   822       let
   823         val prop = Syntax.read_prop (set_mode mode_default ctxt) s
   824           |> singleton (Variable.polymorphic ctxt);
   825         val th = Goal.prove ctxt [] [] prop (K (ALLGOALS (some_fact_tac ctxt)))
   826           handle ERROR msg => cat_error msg "Failed to retrieve literal fact.";
   827       in pick "" [th] end
   828   | retrieve_thms pick ctxt xthmref =
   829       let
   830         val thy = theory_of ctxt;
   831         val local_facts = facts_of ctxt;
   832         val thmref = Facts.map_name_of_ref (Facts.intern local_facts) xthmref;
   833         val name = Facts.name_of_ref thmref;
   834         val thms =
   835           if name = "" then [Thm.transfer thy Drule.dummy_thm]
   836           else
   837             (case Facts.lookup (Context.Proof ctxt) local_facts name of
   838               SOME ths => map (Thm.transfer thy) (Facts.select thmref ths)
   839             | NONE => PureThy.get_fact (Context.Proof ctxt) thy xthmref);
   840       in pick name thms end;
   841 
   842 in
   843 
   844 val get_fact = retrieve_thms (K I);
   845 val get_fact_single = retrieve_thms Facts.the_single;
   846 
   847 fun get_thms ctxt = get_fact ctxt o Facts.named;
   848 fun get_thm ctxt = get_fact_single ctxt o Facts.named;
   849 
   850 end;
   851 
   852 
   853 (* name space operations *)
   854 
   855 val add_path        = map_naming o NameSpace.add_path;
   856 val no_base_names   = map_naming NameSpace.no_base_names;
   857 val qualified_names = map_naming NameSpace.qualified_names;
   858 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   859 val restore_naming  = map_naming o K o naming_of;
   860 val reset_naming    = map_naming (K local_naming);
   861 
   862 
   863 (* facts *)
   864 
   865 fun update_thms _ (bname, NONE) ctxt = ctxt |> map_facts (Facts.del (full_name ctxt bname))
   866   | update_thms do_props (bname, SOME ths) ctxt = ctxt |> map_facts
   867       (Facts.add_local do_props (naming_of ctxt) (full_name ctxt bname, ths));
   868 
   869 fun put_thms do_props thms ctxt =
   870   ctxt |> map_naming (K local_naming) |> update_thms do_props thms |> restore_naming ctxt;
   871 
   872 local
   873 
   874 fun gen_note_thmss get k = fold_map (fn ((bname, more_attrs), raw_facts) => fn ctxt =>
   875   let
   876     val name = full_name ctxt bname;
   877     val facts = PureThy.name_thmss false name (map (apfst (get ctxt)) raw_facts);
   878     fun app (th, attrs) x =
   879       swap (foldl_map (Thm.proof_attributes (attrs @ more_attrs @ [PureThy.kind k])) (x, th));
   880     val (res, ctxt') = fold_map app facts ctxt;
   881     val thms = PureThy.name_thms false false name (flat res);
   882     val Mode {stmt, ...} = get_mode ctxt;
   883   in ((bname, thms), ctxt' |> update_thms stmt (bname, SOME thms)) end);
   884 
   885 in
   886 
   887 fun note_thmss k = gen_note_thmss get_fact k;
   888 fun note_thmss_i k = gen_note_thmss (K I) k;
   889 
   890 end;
   891 
   892 
   893 
   894 (** parameters **)
   895 
   896 (* variables *)
   897 
   898 fun declare_var (x, opt_T, mx) ctxt =
   899   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
   900   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
   901 
   902 local
   903 
   904 fun prep_vars prep_typ internal =
   905   fold_map (fn (raw_x, raw_T, raw_mx) => fn ctxt =>
   906     let
   907       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
   908       val _ = Syntax.is_identifier (no_skolem internal x) orelse
   909         error ("Illegal variable name: " ^ quote x);
   910 
   911       fun cond_tvars T =
   912         if internal then T
   913         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
   914       val opt_T = Option.map (cond_tvars o cert_typ ctxt o prep_typ ctxt) raw_T;
   915       val var = (x, opt_T, mx);
   916     in (var, ctxt |> declare_var var |> #2) end);
   917 
   918 in
   919 
   920 val read_vars = prep_vars Syntax.parse_typ false;
   921 val cert_vars = prep_vars (K I) true;
   922 
   923 end;
   924 
   925 
   926 (* authentic constants *)
   927 
   928 local
   929 
   930 fun const_ast_tr intern ctxt [Syntax.Variable c] =
   931       let
   932         val Const (c', _) = read_const_proper ctxt c;
   933         val d = if intern then const_syntax_name ctxt c' else c;
   934       in Syntax.Constant d end
   935   | const_ast_tr _ _ asts = raise Syntax.AST ("const_ast_tr", asts);
   936 
   937 in
   938 
   939 val _ = Context.>> (Context.map_theory
   940  (Sign.add_syntax
   941    [("_context_const", "id => 'a", Delimfix "CONST _"),
   942     ("_context_const", "longid => 'a", Delimfix "CONST _"),
   943     ("_context_xconst", "id => 'a", Delimfix "XCONST _"),
   944     ("_context_xconst", "longid => 'a", Delimfix "XCONST _")] #>
   945   Sign.add_advanced_trfuns
   946     ([("_context_const", const_ast_tr true), ("_context_xconst", const_ast_tr false)], [], [], [])));
   947 
   948 end;
   949 
   950 
   951 (* notation *)
   952 
   953 local
   954 
   955 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
   956   | const_syntax ctxt (Const (c, _), mx) =
   957       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
   958   | const_syntax _ _ = NONE;
   959 
   960 in
   961 
   962 fun notation add mode args ctxt =
   963   ctxt |> map_syntax
   964     (LocalSyntax.update_modesyntax (theory_of ctxt) add mode (map_filter (const_syntax ctxt) args));
   965 
   966 fun target_notation add mode args phi =
   967   let val args' = filter (fn (t, _) => Type.similar_types (t, Morphism.term phi t)) args;
   968   in Context.mapping (Sign.notation add mode args') (notation add mode args') end;
   969 
   970 end;
   971 
   972 
   973 (* local constants *)
   974 
   975 fun add_const_constraint (c, opt_T) ctxt =
   976   let
   977     fun prepT raw_T =
   978       let val T = cert_typ ctxt raw_T
   979       in cert_term ctxt (Const (c, T)); T end;
   980   in ctxt |> (map_consts o apfst) (Consts.constrain (c, Option.map prepT opt_T)) end;
   981 
   982 fun add_abbrev mode tags (c, raw_t) ctxt =
   983   let
   984     val t0 = cert_term (ctxt |> set_mode mode_abbrev) raw_t
   985       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   986     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
   987     val ((lhs, rhs), consts') = consts_of ctxt
   988       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode tags (c, t);
   989   in
   990     ctxt
   991     |> (map_consts o apfst) (K consts')
   992     |> Variable.declare_term rhs
   993     |> pair (lhs, rhs)
   994   end;
   995 
   996 fun revert_abbrev mode c = (map_consts o apfst) (Consts.revert_abbrev mode c);
   997 
   998 
   999 (* fixes *)
  1000 
  1001 local
  1002 
  1003 fun prep_mixfix (x, T, mx) =
  1004   if mx <> NoSyn andalso mx <> Structure andalso
  1005       (can Name.dest_internal x orelse can Name.dest_skolem x) then
  1006     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
  1007   else (true, (x, T, mx));
  1008 
  1009 fun gen_fixes prep raw_vars ctxt =
  1010   let
  1011     val (vars, _) = prep raw_vars ctxt;
  1012     val (xs', ctxt') = Variable.add_fixes (map #1 vars) ctxt;
  1013   in
  1014     ctxt'
  1015     |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
  1016     |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix)
  1017     |> pair xs'
  1018   end;
  1019 
  1020 in
  1021 
  1022 val add_fixes = gen_fixes read_vars;
  1023 val add_fixes_i = gen_fixes cert_vars;
  1024 
  1025 end;
  1026 
  1027 
  1028 (* fixes vs. frees *)
  1029 
  1030 fun auto_fixes (arg as (ctxt, (propss, x))) =
  1031   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
  1032 
  1033 fun bind_fixes xs ctxt =
  1034   let
  1035     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (x, NONE, NoSyn)) xs);
  1036     fun bind (t as Free (x, T)) =
  1037           if member (op =) xs x then
  1038             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1039           else t
  1040       | bind (t $ u) = bind t $ bind u
  1041       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1042       | bind a = a;
  1043   in (bind, ctxt') end;
  1044 
  1045 
  1046 
  1047 (** assumptions **)
  1048 
  1049 local
  1050 
  1051 fun gen_assms prepp exp args ctxt =
  1052   let
  1053     val cert = Thm.cterm_of (theory_of ctxt);
  1054     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1055     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1056     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1057   in
  1058     ctxt2
  1059     |> auto_bind_facts (flat propss)
  1060     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1061   end;
  1062 
  1063 in
  1064 
  1065 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1066 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1067 
  1068 end;
  1069 
  1070 
  1071 
  1072 (** cases **)
  1073 
  1074 local
  1075 
  1076 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1077 
  1078 fun add_case _ ("", _) cases = cases
  1079   | add_case _ (name, NONE) cases = rem_case name cases
  1080   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1081 
  1082 fun prep_case name fxs c =
  1083   let
  1084     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1085       | replace [] ys = ys
  1086       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1087     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1088     val fixes' = replace fxs fixes;
  1089     val binds' = map drop_schematic binds;
  1090   in
  1091     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1092       null (fold (fold Term.add_vars o snd) assumes []) then
  1093         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1094     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1095   end;
  1096 
  1097 fun fix (x, T) ctxt =
  1098   let
  1099     val (bind, ctxt') = bind_fixes [x] ctxt;
  1100     val t = bind (Free (x, T));
  1101   in (t, ctxt' |> Variable.declare_constraints t) end;
  1102 
  1103 in
  1104 
  1105 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1106 
  1107 fun case_result c ctxt =
  1108   let
  1109     val RuleCases.Case {fixes, ...} = c;
  1110     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1111     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1112   in
  1113     ctxt'
  1114     |> add_binds_i (map drop_schematic binds)
  1115     |> add_cases true (map (apsnd SOME) cases)
  1116     |> pair (assumes, (binds, cases))
  1117   end;
  1118 
  1119 val apply_case = apfst fst oo case_result;
  1120 
  1121 fun get_case ctxt name xs =
  1122   (case AList.lookup (op =) (cases_of ctxt) name of
  1123     NONE => error ("Unknown case: " ^ quote name)
  1124   | SOME (c, _) => prep_case name xs c);
  1125 
  1126 end;
  1127 
  1128 
  1129 
  1130 (** print context information **)
  1131 
  1132 val debug = ref false;
  1133 
  1134 val verbose = ref false;
  1135 fun verb f x = if ! verbose then f (x ()) else [];
  1136 
  1137 fun setmp_verbose f x = Library.setmp verbose true f x;
  1138 
  1139 
  1140 (* local syntax *)
  1141 
  1142 val print_syntax = Syntax.print_syntax o syn_of;
  1143 
  1144 
  1145 (* abbreviations *)
  1146 
  1147 fun pretty_abbrevs show_globals ctxt =
  1148   let
  1149     val ((space, consts), (_, globals)) =
  1150       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1151     fun add_abbr (_, (_, NONE)) = I
  1152       | add_abbr (c, (T, SOME t)) =
  1153           if not show_globals andalso Symtab.defined globals c then I
  1154           else cons (c, Logic.mk_equals (Const (c, T), t));
  1155     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1156   in
  1157     if null abbrevs andalso not (! verbose) then []
  1158     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1159   end;
  1160 
  1161 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1162 
  1163 
  1164 (* term bindings *)
  1165 
  1166 fun pretty_binds ctxt =
  1167   let
  1168     val binds = Variable.binds_of ctxt;
  1169     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1170   in
  1171     if Vartab.is_empty binds andalso not (! verbose) then []
  1172     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1173   end;
  1174 
  1175 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1176 
  1177 
  1178 (* local theorems *)
  1179 
  1180 fun pretty_lthms ctxt =
  1181   let
  1182     val local_facts = facts_of ctxt;
  1183     val props = Facts.props local_facts;
  1184     val facts =
  1185       (if null props then [] else [("unnamed", props)]) @
  1186       Facts.extern_static [] local_facts;
  1187   in
  1188     if null facts andalso not (! verbose) then []
  1189     else [Pretty.big_list "facts:" (map (pretty_fact ctxt) facts)]
  1190   end;
  1191 
  1192 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1193 
  1194 
  1195 (* local contexts *)
  1196 
  1197 local
  1198 
  1199 fun pretty_case (name, (fixes, ((asms, (lets, cs)), ctxt))) =
  1200   let
  1201     val prt_term = Syntax.pretty_term ctxt;
  1202 
  1203     fun prt_let (xi, t) = Pretty.block
  1204       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1205         Pretty.quote (prt_term t)];
  1206 
  1207     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1208       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1209 
  1210     fun prt_sect _ _ _ [] = []
  1211       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1212             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1213   in
  1214     Pretty.block (Pretty.fbreaks
  1215       (Pretty.str (name ^ ":") ::
  1216         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1217         prt_sect "let" [Pretty.str "and"] prt_let
  1218           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1219         (if forall (null o #2) asms then []
  1220           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1221         prt_sect "subcases:" [] (Pretty.str o fst) cs))
  1222   end;
  1223 
  1224 in
  1225 
  1226 fun pretty_cases ctxt =
  1227   let
  1228     fun add_case (_, (_, false)) = I
  1229       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1230           cons (name, (fixes, case_result c ctxt));
  1231     val cases = fold add_case (cases_of ctxt) [];
  1232   in
  1233     if null cases andalso not (! verbose) then []
  1234     else [Pretty.big_list "cases:" (map pretty_case cases)]
  1235   end;
  1236 
  1237 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1238 
  1239 end;
  1240 
  1241 
  1242 (* core context *)
  1243 
  1244 val prems_limit = ref ~1;
  1245 
  1246 fun pretty_ctxt ctxt =
  1247   if ! prems_limit < 0 andalso not (! debug) then []
  1248   else
  1249     let
  1250       val prt_term = Syntax.pretty_term ctxt;
  1251 
  1252       (*structures*)
  1253       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1254       val prt_structs = if null structs then []
  1255         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1256           Pretty.commas (map Pretty.str structs))];
  1257 
  1258       (*fixes*)
  1259       fun prt_fix (x, x') =
  1260         if x = x' then Pretty.str x
  1261         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1262       val fixes =
  1263         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1264           (Variable.fixes_of ctxt));
  1265       val prt_fixes = if null fixes then []
  1266         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1267           Pretty.commas (map prt_fix fixes))];
  1268 
  1269       (*prems*)
  1270       val prems = Assumption.prems_of ctxt;
  1271       val len = length prems;
  1272       val suppressed = len - ! prems_limit;
  1273       val prt_prems = if null prems then []
  1274         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1275           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1276     in prt_structs @ prt_fixes @ prt_prems end;
  1277 
  1278 
  1279 (* main context *)
  1280 
  1281 fun pretty_context ctxt =
  1282   let
  1283     val prt_term = Syntax.pretty_term ctxt;
  1284     val prt_typ = Syntax.pretty_typ ctxt;
  1285     val prt_sort = Syntax.pretty_sort ctxt;
  1286 
  1287     (*theory*)
  1288     val pretty_thy = Pretty.block
  1289       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1290 
  1291     (*defaults*)
  1292     fun prt_atom prt prtT (x, X) = Pretty.block
  1293       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1294 
  1295     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1296       | prt_var xi = prt_term (Syntax.var xi);
  1297 
  1298     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1299       | prt_varT xi = prt_typ (TVar (xi, []));
  1300 
  1301     val prt_defT = prt_atom prt_var prt_typ;
  1302     val prt_defS = prt_atom prt_varT prt_sort;
  1303 
  1304     val (types, sorts) = Variable.constraints_of ctxt;
  1305   in
  1306     verb single (K pretty_thy) @
  1307     pretty_ctxt ctxt @
  1308     verb (pretty_abbrevs false) (K ctxt) @
  1309     verb pretty_binds (K ctxt) @
  1310     verb pretty_lthms (K ctxt) @
  1311     verb pretty_cases (K ctxt) @
  1312     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1313     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1314   end;
  1315 
  1316 end;