src/HOL/Imperative_HOL/Array.thy
author haftmann
Tue Jul 13 12:05:20 2010 +0200 (2010-07-13 ago)
changeset 37797 96551d6b1414
parent 37792 ba0bc31b90d7
parent 37796 08bd610b2583
child 37798 0b0570445a2a
permissions -rw-r--r--
merged
     1 (*  Title:      HOL/Imperative_HOL/Array.thy
     2     Author:     John Matthews, Galois Connections; Alexander Krauss, Lukas Bulwahn & Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* Monadic arrays *}
     6 
     7 theory Array
     8 imports Heap_Monad
     9 begin
    10 
    11 subsection {* Primitives *}
    12 
    13 definition (*FIXME present :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> bool" where*)
    14   array_present :: "'a\<Colon>heap array \<Rightarrow> heap \<Rightarrow> bool" where
    15   "array_present a h \<longleftrightarrow> addr_of_array a < lim h"
    16 
    17 definition (*FIXME get :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a list" where*)
    18   get_array :: "'a\<Colon>heap array \<Rightarrow> heap \<Rightarrow> 'a list" where
    19   "get_array a h = map from_nat (arrays h (TYPEREP('a)) (addr_of_array a))"
    20 
    21 definition (*FIXME set*)
    22   set_array :: "'a\<Colon>heap array \<Rightarrow> 'a list \<Rightarrow> heap \<Rightarrow> heap" where
    23   "set_array a x = 
    24   arrays_update (\<lambda>h. h(TYPEREP('a) := ((h(TYPEREP('a))) (addr_of_array a:=map to_nat x))))"
    25 
    26 definition (*FIXME alloc*)
    27   array :: "'a list \<Rightarrow> heap \<Rightarrow> 'a\<Colon>heap array \<times> heap" where
    28   "array xs h = (let
    29      l = lim h;
    30      r = Array l;
    31      h'' = set_array r xs (h\<lparr>lim := l + 1\<rparr>)
    32    in (r, h''))"
    33 
    34 definition (*FIXME length :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> nat" where*)
    35   length :: "'a\<Colon>heap array \<Rightarrow> heap \<Rightarrow> nat" where
    36   "length a h = List.length (get_array a h)"
    37   
    38 definition (*FIXME update*)
    39   change :: "'a\<Colon>heap array \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> heap \<Rightarrow> heap" where
    40   "change a i x h = set_array a ((get_array a h)[i:=x]) h"
    41 
    42 definition (*FIXME noteq*)
    43   noteq_arrs :: "'a\<Colon>heap array \<Rightarrow> 'b\<Colon>heap array \<Rightarrow> bool" (infix "=!!=" 70) where
    44   "r =!!= s \<longleftrightarrow> TYPEREP('a) \<noteq> TYPEREP('b) \<or> addr_of_array r \<noteq> addr_of_array s"
    45 
    46 
    47 subsection {* Monad operations *}
    48 
    49 definition new :: "nat \<Rightarrow> 'a\<Colon>heap \<Rightarrow> 'a array Heap" where
    50   [code del]: "new n x = Heap_Monad.heap (array (replicate n x))"
    51 
    52 definition of_list :: "'a\<Colon>heap list \<Rightarrow> 'a array Heap" where
    53   [code del]: "of_list xs = Heap_Monad.heap (array xs)"
    54 
    55 definition make :: "nat \<Rightarrow> (nat \<Rightarrow> 'a\<Colon>heap) \<Rightarrow> 'a array Heap" where
    56   [code del]: "make n f = Heap_Monad.heap (array (map f [0 ..< n]))"
    57 
    58 definition len :: "'a\<Colon>heap array \<Rightarrow> nat Heap" where
    59   [code del]: "len a = Heap_Monad.tap (\<lambda>h. length a h)"
    60 
    61 definition nth :: "'a\<Colon>heap array \<Rightarrow> nat \<Rightarrow> 'a Heap" where
    62   [code del]: "nth a i = Heap_Monad.guard (\<lambda>h. i < length a h)
    63     (\<lambda>h. (get_array a h ! i, h))"
    64 
    65 definition upd :: "nat \<Rightarrow> 'a \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a\<Colon>heap array Heap" where
    66   [code del]: "upd i x a = Heap_Monad.guard (\<lambda>h. i < length a h)
    67     (\<lambda>h. (a, change a i x h))"
    68 
    69 definition map_entry :: "nat \<Rightarrow> ('a\<Colon>heap \<Rightarrow> 'a) \<Rightarrow> 'a array \<Rightarrow> 'a array Heap" where
    70   [code del]: "map_entry i f a = Heap_Monad.guard (\<lambda>h. i < length a h)
    71     (\<lambda>h. (a, change a i (f (get_array a h ! i)) h))"
    72 
    73 definition swap :: "nat \<Rightarrow> 'a \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a Heap" where
    74   [code del]: "swap i x a = Heap_Monad.guard (\<lambda>h. i < length a h)
    75     (\<lambda>h. (get_array a h ! i, change a i x h))"
    76 
    77 definition freeze :: "'a\<Colon>heap array \<Rightarrow> 'a list Heap" where
    78   [code del]: "freeze a = Heap_Monad.tap (\<lambda>h. get_array a h)"
    79 
    80 
    81 subsection {* Properties *}
    82 
    83 text {* FIXME: Does there exist a "canonical" array axiomatisation in
    84 the literature?  *}
    85 
    86 text {* Primitives *}
    87 
    88 lemma noteq_arrs_sym: "a =!!= b \<Longrightarrow> b =!!= a"
    89   and unequal_arrs [simp]: "a \<noteq> a' \<longleftrightarrow> a =!!= a'"
    90   unfolding noteq_arrs_def by auto
    91 
    92 lemma noteq_arrs_irrefl: "r =!!= r \<Longrightarrow> False"
    93   unfolding noteq_arrs_def by auto
    94 
    95 lemma present_new_arr: "array_present a h \<Longrightarrow> a =!!= fst (array xs h)"
    96   by (simp add: array_present_def noteq_arrs_def array_def Let_def)
    97 
    98 lemma array_get_set_eq [simp]: "get_array r (set_array r x h) = x"
    99   by (simp add: get_array_def set_array_def o_def)
   100 
   101 lemma array_get_set_neq [simp]: "r =!!= s \<Longrightarrow> get_array r (set_array s x h) = get_array r h"
   102   by (simp add: noteq_arrs_def get_array_def set_array_def)
   103 
   104 lemma set_array_same [simp]:
   105   "set_array r x (set_array r y h) = set_array r x h"
   106   by (simp add: set_array_def)
   107 
   108 lemma array_set_set_swap:
   109   "r =!!= r' \<Longrightarrow> set_array r x (set_array r' x' h) = set_array r' x' (set_array r x h)"
   110   by (simp add: Let_def expand_fun_eq noteq_arrs_def set_array_def)
   111 
   112 lemma get_array_change_eq [simp]:
   113   "get_array a (change a i v h) = (get_array a h) [i := v]"
   114   by (simp add: change_def)
   115 
   116 lemma nth_change_array_neq_array [simp]:
   117   "a =!!= b \<Longrightarrow> get_array a (change b j v h) ! i = get_array a h ! i"
   118   by (simp add: change_def noteq_arrs_def)
   119 
   120 lemma get_arry_array_change_elem_neqIndex [simp]:
   121   "i \<noteq> j \<Longrightarrow> get_array a (change a j v h) ! i = get_array a h ! i"
   122   by simp
   123 
   124 lemma length_change [simp]: 
   125   "length a (change b i v h) = length a h"
   126   by (simp add: change_def length_def set_array_def get_array_def)
   127 
   128 lemma change_swap_neqArray:
   129   "a =!!= a' \<Longrightarrow> 
   130   change a i v (change a' i' v' h) 
   131   = change a' i' v' (change a i v h)"
   132 apply (unfold change_def)
   133 apply simp
   134 apply (subst array_set_set_swap, assumption)
   135 apply (subst array_get_set_neq)
   136 apply (erule noteq_arrs_sym)
   137 apply (simp)
   138 done
   139 
   140 lemma change_swap_neqIndex:
   141   "\<lbrakk> i \<noteq> i' \<rbrakk> \<Longrightarrow> change a i v (change a i' v' h) = change a i' v' (change a i v h)"
   142   by (auto simp add: change_def array_set_set_swap list_update_swap)
   143 
   144 lemma get_array_init_array_list:
   145   "get_array (fst (array ls h)) (snd (array ls' h)) = ls'"
   146   by (simp add: Let_def split_def array_def)
   147 
   148 lemma set_array:
   149   "set_array (fst (array ls h))
   150      new_ls (snd (array ls h))
   151        = snd (array new_ls h)"
   152   by (simp add: Let_def split_def array_def)
   153 
   154 lemma array_present_change [simp]: 
   155   "array_present a (change b i v h) = array_present a h"
   156   by (simp add: change_def array_present_def set_array_def get_array_def)
   157 
   158 lemma array_present_array [simp]:
   159   "array_present (fst (array xs h)) (snd (array xs h))"
   160   by (simp add: array_present_def array_def set_array_def Let_def)
   161 
   162 lemma not_array_present_array [simp]:
   163   "\<not> array_present (fst (array xs h)) h"
   164   by (simp add: array_present_def array_def Let_def)
   165 
   166 
   167 text {* Monad operations *}
   168 
   169 lemma execute_new [execute_simps]:
   170   "execute (new n x) h = Some (array (replicate n x) h)"
   171   by (simp add: new_def execute_simps)
   172 
   173 lemma success_newI [success_intros]:
   174   "success (new n x) h"
   175   by (auto intro: success_intros simp add: new_def)
   176 
   177 lemma crel_newI [crel_intros]:
   178   assumes "(a, h') = array (replicate n x) h"
   179   shows "crel (new n x) h h' a"
   180   by (rule crelI) (simp add: assms execute_simps)
   181 
   182 lemma crel_newE [crel_elims]:
   183   assumes "crel (new n x) h h' r"
   184   obtains "r = fst (array (replicate n x) h)" "h' = snd (array (replicate n x) h)" 
   185     "get_array r h' = replicate n x" "array_present r h'" "\<not> array_present r h"
   186   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   187 
   188 lemma execute_of_list [execute_simps]:
   189   "execute (of_list xs) h = Some (array xs h)"
   190   by (simp add: of_list_def execute_simps)
   191 
   192 lemma success_of_listI [success_intros]:
   193   "success (of_list xs) h"
   194   by (auto intro: success_intros simp add: of_list_def)
   195 
   196 lemma crel_of_listI [crel_intros]:
   197   assumes "(a, h') = array xs h"
   198   shows "crel (of_list xs) h h' a"
   199   by (rule crelI) (simp add: assms execute_simps)
   200 
   201 lemma crel_of_listE [crel_elims]:
   202   assumes "crel (of_list xs) h h' r"
   203   obtains "r = fst (array xs h)" "h' = snd (array xs h)" 
   204     "get_array r h' = xs" "array_present r h'" "\<not> array_present r h"
   205   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   206 
   207 lemma execute_make [execute_simps]:
   208   "execute (make n f) h = Some (array (map f [0 ..< n]) h)"
   209   by (simp add: make_def execute_simps)
   210 
   211 lemma success_makeI [success_intros]:
   212   "success (make n f) h"
   213   by (auto intro: success_intros simp add: make_def)
   214 
   215 lemma crel_makeI [crel_intros]:
   216   assumes "(a, h') = array (map f [0 ..< n]) h"
   217   shows "crel (make n f) h h' a"
   218   by (rule crelI) (simp add: assms execute_simps)
   219 
   220 lemma crel_makeE [crel_elims]:
   221   assumes "crel (make n f) h h' r"
   222   obtains "r = fst (array (map f [0 ..< n]) h)" "h' = snd (array (map f [0 ..< n]) h)" 
   223     "get_array r h' = map f [0 ..< n]" "array_present r h'" "\<not> array_present r h"
   224   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   225 
   226 lemma execute_len [execute_simps]:
   227   "execute (len a) h = Some (length a h, h)"
   228   by (simp add: len_def execute_simps)
   229 
   230 lemma success_lenI [success_intros]:
   231   "success (len a) h"
   232   by (auto intro: success_intros simp add: len_def)
   233 
   234 lemma crel_lengthI [crel_intros]:
   235   assumes "h' = h" "r = length a h"
   236   shows "crel (len a) h h' r"
   237   by (rule crelI) (simp add: assms execute_simps)
   238 
   239 lemma crel_lengthE [crel_elims]:
   240   assumes "crel (len a) h h' r"
   241   obtains "r = length a h'" "h' = h" 
   242   using assms by (rule crelE) (simp add: execute_simps)
   243 
   244 lemma execute_nth [execute_simps]:
   245   "i < length a h \<Longrightarrow>
   246     execute (nth a i) h = Some (get_array a h ! i, h)"
   247   "i \<ge> length a h \<Longrightarrow> execute (nth a i) h = None"
   248   by (simp_all add: nth_def execute_simps)
   249 
   250 lemma success_nthI [success_intros]:
   251   "i < length a h \<Longrightarrow> success (nth a i) h"
   252   by (auto intro: success_intros simp add: nth_def)
   253 
   254 lemma crel_nthI [crel_intros]:
   255   assumes "i < length a h" "h' = h" "r = get_array a h ! i"
   256   shows "crel (nth a i) h h' r"
   257   by (rule crelI) (insert assms, simp add: execute_simps)
   258 
   259 lemma crel_nthE [crel_elims]:
   260   assumes "crel (nth a i) h h' r"
   261   obtains "i < length a h" "r = get_array a h ! i" "h' = h"
   262   using assms by (rule crelE)
   263     (erule successE, cases "i < length a h", simp_all add: execute_simps)
   264 
   265 lemma execute_upd [execute_simps]:
   266   "i < length a h \<Longrightarrow>
   267     execute (upd i x a) h = Some (a, change a i x h)"
   268   "i \<ge> length a h \<Longrightarrow> execute (upd i x a) h = None"
   269   by (simp_all add: upd_def execute_simps)
   270 
   271 lemma success_updI [success_intros]:
   272   "i < length a h \<Longrightarrow> success (upd i x a) h"
   273   by (auto intro: success_intros simp add: upd_def)
   274 
   275 lemma crel_updI [crel_intros]:
   276   assumes "i < length a h" "h' = change a i v h"
   277   shows "crel (upd i v a) h h' a"
   278   by (rule crelI) (insert assms, simp add: execute_simps)
   279 
   280 lemma crel_updE [crel_elims]:
   281   assumes "crel (upd i v a) h h' r"
   282   obtains "r = a" "h' = change a i v h" "i < length a h"
   283   using assms by (rule crelE)
   284     (erule successE, cases "i < length a h", simp_all add: execute_simps)
   285 
   286 lemma execute_map_entry [execute_simps]:
   287   "i < length a h \<Longrightarrow>
   288    execute (map_entry i f a) h =
   289       Some (a, change a i (f (get_array a h ! i)) h)"
   290   "i \<ge> length a h \<Longrightarrow> execute (map_entry i f a) h = None"
   291   by (simp_all add: map_entry_def execute_simps)
   292 
   293 lemma success_map_entryI [success_intros]:
   294   "i < length a h \<Longrightarrow> success (map_entry i f a) h"
   295   by (auto intro: success_intros simp add: map_entry_def)
   296 
   297 lemma crel_map_entryI [crel_intros]:
   298   assumes "i < length a h" "h' = change a i (f (get_array a h ! i)) h" "r = a"
   299   shows "crel (map_entry i f a) h h' r"
   300   by (rule crelI) (insert assms, simp add: execute_simps)
   301 
   302 lemma crel_map_entryE [crel_elims]:
   303   assumes "crel (map_entry i f a) h h' r"
   304   obtains "r = a" "h' = change a i (f (get_array a h ! i)) h" "i < length a h"
   305   using assms by (rule crelE)
   306     (erule successE, cases "i < length a h", simp_all add: execute_simps)
   307 
   308 lemma execute_swap [execute_simps]:
   309   "i < length a h \<Longrightarrow>
   310    execute (swap i x a) h =
   311       Some (get_array a h ! i, change a i x h)"
   312   "i \<ge> length a h \<Longrightarrow> execute (swap i x a) h = None"
   313   by (simp_all add: swap_def execute_simps)
   314 
   315 lemma success_swapI [success_intros]:
   316   "i < length a h \<Longrightarrow> success (swap i x a) h"
   317   by (auto intro: success_intros simp add: swap_def)
   318 
   319 lemma crel_swapI [crel_intros]:
   320   assumes "i < length a h" "h' = change a i x h" "r = get_array a h ! i"
   321   shows "crel (swap i x a) h h' r"
   322   by (rule crelI) (insert assms, simp add: execute_simps)
   323 
   324 lemma crel_swapE [crel_elims]:
   325   assumes "crel (swap i x a) h h' r"
   326   obtains "r = get_array a h ! i" "h' = change a i x h" "i < length a h"
   327   using assms by (rule crelE)
   328     (erule successE, cases "i < length a h", simp_all add: execute_simps)
   329 
   330 lemma execute_freeze [execute_simps]:
   331   "execute (freeze a) h = Some (get_array a h, h)"
   332   by (simp add: freeze_def execute_simps)
   333 
   334 lemma success_freezeI [success_intros]:
   335   "success (freeze a) h"
   336   by (auto intro: success_intros simp add: freeze_def)
   337 
   338 lemma crel_freezeI [crel_intros]:
   339   assumes "h' = h" "r = get_array a h"
   340   shows "crel (freeze a) h h' r"
   341   by (rule crelI) (insert assms, simp add: execute_simps)
   342 
   343 lemma crel_freezeE [crel_elims]:
   344   assumes "crel (freeze a) h h' r"
   345   obtains "h' = h" "r = get_array a h"
   346   using assms by (rule crelE) (simp add: execute_simps)
   347 
   348 lemma upd_return:
   349   "upd i x a \<guillemotright> return a = upd i x a"
   350   by (rule Heap_eqI) (simp add: bind_def guard_def upd_def execute_simps)
   351 
   352 lemma array_make:
   353   "new n x = make n (\<lambda>_. x)"
   354   by (rule Heap_eqI) (simp add: map_replicate_trivial execute_simps)
   355 
   356 lemma array_of_list_make:
   357   "of_list xs = make (List.length xs) (\<lambda>n. xs ! n)"
   358   by (rule Heap_eqI) (simp add: map_nth execute_simps)
   359 
   360 hide_const (open) new
   361 
   362 
   363 subsection {* Code generator setup *}
   364 
   365 subsubsection {* Logical intermediate layer *}
   366 
   367 definition new' where
   368   [code del]: "new' = Array.new o Code_Numeral.nat_of"
   369 
   370 lemma [code]:
   371   "Array.new = new' o Code_Numeral.of_nat"
   372   by (simp add: new'_def o_def)
   373 
   374 definition of_list' where
   375   [code del]: "of_list' i xs = Array.of_list (take (Code_Numeral.nat_of i) xs)"
   376 
   377 lemma [code]:
   378   "Array.of_list xs = of_list' (Code_Numeral.of_nat (List.length xs)) xs"
   379   by (simp add: of_list'_def)
   380 
   381 definition make' where
   382   [code del]: "make' i f = Array.make (Code_Numeral.nat_of i) (f o Code_Numeral.of_nat)"
   383 
   384 lemma [code]:
   385   "Array.make n f = make' (Code_Numeral.of_nat n) (f o Code_Numeral.nat_of)"
   386   by (simp add: make'_def o_def)
   387 
   388 definition len' where
   389   [code del]: "len' a = Array.len a \<guillemotright>= (\<lambda>n. return (Code_Numeral.of_nat n))"
   390 
   391 lemma [code]:
   392   "Array.len a = len' a \<guillemotright>= (\<lambda>i. return (Code_Numeral.nat_of i))"
   393   by (simp add: len'_def)
   394 
   395 definition nth' where
   396   [code del]: "nth' a = Array.nth a o Code_Numeral.nat_of"
   397 
   398 lemma [code]:
   399   "Array.nth a n = nth' a (Code_Numeral.of_nat n)"
   400   by (simp add: nth'_def)
   401 
   402 definition upd' where
   403   [code del]: "upd' a i x = Array.upd (Code_Numeral.nat_of i) x a \<guillemotright> return ()"
   404 
   405 lemma [code]:
   406   "Array.upd i x a = upd' a (Code_Numeral.of_nat i) x \<guillemotright> return a"
   407   by (simp add: upd'_def upd_return)
   408 
   409 lemma [code]:
   410   "map_entry i f a = do {
   411      x \<leftarrow> nth a i;
   412      upd i (f x) a
   413    }"
   414   by (rule Heap_eqI) (simp add: bind_def guard_def map_entry_def execute_simps)
   415 
   416 lemma [code]:
   417   "swap i x a = do {
   418      y \<leftarrow> nth a i;
   419      upd i x a;
   420      return y
   421    }"
   422   by (rule Heap_eqI) (simp add: bind_def guard_def swap_def execute_simps)
   423 
   424 lemma [code]:
   425   "freeze a = do {
   426      n \<leftarrow> len a;
   427      Heap_Monad.fold_map (\<lambda>i. nth a i) [0..<n]
   428    }"
   429 proof (rule Heap_eqI)
   430   fix h
   431   have *: "List.map
   432      (\<lambda>x. fst (the (if x < length a h
   433                     then Some (get_array a h ! x, h) else None)))
   434      [0..<length a h] =
   435        List.map (List.nth (get_array a h)) [0..<length a h]"
   436     by simp
   437   have "execute (Heap_Monad.fold_map (Array.nth a) [0..<length a h]) h =
   438     Some (get_array a h, h)"
   439     apply (subst execute_fold_map_unchanged_heap)
   440     apply (simp_all add: nth_def guard_def *)
   441     apply (simp add: length_def map_nth)
   442     done
   443   then have "execute (do {
   444       n \<leftarrow> len a;
   445       Heap_Monad.fold_map (Array.nth a) [0..<n]
   446     }) h = Some (get_array a h, h)"
   447     by (auto intro: execute_bind_eq_SomeI simp add: execute_simps)
   448   then show "execute (freeze a) h = execute (do {
   449       n \<leftarrow> len a;
   450       Heap_Monad.fold_map (Array.nth a) [0..<n]
   451     }) h" by (simp add: execute_simps)
   452 qed
   453 
   454 hide_const (open) new' of_list' make' len' nth' upd'
   455 
   456 
   457 text {* SML *}
   458 
   459 code_type array (SML "_/ array")
   460 code_const Array (SML "raise/ (Fail/ \"bare Array\")")
   461 code_const Array.new' (SML "(fn/ ()/ =>/ Array.array/ ((_),/ (_)))")
   462 code_const Array.of_list' (SML "(fn/ ()/ =>/ Array.fromList/ _)")
   463 code_const Array.make' (SML "(fn/ ()/ =>/ Array.tabulate/ ((_),/ (_)))")
   464 code_const Array.len' (SML "(fn/ ()/ =>/ Array.length/ _)")
   465 code_const Array.nth' (SML "(fn/ ()/ =>/ Array.sub/ ((_),/ (_)))")
   466 code_const Array.upd' (SML "(fn/ ()/ =>/ Array.update/ ((_),/ (_),/ (_)))")
   467 
   468 code_reserved SML Array
   469 
   470 
   471 text {* OCaml *}
   472 
   473 code_type array (OCaml "_/ array")
   474 code_const Array (OCaml "failwith/ \"bare Array\"")
   475 code_const Array.new' (OCaml "(fun/ ()/ ->/ Array.make/ (Big'_int.int'_of'_big'_int/ _)/ _)")
   476 code_const Array.of_list' (OCaml "(fun/ ()/ ->/ Array.of'_list/ _)")
   477 code_const Array.len' (OCaml "(fun/ ()/ ->/ Big'_int.big'_int'_of'_int/ (Array.length/ _))")
   478 code_const Array.nth' (OCaml "(fun/ ()/ ->/ Array.get/ _/ (Big'_int.int'_of'_big'_int/ _))")
   479 code_const Array.upd' (OCaml "(fun/ ()/ ->/ Array.set/ _/ (Big'_int.int'_of'_big'_int/ _)/ _)")
   480 
   481 code_reserved OCaml Array
   482 
   483 
   484 text {* Haskell *}
   485 
   486 code_type array (Haskell "Heap.STArray/ Heap.RealWorld/ _")
   487 code_const Array (Haskell "error/ \"bare Array\"")
   488 code_const Array.new' (Haskell "Heap.newArray/ (0,/ _)")
   489 code_const Array.of_list' (Haskell "Heap.newListArray/ (0,/ _)")
   490 code_const Array.len' (Haskell "Heap.lengthArray")
   491 code_const Array.nth' (Haskell "Heap.readArray")
   492 code_const Array.upd' (Haskell "Heap.writeArray")
   493 
   494 end