src/HOL/Predicate.thy
author krauss
Mon Jul 27 21:47:41 2009 +0200 (2009-07-27 ago)
changeset 32235 8f9b8d14fc9f
parent 31932 685e7b450ab5
child 32372 b0d2b49bfaed
permissions -rw-r--r--
"more standard" argument order of relation composition (op O)
     1 (*  Title:      HOL/Predicate.thy
     2     Author:     Stefan Berghofer and Lukas Bulwahn and Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* Predicates as relations and enumerations *}
     6 
     7 theory Predicate
     8 imports Inductive Relation
     9 begin
    10 
    11 notation
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   Inf ("\<Sqinter>_" [900] 900) and
    15   Sup ("\<Squnion>_" [900] 900) and
    16   top ("\<top>") and
    17   bot ("\<bottom>")
    18 
    19 
    20 subsection {* Predicates as (complete) lattices *}
    21 
    22 subsubsection {* @{const sup} on @{typ bool} *}
    23 
    24 lemma sup_boolI1:
    25   "P \<Longrightarrow> P \<squnion> Q"
    26   by (simp add: sup_bool_eq)
    27 
    28 lemma sup_boolI2:
    29   "Q \<Longrightarrow> P \<squnion> Q"
    30   by (simp add: sup_bool_eq)
    31 
    32 lemma sup_boolE:
    33   "P \<squnion> Q \<Longrightarrow> (P \<Longrightarrow> R) \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
    34   by (auto simp add: sup_bool_eq)
    35 
    36 
    37 subsubsection {* Equality and Subsets *}
    38 
    39 lemma pred_equals_eq: "((\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S)) = (R = S)"
    40   by (simp add: mem_def)
    41 
    42 lemma pred_equals_eq2 [pred_set_conv]: "((\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S)) = (R = S)"
    43   by (simp add: expand_fun_eq mem_def)
    44 
    45 lemma pred_subset_eq: "((\<lambda>x. x \<in> R) <= (\<lambda>x. x \<in> S)) = (R <= S)"
    46   by (simp add: mem_def)
    47 
    48 lemma pred_subset_eq2 [pred_set_conv]: "((\<lambda>x y. (x, y) \<in> R) <= (\<lambda>x y. (x, y) \<in> S)) = (R <= S)"
    49   by fast
    50 
    51 
    52 subsubsection {* Top and bottom elements *}
    53 
    54 lemma top1I [intro!]: "top x"
    55   by (simp add: top_fun_eq top_bool_eq)
    56 
    57 lemma top2I [intro!]: "top x y"
    58   by (simp add: top_fun_eq top_bool_eq)
    59 
    60 lemma bot1E [elim!]: "bot x \<Longrightarrow> P"
    61   by (simp add: bot_fun_eq bot_bool_eq)
    62 
    63 lemma bot2E [elim!]: "bot x y \<Longrightarrow> P"
    64   by (simp add: bot_fun_eq bot_bool_eq)
    65 
    66 
    67 subsubsection {* The empty set *}
    68 
    69 lemma bot_empty_eq: "bot = (\<lambda>x. x \<in> {})"
    70   by (auto simp add: expand_fun_eq)
    71 
    72 lemma bot_empty_eq2: "bot = (\<lambda>x y. (x, y) \<in> {})"
    73   by (auto simp add: expand_fun_eq)
    74 
    75 
    76 subsubsection {* Binary union *}
    77 
    78 lemma sup1_iff [simp]: "sup A B x \<longleftrightarrow> A x | B x"
    79   by (simp add: sup_fun_eq sup_bool_eq)
    80 
    81 lemma sup2_iff [simp]: "sup A B x y \<longleftrightarrow> A x y | B x y"
    82   by (simp add: sup_fun_eq sup_bool_eq)
    83 
    84 lemma sup_Un_eq [pred_set_conv]: "sup (\<lambda>x. x \<in> R) (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
    85   by (simp add: expand_fun_eq)
    86 
    87 lemma sup_Un_eq2 [pred_set_conv]: "sup (\<lambda>x y. (x, y) \<in> R) (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
    88   by (simp add: expand_fun_eq)
    89 
    90 lemma sup1I1 [elim?]: "A x \<Longrightarrow> sup A B x"
    91   by simp
    92 
    93 lemma sup2I1 [elim?]: "A x y \<Longrightarrow> sup A B x y"
    94   by simp
    95 
    96 lemma sup1I2 [elim?]: "B x \<Longrightarrow> sup A B x"
    97   by simp
    98 
    99 lemma sup2I2 [elim?]: "B x y \<Longrightarrow> sup A B x y"
   100   by simp
   101 
   102 text {*
   103   \medskip Classical introduction rule: no commitment to @{text A} vs
   104   @{text B}.
   105 *}
   106 
   107 lemma sup1CI [intro!]: "(~ B x ==> A x) ==> sup A B x"
   108   by auto
   109 
   110 lemma sup2CI [intro!]: "(~ B x y ==> A x y) ==> sup A B x y"
   111   by auto
   112 
   113 lemma sup1E [elim!]: "sup A B x ==> (A x ==> P) ==> (B x ==> P) ==> P"
   114   by simp iprover
   115 
   116 lemma sup2E [elim!]: "sup A B x y ==> (A x y ==> P) ==> (B x y ==> P) ==> P"
   117   by simp iprover
   118 
   119 
   120 subsubsection {* Binary intersection *}
   121 
   122 lemma inf1_iff [simp]: "inf A B x \<longleftrightarrow> A x \<and> B x"
   123   by (simp add: inf_fun_eq inf_bool_eq)
   124 
   125 lemma inf2_iff [simp]: "inf A B x y \<longleftrightarrow> A x y \<and> B x y"
   126   by (simp add: inf_fun_eq inf_bool_eq)
   127 
   128 lemma inf_Int_eq [pred_set_conv]: "inf (\<lambda>x. x \<in> R) (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
   129   by (simp add: expand_fun_eq)
   130 
   131 lemma inf_Int_eq2 [pred_set_conv]: "inf (\<lambda>x y. (x, y) \<in> R) (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   132   by (simp add: expand_fun_eq)
   133 
   134 lemma inf1I [intro!]: "A x ==> B x ==> inf A B x"
   135   by simp
   136 
   137 lemma inf2I [intro!]: "A x y ==> B x y ==> inf A B x y"
   138   by simp
   139 
   140 lemma inf1D1: "inf A B x ==> A x"
   141   by simp
   142 
   143 lemma inf2D1: "inf A B x y ==> A x y"
   144   by simp
   145 
   146 lemma inf1D2: "inf A B x ==> B x"
   147   by simp
   148 
   149 lemma inf2D2: "inf A B x y ==> B x y"
   150   by simp
   151 
   152 lemma inf1E [elim!]: "inf A B x ==> (A x ==> B x ==> P) ==> P"
   153   by simp
   154 
   155 lemma inf2E [elim!]: "inf A B x y ==> (A x y ==> B x y ==> P) ==> P"
   156   by simp
   157 
   158 
   159 subsubsection {* Unions of families *}
   160 
   161 lemma SUP1_iff [simp]: "(SUP x:A. B x) b = (EX x:A. B x b)"
   162   by (simp add: SUPR_def Sup_fun_def Sup_bool_def) blast
   163 
   164 lemma SUP2_iff [simp]: "(SUP x:A. B x) b c = (EX x:A. B x b c)"
   165   by (simp add: SUPR_def Sup_fun_def Sup_bool_def) blast
   166 
   167 lemma SUP1_I [intro]: "a : A ==> B a b ==> (SUP x:A. B x) b"
   168   by auto
   169 
   170 lemma SUP2_I [intro]: "a : A ==> B a b c ==> (SUP x:A. B x) b c"
   171   by auto
   172 
   173 lemma SUP1_E [elim!]: "(SUP x:A. B x) b ==> (!!x. x : A ==> B x b ==> R) ==> R"
   174   by auto
   175 
   176 lemma SUP2_E [elim!]: "(SUP x:A. B x) b c ==> (!!x. x : A ==> B x b c ==> R) ==> R"
   177   by auto
   178 
   179 lemma SUP_UN_eq: "(SUP i. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (UN i. r i))"
   180   by (simp add: expand_fun_eq)
   181 
   182 lemma SUP_UN_eq2: "(SUP i. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (UN i. r i))"
   183   by (simp add: expand_fun_eq)
   184 
   185 
   186 subsubsection {* Intersections of families *}
   187 
   188 lemma INF1_iff [simp]: "(INF x:A. B x) b = (ALL x:A. B x b)"
   189   by (simp add: INFI_def Inf_fun_def Inf_bool_def) blast
   190 
   191 lemma INF2_iff [simp]: "(INF x:A. B x) b c = (ALL x:A. B x b c)"
   192   by (simp add: INFI_def Inf_fun_def Inf_bool_def) blast
   193 
   194 lemma INF1_I [intro!]: "(!!x. x : A ==> B x b) ==> (INF x:A. B x) b"
   195   by auto
   196 
   197 lemma INF2_I [intro!]: "(!!x. x : A ==> B x b c) ==> (INF x:A. B x) b c"
   198   by auto
   199 
   200 lemma INF1_D [elim]: "(INF x:A. B x) b ==> a : A ==> B a b"
   201   by auto
   202 
   203 lemma INF2_D [elim]: "(INF x:A. B x) b c ==> a : A ==> B a b c"
   204   by auto
   205 
   206 lemma INF1_E [elim]: "(INF x:A. B x) b ==> (B a b ==> R) ==> (a ~: A ==> R) ==> R"
   207   by auto
   208 
   209 lemma INF2_E [elim]: "(INF x:A. B x) b c ==> (B a b c ==> R) ==> (a ~: A ==> R) ==> R"
   210   by auto
   211 
   212 lemma INF_INT_eq: "(INF i. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (INT i. r i))"
   213   by (simp add: expand_fun_eq)
   214 
   215 lemma INF_INT_eq2: "(INF i. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (INT i. r i))"
   216   by (simp add: expand_fun_eq)
   217 
   218 
   219 subsection {* Predicates as relations *}
   220 
   221 subsubsection {* Composition  *}
   222 
   223 inductive
   224   pred_comp  :: "['a => 'b => bool, 'b => 'c => bool] => 'a => 'c => bool"
   225     (infixr "OO" 75)
   226   for r :: "'a => 'b => bool" and s :: "'b => 'c => bool"
   227 where
   228   pred_compI [intro]: "r a b ==> s b c ==> (r OO s) a c"
   229 
   230 inductive_cases pred_compE [elim!]: "(r OO s) a c"
   231 
   232 lemma pred_comp_rel_comp_eq [pred_set_conv]:
   233   "((\<lambda>x y. (x, y) \<in> r) OO (\<lambda>x y. (x, y) \<in> s)) = (\<lambda>x y. (x, y) \<in> r O s)"
   234   by (auto simp add: expand_fun_eq elim: pred_compE)
   235 
   236 
   237 subsubsection {* Converse *}
   238 
   239 inductive
   240   conversep :: "('a => 'b => bool) => 'b => 'a => bool"
   241     ("(_^--1)" [1000] 1000)
   242   for r :: "'a => 'b => bool"
   243 where
   244   conversepI: "r a b ==> r^--1 b a"
   245 
   246 notation (xsymbols)
   247   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   248 
   249 lemma conversepD:
   250   assumes ab: "r^--1 a b"
   251   shows "r b a" using ab
   252   by cases simp
   253 
   254 lemma conversep_iff [iff]: "r^--1 a b = r b a"
   255   by (iprover intro: conversepI dest: conversepD)
   256 
   257 lemma conversep_converse_eq [pred_set_conv]:
   258   "(\<lambda>x y. (x, y) \<in> r)^--1 = (\<lambda>x y. (x, y) \<in> r^-1)"
   259   by (auto simp add: expand_fun_eq)
   260 
   261 lemma conversep_conversep [simp]: "(r^--1)^--1 = r"
   262   by (iprover intro: order_antisym conversepI dest: conversepD)
   263 
   264 lemma converse_pred_comp: "(r OO s)^--1 = s^--1 OO r^--1"
   265   by (iprover intro: order_antisym conversepI pred_compI
   266     elim: pred_compE dest: conversepD)
   267 
   268 lemma converse_meet: "(inf r s)^--1 = inf r^--1 s^--1"
   269   by (simp add: inf_fun_eq inf_bool_eq)
   270     (iprover intro: conversepI ext dest: conversepD)
   271 
   272 lemma converse_join: "(sup r s)^--1 = sup r^--1 s^--1"
   273   by (simp add: sup_fun_eq sup_bool_eq)
   274     (iprover intro: conversepI ext dest: conversepD)
   275 
   276 lemma conversep_noteq [simp]: "(op ~=)^--1 = op ~="
   277   by (auto simp add: expand_fun_eq)
   278 
   279 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   280   by (auto simp add: expand_fun_eq)
   281 
   282 
   283 subsubsection {* Domain *}
   284 
   285 inductive
   286   DomainP :: "('a => 'b => bool) => 'a => bool"
   287   for r :: "'a => 'b => bool"
   288 where
   289   DomainPI [intro]: "r a b ==> DomainP r a"
   290 
   291 inductive_cases DomainPE [elim!]: "DomainP r a"
   292 
   293 lemma DomainP_Domain_eq [pred_set_conv]: "DomainP (\<lambda>x y. (x, y) \<in> r) = (\<lambda>x. x \<in> Domain r)"
   294   by (blast intro!: Orderings.order_antisym predicate1I)
   295 
   296 
   297 subsubsection {* Range *}
   298 
   299 inductive
   300   RangeP :: "('a => 'b => bool) => 'b => bool"
   301   for r :: "'a => 'b => bool"
   302 where
   303   RangePI [intro]: "r a b ==> RangeP r b"
   304 
   305 inductive_cases RangePE [elim!]: "RangeP r b"
   306 
   307 lemma RangeP_Range_eq [pred_set_conv]: "RangeP (\<lambda>x y. (x, y) \<in> r) = (\<lambda>x. x \<in> Range r)"
   308   by (blast intro!: Orderings.order_antisym predicate1I)
   309 
   310 
   311 subsubsection {* Inverse image *}
   312 
   313 definition
   314   inv_imagep :: "('b => 'b => bool) => ('a => 'b) => 'a => 'a => bool" where
   315   "inv_imagep r f == %x y. r (f x) (f y)"
   316 
   317 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
   318   by (simp add: inv_image_def inv_imagep_def)
   319 
   320 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
   321   by (simp add: inv_imagep_def)
   322 
   323 
   324 subsubsection {* Powerset *}
   325 
   326 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool" where
   327   "Powp A == \<lambda>B. \<forall>x \<in> B. A x"
   328 
   329 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
   330   by (auto simp add: Powp_def expand_fun_eq)
   331 
   332 lemmas Powp_mono [mono] = Pow_mono [to_pred pred_subset_eq]
   333 
   334 
   335 subsubsection {* Properties of relations *}
   336 
   337 abbreviation antisymP :: "('a => 'a => bool) => bool" where
   338   "antisymP r == antisym {(x, y). r x y}"
   339 
   340 abbreviation transP :: "('a => 'a => bool) => bool" where
   341   "transP r == trans {(x, y). r x y}"
   342 
   343 abbreviation single_valuedP :: "('a => 'b => bool) => bool" where
   344   "single_valuedP r == single_valued {(x, y). r x y}"
   345 
   346 
   347 subsection {* Predicates as enumerations *}
   348 
   349 subsubsection {* The type of predicate enumerations (a monad) *}
   350 
   351 datatype 'a pred = Pred "'a \<Rightarrow> bool"
   352 
   353 primrec eval :: "'a pred \<Rightarrow> 'a \<Rightarrow> bool" where
   354   eval_pred: "eval (Pred f) = f"
   355 
   356 lemma Pred_eval [simp]:
   357   "Pred (eval x) = x"
   358   by (cases x) simp
   359 
   360 lemma eval_inject: "eval x = eval y \<longleftrightarrow> x = y"
   361   by (cases x) auto
   362 
   363 definition single :: "'a \<Rightarrow> 'a pred" where
   364   "single x = Pred ((op =) x)"
   365 
   366 definition bind :: "'a pred \<Rightarrow> ('a \<Rightarrow> 'b pred) \<Rightarrow> 'b pred" (infixl "\<guillemotright>=" 70) where
   367   "P \<guillemotright>= f = Pred (\<lambda>x. (\<exists>y. eval P y \<and> eval (f y) x))"
   368 
   369 instantiation pred :: (type) complete_lattice
   370 begin
   371 
   372 definition
   373   "P \<le> Q \<longleftrightarrow> eval P \<le> eval Q"
   374 
   375 definition
   376   "P < Q \<longleftrightarrow> eval P < eval Q"
   377 
   378 definition
   379   "\<bottom> = Pred \<bottom>"
   380 
   381 definition
   382   "\<top> = Pred \<top>"
   383 
   384 definition
   385   "P \<sqinter> Q = Pred (eval P \<sqinter> eval Q)"
   386 
   387 definition
   388   "P \<squnion> Q = Pred (eval P \<squnion> eval Q)"
   389 
   390 definition
   391   [code del]: "\<Sqinter>A = Pred (INFI A eval)"
   392 
   393 definition
   394   [code del]: "\<Squnion>A = Pred (SUPR A eval)"
   395 
   396 instance by default
   397   (auto simp add: less_eq_pred_def less_pred_def
   398     inf_pred_def sup_pred_def bot_pred_def top_pred_def
   399     Inf_pred_def Sup_pred_def,
   400     auto simp add: le_fun_def less_fun_def le_bool_def less_bool_def
   401     eval_inject mem_def)
   402 
   403 end
   404 
   405 lemma bind_bind:
   406   "(P \<guillemotright>= Q) \<guillemotright>= R = P \<guillemotright>= (\<lambda>x. Q x \<guillemotright>= R)"
   407   by (auto simp add: bind_def expand_fun_eq)
   408 
   409 lemma bind_single:
   410   "P \<guillemotright>= single = P"
   411   by (simp add: bind_def single_def)
   412 
   413 lemma single_bind:
   414   "single x \<guillemotright>= P = P x"
   415   by (simp add: bind_def single_def)
   416 
   417 lemma bottom_bind:
   418   "\<bottom> \<guillemotright>= P = \<bottom>"
   419   by (auto simp add: bot_pred_def bind_def expand_fun_eq)
   420 
   421 lemma sup_bind:
   422   "(P \<squnion> Q) \<guillemotright>= R = P \<guillemotright>= R \<squnion> Q \<guillemotright>= R"
   423   by (auto simp add: bind_def sup_pred_def expand_fun_eq)
   424 
   425 lemma Sup_bind: "(\<Squnion>A \<guillemotright>= f) = \<Squnion>((\<lambda>x. x \<guillemotright>= f) ` A)"
   426   by (auto simp add: bind_def Sup_pred_def expand_fun_eq)
   427 
   428 lemma pred_iffI:
   429   assumes "\<And>x. eval A x \<Longrightarrow> eval B x"
   430   and "\<And>x. eval B x \<Longrightarrow> eval A x"
   431   shows "A = B"
   432 proof -
   433   from assms have "\<And>x. eval A x \<longleftrightarrow> eval B x" by blast
   434   then show ?thesis by (cases A, cases B) (simp add: expand_fun_eq)
   435 qed
   436   
   437 lemma singleI: "eval (single x) x"
   438   unfolding single_def by simp
   439 
   440 lemma singleI_unit: "eval (single ()) x"
   441   by simp (rule singleI)
   442 
   443 lemma singleE: "eval (single x) y \<Longrightarrow> (y = x \<Longrightarrow> P) \<Longrightarrow> P"
   444   unfolding single_def by simp
   445 
   446 lemma singleE': "eval (single x) y \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> P"
   447   by (erule singleE) simp
   448 
   449 lemma bindI: "eval P x \<Longrightarrow> eval (Q x) y \<Longrightarrow> eval (P \<guillemotright>= Q) y"
   450   unfolding bind_def by auto
   451 
   452 lemma bindE: "eval (R \<guillemotright>= Q) y \<Longrightarrow> (\<And>x. eval R x \<Longrightarrow> eval (Q x) y \<Longrightarrow> P) \<Longrightarrow> P"
   453   unfolding bind_def by auto
   454 
   455 lemma botE: "eval \<bottom> x \<Longrightarrow> P"
   456   unfolding bot_pred_def by auto
   457 
   458 lemma supI1: "eval A x \<Longrightarrow> eval (A \<squnion> B) x"
   459   unfolding sup_pred_def by simp
   460 
   461 lemma supI2: "eval B x \<Longrightarrow> eval (A \<squnion> B) x" 
   462   unfolding sup_pred_def by simp
   463 
   464 lemma supE: "eval (A \<squnion> B) x \<Longrightarrow> (eval A x \<Longrightarrow> P) \<Longrightarrow> (eval B x \<Longrightarrow> P) \<Longrightarrow> P"
   465   unfolding sup_pred_def by auto
   466 
   467 
   468 subsubsection {* Derived operations *}
   469 
   470 definition if_pred :: "bool \<Rightarrow> unit pred" where
   471   if_pred_eq: "if_pred b = (if b then single () else \<bottom>)"
   472 
   473 definition not_pred :: "unit pred \<Rightarrow> unit pred" where
   474   not_pred_eq: "not_pred P = (if eval P () then \<bottom> else single ())"
   475 
   476 lemma if_predI: "P \<Longrightarrow> eval (if_pred P) ()"
   477   unfolding if_pred_eq by (auto intro: singleI)
   478 
   479 lemma if_predE: "eval (if_pred b) x \<Longrightarrow> (b \<Longrightarrow> x = () \<Longrightarrow> P) \<Longrightarrow> P"
   480   unfolding if_pred_eq by (cases b) (auto elim: botE)
   481 
   482 lemma not_predI: "\<not> P \<Longrightarrow> eval (not_pred (Pred (\<lambda>u. P))) ()"
   483   unfolding not_pred_eq eval_pred by (auto intro: singleI)
   484 
   485 lemma not_predI': "\<not> eval P () \<Longrightarrow> eval (not_pred P) ()"
   486   unfolding not_pred_eq by (auto intro: singleI)
   487 
   488 lemma not_predE: "eval (not_pred (Pred (\<lambda>u. P))) x \<Longrightarrow> (\<not> P \<Longrightarrow> thesis) \<Longrightarrow> thesis"
   489   unfolding not_pred_eq
   490   by (auto split: split_if_asm elim: botE)
   491 
   492 lemma not_predE': "eval (not_pred P) x \<Longrightarrow> (\<not> eval P x \<Longrightarrow> thesis) \<Longrightarrow> thesis"
   493   unfolding not_pred_eq
   494   by (auto split: split_if_asm elim: botE)
   495 
   496 
   497 subsubsection {* Implementation *}
   498 
   499 datatype 'a seq = Empty | Insert "'a" "'a pred" | Join "'a pred" "'a seq"
   500 
   501 primrec pred_of_seq :: "'a seq \<Rightarrow> 'a pred" where
   502     "pred_of_seq Empty = \<bottom>"
   503   | "pred_of_seq (Insert x P) = single x \<squnion> P"
   504   | "pred_of_seq (Join P xq) = P \<squnion> pred_of_seq xq"
   505 
   506 definition Seq :: "(unit \<Rightarrow> 'a seq) \<Rightarrow> 'a pred" where
   507   "Seq f = pred_of_seq (f ())"
   508 
   509 code_datatype Seq
   510 
   511 primrec member :: "'a seq \<Rightarrow> 'a \<Rightarrow> bool"  where
   512   "member Empty x \<longleftrightarrow> False"
   513   | "member (Insert y P) x \<longleftrightarrow> x = y \<or> eval P x"
   514   | "member (Join P xq) x \<longleftrightarrow> eval P x \<or> member xq x"
   515 
   516 lemma eval_member:
   517   "member xq = eval (pred_of_seq xq)"
   518 proof (induct xq)
   519   case Empty show ?case
   520   by (auto simp add: expand_fun_eq elim: botE)
   521 next
   522   case Insert show ?case
   523   by (auto simp add: expand_fun_eq elim: supE singleE intro: supI1 supI2 singleI)
   524 next
   525   case Join then show ?case
   526   by (auto simp add: expand_fun_eq elim: supE intro: supI1 supI2)
   527 qed
   528 
   529 lemma eval_code [code]: "eval (Seq f) = member (f ())"
   530   unfolding Seq_def by (rule sym, rule eval_member)
   531 
   532 lemma single_code [code]:
   533   "single x = Seq (\<lambda>u. Insert x \<bottom>)"
   534   unfolding Seq_def by simp
   535 
   536 primrec "apply" :: "('a \<Rightarrow> 'b Predicate.pred) \<Rightarrow> 'a seq \<Rightarrow> 'b seq" where
   537     "apply f Empty = Empty"
   538   | "apply f (Insert x P) = Join (f x) (Join (P \<guillemotright>= f) Empty)"
   539   | "apply f (Join P xq) = Join (P \<guillemotright>= f) (apply f xq)"
   540 
   541 lemma apply_bind:
   542   "pred_of_seq (apply f xq) = pred_of_seq xq \<guillemotright>= f"
   543 proof (induct xq)
   544   case Empty show ?case
   545     by (simp add: bottom_bind)
   546 next
   547   case Insert show ?case
   548     by (simp add: single_bind sup_bind)
   549 next
   550   case Join then show ?case
   551     by (simp add: sup_bind)
   552 qed
   553   
   554 lemma bind_code [code]:
   555   "Seq g \<guillemotright>= f = Seq (\<lambda>u. apply f (g ()))"
   556   unfolding Seq_def by (rule sym, rule apply_bind)
   557 
   558 lemma bot_set_code [code]:
   559   "\<bottom> = Seq (\<lambda>u. Empty)"
   560   unfolding Seq_def by simp
   561 
   562 primrec adjunct :: "'a pred \<Rightarrow> 'a seq \<Rightarrow> 'a seq" where
   563     "adjunct P Empty = Join P Empty"
   564   | "adjunct P (Insert x Q) = Insert x (Q \<squnion> P)"
   565   | "adjunct P (Join Q xq) = Join Q (adjunct P xq)"
   566 
   567 lemma adjunct_sup:
   568   "pred_of_seq (adjunct P xq) = P \<squnion> pred_of_seq xq"
   569   by (induct xq) (simp_all add: sup_assoc sup_commute sup_left_commute)
   570 
   571 lemma sup_code [code]:
   572   "Seq f \<squnion> Seq g = Seq (\<lambda>u. case f ()
   573     of Empty \<Rightarrow> g ()
   574      | Insert x P \<Rightarrow> Insert x (P \<squnion> Seq g)
   575      | Join P xq \<Rightarrow> adjunct (Seq g) (Join P xq))"
   576 proof (cases "f ()")
   577   case Empty
   578   thus ?thesis
   579     unfolding Seq_def by (simp add: sup_commute [of "\<bottom>"]  sup_bot)
   580 next
   581   case Insert
   582   thus ?thesis
   583     unfolding Seq_def by (simp add: sup_assoc)
   584 next
   585   case Join
   586   thus ?thesis
   587     unfolding Seq_def
   588     by (simp add: adjunct_sup sup_assoc sup_commute sup_left_commute)
   589 qed
   590 
   591 primrec contained :: "'a seq \<Rightarrow> 'a pred \<Rightarrow> bool" where
   592     "contained Empty Q \<longleftrightarrow> True"
   593   | "contained (Insert x P) Q \<longleftrightarrow> eval Q x \<and> P \<le> Q"
   594   | "contained (Join P xq) Q \<longleftrightarrow> P \<le> Q \<and> contained xq Q"
   595 
   596 lemma single_less_eq_eval:
   597   "single x \<le> P \<longleftrightarrow> eval P x"
   598   by (auto simp add: single_def less_eq_pred_def mem_def)
   599 
   600 lemma contained_less_eq:
   601   "contained xq Q \<longleftrightarrow> pred_of_seq xq \<le> Q"
   602   by (induct xq) (simp_all add: single_less_eq_eval)
   603 
   604 lemma less_eq_pred_code [code]:
   605   "Seq f \<le> Q = (case f ()
   606    of Empty \<Rightarrow> True
   607     | Insert x P \<Rightarrow> eval Q x \<and> P \<le> Q
   608     | Join P xq \<Rightarrow> P \<le> Q \<and> contained xq Q)"
   609   by (cases "f ()")
   610     (simp_all add: Seq_def single_less_eq_eval contained_less_eq)
   611 
   612 lemma eq_pred_code [code]:
   613   fixes P Q :: "'a pred"
   614   shows "eq_class.eq P Q \<longleftrightarrow> P \<le> Q \<and> Q \<le> P"
   615   unfolding eq by auto
   616 
   617 lemma [code]:
   618   "pred_case f P = f (eval P)"
   619   by (cases P) simp
   620 
   621 lemma [code]:
   622   "pred_rec f P = f (eval P)"
   623   by (cases P) simp
   624 
   625 inductive eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where "eq x x"
   626 
   627 lemma eq_is_eq: "eq x y \<equiv> (x = y)"
   628   by (rule eq_reflection) (auto intro: eq.intros elim: eq.cases)
   629 
   630 definition map :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a pred \<Rightarrow> 'b pred" where
   631   "map f P = P \<guillemotright>= (single o f)"
   632 
   633 ML {*
   634 signature PREDICATE =
   635 sig
   636   datatype 'a pred = Seq of (unit -> 'a seq)
   637   and 'a seq = Empty | Insert of 'a * 'a pred | Join of 'a pred * 'a seq
   638   val yield: 'a pred -> ('a * 'a pred) option
   639   val yieldn: int -> 'a pred -> 'a list * 'a pred
   640   val map: ('a -> 'b) -> 'a pred -> 'b pred
   641 end;
   642 
   643 structure Predicate : PREDICATE =
   644 struct
   645 
   646 @{code_datatype pred = Seq};
   647 @{code_datatype seq = Empty | Insert | Join};
   648 
   649 fun yield (Seq f) = next (f ())
   650 and next @{code Empty} = NONE
   651   | next (@{code Insert} (x, P)) = SOME (x, P)
   652   | next (@{code Join} (P, xq)) = (case yield P
   653      of NONE => next xq
   654       | SOME (x, Q) => SOME (x, @{code Seq} (fn _ => @{code Join} (Q, xq))))
   655 
   656 fun anamorph f k x = (if k = 0 then ([], x)
   657   else case f x
   658    of NONE => ([], x)
   659     | SOME (v, y) => let
   660         val (vs, z) = anamorph f (k - 1) y
   661       in (v :: vs, z) end)
   662 
   663 fun yieldn P = anamorph yield P;
   664 
   665 fun map f = @{code map} f;
   666 
   667 end;
   668 *}
   669 
   670 code_reserved Eval Predicate
   671 
   672 code_type pred and seq
   673   (Eval "_/ Predicate.pred" and "_/ Predicate.seq")
   674 
   675 code_const Seq and Empty and Insert and Join
   676   (Eval "Predicate.Seq" and "Predicate.Empty" and "Predicate.Insert/ (_,/ _)" and "Predicate.Join/ (_,/ _)")
   677 
   678 text {* dummy setup for @{text code_pred} and @{text values} keywords *}
   679 
   680 ML {*
   681 local
   682 
   683 structure P = OuterParse;
   684 
   685 val opt_modes = Scan.optional (P.$$$ "(" |-- P.!!! (Scan.repeat1 P.xname --| P.$$$ ")")) [];
   686 
   687 in
   688 
   689 val _ = OuterSyntax.local_theory_to_proof "code_pred" "sets up goal for cases rule from given introduction rules and compiles predicate"
   690   OuterKeyword.thy_goal (P.term_group >> (K (Proof.theorem_i NONE (K I) [[]])));
   691 
   692 val _ = OuterSyntax.improper_command "values" "enumerate and print comprehensions"
   693   OuterKeyword.diag ((opt_modes -- P.term)
   694     >> (fn (modes, t) => Toplevel.no_timing o Toplevel.keep
   695         (K ())));
   696 
   697 end
   698 *}
   699 
   700 no_notation
   701   inf (infixl "\<sqinter>" 70) and
   702   sup (infixl "\<squnion>" 65) and
   703   Inf ("\<Sqinter>_" [900] 900) and
   704   Sup ("\<Squnion>_" [900] 900) and
   705   top ("\<top>") and
   706   bot ("\<bottom>") and
   707   bind (infixl "\<guillemotright>=" 70)
   708 
   709 hide (open) type pred seq
   710 hide (open) const Pred eval single bind if_pred not_pred
   711   Empty Insert Join Seq member pred_of_seq "apply" adjunct eq map
   712 
   713 end