src/HOL/Transitive_Closure.thy
author krauss
Mon Jul 27 21:47:41 2009 +0200 (2009-07-27 ago)
changeset 32235 8f9b8d14fc9f
parent 32215 87806301a813
child 32601 47d0c967c64e
permissions -rw-r--r--
"more standard" argument order of relation composition (op O)
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Reflexive and Transitive closure of a relation *}
     7 
     8 theory Transitive_Closure
     9 imports Predicate
    10 uses "~~/src/Provers/trancl.ML"
    11 begin
    12 
    13 text {*
    14   @{text rtrancl} is reflexive/transitive closure,
    15   @{text trancl} is transitive closure,
    16   @{text reflcl} is reflexive closure.
    17 
    18   These postfix operators have \emph{maximum priority}, forcing their
    19   operands to be atomic.
    20 *}
    21 
    22 inductive_set
    23   rtrancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"   ("(_^*)" [1000] 999)
    24   for r :: "('a \<times> 'a) set"
    25 where
    26     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"
    27   | rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    28 
    29 inductive_set
    30   trancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"  ("(_^+)" [1000] 999)
    31   for r :: "('a \<times> 'a) set"
    32 where
    33     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"
    34   | trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a, c) : r^+"
    35 
    36 notation
    37   rtranclp  ("(_^**)" [1000] 1000) and
    38   tranclp  ("(_^++)" [1000] 1000)
    39 
    40 abbreviation
    41   reflclp :: "('a => 'a => bool) => 'a => 'a => bool"  ("(_^==)" [1000] 1000) where
    42   "r^== == sup r op ="
    43 
    44 abbreviation
    45   reflcl :: "('a \<times> 'a) set => ('a \<times> 'a) set"  ("(_^=)" [1000] 999) where
    46   "r^= == r \<union> Id"
    47 
    48 notation (xsymbols)
    49   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    50   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    51   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    52   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    53   trancl  ("(_\<^sup>+)" [1000] 999) and
    54   reflcl  ("(_\<^sup>=)" [1000] 999)
    55 
    56 notation (HTML output)
    57   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    58   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    59   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    60   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    61   trancl  ("(_\<^sup>+)" [1000] 999) and
    62   reflcl  ("(_\<^sup>=)" [1000] 999)
    63 
    64 
    65 subsection {* Reflexive closure *}
    66 
    67 lemma refl_reflcl[simp]: "refl(r^=)"
    68 by(simp add:refl_on_def)
    69 
    70 lemma antisym_reflcl[simp]: "antisym(r^=) = antisym r"
    71 by(simp add:antisym_def)
    72 
    73 lemma trans_reflclI[simp]: "trans r \<Longrightarrow> trans(r^=)"
    74 unfolding trans_def by blast
    75 
    76 
    77 subsection {* Reflexive-transitive closure *}
    78 
    79 lemma reflcl_set_eq [pred_set_conv]: "(sup (\<lambda>x y. (x, y) \<in> r) op =) = (\<lambda>x y. (x, y) \<in> r Un Id)"
    80   by (simp add: expand_fun_eq)
    81 
    82 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    83   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    84   apply (simp only: split_tupled_all)
    85   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    86   done
    87 
    88 lemma r_into_rtranclp [intro]: "r x y ==> r^** x y"
    89   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    90   by (erule rtranclp.rtrancl_refl [THEN rtranclp.rtrancl_into_rtrancl])
    91 
    92 lemma rtranclp_mono: "r \<le> s ==> r^** \<le> s^**"
    93   -- {* monotonicity of @{text rtrancl} *}
    94   apply (rule predicate2I)
    95   apply (erule rtranclp.induct)
    96    apply (rule_tac [2] rtranclp.rtrancl_into_rtrancl, blast+)
    97   done
    98 
    99 lemmas rtrancl_mono = rtranclp_mono [to_set]
   100 
   101 theorem rtranclp_induct [consumes 1, case_names base step, induct set: rtranclp]:
   102   assumes a: "r^** a b"
   103     and cases: "P a" "!!y z. [| r^** a y; r y z; P y |] ==> P z"
   104   shows "P b"
   105 proof -
   106   from a have "a = a --> P b"
   107     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
   108   then show ?thesis by iprover
   109 qed
   110 
   111 lemmas rtrancl_induct [induct set: rtrancl] = rtranclp_induct [to_set]
   112 
   113 lemmas rtranclp_induct2 =
   114   rtranclp_induct[of _ "(ax,ay)" "(bx,by)", split_rule,
   115                  consumes 1, case_names refl step]
   116 
   117 lemmas rtrancl_induct2 =
   118   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   119                  consumes 1, case_names refl step]
   120 
   121 lemma refl_rtrancl: "refl (r^*)"
   122 by (unfold refl_on_def) fast
   123 
   124 text {* Transitivity of transitive closure. *}
   125 lemma trans_rtrancl: "trans (r^*)"
   126 proof (rule transI)
   127   fix x y z
   128   assume "(x, y) \<in> r\<^sup>*"
   129   assume "(y, z) \<in> r\<^sup>*"
   130   then show "(x, z) \<in> r\<^sup>*"
   131   proof induct
   132     case base
   133     show "(x, y) \<in> r\<^sup>*" by fact
   134   next
   135     case (step u v)
   136     from `(x, u) \<in> r\<^sup>*` and `(u, v) \<in> r`
   137     show "(x, v) \<in> r\<^sup>*" ..
   138   qed
   139 qed
   140 
   141 lemmas rtrancl_trans = trans_rtrancl [THEN transD, standard]
   142 
   143 lemma rtranclp_trans:
   144   assumes xy: "r^** x y"
   145   and yz: "r^** y z"
   146   shows "r^** x z" using yz xy
   147   by induct iprover+
   148 
   149 lemma rtranclE [cases set: rtrancl]:
   150   assumes major: "(a::'a, b) : r^*"
   151   obtains
   152     (base) "a = b"
   153   | (step) y where "(a, y) : r^*" and "(y, b) : r"
   154   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
   155   apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   156    apply (rule_tac [2] major [THEN rtrancl_induct])
   157     prefer 2 apply blast
   158    prefer 2 apply blast
   159   apply (erule asm_rl exE disjE conjE base step)+
   160   done
   161 
   162 lemma rtrancl_Int_subset: "[| Id \<subseteq> s; (r^* \<inter> s) O r \<subseteq> s|] ==> r^* \<subseteq> s"
   163   apply (rule subsetI)
   164   apply (rule_tac p="x" in PairE, clarify)
   165   apply (erule rtrancl_induct, auto) 
   166   done
   167 
   168 lemma converse_rtranclp_into_rtranclp:
   169   "r a b \<Longrightarrow> r\<^sup>*\<^sup>* b c \<Longrightarrow> r\<^sup>*\<^sup>* a c"
   170   by (rule rtranclp_trans) iprover+
   171 
   172 lemmas converse_rtrancl_into_rtrancl = converse_rtranclp_into_rtranclp [to_set]
   173 
   174 text {*
   175   \medskip More @{term "r^*"} equations and inclusions.
   176 *}
   177 
   178 lemma rtranclp_idemp [simp]: "(r^**)^** = r^**"
   179   apply (auto intro!: order_antisym)
   180   apply (erule rtranclp_induct)
   181    apply (rule rtranclp.rtrancl_refl)
   182   apply (blast intro: rtranclp_trans)
   183   done
   184 
   185 lemmas rtrancl_idemp [simp] = rtranclp_idemp [to_set]
   186 
   187 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   188   apply (rule set_ext)
   189   apply (simp only: split_tupled_all)
   190   apply (blast intro: rtrancl_trans)
   191   done
   192 
   193 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   194   apply (drule rtrancl_mono)
   195   apply simp
   196   done
   197 
   198 lemma rtranclp_subset: "R \<le> S ==> S \<le> R^** ==> S^** = R^**"
   199   apply (drule rtranclp_mono)
   200   apply (drule rtranclp_mono)
   201   apply simp
   202   done
   203 
   204 lemmas rtrancl_subset = rtranclp_subset [to_set]
   205 
   206 lemma rtranclp_sup_rtranclp: "(sup (R^**) (S^**))^** = (sup R S)^**"
   207   by (blast intro!: rtranclp_subset intro: rtranclp_mono [THEN predicate2D])
   208 
   209 lemmas rtrancl_Un_rtrancl = rtranclp_sup_rtranclp [to_set]
   210 
   211 lemma rtranclp_reflcl [simp]: "(R^==)^** = R^**"
   212   by (blast intro!: rtranclp_subset)
   213 
   214 lemmas rtrancl_reflcl [simp] = rtranclp_reflcl [to_set]
   215 
   216 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   217   apply (rule sym)
   218   apply (rule rtrancl_subset, blast, clarify)
   219   apply (rename_tac a b)
   220   apply (case_tac "a = b")
   221    apply blast
   222   apply (blast intro!: r_into_rtrancl)
   223   done
   224 
   225 lemma rtranclp_r_diff_Id: "(inf r op ~=)^** = r^**"
   226   apply (rule sym)
   227   apply (rule rtranclp_subset)
   228    apply blast+
   229   done
   230 
   231 theorem rtranclp_converseD:
   232   assumes r: "(r^--1)^** x y"
   233   shows "r^** y x"
   234 proof -
   235   from r show ?thesis
   236     by induct (iprover intro: rtranclp_trans dest!: conversepD)+
   237 qed
   238 
   239 lemmas rtrancl_converseD = rtranclp_converseD [to_set]
   240 
   241 theorem rtranclp_converseI:
   242   assumes "r^** y x"
   243   shows "(r^--1)^** x y"
   244   using assms
   245   by induct (iprover intro: rtranclp_trans conversepI)+
   246 
   247 lemmas rtrancl_converseI = rtranclp_converseI [to_set]
   248 
   249 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   250   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   251 
   252 lemma sym_rtrancl: "sym r ==> sym (r^*)"
   253   by (simp only: sym_conv_converse_eq rtrancl_converse [symmetric])
   254 
   255 theorem converse_rtranclp_induct[consumes 1]:
   256   assumes major: "r^** a b"
   257     and cases: "P b" "!!y z. [| r y z; r^** z b; P z |] ==> P y"
   258   shows "P a"
   259   using rtranclp_converseI [OF major]
   260   by induct (iprover intro: cases dest!: conversepD rtranclp_converseD)+
   261 
   262 lemmas converse_rtrancl_induct = converse_rtranclp_induct [to_set]
   263 
   264 lemmas converse_rtranclp_induct2 =
   265   converse_rtranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   266                  consumes 1, case_names refl step]
   267 
   268 lemmas converse_rtrancl_induct2 =
   269   converse_rtrancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   270                  consumes 1, case_names refl step]
   271 
   272 lemma converse_rtranclpE:
   273   assumes major: "r^** x z"
   274     and cases: "x=z ==> P"
   275       "!!y. [| r x y; r^** y z |] ==> P"
   276   shows P
   277   apply (subgoal_tac "x = z | (EX y. r x y & r^** y z)")
   278    apply (rule_tac [2] major [THEN converse_rtranclp_induct])
   279     prefer 2 apply iprover
   280    prefer 2 apply iprover
   281   apply (erule asm_rl exE disjE conjE cases)+
   282   done
   283 
   284 lemmas converse_rtranclE = converse_rtranclpE [to_set]
   285 
   286 lemmas converse_rtranclpE2 = converse_rtranclpE [of _ "(xa,xb)" "(za,zb)", split_rule]
   287 
   288 lemmas converse_rtranclE2 = converse_rtranclE [of "(xa,xb)" "(za,zb)", split_rule]
   289 
   290 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   291   by (blast elim: rtranclE converse_rtranclE
   292     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   293 
   294 lemma rtrancl_unfold: "r^* = Id Un r^* O r"
   295   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)
   296 
   297 lemma rtrancl_Un_separatorE:
   298   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (a,x) : P^* \<longrightarrow> (x,y) : Q \<longrightarrow> x=y \<Longrightarrow> (a,b) : P^*"
   299 apply (induct rule:rtrancl.induct)
   300  apply blast
   301 apply (blast intro:rtrancl_trans)
   302 done
   303 
   304 lemma rtrancl_Un_separator_converseE:
   305   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (x,b) : P^* \<longrightarrow> (y,x) : Q \<longrightarrow> y=x \<Longrightarrow> (a,b) : P^*"
   306 apply (induct rule:converse_rtrancl_induct)
   307  apply blast
   308 apply (blast intro:rtrancl_trans)
   309 done
   310 
   311 
   312 subsection {* Transitive closure *}
   313 
   314 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   315   apply (simp add: split_tupled_all)
   316   apply (erule trancl.induct)
   317    apply (iprover dest: subsetD)+
   318   done
   319 
   320 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   321   by (simp only: split_tupled_all) (erule r_into_trancl)
   322 
   323 text {*
   324   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   325 *}
   326 
   327 lemma tranclp_into_rtranclp: "r^++ a b ==> r^** a b"
   328   by (erule tranclp.induct) iprover+
   329 
   330 lemmas trancl_into_rtrancl = tranclp_into_rtranclp [to_set]
   331 
   332 lemma rtranclp_into_tranclp1: assumes r: "r^** a b"
   333   shows "!!c. r b c ==> r^++ a c" using r
   334   by induct iprover+
   335 
   336 lemmas rtrancl_into_trancl1 = rtranclp_into_tranclp1 [to_set]
   337 
   338 lemma rtranclp_into_tranclp2: "[| r a b; r^** b c |] ==> r^++ a c"
   339   -- {* intro rule from @{text r} and @{text rtrancl} *}
   340   apply (erule rtranclp.cases)
   341    apply iprover
   342   apply (rule rtranclp_trans [THEN rtranclp_into_tranclp1])
   343     apply (simp | rule r_into_rtranclp)+
   344   done
   345 
   346 lemmas rtrancl_into_trancl2 = rtranclp_into_tranclp2 [to_set]
   347 
   348 text {* Nice induction rule for @{text trancl} *}
   349 lemma tranclp_induct [consumes 1, case_names base step, induct pred: tranclp]:
   350   assumes "r^++ a b"
   351   and cases: "!!y. r a y ==> P y"
   352     "!!y z. r^++ a y ==> r y z ==> P y ==> P z"
   353   shows "P b"
   354 proof -
   355   from `r^++ a b` have "a = a --> P b"
   356     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
   357   then show ?thesis by iprover
   358 qed
   359 
   360 lemmas trancl_induct [induct set: trancl] = tranclp_induct [to_set]
   361 
   362 lemmas tranclp_induct2 =
   363   tranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   364     consumes 1, case_names base step]
   365 
   366 lemmas trancl_induct2 =
   367   trancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   368     consumes 1, case_names base step]
   369 
   370 lemma tranclp_trans_induct:
   371   assumes major: "r^++ x y"
   372     and cases: "!!x y. r x y ==> P x y"
   373       "!!x y z. [| r^++ x y; P x y; r^++ y z; P y z |] ==> P x z"
   374   shows "P x y"
   375   -- {* Another induction rule for trancl, incorporating transitivity *}
   376   by (iprover intro: major [THEN tranclp_induct] cases)
   377 
   378 lemmas trancl_trans_induct = tranclp_trans_induct [to_set]
   379 
   380 lemma tranclE [cases set: trancl]:
   381   assumes "(a, b) : r^+"
   382   obtains
   383     (base) "(a, b) : r"
   384   | (step) c where "(a, c) : r^+" and "(c, b) : r"
   385   using assms by cases simp_all
   386 
   387 lemma trancl_Int_subset: "[| r \<subseteq> s; (r^+ \<inter> s) O r \<subseteq> s|] ==> r^+ \<subseteq> s"
   388   apply (rule subsetI)
   389   apply (rule_tac p = x in PairE)
   390   apply clarify
   391   apply (erule trancl_induct)
   392    apply auto
   393   done
   394 
   395 lemma trancl_unfold: "r^+ = r Un r^+ O r"
   396   by (auto intro: trancl_into_trancl elim: tranclE)
   397 
   398 text {* Transitivity of @{term "r^+"} *}
   399 lemma trans_trancl [simp]: "trans (r^+)"
   400 proof (rule transI)
   401   fix x y z
   402   assume "(x, y) \<in> r^+"
   403   assume "(y, z) \<in> r^+"
   404   then show "(x, z) \<in> r^+"
   405   proof induct
   406     case (base u)
   407     from `(x, y) \<in> r^+` and `(y, u) \<in> r`
   408     show "(x, u) \<in> r^+" ..
   409   next
   410     case (step u v)
   411     from `(x, u) \<in> r^+` and `(u, v) \<in> r`
   412     show "(x, v) \<in> r^+" ..
   413   qed
   414 qed
   415 
   416 lemmas trancl_trans = trans_trancl [THEN transD, standard]
   417 
   418 lemma tranclp_trans:
   419   assumes xy: "r^++ x y"
   420   and yz: "r^++ y z"
   421   shows "r^++ x z" using yz xy
   422   by induct iprover+
   423 
   424 lemma trancl_id [simp]: "trans r \<Longrightarrow> r^+ = r"
   425   apply auto
   426   apply (erule trancl_induct)
   427    apply assumption
   428   apply (unfold trans_def)
   429   apply blast
   430   done
   431 
   432 lemma rtranclp_tranclp_tranclp:
   433   assumes "r^** x y"
   434   shows "!!z. r^++ y z ==> r^++ x z" using assms
   435   by induct (iprover intro: tranclp_trans)+
   436 
   437 lemmas rtrancl_trancl_trancl = rtranclp_tranclp_tranclp [to_set]
   438 
   439 lemma tranclp_into_tranclp2: "r a b ==> r^++ b c ==> r^++ a c"
   440   by (erule tranclp_trans [OF tranclp.r_into_trancl])
   441 
   442 lemmas trancl_into_trancl2 = tranclp_into_tranclp2 [to_set]
   443 
   444 lemma trancl_insert:
   445   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   446   -- {* primitive recursion for @{text trancl} over finite relations *}
   447   apply (rule equalityI)
   448    apply (rule subsetI)
   449    apply (simp only: split_tupled_all)
   450    apply (erule trancl_induct, blast)
   451    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl r_into_trancl trancl_trans)
   452   apply (rule subsetI)
   453   apply (blast intro: trancl_mono rtrancl_mono
   454     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   455   done
   456 
   457 lemma tranclp_converseI: "(r^++)^--1 x y ==> (r^--1)^++ x y"
   458   apply (drule conversepD)
   459   apply (erule tranclp_induct)
   460   apply (iprover intro: conversepI tranclp_trans)+
   461   done
   462 
   463 lemmas trancl_converseI = tranclp_converseI [to_set]
   464 
   465 lemma tranclp_converseD: "(r^--1)^++ x y ==> (r^++)^--1 x y"
   466   apply (rule conversepI)
   467   apply (erule tranclp_induct)
   468   apply (iprover dest: conversepD intro: tranclp_trans)+
   469   done
   470 
   471 lemmas trancl_converseD = tranclp_converseD [to_set]
   472 
   473 lemma tranclp_converse: "(r^--1)^++ = (r^++)^--1"
   474   by (fastsimp simp add: expand_fun_eq
   475     intro!: tranclp_converseI dest!: tranclp_converseD)
   476 
   477 lemmas trancl_converse = tranclp_converse [to_set]
   478 
   479 lemma sym_trancl: "sym r ==> sym (r^+)"
   480   by (simp only: sym_conv_converse_eq trancl_converse [symmetric])
   481 
   482 lemma converse_tranclp_induct:
   483   assumes major: "r^++ a b"
   484     and cases: "!!y. r y b ==> P(y)"
   485       "!!y z.[| r y z;  r^++ z b;  P(z) |] ==> P(y)"
   486   shows "P a"
   487   apply (rule tranclp_induct [OF tranclp_converseI, OF conversepI, OF major])
   488    apply (rule cases)
   489    apply (erule conversepD)
   490   apply (blast intro: prems dest!: tranclp_converseD conversepD)
   491   done
   492 
   493 lemmas converse_trancl_induct = converse_tranclp_induct [to_set]
   494 
   495 lemma tranclpD: "R^++ x y ==> EX z. R x z \<and> R^** z y"
   496   apply (erule converse_tranclp_induct)
   497    apply auto
   498   apply (blast intro: rtranclp_trans)
   499   done
   500 
   501 lemmas tranclD = tranclpD [to_set]
   502 
   503 lemma converse_tranclpE:
   504   assumes major: "tranclp r x z"
   505   assumes base: "r x z ==> P"
   506   assumes step: "\<And> y. [| r x y; tranclp r y z |] ==> P"
   507   shows P
   508 proof -
   509   from tranclpD[OF major]
   510   obtain y where "r x y" and "rtranclp r y z" by iprover
   511   from this(2) show P
   512   proof (cases rule: rtranclp.cases)
   513     case rtrancl_refl
   514     with `r x y` base show P by iprover
   515   next
   516     case rtrancl_into_rtrancl
   517     from this have "tranclp r y z"
   518       by (iprover intro: rtranclp_into_tranclp1)
   519     with `r x y` step show P by iprover
   520   qed
   521 qed
   522 
   523 lemmas converse_tranclE = converse_tranclpE [to_set]
   524 
   525 lemma tranclD2:
   526   "(x, y) \<in> R\<^sup>+ \<Longrightarrow> \<exists>z. (x, z) \<in> R\<^sup>* \<and> (z, y) \<in> R"
   527   by (blast elim: tranclE intro: trancl_into_rtrancl)
   528 
   529 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   530   by (blast elim: tranclE dest: trancl_into_rtrancl)
   531 
   532 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   533   by (blast dest: r_into_trancl)
   534 
   535 lemma trancl_subset_Sigma_aux:
   536     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   537   by (induct rule: rtrancl_induct) auto
   538 
   539 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   540   apply (rule subsetI)
   541   apply (simp only: split_tupled_all)
   542   apply (erule tranclE)
   543    apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   544   done
   545 
   546 lemma reflcl_tranclp [simp]: "(r^++)^== = r^**"
   547   apply (safe intro!: order_antisym)
   548    apply (erule tranclp_into_rtranclp)
   549   apply (blast elim: rtranclp.cases dest: rtranclp_into_tranclp1)
   550   done
   551 
   552 lemmas reflcl_trancl [simp] = reflcl_tranclp [to_set]
   553 
   554 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   555   apply safe
   556    apply (drule trancl_into_rtrancl, simp)
   557   apply (erule rtranclE, safe)
   558    apply (rule r_into_trancl, simp)
   559   apply (rule rtrancl_into_trancl1)
   560    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   561   done
   562 
   563 lemma trancl_empty [simp]: "{}^+ = {}"
   564   by (auto elim: trancl_induct)
   565 
   566 lemma rtrancl_empty [simp]: "{}^* = Id"
   567   by (rule subst [OF reflcl_trancl]) simp
   568 
   569 lemma rtranclpD: "R^** a b ==> a = b \<or> a \<noteq> b \<and> R^++ a b"
   570   by (force simp add: reflcl_tranclp [symmetric] simp del: reflcl_tranclp)
   571 
   572 lemmas rtranclD = rtranclpD [to_set]
   573 
   574 lemma rtrancl_eq_or_trancl:
   575   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"
   576   by (fast elim: trancl_into_rtrancl dest: rtranclD)
   577 
   578 text {* @{text Domain} and @{text Range} *}
   579 
   580 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   581   by blast
   582 
   583 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   584   by blast
   585 
   586 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   587   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   588 
   589 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   590   by (blast intro: subsetD [OF rtrancl_Un_subset])
   591 
   592 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   593   by (unfold Domain_def) (blast dest: tranclD)
   594 
   595 lemma trancl_range [simp]: "Range (r^+) = Range r"
   596 unfolding Range_def by(simp add: trancl_converse [symmetric])
   597 
   598 lemma Not_Domain_rtrancl:
   599     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   600   apply auto
   601   apply (erule rev_mp)
   602   apply (erule rtrancl_induct)
   603    apply auto
   604   done
   605 
   606 lemma trancl_subset_Field2: "r^+ <= Field r \<times> Field r"
   607   apply clarify
   608   apply (erule trancl_induct)
   609    apply (auto simp add: Field_def)
   610   done
   611 
   612 lemma finite_trancl: "finite (r^+) = finite r"
   613   apply auto
   614    prefer 2
   615    apply (rule trancl_subset_Field2 [THEN finite_subset])
   616    apply (rule finite_SigmaI)
   617     prefer 3
   618     apply (blast intro: r_into_trancl' finite_subset)
   619    apply (auto simp add: finite_Field)
   620   done
   621 
   622 text {* More about converse @{text rtrancl} and @{text trancl}, should
   623   be merged with main body. *}
   624 
   625 lemma single_valued_confluent:
   626   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   627   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   628   apply (erule rtrancl_induct)
   629   apply simp
   630   apply (erule disjE)
   631    apply (blast elim:converse_rtranclE dest:single_valuedD)
   632   apply(blast intro:rtrancl_trans)
   633   done
   634 
   635 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   636   by (fast intro: trancl_trans)
   637 
   638 lemma trancl_into_trancl [rule_format]:
   639     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   640   apply (erule trancl_induct)
   641    apply (fast intro: r_r_into_trancl)
   642   apply (fast intro: r_r_into_trancl trancl_trans)
   643   done
   644 
   645 lemma tranclp_rtranclp_tranclp:
   646     "r\<^sup>+\<^sup>+ a b ==> r\<^sup>*\<^sup>* b c ==> r\<^sup>+\<^sup>+ a c"
   647   apply (drule tranclpD)
   648   apply (elim exE conjE)
   649   apply (drule rtranclp_trans, assumption)
   650   apply (drule rtranclp_into_tranclp2, assumption, assumption)
   651   done
   652 
   653 lemmas trancl_rtrancl_trancl = tranclp_rtranclp_tranclp [to_set]
   654 
   655 lemmas transitive_closure_trans [trans] =
   656   r_r_into_trancl trancl_trans rtrancl_trans
   657   trancl.trancl_into_trancl trancl_into_trancl2
   658   rtrancl.rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   659   rtrancl_trancl_trancl trancl_rtrancl_trancl
   660 
   661 lemmas transitive_closurep_trans' [trans] =
   662   tranclp_trans rtranclp_trans
   663   tranclp.trancl_into_trancl tranclp_into_tranclp2
   664   rtranclp.rtrancl_into_rtrancl converse_rtranclp_into_rtranclp
   665   rtranclp_tranclp_tranclp tranclp_rtranclp_tranclp
   666 
   667 declare trancl_into_rtrancl [elim]
   668 
   669 subsection {* The power operation on relations *}
   670 
   671 text {* @{text "R ^^ n = R O ... O R"}, the n-fold composition of @{text R} *}
   672 
   673 overloading
   674   relpow == "compow :: nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"
   675 begin
   676 
   677 primrec relpow :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" where
   678     "relpow 0 R = Id"
   679   | "relpow (Suc n) R = (R ^^ n) O R"
   680 
   681 end
   682 
   683 lemma rel_pow_1 [simp]:
   684   fixes R :: "('a \<times> 'a) set"
   685   shows "R ^^ 1 = R"
   686   by simp
   687 
   688 lemma rel_pow_0_I: 
   689   "(x, x) \<in> R ^^ 0"
   690   by simp
   691 
   692 lemma rel_pow_Suc_I:
   693   "(x, y) \<in>  R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   694   by auto
   695 
   696 lemma rel_pow_Suc_I2:
   697   "(x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   698   by (induct n arbitrary: z) (simp, fastsimp)
   699 
   700 lemma rel_pow_0_E:
   701   "(x, y) \<in> R ^^ 0 \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> P"
   702   by simp
   703 
   704 lemma rel_pow_Suc_E:
   705   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P) \<Longrightarrow> P"
   706   by auto
   707 
   708 lemma rel_pow_E:
   709   "(x, z) \<in>  R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   710    \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in>  R ^^ m \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P)
   711    \<Longrightarrow> P"
   712   by (cases n) auto
   713 
   714 lemma rel_pow_Suc_D2:
   715   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<exists>y. (x, y) \<in> R \<and> (y, z) \<in> R ^^ n)"
   716   apply (induct n arbitrary: x z)
   717    apply (blast intro: rel_pow_0_I elim: rel_pow_0_E rel_pow_Suc_E)
   718   apply (blast intro: rel_pow_Suc_I elim: rel_pow_0_E rel_pow_Suc_E)
   719   done
   720 
   721 lemma rel_pow_Suc_E2:
   722   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> P) \<Longrightarrow> P"
   723   by (blast dest: rel_pow_Suc_D2)
   724 
   725 lemma rel_pow_Suc_D2':
   726   "\<forall>x y z. (x, y) \<in> R ^^ n \<and> (y, z) \<in> R \<longrightarrow> (\<exists>w. (x, w) \<in> R \<and> (w, z) \<in> R ^^ n)"
   727   by (induct n) (simp_all, blast)
   728 
   729 lemma rel_pow_E2:
   730   "(x, z) \<in> R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   731      \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ m \<Longrightarrow> P)
   732    \<Longrightarrow> P"
   733   apply (cases n, simp)
   734   apply (cut_tac n=nat and R=R in rel_pow_Suc_D2', simp, blast)
   735   done
   736 
   737 lemma rel_pow_add: "R ^^ (m+n) = R^^m O R^^n"
   738 by(induct n) auto
   739 
   740 lemma rel_pow_commute: "R O R ^^ n = R ^^ n O R"
   741 by (induct n) (simp, simp add: O_assoc [symmetric])
   742 
   743 lemma rtrancl_imp_UN_rel_pow:
   744   assumes "p \<in> R^*"
   745   shows "p \<in> (\<Union>n. R ^^ n)"
   746 proof (cases p)
   747   case (Pair x y)
   748   with assms have "(x, y) \<in> R^*" by simp
   749   then have "(x, y) \<in> (\<Union>n. R ^^ n)" proof induct
   750     case base show ?case by (blast intro: rel_pow_0_I)
   751   next
   752     case step then show ?case by (blast intro: rel_pow_Suc_I)
   753   qed
   754   with Pair show ?thesis by simp
   755 qed
   756 
   757 lemma rel_pow_imp_rtrancl:
   758   assumes "p \<in> R ^^ n"
   759   shows "p \<in> R^*"
   760 proof (cases p)
   761   case (Pair x y)
   762   with assms have "(x, y) \<in> R ^^ n" by simp
   763   then have "(x, y) \<in> R^*" proof (induct n arbitrary: x y)
   764     case 0 then show ?case by simp
   765   next
   766     case Suc then show ?case
   767       by (blast elim: rel_pow_Suc_E intro: rtrancl_into_rtrancl)
   768   qed
   769   with Pair show ?thesis by simp
   770 qed
   771 
   772 lemma rtrancl_is_UN_rel_pow:
   773   "R^* = (\<Union>n. R ^^ n)"
   774   by (blast intro: rtrancl_imp_UN_rel_pow rel_pow_imp_rtrancl)
   775 
   776 lemma rtrancl_power:
   777   "p \<in> R^* \<longleftrightarrow> (\<exists>n. p \<in> R ^^ n)"
   778   by (simp add: rtrancl_is_UN_rel_pow)
   779 
   780 lemma trancl_power:
   781   "p \<in> R^+ \<longleftrightarrow> (\<exists>n > 0. p \<in> R ^^ n)"
   782   apply (cases p)
   783   apply simp
   784   apply (rule iffI)
   785    apply (drule tranclD2)
   786    apply (clarsimp simp: rtrancl_is_UN_rel_pow)
   787    apply (rule_tac x="Suc n" in exI)
   788    apply (clarsimp simp: rel_comp_def)
   789    apply fastsimp
   790   apply clarsimp
   791   apply (case_tac n, simp)
   792   apply clarsimp
   793   apply (drule rel_pow_imp_rtrancl)
   794   apply (drule rtrancl_into_trancl1) apply auto
   795   done
   796 
   797 lemma rtrancl_imp_rel_pow:
   798   "p \<in> R^* \<Longrightarrow> \<exists>n. p \<in> R ^^ n"
   799   by (auto dest: rtrancl_imp_UN_rel_pow)
   800 
   801 lemma single_valued_rel_pow:
   802   fixes R :: "('a * 'a) set"
   803   shows "single_valued R \<Longrightarrow> single_valued (R ^^ n)"
   804   apply (induct n arbitrary: R)
   805   apply simp_all
   806   apply (rule single_valuedI)
   807   apply (fast dest: single_valuedD elim: rel_pow_Suc_E)
   808   done
   809 
   810 subsection {* Setup of transitivity reasoner *}
   811 
   812 ML {*
   813 
   814 structure Trancl_Tac = Trancl_Tac
   815 (
   816   val r_into_trancl = @{thm trancl.r_into_trancl};
   817   val trancl_trans  = @{thm trancl_trans};
   818   val rtrancl_refl = @{thm rtrancl.rtrancl_refl};
   819   val r_into_rtrancl = @{thm r_into_rtrancl};
   820   val trancl_into_rtrancl = @{thm trancl_into_rtrancl};
   821   val rtrancl_trancl_trancl = @{thm rtrancl_trancl_trancl};
   822   val trancl_rtrancl_trancl = @{thm trancl_rtrancl_trancl};
   823   val rtrancl_trans = @{thm rtrancl_trans};
   824 
   825   fun decomp (@{const Trueprop} $ t) =
   826     let fun dec (Const ("op :", _) $ (Const ("Pair", _) $ a $ b) $ rel ) =
   827         let fun decr (Const ("Transitive_Closure.rtrancl", _ ) $ r) = (r,"r*")
   828               | decr (Const ("Transitive_Closure.trancl", _ ) $ r)  = (r,"r+")
   829               | decr r = (r,"r");
   830             val (rel,r) = decr (Envir.beta_eta_contract rel);
   831         in SOME (a,b,rel,r) end
   832       | dec _ =  NONE
   833     in dec t end
   834     | decomp _ = NONE;
   835 );
   836 
   837 structure Tranclp_Tac = Trancl_Tac
   838 (
   839   val r_into_trancl = @{thm tranclp.r_into_trancl};
   840   val trancl_trans  = @{thm tranclp_trans};
   841   val rtrancl_refl = @{thm rtranclp.rtrancl_refl};
   842   val r_into_rtrancl = @{thm r_into_rtranclp};
   843   val trancl_into_rtrancl = @{thm tranclp_into_rtranclp};
   844   val rtrancl_trancl_trancl = @{thm rtranclp_tranclp_tranclp};
   845   val trancl_rtrancl_trancl = @{thm tranclp_rtranclp_tranclp};
   846   val rtrancl_trans = @{thm rtranclp_trans};
   847 
   848   fun decomp (@{const Trueprop} $ t) =
   849     let fun dec (rel $ a $ b) =
   850         let fun decr (Const ("Transitive_Closure.rtranclp", _ ) $ r) = (r,"r*")
   851               | decr (Const ("Transitive_Closure.tranclp", _ ) $ r)  = (r,"r+")
   852               | decr r = (r,"r");
   853             val (rel,r) = decr rel;
   854         in SOME (a, b, rel, r) end
   855       | dec _ =  NONE
   856     in dec t end
   857     | decomp _ = NONE;
   858 );
   859 *}
   860 
   861 declaration {* fn _ =>
   862   Simplifier.map_ss (fn ss => ss
   863     addSolver (mk_solver' "Trancl" (Trancl_Tac.trancl_tac o Simplifier.the_context))
   864     addSolver (mk_solver' "Rtrancl" (Trancl_Tac.rtrancl_tac o Simplifier.the_context))
   865     addSolver (mk_solver' "Tranclp" (Tranclp_Tac.trancl_tac o Simplifier.the_context))
   866     addSolver (mk_solver' "Rtranclp" (Tranclp_Tac.rtrancl_tac o Simplifier.the_context)))
   867 *}
   868 
   869 
   870 text {* Optional methods. *}
   871 
   872 method_setup trancl =
   873   {* Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.trancl_tac) *}
   874   {* simple transitivity reasoner *}
   875 method_setup rtrancl =
   876   {* Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.rtrancl_tac) *}
   877   {* simple transitivity reasoner *}
   878 method_setup tranclp =
   879   {* Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.trancl_tac) *}
   880   {* simple transitivity reasoner (predicate version) *}
   881 method_setup rtranclp =
   882   {* Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.rtrancl_tac) *}
   883   {* simple transitivity reasoner (predicate version) *}
   884 
   885 end