src/Pure/Isar/proof_context.ML
author wenzelm
Wed Mar 19 22:27:57 2008 +0100 (2008-03-19 ago)
changeset 26336 a0e2b706ce73
parent 26321 d875e70a94de
child 26346 17debd2fff8e
permissions -rw-r--r--
renamed datatype thmref to Facts.ref, tuned interfaces;
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The key concept of Isar proof contexts: elevates primitive local
     6 reasoning Gamma |- phi to a structured concept, with generic context
     7 elements.  See also structure Variable and Assumption.
     8 *)
     9 
    10 signature PROOF_CONTEXT =
    11 sig
    12   val theory_of: Proof.context -> theory
    13   val init: theory -> Proof.context
    14   type mode
    15   val mode_default: mode
    16   val mode_stmt: mode
    17   val mode_pattern: mode
    18   val mode_schematic: mode
    19   val mode_abbrev: mode
    20   val set_mode: mode -> Proof.context -> Proof.context
    21   val get_mode: Proof.context -> mode
    22   val restore_mode: Proof.context -> Proof.context -> Proof.context
    23   val set_stmt: bool -> Proof.context -> Proof.context
    24   val naming_of: Proof.context -> NameSpace.naming
    25   val full_name: Proof.context -> bstring -> string
    26   val consts_of: Proof.context -> Consts.T
    27   val const_syntax_name: Proof.context -> string -> string
    28   val the_const_constraint: Proof.context -> string -> typ
    29   val mk_const: Proof.context -> string * typ list -> term
    30   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    31   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    32   val facts_of: Proof.context -> Facts.T
    33   val transfer: theory -> Proof.context -> Proof.context
    34   val theory: (theory -> theory) -> Proof.context -> Proof.context
    35   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    36   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    37   val pretty_thm_legacy: thm -> Pretty.T
    38   val pretty_thm: Proof.context -> thm -> Pretty.T
    39   val pretty_thms: Proof.context -> thm list -> Pretty.T
    40   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    41   val pretty_proof: Proof.context -> Proofterm.proof -> Pretty.T
    42   val pretty_proof_of: Proof.context -> bool -> thm -> Pretty.T
    43   val string_of_thm: Proof.context -> thm -> string
    44   val read_typ: Proof.context -> string -> typ
    45   val read_typ_syntax: Proof.context -> string -> typ
    46   val read_typ_abbrev: Proof.context -> string -> typ
    47   val cert_typ: Proof.context -> typ -> typ
    48   val cert_typ_syntax: Proof.context -> typ -> typ
    49   val cert_typ_abbrev: Proof.context -> typ -> typ
    50   val get_skolem: Proof.context -> string -> string
    51   val revert_skolem: Proof.context -> string -> string
    52   val revert_skolems: Proof.context -> term -> term
    53   val infer_type: Proof.context -> string -> typ
    54   val inferred_param: string -> Proof.context -> (string * typ) * Proof.context
    55   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    56   val read_tyname: Proof.context -> string -> typ
    57   val read_const_proper: Proof.context -> string -> term
    58   val read_const: Proof.context -> string -> term
    59   val decode_term: Proof.context -> term -> term
    60   val standard_infer_types: Proof.context -> term list -> term list
    61   val read_term_pattern: Proof.context -> string -> term
    62   val read_term_schematic: Proof.context -> string -> term
    63   val read_term_abbrev: Proof.context -> string -> term
    64   val expand_abbrevs: Proof.context -> term -> term
    65   val cert_term: Proof.context -> term -> term
    66   val cert_prop: Proof.context -> term -> term
    67   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    68   val export: Proof.context -> Proof.context -> thm list -> thm list
    69   val export_morphism: Proof.context -> Proof.context -> morphism
    70   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    71   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    72   val auto_bind_goal: term list -> Proof.context -> Proof.context
    73   val auto_bind_facts: term list -> Proof.context -> Proof.context
    74   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    75   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    76   val read_propp: Proof.context * (string * string list) list list
    77     -> Proof.context * (term * term list) list list
    78   val cert_propp: Proof.context * (term * term list) list list
    79     -> Proof.context * (term * term list) list list
    80   val read_propp_schematic: Proof.context * (string * string list) list list
    81     -> Proof.context * (term * term list) list list
    82   val cert_propp_schematic: Proof.context * (term * term list) list list
    83     -> Proof.context * (term * term list) list list
    84   val bind_propp: Proof.context * (string * string list) list list
    85     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    86   val bind_propp_i: Proof.context * (term * term list) list list
    87     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    88   val bind_propp_schematic: Proof.context * (string * string list) list list
    89     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    90   val bind_propp_schematic_i: Proof.context * (term * term list) list list
    91     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    92   val fact_tac: thm list -> int -> tactic
    93   val some_fact_tac: Proof.context -> int -> tactic
    94   val get_thm: Proof.context -> Facts.ref -> thm
    95   val get_thms: Proof.context -> Facts.ref -> thm list
    96   val valid_thms: Proof.context -> string * thm list -> bool
    97   val add_path: string -> Proof.context -> Proof.context
    98   val no_base_names: Proof.context -> Proof.context
    99   val qualified_names: Proof.context -> Proof.context
   100   val sticky_prefix: string -> Proof.context -> Proof.context
   101   val restore_naming: Proof.context -> Proof.context -> Proof.context
   102   val reset_naming: Proof.context -> Proof.context
   103   val put_thms: bool -> string * thm list option -> Proof.context -> Proof.context
   104   val note_thmss: string ->
   105     ((bstring * attribute list) * (Facts.ref * attribute list) list) list ->
   106       Proof.context -> (bstring * thm list) list * Proof.context
   107   val note_thmss_i: string ->
   108     ((bstring * attribute list) * (thm list * attribute list) list) list ->
   109       Proof.context -> (bstring * thm list) list * Proof.context
   110   val read_vars: (string * string option * mixfix) list -> Proof.context ->
   111     (string * typ option * mixfix) list * Proof.context
   112   val cert_vars: (string * typ option * mixfix) list -> Proof.context ->
   113     (string * typ option * mixfix) list * Proof.context
   114   val add_fixes: (string * string option * mixfix) list ->
   115     Proof.context -> string list * Proof.context
   116   val add_fixes_i: (string * typ option * mixfix) list ->
   117     Proof.context -> string list * Proof.context
   118   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   119   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   120   val add_assms: Assumption.export ->
   121     ((string * attribute list) * (string * string list) list) list ->
   122     Proof.context -> (bstring * thm list) list * Proof.context
   123   val add_assms_i: Assumption.export ->
   124     ((string * attribute list) * (term * term list) list) list ->
   125     Proof.context -> (bstring * thm list) list * Proof.context
   126   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   127   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   128   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   129   val notation: bool -> Syntax.mode -> (term * mixfix) list -> Proof.context -> Proof.context
   130   val target_notation: bool -> Syntax.mode -> (term * mixfix) list -> morphism ->
   131     Context.generic -> Context.generic
   132   val add_const_constraint: string * typ option -> Proof.context -> Proof.context
   133   val add_abbrev: string -> Markup.property list ->
   134     bstring * term -> Proof.context -> (term * term) * Proof.context
   135   val revert_abbrev: string -> string -> Proof.context -> Proof.context
   136   val verbose: bool ref
   137   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   138   val print_syntax: Proof.context -> unit
   139   val print_abbrevs: Proof.context -> unit
   140   val print_binds: Proof.context -> unit
   141   val print_lthms: Proof.context -> unit
   142   val print_cases: Proof.context -> unit
   143   val debug: bool ref
   144   val prems_limit: int ref
   145   val pretty_ctxt: Proof.context -> Pretty.T list
   146   val pretty_context: Proof.context -> Pretty.T list
   147 end;
   148 
   149 structure ProofContext: PROOF_CONTEXT =
   150 struct
   151 
   152 val theory_of = Context.theory_of_proof;
   153 val init = Context.init_proof;
   154 
   155 
   156 (** inner syntax mode **)
   157 
   158 datatype mode =
   159   Mode of
   160    {stmt: bool,                (*inner statement mode*)
   161     pattern: bool,             (*pattern binding schematic variables*)
   162     schematic: bool,           (*term referencing loose schematic variables*)
   163     abbrev: bool};             (*abbrev mode -- no normalization*)
   164 
   165 fun make_mode (stmt, pattern, schematic, abbrev) =
   166   Mode {stmt = stmt, pattern = pattern, schematic = schematic, abbrev = abbrev};
   167 
   168 val mode_default   = make_mode (false, false, false, false);
   169 val mode_stmt      = make_mode (true, false, false, false);
   170 val mode_pattern   = make_mode (false, true, false, false);
   171 val mode_schematic = make_mode (false, false, true, false);
   172 val mode_abbrev    = make_mode (false, false, false, true);
   173 
   174 
   175 
   176 (** Isar proof context information **)
   177 
   178 datatype ctxt =
   179   Ctxt of
   180    {mode: mode,                                       (*inner syntax mode*)
   181     naming: NameSpace.naming,                         (*local naming conventions*)
   182     syntax: LocalSyntax.T,                            (*local syntax*)
   183     consts: Consts.T * Consts.T,                      (*local/global consts*)
   184     facts: Facts.T,                                   (*local facts*)
   185     cases: (string * (RuleCases.T * bool)) list};     (*named case contexts*)
   186 
   187 fun make_ctxt (mode, naming, syntax, consts, facts, cases) =
   188   Ctxt {mode = mode, naming = naming, syntax = syntax,
   189     consts = consts, facts = facts, cases = cases};
   190 
   191 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   192 
   193 structure ContextData = ProofDataFun
   194 (
   195   type T = ctxt;
   196   fun init thy =
   197     make_ctxt (mode_default, local_naming, LocalSyntax.init thy,
   198       (Sign.consts_of thy, Sign.consts_of thy), Facts.empty, []);
   199 );
   200 
   201 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   202 
   203 fun map_context f =
   204   ContextData.map (fn Ctxt {mode, naming, syntax, consts, facts, cases} =>
   205     make_ctxt (f (mode, naming, syntax, consts, facts, cases)));
   206 
   207 fun set_mode mode = map_context (fn (_, naming, syntax, consts, facts, cases) =>
   208   (mode, naming, syntax, consts, facts, cases));
   209 
   210 fun map_mode f =
   211   map_context (fn (Mode {stmt, pattern, schematic, abbrev}, naming, syntax, consts, facts, cases) =>
   212     (make_mode (f (stmt, pattern, schematic, abbrev)), naming, syntax, consts, facts, cases));
   213 
   214 fun map_naming f =
   215   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   216     (mode, f naming, syntax, consts, facts, cases));
   217 
   218 fun map_syntax f =
   219   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   220     (mode, naming, f syntax, consts, facts, cases));
   221 
   222 fun map_consts f =
   223   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   224     (mode, naming, syntax, f consts, facts, cases));
   225 
   226 fun map_facts f =
   227   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   228     (mode, naming, syntax, consts, f facts, cases));
   229 
   230 fun map_cases f =
   231   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   232     (mode, naming, syntax, consts, facts, f cases));
   233 
   234 val get_mode = #mode o rep_context;
   235 fun restore_mode ctxt = set_mode (get_mode ctxt);
   236 
   237 fun set_stmt stmt =
   238   map_mode (fn (_, pattern, schematic, abbrev) => (stmt, pattern, schematic, abbrev));
   239 
   240 val naming_of = #naming o rep_context;
   241 val full_name = NameSpace.full o naming_of;
   242 
   243 val syntax_of = #syntax o rep_context;
   244 val syn_of = LocalSyntax.syn_of o syntax_of;
   245 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   246 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   247 
   248 val consts_of = #1 o #consts o rep_context;
   249 val const_syntax_name = Consts.syntax_name o consts_of;
   250 val the_const_constraint = Consts.the_constraint o consts_of;
   251 
   252 fun mk_const ctxt (c, Ts) = Const (c, Consts.instance (consts_of ctxt) (c, Ts));
   253 
   254 val facts_of = #facts o rep_context;
   255 val cases_of = #cases o rep_context;
   256 
   257 
   258 (* theory transfer *)
   259 
   260 fun transfer_syntax thy =
   261   map_syntax (LocalSyntax.rebuild thy) #>
   262   map_consts (fn consts as (local_consts, global_consts) =>
   263     let val thy_consts = Sign.consts_of thy in
   264       if Consts.eq_consts (thy_consts, global_consts) then consts
   265       else (Consts.merge (local_consts, thy_consts), thy_consts)
   266     end);
   267 
   268 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   269 
   270 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   271 
   272 fun theory_result f ctxt =
   273   let val (res, thy') = f (theory_of ctxt)
   274   in (res, ctxt |> transfer thy') end;
   275 
   276 
   277 
   278 (** pretty printing **)
   279 
   280 fun pretty_term_abbrev ctxt = Syntax.pretty_term (set_mode mode_abbrev ctxt);
   281 
   282 fun pretty_thm_legacy th =
   283   let val thy = Thm.theory_of_thm th
   284   in Display.pretty_thm_aux (Syntax.pp (init thy)) true false [] th end;
   285 
   286 fun pretty_thm ctxt th =
   287   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   288   in Display.pretty_thm_aux (Syntax.pp ctxt) false true asms th end;
   289 
   290 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   291   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   292 
   293 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   294   | pretty_fact ctxt (a, [th]) =
   295       Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, pretty_thm ctxt th]
   296   | pretty_fact ctxt (a, ths) =
   297       Pretty.block (Pretty.fbreaks (Pretty.str (a ^ ":") :: map (pretty_thm ctxt) ths));
   298 
   299 fun pretty_proof ctxt prf =
   300   pretty_term_abbrev (ctxt |> transfer_syntax (ProofSyntax.proof_syntax prf (theory_of ctxt)))
   301     (ProofSyntax.term_of_proof prf);
   302 
   303 fun pretty_proof_of ctxt full th =
   304   pretty_proof ctxt (ProofSyntax.proof_of full th);
   305 
   306 val string_of_thm = Pretty.string_of oo pretty_thm;
   307 
   308 
   309 
   310 (** prepare types **)
   311 
   312 (* read_typ *)
   313 
   314 fun read_typ_mode mode ctxt s =
   315   Syntax.read_typ (Type.set_mode mode ctxt) s;
   316 
   317 val read_typ        = read_typ_mode Type.mode_default;
   318 val read_typ_syntax = read_typ_mode Type.mode_syntax;
   319 val read_typ_abbrev = read_typ_mode Type.mode_abbrev;
   320 
   321 
   322 (* cert_typ *)
   323 
   324 fun cert_typ_mode mode ctxt T =
   325   Sign.certify_typ_mode mode (theory_of ctxt) T
   326     handle TYPE (msg, _, _) => error msg;
   327 
   328 val cert_typ        = cert_typ_mode Type.mode_default;
   329 val cert_typ_syntax = cert_typ_mode Type.mode_syntax;
   330 val cert_typ_abbrev = cert_typ_mode Type.mode_abbrev;
   331 
   332 
   333 
   334 (** prepare variables **)
   335 
   336 (* internalize Skolem constants *)
   337 
   338 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   339 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   340 
   341 fun no_skolem internal x =
   342   if can Name.dest_skolem x then
   343     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   344   else if not internal andalso can Name.dest_internal x then
   345     error ("Illegal reference to internal variable: " ^ quote x)
   346   else x;
   347 
   348 
   349 (* revert Skolem constants -- approximation only! *)
   350 
   351 fun revert_skolem ctxt =
   352   let
   353     val rev_fixes = map Library.swap (Variable.fixes_of ctxt);
   354     val revert = AList.lookup (op =) rev_fixes;
   355   in
   356     fn x =>
   357       (case revert x of
   358         SOME x' => x'
   359       | NONE => perhaps (try Name.dest_skolem) x)
   360    end;
   361 
   362 fun revert_skolems ctxt =
   363   let
   364     val revert = revert_skolem ctxt;
   365     fun reverts (Free (x, T)) = Free (revert x, T)
   366       | reverts (t $ u) = reverts t $ reverts u
   367       | reverts (Abs (x, T, t)) = Abs (x, T, reverts t)
   368       | reverts a = a;
   369   in reverts end;
   370 
   371 
   372 
   373 (** prepare terms and propositions **)
   374 
   375 (* inferred types of parameters *)
   376 
   377 fun infer_type ctxt x =
   378   Term.fastype_of (singleton (Syntax.check_terms (set_mode mode_schematic ctxt))
   379     (Free (x, dummyT)));
   380 
   381 fun inferred_param x ctxt =
   382   let val T = infer_type ctxt x
   383   in ((x, T), ctxt |> Variable.declare_term (Free (x, T))) end;
   384 
   385 fun inferred_fixes ctxt =
   386   fold_map inferred_param (rev (map #2 (Variable.fixes_of ctxt))) ctxt;
   387 
   388 
   389 (* type and constant names *)
   390 
   391 fun read_tyname ctxt c =
   392   if Syntax.is_tid c then
   393     TFree (c, the_default (Sign.defaultS (theory_of ctxt)) (Variable.def_sort ctxt (c, ~1)))
   394   else
   395     let
   396       val thy = theory_of ctxt;
   397       val d = Sign.intern_type thy c;
   398     in Type (d, replicate (Sign.arity_number thy d) dummyT) end;
   399 
   400 fun read_const_proper ctxt c =
   401   (case Variable.lookup_const ctxt c of
   402     SOME d => Const (d, Consts.type_scheme (consts_of ctxt) d handle TYPE (msg, _, _) => error msg)
   403   | NONE => Consts.read_const (consts_of ctxt) c);
   404 
   405 fun read_const ctxt c =
   406   (case (lookup_skolem ctxt c, Variable.is_const ctxt c) of
   407     (SOME x, false) => Free (x, infer_type ctxt x)
   408   | _ => read_const_proper ctxt c);
   409 
   410 
   411 (* read_term *)
   412 
   413 fun read_term_mode mode ctxt = Syntax.read_term (set_mode mode ctxt);
   414 
   415 val read_term_pattern   = read_term_mode mode_pattern;
   416 val read_term_schematic = read_term_mode mode_schematic;
   417 val read_term_abbrev    = read_term_mode mode_abbrev;
   418 
   419 
   420 (* local abbreviations *)
   421 
   422 val tsig_of = Sign.tsig_of o ProofContext.theory_of;
   423 
   424 local
   425 
   426 fun certify_consts ctxt =
   427   let val Mode {abbrev, ...} = get_mode ctxt
   428   in Consts.certify (Syntax.pp ctxt) (tsig_of ctxt) (not abbrev) (consts_of ctxt) end;
   429 
   430 fun reject_schematic (Var (xi, _)) =
   431       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   432   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   433   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   434   | reject_schematic _ = ();
   435 
   436 fun expand_binds ctxt =
   437   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   438     if pattern then I
   439     else Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic)
   440   end;
   441 
   442 in
   443 
   444 fun expand_abbrevs ctxt = certify_consts ctxt #> expand_binds ctxt;
   445 
   446 end;
   447 
   448 
   449 fun contract_abbrevs ctxt t =
   450   let
   451     val thy = theory_of ctxt;
   452     val consts = consts_of ctxt;
   453     val Mode {abbrev, ...} = get_mode ctxt;
   454   in
   455     if abbrev orelse print_mode_active "no_abbrevs" orelse not (can Term.type_of t) then t
   456     else t |> Pattern.rewrite_term thy (Consts.abbrevs_of consts (print_mode_value () @ [""])) []
   457   end;
   458 
   459 
   460 (* patterns *)
   461 
   462 fun prepare_patternT ctxt =
   463   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   464     if pattern orelse schematic then I
   465     else Term.map_atyps
   466       (fn T as TVar (xi, _) =>
   467             if not (TypeInfer.is_param xi)
   468             then error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   469             else T
   470         | T => T)
   471   end;
   472 
   473 
   474 local
   475 
   476 fun prepare_dummies ts = #1 (fold_map Term.replace_dummy_patterns ts 1);
   477 
   478 fun reject_dummies t = Term.no_dummy_patterns t
   479   handle TERM _ => error "Illegal dummy pattern(s) in term";
   480 
   481 in
   482 
   483 fun prepare_patterns ctxt =
   484   let val Mode {pattern, ...} = get_mode ctxt in
   485     TypeInfer.fixate_params (Variable.names_of ctxt) #>
   486     pattern ? Variable.polymorphic ctxt #>
   487     (map o Term.map_types) (prepare_patternT ctxt) #>
   488     (if pattern then prepare_dummies else map reject_dummies)
   489   end;
   490 
   491 end;
   492 
   493 
   494 (* decoding raw terms (syntax trees) *)
   495 
   496 local
   497 
   498 fun intern_skolem ctxt def_type x =
   499   let
   500     val _ = no_skolem false x;
   501     val sko = lookup_skolem ctxt x;
   502     val is_const = can (read_const_proper ctxt) x orelse NameSpace.is_qualified x;
   503     val is_declared = is_some (def_type (x, ~1));
   504   in
   505     if Variable.is_const ctxt x then NONE
   506     else if is_some sko then sko
   507     else if not is_const orelse is_declared then SOME x
   508     else NONE
   509   end;
   510 
   511 in
   512 
   513 fun term_context ctxt =
   514   let val thy = theory_of ctxt in
   515    {get_sort = Sign.get_sort thy (Variable.def_sort ctxt),
   516     map_const = try (#1 o Term.dest_Const o read_const_proper ctxt),
   517     map_free = intern_skolem ctxt (Variable.def_type ctxt false),
   518     map_type = Sign.intern_tycons thy,
   519     map_sort = Sign.intern_sort thy}
   520   end;
   521 
   522 fun decode_term ctxt =
   523   let val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt
   524   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   525 
   526 end;
   527 
   528 
   529 (* certify terms *)
   530 
   531 local
   532 
   533 fun gen_cert prop ctxt t =
   534   t
   535   |> expand_abbrevs ctxt
   536   |> (fn t' => #1 (Sign.certify' prop (Syntax.pp ctxt) false (consts_of ctxt) (theory_of ctxt) t')
   537     handle TYPE (msg, _, _) => error msg
   538       | TERM (msg, _) => error msg);
   539 
   540 in
   541 
   542 val cert_term = gen_cert false;
   543 val cert_prop = gen_cert true;
   544 
   545 end;
   546 
   547 
   548 (* type checking/inference *)
   549 
   550 fun standard_infer_types ctxt ts =
   551   let val Mode {pattern, ...} = get_mode ctxt in
   552     TypeInfer.infer_types (Syntax.pp ctxt) (tsig_of ctxt) (Syntax.check_typs ctxt)
   553       (try (Consts.the_constraint (consts_of ctxt))) (Variable.def_type ctxt pattern)
   554       (Variable.names_of ctxt) (Variable.maxidx_of ctxt) NONE (map (rpair dummyT) ts)
   555     |> #1 |> map #1
   556     handle TYPE (msg, _, _) => error msg
   557   end;
   558 
   559 local
   560 
   561 fun standard_typ_check ctxt =
   562   map (cert_typ_mode (Type.get_mode ctxt) ctxt) #>
   563   map (prepare_patternT ctxt);
   564 
   565 fun standard_term_check ctxt =
   566   standard_infer_types ctxt #>
   567   map (expand_abbrevs ctxt);
   568 
   569 fun standard_term_uncheck ctxt =
   570   map (contract_abbrevs ctxt);
   571 
   572 fun add eq what f = Context.add_setup
   573   (Context.theory_map (what (fn xs => fn ctxt =>
   574     let val xs' = f ctxt xs in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end)));
   575 
   576 in
   577 
   578 val _ = add (op =) (Syntax.add_typ_check 0 "standard") standard_typ_check;
   579 val _ = add (op aconv) (Syntax.add_term_check 0 "standard") standard_term_check;
   580 val _ = add (op aconv) (Syntax.add_term_check 100 "fixate") prepare_patterns;
   581 
   582 val _ = add (op aconv) (Syntax.add_term_uncheck 0 "standard") standard_term_uncheck;
   583 
   584 end;
   585 
   586 
   587 
   588 (** inner syntax operations **)
   589 
   590 local
   591 
   592 fun parse_sort ctxt str =
   593   Syntax.standard_parse_sort ctxt (syn_of ctxt) (Sign.intern_sort (theory_of ctxt)) str;
   594 
   595 fun parse_typ ctxt str =
   596   let
   597     val thy = ProofContext.theory_of ctxt;
   598     val get_sort = Sign.get_sort thy (Variable.def_sort ctxt);
   599     val T = Sign.intern_tycons thy
   600       (Syntax.standard_parse_typ ctxt (syn_of ctxt) get_sort (Sign.intern_sort thy) str);
   601   in T end
   602   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   603 
   604 fun parse_term T ctxt str =
   605   let
   606     val thy = theory_of ctxt;
   607     val (T', _) = TypeInfer.paramify_dummies T 0;
   608     fun check t = (Syntax.check_term ctxt (TypeInfer.constrain T' t); NONE)
   609       handle ERROR msg => SOME msg;
   610     val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt;
   611     val read = Syntax.standard_parse_term (Syntax.pp ctxt) check get_sort
   612       map_const map_free map_type map_sort ctxt (Sign.is_logtype thy) (syn_of ctxt) T';
   613   in read str end;
   614 
   615 
   616 fun unparse_sort ctxt S =
   617   Syntax.standard_unparse_sort ctxt (syn_of ctxt) (Sign.extern_sort (theory_of ctxt) S);
   618 
   619 fun unparse_typ ctxt T =
   620   Syntax.standard_unparse_typ ctxt (syn_of ctxt) (Sign.extern_typ (theory_of ctxt) T);
   621 
   622 fun unparse_term ctxt t =
   623   let
   624     val thy = theory_of ctxt;
   625     val syntax = syntax_of ctxt;
   626     val consts = consts_of ctxt;
   627   in
   628     t
   629     |> Sign.extern_term (Consts.extern_early consts) thy
   630     |> LocalSyntax.extern_term syntax
   631     |> Syntax.standard_unparse_term (Consts.extern consts) ctxt (LocalSyntax.syn_of syntax)
   632         (Context.exists_name Context.CPureN thy)
   633   end;
   634 
   635 in
   636 
   637 val _ = Syntax.install_operations
   638   {parse_sort = parse_sort,
   639    parse_typ = parse_typ,
   640    parse_term = parse_term dummyT,
   641    parse_prop = parse_term propT,
   642    unparse_sort = unparse_sort,
   643    unparse_typ = unparse_typ,
   644    unparse_term = unparse_term};
   645 
   646 end;
   647 
   648 
   649 
   650 (** export results **)
   651 
   652 fun common_export is_goal inner outer =
   653   map (Assumption.export is_goal inner outer) #>
   654   Variable.export inner outer;
   655 
   656 val goal_export = common_export true;
   657 val export = common_export false;
   658 
   659 fun export_morphism inner outer =
   660   Assumption.export_morphism inner outer $>
   661   Variable.export_morphism inner outer;
   662 
   663 
   664 
   665 (** bindings **)
   666 
   667 (* simult_matches *)
   668 
   669 fun simult_matches ctxt (t, pats) =
   670   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   671     NONE => error "Pattern match failed!"
   672   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   673 
   674 
   675 (* add_binds(_i) *)
   676 
   677 local
   678 
   679 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   680   ctxt
   681   |> Variable.add_binds [(xi, Option.map (prep (set_mode mode_default ctxt)) raw_t)];
   682 
   683 in
   684 
   685 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   686   | drop_schematic b = b;
   687 
   688 val add_binds = fold (gen_bind Syntax.read_term);
   689 val add_binds_i = fold (gen_bind cert_term);
   690 
   691 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   692 val auto_bind_goal = auto_bind AutoBind.goal;
   693 val auto_bind_facts = auto_bind AutoBind.facts;
   694 
   695 end;
   696 
   697 
   698 (* match_bind(_i) *)
   699 
   700 local
   701 
   702 fun gen_bind prep_terms gen raw_binds ctxt =
   703   let
   704     fun prep_bind (raw_pats, t) ctxt1 =
   705       let
   706         val T = Term.fastype_of t;
   707         val ctxt2 = Variable.declare_term t ctxt1;
   708         val pats = prep_terms (set_mode mode_pattern ctxt2) T raw_pats;
   709         val binds = simult_matches ctxt2 (t, pats);
   710       in (binds, ctxt2) end;
   711 
   712     val ts = prep_terms ctxt dummyT (map snd raw_binds);
   713     val (binds, ctxt') = apfst flat (fold_map prep_bind (map fst raw_binds ~~ ts) ctxt);
   714     val binds' =
   715       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   716       else binds;
   717     val binds'' = map (apsnd SOME) binds';
   718     val ctxt'' =
   719       tap (Variable.warn_extra_tfrees ctxt)
   720        (if gen then
   721           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   722         else ctxt' |> add_binds_i binds'');
   723   in (ts, ctxt'') end;
   724 
   725 in
   726 
   727 fun read_terms ctxt T =
   728   map (Syntax.parse_term ctxt #> TypeInfer.constrain T) #> Syntax.check_terms ctxt;
   729 
   730 val match_bind = gen_bind read_terms;
   731 val match_bind_i = gen_bind (fn ctxt => fn _ => map (cert_term ctxt));
   732 
   733 end;
   734 
   735 
   736 (* propositions with patterns *)
   737 
   738 local
   739 
   740 fun prep_propp mode prep_props (context, args) =
   741   let
   742     fun prep (_, raw_pats) (ctxt, prop :: props) =
   743       let val ctxt' = Variable.declare_term prop ctxt
   744       in ((prop, prep_props (set_mode mode_pattern ctxt') raw_pats), (ctxt', props)) end;
   745 
   746     val (propp, (context', _)) = (fold_map o fold_map) prep args
   747       (context, prep_props (set_mode mode context) (maps (map fst) args));
   748   in (context', propp) end;
   749 
   750 fun gen_bind_propp mode parse_prop (ctxt, raw_args) =
   751   let
   752     val (ctxt', args) = prep_propp mode parse_prop (ctxt, raw_args);
   753     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   754     val propss = map (map #1) args;
   755 
   756     (*generalize result: context evaluated now, binds added later*)
   757     val gen = Variable.exportT_terms ctxt' ctxt;
   758     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   759   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   760 
   761 in
   762 
   763 val read_propp           = prep_propp mode_default Syntax.read_props;
   764 val cert_propp           = prep_propp mode_default (map o cert_prop);
   765 val read_propp_schematic = prep_propp mode_schematic Syntax.read_props;
   766 val cert_propp_schematic = prep_propp mode_schematic (map o cert_prop);
   767 
   768 val bind_propp             = gen_bind_propp mode_default Syntax.read_props;
   769 val bind_propp_i           = gen_bind_propp mode_default (map o cert_prop);
   770 val bind_propp_schematic   = gen_bind_propp mode_schematic Syntax.read_props;
   771 val bind_propp_schematic_i = gen_bind_propp mode_schematic (map o cert_prop);
   772 
   773 end;
   774 
   775 
   776 
   777 (** theorems **)
   778 
   779 (* fact_tac *)
   780 
   781 fun comp_incr_tac [] _ st = no_tac st
   782   | comp_incr_tac (th :: ths) i st =
   783       (Goal.compose_hhf_tac (Drule.incr_indexes st th) i APPEND comp_incr_tac ths i) st;
   784 
   785 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   786 
   787 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) =>
   788   fact_tac (Facts.could_unify (facts_of ctxt) (Term.strip_all_body goal)) i);
   789 
   790 
   791 (* get_thm(s) *)
   792 
   793 fun retrieve_thms _ pick ctxt (Facts.Fact s) =
   794       let
   795         val prop = Syntax.read_prop (set_mode mode_default ctxt) s
   796           |> singleton (Variable.polymorphic ctxt);
   797         val th = Goal.prove ctxt [] [] prop (K (ALLGOALS (some_fact_tac ctxt)))
   798           handle ERROR msg => cat_error msg "Failed to retrieve literal fact.";
   799       in pick "" [th] end
   800   | retrieve_thms from_thy pick ctxt xthmref =
   801       let
   802         val thy = theory_of ctxt;
   803         val local_facts = facts_of ctxt;
   804         val space = Facts.space_of local_facts;
   805         val thmref = Facts.map_name_of_ref (NameSpace.intern space) xthmref;
   806         val name = Facts.name_of_ref thmref;
   807         val thms =
   808           if name = "" then [Thm.transfer thy Drule.dummy_thm]
   809           else
   810             (case Facts.lookup local_facts name of
   811               SOME ths => map (Thm.transfer thy) (Facts.select thmref ths)
   812             | NONE => from_thy thy xthmref);
   813       in pick name thms end;
   814 
   815 val get_thm = retrieve_thms PureThy.get_thms Facts.the_single;
   816 val get_thms = retrieve_thms PureThy.get_thms (K I);
   817 val get_thms_silent = retrieve_thms PureThy.get_thms_silent (K I);
   818 
   819 
   820 (* valid_thms *)
   821 
   822 fun valid_thms ctxt (name, ths) =
   823   (case try (fn () => get_thms_silent ctxt (Facts.Named (name, NONE))) () of
   824     NONE => false
   825   | SOME ths' => Thm.eq_thms (ths, ths'));
   826 
   827 
   828 (* name space operations *)
   829 
   830 val add_path        = map_naming o NameSpace.add_path;
   831 val no_base_names   = map_naming NameSpace.no_base_names;
   832 val qualified_names = map_naming NameSpace.qualified_names;
   833 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   834 val restore_naming  = map_naming o K o naming_of;
   835 val reset_naming    = map_naming (K local_naming);
   836 
   837 
   838 (* facts *)
   839 
   840 fun update_thms _ (bname, NONE) ctxt = ctxt |> map_facts (Facts.del (full_name ctxt bname))
   841   | update_thms do_props (bname, SOME ths) ctxt = ctxt |> map_facts
   842       (Facts.add_local do_props (naming_of ctxt) (full_name ctxt bname, ths));
   843 
   844 fun put_thms do_props thms ctxt =
   845   ctxt |> map_naming (K local_naming) |> update_thms do_props thms |> restore_naming ctxt;
   846 
   847 local
   848 
   849 fun gen_note_thmss get k = fold_map (fn ((bname, more_attrs), raw_facts) => fn ctxt =>
   850   let
   851     val name = full_name ctxt bname;
   852     val facts = PureThy.name_thmss false name (map (apfst (get ctxt)) raw_facts);
   853     fun app (th, attrs) x =
   854       swap (foldl_map (Thm.proof_attributes (attrs @ more_attrs @ [PureThy.kind k])) (x, th));
   855     val (res, ctxt') = fold_map app facts ctxt;
   856     val thms = PureThy.name_thms false false name (flat res);
   857     val Mode {stmt, ...} = get_mode ctxt;
   858   in ((bname, thms), ctxt' |> update_thms stmt (bname, SOME thms)) end);
   859 
   860 in
   861 
   862 fun note_thmss k = gen_note_thmss get_thms k;
   863 fun note_thmss_i k = gen_note_thmss (K I) k;
   864 
   865 end;
   866 
   867 
   868 
   869 (** parameters **)
   870 
   871 (* variables *)
   872 
   873 fun declare_var (x, opt_T, mx) ctxt =
   874   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
   875   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
   876 
   877 local
   878 
   879 fun prep_vars prep_typ internal =
   880   fold_map (fn (raw_x, raw_T, raw_mx) => fn ctxt =>
   881     let
   882       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
   883       val _ = Syntax.is_identifier (no_skolem internal x) orelse
   884         error ("Illegal variable name: " ^ quote x);
   885 
   886       fun cond_tvars T =
   887         if internal then T
   888         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
   889       val opt_T = Option.map (cond_tvars o cert_typ ctxt o prep_typ ctxt) raw_T;
   890       val var = (x, opt_T, mx);
   891     in (var, ctxt |> declare_var var |> #2) end);
   892 
   893 in
   894 
   895 val read_vars = prep_vars Syntax.parse_typ false;
   896 val cert_vars = prep_vars (K I) true;
   897 
   898 end;
   899 
   900 
   901 (* authentic constants *)
   902 
   903 local
   904 
   905 fun const_ast_tr intern ctxt [Syntax.Variable c] =
   906       let
   907         val Const (c', _) = read_const_proper ctxt c;
   908         val d = if intern then const_syntax_name ctxt c' else c;
   909       in Syntax.Constant d end
   910   | const_ast_tr _ _ asts = raise Syntax.AST ("const_ast_tr", asts);
   911 
   912 in
   913 
   914 val _ = Context.add_setup
   915  (Sign.add_syntax
   916    [("_context_const", "id => 'a", Delimfix "CONST _"),
   917     ("_context_const", "longid => 'a", Delimfix "CONST _"),
   918     ("_context_xconst", "id => 'a", Delimfix "XCONST _"),
   919     ("_context_xconst", "longid => 'a", Delimfix "XCONST _")] #>
   920   Sign.add_advanced_trfuns
   921     ([("_context_const", const_ast_tr true), ("_context_xconst", const_ast_tr false)], [], [], []));
   922 
   923 end;
   924 
   925 
   926 (* notation *)
   927 
   928 local
   929 
   930 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
   931   | const_syntax ctxt (Const (c, _), mx) =
   932       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
   933   | const_syntax _ _ = NONE;
   934 
   935 in
   936 
   937 fun notation add mode args ctxt =
   938   ctxt |> map_syntax
   939     (LocalSyntax.update_modesyntax (theory_of ctxt) add mode (map_filter (const_syntax ctxt) args));
   940 
   941 fun target_notation add mode args phi =
   942   let val args' = filter (fn (t, _) => Type.similar_types (t, Morphism.term phi t)) args;
   943   in Context.mapping (Sign.notation add mode args') (notation add mode args') end;
   944 
   945 end;
   946 
   947 
   948 (* local constants *)
   949 
   950 fun add_const_constraint (c, opt_T) ctxt =
   951   let
   952     fun prepT raw_T =
   953       let val T = cert_typ ctxt raw_T
   954       in cert_term ctxt (Const (c, T)); T end;
   955   in ctxt |> (map_consts o apfst) (Consts.constrain (c, Option.map prepT opt_T)) end;
   956 
   957 fun add_abbrev mode tags (c, raw_t) ctxt =
   958   let
   959     val t0 = cert_term (ctxt |> set_mode mode_abbrev) raw_t
   960       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   961     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
   962     val ((lhs, rhs), consts') = consts_of ctxt
   963       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode tags (c, t);
   964   in
   965     ctxt
   966     |> (map_consts o apfst) (K consts')
   967     |> Variable.declare_term rhs
   968     |> pair (lhs, rhs)
   969   end;
   970 
   971 fun revert_abbrev mode c = (map_consts o apfst) (Consts.revert_abbrev mode c);
   972 
   973 
   974 (* fixes *)
   975 
   976 local
   977 
   978 fun prep_mixfix (x, T, mx) =
   979   if mx <> NoSyn andalso mx <> Structure andalso
   980       (can Name.dest_internal x orelse can Name.dest_skolem x) then
   981     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
   982   else (true, (x, T, mx));
   983 
   984 fun gen_fixes prep raw_vars ctxt =
   985   let
   986     val (vars, _) = prep raw_vars ctxt;
   987     val (xs', ctxt') = Variable.add_fixes (map #1 vars) ctxt;
   988   in
   989     ctxt'
   990     |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
   991     |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix)
   992     |> pair xs'
   993   end;
   994 
   995 in
   996 
   997 val add_fixes = gen_fixes read_vars;
   998 val add_fixes_i = gen_fixes cert_vars;
   999 
  1000 end;
  1001 
  1002 
  1003 (* fixes vs. frees *)
  1004 
  1005 fun auto_fixes (arg as (ctxt, (propss, x))) =
  1006   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
  1007 
  1008 fun bind_fixes xs ctxt =
  1009   let
  1010     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (x, NONE, NoSyn)) xs);
  1011     fun bind (t as Free (x, T)) =
  1012           if member (op =) xs x then
  1013             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1014           else t
  1015       | bind (t $ u) = bind t $ bind u
  1016       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1017       | bind a = a;
  1018   in (bind, ctxt') end;
  1019 
  1020 
  1021 
  1022 (** assumptions **)
  1023 
  1024 local
  1025 
  1026 fun gen_assms prepp exp args ctxt =
  1027   let
  1028     val cert = Thm.cterm_of (theory_of ctxt);
  1029     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1030     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1031     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1032   in
  1033     ctxt2
  1034     |> auto_bind_facts (flat propss)
  1035     |> put_thms false (AutoBind.premsN, SOME (Assumption.prems_of ctxt2))
  1036     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1037   end;
  1038 
  1039 in
  1040 
  1041 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1042 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1043 
  1044 end;
  1045 
  1046 
  1047 
  1048 (** cases **)
  1049 
  1050 local
  1051 
  1052 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1053 
  1054 fun add_case _ ("", _) cases = cases
  1055   | add_case _ (name, NONE) cases = rem_case name cases
  1056   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1057 
  1058 fun prep_case name fxs c =
  1059   let
  1060     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1061       | replace [] ys = ys
  1062       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1063     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1064     val fixes' = replace fxs fixes;
  1065     val binds' = map drop_schematic binds;
  1066   in
  1067     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1068       null (fold (fold Term.add_vars o snd) assumes []) then
  1069         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1070     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1071   end;
  1072 
  1073 fun fix (x, T) ctxt =
  1074   let
  1075     val (bind, ctxt') = bind_fixes [x] ctxt;
  1076     val t = bind (Free (x, T));
  1077   in (t, ctxt' |> Variable.declare_constraints t) end;
  1078 
  1079 in
  1080 
  1081 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1082 
  1083 fun case_result c ctxt =
  1084   let
  1085     val RuleCases.Case {fixes, ...} = c;
  1086     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1087     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1088   in
  1089     ctxt'
  1090     |> add_binds_i (map drop_schematic binds)
  1091     |> add_cases true (map (apsnd SOME) cases)
  1092     |> pair (assumes, (binds, cases))
  1093   end;
  1094 
  1095 val apply_case = apfst fst oo case_result;
  1096 
  1097 fun get_case ctxt name xs =
  1098   (case AList.lookup (op =) (cases_of ctxt) name of
  1099     NONE => error ("Unknown case: " ^ quote name)
  1100   | SOME (c, _) => prep_case name xs c);
  1101 
  1102 end;
  1103 
  1104 
  1105 
  1106 (** print context information **)
  1107 
  1108 val debug = ref false;
  1109 
  1110 val verbose = ref false;
  1111 fun verb f x = if ! verbose then f (x ()) else [];
  1112 
  1113 fun setmp_verbose f x = Library.setmp verbose true f x;
  1114 
  1115 
  1116 (* local syntax *)
  1117 
  1118 val print_syntax = Syntax.print_syntax o syn_of;
  1119 
  1120 
  1121 (* abbreviations *)
  1122 
  1123 fun pretty_abbrevs show_globals ctxt =
  1124   let
  1125     val ((space, consts), (_, globals)) =
  1126       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1127     fun add_abbr (_, (_, NONE)) = I
  1128       | add_abbr (c, (T, SOME t)) =
  1129           if not show_globals andalso Symtab.defined globals c then I
  1130           else cons (c, Logic.mk_equals (Const (c, T), t));
  1131     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1132   in
  1133     if null abbrevs andalso not (! verbose) then []
  1134     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1135   end;
  1136 
  1137 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1138 
  1139 
  1140 (* term bindings *)
  1141 
  1142 fun pretty_binds ctxt =
  1143   let
  1144     val binds = Variable.binds_of ctxt;
  1145     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1146   in
  1147     if Vartab.is_empty binds andalso not (! verbose) then []
  1148     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1149   end;
  1150 
  1151 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1152 
  1153 
  1154 (* local theorems *)
  1155 
  1156 fun pretty_lthms ctxt =
  1157   let
  1158     val local_facts = facts_of ctxt;
  1159     val props = Facts.props local_facts;
  1160     val facts = (if null props then I else cons ("unnamed", props)) (Facts.extern local_facts);
  1161   in
  1162     if null facts andalso not (! verbose) then []
  1163     else [Pretty.big_list "facts:" (map (pretty_fact ctxt) facts)]
  1164   end;
  1165 
  1166 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1167 
  1168 
  1169 (* local contexts *)
  1170 
  1171 fun pretty_cases ctxt =
  1172   let
  1173     val prt_term = Syntax.pretty_term ctxt;
  1174 
  1175     fun prt_let (xi, t) = Pretty.block
  1176       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1177         Pretty.quote (prt_term t)];
  1178 
  1179     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1180       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1181 
  1182     fun prt_sect _ _ _ [] = []
  1183       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1184             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1185 
  1186     fun prt_case (name, (fixes, (asms, (lets, cs)))) = Pretty.block (Pretty.fbreaks
  1187       (Pretty.str (name ^ ":") ::
  1188         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1189         prt_sect "let" [Pretty.str "and"] prt_let
  1190           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1191         (if forall (null o #2) asms then []
  1192           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1193         prt_sect "subcases:" [] (Pretty.str o fst) cs));
  1194 
  1195     fun add_case (_, (_, false)) = I
  1196       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1197           cons (name, (fixes, #1 (case_result c ctxt)));
  1198     val cases = fold add_case (cases_of ctxt) [];
  1199   in
  1200     if null cases andalso not (! verbose) then []
  1201     else [Pretty.big_list "cases:" (map prt_case cases)]
  1202   end;
  1203 
  1204 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1205 
  1206 
  1207 (* core context *)
  1208 
  1209 val prems_limit = ref ~1;
  1210 
  1211 fun pretty_ctxt ctxt =
  1212   if ! prems_limit < 0 andalso not (! debug) then []
  1213   else
  1214     let
  1215       val prt_term = Syntax.pretty_term ctxt;
  1216 
  1217       (*structures*)
  1218       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1219       val prt_structs = if null structs then []
  1220         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1221           Pretty.commas (map Pretty.str structs))];
  1222 
  1223       (*fixes*)
  1224       fun prt_fix (x, x') =
  1225         if x = x' then Pretty.str x
  1226         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1227       val fixes =
  1228         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1229           (Variable.fixes_of ctxt));
  1230       val prt_fixes = if null fixes then []
  1231         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1232           Pretty.commas (map prt_fix fixes))];
  1233 
  1234       (*prems*)
  1235       val prems = Assumption.prems_of ctxt;
  1236       val len = length prems;
  1237       val suppressed = len - ! prems_limit;
  1238       val prt_prems = if null prems then []
  1239         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1240           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1241     in prt_structs @ prt_fixes @ prt_prems end;
  1242 
  1243 
  1244 (* main context *)
  1245 
  1246 fun pretty_context ctxt =
  1247   let
  1248     val prt_term = Syntax.pretty_term ctxt;
  1249     val prt_typ = Syntax.pretty_typ ctxt;
  1250     val prt_sort = Syntax.pretty_sort ctxt;
  1251 
  1252     (*theory*)
  1253     val pretty_thy = Pretty.block
  1254       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1255 
  1256     (*defaults*)
  1257     fun prt_atom prt prtT (x, X) = Pretty.block
  1258       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1259 
  1260     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1261       | prt_var xi = prt_term (Syntax.var xi);
  1262 
  1263     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1264       | prt_varT xi = prt_typ (TVar (xi, []));
  1265 
  1266     val prt_defT = prt_atom prt_var prt_typ;
  1267     val prt_defS = prt_atom prt_varT prt_sort;
  1268 
  1269     val (types, sorts) = Variable.constraints_of ctxt;
  1270   in
  1271     verb single (K pretty_thy) @
  1272     pretty_ctxt ctxt @
  1273     verb (pretty_abbrevs false) (K ctxt) @
  1274     verb pretty_binds (K ctxt) @
  1275     verb pretty_lthms (K ctxt) @
  1276     verb pretty_cases (K ctxt) @
  1277     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1278     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1279   end;
  1280 
  1281 end;