src/Pure/Isar/attrib.ML
author wenzelm
Sat May 30 15:25:46 2009 +0200 (2009-05-30 ago)
changeset 31305 a16f4d4f5b24
parent 31177 c39994cb152a
child 31306 a74ee84288a0
permissions -rw-r--r--
modernized attribute setup;
removed obsolete no_args, add_del_args;
     1 (*  Title:      Pure/Isar/attrib.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Symbolic representation of attributes -- with name and syntax.
     5 *)
     6 
     7 signature ATTRIB =
     8 sig
     9   type src = Args.src
    10   type binding = binding * src list
    11   val empty_binding: binding
    12   val print_attributes: theory -> unit
    13   val intern: theory -> xstring -> string
    14   val intern_src: theory -> src -> src
    15   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    16   val defined: theory -> string -> bool
    17   val attribute: theory -> src -> attribute
    18   val attribute_i: theory -> src -> attribute
    19   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    20   val map_specs: ('a -> 'att) ->
    21     (('c * 'a list) * 'b) list -> (('c * 'att list) * 'b) list
    22   val map_facts: ('a -> 'att) ->
    23     (('c * 'a list) * ('d * 'a list) list) list ->
    24     (('c * 'att list) * ('d * 'att list) list) list
    25   val map_facts_refs: ('a -> 'att) -> ('b -> 'fact) ->
    26     (('c * 'a list) * ('b * 'a list) list) list ->
    27     (('c * 'att list) * ('fact * 'att list) list) list
    28   val crude_closure: Proof.context -> src -> src
    29   val add_attributes: (bstring * (src -> attribute) * string) list -> theory -> theory
    30   val syntax: attribute context_parser -> src -> attribute
    31   val setup: Binding.binding -> attribute context_parser -> string -> theory -> theory
    32   val attribute_setup: bstring * Position.T -> Symbol_Pos.text * Position.T -> string ->
    33     theory -> theory
    34   val add_del: attribute -> attribute -> attribute context_parser
    35   val thm_sel: Facts.interval list parser
    36   val thm: thm context_parser
    37   val thms: thm list context_parser
    38   val multi_thm: thm list context_parser
    39   val print_configs: Proof.context -> unit
    40   val internal: (morphism -> attribute) -> src
    41   val register_config: Config.value Config.T -> theory -> theory
    42   val config_bool: bstring -> bool -> bool Config.T * (theory -> theory)
    43   val config_int: bstring -> int -> int Config.T * (theory -> theory)
    44   val config_string: bstring -> string -> string Config.T * (theory -> theory)
    45   val config_bool_global: bstring -> bool -> bool Config.T * (theory -> theory)
    46   val config_int_global: bstring -> int -> int Config.T * (theory -> theory)
    47   val config_string_global: bstring -> string -> string Config.T * (theory -> theory)
    48 end;
    49 
    50 structure Attrib: ATTRIB =
    51 struct
    52 
    53 structure T = OuterLex;
    54 structure P = OuterParse;
    55 
    56 
    57 (* source and bindings *)
    58 
    59 type src = Args.src;
    60 
    61 type binding = binding * src list;
    62 val empty_binding: binding = (Binding.empty, []);
    63 
    64 
    65 
    66 (** named attributes **)
    67 
    68 (* theory data *)
    69 
    70 structure Attributes = TheoryDataFun
    71 (
    72   type T = (((src -> attribute) * string) * stamp) NameSpace.table;
    73   val empty = NameSpace.empty_table;
    74   val copy = I;
    75   val extend = I;
    76   fun merge _ tables : T = NameSpace.merge_tables (eq_snd (op =)) tables handle Symtab.DUP dup =>
    77     error ("Attempt to merge different versions of attribute " ^ quote dup);
    78 );
    79 
    80 fun print_attributes thy =
    81   let
    82     val attribs = Attributes.get thy;
    83     fun prt_attr (name, ((_, comment), _)) = Pretty.block
    84       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    85   in
    86     [Pretty.big_list "attributes:" (map prt_attr (NameSpace.extern_table attribs))]
    87     |> Pretty.chunks |> Pretty.writeln
    88   end;
    89 
    90 
    91 (* name space *)
    92 
    93 val intern = NameSpace.intern o #1 o Attributes.get;
    94 val intern_src = Args.map_name o intern;
    95 
    96 val extern = NameSpace.extern o #1 o Attributes.get o ProofContext.theory_of;
    97 
    98 
    99 (* pretty printing *)
   100 
   101 fun pretty_attribs _ [] = []
   102   | pretty_attribs ctxt srcs =
   103       [Pretty.enclose "[" "]"
   104         (Pretty.commas (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs))];
   105 
   106 
   107 (* get attributes *)
   108 
   109 val defined = Symtab.defined o #2 o Attributes.get;
   110 
   111 fun attribute_i thy =
   112   let
   113     val attrs = #2 (Attributes.get thy);
   114     fun attr src =
   115       let val ((name, _), pos) = Args.dest_src src in
   116         (case Symtab.lookup attrs name of
   117           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   118         | SOME ((att, _), _) => (Position.report (Markup.attribute name) pos; att src))
   119       end;
   120   in attr end;
   121 
   122 fun attribute thy = attribute_i thy o intern_src thy;
   123 
   124 fun eval_thms ctxt args = ProofContext.note_thmss Thm.generatedK
   125     [(Thm.empty_binding, args |> map (fn (a, atts) =>
   126         (ProofContext.get_fact ctxt a, map (attribute (ProofContext.theory_of ctxt)) atts)))] ctxt
   127   |> fst |> maps snd;
   128 
   129 
   130 (* attributed declarations *)
   131 
   132 fun map_specs f = map (apfst (apsnd (map f)));
   133 
   134 fun map_facts f = map (apfst (apsnd (map f)) o apsnd (map (apsnd (map f))));
   135 fun map_facts_refs f g = map_facts f #> map (apsnd (map (apfst g)));
   136 
   137 
   138 (* crude_closure *)
   139 
   140 (*Produce closure without knowing facts in advance! The following
   141   works reasonably well for attribute parsers that do not peek at the
   142   thm structure.*)
   143 
   144 fun crude_closure ctxt src =
   145  (try (fn () => attribute_i (ProofContext.theory_of ctxt) src
   146     (Context.Proof ctxt, Drule.asm_rl)) ();
   147   Args.closure src);
   148 
   149 
   150 (* add_attributes *)
   151 
   152 fun add_attributes raw_attrs thy =
   153   let
   154     val new_attrs =
   155       raw_attrs |> map (fn (name, att, comment) => (Binding.name name, ((att, comment), stamp ())));
   156     fun add attrs = fold (snd oo NameSpace.define (Sign.naming_of thy)) new_attrs attrs
   157       handle Symtab.DUP dup => error ("Duplicate declaration of attributes " ^ quote dup);
   158   in Attributes.map add thy end;
   159 
   160 
   161 (* attribute setup *)
   162 
   163 fun syntax scan src (context, th) =
   164   let val (f: attribute, context') = Args.syntax "attribute" scan src context
   165   in f (context', th) end;
   166 
   167 fun setup name scan comment = add_attributes [(Binding.name_of name, syntax scan, comment)];
   168 
   169 fun attribute_setup name (txt, pos) cmt =
   170   Context.theory_map (ML_Context.expression pos
   171     "val (name, scan, comment): binding * attribute context_parser * string"
   172     "Context.map_theory (Attrib.setup name scan comment)"
   173     ("(" ^ ML_Syntax.make_binding name ^ ", " ^ txt ^ ", " ^ ML_Syntax.print_string cmt ^ ")"));
   174 
   175 
   176 (* add/del syntax *)
   177 
   178 fun add_del add del = Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add);
   179 
   180 
   181 
   182 (** parsing attributed theorems **)
   183 
   184 val thm_sel = P.$$$ "(" |-- P.list1
   185  (P.nat --| P.minus -- P.nat >> Facts.FromTo ||
   186   P.nat --| P.minus >> Facts.From ||
   187   P.nat >> Facts.Single) --| P.$$$ ")";
   188 
   189 local
   190 
   191 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   192 
   193 fun gen_thm pick = Scan.depend (fn context =>
   194   let
   195     val thy = Context.theory_of context;
   196     val get = Context.cases (PureThy.get_fact context) ProofContext.get_fact context;
   197     val get_fact = get o Facts.Fact;
   198     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   199   in
   200     P.$$$ "[" |-- Args.attribs (intern thy) --| P.$$$ "]" >> (fn srcs =>
   201       let
   202         val atts = map (attribute_i thy) srcs;
   203         val (context', th') = Library.apply atts (context, Drule.dummy_thm);
   204       in (context', pick "" [th']) end)
   205     ||
   206     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   207       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   208      Scan.ahead (P.position fact_name) :|-- (fn (name, pos) =>
   209       Args.named_fact (get_named pos) -- Scan.option thm_sel
   210         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   211     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   212       let
   213         val ths = Facts.select thmref fact;
   214         val atts = map (attribute_i thy) srcs;
   215         val (context', ths') = Library.foldl_map (Library.apply atts) (context, ths);
   216       in (context', pick name ths') end)
   217   end);
   218 
   219 in
   220 
   221 val thm = gen_thm Facts.the_single;
   222 val multi_thm = gen_thm (K I);
   223 val thms = Scan.repeat multi_thm >> flat;
   224 
   225 end;
   226 
   227 
   228 
   229 (** basic attributes **)
   230 
   231 (* internal *)
   232 
   233 fun internal att = Args.src (("Pure.attribute", [T.mk_attribute att]), Position.none);
   234 
   235 
   236 (* rule composition *)
   237 
   238 val COMP_att =
   239   Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   240     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B)));
   241 
   242 val THEN_att =
   243   Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   244     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B)));
   245 
   246 val OF_att =
   247   thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A));
   248 
   249 
   250 (* rename_abs *)
   251 
   252 val rename_abs = Scan.repeat (Args.maybe Args.name) >> (apsnd o Drule.rename_bvars');
   253 
   254 
   255 (* unfold / fold definitions *)
   256 
   257 fun unfolded_syntax rule =
   258   thms >> (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths));
   259 
   260 val unfolded = unfolded_syntax LocalDefs.unfold;
   261 val folded = unfolded_syntax LocalDefs.fold;
   262 
   263 
   264 (* rule format *)
   265 
   266 val rule_format = Args.mode "no_asm"
   267   >> (fn true => ObjectLogic.rule_format_no_asm | false => ObjectLogic.rule_format);
   268 
   269 val elim_format = Thm.rule_attribute (K Tactic.make_elim);
   270 
   271 
   272 (* misc rules *)
   273 
   274 val no_vars = Thm.rule_attribute (fn context => fn th =>
   275   let
   276     val ctxt = Variable.set_body false (Context.proof_of context);
   277     val ((_, [th']), _) = Variable.import_thms true [th] ctxt;
   278   in th' end);
   279 
   280 val eta_long =
   281   Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion));
   282 
   283 val rotated = Scan.optional P.int 1 >> (fn n => Thm.rule_attribute (K (rotate_prems n)));
   284 
   285 
   286 (* theory setup *)
   287 
   288 val _ = Context.>> (Context.map_theory
   289  (setup (Binding.name "attribute") (Scan.lift Args.internal_attribute >> Morphism.form)
   290     "internal attribute" #>
   291   setup (Binding.name "tagged") (Scan.lift (Args.name -- Args.name) >> Thm.tag) "tagged theorem" #>
   292   setup (Binding.name "untagged") (Scan.lift Args.name >> Thm.untag) "untagged theorem" #>
   293   setup (Binding.name "kind") (Scan.lift Args.name >> Thm.kind) "theorem kind" #>
   294   setup (Binding.name "COMP") COMP_att "direct composition with rules (no lifting)" #>
   295   setup (Binding.name "THEN") THEN_att "resolution with rule" #>
   296   setup (Binding.name "OF") OF_att "rule applied to facts" #>
   297   setup (Binding.name "rename_abs") (Scan.lift rename_abs)
   298     "rename bound variables in abstractions" #>
   299   setup (Binding.name "unfolded") unfolded "unfolded definitions" #>
   300   setup (Binding.name "folded") folded "folded definitions" #>
   301   setup (Binding.name "consumes") (Scan.lift (Scan.optional P.nat 1) >> RuleCases.consumes)
   302     "number of consumed facts" #>
   303   setup (Binding.name "case_names") (Scan.lift (Scan.repeat1 Args.name) >> RuleCases.case_names)
   304     "named rule cases" #>
   305   setup (Binding.name "case_conclusion")
   306     (Scan.lift (Args.name -- Scan.repeat Args.name) >> RuleCases.case_conclusion)
   307     "named conclusion of rule cases" #>
   308   setup (Binding.name "params")
   309     (Scan.lift (P.and_list1 (Scan.repeat Args.name)) >> RuleCases.params)
   310     "named rule parameters" #>
   311   setup (Binding.name "standard") (Scan.succeed (Thm.rule_attribute (K Drule.standard)))
   312     "result put into standard form (legacy)" #>
   313   setup (Binding.name "rule_format") rule_format "result put into canonical rule format" #>
   314   setup (Binding.name "elim_format") (Scan.succeed elim_format)
   315     "destruct rule turned into elimination rule format" #>
   316   setup (Binding.name "no_vars") (Scan.succeed no_vars) "frozen schematic vars" #>
   317   setup (Binding.name "eta_long") (Scan.succeed eta_long)
   318     "put theorem into eta long beta normal form" #>
   319   setup (Binding.name "atomize") (Scan.succeed ObjectLogic.declare_atomize)
   320     "declaration of atomize rule" #>
   321   setup (Binding.name "rulify") (Scan.succeed ObjectLogic.declare_rulify)
   322     "declaration of rulify rule" #>
   323   setup (Binding.name "rotated") (Scan.lift rotated) "rotated theorem premises" #>
   324   setup (Binding.name "defn") (add_del LocalDefs.defn_add LocalDefs.defn_del)
   325     "declaration of definitional transformations" #>
   326   setup (Binding.name "abs_def") (Scan.succeed (Thm.rule_attribute (K Drule.abs_def)))
   327     "abstract over free variables of a definition"));
   328 
   329 
   330 
   331 (** configuration options **)
   332 
   333 (* naming *)
   334 
   335 structure Configs = TheoryDataFun
   336 (
   337   type T = Config.value Config.T Symtab.table;
   338   val empty = Symtab.empty;
   339   val copy = I;
   340   val extend = I;
   341   fun merge _ = Symtab.merge (K true);
   342 );
   343 
   344 fun print_configs ctxt =
   345   let
   346     val thy = ProofContext.theory_of ctxt;
   347     fun prt (name, config) =
   348       let val value = Config.get ctxt config in
   349         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   350           Pretty.str (Config.print_value value)]
   351       end;
   352     val configs = NameSpace.extern_table (#1 (Attributes.get thy), Configs.get thy);
   353   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   354 
   355 
   356 (* concrete syntax *)
   357 
   358 local
   359 
   360 val equals = P.$$$ "=";
   361 
   362 fun scan_value (Config.Bool _) =
   363       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   364       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   365       Scan.succeed (Config.Bool true)
   366   | scan_value (Config.Int _) = equals |-- P.int >> Config.Int
   367   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   368 
   369 fun scan_config thy config =
   370   let val config_type = Config.get_thy thy config
   371   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   372 
   373 in
   374 
   375 fun register_config config thy =
   376   let
   377     val bname = Config.name_of config;
   378     val name = Sign.full_bname thy bname;
   379   in
   380     thy
   381     |> add_attributes [(bname, syntax (Scan.lift (scan_config thy config) >> Morphism.form),
   382       "configuration option")]
   383     |> Configs.map (Symtab.update (name, config))
   384   end;
   385 
   386 fun declare_config make coerce global name default =
   387   let
   388     val config_value = Config.declare global name (make default);
   389     val config = coerce config_value;
   390   in (config, register_config config_value) end;
   391 
   392 val config_bool   = declare_config Config.Bool Config.bool false;
   393 val config_int    = declare_config Config.Int Config.int false;
   394 val config_string = declare_config Config.String Config.string false;
   395 
   396 val config_bool_global   = declare_config Config.Bool Config.bool true;
   397 val config_int_global    = declare_config Config.Int Config.int true;
   398 val config_string_global = declare_config Config.String Config.string true;
   399 
   400 end;
   401 
   402 
   403 (* theory setup *)
   404 
   405 val _ = Context.>> (Context.map_theory
   406  (register_config Unify.trace_bound_value #>
   407   register_config Unify.search_bound_value #>
   408   register_config Unify.trace_simp_value #>
   409   register_config Unify.trace_types_value #>
   410   register_config MetaSimplifier.simp_depth_limit_value));
   411 
   412 end;