src/Pure/axclass.ML
author wenzelm
Sun Apr 25 19:09:37 2010 +0200 (2010-04-25 ago)
changeset 36325 8715343af626
parent 36106 19deea200358
child 36326 85d026788fce
permissions -rw-r--r--
classrel and arity completion by krauss/schropp;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val define_class: binding * class list -> string list ->
    11     (Thm.binding * term list) list -> theory -> class * theory
    12   val add_classrel: thm -> theory -> theory
    13   val add_arity: thm -> theory -> theory
    14   val prove_classrel: class * class -> tactic -> theory -> theory
    15   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    16   val get_info: theory -> class ->
    17     {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    18   val class_intros: theory -> thm list
    19   val class_of_param: theory -> string -> class option
    20   val cert_classrel: theory -> class * class -> class * class
    21   val read_classrel: theory -> xstring * xstring -> class * class
    22   val axiomatize_class: binding * class list -> theory -> theory
    23   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    24   val axiomatize_classrel: (class * class) list -> theory -> theory
    25   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    26   val axiomatize_arity: arity -> theory -> theory
    27   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    28   val instance_name: string * class -> string
    29   val declare_overloaded: string * typ -> theory -> term * theory
    30   val define_overloaded: binding -> string * term -> theory -> thm * theory
    31   val unoverload: theory -> thm -> thm
    32   val overload: theory -> thm -> thm
    33   val unoverload_conv: theory -> conv
    34   val overload_conv: theory -> conv
    35   val unoverload_const: theory -> string * typ -> string
    36   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    37   val param_of_inst: theory -> string * string -> string
    38   val inst_of_param: theory -> string -> (string * string) option
    39   val thynames_of_arity: theory -> class * string -> string list
    40   val introN: string
    41   val axiomsN: string
    42 end;
    43 
    44 structure AxClass: AX_CLASS =
    45 struct
    46 
    47 (** theory data **)
    48 
    49 (* class parameters (canonical order) *)
    50 
    51 type param = string * class;
    52 
    53 fun add_param pp ((x, c): param) params =
    54   (case AList.lookup (op =) params x of
    55     NONE => (x, c) :: params
    56   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    57       " for " ^ Pretty.string_of_sort pp [c] ^
    58       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    59 
    60 fun merge_params _ ([], qs) = qs
    61   | merge_params pp (ps, qs) =
    62       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    63 
    64 
    65 (* axclasses *)
    66 
    67 val introN = "intro";
    68 val superN = "super";
    69 val axiomsN = "axioms";
    70 
    71 datatype axclass = AxClass of
    72  {def: thm,
    73   intro: thm,
    74   axioms: thm list,
    75   params: (string * typ) list};
    76 
    77 type axclasses = axclass Symtab.table * param list;
    78 
    79 fun make_axclass ((def, intro, axioms), params) = AxClass
    80   {def = def, intro = intro, axioms = axioms, params = params};
    81 
    82 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    83   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    84 
    85 
    86 (* instances *)
    87 
    88 val classrel_prefix = "classrel_";
    89 val arity_prefix = "arity_";
    90 
    91 type instances =
    92   (thm * proof) Symreltab.table *  (*classrel theorems*)
    93   ((class * sort list) * ((thm * string) * proof)) list Symtab.table;  (*arity theorems with theory name*)
    94 
    95 (*transitive closure of classrels and arity completion is done in Theory.at_begin hook*)
    96 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    97  (Symreltab.join (K fst) (classrel1, classrel2),
    98   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
    99 
   100 
   101 (* instance parameters *)
   102 
   103 type inst_params =
   104   (string * thm) Symtab.table Symtab.table
   105     (*constant name ~> type constructor ~> (constant name, equation)*)
   106   * (string * string) Symtab.table; (*constant name ~> (constant name, type constructor)*)
   107 
   108 fun merge_inst_params ((const_param1, param_const1), (const_param2, param_const2)) =
   109   (Symtab.join  (K (Symtab.merge (K true))) (const_param1, const_param2),
   110     Symtab.merge (K true) (param_const1, param_const2));
   111 
   112 
   113 (* setup data *)
   114 
   115 structure AxClassData = Theory_Data_PP
   116 (
   117   type T = axclasses * ((instances * inst_params) * (class * class) list);
   118   val empty = ((Symtab.empty, []), (((Symreltab.empty, Symtab.empty), (Symtab.empty, Symtab.empty)), []));
   119   val extend = I;
   120   fun merge pp ((axclasses1, ((instances1, inst_params1), diff_merge_classrels1)),
   121     (axclasses2, ((instances2, inst_params2), diff_merge_classrels2))) =
   122     let
   123       val (classrels1, classrels2) = pairself (Symreltab.keys o fst) (instances1, instances2)
   124       val diff_merge_classrels = subtract (op =) classrels1 classrels2
   125         @ subtract (op =) classrels2 classrels1
   126         @ diff_merge_classrels1 @ diff_merge_classrels2
   127     in
   128       (merge_axclasses pp (axclasses1, axclasses2),
   129         ((merge_instances (instances1, instances2), merge_inst_params (inst_params1, inst_params2)),
   130           diff_merge_classrels))
   131     end;
   132 );
   133 
   134 
   135 (* maintain axclasses *)
   136 
   137 val get_axclasses = #1 o AxClassData.get;
   138 val map_axclasses = AxClassData.map o apfst;
   139 
   140 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   141 
   142 fun get_info thy c =
   143   (case lookup_def thy c of
   144     SOME (AxClass info) => info
   145   | NONE => error ("No such axclass: " ^ quote c));
   146 
   147 fun class_intros thy =
   148   let
   149     fun add_intro c =
   150       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   151     val classes = Sign.all_classes thy;
   152   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   153 
   154 
   155 fun get_params thy pred =
   156   let val params = #2 (get_axclasses thy);
   157   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   158 
   159 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   160 
   161 fun class_of_param thy = AList.lookup (op =) (#2 (get_axclasses thy));
   162 
   163 
   164 (* maintain instances *)
   165 
   166 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   167 
   168 val get_instances = #1 o #1 o #2 o AxClassData.get;
   169 val map_instances = AxClassData.map o apsnd o apfst o apfst;
   170 
   171 val get_diff_merge_classrels = #2 o #2 o AxClassData.get;
   172 val clear_diff_merge_classrels = AxClassData.map (apsnd (apsnd (K [])));
   173 
   174 
   175 fun the_classrel thy (c1, c2) =
   176   (case Symreltab.lookup (#1 (get_instances thy)) (c1, c2) of
   177     SOME classrel => classrel
   178   | NONE => error ("Unproven class relation " ^
   179       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   180 
   181 fun the_classrel_thm thy = Thm.transfer thy o fst o the_classrel thy;
   182 fun the_classrel_prf thy = snd o the_classrel thy;
   183 
   184 fun put_trancl_classrel ((c1, c2), th) thy =
   185   let
   186     val classrels = fst (get_instances thy)
   187     val alg = Sign.classes_of thy
   188     val {classes, ...} = alg |> Sorts.rep_algebra
   189 
   190     fun reflcl_classrel (c1', c2') =
   191       if c1' = c2' then Thm.trivial (Logic.mk_of_class (TVar(("'a",0),[]), c1') |> cterm_of thy)
   192       else the_classrel_thm thy (c1', c2')
   193     fun gen_classrel (c1_pred, c2_succ) =
   194       let
   195         val th' = ((reflcl_classrel (c1_pred, c1) RS th) RS reflcl_classrel (c2, c2_succ))
   196           |> Drule.instantiate' [SOME (ctyp_of thy (TVar ((Name.aT, 0), [])))] []
   197           |> Thm.close_derivation
   198         val prf' = th' |> Thm.proof_of
   199       in ((c1_pred, c2_succ), (th',prf')) end
   200 
   201     val new_classrels = Library.map_product pair
   202         (c1 :: Graph.imm_preds classes c1) (c2 :: Graph.imm_succs classes c2)
   203       |> filter_out (Symreltab.defined classrels)
   204       |> map gen_classrel
   205     val needed = length new_classrels > 0
   206   in
   207     (needed,
   208      if needed then
   209        thy |> map_instances (fn (classrels, arities) =>
   210          (classrels |> fold Symreltab.update new_classrels, arities))
   211      else thy)
   212   end;
   213 
   214 fun complete_classrels thy =
   215   let
   216     val diff_merge_classrels = get_diff_merge_classrels thy
   217     val classrels = fst (get_instances thy)
   218     val (needed, thy') = (false, thy) |>
   219       fold (fn c12 => fn (needed, thy) =>
   220           put_trancl_classrel (c12, Symreltab.lookup classrels c12 |> the |> fst) thy
   221           |>> (fn b => needed orelse b))
   222         diff_merge_classrels
   223   in
   224     if null diff_merge_classrels then NONE
   225     else thy' |> clear_diff_merge_classrels |> SOME
   226   end;
   227 
   228 
   229 fun the_arity thy a (c, Ss) =
   230   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss) of
   231     SOME arity => arity
   232   | NONE => error ("Unproven type arity " ^
   233       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   234 
   235 fun the_arity_thm thy a c_Ss = the_arity thy a c_Ss |> fst |> fst |> Thm.transfer thy;
   236 fun the_arity_prf thy a c_Ss = the_arity thy a c_Ss |> snd;
   237 
   238 fun thynames_of_arity thy (c, a) =
   239   Symtab.lookup_list (#2 (get_instances thy)) a
   240   |> map_filter (fn ((c', _), ((_, name),_)) => if c = c' then SOME name else NONE)
   241   |> rev;
   242 
   243 fun insert_arity_completions thy (t, ((c, Ss), ((th, thy_name), _))) arities =
   244   let
   245     val algebra = Sign.classes_of thy;
   246     val super_class_completions =
   247       Sign.super_classes thy c
   248       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) => c1 = c2
   249           andalso Sorts.sorts_le algebra (Ss2, Ss)) (Symtab.lookup_list arities t));
   250     val names_and_Ss = Name.names Name.context Name.aT (map (K []) Ss);
   251     val completions = super_class_completions |> map (fn c1 =>
   252       let
   253         val th1 = (th RS the_classrel_thm thy (c, c1))
   254           |> Drule.instantiate' (map (SOME o ctyp_of thy o TVar o apfst (rpair 0)) names_and_Ss) []
   255           |> Thm.close_derivation
   256         val prf1 = Thm.proof_of th1
   257       in (((th1,thy_name), prf1), c1) end)
   258     val arities' = fold (fn (th_thy_prf1, c1) => Symtab.cons_list (t, ((c1, Ss), th_thy_prf1)))
   259       completions arities;
   260   in (null completions, arities') end;
   261 
   262 fun put_arity ((t, Ss, c), th) thy =
   263   let
   264     val arity' = (t, ((c, Ss), ((th, Context.theory_name thy), Thm.proof_of th)));
   265   in
   266     thy
   267     |> map_instances (fn (classrel, arities) => (classrel,
   268       arities
   269       |> Symtab.insert_list (eq_fst op =) arity'
   270       |> insert_arity_completions thy arity'
   271       |> snd))
   272   end;
   273 
   274 fun complete_arities thy =
   275   let
   276     val arities = snd (get_instances thy);
   277     val (finished, arities') = arities
   278       |> fold_map (insert_arity_completions thy) (Symtab.dest_list arities);
   279   in
   280     if forall I finished then NONE
   281     else SOME (thy |> map_instances (fn (classrel, _) => (classrel, arities')))
   282   end;
   283 
   284 val _ = Context.>> (Context.map_theory
   285   (Theory.at_begin complete_classrels #> Theory.at_begin complete_arities))
   286 
   287 
   288 (* maintain instance parameters *)
   289 
   290 val get_inst_params = #2 o #1 o #2 o AxClassData.get;
   291 val map_inst_params = AxClassData.map o apsnd o apfst o apsnd;
   292 
   293 fun get_inst_param thy (c, tyco) =
   294   case Symtab.lookup ((the_default Symtab.empty o Symtab.lookup (fst (get_inst_params thy))) c) tyco
   295    of SOME c' => c'
   296     | NONE => error ("No instance parameter for constant " ^ quote c
   297         ^ " on type constructor " ^ quote tyco);
   298 
   299 fun add_inst_param (c, tyco) inst = (map_inst_params o apfst
   300       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   301   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   302 
   303 val inst_of_param = Symtab.lookup o snd o get_inst_params;
   304 val param_of_inst = fst oo get_inst_param;
   305 
   306 fun inst_thms thy = (Symtab.fold (Symtab.fold (cons o snd o snd) o snd) o fst)
   307   (get_inst_params thy) [];
   308 
   309 fun get_inst_tyco consts = try (fst o dest_Type o the_single o Consts.typargs consts);
   310 
   311 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   312 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   313 
   314 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   315 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   316 
   317 fun lookup_inst_param consts params (c, T) = case get_inst_tyco consts (c, T)
   318  of SOME tyco => AList.lookup (op =) params (c, tyco)
   319   | NONE => NONE;
   320 
   321 fun unoverload_const thy (c_ty as (c, _)) =
   322   if is_some (class_of_param thy c)
   323   then case get_inst_tyco (Sign.consts_of thy) c_ty
   324    of SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   325     | NONE => c
   326   else c;
   327 
   328 
   329 (** instances **)
   330 
   331 (* class relations *)
   332 
   333 fun cert_classrel thy raw_rel =
   334   let
   335     val string_of_sort = Syntax.string_of_sort_global thy;
   336     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   337     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   338     val _ =
   339       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   340         [] => ()
   341       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   342           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   343   in (c1, c2) end;
   344 
   345 fun read_classrel thy raw_rel =
   346   cert_classrel thy (pairself (ProofContext.read_class (ProofContext.init thy)) raw_rel)
   347     handle TYPE (msg, _, _) => error msg;
   348 
   349 fun check_shyps_topped th errmsg =
   350   let val {shyps, ...} = Thm.rep_thm th
   351   in
   352     forall null shyps orelse raise Fail errmsg
   353   end;
   354 
   355 (* declaration and definition of instances of overloaded constants *)
   356 
   357 fun inst_tyco_of thy (c, T) =
   358   (case get_inst_tyco (Sign.consts_of thy) (c, T) of
   359     SOME tyco => tyco
   360   | NONE => error ("Illegal type for instantiation of class parameter: " ^
   361       quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T)));
   362 
   363 fun declare_overloaded (c, T) thy =
   364   let
   365     val class =
   366       (case class_of_param thy c of
   367         SOME class => class
   368       | NONE => error ("Not a class parameter: " ^ quote c));
   369     val tyco = inst_tyco_of thy (c, T);
   370     val name_inst = instance_name (tyco, class) ^ "_inst";
   371     val c' = Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco;
   372     val T' = Type.strip_sorts T;
   373   in
   374     thy
   375     |> Sign.qualified_path true (Binding.name name_inst)
   376     |> Sign.declare_const ((Binding.name c', T'), NoSyn)
   377     |-> (fn const' as Const (c'', _) =>
   378       Thm.add_def false true
   379         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   380       #>> apsnd Thm.varifyT_global
   381       #-> (fn (_, thm) => add_inst_param (c, tyco) (c'', thm)
   382         #> PureThy.add_thm ((Binding.conceal (Binding.name c'), thm), [])
   383         #> snd
   384         #> pair (Const (c, T))))
   385     ||> Sign.restore_naming thy
   386   end;
   387 
   388 fun define_overloaded b (c, t) thy =
   389   let
   390     val T = Term.fastype_of t;
   391     val tyco = inst_tyco_of thy (c, T);
   392     val (c', eq) = get_inst_param thy (c, tyco);
   393     val prop = Logic.mk_equals (Const (c', T), t);
   394     val b' = Thm.def_binding_optional
   395       (Binding.name (Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco)) b;
   396   in
   397     thy
   398     |> Thm.add_def false false (b', prop)
   399     |>> (fn (_, thm) =>  Drule.transitive_thm OF [eq, thm])
   400   end;
   401 
   402 
   403 (* primitive rules *)
   404 
   405 fun add_classrel raw_th thy =
   406   let
   407     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   408     val prop = Thm.plain_prop_of th;
   409     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   410     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   411     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   412     val th' = th
   413       |> Drule.instantiate' [SOME (ctyp_of thy (TVar ((Name.aT, 0), [c1])))] []
   414       |> Drule.unconstrainTs;
   415     val _ = check_shyps_topped th' "add_classrel: nontop shyps after unconstrain"
   416   in
   417     thy
   418     |> Sign.primitive_classrel (c1, c2)
   419     |> (snd oo put_trancl_classrel) ((c1, c2), th')
   420     |> perhaps complete_arities
   421   end;
   422 
   423 fun add_arity raw_th thy =
   424   let
   425     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   426     val prop = Thm.plain_prop_of th;
   427     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   428     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   429     val names = Name.names Name.context Name.aT Ss;
   430     val T = Type (t, map TFree names);
   431     val missing_params = Sign.complete_sort thy [c]
   432       |> maps (these o Option.map #params o try (get_info thy))
   433       |> filter_out (fn (const, _) => can (get_inst_param thy) (const, t))
   434       |> (map o apsnd o map_atyps) (K T);
   435     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   436     val th' = th
   437       |> Drule.instantiate' (map (SOME o ctyp_of thy o TVar o apfst (rpair 0)) names) []
   438       |> Drule.unconstrainTs;
   439     val _ = check_shyps_topped th' "add_arity: nontop shyps after unconstrain"
   440   in
   441     thy
   442     |> fold (snd oo declare_overloaded) missing_params
   443     |> Sign.primitive_arity (t, Ss, [c])
   444     |> put_arity ((t, Ss, c), th')
   445   end;
   446 
   447 
   448 (* tactical proofs *)
   449 
   450 fun prove_classrel raw_rel tac thy =
   451   let
   452     val ctxt = ProofContext.init thy;
   453     val (c1, c2) = cert_classrel thy raw_rel;
   454     val th = Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   455       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   456         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   457   in
   458     thy
   459     |> PureThy.add_thms [((Binding.name
   460         (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th), [])]
   461     |-> (fn [th'] => add_classrel th')
   462   end;
   463 
   464 fun prove_arity raw_arity tac thy =
   465   let
   466     val ctxt = ProofContext.init thy;
   467     val arity = ProofContext.cert_arity ctxt raw_arity;
   468     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   469     val props = Logic.mk_arities arity;
   470     val ths = Goal.prove_multi ctxt [] [] props
   471       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   472         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   473           quote (Syntax.string_of_arity ctxt arity));
   474   in
   475     thy
   476     |> PureThy.add_thms (map (rpair []) (map Binding.name names ~~ ths))
   477     |-> fold add_arity
   478   end;
   479 
   480 
   481 
   482 (** class definitions **)
   483 
   484 fun split_defined n eq =
   485   let
   486     val intro =
   487       (eq RS Drule.equal_elim_rule2)
   488       |> Conjunction.curry_balanced n
   489       |> n = 0 ? Thm.eq_assumption 1;
   490     val dests =
   491       if n = 0 then []
   492       else
   493         (eq RS Drule.equal_elim_rule1)
   494         |> Balanced_Tree.dest (fn th =>
   495           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   496   in (intro, dests) end;
   497 
   498 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   499   let
   500     val ctxt = ProofContext.init thy;
   501     val pp = Syntax.pp ctxt;
   502 
   503 
   504     (* class *)
   505 
   506     val bconst = Binding.map_name Logic.const_of_class bclass;
   507     val class = Sign.full_name thy bclass;
   508     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   509 
   510     fun check_constraint (a, S) =
   511       if Sign.subsort thy (super, S) then ()
   512       else error ("Sort constraint of type variable " ^
   513         setmp_CRITICAL show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   514         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   515 
   516 
   517     (* params *)
   518 
   519     val params = raw_params |> map (fn p =>
   520       let
   521         val T = Sign.the_const_type thy p;
   522         val _ =
   523           (case Term.add_tvarsT T [] of
   524             [((a, _), S)] => check_constraint (a, S)
   525           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   526         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   527       in (p, T') end);
   528 
   529 
   530     (* axioms *)
   531 
   532     fun prep_axiom t =
   533       (case Term.add_tfrees t [] of
   534         [(a, S)] => check_constraint (a, S)
   535       | [] => ()
   536       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   537       t
   538       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   539       |> Logic.close_form);
   540 
   541     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   542     val name_atts = map fst raw_specs;
   543 
   544 
   545     (* definition *)
   546 
   547     val conjs = Logic.mk_of_sort (Term.aT [], super) @ flat axiomss;
   548     val class_eq =
   549       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   550 
   551     val ([def], def_thy) =
   552       thy
   553       |> Sign.primitive_class (bclass, super)
   554       |> PureThy.add_defs false [((Thm.def_binding bconst, class_eq), [])];
   555     val (raw_intro, (raw_classrel, raw_axioms)) =
   556       split_defined (length conjs) def ||> chop (length super);
   557 
   558 
   559     (* facts *)
   560 
   561     val class_triv = Thm.class_triv def_thy class;
   562     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   563       def_thy
   564       |> Sign.qualified_path true bconst
   565       |> PureThy.note_thmss ""
   566         [((Binding.name introN, []), [([Drule.export_without_context raw_intro], [])]),
   567          ((Binding.name superN, []), [(map Drule.export_without_context raw_classrel, [])]),
   568          ((Binding.name axiomsN, []),
   569            [(map (fn th => Drule.export_without_context (class_triv RS th)) raw_axioms, [])])]
   570       ||> Sign.restore_naming def_thy;
   571 
   572 
   573     (* result *)
   574 
   575     val axclass = make_axclass ((def, intro, axioms), params);
   576     val result_thy =
   577       facts_thy
   578       |> fold (snd oo put_trancl_classrel) (map (pair class) super ~~ classrel)
   579       |> Sign.qualified_path false bconst
   580       |> PureThy.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   581       |> Sign.restore_naming facts_thy
   582       |> map_axclasses (fn (axclasses, parameters) =>
   583         (Symtab.update (class, axclass) axclasses,
   584           fold (fn (x, _) => add_param pp (x, class)) params parameters));
   585 
   586   in (class, result_thy) end;
   587 
   588 
   589 
   590 (** axiomatizations **)
   591 
   592 local
   593 
   594 (* old-style axioms *)
   595 
   596 fun add_axiom (b, prop) =
   597   Thm.add_axiom (b, prop) #->
   598   (fn (_, thm) => PureThy.add_thm ((b, Drule.export_without_context thm), []));
   599 
   600 fun axiomatize prep mk name add raw_args thy =
   601   let
   602     val args = prep thy raw_args;
   603     val specs = mk args;
   604     val names = name args;
   605   in
   606     thy
   607     |> fold_map add_axiom (map Binding.name names ~~ specs)
   608     |-> fold add
   609   end;
   610 
   611 fun ax_classrel prep =
   612   axiomatize (map o prep) (map Logic.mk_classrel)
   613     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   614 
   615 fun ax_arity prep =
   616   axiomatize (prep o ProofContext.init) Logic.mk_arities
   617     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   618 
   619 fun class_const c =
   620   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   621 
   622 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   623   let
   624     val class = Sign.full_name thy bclass;
   625     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   626   in
   627     thy
   628     |> Sign.primitive_class (bclass, super)
   629     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   630     |> Theory.add_deps "" (class_const class) (map class_const super)
   631   end;
   632 
   633 in
   634 
   635 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   636 val axiomatize_class_cmd = ax_class (ProofContext.read_class o ProofContext.init) read_classrel;
   637 val axiomatize_classrel = ax_classrel cert_classrel;
   638 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   639 val axiomatize_arity = ax_arity ProofContext.cert_arity;
   640 val axiomatize_arity_cmd = ax_arity ProofContext.read_arity;
   641 
   642 end;
   643 
   644 end;