src/Pure/axclass.ML
author wenzelm
Tue May 31 11:53:13 2005 +0200 (2005-05-31 ago)
changeset 16122 864fda4a4056
parent 15973 5fd94d84470f
child 16180 a51be5cbd81d
permissions -rw-r--r--
renamed cond_extern to extern;
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Axiomatic type class package.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val quiet_mode: bool ref
    11   val print_axclasses: theory -> unit
    12   val add_axclass: bclass * xclass list -> ((bstring * string) * Attrib.src list) list
    13     -> theory -> theory * {intro: thm, axioms: thm list}
    14   val add_axclass_i: bclass * class list -> ((bstring * term) * theory attribute list) list
    15     -> theory -> theory * {intro: thm, axioms: thm list}
    16   val add_classrel_thms: thm list -> theory -> theory
    17   val add_arity_thms: thm list -> theory -> theory
    18   val add_inst_subclass: xclass * xclass -> tactic -> theory -> theory
    19   val add_inst_subclass_i: class * class -> tactic -> theory -> theory
    20   val add_inst_arity: xstring * string list * string -> tactic -> theory -> theory
    21   val add_inst_arity_i: string * sort list * sort -> tactic -> theory -> theory
    22   val instance_subclass_proof: xclass * xclass -> bool -> theory -> ProofHistory.T
    23   val instance_subclass_proof_i: class * class -> bool -> theory -> ProofHistory.T
    24   val instance_arity_proof: xstring * string list * string -> bool -> theory -> ProofHistory.T
    25   val instance_arity_proof_i: string * sort list * sort -> bool -> theory -> ProofHistory.T
    26   val intro_classes_tac: thm list -> tactic
    27   val default_intro_classes_tac: thm list -> tactic
    28 
    29   (*legacy interfaces*)
    30   val axclass_tac: thm list -> tactic
    31   val add_inst_subclass_x: xclass * xclass -> string list -> thm list
    32     -> tactic option -> theory -> theory
    33   val add_inst_arity_x: xstring * string list * string -> string list
    34     -> thm list -> tactic option -> theory -> theory
    35 end;
    36 
    37 structure AxClass: AX_CLASS =
    38 struct
    39 
    40 
    41 (** utilities **)
    42 
    43 (* messages *)
    44 
    45 val quiet_mode = ref false;
    46 fun message s = if ! quiet_mode then () else writeln s;
    47 
    48 
    49 (* type vars *)
    50 
    51 fun map_typ_frees f (Type (t, tys)) = Type (t, map (map_typ_frees f) tys)
    52   | map_typ_frees f (TFree a) = f a
    53   | map_typ_frees _ a = a;
    54 
    55 val map_term_tfrees = map_term_types o map_typ_frees;
    56 
    57 fun aT S = TFree ("'a", S);
    58 
    59 fun dest_varT (TFree (x, S)) = ((x, ~1), S)
    60   | dest_varT (TVar xi_S) = xi_S
    61   | dest_varT T = raise TYPE ("dest_varT", [T], []);
    62 
    63 
    64 
    65 (** abstract syntax operations **)
    66 
    67 (* names *)
    68 
    69 fun intro_name c = c ^ "I";
    70 val introN = "intro";
    71 val axiomsN = "axioms";
    72 
    73 
    74 (* subclass relations as terms *)
    75 
    76 fun mk_classrel (c1, c2) = Logic.mk_inclass (aT [c1], c2);
    77 
    78 fun dest_classrel tm =
    79   let
    80     fun err () = raise TERM ("dest_classrel", [tm]);
    81 
    82     val (ty, c2) = Logic.dest_inclass tm handle TERM _ => err ();
    83     val c1 = (case dest_varT ty of (_, [c]) => c | _ => err ())
    84       handle TYPE _ => err ();
    85   in (c1, c2) end;
    86 
    87 
    88 (* arities as terms *)
    89 
    90 fun mk_arity (t, Ss, c) =
    91   let
    92     val tfrees = ListPair.map TFree (Term.invent_names [] "'a" (length Ss), Ss);
    93   in Logic.mk_inclass (Type (t, tfrees), c) end;
    94 
    95 fun mk_arities (t, Ss, S) = map (fn c => mk_arity (t, Ss, c)) S;
    96 
    97 fun dest_arity tm =
    98   let
    99     fun err () = raise TERM ("dest_arity", [tm]);
   100 
   101     val (ty, c) = Logic.dest_inclass tm handle TERM _ => err ();
   102     val (t, tvars) =
   103       (case ty of
   104         Type (t, tys) => (t, map dest_varT tys handle TYPE _ => err ())
   105       | _ => err ());
   106     val ss =
   107       if null (gen_duplicates eq_fst tvars)
   108       then map snd tvars else err ();
   109   in (t, ss, c) end;
   110 
   111 
   112 
   113 (** axclass info **)
   114 
   115 (* data kind 'Pure/axclasses' *)
   116 
   117 type axclass_info =
   118   {super_classes: class list,
   119     intro: thm,
   120     axioms: thm list};
   121 
   122 structure AxclassesArgs =
   123 struct
   124   val name = "Pure/axclasses";
   125   type T = axclass_info Symtab.table;
   126 
   127   val empty = Symtab.empty;
   128   val copy = I;
   129   val prep_ext = I;
   130   fun merge (tab1, tab2) = Symtab.merge (K true) (tab1, tab2);
   131 
   132   fun print sg tab =
   133     let
   134       val ext_class = Sign.extern sg Sign.classK;
   135       val ext_thm = PureThy.extern_thm_sg sg;
   136 
   137       fun pretty_class c cs = Pretty.block
   138         (Pretty.str (ext_class c) :: Pretty.str " <" :: Pretty.brk 1 ::
   139           Pretty.breaks (map (Pretty.str o ext_class) cs));
   140 
   141       fun pretty_thms name thms = Pretty.big_list (name ^ ":")
   142         (map (Display.pretty_thm_sg sg) thms);
   143 
   144       fun pretty_axclass (name, {super_classes, intro, axioms}) = Pretty.block (Pretty.fbreaks
   145         [pretty_class name super_classes, pretty_thms introN [intro], pretty_thms axiomsN axioms]);
   146     in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest tab))) end;
   147 end;
   148 
   149 structure AxclassesData = TheoryDataFun(AxclassesArgs);
   150 val _ = Context.add_setup [AxclassesData.init];
   151 val print_axclasses = AxclassesData.print;
   152 
   153 
   154 (* get and put data *)
   155 
   156 fun lookup_axclass_info_sg sg c = Symtab.lookup (AxclassesData.get_sg sg, c);
   157 
   158 fun get_axclass_info thy c =
   159   (case lookup_axclass_info_sg (Theory.sign_of thy) c of
   160     NONE => error ("Unknown axclass " ^ quote c)
   161   | SOME info => info);
   162 
   163 fun put_axclass_info c info thy =
   164   thy |> AxclassesData.put (Symtab.update ((c, info), AxclassesData.get thy));
   165 
   166 
   167 (* class_axms *)
   168 
   169 fun class_axms sign =
   170   let val classes = Sign.classes sign in
   171     map (Thm.class_triv sign) classes @
   172     List.mapPartial (Option.map #intro o lookup_axclass_info_sg sign) classes
   173   end;
   174 
   175 
   176 
   177 (** add axiomatic type classes **)
   178 
   179 local
   180 
   181 fun err_bad_axsort ax c =
   182   error ("Sort constraint in axiom " ^ quote ax ^ " not supersort of " ^ quote c);
   183 
   184 fun err_bad_tfrees ax =
   185   error ("More than one type variable in axiom " ^ quote ax);
   186 
   187 fun ext_axclass prep_class prep_axm prep_att (bclass, raw_super_classes) raw_axioms_atts thy =
   188   let
   189     val sign = Theory.sign_of thy;
   190 
   191     val class = Sign.full_name sign bclass;
   192     val super_classes = map (prep_class sign) raw_super_classes;
   193     val axms = map (prep_axm sign o fst) raw_axioms_atts;
   194     val atts = map (map (prep_att thy) o snd) raw_axioms_atts;
   195 
   196     (*declare class*)
   197     val class_thy =
   198       thy |> Theory.add_classes_i [(bclass, super_classes)];
   199     val class_sign = Theory.sign_of class_thy;
   200 
   201     (*prepare abstract axioms*)
   202     fun abs_axm ax =
   203       if null (term_tfrees ax) then
   204         Logic.mk_implies (Logic.mk_inclass (aT [], class), ax)
   205       else map_term_tfrees (K (aT [class])) ax;
   206     val abs_axms = map (abs_axm o #2) axms;
   207 
   208     fun axm_sort (name, ax) =
   209       (case term_tfrees ax of
   210         [] => []
   211       | [(_, S)] => if Sign.subsort class_sign ([class], S) then S else err_bad_axsort name class
   212       | _ => err_bad_tfrees name);
   213     val axS = Sign.certify_sort class_sign (List.concat (map axm_sort axms));
   214 
   215     val int_axm = Logic.close_form o map_term_tfrees (K (aT axS));
   216     fun inclass c = Logic.mk_inclass (aT axS, c);
   217 
   218     val intro_axm = Logic.list_implies
   219       (map inclass super_classes @ map (int_axm o #2) axms, inclass class);
   220 
   221     (*declare axioms and rule*)
   222     val (axms_thy, ([intro], [axioms])) =
   223       class_thy
   224       |> Theory.add_path bclass
   225       |> PureThy.add_axioms_i [Thm.no_attributes (introN, intro_axm)]
   226       |>>> PureThy.add_axiomss_i [Thm.no_attributes (axiomsN, abs_axms)];
   227     val info = {super_classes = super_classes, intro = intro, axioms = axioms};
   228 
   229     (*store info*)
   230     val final_thy =
   231       axms_thy
   232       |> (#1 o PureThy.add_thms ((map #1 axms ~~ axioms) ~~ atts))
   233       |> Theory.parent_path
   234       |> (#1 o PureThy.add_thms [Thm.no_attributes (intro_name bclass, intro)])
   235       |> put_axclass_info class info;
   236   in (final_thy, {intro = intro, axioms = axioms}) end;
   237 
   238 in
   239 
   240 val add_axclass = ext_axclass Sign.intern_class Theory.read_axm Attrib.global_attribute;
   241 val add_axclass_i = ext_axclass (K I) Theory.cert_axm (K I);
   242 
   243 end;
   244 
   245 
   246 
   247 (** proven class instantiation **)
   248 
   249 (* add thms to type signature *)
   250 
   251 fun add_classrel_thms thms thy =
   252   let
   253     fun prep_thm thm =
   254       let
   255         val prop = Drule.plain_prop_of (Thm.transfer thy thm);
   256         val (c1, c2) = dest_classrel prop handle TERM _ =>
   257           raise THM ("add_classrel_thms: not a class relation", 0, [thm]);
   258       in (c1, c2) end;
   259   in Theory.add_classrel_i (map prep_thm thms) thy end;
   260 
   261 fun add_arity_thms thms thy =
   262   let
   263     fun prep_thm thm =
   264       let
   265         val prop = Drule.plain_prop_of (Thm.transfer thy thm);
   266         val (t, ss, c) = dest_arity prop handle TERM _ =>
   267           raise THM ("add_arity_thms: not an arity", 0, [thm]);
   268       in (t, ss, [c]) end;
   269   in Theory.add_arities_i (map prep_thm thms) thy end;
   270 
   271 
   272 (* prepare classes and arities *)
   273 
   274 fun read_class sg c = Sign.certify_class sg (Sign.intern_class sg c);
   275 
   276 fun test_classrel sg cc = (Type.add_classrel (Sign.pp sg) [cc] (Sign.tsig_of sg); cc);
   277 fun cert_classrel sg = test_classrel sg o Library.pairself (Sign.certify_class sg);
   278 fun read_classrel sg = test_classrel sg o Library.pairself (read_class sg);
   279 
   280 fun test_arity sg ar = (Type.add_arities (Sign.pp sg) [ar] (Sign.tsig_of sg); ar);
   281 
   282 fun prep_arity prep_tycon prep_sort prep sg (t, Ss, x) =
   283   test_arity sg (prep_tycon sg t, map (prep_sort sg) Ss, prep sg x);
   284 
   285 val read_arity = prep_arity Sign.intern_tycon Sign.read_sort Sign.read_sort;
   286 val cert_arity = prep_arity (K I) Sign.certify_sort Sign.certify_sort;
   287 
   288 
   289 (* instance declarations -- tactical proof *)
   290 
   291 local
   292 
   293 fun ext_inst_subclass prep_classrel raw_cc tac thy =
   294   let
   295     val sign = Theory.sign_of thy;
   296     val (c1, c2) = prep_classrel sign raw_cc;
   297     val txt = quote (Sign.string_of_classrel sign [c1, c2]);
   298     val _ = message ("Proving class inclusion " ^ txt ^ " ...");
   299     val th = Tactic.prove sign [] [] (mk_classrel (c1, c2)) (K tac) handle ERROR =>
   300       error ("The error(s) above occurred while trying to prove " ^ txt);
   301   in add_classrel_thms [th] thy end;
   302 
   303 fun ext_inst_arity prep_arity raw_arity tac thy =
   304   let
   305     val sign = Theory.sign_of thy;
   306     val arity = prep_arity sign raw_arity;
   307     val txt = quote (Sign.string_of_arity sign arity);
   308     val _ = message ("Proving type arity " ^ txt ^ " ...");
   309     val props = (mk_arities arity);
   310     val ths = Tactic.prove_multi sign [] [] props
   311         (fn _ => Tactic.smart_conjunction_tac (length props) THEN tac)
   312       handle ERROR => error ("The error(s) above occurred while trying to prove " ^ txt);
   313   in add_arity_thms ths thy end;
   314 
   315 in
   316 
   317 val add_inst_subclass = ext_inst_subclass read_classrel;
   318 val add_inst_subclass_i = ext_inst_subclass cert_classrel;
   319 val add_inst_arity = ext_inst_arity read_arity;
   320 val add_inst_arity_i = ext_inst_arity cert_arity;
   321 
   322 end;
   323 
   324 
   325 (* instance declarations -- Isar proof *)
   326 
   327 local
   328 
   329 fun inst_proof mk_prop add_thms inst int theory =
   330   theory
   331   |> IsarThy.multi_theorem_i Drule.internalK I ProofContext.export_standard
   332     ("", [fn (thy, th) => (add_thms [th] thy, th)]) []
   333     (map (fn t => (("", []), [(t, ([], []))])) (mk_prop (Theory.sign_of theory) inst)) int;
   334 
   335 in
   336 
   337 val instance_subclass_proof =
   338   inst_proof (single oo (mk_classrel oo read_classrel)) add_classrel_thms;
   339 val instance_subclass_proof_i =
   340   inst_proof (single oo (mk_classrel oo cert_classrel)) add_classrel_thms;
   341 val instance_arity_proof = inst_proof (mk_arities oo read_arity) add_arity_thms;
   342 val instance_arity_proof_i = inst_proof (mk_arities oo cert_arity) add_arity_thms;
   343 
   344 end;
   345 
   346 
   347 (* tactics and methods *)
   348 
   349 fun intro_classes_tac facts st =
   350   (ALLGOALS (Method.insert_tac facts THEN'
   351       REPEAT_ALL_NEW (resolve_tac (class_axms (Thm.sign_of_thm st))))
   352     THEN Tactic.distinct_subgoals_tac) st;
   353 
   354 fun default_intro_classes_tac [] = intro_classes_tac []
   355   | default_intro_classes_tac _ = Tactical.no_tac;    (*no error message!*)
   356 
   357 fun default_tac rules ctxt facts =
   358   HEADGOAL (Method.some_rule_tac rules ctxt facts) ORELSE
   359     default_intro_classes_tac facts;
   360 
   361 val _ = Context.add_setup [Method.add_methods
   362  [("intro_classes", Method.no_args (Method.METHOD intro_classes_tac),
   363    "back-chain introduction rules of axiomatic type classes"),
   364   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac), "apply some intro/elim rule")]];
   365 
   366 
   367 
   368 (** outer syntax **)
   369 
   370 local structure P = OuterParse and K = OuterSyntax.Keyword in
   371 
   372 val axclassP =
   373   OuterSyntax.command "axclass" "define axiomatic type class" K.thy_decl
   374     ((P.name -- Scan.optional ((P.$$$ "\\<subseteq>" || P.$$$ "<") |--
   375         P.!!! (P.list1 P.xname)) []) -- Scan.repeat P.spec_name
   376       >> (fn (cls, axs) => Toplevel.theory (#1 o add_axclass cls axs)));
   377 
   378 val instanceP =
   379   OuterSyntax.command "instance" "prove type arity or subclass relation" K.thy_goal
   380     ((P.xname -- ((P.$$$ "\\<subseteq>" || P.$$$ "<") |-- P.xname) >> instance_subclass_proof ||
   381       (P.xname -- (P.$$$ "::" |-- P.arity) >> P.triple2) >> instance_arity_proof)
   382       >> (Toplevel.print oo Toplevel.theory_to_proof));
   383 
   384 val _ = OuterSyntax.add_parsers [axclassP, instanceP];
   385 
   386 end;
   387 
   388 
   389 
   390 (** old-style instantiation proofs **)
   391 
   392 (* axclass_tac *)
   393 
   394 (*(1) repeatedly resolve goals of form "OFCLASS(ty, c_class)",
   395       try class_trivs first, then "cI" axioms
   396   (2) rewrite goals using user supplied definitions
   397   (3) repeatedly resolve goals with user supplied non-definitions*)
   398 
   399 val is_def = Logic.is_equals o #prop o rep_thm;
   400 
   401 fun axclass_tac thms =
   402   let
   403     val defs = List.filter is_def thms;
   404     val non_defs = filter_out is_def thms;
   405   in
   406     intro_classes_tac [] THEN
   407     TRY (rewrite_goals_tac defs) THEN
   408     TRY (REPEAT_FIRST (fn i => assume_tac i ORELSE resolve_tac non_defs i))
   409   end;
   410 
   411 
   412 (* instance declarations *)
   413 
   414 local
   415 
   416 fun prove mk_prop str_of sign prop thms usr_tac =
   417   (Tactic.prove sign [] [] (mk_prop prop)
   418       (K (axclass_tac thms THEN (if_none usr_tac all_tac)))
   419     handle ERROR => error ("The error(s) above occurred while trying to prove " ^
   420      quote (str_of sign prop))) |> Drule.standard;
   421 
   422 val prove_subclass = prove mk_classrel (fn sg => fn (c1, c2) =>
   423   Pretty.string_of_classrel (Sign.pp sg) [c1, c2]);
   424 
   425 val prove_arity = prove mk_arity (fn sg => fn (t, Ss, c) =>
   426   Pretty.string_of_arity (Sign.pp sg) (t, Ss, [c]));
   427 
   428 fun witnesses thy names thms =
   429   PureThy.get_thmss thy (map (rpair NONE) names) @ thms @ List.filter is_def (map snd (axioms_of thy));
   430 
   431 in
   432 
   433 fun add_inst_subclass_x raw_c1_c2 names thms usr_tac thy =
   434   let
   435     val sign = Theory.sign_of thy;
   436     val (c1, c2) = read_classrel sign raw_c1_c2;
   437   in
   438     message ("Proving class inclusion " ^ quote (Sign.string_of_classrel sign [c1, c2]) ^ " ...");
   439     thy |> add_classrel_thms [prove_subclass sign (c1, c2) (witnesses thy names thms) usr_tac]
   440   end;
   441 
   442 fun add_inst_arity_x raw_arity names thms usr_tac thy =
   443   let
   444     val sign = Theory.sign_of thy;
   445     val (t, Ss, cs) = read_arity sign raw_arity;
   446     val wthms = witnesses thy names thms;
   447     fun prove c =
   448      (message ("Proving type arity " ^
   449         quote (Sign.string_of_arity sign (t, Ss, [c])) ^ " ...");
   450         prove_arity sign (t, Ss, c) wthms usr_tac);
   451   in add_arity_thms (map prove cs) thy end;
   452 
   453 end;
   454 
   455 end;