src/Pure/Isar/proof.ML
author wenzelm
Mon Mar 04 15:03:46 2013 +0100 (2013-03-04 ago)
changeset 51332 8707df0b0255
parent 51318 e6524a89c9e3
child 51383 50fb0f35a14f
permissions -rw-r--r--
refined parallel_proofs = 2: fork whole Isar sub-proofs, not just terminal ones;
refined parallel_proofs = 3: fork terminal proofs, as poor man's parallelization in interactive mode;
     1 (*  Title:      Pure/Isar/proof.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The Isar/VM proof language interpreter: maintains a structured flow of
     5 context elements, goals, refinements, and facts.
     6 *)
     7 
     8 signature PROOF =
     9 sig
    10   type context = Proof.context
    11   type method = Method.method
    12   type state
    13   val init: context -> state
    14   val level: state -> int
    15   val assert_bottom: bool -> state -> state
    16   val context_of: state -> context
    17   val theory_of: state -> theory
    18   val map_context: (context -> context) -> state -> state
    19   val map_context_result : (context -> 'a * context) -> state -> 'a * state
    20   val map_contexts: (context -> context) -> state -> state
    21   val propagate_ml_env: state -> state
    22   val bind_terms: (indexname * term option) list -> state -> state
    23   val put_thms: bool -> string * thm list option -> state -> state
    24   val the_facts: state -> thm list
    25   val the_fact: state -> thm
    26   val set_facts: thm list -> state -> state
    27   val reset_facts: state -> state
    28   val assert_forward: state -> state
    29   val assert_chain: state -> state
    30   val assert_forward_or_chain: state -> state
    31   val assert_backward: state -> state
    32   val assert_no_chain: state -> state
    33   val enter_forward: state -> state
    34   val goal_message: (unit -> Pretty.T) -> state -> state
    35   val pretty_state: int -> state -> Pretty.T list
    36   val refine: Method.text -> state -> state Seq.seq
    37   val refine_end: Method.text -> state -> state Seq.seq
    38   val refine_insert: thm list -> state -> state
    39   val refine_goals: (context -> thm -> unit) -> context -> thm list -> state -> state Seq.seq
    40   val raw_goal: state -> {context: context, facts: thm list, goal: thm}
    41   val goal: state -> {context: context, facts: thm list, goal: thm}
    42   val simple_goal: state -> {context: context, goal: thm}
    43   val status_markup: state -> Markup.T
    44   val let_bind: (term list * term) list -> state -> state
    45   val let_bind_cmd: (string list * string) list -> state -> state
    46   val write: Syntax.mode -> (term * mixfix) list -> state -> state
    47   val write_cmd: Syntax.mode -> (string * mixfix) list -> state -> state
    48   val fix: (binding * typ option * mixfix) list -> state -> state
    49   val fix_cmd: (binding * string option * mixfix) list -> state -> state
    50   val assm: Assumption.export ->
    51     (Thm.binding * (term * term list) list) list -> state -> state
    52   val assm_cmd: Assumption.export ->
    53     (Attrib.binding * (string * string list) list) list -> state -> state
    54   val assume: (Thm.binding * (term * term list) list) list -> state -> state
    55   val assume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    56   val presume: (Thm.binding * (term * term list) list) list -> state -> state
    57   val presume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    58   val def: (Thm.binding * ((binding * mixfix) * (term * term list))) list -> state -> state
    59   val def_cmd: (Attrib.binding * ((binding * mixfix) * (string * string list))) list -> state -> state
    60   val chain: state -> state
    61   val chain_facts: thm list -> state -> state
    62   val note_thmss: (Thm.binding * (thm list * attribute list) list) list -> state -> state
    63   val note_thmss_cmd: (Attrib.binding * (Facts.ref * Attrib.src list) list) list -> state -> state
    64   val from_thmss: ((thm list * attribute list) list) list -> state -> state
    65   val from_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    66   val with_thmss: ((thm list * attribute list) list) list -> state -> state
    67   val with_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    68   val using: ((thm list * attribute list) list) list -> state -> state
    69   val using_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    70   val unfolding: ((thm list * attribute list) list) list -> state -> state
    71   val unfolding_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    72   val invoke_case: string * binding option list * attribute list -> state -> state
    73   val invoke_case_cmd: string * binding option list * Attrib.src list -> state -> state
    74   val begin_block: state -> state
    75   val next_block: state -> state
    76   val end_block: state -> state
    77   val begin_notepad: context -> state
    78   val end_notepad: state -> context
    79   val proof: Method.text option -> state -> state Seq.seq
    80   val proof_results: Method.text_range option -> state -> state Seq.result Seq.seq
    81   val defer: int -> state -> state
    82   val prefer: int -> state -> state
    83   val apply: Method.text -> state -> state Seq.seq
    84   val apply_end: Method.text -> state -> state Seq.seq
    85   val apply_results: Method.text_range -> state -> state Seq.result Seq.seq
    86   val apply_end_results: Method.text_range -> state -> state Seq.result Seq.seq
    87   val local_goal: (context -> ((string * string) * (string * thm list) list) -> unit) ->
    88     (context -> 'a -> attribute) ->
    89     ('b list -> context -> (term list list * (context -> context)) * context) ->
    90     string -> Method.text option -> (thm list list -> state -> state) ->
    91     ((binding * 'a list) * 'b) list -> state -> state
    92   val local_qed: Method.text_range option * bool -> state -> state
    93   val theorem: Method.text option -> (thm list list -> context -> context) ->
    94     (term * term list) list list -> context -> state
    95   val theorem_cmd: Method.text option -> (thm list list -> context -> context) ->
    96     (string * string list) list list -> context -> state
    97   val global_qed: Method.text_range option * bool -> state -> context
    98   val local_terminal_proof: Method.text_range * Method.text_range option -> state -> state
    99   val local_default_proof: state -> state
   100   val local_immediate_proof: state -> state
   101   val local_skip_proof: bool -> state -> state
   102   val local_done_proof: state -> state
   103   val global_terminal_proof: Method.text_range * Method.text_range option -> state -> context
   104   val global_default_proof: state -> context
   105   val global_immediate_proof: state -> context
   106   val global_skip_proof: bool -> state -> context
   107   val global_done_proof: state -> context
   108   val have: Method.text option -> (thm list list -> state -> state) ->
   109     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   110   val have_cmd: Method.text option -> (thm list list -> state -> state) ->
   111     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   112   val show: Method.text option -> (thm list list -> state -> state) ->
   113     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   114   val show_cmd: Method.text option -> (thm list list -> state -> state) ->
   115     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   116   val schematic_goal: state -> bool
   117   val is_relevant: state -> bool
   118   val future_proof: (state -> ('a * context) future) -> state -> 'a future * state
   119   val local_future_terminal_proof: Method.text_range * Method.text_range option -> bool ->
   120     state -> state
   121   val global_future_terminal_proof: Method.text_range * Method.text_range option -> bool ->
   122     state -> context
   123 end;
   124 
   125 structure Proof: PROOF =
   126 struct
   127 
   128 type context = Proof.context;
   129 type method = Method.method;
   130 
   131 
   132 (** proof state **)
   133 
   134 (* datatype state *)
   135 
   136 datatype mode = Forward | Chain | Backward;
   137 
   138 datatype state =
   139   State of node Stack.T
   140 and node =
   141   Node of
   142    {context: context,
   143     facts: thm list option,
   144     mode: mode,
   145     goal: goal option}
   146 and goal =
   147   Goal of
   148    {statement: (string * Position.T) * term list list * term,
   149       (*goal kind and statement (starting with vars), initial proposition*)
   150     messages: (unit -> Pretty.T) list,    (*persistent messages (hints etc.)*)
   151     using: thm list,                      (*goal facts*)
   152     goal: thm,                            (*subgoals ==> statement*)
   153     before_qed: Method.text option,
   154     after_qed:
   155       (thm list list -> state -> state) *
   156       (thm list list -> context -> context)};
   157 
   158 fun make_goal (statement, messages, using, goal, before_qed, after_qed) =
   159   Goal {statement = statement, messages = messages, using = using, goal = goal,
   160     before_qed = before_qed, after_qed = after_qed};
   161 
   162 fun make_node (context, facts, mode, goal) =
   163   Node {context = context, facts = facts, mode = mode, goal = goal};
   164 
   165 fun map_node f (Node {context, facts, mode, goal}) =
   166   make_node (f (context, facts, mode, goal));
   167 
   168 val init_context =
   169   Proof_Context.set_stmt true #>
   170   Proof_Context.map_naming (K Name_Space.local_naming);
   171 
   172 fun init ctxt =
   173   State (Stack.init (make_node (init_context ctxt, NONE, Forward, NONE)));
   174 
   175 fun top (State st) = Stack.top st |> (fn Node node => node);
   176 fun map_top f (State st) = State (Stack.map_top (map_node f) st);
   177 fun map_all f (State st) = State (Stack.map_all (map_node f) st);
   178 
   179 
   180 
   181 (** basic proof state operations **)
   182 
   183 (* block structure *)
   184 
   185 fun open_block (State st) = State (Stack.push st);
   186 
   187 fun close_block (State st) = State (Stack.pop st)
   188   handle List.Empty => error "Unbalanced block parentheses";
   189 
   190 fun level (State st) = Stack.level st;
   191 
   192 fun assert_bottom b state =
   193   let val b' = level state <= 2 in
   194     if b andalso not b' then error "Not at bottom of proof"
   195     else if not b andalso b' then error "Already at bottom of proof"
   196     else state
   197   end;
   198 
   199 
   200 (* context *)
   201 
   202 val context_of = #context o top;
   203 val theory_of = Proof_Context.theory_of o context_of;
   204 
   205 fun map_node_context f =
   206   map_node (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   207 
   208 fun map_context f =
   209   map_top (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   210 
   211 fun map_context_result f state =
   212   f (context_of state) ||> (fn ctxt => map_context (K ctxt) state);
   213 
   214 fun map_contexts f = map_all (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   215 
   216 fun propagate_ml_env state = map_contexts
   217   (Context.proof_map (ML_Env.inherit (Context.Proof (context_of state)))) state;
   218 
   219 val bind_terms = map_context o Proof_Context.bind_terms;
   220 val put_thms = map_context oo Proof_Context.put_thms;
   221 
   222 
   223 (* facts *)
   224 
   225 val get_facts = #facts o top;
   226 
   227 fun the_facts state =
   228   (case get_facts state of SOME facts => facts
   229   | NONE => error "No current facts available");
   230 
   231 fun the_fact state =
   232   (case the_facts state of [thm] => thm
   233   | _ => error "Single theorem expected");
   234 
   235 fun put_facts facts =
   236   map_top (fn (ctxt, _, mode, goal) => (ctxt, facts, mode, goal)) #>
   237   put_thms true (Auto_Bind.thisN, facts);
   238 
   239 val set_facts = put_facts o SOME;
   240 val reset_facts = put_facts NONE;
   241 
   242 fun these_factss more_facts (named_factss, state) =
   243   (named_factss, state |> set_facts (maps snd named_factss @ more_facts));
   244 
   245 fun export_facts inner outer =
   246   (case get_facts inner of
   247     NONE => reset_facts outer
   248   | SOME thms =>
   249       thms
   250       |> Proof_Context.export (context_of inner) (context_of outer)
   251       |> (fn ths => set_facts ths outer));
   252 
   253 
   254 (* mode *)
   255 
   256 val get_mode = #mode o top;
   257 fun put_mode mode = map_top (fn (ctxt, facts, _, goal) => (ctxt, facts, mode, goal));
   258 
   259 val mode_name = (fn Forward => "state" | Chain => "chain" | Backward => "prove");
   260 
   261 fun assert_mode pred state =
   262   let val mode = get_mode state in
   263     if pred mode then state
   264     else error ("Illegal application of proof command in " ^ quote (mode_name mode) ^ " mode")
   265   end;
   266 
   267 val assert_forward = assert_mode (fn mode => mode = Forward);
   268 val assert_chain = assert_mode (fn mode => mode = Chain);
   269 val assert_forward_or_chain = assert_mode (fn mode => mode = Forward orelse mode = Chain);
   270 val assert_backward = assert_mode (fn mode => mode = Backward);
   271 val assert_no_chain = assert_mode (fn mode => mode <> Chain);
   272 
   273 val enter_forward = put_mode Forward;
   274 val enter_chain = put_mode Chain;
   275 val enter_backward = put_mode Backward;
   276 
   277 
   278 (* current goal *)
   279 
   280 fun current_goal state =
   281   (case top state of
   282     {context, goal = SOME (Goal goal), ...} => (context, goal)
   283   | _ => error "No current goal");
   284 
   285 fun assert_current_goal g state =
   286   let val g' = can current_goal state in
   287     if g andalso not g' then error "No goal in this block"
   288     else if not g andalso g' then error "Goal present in this block"
   289     else state
   290   end;
   291 
   292 fun put_goal goal = map_top (fn (ctxt, using, mode, _) => (ctxt, using, mode, goal));
   293 
   294 val set_goal = put_goal o SOME;
   295 val reset_goal = put_goal NONE;
   296 
   297 val before_qed = #before_qed o #2 o current_goal;
   298 
   299 
   300 (* nested goal *)
   301 
   302 fun map_goal f g h (State (Node {context, facts, mode, goal = SOME goal}, node :: nodes)) =
   303       let
   304         val Goal {statement, messages, using, goal, before_qed, after_qed} = goal;
   305         val goal' = make_goal (g (statement, messages, using, goal, before_qed, after_qed));
   306         val node' = map_node_context h node;
   307       in State (make_node (f context, facts, mode, SOME goal'), node' :: nodes) end
   308   | map_goal f g h (State (nd, node :: nodes)) =
   309       let
   310         val nd' = map_node_context f nd;
   311         val State (node', nodes') = map_goal f g h (State (node, nodes));
   312       in State (nd', node' :: nodes') end
   313   | map_goal _ _ _ state = state;
   314 
   315 fun provide_goal goal = map_goal I (fn (statement, _, using, _, before_qed, after_qed) =>
   316   (statement, [], using, goal, before_qed, after_qed)) I;
   317 
   318 fun goal_message msg = map_goal I (fn (statement, messages, using, goal, before_qed, after_qed) =>
   319   (statement, msg :: messages, using, goal, before_qed, after_qed)) I;
   320 
   321 fun using_facts using = map_goal I (fn (statement, _, _, goal, before_qed, after_qed) =>
   322   (statement, [], using, goal, before_qed, after_qed)) I;
   323 
   324 local
   325   fun find i state =
   326     (case try current_goal state of
   327       SOME (ctxt, goal) => (ctxt, (i, goal))
   328     | NONE => find (i + 1) (close_block state handle ERROR _ => error "No goal present"));
   329 in val find_goal = find 0 end;
   330 
   331 fun get_goal state =
   332   let val (ctxt, (_, {using, goal, ...})) = find_goal state
   333   in (ctxt, (using, goal)) end;
   334 
   335 
   336 
   337 (** pretty_state **)
   338 
   339 fun pretty_facts _ _ NONE = []
   340   | pretty_facts s ctxt (SOME ths) =
   341       [(Pretty.block o Pretty.fbreaks)
   342         ((if s = "" then Pretty.str "this:"
   343           else Pretty.block [Pretty.command s, Pretty.brk 1, Pretty.str "this:"]) ::
   344           map (Display.pretty_thm ctxt) ths),
   345         Pretty.str ""];
   346 
   347 fun pretty_state nr state =
   348   let
   349     val {context = ctxt, facts, mode, goal = _} = top state;
   350     val verbose = Config.get ctxt Proof_Context.verbose;
   351 
   352     fun prt_goal (SOME (_, (_,
   353       {statement = ((_, pos), _, _), messages, using, goal, before_qed = _, after_qed = _}))) =
   354           pretty_facts "using" ctxt
   355             (if mode <> Backward orelse null using then NONE else SOME using) @
   356           [Proof_Display.pretty_goal_header goal] @ Goal_Display.pretty_goals ctxt goal @
   357           (map (fn msg => Position.setmp_thread_data pos msg ()) (rev messages))
   358       | prt_goal NONE = [];
   359 
   360     val prt_ctxt =
   361       if verbose orelse mode = Forward then Proof_Context.pretty_context ctxt
   362       else if mode = Backward then Proof_Context.pretty_ctxt ctxt
   363       else [];
   364   in
   365     [Pretty.str ("proof (" ^ mode_name mode ^ "): step " ^ string_of_int nr ^
   366       (if verbose then ", depth " ^ string_of_int (level state div 2 - 1) else "")),
   367       Pretty.str ""] @
   368     (if null prt_ctxt then [] else prt_ctxt @ [Pretty.str ""]) @
   369     (if verbose orelse mode = Forward then
   370        pretty_facts "" ctxt facts @ prt_goal (try find_goal state)
   371      else if mode = Chain then pretty_facts "picking" ctxt facts
   372      else prt_goal (try find_goal state))
   373   end;
   374 
   375 
   376 
   377 (** proof steps **)
   378 
   379 (* refine via method *)
   380 
   381 local
   382 
   383 fun goalN i = "goal" ^ string_of_int i;
   384 fun goals st = map goalN (1 upto Thm.nprems_of st);
   385 
   386 fun no_goal_cases st = map (rpair NONE) (goals st);
   387 
   388 fun goal_cases st =
   389   Rule_Cases.make_common
   390     (Thm.theory_of_thm st, Thm.prop_of st) (map (rpair [] o rpair []) (goals st));
   391 
   392 fun apply_method current_context meth state =
   393   let
   394     val (goal_ctxt, (_, {statement, messages = _, using, goal, before_qed, after_qed})) =
   395       find_goal state;
   396     val ctxt = if current_context then context_of state else goal_ctxt;
   397   in
   398     Method.apply meth ctxt using goal |> Seq.map (fn (meth_cases, goal') =>
   399       state
   400       |> map_goal
   401           (Proof_Context.add_cases false (no_goal_cases goal @ goal_cases goal') #>
   402            Proof_Context.add_cases true meth_cases)
   403           (K (statement, [], using, goal', before_qed, after_qed)) I)
   404   end;
   405 
   406 fun select_goals n meth state =
   407   state
   408   |> (#2 o #2 o get_goal)
   409   |> ALLGOALS Goal.conjunction_tac
   410   |> Seq.maps (fn goal =>
   411     state
   412     |> Seq.lift provide_goal (Goal.extract 1 n goal |> Seq.maps (Goal.conjunction_tac 1))
   413     |> Seq.maps meth
   414     |> Seq.maps (fn state' => state'
   415       |> Seq.lift provide_goal (Goal.retrofit 1 n (#2 (#2 (get_goal state'))) goal))
   416     |> Seq.maps (apply_method true (K Method.succeed)));
   417 
   418 fun apply_text cc text state =
   419   let
   420     val thy = theory_of state;
   421 
   422     fun eval (Method.Basic m) = apply_method cc m
   423       | eval (Method.Source src) = apply_method cc (Method.method thy src)
   424       | eval (Method.Source_i src) = apply_method cc (Method.method_i thy src)
   425       | eval (Method.Then txts) = Seq.EVERY (map eval txts)
   426       | eval (Method.Orelse txts) = Seq.FIRST (map eval txts)
   427       | eval (Method.Try txt) = Seq.TRY (eval txt)
   428       | eval (Method.Repeat1 txt) = Seq.REPEAT1 (eval txt)
   429       | eval (Method.SelectGoals (n, txt)) = select_goals n (eval txt);
   430   in eval text state end;
   431 
   432 in
   433 
   434 val refine = apply_text true;
   435 val refine_end = apply_text false;
   436 fun refine_insert ths = Seq.hd o refine (Method.Basic (K (Method.insert ths)));
   437 
   438 end;
   439 
   440 
   441 (* refine via sub-proof *)
   442 
   443 local
   444 
   445 fun finish_tac 0 = K all_tac
   446   | finish_tac n =
   447       Goal.norm_hhf_tac THEN'
   448       SUBGOAL (fn (goal, i) =>
   449         if can Logic.unprotect (Logic.strip_assums_concl goal) then
   450           Tactic.etac Drule.protectI i THEN finish_tac (n - 1) i
   451         else finish_tac (n - 1) (i + 1));
   452 
   453 fun goal_tac rule =
   454   Goal.norm_hhf_tac THEN'
   455   Tactic.rtac rule THEN'
   456   finish_tac (Thm.nprems_of rule);
   457 
   458 fun FINDGOAL tac st =
   459   let fun find i n = if i > n then Seq.fail else Seq.APPEND (tac i, find (i + 1) n)
   460   in find 1 (Thm.nprems_of st) st end;
   461 
   462 in
   463 
   464 fun refine_goals print_rule inner raw_rules state =
   465   let
   466     val (outer, (_, goal)) = get_goal state;
   467     fun refine rule st = (print_rule outer rule; FINDGOAL (goal_tac rule) st);
   468   in
   469     raw_rules
   470     |> Proof_Context.goal_export inner outer
   471     |> (fn rules => Seq.lift provide_goal (EVERY (map refine rules) goal) state)
   472   end;
   473 
   474 end;
   475 
   476 
   477 (* conclude goal *)
   478 
   479 fun conclude_goal ctxt goal propss =
   480   let
   481     val thy = Proof_Context.theory_of ctxt;
   482     val string_of_term = Syntax.string_of_term ctxt;
   483     val string_of_thm = Display.string_of_thm ctxt;
   484 
   485     val _ = Thm.no_prems goal orelse error (Proof_Display.string_of_goal ctxt goal);
   486 
   487     val extra_hyps = Assumption.extra_hyps ctxt goal;
   488     val _ = null extra_hyps orelse
   489       error ("Additional hypotheses:\n" ^ cat_lines (map string_of_term extra_hyps));
   490 
   491     fun lost_structure () = error ("Lost goal structure:\n" ^ string_of_thm goal);
   492 
   493     val th = Goal.conclude
   494       (if length (flat propss) > 1 then Thm.norm_proof goal else goal)
   495       handle THM _ => lost_structure ();
   496     val goal_propss = filter_out null propss;
   497     val results =
   498       Conjunction.elim_balanced (length goal_propss) th
   499       |> map2 Conjunction.elim_balanced (map length goal_propss)
   500       handle THM _ => lost_structure ();
   501     val _ = Unify.matches_list thy (flat goal_propss) (map Thm.prop_of (flat results)) orelse
   502       error ("Proved a different theorem:\n" ^ string_of_thm th);
   503     val _ = Thm.check_shyps (Variable.sorts_of ctxt) th;
   504 
   505     fun recover_result ([] :: pss) thss = [] :: recover_result pss thss
   506       | recover_result (_ :: pss) (ths :: thss) = ths :: recover_result pss thss
   507       | recover_result [] [] = []
   508       | recover_result _ _ = lost_structure ();
   509   in recover_result propss results end;
   510 
   511 val finished_goal_error = "Failed to finish proof";
   512 
   513 fun finished_goal pos state =
   514   let val (ctxt, (_, goal)) = get_goal state in
   515     if Thm.no_prems goal then Seq.Result state
   516     else
   517       Seq.Error (fn () =>
   518         finished_goal_error ^ Position.here pos ^ ":\n" ^
   519           Proof_Display.string_of_goal ctxt goal)
   520   end;
   521 
   522 
   523 (* goal views -- corresponding to methods *)
   524 
   525 fun raw_goal state =
   526   let val (ctxt, (facts, goal)) = get_goal state
   527   in {context = ctxt, facts = facts, goal = goal} end;
   528 
   529 val goal = raw_goal o refine_insert [];
   530 
   531 fun simple_goal state =
   532   let
   533     val (_, (facts, _)) = get_goal state;
   534     val (ctxt, (_, goal)) = get_goal (refine_insert facts state);
   535   in {context = ctxt, goal = goal} end;
   536 
   537 fun status_markup state =
   538   (case try goal state of
   539     SOME {goal, ...} => Markup.proof_state (Thm.nprems_of goal)
   540   | NONE => Markup.empty);
   541 
   542 fun method_error kind pos state =
   543   Seq.single (Proof_Display.method_error kind pos (raw_goal state));
   544 
   545 
   546 
   547 (*** structured proof commands ***)
   548 
   549 (** context elements **)
   550 
   551 (* let bindings *)
   552 
   553 local
   554 
   555 fun gen_bind bind args state =
   556   state
   557   |> assert_forward
   558   |> map_context (bind true args #> snd)
   559   |> reset_facts;
   560 
   561 in
   562 
   563 val let_bind = gen_bind Proof_Context.match_bind_i;
   564 val let_bind_cmd = gen_bind Proof_Context.match_bind;
   565 
   566 end;
   567 
   568 
   569 (* concrete syntax *)
   570 
   571 local
   572 
   573 fun gen_write prep_arg mode args =
   574   assert_forward
   575   #> map_context (fn ctxt => ctxt |> Proof_Context.notation true mode (map (prep_arg ctxt) args))
   576   #> reset_facts;
   577 
   578 in
   579 
   580 val write = gen_write (K I);
   581 
   582 val write_cmd =
   583   gen_write (fn ctxt => fn (c, mx) =>
   584     (Proof_Context.read_const ctxt false (Mixfix.mixfixT mx) c, mx));
   585 
   586 end;
   587 
   588 
   589 (* fix *)
   590 
   591 local
   592 
   593 fun gen_fix prep_vars args =
   594   assert_forward
   595   #> map_context (fn ctxt => snd (Proof_Context.add_fixes (fst (prep_vars args ctxt)) ctxt))
   596   #> reset_facts;
   597 
   598 in
   599 
   600 val fix = gen_fix Proof_Context.cert_vars;
   601 val fix_cmd = gen_fix Proof_Context.read_vars;
   602 
   603 end;
   604 
   605 
   606 (* assume etc. *)
   607 
   608 local
   609 
   610 fun gen_assume asm prep_att exp args state =
   611   state
   612   |> assert_forward
   613   |> map_context_result (asm exp (Attrib.map_specs (map (prep_att (context_of state))) args))
   614   |> these_factss [] |> #2;
   615 
   616 in
   617 
   618 val assm = gen_assume Proof_Context.add_assms_i (K I);
   619 val assm_cmd = gen_assume Proof_Context.add_assms Attrib.attribute_cmd;
   620 val assume = assm Assumption.assume_export;
   621 val assume_cmd = assm_cmd Assumption.assume_export;
   622 val presume = assm Assumption.presume_export;
   623 val presume_cmd = assm_cmd Assumption.presume_export;
   624 
   625 end;
   626 
   627 
   628 (* def *)
   629 
   630 local
   631 
   632 fun gen_def prep_att prep_vars prep_binds args state =
   633   let
   634     val _ = assert_forward state;
   635     val (raw_name_atts, (raw_vars, raw_rhss)) = args |> split_list ||> split_list;
   636     val name_atts = map (apsnd (map (prep_att (context_of state)))) raw_name_atts;
   637   in
   638     state
   639     |> map_context_result (prep_vars (map (fn (x, mx) => (x, NONE, mx)) raw_vars))
   640     |>> map (fn (x, _, mx) => (x, mx))
   641     |-> (fn vars =>
   642       map_context_result (prep_binds false (map swap raw_rhss))
   643       #-> (fn rhss =>
   644         let
   645           val defs = (vars ~~ (name_atts ~~ rhss)) |> map (fn ((x, mx), ((a, atts), rhs)) =>
   646             ((x, mx), ((Thm.def_binding_optional x a, atts), rhs)));
   647         in map_context_result (Local_Defs.add_defs defs) end))
   648     |-> (set_facts o map (#2 o #2))
   649   end;
   650 
   651 in
   652 
   653 val def = gen_def (K I) Proof_Context.cert_vars Proof_Context.match_bind_i;
   654 val def_cmd = gen_def Attrib.attribute_cmd Proof_Context.read_vars Proof_Context.match_bind;
   655 
   656 end;
   657 
   658 
   659 
   660 (** facts **)
   661 
   662 (* chain *)
   663 
   664 fun clean_facts ctxt =
   665   set_facts (filter_out Thm.is_dummy (the_facts ctxt)) ctxt;
   666 
   667 val chain =
   668   assert_forward
   669   #> clean_facts
   670   #> enter_chain;
   671 
   672 fun chain_facts facts =
   673   set_facts facts
   674   #> chain;
   675 
   676 
   677 (* note etc. *)
   678 
   679 fun no_binding args = map (pair (Binding.empty, [])) args;
   680 
   681 local
   682 
   683 fun gen_thmss more_facts opt_chain opt_result prep_atts prep_fact args state =
   684   state
   685   |> assert_forward
   686   |> map_context_result (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   687     (Attrib.map_facts_refs (map (prep_atts ctxt)) (prep_fact ctxt) args))
   688   |> these_factss (more_facts state)
   689   ||> opt_chain
   690   |> opt_result;
   691 
   692 in
   693 
   694 val note_thmss = gen_thmss (K []) I #2 (K I) (K I);
   695 val note_thmss_cmd = gen_thmss (K []) I #2 Attrib.attribute_cmd Proof_Context.get_fact;
   696 
   697 val from_thmss = gen_thmss (K []) chain #2 (K I) (K I) o no_binding;
   698 val from_thmss_cmd =
   699   gen_thmss (K []) chain #2 Attrib.attribute_cmd Proof_Context.get_fact o no_binding;
   700 
   701 val with_thmss = gen_thmss the_facts chain #2 (K I) (K I) o no_binding;
   702 val with_thmss_cmd =
   703   gen_thmss the_facts chain #2 Attrib.attribute_cmd Proof_Context.get_fact o no_binding;
   704 
   705 val local_results = gen_thmss (K []) I I (K I) (K I) o map (apsnd Thm.simple_fact);
   706 
   707 end;
   708 
   709 
   710 (* using/unfolding *)
   711 
   712 local
   713 
   714 fun gen_using f g prep_att prep_fact args state =
   715   state
   716   |> assert_backward
   717   |> map_context_result
   718     (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   719       (Attrib.map_facts_refs (map (prep_att ctxt)) (prep_fact ctxt) (no_binding args)))
   720   |> (fn (named_facts, state') =>
   721     state' |> map_goal I (fn (statement, _, using, goal, before_qed, after_qed) =>
   722       let
   723         val ctxt = context_of state';
   724         val ths = maps snd named_facts;
   725       in (statement, [], f ctxt ths using, g ctxt ths goal, before_qed, after_qed) end) I);
   726 
   727 fun append_using _ ths using = using @ filter_out Thm.is_dummy ths;
   728 fun unfold_using ctxt ths = map (Local_Defs.unfold ctxt ths);
   729 val unfold_goals = Local_Defs.unfold_goals;
   730 
   731 in
   732 
   733 val using = gen_using append_using (K (K I)) (K I) (K I);
   734 val using_cmd = gen_using append_using (K (K I)) Attrib.attribute_cmd Proof_Context.get_fact;
   735 val unfolding = gen_using unfold_using unfold_goals (K I) (K I);
   736 val unfolding_cmd = gen_using unfold_using unfold_goals Attrib.attribute_cmd Proof_Context.get_fact;
   737 
   738 end;
   739 
   740 
   741 (* case *)
   742 
   743 local
   744 
   745 fun qualified_binding a =
   746   Binding.qualify true (Long_Name.qualifier a) (Binding.name (Long_Name.base_name a));
   747 
   748 fun gen_invoke_case prep_att (name, xs, raw_atts) state =
   749   let
   750     val atts = map (prep_att (context_of state)) raw_atts;
   751     val (asms, state') = state |> map_context_result (fn ctxt =>
   752       ctxt |> Proof_Context.apply_case (Proof_Context.get_case ctxt name xs));
   753     val assumptions = asms |> map (fn (a, ts) => ((qualified_binding a, atts), map (rpair []) ts));
   754   in
   755     state'
   756     |> assume assumptions
   757     |> bind_terms Auto_Bind.no_facts
   758     |> `the_facts |-> (fn thms => note_thmss [((Binding.name name, []), [(thms, [])])])
   759   end;
   760 
   761 in
   762 
   763 val invoke_case = gen_invoke_case (K I);
   764 val invoke_case_cmd = gen_invoke_case Attrib.attribute_cmd;
   765 
   766 end;
   767 
   768 
   769 
   770 (** proof structure **)
   771 
   772 (* blocks *)
   773 
   774 val begin_block =
   775   assert_forward
   776   #> open_block
   777   #> reset_goal
   778   #> open_block;
   779 
   780 val next_block =
   781   assert_forward
   782   #> close_block
   783   #> open_block
   784   #> reset_goal
   785   #> reset_facts;
   786 
   787 fun end_block state =
   788   state
   789   |> assert_forward
   790   |> assert_bottom false
   791   |> close_block
   792   |> assert_current_goal false
   793   |> close_block
   794   |> export_facts state;
   795 
   796 
   797 (* global notepad *)
   798 
   799 val begin_notepad =
   800   init
   801   #> open_block
   802   #> map_context (Variable.set_body true)
   803   #> open_block;
   804 
   805 val end_notepad =
   806   assert_forward
   807   #> assert_bottom true
   808   #> close_block
   809   #> assert_current_goal false
   810   #> close_block
   811   #> context_of;
   812 
   813 
   814 (* sub-proofs *)
   815 
   816 fun proof opt_text =
   817   assert_backward
   818   #> refine (the_default Method.default_text opt_text)
   819   #> Seq.map (using_facts [] #> enter_forward);
   820 
   821 fun proof_results arg =
   822   Seq.APPEND (proof (Method.text arg) #> Seq.make_results,
   823     method_error "initial" (Method.position arg));
   824 
   825 fun end_proof bot (prev_pos, (opt_text, immed)) =
   826   let
   827     val (finish_text, terminal_pos, finished_pos) =
   828       (case opt_text of
   829         NONE => (Method.finish_text (NONE, immed), Position.none, prev_pos)
   830       | SOME (text, (pos, end_pos)) =>
   831           (Method.finish_text (SOME text, immed), Position.set_range (pos, end_pos), end_pos));
   832   in
   833     Seq.APPEND (fn state =>
   834       state
   835       |> assert_forward
   836       |> assert_bottom bot
   837       |> close_block
   838       |> assert_current_goal true
   839       |> using_facts []
   840       |> `before_qed |-> (refine o the_default Method.succeed_text)
   841       |> Seq.maps (refine finish_text)
   842       |> Seq.make_results, method_error "terminal" terminal_pos)
   843     #> Seq.maps_results (Seq.single o finished_goal finished_pos)
   844   end;
   845 
   846 fun check_result msg sq =
   847   (case Seq.pull sq of
   848     NONE => error msg
   849   | SOME (s, _) => s);
   850 
   851 
   852 (* unstructured refinement *)
   853 
   854 fun defer i =
   855   assert_no_chain #>
   856   refine (Method.Basic (fn _ => METHOD (fn _ => ASSERT_SUBGOAL defer_tac i))) #> Seq.hd;
   857 
   858 fun prefer i =
   859   assert_no_chain #>
   860   refine (Method.Basic (fn _ => METHOD (fn _ => ASSERT_SUBGOAL prefer_tac i))) #> Seq.hd;
   861 
   862 fun apply text = assert_backward #> refine text #> Seq.map (using_facts []);
   863 
   864 fun apply_end text = assert_forward #> refine_end text;
   865 
   866 fun apply_results (text, range) =
   867   Seq.APPEND (apply text #> Seq.make_results, method_error "" (Position.set_range range));
   868 
   869 fun apply_end_results (text, range) =
   870   Seq.APPEND (apply_end text #> Seq.make_results, method_error "" (Position.set_range range));
   871 
   872 
   873 
   874 (** goals **)
   875 
   876 (* generic goals *)
   877 
   878 local
   879 
   880 val is_var =
   881   can (dest_TVar o Logic.dest_type o Logic.dest_term) orf
   882   can (dest_Var o Logic.dest_term);
   883 
   884 fun implicit_vars props =
   885   let
   886     val (var_props, _) = take_prefix is_var props;
   887     val explicit_vars = fold Term.add_vars var_props [];
   888     val vars = filter_out (member (op =) explicit_vars) (fold Term.add_vars props []);
   889   in map (Logic.mk_term o Var) vars end;
   890 
   891 fun refine_terms n =
   892   refine (Method.Basic (K (RAW_METHOD
   893     (K (HEADGOAL (PRECISE_CONJUNCTS n
   894       (HEADGOAL (CONJUNCTS (ALLGOALS (rtac Drule.termI))))))))))
   895   #> Seq.hd;
   896 
   897 in
   898 
   899 fun generic_goal prepp kind before_qed after_qed raw_propp state =
   900   let
   901     val thy = theory_of state;
   902     val cert = Thm.cterm_of thy;
   903     val chaining = can assert_chain state;
   904     val pos = Position.thread_data ();
   905 
   906     val ((propss, after_ctxt), goal_state) =
   907       state
   908       |> assert_forward_or_chain
   909       |> enter_forward
   910       |> open_block
   911       |> map_context_result (prepp raw_propp);
   912     val props = flat propss;
   913 
   914     val vars = implicit_vars props;
   915     val propss' = vars :: propss;
   916     val goal_propss = filter_out null propss';
   917     val goal =
   918       cert (Logic.mk_conjunction_balanced (map Logic.mk_conjunction_balanced goal_propss))
   919       |> Thm.weaken_sorts (Variable.sorts_of (context_of goal_state));
   920     val statement = ((kind, pos), propss', Thm.term_of goal);
   921     val after_qed' = after_qed |>> (fn after_local =>
   922       fn results => map_context after_ctxt #> after_local results);
   923   in
   924     goal_state
   925     |> map_context (init_context #> Variable.set_body true)
   926     |> set_goal (make_goal (statement, [], [], Goal.init goal, before_qed, after_qed'))
   927     |> map_context (Proof_Context.auto_bind_goal props)
   928     |> chaining ? (`the_facts #-> using_facts)
   929     |> reset_facts
   930     |> open_block
   931     |> reset_goal
   932     |> enter_backward
   933     |> not (null vars) ? refine_terms (length goal_propss)
   934     |> null props ? (refine (Method.Basic Method.assumption) #> Seq.hd)
   935   end;
   936 
   937 fun generic_qed after_ctxt state =
   938   let
   939     val (goal_ctxt, {statement = (_, stmt, _), goal, after_qed, ...}) = current_goal state;
   940     val outer_state = state |> close_block;
   941     val outer_ctxt = context_of outer_state;
   942 
   943     val props =
   944       flat (tl stmt)
   945       |> Variable.exportT_terms goal_ctxt outer_ctxt;
   946     val results =
   947       tl (conclude_goal goal_ctxt goal stmt)
   948       |> burrow (Proof_Context.export goal_ctxt outer_ctxt);
   949   in
   950     outer_state
   951     |> map_context (after_ctxt props)
   952     |> pair (after_qed, results)
   953   end;
   954 
   955 end;
   956 
   957 
   958 (* local goals *)
   959 
   960 fun local_goal print_results prep_att prepp kind before_qed after_qed stmt state =
   961   let
   962     val ((names, attss), propp) =
   963       Attrib.map_specs (map (prep_att (context_of state))) stmt |> split_list |>> split_list;
   964 
   965     fun after_qed' results =
   966       local_results ((names ~~ attss) ~~ results)
   967       #-> (fn res => tap (fn st => print_results (context_of st) ((kind, ""), res) : unit))
   968       #> after_qed results;
   969   in
   970     state
   971     |> generic_goal prepp kind before_qed (after_qed', K I) propp
   972     |> tap (Variable.warn_extra_tfrees (context_of state) o context_of)
   973   end;
   974 
   975 fun local_qeds arg =
   976   end_proof false arg
   977   #> Seq.map_result (generic_qed Proof_Context.auto_bind_facts #->
   978     (fn ((after_qed, _), results) => after_qed results));
   979 
   980 fun local_qed arg =
   981   local_qeds (Position.none, arg) #> Seq.the_result finished_goal_error;
   982 
   983 
   984 (* global goals *)
   985 
   986 fun prepp_auto_fixes prepp args =
   987   prepp args #>
   988   (fn ((propss, a), ctxt) => ((propss, a), (fold o fold) Variable.auto_fixes propss ctxt));
   989 
   990 fun global_goal prepp before_qed after_qed propp =
   991   init #>
   992   generic_goal (prepp_auto_fixes prepp) "" before_qed (K I, after_qed) propp;
   993 
   994 val theorem = global_goal Proof_Context.bind_propp_schematic_i;
   995 val theorem_cmd = global_goal Proof_Context.bind_propp_schematic;
   996 
   997 fun global_qeds arg =
   998   end_proof true arg
   999   #> Seq.map_result (generic_qed (K I) #> (fn (((_, after_qed), results), state) =>
  1000     after_qed results (context_of state)));
  1001 
  1002 fun global_qed arg =
  1003   global_qeds (Position.none, arg) #> Seq.the_result finished_goal_error;
  1004 
  1005 
  1006 (* terminal proof steps *)
  1007 
  1008 local
  1009 
  1010 fun terminal_proof qeds initial terminal =
  1011   proof_results (SOME initial) #> Seq.maps_results (qeds (#2 (#2 initial), terminal))
  1012   #> Seq.the_result "";
  1013 
  1014 in
  1015 
  1016 fun local_terminal_proof (text, opt_text) = terminal_proof local_qeds text (opt_text, true);
  1017 val local_default_proof = local_terminal_proof ((Method.default_text, Position.no_range), NONE);
  1018 val local_immediate_proof = local_terminal_proof ((Method.this_text, Position.no_range), NONE);
  1019 val local_done_proof = terminal_proof local_qeds (Method.done_text, Position.no_range) (NONE, false);
  1020 
  1021 fun global_terminal_proof (text, opt_text) = terminal_proof global_qeds text (opt_text, true);
  1022 val global_default_proof = global_terminal_proof ((Method.default_text, Position.no_range), NONE);
  1023 val global_immediate_proof = global_terminal_proof ((Method.this_text, Position.no_range), NONE);
  1024 val global_done_proof = terminal_proof global_qeds (Method.done_text, Position.no_range) (NONE, false);
  1025 
  1026 end;
  1027 
  1028 
  1029 (* skip proofs *)
  1030 
  1031 local
  1032 
  1033 fun skipped_proof state =
  1034   Context_Position.if_visible (context_of state) Output.report
  1035     (Markup.markup Markup.bad "Skipped proof");
  1036 
  1037 in
  1038 
  1039 fun local_skip_proof int state =
  1040   local_terminal_proof ((Method.sorry_text int, Position.no_range), NONE) state before
  1041   skipped_proof state;
  1042 
  1043 fun global_skip_proof int state =
  1044   global_terminal_proof ((Method.sorry_text int, Position.no_range), NONE) state before
  1045   skipped_proof state;
  1046 
  1047 end;
  1048 
  1049 
  1050 (* common goal statements *)
  1051 
  1052 local
  1053 
  1054 fun gen_have prep_att prepp before_qed after_qed stmt int =
  1055   local_goal (Proof_Display.print_results Markup.state int)
  1056     prep_att prepp "have" before_qed after_qed stmt;
  1057 
  1058 fun gen_show prep_att prepp before_qed after_qed stmt int state =
  1059   let
  1060     val testing = Unsynchronized.ref false;
  1061     val rule = Unsynchronized.ref (NONE: thm option);
  1062     fun fail_msg ctxt =
  1063       "Local statement fails to refine any pending goal" ::
  1064       (case ! rule of NONE => [] | SOME th => [Proof_Display.string_of_rule ctxt "Failed" th])
  1065       |> cat_lines;
  1066 
  1067     fun print_results ctxt res =
  1068       if ! testing then ()
  1069       else Proof_Display.print_results Markup.state int ctxt res;
  1070     fun print_rule ctxt th =
  1071       if ! testing then rule := SOME th
  1072       else if int then
  1073         writeln (Markup.markup Markup.state (Proof_Display.string_of_rule ctxt "Successful" th))
  1074       else ();
  1075     val test_proof =
  1076       local_skip_proof true
  1077       |> Unsynchronized.setmp testing true
  1078       |> Exn.interruptible_capture;
  1079 
  1080     fun after_qed' results =
  1081       refine_goals print_rule (context_of state) (flat results)
  1082       #> check_result "Failed to refine any pending goal"
  1083       #> after_qed results;
  1084   in
  1085     state
  1086     |> local_goal print_results prep_att prepp "show" before_qed after_qed' stmt
  1087     |> int ? (fn goal_state =>
  1088       (case test_proof (map_context (Context_Position.set_visible false) goal_state) of
  1089         Exn.Res _ => goal_state
  1090       | Exn.Exn exn => raise Exn.EXCEPTIONS ([exn, ERROR (fail_msg (context_of goal_state))])))
  1091   end;
  1092 
  1093 in
  1094 
  1095 val have = gen_have (K I) Proof_Context.bind_propp_i;
  1096 val have_cmd = gen_have Attrib.attribute_cmd Proof_Context.bind_propp;
  1097 val show = gen_show (K I) Proof_Context.bind_propp_i;
  1098 val show_cmd = gen_show Attrib.attribute_cmd Proof_Context.bind_propp;
  1099 
  1100 end;
  1101 
  1102 
  1103 
  1104 (** future proofs **)
  1105 
  1106 (* relevant proof states *)
  1107 
  1108 fun is_schematic t =
  1109   Term.exists_subterm Term.is_Var t orelse
  1110   Term.exists_type (Term.exists_subtype Term.is_TVar) t;
  1111 
  1112 fun schematic_goal state =
  1113   let val (_, (_, {statement = (_, _, prop), ...})) = find_goal state
  1114   in is_schematic prop end;
  1115 
  1116 fun is_relevant state =
  1117   (case try find_goal state of
  1118     NONE => true
  1119   | SOME (_, (_, {statement = (_, _, prop), goal, ...})) =>
  1120       is_schematic prop orelse not (Logic.protect prop aconv Thm.concl_of goal));
  1121 
  1122 
  1123 (* full proofs *)
  1124 
  1125 local
  1126 
  1127 structure Result = Proof_Data
  1128 (
  1129   type T = thm option;
  1130   val empty = NONE;
  1131   fun init _ = empty;
  1132 );
  1133 
  1134 fun the_result ctxt =
  1135   (case Result.get ctxt of
  1136     NONE => error "No result of forked proof"
  1137   | SOME th => th);
  1138 
  1139 val set_result = Result.put o SOME;
  1140 val reset_result = Result.put NONE;
  1141 
  1142 in
  1143 
  1144 fun future_proof fork_proof state =
  1145   let
  1146     val _ = assert_backward state;
  1147     val (goal_ctxt, (_, goal)) = find_goal state;
  1148     val {statement as (kind, _, prop), messages, using, goal, before_qed, after_qed} = goal;
  1149     val goal_tfrees =
  1150       fold Term.add_tfrees
  1151         (prop :: map Thm.term_of (Assumption.all_assms_of goal_ctxt)) [];
  1152 
  1153     val _ = is_relevant state andalso error "Cannot fork relevant proof";
  1154 
  1155     val prop' = Logic.protect prop;
  1156     val statement' = (kind, [[], [prop']], prop');
  1157     val goal' = Thm.adjust_maxidx_thm (Thm.maxidx_of goal)
  1158       (Drule.comp_no_flatten (goal, Thm.nprems_of goal) 1 Drule.protectI);
  1159     val after_qed' = (fn [[th]] => map_context (set_result th), fn [[th]] => set_result th);
  1160 
  1161     val result_ctxt =
  1162       state
  1163       |> map_context reset_result
  1164       |> map_goal I (K (statement', messages, using, goal', before_qed, after_qed'))
  1165         (fold (Variable.declare_typ o TFree) goal_tfrees)
  1166       |> fork_proof;
  1167 
  1168     val future_thm = Future.map (the_result o snd) result_ctxt;
  1169     val finished_goal = Goal.future_result goal_ctxt future_thm prop';
  1170     val state' =
  1171       state
  1172       |> map_goal I (K (statement, messages, using, finished_goal, NONE, after_qed)) I;
  1173   in (Future.map fst result_ctxt, state') end;
  1174 
  1175 end;
  1176 
  1177 
  1178 (* terminal proofs *)
  1179 
  1180 local
  1181 
  1182 fun future_terminal_proof n proof1 proof2 done int state =
  1183   if (Goal.future_enabled_level 4 orelse Goal.future_enabled_nested n andalso not int)
  1184     andalso not (is_relevant state)
  1185   then
  1186     state |> future_proof (fn state' =>
  1187       Goal.fork_name "Proof.future_terminal_proof" ~1
  1188         (fn () => ((), proof2 state'))) |> snd |> done
  1189   else proof1 state;
  1190 
  1191 in
  1192 
  1193 fun local_future_terminal_proof meths =
  1194   future_terminal_proof 3
  1195     (local_terminal_proof meths)
  1196     (local_terminal_proof meths #> context_of) local_done_proof;
  1197 
  1198 fun global_future_terminal_proof meths =
  1199   future_terminal_proof 3
  1200     (global_terminal_proof meths)
  1201     (global_terminal_proof meths) global_done_proof;
  1202 
  1203 end;
  1204 
  1205 end;
  1206