src/Pure/Isar/toplevel.ML
author wenzelm
Wed Apr 06 16:33:33 2016 +0200 (2016-04-06 ago)
changeset 62889 99c7f31615c2
parent 62826 eb94e570c1a4
child 62895 54c2abe7e9a4
permissions -rw-r--r--
clarified modules;
tuned signature;
     1 (*  Title:      Pure/Isar/toplevel.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Isabelle/Isar toplevel transactions.
     5 *)
     6 
     7 signature TOPLEVEL =
     8 sig
     9   exception UNDEF
    10   type state
    11   val toplevel: state
    12   val is_toplevel: state -> bool
    13   val is_theory: state -> bool
    14   val is_proof: state -> bool
    15   val is_skipped_proof: state -> bool
    16   val level: state -> int
    17   val presentation_context_of: state -> Proof.context
    18   val previous_context_of: state -> Proof.context option
    19   val context_of: state -> Proof.context
    20   val generic_theory_of: state -> generic_theory
    21   val theory_of: state -> theory
    22   val proof_of: state -> Proof.state
    23   val proof_position_of: state -> int
    24   val end_theory: Position.T -> state -> theory
    25   val pretty_context: state -> Pretty.T list
    26   val pretty_state: state -> Pretty.T list
    27   val string_of_state: state -> string
    28   val pretty_abstract: state -> Pretty.T
    29   type transition
    30   val empty: transition
    31   val name_of: transition -> string
    32   val pos_of: transition -> Position.T
    33   val type_error: transition -> string
    34   val name: string -> transition -> transition
    35   val position: Position.T -> transition -> transition
    36   val init_theory: (unit -> theory) -> transition -> transition
    37   val is_init: transition -> bool
    38   val modify_init: (unit -> theory) -> transition -> transition
    39   val exit: transition -> transition
    40   val keep: (state -> unit) -> transition -> transition
    41   val keep': (bool -> state -> unit) -> transition -> transition
    42   val keep_proof: (state -> unit) -> transition -> transition
    43   val ignored: Position.T -> transition
    44   val is_ignored: transition -> bool
    45   val malformed: Position.T -> string -> transition
    46   val generic_theory: (generic_theory -> generic_theory) -> transition -> transition
    47   val theory': (bool -> theory -> theory) -> transition -> transition
    48   val theory: (theory -> theory) -> transition -> transition
    49   val begin_local_theory: bool -> (theory -> local_theory) -> transition -> transition
    50   val end_local_theory: transition -> transition
    51   val open_target: (generic_theory -> local_theory) -> transition -> transition
    52   val close_target: transition -> transition
    53   val local_theory': (bool * Position.T) option -> (xstring * Position.T) option ->
    54     (bool -> local_theory -> local_theory) -> transition -> transition
    55   val local_theory: (bool * Position.T) option -> (xstring * Position.T) option ->
    56     (local_theory -> local_theory) -> transition -> transition
    57   val present_local_theory: (xstring * Position.T) option -> (state -> unit) ->
    58     transition -> transition
    59   val local_theory_to_proof': (bool * Position.T) option -> (xstring * Position.T) option ->
    60     (bool -> local_theory -> Proof.state) -> transition -> transition
    61   val local_theory_to_proof: (bool * Position.T) option -> (xstring * Position.T) option ->
    62     (local_theory -> Proof.state) -> transition -> transition
    63   val theory_to_proof: (theory -> Proof.state) -> transition -> transition
    64   val end_proof: (bool -> Proof.state -> Proof.context) -> transition -> transition
    65   val forget_proof: bool -> transition -> transition
    66   val proofs': (bool -> Proof.state -> Proof.state Seq.result Seq.seq) -> transition -> transition
    67   val proof': (bool -> Proof.state -> Proof.state) -> transition -> transition
    68   val proofs: (Proof.state -> Proof.state Seq.result Seq.seq) -> transition -> transition
    69   val proof: (Proof.state -> Proof.state) -> transition -> transition
    70   val actual_proof: (Proof_Node.T -> Proof_Node.T) -> transition -> transition
    71   val skip_proof: (unit -> unit) -> transition -> transition
    72   val skip_proof_open: transition -> transition
    73   val skip_proof_close: transition -> transition
    74   val exec_id: Document_ID.exec -> transition -> transition
    75   val setmp_thread_position: transition -> ('a -> 'b) -> 'a -> 'b
    76   val add_hook: (transition -> state -> state -> unit) -> unit
    77   val get_timing: transition -> Time.time option
    78   val put_timing: Time.time option -> transition -> transition
    79   val transition: bool -> transition -> state -> state * (exn * string) option
    80   val command_errors: bool -> transition -> state -> Runtime.error list * state option
    81   val command_exception: bool -> transition -> state -> state
    82   val reset_theory: state -> state option
    83   val reset_proof: state -> state option
    84   type result
    85   val join_results: result -> (transition * state) list
    86   val element_result: Keyword.keywords -> transition Thy_Syntax.element -> state -> result * state
    87 end;
    88 
    89 structure Toplevel: TOPLEVEL =
    90 struct
    91 
    92 (** toplevel state **)
    93 
    94 exception UNDEF = Runtime.UNDEF;
    95 
    96 
    97 (* datatype node *)
    98 
    99 datatype node =
   100   Theory of generic_theory * Proof.context option
   101     (*theory with presentation context*) |
   102   Proof of Proof_Node.T * ((Proof.context -> generic_theory) * generic_theory)
   103     (*proof node, finish, original theory*) |
   104   Skipped_Proof of int * (generic_theory * generic_theory);
   105     (*proof depth, resulting theory, original theory*)
   106 
   107 val theory_node = fn Theory (gthy, _) => SOME gthy | _ => NONE;
   108 val proof_node = fn Proof (prf, _) => SOME prf | _ => NONE;
   109 val skipped_proof_node = fn Skipped_Proof _ => true | _ => false;
   110 
   111 fun cases_node f _ (Theory (gthy, _)) = f gthy
   112   | cases_node _ g (Proof (prf, _)) = g (Proof_Node.current prf)
   113   | cases_node f _ (Skipped_Proof (_, (gthy, _))) = f gthy;
   114 
   115 val context_node = cases_node Context.proof_of Proof.context_of;
   116 
   117 
   118 (* datatype state *)
   119 
   120 datatype state = State of node option * node option;  (*current, previous*)
   121 
   122 val toplevel = State (NONE, NONE);
   123 
   124 fun is_toplevel (State (NONE, _)) = true
   125   | is_toplevel _ = false;
   126 
   127 fun level (State (NONE, _)) = 0
   128   | level (State (SOME (Theory _), _)) = 0
   129   | level (State (SOME (Proof (prf, _)), _)) = Proof.level (Proof_Node.current prf)
   130   | level (State (SOME (Skipped_Proof (d, _)), _)) = d + 1;   (*different notion of proof depth!*)
   131 
   132 fun str_of_state (State (NONE, SOME (Theory (Context.Theory thy, _)))) =
   133       "at top level, result theory " ^ quote (Context.theory_name thy)
   134   | str_of_state (State (NONE, _)) = "at top level"
   135   | str_of_state (State (SOME (Theory (Context.Theory _, _)), _)) = "in theory mode"
   136   | str_of_state (State (SOME (Theory (Context.Proof _, _)), _)) = "in local theory mode"
   137   | str_of_state (State (SOME (Proof _), _)) = "in proof mode"
   138   | str_of_state (State (SOME (Skipped_Proof _), _)) = "in skipped proof mode";
   139 
   140 
   141 (* current node *)
   142 
   143 fun node_of (State (NONE, _)) = raise UNDEF
   144   | node_of (State (SOME node, _)) = node;
   145 
   146 fun is_theory state = not (is_toplevel state) andalso is_some (theory_node (node_of state));
   147 fun is_proof state = not (is_toplevel state) andalso is_some (proof_node (node_of state));
   148 fun is_skipped_proof state = not (is_toplevel state) andalso skipped_proof_node (node_of state);
   149 
   150 fun node_case f g state = cases_node f g (node_of state);
   151 
   152 fun presentation_context_of state =
   153   (case try node_of state of
   154     SOME (Theory (_, SOME ctxt)) => ctxt
   155   | SOME node => context_node node
   156   | NONE => raise UNDEF);
   157 
   158 fun previous_context_of (State (_, NONE)) = NONE
   159   | previous_context_of (State (_, SOME prev)) = SOME (context_node prev);
   160 
   161 val context_of = node_case Context.proof_of Proof.context_of;
   162 val generic_theory_of = node_case I (Context.Proof o Proof.context_of);
   163 val theory_of = node_case Context.theory_of Proof.theory_of;
   164 val proof_of = node_case (fn _ => error "No proof state") I;
   165 
   166 fun proof_position_of state =
   167   (case node_of state of
   168     Proof (prf, _) => Proof_Node.position prf
   169   | _ => ~1);
   170 
   171 fun end_theory _ (State (NONE, SOME (Theory (Context.Theory thy, _)))) = thy
   172   | end_theory pos (State (NONE, _)) = error ("Bad theory" ^ Position.here pos)
   173   | end_theory pos (State (SOME _, _)) = error ("Unfinished theory" ^ Position.here pos);
   174 
   175 
   176 (* print state *)
   177 
   178 fun pretty_context state =
   179   (case try node_of state of
   180     NONE => []
   181   | SOME node =>
   182       let
   183         val gthy =
   184           (case node of
   185             Theory (gthy, _) => gthy
   186           | Proof (_, (_, gthy)) => gthy
   187           | Skipped_Proof (_, (gthy, _)) => gthy);
   188         val lthy = Context.cases (Named_Target.theory_init) I gthy;
   189       in Local_Theory.pretty lthy end);
   190 
   191 fun pretty_state state =
   192   (case try node_of state of
   193     NONE => []
   194   | SOME (Theory _) => []
   195   | SOME (Proof (prf, _)) => Proof.pretty_state (Proof_Node.current prf)
   196   | SOME (Skipped_Proof (d, _)) => [Pretty.str ("skipped proof: depth " ^ string_of_int d)]);
   197 
   198 val string_of_state = pretty_state #> Pretty.chunks #> Pretty.string_of;
   199 
   200 fun pretty_abstract state = Pretty.str ("<Isar " ^ str_of_state state ^ ">");
   201 
   202 val _ = ML_system_pp (fn _ => fn _ => Pretty.to_polyml o pretty_abstract);
   203 
   204 
   205 
   206 (** toplevel transitions **)
   207 
   208 (* node transactions -- maintaining stable checkpoints *)
   209 
   210 exception FAILURE of state * exn;
   211 
   212 local
   213 
   214 fun reset_presentation (Theory (gthy, _)) = Theory (gthy, NONE)
   215   | reset_presentation node = node;
   216 
   217 in
   218 
   219 fun apply_transaction f g node =
   220   let
   221     val cont_node = reset_presentation node;
   222     val context = cases_node I (Context.Proof o Proof.context_of) cont_node;
   223     fun state_error e nd = (State (SOME nd, SOME node), e);
   224 
   225     val (result, err) =
   226       cont_node
   227       |> Runtime.controlled_execution (SOME context) f
   228       |> state_error NONE
   229       handle exn => state_error (SOME exn) cont_node;
   230   in
   231     (case err of
   232       NONE => tap g result
   233     | SOME exn => raise FAILURE (result, exn))
   234   end;
   235 
   236 val exit_transaction =
   237   apply_transaction
   238     (fn Theory (Context.Theory thy, _) => Theory (Context.Theory (Theory.end_theory thy), NONE)
   239       | node => node) (K ())
   240   #> (fn State (node', _) => State (NONE, node'));
   241 
   242 end;
   243 
   244 
   245 (* primitive transitions *)
   246 
   247 datatype trans =
   248   Init of unit -> theory |               (*init theory*)
   249   Exit |                                 (*formal exit of theory*)
   250   Keep of bool -> state -> unit |        (*peek at state*)
   251   Transaction of (bool -> node -> node) * (state -> unit);  (*node transaction and presentation*)
   252 
   253 local
   254 
   255 fun apply_tr _ (Init f) (State (NONE, _)) =
   256       State (SOME (Theory (Context.Theory (Runtime.controlled_execution NONE f ()), NONE)), NONE)
   257   | apply_tr _ Exit (State (SOME (state as Theory (Context.Theory _, _)), _)) =
   258       exit_transaction state
   259   | apply_tr int (Keep f) state =
   260       Runtime.controlled_execution (try generic_theory_of state) (fn x => tap (f int) x) state
   261   | apply_tr int (Transaction (f, g)) (State (SOME state, _)) =
   262       apply_transaction (fn x => f int x) g state
   263   | apply_tr _ _ _ = raise UNDEF;
   264 
   265 fun apply_union _ [] state = raise FAILURE (state, UNDEF)
   266   | apply_union int (tr :: trs) state =
   267       apply_union int trs state
   268         handle Runtime.UNDEF => apply_tr int tr state
   269           | FAILURE (alt_state, UNDEF) => apply_tr int tr alt_state
   270           | exn as FAILURE _ => raise exn
   271           | exn => raise FAILURE (state, exn);
   272 
   273 in
   274 
   275 fun apply_trans int trs state = (apply_union int trs state, NONE)
   276   handle FAILURE (alt_state, exn) => (alt_state, SOME exn) | exn => (state, SOME exn);
   277 
   278 end;
   279 
   280 
   281 (* datatype transition *)
   282 
   283 datatype transition = Transition of
   284  {name: string,              (*command name*)
   285   pos: Position.T,           (*source position*)
   286   timing: Time.time option,  (*prescient timing information*)
   287   trans: trans list};        (*primitive transitions (union)*)
   288 
   289 fun make_transition (name, pos, timing, trans) =
   290   Transition {name = name, pos = pos, timing = timing, trans = trans};
   291 
   292 fun map_transition f (Transition {name, pos, timing, trans}) =
   293   make_transition (f (name, pos, timing, trans));
   294 
   295 val empty = make_transition ("", Position.none, NONE, []);
   296 
   297 
   298 (* diagnostics *)
   299 
   300 fun name_of (Transition {name, ...}) = name;
   301 fun pos_of (Transition {pos, ...}) = pos;
   302 
   303 fun command_msg msg tr =
   304   msg ^ "command " ^ quote (Markup.markup Markup.keyword1 (name_of tr)) ^
   305     Position.here (pos_of tr);
   306 
   307 fun at_command tr = command_msg "At " tr;
   308 fun type_error tr = command_msg "Bad context for " tr;
   309 
   310 
   311 (* modify transitions *)
   312 
   313 fun name name = map_transition (fn (_, pos, timing, trans) =>
   314   (name, pos, timing, trans));
   315 
   316 fun position pos = map_transition (fn (name, _, timing, trans) =>
   317   (name, pos, timing, trans));
   318 
   319 fun add_trans tr = map_transition (fn (name, pos, timing, trans) =>
   320   (name, pos, timing, tr :: trans));
   321 
   322 val reset_trans = map_transition (fn (name, pos, timing, _) =>
   323   (name, pos, timing, []));
   324 
   325 
   326 (* basic transitions *)
   327 
   328 fun init_theory f = add_trans (Init f);
   329 
   330 fun is_init (Transition {trans = [Init _], ...}) = true
   331   | is_init _ = false;
   332 
   333 fun modify_init f tr = if is_init tr then init_theory f (reset_trans tr) else tr;
   334 
   335 val exit = add_trans Exit;
   336 val keep' = add_trans o Keep;
   337 
   338 fun present_transaction f g = add_trans (Transaction (f, g));
   339 fun transaction f = present_transaction f (K ());
   340 
   341 fun keep f = add_trans (Keep (fn _ => f));
   342 
   343 fun keep_proof f =
   344   keep (fn st =>
   345     if is_proof st then f st
   346     else if is_skipped_proof st then ()
   347     else warning "No proof state");
   348 
   349 fun ignored pos = empty |> name "<ignored>" |> position pos |> keep (fn _ => ());
   350 fun is_ignored tr = name_of tr = "<ignored>";
   351 
   352 fun malformed pos msg =
   353   empty |> name "<malformed>" |> position pos |> keep (fn _ => error msg);
   354 
   355 
   356 (* theory transitions *)
   357 
   358 fun generic_theory f = transaction (fn _ =>
   359   (fn Theory (gthy, _) => Theory (f gthy, NONE)
   360     | _ => raise UNDEF));
   361 
   362 fun theory' f = transaction (fn int =>
   363   (fn Theory (Context.Theory thy, _) =>
   364       let val thy' = thy
   365         |> Sign.new_group
   366         |> f int
   367         |> Sign.reset_group;
   368       in Theory (Context.Theory thy', NONE) end
   369     | _ => raise UNDEF));
   370 
   371 fun theory f = theory' (K f);
   372 
   373 fun begin_local_theory begin f = transaction (fn _ =>
   374   (fn Theory (Context.Theory thy, _) =>
   375         let
   376           val lthy = f thy;
   377           val gthy = if begin then Context.Proof lthy else Context.Theory (Named_Target.exit lthy);
   378           val _ =
   379             (case Local_Theory.pretty lthy of
   380               [] => ()
   381             | prts => Output.state (Pretty.string_of (Pretty.chunks prts)));
   382         in Theory (gthy, SOME lthy) end
   383     | _ => raise UNDEF));
   384 
   385 val end_local_theory = transaction (fn _ =>
   386   (fn Theory (Context.Proof lthy, _) => Theory (Context.Theory (Named_Target.exit lthy), SOME lthy)
   387     | _ => raise UNDEF));
   388 
   389 fun open_target f = transaction (fn _ =>
   390   (fn Theory (gthy, _) =>
   391         let val lthy = f gthy
   392         in Theory (Context.Proof lthy, SOME lthy) end
   393     | _ => raise UNDEF));
   394 
   395 val close_target = transaction (fn _ =>
   396   (fn Theory (Context.Proof lthy, _) =>
   397         (case try Local_Theory.close_target lthy of
   398           SOME ctxt' =>
   399             let
   400               val gthy' =
   401                 if can Local_Theory.assert ctxt'
   402                 then Context.Proof ctxt'
   403                 else Context.Theory (Proof_Context.theory_of ctxt');
   404             in Theory (gthy', SOME lthy) end
   405         | NONE => raise UNDEF)
   406     | _ => raise UNDEF));
   407 
   408 fun restricted_context (SOME (strict, scope)) =
   409       Proof_Context.map_naming (Name_Space.restricted strict scope)
   410   | restricted_context NONE = I;
   411 
   412 fun local_theory' restricted target f = present_transaction (fn int =>
   413   (fn Theory (gthy, _) =>
   414         let
   415           val (finish, lthy) = Named_Target.switch target gthy;
   416           val lthy' = lthy
   417             |> restricted_context restricted
   418             |> Local_Theory.new_group
   419             |> f int
   420             |> Local_Theory.reset_group;
   421         in Theory (finish lthy', SOME lthy') end
   422     | _ => raise UNDEF))
   423   (K ());
   424 
   425 fun local_theory restricted target f = local_theory' restricted target (K f);
   426 
   427 fun present_local_theory target = present_transaction (fn int =>
   428   (fn Theory (gthy, _) =>
   429         let val (finish, lthy) = Named_Target.switch target gthy;
   430         in Theory (finish lthy, SOME lthy) end
   431     | _ => raise UNDEF));
   432 
   433 
   434 (* proof transitions *)
   435 
   436 fun end_proof f = transaction (fn int =>
   437   (fn Proof (prf, (finish, _)) =>
   438         let val state = Proof_Node.current prf in
   439           if can (Proof.assert_bottom true) state then
   440             let
   441               val ctxt' = f int state;
   442               val gthy' = finish ctxt';
   443             in Theory (gthy', SOME ctxt') end
   444           else raise UNDEF
   445         end
   446     | Skipped_Proof (0, (gthy, _)) => Theory (gthy, NONE)
   447     | _ => raise UNDEF));
   448 
   449 local
   450 
   451 fun begin_proof init = transaction (fn int =>
   452   (fn Theory (gthy, _) =>
   453     let
   454       val (finish, prf) = init int gthy;
   455       val skip = Goal.skip_proofs_enabled ();
   456       val schematic_goal = try Proof.schematic_goal prf;
   457       val _ =
   458         if skip andalso schematic_goal = SOME true then
   459           warning "Cannot skip proof of schematic goal statement"
   460         else ();
   461     in
   462       if skip andalso schematic_goal = SOME false then
   463         Skipped_Proof (0, (finish (Proof.global_skip_proof true prf), gthy))
   464       else Proof (Proof_Node.init prf, (finish, gthy))
   465     end
   466   | _ => raise UNDEF));
   467 
   468 in
   469 
   470 fun local_theory_to_proof' restricted target f = begin_proof
   471   (fn int => fn gthy =>
   472     let
   473       val (finish, lthy) = Named_Target.switch target gthy;
   474       val prf = lthy
   475         |> restricted_context restricted
   476         |> Local_Theory.new_group
   477         |> f int;
   478     in (finish o Local_Theory.reset_group, prf) end);
   479 
   480 fun local_theory_to_proof restricted target f =
   481   local_theory_to_proof' restricted target (K f);
   482 
   483 fun theory_to_proof f = begin_proof
   484   (fn _ => fn gthy =>
   485     (Context.Theory o Sign.reset_group o Sign.change_check o Proof_Context.theory_of,
   486       (case gthy of
   487         Context.Theory thy => f (Sign.new_group thy)
   488       | _ => raise UNDEF)));
   489 
   490 end;
   491 
   492 fun forget_proof strict = transaction (fn _ =>
   493   (fn Proof (prf, (_, orig_gthy)) =>
   494         if strict andalso not (Proof.has_bottom_goal (Proof_Node.current prf))
   495         then raise UNDEF else Theory (orig_gthy, NONE)
   496     | Skipped_Proof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   497     | _ => raise UNDEF));
   498 
   499 fun proofs' f = transaction (fn int =>
   500   (fn Proof (prf, x) => Proof (Proof_Node.applys (f int) prf, x)
   501     | skip as Skipped_Proof _ => skip
   502     | _ => raise UNDEF));
   503 
   504 fun proof' f = proofs' ((Seq.single o Seq.Result) oo f);
   505 val proofs = proofs' o K;
   506 val proof = proof' o K;
   507 
   508 
   509 (* skipped proofs *)
   510 
   511 fun actual_proof f = transaction (fn _ =>
   512   (fn Proof (prf, x) => Proof (f prf, x)
   513     | _ => raise UNDEF));
   514 
   515 fun skip_proof f = transaction (fn _ =>
   516   (fn skip as Skipped_Proof _ => (f (); skip)
   517     | _ => raise UNDEF));
   518 
   519 val skip_proof_open = transaction (fn _ =>
   520   (fn Skipped_Proof (d, x) => Skipped_Proof (d + 1, x)
   521     | _ => raise UNDEF));
   522 
   523 val skip_proof_close = transaction (fn _ =>
   524   (fn Skipped_Proof (0, (gthy, _)) => Theory (gthy, NONE)
   525     | Skipped_Proof (d, x) => Skipped_Proof (d - 1, x)
   526     | _ => raise UNDEF));
   527 
   528 
   529 
   530 (** toplevel transactions **)
   531 
   532 (* runtime position *)
   533 
   534 fun exec_id id (tr as Transition {pos, ...}) =
   535   position (Position.put_id (Document_ID.print id) pos) tr;
   536 
   537 fun setmp_thread_position (Transition {pos, ...}) f x =
   538   Position.setmp_thread_data pos f x;
   539 
   540 
   541 (* post-transition hooks *)
   542 
   543 local
   544   val hooks =
   545     Synchronized.var "Toplevel.hooks" ([]: (transition -> state -> state -> unit) list);
   546 in
   547 
   548 fun add_hook hook = Synchronized.change hooks (cons hook);
   549 fun get_hooks () = Synchronized.value hooks;
   550 
   551 end;
   552 
   553 
   554 (* apply transitions *)
   555 
   556 fun get_timing (Transition {timing, ...}) = timing;
   557 fun put_timing timing = map_transition (fn (name, pos, _, trans) => (name, pos, timing, trans));
   558 
   559 local
   560 
   561 fun app int (tr as Transition {name, trans, ...}) =
   562   setmp_thread_position tr (fn state =>
   563     let
   564       val timing_start = Timing.start ();
   565       val (result, opt_err) = apply_trans int trans state;
   566       val timing_result = Timing.result timing_start;
   567       val timing_props =
   568         Markup.command_timing :: (Markup.nameN, name_of tr) :: Position.properties_of (pos_of tr);
   569       val _ = Timing.protocol_message timing_props timing_result;
   570     in (result, Option.map (fn UNDEF => ERROR (type_error tr) | exn => exn) opt_err) end);
   571 
   572 in
   573 
   574 fun transition int tr st =
   575   let
   576     val (st', opt_err) =
   577       Context.setmp_generic_context (try (Context.Proof o presentation_context_of) st)
   578         (fn () => app int tr st) ();
   579     val opt_err' = opt_err |> Option.map
   580       (fn Runtime.EXCURSION_FAIL exn_info => exn_info
   581         | exn => (Runtime.exn_context (try context_of st) exn, at_command tr));
   582     val _ = get_hooks () |> List.app (fn f => (try (fn () => f tr st st') (); ()));
   583   in (st', opt_err') end;
   584 
   585 end;
   586 
   587 
   588 (* managed commands *)
   589 
   590 fun command_errors int tr st =
   591   (case transition int tr st of
   592     (st', NONE) => ([], SOME st')
   593   | (_, SOME (exn, _)) => (Runtime.exn_messages_ids exn, NONE));
   594 
   595 fun command_exception int tr st =
   596   (case transition int tr st of
   597     (st', NONE) => st'
   598   | (_, SOME (exn, info)) =>
   599       if Exn.is_interrupt exn then Exn.reraise exn
   600       else raise Runtime.EXCURSION_FAIL (exn, info));
   601 
   602 val command = command_exception false;
   603 
   604 
   605 (* reset state *)
   606 
   607 local
   608 
   609 fun reset_state check trans st =
   610   if check st then NONE
   611   else #2 (command_errors false (trans empty) st);
   612 
   613 in
   614 
   615 val reset_theory = reset_state is_theory (forget_proof false);
   616 
   617 val reset_proof =
   618   reset_state is_proof
   619     (transaction (fn _ =>
   620       (fn Theory (gthy, _) => Skipped_Proof (0, (gthy, gthy))
   621         | _ => raise UNDEF)));
   622 
   623 end;
   624 
   625 
   626 (* scheduled proof result *)
   627 
   628 datatype result =
   629   Result of transition * state |
   630   Result_List of result list |
   631   Result_Future of result future;
   632 
   633 fun join_results (Result x) = [x]
   634   | join_results (Result_List xs) = maps join_results xs
   635   | join_results (Result_Future x) = join_results (Future.join x);
   636 
   637 local
   638 
   639 structure Result = Proof_Data
   640 (
   641   type T = result;
   642   fun init _ = Result_List [];
   643 );
   644 
   645 val get_result = Result.get o Proof.context_of;
   646 val put_result = Proof.map_context o Result.put;
   647 
   648 fun timing_estimate include_head elem =
   649   let
   650     val trs = Thy_Syntax.flat_element elem |> not include_head ? tl;
   651     val timings = map get_timing trs;
   652   in
   653     if forall is_some timings then
   654       SOME (fold (curry (op +) o the) timings Time.zeroTime)
   655     else NONE
   656   end;
   657 
   658 fun priority NONE = ~1
   659   | priority (SOME estimate) =
   660       Int.min (Real.floor (Real.max (Math.log10 (Time.toReal estimate), ~3.0)) - 3, ~1);
   661 
   662 fun proof_future_enabled estimate st =
   663   (case try proof_of st of
   664     NONE => false
   665   | SOME state =>
   666       not (Proof.is_relevant state) andalso
   667        (if can (Proof.assert_bottom true) state
   668         then Goal.future_enabled 1
   669         else
   670           (case estimate of
   671             NONE => Goal.future_enabled 2
   672           | SOME t => Goal.future_enabled_timing t)));
   673 
   674 fun atom_result keywords tr st =
   675   let
   676     val st' =
   677       if Goal.future_enabled 1 andalso Keyword.is_diag keywords (name_of tr) then
   678         (Execution.fork
   679           {name = "Toplevel.diag", pos = pos_of tr,
   680             pri = priority (timing_estimate true (Thy_Syntax.atom tr))}
   681           (fn () => command tr st); st)
   682       else command tr st;
   683   in (Result (tr, st'), st') end;
   684 
   685 in
   686 
   687 fun element_result keywords (Thy_Syntax.Element (tr, NONE)) st = atom_result keywords tr st
   688   | element_result keywords (elem as Thy_Syntax.Element (head_tr, SOME element_rest)) st =
   689       let
   690         val (head_result, st') = atom_result keywords head_tr st;
   691         val (body_elems, end_tr) = element_rest;
   692         val estimate = timing_estimate false elem;
   693       in
   694         if not (proof_future_enabled estimate st')
   695         then
   696           let
   697             val proof_trs = maps Thy_Syntax.flat_element body_elems @ [end_tr];
   698             val (proof_results, st'') = fold_map (atom_result keywords) proof_trs st';
   699           in (Result_List (head_result :: proof_results), st'') end
   700         else
   701           let
   702             val finish = Context.Theory o Proof_Context.theory_of;
   703 
   704             val future_proof =
   705               Proof.future_proof (fn state =>
   706                 Execution.fork
   707                   {name = "Toplevel.future_proof", pos = pos_of head_tr, pri = priority estimate}
   708                   (fn () =>
   709                     let
   710                       val State (SOME (Proof (prf, (_, orig_gthy))), prev) = st';
   711                       val prf' = Proof_Node.apply (K state) prf;
   712                       val (result, result_state) =
   713                         State (SOME (Proof (prf', (finish, orig_gthy))), prev)
   714                         |> fold_map (element_result keywords) body_elems ||> command end_tr;
   715                     in (Result_List result, presentation_context_of result_state) end))
   716               #> (fn (res, state') => state' |> put_result (Result_Future res));
   717 
   718             val forked_proof =
   719               proof (future_proof #>
   720                 (fn state => state |> Proof.local_done_proof |> put_result (get_result state))) o
   721               end_proof (fn _ => future_proof #>
   722                 (fn state => state |> Proof.global_done_proof |> Result.put (get_result state)));
   723 
   724             val st'' = st'
   725               |> command (head_tr |> reset_trans |> forked_proof);
   726             val end_result = Result (end_tr, st'');
   727             val result =
   728               Result_List [head_result, Result.get (presentation_context_of st''), end_result];
   729           in (result, st'') end
   730       end;
   731 
   732 end;
   733 
   734 end;