src/Pure/tactical.ML
author wenzelm
Mon Jul 27 20:45:40 2009 +0200 (2009-07-27 ago)
changeset 32231 95b8afcbb0ed
parent 32187 cca43ca13f4f
child 32738 15bb09ca0378
permissions -rw-r--r--
moved METAHYPS to old_goals.ML (cf. SUBPROOF and FOCUS in subgoal.ML for properly localized versions of the same idea);
     1 (*  Title:      Pure/tactical.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Tacticals.
     5 *)
     6 
     7 infix 1 THEN THEN' THEN_ALL_NEW;
     8 infix 0 ORELSE APPEND INTLEAVE ORELSE' APPEND' INTLEAVE';
     9 infix 0 THEN_ELSE;
    10 
    11 signature TACTICAL =
    12 sig
    13   type tactic = thm -> thm Seq.seq
    14   val THEN: tactic * tactic -> tactic
    15   val ORELSE: tactic * tactic -> tactic
    16   val APPEND: tactic * tactic -> tactic
    17   val INTLEAVE: tactic * tactic -> tactic
    18   val THEN_ELSE: tactic * (tactic*tactic) -> tactic
    19   val THEN': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    20   val ORELSE': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    21   val APPEND': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    22   val INTLEAVE': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    23   val all_tac: tactic
    24   val no_tac: tactic
    25   val DETERM: tactic -> tactic
    26   val COND: (thm -> bool) -> tactic -> tactic -> tactic
    27   val TRY: tactic -> tactic
    28   val EVERY: tactic list -> tactic
    29   val EVERY': ('a -> tactic) list -> 'a -> tactic
    30   val EVERY1: (int -> tactic) list -> tactic
    31   val FIRST: tactic list -> tactic
    32   val FIRST': ('a -> tactic) list -> 'a -> tactic
    33   val FIRST1: (int -> tactic) list -> tactic
    34   val RANGE: (int -> tactic) list -> int -> tactic
    35   val print_tac: string -> tactic
    36   val pause_tac: tactic
    37   val trace_REPEAT: bool ref
    38   val suppress_tracing: bool ref
    39   val tracify: bool ref -> tactic -> tactic
    40   val traced_tac: (thm -> (thm * thm Seq.seq) option) -> tactic
    41   val DETERM_UNTIL: (thm -> bool) -> tactic -> tactic
    42   val REPEAT_DETERM_N: int -> tactic -> tactic
    43   val REPEAT_DETERM: tactic -> tactic
    44   val REPEAT: tactic -> tactic
    45   val REPEAT_DETERM1: tactic -> tactic
    46   val REPEAT1: tactic -> tactic
    47   val FILTER: (thm -> bool) -> tactic -> tactic
    48   val CHANGED: tactic -> tactic
    49   val CHANGED_PROP: tactic -> tactic
    50   val ALLGOALS: (int -> tactic) -> tactic
    51   val SOMEGOAL: (int -> tactic) -> tactic
    52   val FIRSTGOAL: (int -> tactic) -> tactic
    53   val REPEAT_SOME: (int -> tactic) -> tactic
    54   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    55   val REPEAT_FIRST: (int -> tactic) -> tactic
    56   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    57   val TRYALL: (int -> tactic) -> tactic
    58   val CSUBGOAL: ((cterm * int) -> tactic) -> int -> tactic
    59   val SUBGOAL: ((term * int) -> tactic) -> int -> tactic
    60   val CHANGED_GOAL: (int -> tactic) -> int -> tactic
    61   val THEN_ALL_NEW: (int -> tactic) * (int -> tactic) -> int -> tactic
    62   val REPEAT_ALL_NEW: (int -> tactic) -> int -> tactic
    63   val PRIMSEQ: (thm -> thm Seq.seq) -> tactic
    64   val PRIMITIVE: (thm -> thm) -> tactic
    65   val SINGLE: tactic -> thm -> thm option
    66   val CONVERSION: conv -> int -> tactic
    67 end;
    68 
    69 structure Tactical : TACTICAL =
    70 struct
    71 
    72 (**** Tactics ****)
    73 
    74 (*A tactic maps a proof tree to a sequence of proof trees:
    75     if length of sequence = 0 then the tactic does not apply;
    76     if length > 1 then backtracking on the alternatives can occur.*)
    77 
    78 type tactic = thm -> thm Seq.seq;
    79 
    80 
    81 (*** LCF-style tacticals ***)
    82 
    83 (*the tactical THEN performs one tactic followed by another*)
    84 fun (tac1 THEN tac2) st = Seq.maps tac2 (tac1 st);
    85 
    86 
    87 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    88   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    89   Does not backtrack to tac2 if tac1 was initially chosen. *)
    90 fun (tac1 ORELSE tac2) st =
    91     case Seq.pull(tac1 st) of
    92         NONE       => tac2 st
    93       | sequencecell => Seq.make(fn()=> sequencecell);
    94 
    95 
    96 (*The tactical APPEND combines the results of two tactics.
    97   Like ORELSE, but allows backtracking on both tac1 and tac2.
    98   The tactic tac2 is not applied until needed.*)
    99 fun (tac1 APPEND tac2) st =
   100   Seq.append (tac1 st) (Seq.make(fn()=> Seq.pull (tac2 st)));
   101 
   102 (*Like APPEND, but interleaves results of tac1 and tac2.*)
   103 fun (tac1 INTLEAVE tac2) st =
   104     Seq.interleave(tac1 st,
   105                         Seq.make(fn()=> Seq.pull (tac2 st)));
   106 
   107 (*Conditional tactic.
   108         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   109         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   110 *)
   111 fun (tac THEN_ELSE (tac1, tac2)) st =
   112     case Seq.pull(tac st) of
   113         NONE    => tac2 st                                   (*failed; try tactic 2*)
   114       | seqcell => Seq.maps tac1 (Seq.make(fn()=> seqcell)); (*succeeded; use tactic 1*)
   115 
   116 
   117 (*Versions for combining tactic-valued functions, as in
   118      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   119 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   120 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   121 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   122 fun (tac1 INTLEAVE' tac2) x = tac1 x INTLEAVE tac2 x;
   123 
   124 (*passes all proofs through unchanged;  identity of THEN*)
   125 fun all_tac st = Seq.single st;
   126 
   127 (*passes no proofs through;  identity of ORELSE and APPEND*)
   128 fun no_tac st  = Seq.empty;
   129 
   130 
   131 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   132 fun DETERM tac = Seq.DETERM tac;
   133 
   134 (*Conditional tactical: testfun controls which tactic to use next.
   135   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   136 fun COND testfun thenf elsef = (fn prf =>
   137     if testfun prf then  thenf prf   else  elsef prf);
   138 
   139 (*Do the tactic or else do nothing*)
   140 fun TRY tac = tac ORELSE all_tac;
   141 
   142 (*** List-oriented tactics ***)
   143 
   144 local
   145   (*This version of EVERY avoids backtracking over repeated states*)
   146 
   147   fun EVY (trail, []) st =
   148         Seq.make (fn()=> SOME(st,
   149                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   150     | EVY (trail, tac::tacs) st =
   151           case Seq.pull(tac st) of
   152               NONE    => evyBack trail              (*failed: backtrack*)
   153             | SOME(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   154   and evyBack [] = Seq.empty (*no alternatives*)
   155     | evyBack ((st',q,tacs)::trail) =
   156           case Seq.pull q of
   157               NONE        => evyBack trail
   158             | SOME(st,q') => if Thm.eq_thm (st',st)
   159                              then evyBack ((st',q',tacs)::trail)
   160                              else EVY ((st,q',tacs)::trail, tacs) st
   161 in
   162 
   163 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   164 fun EVERY tacs = EVY ([], tacs);
   165 end;
   166 
   167 
   168 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   169 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   170 
   171 (*Apply every tactic to 1*)
   172 fun EVERY1 tacs = EVERY' tacs 1;
   173 
   174 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   175 fun FIRST tacs = fold_rev (curry op ORELSE) tacs no_tac;
   176 
   177 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   178 fun FIRST' tacs = fold_rev (curry op ORELSE') tacs (K no_tac);
   179 
   180 (*Apply first tactic to 1*)
   181 fun FIRST1 tacs = FIRST' tacs 1;
   182 
   183 (*Apply tactics on consecutive subgoals*)
   184 fun RANGE [] _ = all_tac
   185   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   186 
   187 
   188 (*** Tracing tactics ***)
   189 
   190 (*Print the current proof state and pass it on.*)
   191 fun print_tac msg st =
   192  (tracing (msg ^ "\n" ^
   193     Pretty.string_of (Pretty.chunks
   194       (Goal_Display.pretty_goals_without_context (! Goal_Display.goals_limit) st)));
   195   Seq.single st);
   196 
   197 (*Pause until a line is typed -- if non-empty then fail. *)
   198 fun pause_tac st =
   199   (tracing "** Press RETURN to continue:";
   200    if TextIO.inputLine TextIO.stdIn = SOME "\n" then Seq.single st
   201    else (tracing "Goodbye";  Seq.empty));
   202 
   203 exception TRACE_EXIT of thm
   204 and TRACE_QUIT;
   205 
   206 (*Tracing flags*)
   207 val trace_REPEAT= ref false
   208 and suppress_tracing = ref false;
   209 
   210 (*Handle all tracing commands for current state and tactic *)
   211 fun exec_trace_command flag (tac, st) =
   212    case TextIO.inputLine TextIO.stdIn of
   213        SOME "\n" => tac st
   214      | SOME "f\n" => Seq.empty
   215      | SOME "o\n" => (flag:=false;  tac st)
   216      | SOME "s\n" => (suppress_tracing:=true;  tac st)
   217      | SOME "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   218      | SOME "quit\n" => raise TRACE_QUIT
   219      | _     => (tracing
   220 "Type RETURN to continue or...\n\
   221 \     f    - to fail here\n\
   222 \     o    - to switch tracing off\n\
   223 \     s    - to suppress tracing until next entry to a tactical\n\
   224 \     x    - to exit at this point\n\
   225 \     quit - to abort this tracing run\n\
   226 \** Well? "     ;  exec_trace_command flag (tac, st));
   227 
   228 
   229 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   230 fun tracify flag tac st =
   231   if !flag andalso not (!suppress_tracing) then
   232     (tracing (Pretty.string_of (Pretty.chunks
   233         (Goal_Display.pretty_goals_without_context (! Goal_Display.goals_limit) st @
   234           [Pretty.str "** Press RETURN to continue:"])));
   235      exec_trace_command flag (tac, st))
   236   else tac st;
   237 
   238 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   239 fun traced_tac seqf st =
   240     (suppress_tracing := false;
   241      Seq.make (fn()=> seqf st
   242                          handle TRACE_EXIT st' => SOME(st', Seq.empty)));
   243 
   244 
   245 (*Deterministic DO..UNTIL: only retains the first outcome; tail recursive.
   246   Forces repitition until predicate on state is fulfilled.*)
   247 fun DETERM_UNTIL p tac =
   248 let val tac = tracify trace_REPEAT tac
   249     fun drep st = if p st then SOME (st, Seq.empty)
   250                           else (case Seq.pull(tac st) of
   251                                   NONE        => NONE
   252                                 | SOME(st',_) => drep st')
   253 in  traced_tac drep  end;
   254 
   255 (*Deterministic REPEAT: only retains the first outcome;
   256   uses less space than REPEAT; tail recursive.
   257   If non-negative, n bounds the number of repetitions.*)
   258 fun REPEAT_DETERM_N n tac =
   259   let val tac = tracify trace_REPEAT tac
   260       fun drep 0 st = SOME(st, Seq.empty)
   261         | drep n st =
   262            (case Seq.pull(tac st) of
   263                 NONE       => SOME(st, Seq.empty)
   264               | SOME(st',_) => drep (n-1) st')
   265   in  traced_tac (drep n)  end;
   266 
   267 (*Allows any number of repetitions*)
   268 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   269 
   270 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   271 fun REPEAT tac =
   272   let val tac = tracify trace_REPEAT tac
   273       fun rep qs st =
   274         case Seq.pull(tac st) of
   275             NONE       => SOME(st, Seq.make(fn()=> repq qs))
   276           | SOME(st',q) => rep (q::qs) st'
   277       and repq [] = NONE
   278         | repq(q::qs) = case Seq.pull q of
   279             NONE       => repq qs
   280           | SOME(st,q) => rep (q::qs) st
   281   in  traced_tac (rep [])  end;
   282 
   283 (*Repeat 1 or more times*)
   284 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   285 fun REPEAT1 tac = tac THEN REPEAT tac;
   286 
   287 
   288 (** Filtering tacticals **)
   289 
   290 fun FILTER pred tac st = Seq.filter pred (tac st);
   291 
   292 (*Accept only next states that change the theorem somehow*)
   293 fun CHANGED tac st =
   294   let fun diff st' = not (Thm.eq_thm (st, st'));
   295   in Seq.filter diff (tac st) end;
   296 
   297 (*Accept only next states that change the theorem's prop field
   298   (changes to signature, hyps, etc. don't count)*)
   299 fun CHANGED_PROP tac st =
   300   let fun diff st' = not (Thm.eq_thm_prop (st, st'));
   301   in Seq.filter diff (tac st) end;
   302 
   303 
   304 (*** Tacticals based on subgoal numbering ***)
   305 
   306 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   307   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   308 fun ALLGOALS tac st =
   309   let fun doall 0 = all_tac
   310         | doall n = tac(n) THEN doall(n-1)
   311   in  doall(nprems_of st)st  end;
   312 
   313 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   314 fun SOMEGOAL tac st =
   315   let fun find 0 = no_tac
   316         | find n = tac(n) ORELSE find(n-1)
   317   in  find(nprems_of st)st  end;
   318 
   319 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   320   More appropriate than SOMEGOAL in some cases.*)
   321 fun FIRSTGOAL tac st =
   322   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   323   in  find(1, nprems_of st)st  end;
   324 
   325 (*Repeatedly solve some using tac. *)
   326 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   327 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   328 
   329 (*Repeatedly solve the first possible subgoal using tac. *)
   330 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   331 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   332 
   333 (*For n subgoals, tries to apply tac to n,...1  *)
   334 fun TRYALL tac = ALLGOALS (TRY o tac);
   335 
   336 
   337 (*Make a tactic for subgoal i, if there is one.  *)
   338 fun CSUBGOAL goalfun i st =
   339   (case SOME (Thm.cprem_of st i) handle THM _ => NONE of
   340     SOME goal => goalfun (goal, i) st
   341   | NONE => Seq.empty);
   342 
   343 fun SUBGOAL goalfun =
   344   CSUBGOAL (fn (goal, i) => goalfun (Thm.term_of goal, i));
   345 
   346 (*Returns all states that have changed in subgoal i, counted from the LAST
   347   subgoal.  For stac, for example.*)
   348 fun CHANGED_GOAL tac i st =
   349     let val np = Thm.nprems_of st
   350         val d = np-i                 (*distance from END*)
   351         val t = Thm.term_of (Thm.cprem_of st i)
   352         fun diff st' =
   353             Thm.nprems_of st' - d <= 0   (*the subgoal no longer exists*)
   354             orelse
   355              not (Pattern.aeconv (t, Thm.term_of (Thm.cprem_of st' (Thm.nprems_of st' - d))))
   356     in  Seq.filter diff (tac i st)  end
   357     handle Subscript => Seq.empty  (*no subgoal i*);
   358 
   359 fun (tac1 THEN_ALL_NEW tac2) i st =
   360   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   361 
   362 (*repeatedly dig into any emerging subgoals*)
   363 fun REPEAT_ALL_NEW tac =
   364   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   365 
   366 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   367 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   368 
   369 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   370 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   371 
   372 (*Inverse (more or less) of PRIMITIVE*)
   373 fun SINGLE tacf = Option.map fst o Seq.pull o tacf
   374 
   375 (*Conversions as tactics*)
   376 fun CONVERSION cv i st = Seq.single (Conv.gconv_rule cv i st)
   377   handle THM _ => Seq.empty
   378     | CTERM _ => Seq.empty
   379     | TERM _ => Seq.empty
   380     | TYPE _ => Seq.empty;
   381 
   382 end;
   383 
   384 open Tactical;