src/HOL/Tools/Sledgehammer/sledgehammer_fol_clause.ML
author blanchet
Tue Apr 27 14:27:47 2010 +0200 (2010-04-27 ago)
changeset 36476 a04cf4704668
parent 36393 be73a2b2443b
child 36491 6769f8eacaac
permissions -rw-r--r--
in Sledgehammer "debug" mode, the names of most variables are already short and sweet, so most of the entries of the "const_trans_table" don't have a raison d'etre anymore
     1 (*  Title:      HOL/Tools/Sledgehammer/sledgehammer_fol_clause.ML
     2     Author:     Jia Meng, Cambridge University Computer Laboratory
     3     Author:     Jasmin Blanchette, TU Muenchen
     4 
     5 Storing/printing FOL clauses and arity clauses.  Typed equality is
     6 treated differently.
     7 
     8 FIXME: combine with sledgehammer_hol_clause!
     9 *)
    10 
    11 signature SLEDGEHAMMER_FOL_CLAUSE =
    12 sig
    13   val schematic_var_prefix: string
    14   val fixed_var_prefix: string
    15   val tvar_prefix: string
    16   val tfree_prefix: string
    17   val clause_prefix: string
    18   val const_prefix: string
    19   val tconst_prefix: string
    20   val class_prefix: string
    21   val union_all: ''a list list -> ''a list
    22   val const_trans_table: string Symtab.table
    23   val type_const_trans_table: string Symtab.table
    24   val ascii_of: string -> string
    25   val undo_ascii_of: string -> string
    26   val paren_pack : string list -> string
    27   val make_schematic_var : string * int -> string
    28   val make_fixed_var : string -> string
    29   val make_schematic_type_var : string * int -> string
    30   val make_fixed_type_var : string -> string
    31   val make_fixed_const : bool -> string -> string
    32   val make_fixed_type_const : bool -> string -> string
    33   val make_type_class : string -> string
    34   type name = string * string
    35   type name_pool = string Symtab.table * string Symtab.table
    36   val empty_name_pool : bool -> name_pool option
    37   val pool_map : ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
    38   val nice_name : name -> name_pool option -> string * name_pool option
    39   datatype kind = Axiom | Conjecture
    40   type axiom_name = string
    41   datatype fol_type =
    42     TyVar of name |
    43     TyFree of name |
    44     TyConstr of name * fol_type list
    45   val string_of_fol_type :
    46     fol_type -> name_pool option -> string * name_pool option
    47   datatype type_literal = LTVar of string * string | LTFree of string * string
    48   exception CLAUSE of string * term
    49   val add_typs : typ list -> type_literal list
    50   val get_tvar_strs: typ list -> string list
    51   datatype arLit =
    52       TConsLit of class * string * string list
    53     | TVarLit of class * string
    54   datatype arity_clause = ArityClause of
    55    {axiom_name: axiom_name, conclLit: arLit, premLits: arLit list}
    56   datatype classrel_clause = ClassrelClause of
    57    {axiom_name: axiom_name, subclass: class, superclass: class}
    58   val make_classrel_clauses: theory -> class list -> class list -> classrel_clause list
    59   val make_arity_clauses_dfg: bool -> theory -> string list -> class list -> class list * arity_clause list
    60   val make_arity_clauses: theory -> string list -> class list -> class list * arity_clause list
    61   val add_type_sort_preds: typ -> int Symtab.table -> int Symtab.table
    62   val add_classrel_clause_preds :
    63     classrel_clause -> int Symtab.table -> int Symtab.table
    64   val class_of_arityLit: arLit -> class
    65   val add_arity_clause_preds: arity_clause -> int Symtab.table -> int Symtab.table
    66   val add_fol_type_funcs: fol_type -> int Symtab.table -> int Symtab.table
    67   val add_arity_clause_funcs:
    68     arity_clause -> int Symtab.table -> int Symtab.table
    69   val init_functab: int Symtab.table
    70   val dfg_sign: bool -> string -> string
    71   val dfg_of_typeLit: bool -> type_literal -> string
    72   val gen_dfg_cls: int * string * kind * string list * string list * string list -> string
    73   val string_of_preds: (string * Int.int) list -> string
    74   val string_of_funcs: (string * int) list -> string
    75   val string_of_symbols: string -> string -> string
    76   val string_of_start: string -> string
    77   val string_of_descrip : string -> string
    78   val dfg_tfree_clause : string -> string
    79   val dfg_classrel_clause: classrel_clause -> string
    80   val dfg_arity_clause: arity_clause -> string
    81   val tptp_sign: bool -> string -> string
    82   val tptp_of_typeLit : bool -> type_literal -> string
    83   val gen_tptp_cls : int * string * kind * string list * string list -> string
    84   val tptp_tfree_clause : string -> string
    85   val tptp_arity_clause : arity_clause -> string
    86   val tptp_classrel_clause : classrel_clause -> string
    87 end
    88 
    89 structure Sledgehammer_FOL_Clause : SLEDGEHAMMER_FOL_CLAUSE =
    90 struct
    91 
    92 open Sledgehammer_Util
    93 
    94 val schematic_var_prefix = "V_";
    95 val fixed_var_prefix = "v_";
    96 
    97 val tvar_prefix = "T_";
    98 val tfree_prefix = "t_";
    99 
   100 val clause_prefix = "cls_";
   101 val arclause_prefix = "clsarity_"
   102 val clrelclause_prefix = "clsrel_";
   103 
   104 val const_prefix = "c_";
   105 val tconst_prefix = "tc_";
   106 val class_prefix = "class_";
   107 
   108 fun union_all xss = fold (union (op =)) xss []
   109 
   110 (* Provide readable names for the more common symbolic functions *)
   111 val const_trans_table =
   112   Symtab.make [(@{const_name "op ="}, "equal"),
   113                (@{const_name "op &"}, "and"),
   114                (@{const_name "op |"}, "or"),
   115                (@{const_name "op -->"}, "implies"),
   116                (@{const_name "op :"}, "in")]
   117 
   118 val type_const_trans_table =
   119   Symtab.make [(@{type_name "*"}, "prod"),
   120                (@{type_name "+"}, "sum")]
   121 
   122 (*Escaping of special characters.
   123   Alphanumeric characters are left unchanged.
   124   The character _ goes to __
   125   Characters in the range ASCII space to / go to _A to _P, respectively.
   126   Other printing characters go to _nnn where nnn is the decimal ASCII code.*)
   127 val A_minus_space = Char.ord #"A" - Char.ord #" ";
   128 
   129 fun stringN_of_int 0 _ = ""
   130   | stringN_of_int k n = stringN_of_int (k-1) (n div 10) ^ Int.toString (n mod 10);
   131 
   132 fun ascii_of_c c =
   133   if Char.isAlphaNum c then String.str c
   134   else if c = #"_" then "__"
   135   else if #" " <= c andalso c <= #"/"
   136        then "_" ^ String.str (Char.chr (Char.ord c + A_minus_space))
   137   else if Char.isPrint c
   138        then ("_" ^ stringN_of_int 3 (Char.ord c))  (*fixed width, in case more digits follow*)
   139   else ""
   140 
   141 val ascii_of = String.translate ascii_of_c;
   142 
   143 (** Remove ASCII armouring from names in proof files **)
   144 
   145 (*We don't raise error exceptions because this code can run inside the watcher.
   146   Also, the errors are "impossible" (hah!)*)
   147 fun undo_ascii_aux rcs [] = String.implode(rev rcs)
   148   | undo_ascii_aux rcs [#"_"] = undo_ascii_aux (#"_"::rcs) []  (*ERROR*)
   149       (*Three types of _ escapes: __, _A to _P, _nnn*)
   150   | undo_ascii_aux rcs (#"_" :: #"_" :: cs) = undo_ascii_aux (#"_"::rcs) cs
   151   | undo_ascii_aux rcs (#"_" :: c :: cs) =
   152       if #"A" <= c andalso c<= #"P"  (*translation of #" " to #"/"*)
   153       then undo_ascii_aux (Char.chr(Char.ord c - A_minus_space) :: rcs) cs
   154       else
   155         let val digits = List.take (c::cs, 3) handle Subscript => []
   156         in
   157             case Int.fromString (String.implode digits) of
   158                 NONE => undo_ascii_aux (c:: #"_"::rcs) cs  (*ERROR*)
   159               | SOME n => undo_ascii_aux (Char.chr n :: rcs) (List.drop (cs, 2))
   160         end
   161   | undo_ascii_aux rcs (c::cs) = undo_ascii_aux (c::rcs) cs;
   162 
   163 val undo_ascii_of = undo_ascii_aux [] o String.explode;
   164 
   165 (* convert a list of strings into one single string; surrounded by brackets *)
   166 fun paren_pack [] = ""   (*empty argument list*)
   167   | paren_pack strings = "(" ^ commas strings ^ ")";
   168 
   169 (*TSTP format uses (...) rather than the old [...]*)
   170 fun tptp_pack strings = "(" ^ space_implode " | " strings ^ ")";
   171 
   172 
   173 (*Remove the initial ' character from a type variable, if it is present*)
   174 fun trim_type_var s =
   175   if s <> "" andalso String.sub(s,0) = #"'" then String.extract(s,1,NONE)
   176   else error ("trim_type: Malformed type variable encountered: " ^ s);
   177 
   178 fun ascii_of_indexname (v,0) = ascii_of v
   179   | ascii_of_indexname (v,i) = ascii_of v ^ "_" ^ Int.toString i;
   180 
   181 fun make_schematic_var v = schematic_var_prefix ^ (ascii_of_indexname v);
   182 fun make_fixed_var x = fixed_var_prefix ^ (ascii_of x);
   183 
   184 fun make_schematic_type_var (x,i) =
   185       tvar_prefix ^ (ascii_of_indexname (trim_type_var x,i));
   186 fun make_fixed_type_var x = tfree_prefix ^ (ascii_of (trim_type_var x));
   187 
   188 val max_dfg_symbol_length = 63
   189 
   190 (* HACK because SPASS 3.0 truncates identifiers to 63 characters. *)
   191 fun controlled_length dfg s =
   192   if dfg andalso size s > max_dfg_symbol_length then
   193     String.extract (s, 0, SOME (max_dfg_symbol_length div 2 - 1)) ^ "__" ^
   194     String.extract (s, size s - max_dfg_symbol_length div 2 + 1, NONE)
   195   else
   196     s
   197 
   198 fun lookup_const dfg c =
   199     case Symtab.lookup const_trans_table c of
   200         SOME c' => c'
   201       | NONE => controlled_length dfg (ascii_of c);
   202 
   203 fun lookup_type_const dfg c =
   204     case Symtab.lookup type_const_trans_table c of
   205         SOME c' => c'
   206       | NONE => controlled_length dfg (ascii_of c);
   207 
   208 (* "op =" MUST BE "equal" because it's built into ATPs. *)
   209 fun make_fixed_const _ (@{const_name "op ="}) = "equal"
   210   | make_fixed_const dfg c = const_prefix ^ lookup_const dfg c;
   211 
   212 fun make_fixed_type_const dfg c = tconst_prefix ^ lookup_type_const dfg c;
   213 
   214 fun make_type_class clas = class_prefix ^ ascii_of clas;
   215 
   216 
   217 (**** name pool ****)
   218  
   219 type name = string * string
   220 type name_pool = string Symtab.table * string Symtab.table
   221 
   222 fun empty_name_pool readable_names =
   223   if readable_names then SOME (`I Symtab.empty) else NONE
   224 
   225 fun pool_map f xs =
   226   fold_rev (fn x => fn (ys, pool) => f x pool |>> (fn y => y :: ys)) xs
   227   o pair []
   228 
   229 fun add_nice_name full_name nice_prefix j the_pool =
   230   let
   231     val nice_name = nice_prefix ^ (if j = 0 then "" else "_" ^ Int.toString j)
   232   in
   233     case Symtab.lookup (snd the_pool) nice_name of
   234       SOME full_name' =>
   235       if full_name = full_name' then (nice_name, the_pool)
   236       else add_nice_name full_name nice_prefix (j + 1) the_pool
   237     | NONE =>
   238       (nice_name, (Symtab.update_new (full_name, nice_name) (fst the_pool),
   239                    Symtab.update_new (nice_name, full_name) (snd the_pool)))
   240   end
   241 
   242 fun translate_first_char f s =
   243   String.str (f (String.sub (s, 0))) ^ String.extract (s, 1, NONE)
   244 
   245 fun readable_name full_name s =
   246   let
   247     val s = s |> Long_Name.base_name
   248               |> fold remove_all ["\<^sub>", "\<^bsub>", "\<^esub>", "\<^isub>"]
   249     val s' = s |> explode |> rev |> dropwhile (curry (op =) "'")
   250     val s' =
   251       (s' |> rev
   252           |> implode
   253           |> String.translate
   254                  (fn c => if Char.isAlphaNum c orelse c = #"_" then String.str c
   255                           else ""))
   256       ^ replicate_string (String.size s - length s') "_"
   257     val s' =
   258       if s' = "" orelse not (Char.isAlpha (String.sub (s', 0))) then "X" ^ s'
   259       else s'
   260     (* Avoid "equal", since it's built into ATPs; and "op" is very ambiguous
   261        ("op &", "op |", etc.). *)
   262     val s' = if s' = "equal" orelse s' = "op" then full_name else s'
   263   in
   264     case (Char.isLower (String.sub (full_name, 0)),
   265           Char.isLower (String.sub (s', 0))) of
   266       (true, false) => translate_first_char Char.toLower s'
   267     | (false, true) => translate_first_char Char.toUpper s'
   268     | _ => s'
   269   end
   270 
   271 fun nice_name (full_name, _) NONE = (full_name, NONE)
   272   | nice_name (full_name, desired_name) (SOME the_pool) =
   273     case Symtab.lookup (fst the_pool) full_name of
   274       SOME nice_name => (nice_name, SOME the_pool)
   275     | NONE => add_nice_name full_name (readable_name full_name desired_name) 0
   276                             the_pool
   277               |> apsnd SOME
   278 
   279 (**** Definitions and functions for FOL clauses, for conversion to TPTP or DFG
   280       format ****)
   281 
   282 datatype kind = Axiom | Conjecture;
   283 
   284 type axiom_name = string;
   285 
   286 (**** Isabelle FOL clauses ****)
   287 
   288 datatype fol_type =
   289   TyVar of name |
   290   TyFree of name |
   291   TyConstr of name * fol_type list
   292 
   293 fun string_of_fol_type (TyVar sp) pool = nice_name sp pool
   294   | string_of_fol_type (TyFree sp) pool = nice_name sp pool
   295   | string_of_fol_type (TyConstr (sp, tys)) pool =
   296     let
   297       val (s, pool) = nice_name sp pool
   298       val (ss, pool) = pool_map string_of_fol_type tys pool
   299     in (s ^ paren_pack ss, pool) end
   300 
   301 (*First string is the type class; the second is a TVar or TFfree*)
   302 datatype type_literal = LTVar of string * string | LTFree of string * string;
   303 
   304 exception CLAUSE of string * term;
   305 
   306 (*Make literals for sorted type variables*)
   307 fun sorts_on_typs_aux (_, [])   = []
   308   | sorts_on_typs_aux ((x,i),  s::ss) =
   309       let val sorts = sorts_on_typs_aux ((x,i), ss)
   310       in
   311           if s = "HOL.type" then sorts
   312           else if i = ~1 then LTFree(make_type_class s, make_fixed_type_var x) :: sorts
   313           else LTVar(make_type_class s, make_schematic_type_var (x,i)) :: sorts
   314       end;
   315 
   316 fun sorts_on_typs (TFree (a,s)) = sorts_on_typs_aux ((a,~1),s)
   317   | sorts_on_typs (TVar (v,s))  = sorts_on_typs_aux (v,s);
   318 
   319 fun pred_of_sort (LTVar (s,ty)) = (s,1)
   320   | pred_of_sort (LTFree (s,ty)) = (s,1)
   321 
   322 (*Given a list of sorted type variables, return a list of type literals.*)
   323 fun add_typs Ts = fold (union (op =)) (map sorts_on_typs Ts) []
   324 
   325 (*The correct treatment of TFrees like 'a in lemmas (axiom clauses) is not clear.
   326   * Ignoring them leads to unsound proofs, since we do nothing to ensure that 'a
   327     in a lemma has the same sort as 'a in the conjecture.
   328   * Deleting such clauses will lead to problems with locales in other use of local results
   329     where 'a is fixed. Probably we should delete clauses unless the sorts agree.
   330   * Currently we include a class constraint in the clause, exactly as with TVars.
   331 *)
   332 
   333 (** make axiom and conjecture clauses. **)
   334 
   335 fun get_tvar_strs [] = []
   336   | get_tvar_strs ((TVar (indx,s))::Ts) =
   337       insert (op =) (make_schematic_type_var indx) (get_tvar_strs Ts)
   338   | get_tvar_strs((TFree _)::Ts) = get_tvar_strs Ts
   339 
   340 
   341 
   342 (**** Isabelle arities ****)
   343 
   344 datatype arLit = TConsLit of class * string * string list
   345                | TVarLit of class * string;
   346 
   347 datatype arity_clause =
   348          ArityClause of {axiom_name: axiom_name,
   349                          conclLit: arLit,
   350                          premLits: arLit list};
   351 
   352 
   353 fun gen_TVars 0 = []
   354   | gen_TVars n = ("T_" ^ Int.toString n) :: gen_TVars (n-1);
   355 
   356 fun pack_sort(_,[])  = []
   357   | pack_sort(tvar, "HOL.type"::srt) = pack_sort(tvar, srt)   (*IGNORE sort "type"*)
   358   | pack_sort(tvar, cls::srt) =  (cls, tvar) :: pack_sort(tvar, srt);
   359 
   360 (*Arity of type constructor tcon :: (arg1,...,argN)res*)
   361 fun make_axiom_arity_clause dfg (tcons, axiom_name, (cls,args)) =
   362    let val tvars = gen_TVars (length args)
   363        val tvars_srts = ListPair.zip (tvars,args)
   364    in
   365       ArityClause {axiom_name = axiom_name, 
   366                    conclLit = TConsLit (cls, make_fixed_type_const dfg tcons, tvars),
   367                    premLits = map TVarLit (union_all(map pack_sort tvars_srts))}
   368    end;
   369 
   370 
   371 (**** Isabelle class relations ****)
   372 
   373 datatype classrel_clause =
   374          ClassrelClause of {axiom_name: axiom_name,
   375                             subclass: class,
   376                             superclass: class};
   377 
   378 (*Generate all pairs (sub,super) such that sub is a proper subclass of super in theory thy.*)
   379 fun class_pairs thy [] supers = []
   380   | class_pairs thy subs supers =
   381       let
   382         val class_less = Sorts.class_less (Sign.classes_of thy)
   383         fun add_super sub super = class_less (sub, super) ? cons (sub, super)
   384         fun add_supers sub = fold (add_super sub) supers
   385       in fold add_supers subs [] end
   386 
   387 fun make_classrel_clause (sub,super) =
   388   ClassrelClause {axiom_name = clrelclause_prefix ^ ascii_of sub ^ "_" ^ ascii_of super,
   389                   subclass = make_type_class sub,
   390                   superclass = make_type_class super};
   391 
   392 fun make_classrel_clauses thy subs supers =
   393   map make_classrel_clause (class_pairs thy subs supers);
   394 
   395 
   396 (** Isabelle arities **)
   397 
   398 fun arity_clause dfg _ _ (tcons, []) = []
   399   | arity_clause dfg seen n (tcons, ("HOL.type",_)::ars) =  (*ignore*)
   400       arity_clause dfg seen n (tcons,ars)
   401   | arity_clause dfg seen n (tcons, (ar as (class,_)) :: ars) =
   402       if class mem_string seen then (*multiple arities for the same tycon, class pair*)
   403           make_axiom_arity_clause dfg (tcons, lookup_type_const dfg tcons ^ "_" ^ class ^ "_" ^ Int.toString n, ar) ::
   404           arity_clause dfg seen (n+1) (tcons,ars)
   405       else
   406           make_axiom_arity_clause dfg (tcons, lookup_type_const dfg tcons ^ "_" ^ class, ar) ::
   407           arity_clause dfg (class::seen) n (tcons,ars)
   408 
   409 fun multi_arity_clause dfg [] = []
   410   | multi_arity_clause dfg ((tcons, ars) :: tc_arlists) =
   411       arity_clause dfg [] 1 (tcons, ars) @ multi_arity_clause dfg tc_arlists
   412 
   413 (*Generate all pairs (tycon,class,sorts) such that tycon belongs to class in theory thy
   414   provided its arguments have the corresponding sorts.*)
   415 fun type_class_pairs thy tycons classes =
   416   let val alg = Sign.classes_of thy
   417       fun domain_sorts tycon = Sorts.mg_domain alg tycon o single
   418       fun add_class tycon class =
   419         cons (class, domain_sorts tycon class)
   420         handle Sorts.CLASS_ERROR _ => I
   421       fun try_classes tycon = (tycon, fold (add_class tycon) classes [])
   422   in  map try_classes tycons  end;
   423 
   424 (*Proving one (tycon, class) membership may require proving others, so iterate.*)
   425 fun iter_type_class_pairs thy tycons [] = ([], [])
   426   | iter_type_class_pairs thy tycons classes =
   427       let val cpairs = type_class_pairs thy tycons classes
   428           val newclasses = union_all (union_all (union_all (map (map #2 o #2) cpairs)))
   429             |> subtract (op =) classes |> subtract (op =) HOLogic.typeS
   430           val (classes', cpairs') = iter_type_class_pairs thy tycons newclasses
   431       in (union (op =) classes' classes, union (op =) cpairs' cpairs) end;
   432 
   433 fun make_arity_clauses_dfg dfg thy tycons classes =
   434   let val (classes', cpairs) = iter_type_class_pairs thy tycons classes
   435   in  (classes', multi_arity_clause dfg cpairs)  end;
   436 val make_arity_clauses = make_arity_clauses_dfg false;
   437 
   438 (**** Find occurrences of predicates in clauses ****)
   439 
   440 (*FIXME: multiple-arity checking doesn't work, as update_new is the wrong
   441   function (it flags repeated declarations of a function, even with the same arity)*)
   442 
   443 fun update_many keypairs = fold Symtab.update keypairs
   444 
   445 val add_type_sort_preds = update_many o map pred_of_sort o sorts_on_typs
   446 
   447 fun add_classrel_clause_preds (ClassrelClause {subclass, superclass, ...}) =
   448   Symtab.update (subclass, 1) #> Symtab.update (superclass, 1)
   449 
   450 fun class_of_arityLit (TConsLit (tclass, _, _)) = tclass
   451   | class_of_arityLit (TVarLit (tclass, _)) = tclass;
   452 
   453 fun add_arity_clause_preds (ArityClause {conclLit, premLits, ...}) =
   454   let
   455     val classes = map (make_type_class o class_of_arityLit)
   456                       (conclLit :: premLits)
   457   in fold (Symtab.update o rpair 1) classes end;
   458 
   459 (*** Find occurrences of functions in clauses ***)
   460 
   461 fun add_fol_type_funcs (TyVar _) = I
   462   | add_fol_type_funcs (TyFree (s, _)) = Symtab.update (s, 0)
   463   | add_fol_type_funcs (TyConstr ((s, _), tys)) =
   464     Symtab.update (s, length tys) #> fold add_fol_type_funcs tys
   465 
   466 (*TFrees are recorded as constants*)
   467 fun add_type_sort_funcs (TVar _, funcs) = funcs
   468   | add_type_sort_funcs (TFree (a, _), funcs) =
   469       Symtab.update (make_fixed_type_var a, 0) funcs
   470 
   471 fun add_arity_clause_funcs (ArityClause {conclLit,...}) funcs =
   472   let val TConsLit (_, tcons, tvars) = conclLit
   473   in  Symtab.update (tcons, length tvars) funcs  end;
   474 
   475 (*This type can be overlooked because it is built-in...*)
   476 val init_functab = Symtab.update ("tc_itself", 1) Symtab.empty;
   477 
   478 
   479 (**** String-oriented operations ****)
   480 
   481 fun string_of_clausename (cls_id,ax_name) =
   482     clause_prefix ^ ascii_of ax_name ^ "_" ^ Int.toString cls_id;
   483 
   484 fun string_of_type_clsname (cls_id,ax_name,idx) =
   485     string_of_clausename (cls_id,ax_name) ^ "_tcs" ^ (Int.toString idx);
   486 
   487 
   488 (**** Producing DFG files ****)
   489 
   490 (*Attach sign in DFG syntax: false means negate.*)
   491 fun dfg_sign true s = s
   492   | dfg_sign false s = "not(" ^ s ^ ")"
   493 
   494 fun dfg_of_typeLit pos (LTVar (s,ty))  = dfg_sign pos (s ^ "(" ^ ty ^ ")")
   495   | dfg_of_typeLit pos (LTFree (s,ty)) = dfg_sign pos (s ^ "(" ^ ty ^ ")");
   496 
   497 (*Enclose the clause body by quantifiers, if necessary*)
   498 fun dfg_forall [] body = body
   499   | dfg_forall vars body = "forall([" ^ commas vars ^ "],\n" ^ body ^ ")"
   500 
   501 fun gen_dfg_cls (cls_id, ax_name, Axiom, lits, tylits, vars) =
   502       "clause( %(axiom)\n" ^
   503       dfg_forall vars ("or(" ^ commas (tylits@lits) ^ ")") ^ ",\n" ^
   504       string_of_clausename (cls_id,ax_name) ^  ").\n\n"
   505   | gen_dfg_cls (cls_id, ax_name, Conjecture, lits, _, vars) =
   506       "clause( %(negated_conjecture)\n" ^
   507       dfg_forall vars ("or(" ^ commas lits ^ ")") ^ ",\n" ^
   508       string_of_clausename (cls_id,ax_name) ^  ").\n\n";
   509 
   510 fun string_of_arity (name, num) =  "(" ^ name ^ "," ^ Int.toString num ^ ")"
   511 
   512 fun string_of_preds [] = ""
   513   | string_of_preds preds = "predicates[" ^ commas(map string_of_arity preds) ^ "].\n";
   514 
   515 fun string_of_funcs [] = ""
   516   | string_of_funcs funcs = "functions[" ^ commas(map string_of_arity funcs) ^ "].\n" ;
   517 
   518 fun string_of_symbols predstr funcstr =
   519   "list_of_symbols.\n" ^ predstr  ^ funcstr  ^ "end_of_list.\n\n";
   520 
   521 fun string_of_start name = "begin_problem(" ^ name ^ ").\n\n";
   522 
   523 fun string_of_descrip name =
   524   "list_of_descriptions.\nname({*" ^ name ^
   525   "*}).\nauthor({*Isabelle*}).\nstatus(unknown).\ndescription({*auto-generated*}).\nend_of_list.\n\n"
   526 
   527 fun dfg_tfree_clause tfree_lit =
   528   "clause( %(negated_conjecture)\n" ^ "or( " ^ tfree_lit ^ "),\n" ^ "tfree_tcs" ^ ").\n\n"
   529 
   530 fun dfg_of_arLit (TConsLit (c,t,args)) =
   531       dfg_sign true (make_type_class c ^ "(" ^ t ^ paren_pack args ^ ")")
   532   | dfg_of_arLit (TVarLit (c,str)) =
   533       dfg_sign false (make_type_class c ^ "(" ^ str ^ ")")
   534 
   535 fun dfg_classrelLits sub sup =  "not(" ^ sub ^ "(T)), " ^ sup ^ "(T)";
   536 
   537 fun dfg_classrel_clause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   538   "clause(forall([T],\nor( " ^ dfg_classrelLits subclass superclass ^ ")),\n" ^
   539   axiom_name ^ ").\n\n";
   540 
   541 fun string_of_ar axiom_name = arclause_prefix ^ ascii_of axiom_name;
   542 
   543 fun dfg_arity_clause (ArityClause{axiom_name,conclLit,premLits,...}) =
   544   let val TConsLit (_,_,tvars) = conclLit
   545       val lits = map dfg_of_arLit (conclLit :: premLits)
   546   in
   547       "clause( %(axiom)\n" ^
   548       dfg_forall tvars ("or( " ^ commas lits ^ ")") ^ ",\n" ^
   549       string_of_ar axiom_name ^ ").\n\n"
   550   end;
   551 
   552 
   553 (**** Produce TPTP files ****)
   554 
   555 fun tptp_sign true s = s
   556   | tptp_sign false s = "~ " ^ s
   557 
   558 fun tptp_of_typeLit pos (LTVar (s, ty))  = tptp_sign pos (s ^ "(" ^ ty ^ ")")
   559   | tptp_of_typeLit pos (LTFree (s, ty)) = tptp_sign pos (s ^ "(" ^ ty ^ ")")
   560 
   561 fun tptp_cnf name kind formula =
   562   "cnf(" ^ name ^ ", " ^ kind ^ ",\n    " ^ formula ^ ").\n"
   563 
   564 fun gen_tptp_cls (cls_id, ax_name, Axiom, lits, tylits) =
   565       tptp_cnf (string_of_clausename (cls_id, ax_name)) "axiom"
   566                (tptp_pack (tylits @ lits))
   567   | gen_tptp_cls (cls_id, ax_name, Conjecture, lits, _) =
   568       tptp_cnf (string_of_clausename (cls_id, ax_name)) "negated_conjecture"
   569                (tptp_pack lits)
   570 
   571 fun tptp_tfree_clause tfree_lit =
   572     tptp_cnf "tfree_tcs" "negated_conjecture" (tptp_pack [tfree_lit])
   573 
   574 fun tptp_of_arLit (TConsLit (c,t,args)) =
   575       tptp_sign true (make_type_class c ^ "(" ^ t ^ paren_pack args ^ ")")
   576   | tptp_of_arLit (TVarLit (c,str)) =
   577       tptp_sign false (make_type_class c ^ "(" ^ str ^ ")")
   578 
   579 fun tptp_arity_clause (ArityClause{axiom_name,conclLit,premLits,...}) =
   580   tptp_cnf (string_of_ar axiom_name) "axiom"
   581            (tptp_pack (map tptp_of_arLit (conclLit :: premLits)))
   582 
   583 fun tptp_classrelLits sub sup =
   584   let val tvar = "(T)"
   585   in  tptp_pack [tptp_sign false (sub^tvar), tptp_sign true (sup^tvar)]  end;
   586 
   587 fun tptp_classrel_clause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   588   tptp_cnf axiom_name "axiom" (tptp_classrelLits subclass superclass)
   589 
   590 end;