src/Pure/Thy/thy_output.ML
author wenzelm
Wed Sep 12 13:21:33 2012 +0200 (2012-09-12 ago)
changeset 49321 a48f9bbbe720
parent 49244 fb669aff821e
child 49847 ed5080c03165
permissions -rw-r--r--
avoid spaces in markup names, which might cause problems in boundary situations (e.g. HTML class);
     1 (*  Title:      Pure/Thy/thy_output.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Theory document output with antiquotations.
     5 *)
     6 
     7 signature THY_OUTPUT =
     8 sig
     9   val display_default: bool Unsynchronized.ref
    10   val quotes_default: bool Unsynchronized.ref
    11   val indent_default: int Unsynchronized.ref
    12   val source_default: bool Unsynchronized.ref
    13   val break_default: bool Unsynchronized.ref
    14   val display: bool Config.T
    15   val quotes: bool Config.T
    16   val indent: int Config.T
    17   val source: bool Config.T
    18   val break: bool Config.T
    19   val add_wrapper: ((unit -> string) -> unit -> string) -> Proof.context -> Proof.context
    20   val add_option: binding -> (string -> Proof.context -> Proof.context) -> theory -> theory
    21   val intern_command: theory -> xstring -> string
    22   val defined_command: theory -> string -> bool
    23   val intern_option: theory -> xstring -> string
    24   val defined_option: theory -> string -> bool
    25   val print_antiquotations: Proof.context -> unit
    26   val antiquotation: binding -> 'a context_parser ->
    27     ({source: Args.src, state: Toplevel.state, context: Proof.context} -> 'a -> string) ->
    28       theory -> theory
    29   val boolean: string -> bool
    30   val integer: string -> int
    31   datatype markup = Markup | MarkupEnv | Verbatim
    32   val modes: string list Unsynchronized.ref
    33   val eval_antiq: Scan.lexicon -> Toplevel.state -> Symbol_Pos.T list * Position.range -> string
    34   val eval_antiquote: Scan.lexicon -> Toplevel.state -> Symbol_Pos.text * Position.T -> string
    35   val check_text: Symbol_Pos.text * Position.T -> Toplevel.state -> unit
    36   val present_thy: Scan.lexicon -> (string -> string list) -> (markup -> string -> bool) ->
    37     (Toplevel.transition * Toplevel.state) list -> Token.T list -> Buffer.T
    38   val pretty_text: Proof.context -> string -> Pretty.T
    39   val pretty_term: Proof.context -> term -> Pretty.T
    40   val pretty_thm: Proof.context -> thm -> Pretty.T
    41   val str_of_source: Args.src -> string
    42   val maybe_pretty_source: (Proof.context -> 'a -> Pretty.T) -> Proof.context ->
    43     Args.src -> 'a list -> Pretty.T list
    44   val output: Proof.context -> Pretty.T list -> string
    45   val verb_text: string -> string
    46 end;
    47 
    48 structure Thy_Output: THY_OUTPUT =
    49 struct
    50 
    51 (** global options **)
    52 
    53 val display_default = Unsynchronized.ref false;
    54 val quotes_default = Unsynchronized.ref false;
    55 val indent_default = Unsynchronized.ref 0;
    56 val source_default = Unsynchronized.ref false;
    57 val break_default = Unsynchronized.ref false;
    58 
    59 val display = Attrib.setup_config_bool (Binding.name "thy_output_display") (fn _ => ! display_default);
    60 val quotes = Attrib.setup_config_bool (Binding.name "thy_output_quotes") (fn _ => ! quotes_default);
    61 val indent = Attrib.setup_config_int (Binding.name "thy_output_indent") (fn _ => ! indent_default);
    62 val source = Attrib.setup_config_bool (Binding.name "thy_output_source") (fn _ => ! source_default);
    63 val break = Attrib.setup_config_bool (Binding.name "thy_output_break") (fn _ => ! break_default);
    64 
    65 
    66 structure Wrappers = Proof_Data
    67 (
    68   type T = ((unit -> string) -> unit -> string) list;
    69   fun init _ = [];
    70 );
    71 
    72 fun add_wrapper wrapper = Wrappers.map (cons wrapper);
    73 
    74 val wrap = Wrappers.get #> fold (fn wrapper => fn f => wrapper f);
    75 
    76 
    77 
    78 (** maintain global antiquotations **)
    79 
    80 structure Antiquotations = Theory_Data
    81 (
    82   type T =
    83     (Args.src -> Toplevel.state -> Proof.context -> string) Name_Space.table *
    84       (string -> Proof.context -> Proof.context) Name_Space.table;
    85   val empty : T =
    86     (Name_Space.empty_table Isabelle_Markup.document_antiquotationN,
    87       Name_Space.empty_table Isabelle_Markup.document_antiquotation_optionN);
    88   val extend = I;
    89   fun merge ((commands1, options1), (commands2, options2)) : T =
    90     (Name_Space.merge_tables (commands1, commands2),
    91       Name_Space.merge_tables (options1, options2));
    92 );
    93 
    94 fun add_command name cmd thy = thy
    95   |> Antiquotations.map (apfst (Name_Space.define (Context.Theory thy) true (name, cmd) #> snd));
    96 
    97 fun add_option name opt thy = thy
    98   |> Antiquotations.map (apsnd (Name_Space.define (Context.Theory thy) true (name, opt) #> snd));
    99 
   100 val intern_command = Name_Space.intern o #1 o #1 o Antiquotations.get;
   101 val defined_command = Symtab.defined o #2 o #1 o Antiquotations.get;
   102 
   103 val intern_option = Name_Space.intern o #1 o #2 o Antiquotations.get;
   104 val defined_option = Symtab.defined o #2 o #2 o Antiquotations.get;
   105 
   106 fun command src state ctxt =
   107   let
   108     val thy = Proof_Context.theory_of ctxt;
   109     val ((xname, _), pos) = Args.dest_src src;
   110     val (name, f) = Name_Space.check (Context.Proof ctxt) (#1 (Antiquotations.get thy)) (xname, pos);
   111   in
   112     f src state ctxt handle ERROR msg =>
   113       cat_error msg ("The error(s) above occurred in document antiquotation: " ^
   114         quote name ^ Position.here pos)
   115   end;
   116 
   117 fun option ((xname, pos), s) ctxt =
   118   let
   119     val thy = Proof_Context.theory_of ctxt;
   120     val (_, opt) = Name_Space.check (Context.Proof ctxt) (#2 (Antiquotations.get thy)) (xname, pos);
   121   in opt s ctxt end;
   122 
   123 fun print_antiquotations ctxt =
   124   let
   125     val thy = Proof_Context.theory_of ctxt;
   126     val (commands, options) = Antiquotations.get thy;
   127     val command_names = map #1 (Name_Space.extern_table ctxt commands);
   128     val option_names = map #1 (Name_Space.extern_table ctxt options);
   129   in
   130     [Pretty.big_list "document antiquotations:" (map Pretty.str command_names),
   131       Pretty.big_list "document antiquotation options:" (map Pretty.str option_names)]
   132     |> Pretty.chunks |> Pretty.writeln
   133   end;
   134 
   135 fun antiquotation name scan out =
   136   add_command name
   137     (fn src => fn state => fn ctxt =>
   138       let val (x, ctxt') = Args.context_syntax "document antiquotation" scan src ctxt
   139       in out {source = src, state = state, context = ctxt'} x end);
   140 
   141 
   142 
   143 (** syntax of antiquotations **)
   144 
   145 (* option values *)
   146 
   147 fun boolean "" = true
   148   | boolean "true" = true
   149   | boolean "false" = false
   150   | boolean s = error ("Bad boolean value: " ^ quote s);
   151 
   152 fun integer s =
   153   let
   154     fun int ss =
   155       (case Library.read_int ss of (i, []) => i
   156       | _ => error ("Bad integer value: " ^ quote s));
   157   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   158 
   159 
   160 (* outer syntax *)
   161 
   162 local
   163 
   164 val property =
   165   Parse.position Parse.xname -- Scan.optional (Parse.$$$ "=" |-- Parse.!!! Parse.xname) "";
   166 
   167 val properties =
   168   Scan.optional (Parse.$$$ "[" |-- Parse.!!! (Parse.enum "," property --| Parse.$$$ "]")) [];
   169 
   170 in
   171 
   172 val antiq =
   173   Parse.!!!
   174     (Parse.position Parse.liberal_name -- properties -- Args.parse --| Scan.ahead Parse.eof)
   175   >> (fn (((x, pos), y), z) => (y, Args.src ((x, z), pos)));
   176 
   177 end;
   178 
   179 
   180 (* eval_antiquote *)
   181 
   182 val modes = Unsynchronized.ref ([]: string list);
   183 
   184 fun eval_antiq lex state (ss, (pos, _)) =
   185   let
   186     val (opts, src) = Token.read_antiq lex antiq (ss, pos);
   187     fun cmd ctxt = wrap ctxt (fn () => command src state ctxt) ();
   188     val preview_ctxt = fold option opts (Toplevel.presentation_context_of state);
   189     val print_ctxt = Context_Position.set_visible false preview_ctxt;
   190     val _ = cmd preview_ctxt;
   191   in Print_Mode.with_modes (! modes @ Latex.modes) (fn () => cmd print_ctxt) () end;
   192 
   193 fun eval_antiquote lex state (txt, pos) =
   194   let
   195     fun expand (Antiquote.Text ss) = Symbol_Pos.content ss
   196       | expand (Antiquote.Antiq antiq) = eval_antiq lex state antiq
   197       | expand (Antiquote.Open _) = ""
   198       | expand (Antiquote.Close _) = "";
   199     val ants = Antiquote.read (Symbol_Pos.explode (txt, pos), pos);
   200   in
   201     if Toplevel.is_toplevel state andalso not (forall Antiquote.is_text ants) then
   202       error ("Unknown context -- cannot expand document antiquotations" ^ Position.here pos)
   203     else implode (map expand ants)
   204   end;
   205 
   206 
   207 fun check_text (txt, pos) state =
   208  (Position.report pos Isabelle_Markup.doc_source;
   209   ignore (eval_antiquote (#1 (Keyword.get_lexicons ())) state (txt, pos)));
   210 
   211 
   212 
   213 (** present theory source **)
   214 
   215 (*NB: arranging white space around command spans is a black art.*)
   216 
   217 (* presentation tokens *)
   218 
   219 datatype token =
   220     NoToken
   221   | BasicToken of Token.T
   222   | MarkupToken of string * (string * Position.T)
   223   | MarkupEnvToken of string * (string * Position.T)
   224   | VerbatimToken of string * Position.T;
   225 
   226 fun output_token lex state =
   227   let val eval = eval_antiquote lex state in
   228     fn NoToken => ""
   229      | BasicToken tok => Latex.output_basic tok
   230      | MarkupToken (cmd, txt) => Latex.output_markup cmd (eval txt)
   231      | MarkupEnvToken (cmd, txt) => Latex.output_markup_env cmd (eval txt)
   232      | VerbatimToken txt => Latex.output_verbatim (eval txt)
   233   end;
   234 
   235 fun basic_token pred (BasicToken tok) = pred tok
   236   | basic_token _ _ = false;
   237 
   238 val improper_token = basic_token (not o Token.is_proper);
   239 val comment_token = basic_token Token.is_comment;
   240 val blank_token = basic_token Token.is_blank;
   241 val newline_token = basic_token Token.is_newline;
   242 
   243 
   244 (* command spans *)
   245 
   246 type command = string * Position.T * string list;   (*name, position, tags*)
   247 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   248 
   249 datatype span = Span of command * (source * source * source * source) * bool;
   250 
   251 fun make_span cmd src =
   252   let
   253     fun take_newline (tok :: toks) =
   254           if newline_token (fst tok) then ([tok], toks, true)
   255           else ([], tok :: toks, false)
   256       | take_newline [] = ([], [], false);
   257     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   258       src
   259       |> take_prefix (improper_token o fst)
   260       ||>> take_suffix (improper_token o fst)
   261       ||>> take_prefix (comment_token o fst)
   262       ||> take_newline;
   263   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   264 
   265 
   266 (* present spans *)
   267 
   268 local
   269 
   270 fun err_bad_nesting pos =
   271   error ("Bad nesting of commands in presentation" ^ pos);
   272 
   273 fun edge which f (x: string option, y) =
   274   if x = y then I
   275   else (case which (x, y) of NONE => I | SOME txt => Buffer.add (f txt));
   276 
   277 val begin_tag = edge #2 Latex.begin_tag;
   278 val end_tag = edge #1 Latex.end_tag;
   279 fun open_delim delim e = edge #2 Latex.begin_delim e #> delim #> edge #2 Latex.end_delim e;
   280 fun close_delim delim e = edge #1 Latex.begin_delim e #> delim #> edge #1 Latex.end_delim e;
   281 
   282 in
   283 
   284 fun present_span lex default_tags span state state'
   285     (tag_stack, active_tag, newline, buffer, present_cont) =
   286   let
   287     val present = fold (fn (tok, (flag, 0)) =>
   288         Buffer.add (output_token lex state' tok)
   289         #> Buffer.add flag
   290       | _ => I);
   291 
   292     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   293 
   294     val (tag, tags) = tag_stack;
   295     val tag' = try hd (fold (update (op =)) cmd_tags (the_list tag));
   296 
   297     val active_tag' =
   298       if is_some tag' then tag'
   299       else if cmd_name = "end" andalso not (Toplevel.is_toplevel state') then NONE
   300       else try hd (default_tags cmd_name);
   301     val edge = (active_tag, active_tag');
   302 
   303     val newline' =
   304       if is_none active_tag' then span_newline else newline;
   305 
   306     val nesting = Toplevel.level state' - Toplevel.level state;
   307     val tag_stack' =
   308       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   309       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   310       else
   311         (case drop (~ nesting - 1) tags of
   312           tgs :: tgss => (tgs, tgss)
   313         | [] => err_bad_nesting (Position.here cmd_pos));
   314 
   315     val buffer' =
   316       buffer
   317       |> end_tag edge
   318       |> close_delim (fst present_cont) edge
   319       |> snd present_cont
   320       |> open_delim (present (#1 srcs)) edge
   321       |> begin_tag edge
   322       |> present (#2 srcs);
   323     val present_cont' =
   324       if newline then (present (#3 srcs), present (#4 srcs))
   325       else (I, present (#3 srcs) #> present (#4 srcs));
   326   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   327 
   328 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   329   if not (null tags) then err_bad_nesting " at end of theory"
   330   else
   331     buffer
   332     |> end_tag (active_tag, NONE)
   333     |> close_delim (fst present_cont) (active_tag, NONE)
   334     |> snd present_cont;
   335 
   336 end;
   337 
   338 
   339 (* present_thy *)
   340 
   341 datatype markup = Markup | MarkupEnv | Verbatim;
   342 
   343 local
   344 
   345 val space_proper =
   346   Scan.one Token.is_blank -- Scan.many Token.is_comment -- Scan.one Token.is_proper;
   347 
   348 val is_improper = not o (Token.is_proper orf Token.is_begin_ignore orf Token.is_end_ignore);
   349 val improper = Scan.many is_improper;
   350 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   351 val blank_end = Scan.repeat (Scan.unless space_proper (Scan.one Token.is_blank));
   352 
   353 val opt_newline = Scan.option (Scan.one Token.is_newline);
   354 
   355 val ignore =
   356   Scan.depend (fn d => opt_newline |-- Scan.one Token.is_begin_ignore
   357     >> pair (d + 1)) ||
   358   Scan.depend (fn d => Scan.one Token.is_end_ignore --|
   359     (if d = 0 then Scan.fail_with (K (fn () => "Bad nesting of meta-comments")) else opt_newline)
   360     >> pair (d - 1));
   361 
   362 val tag = (improper -- Parse.$$$ "%" -- improper) |-- Parse.!!! (Parse.tag_name --| blank_end);
   363 
   364 val locale =
   365   Scan.option ((Parse.$$$ "(" -- improper -- Parse.$$$ "in") |--
   366     Parse.!!! (improper |-- Parse.xname --| (improper -- Parse.$$$ ")")));
   367 
   368 in
   369 
   370 fun present_thy lex default_tags is_markup command_results toks =
   371   let
   372     (* tokens *)
   373 
   374     val ignored = Scan.state --| ignore
   375       >> (fn d => (NONE, (NoToken, ("", d))));
   376 
   377     fun markup mark mk flag = Scan.peek (fn d =>
   378       improper |--
   379         Parse.position (Scan.one (Token.is_command andf is_markup mark o Token.content_of)) --
   380       Scan.repeat tag --
   381       Parse.!!!! ((improper -- locale -- improper) |-- Parse.doc_source --| improper_end)
   382       >> (fn (((tok, pos), tags), txt) =>
   383         let val name = Token.content_of tok
   384         in (SOME (name, pos, tags), (mk (name, txt), (flag, d))) end));
   385 
   386     val command = Scan.peek (fn d =>
   387       Parse.position (Scan.one (Token.is_command)) --
   388       Scan.repeat tag
   389       >> (fn ((tok, pos), tags) =>
   390         let val name = Token.content_of tok
   391         in (SOME (name, pos, tags), (BasicToken tok, (Latex.markup_false, d))) end));
   392 
   393     val cmt = Scan.peek (fn d =>
   394       Parse.$$$ "--" |-- Parse.!!!! (improper |-- Parse.doc_source)
   395       >> (fn txt => (NONE, (MarkupToken ("cmt", txt), ("", d)))));
   396 
   397     val other = Scan.peek (fn d =>
   398        Parse.not_eof >> (fn tok => (NONE, (BasicToken tok, ("", d)))));
   399 
   400     val token =
   401       ignored ||
   402       markup Markup MarkupToken Latex.markup_true ||
   403       markup MarkupEnv MarkupEnvToken Latex.markup_true ||
   404       markup Verbatim (VerbatimToken o #2) "" ||
   405       command || cmt || other;
   406 
   407 
   408     (* spans *)
   409 
   410     val is_eof = fn (_, (BasicToken x, _)) => Token.is_eof x | _ => false;
   411     val stopper = Scan.stopper (K (NONE, (BasicToken Token.eof, ("", 0)))) is_eof;
   412 
   413     val cmd = Scan.one (is_some o fst);
   414     val non_cmd = Scan.one (is_none o fst andf not o is_eof) >> #2;
   415 
   416     val comments = Scan.many (comment_token o fst o snd);
   417     val blank = Scan.one (blank_token o fst o snd);
   418     val newline = Scan.one (newline_token o fst o snd);
   419     val before_cmd =
   420       Scan.option (newline -- comments) --
   421       Scan.option (newline -- comments) --
   422       Scan.option (blank -- comments) -- cmd;
   423 
   424     val span =
   425       Scan.repeat non_cmd -- cmd --
   426         Scan.repeat (Scan.unless before_cmd non_cmd) --
   427         Scan.option (newline >> (single o snd))
   428       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   429           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   430 
   431     val spans =
   432       Source.of_list (filter_out Token.is_semicolon toks)
   433       |> Source.source' 0 Token.stopper (Scan.error (Scan.bulk token)) NONE
   434       |> Source.source stopper (Scan.error (Scan.bulk span)) NONE
   435       |> Source.exhaust;
   436 
   437 
   438     (* present commands *)
   439 
   440     fun present_command tr span st st' =
   441       Toplevel.setmp_thread_position tr (present_span lex default_tags span st st');
   442 
   443     fun present _ [] = I
   444       | present st (((tr, st'), span) :: rest) = present_command tr span st st' #> present st' rest;
   445   in
   446     if length command_results = length spans then
   447       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   448       |> present Toplevel.toplevel (command_results ~~ spans)
   449       |> present_trailer
   450     else error "Messed-up outer syntax for presentation"
   451   end;
   452 
   453 end;
   454 
   455 
   456 
   457 (** setup default output **)
   458 
   459 (* options *)
   460 
   461 val _ =
   462   Context.>> (Context.map_theory
   463    (add_option (Binding.name "show_types") (Config.put show_types o boolean) #>
   464     add_option (Binding.name "show_sorts") (Config.put show_sorts o boolean) #>
   465     add_option (Binding.name "show_structs") (Config.put show_structs o boolean) #>
   466     add_option (Binding.name "show_question_marks") (Config.put show_question_marks o boolean) #>
   467     add_option (Binding.name "show_abbrevs") (Config.put show_abbrevs o boolean) #>
   468     add_option (Binding.name "names_long") (Config.put Name_Space.names_long o boolean) #>
   469     add_option (Binding.name "names_short") (Config.put Name_Space.names_short o boolean) #>
   470     add_option (Binding.name "names_unique") (Config.put Name_Space.names_unique o boolean) #>
   471     add_option (Binding.name "eta_contract") (Config.put Syntax_Trans.eta_contract o boolean) #>
   472     add_option (Binding.name "display") (Config.put display o boolean) #>
   473     add_option (Binding.name "break") (Config.put break o boolean) #>
   474     add_option (Binding.name "quotes") (Config.put quotes o boolean) #>
   475     add_option (Binding.name "mode") (add_wrapper o Print_Mode.with_modes o single) #>
   476     add_option (Binding.name "margin") (add_wrapper o setmp_CRITICAL Pretty.margin_default o integer) #>
   477     add_option (Binding.name "indent") (Config.put indent o integer) #>
   478     add_option (Binding.name "source") (Config.put source o boolean) #>
   479     add_option (Binding.name "goals_limit") (Config.put Goal_Display.goals_limit o integer)));
   480 
   481 
   482 (* basic pretty printing *)
   483 
   484 fun tweak_line ctxt s =
   485   if Config.get ctxt display then s else Symbol.strip_blanks s;
   486 
   487 fun pretty_text ctxt =
   488   Pretty.chunks o map Pretty.str o map (tweak_line ctxt) o split_lines;
   489 
   490 fun pretty_term ctxt t = Syntax.pretty_term (Variable.auto_fixes t ctxt) t;
   491 
   492 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   493 
   494 fun pretty_term_style ctxt (style, t) =
   495   pretty_term ctxt (style t);
   496 
   497 fun pretty_thm_style ctxt (style, th) =
   498   pretty_term ctxt (style (Thm.full_prop_of th));
   499 
   500 fun pretty_term_typ ctxt (style, t) =
   501   let val t' = style t
   502   in pretty_term ctxt (Type.constraint (Term.fastype_of t') t') end;
   503 
   504 fun pretty_term_typeof ctxt (style, t) =
   505   Syntax.pretty_typ ctxt (Term.fastype_of (style t));
   506 
   507 fun pretty_const ctxt c =
   508   let
   509     val t = Const (c, Consts.type_scheme (Proof_Context.consts_of ctxt) c)
   510       handle TYPE (msg, _, _) => error msg;
   511     val ([t'], _) = Variable.import_terms true [t] ctxt;
   512   in pretty_term ctxt t' end;
   513 
   514 fun pretty_abbrev ctxt s =
   515   let
   516     val t = Syntax.read_term (Proof_Context.set_mode Proof_Context.mode_abbrev ctxt) s;
   517     fun err () = error ("Abbreviated constant expected: " ^ Syntax.string_of_term ctxt t);
   518     val (head, args) = Term.strip_comb t;
   519     val (c, T) = Term.dest_Const head handle TERM _ => err ();
   520     val (U, u) = Consts.the_abbreviation (Proof_Context.consts_of ctxt) c
   521       handle TYPE _ => err ();
   522     val t' = Term.betapplys (Envir.expand_atom T (U, u), args);
   523     val eq = Logic.mk_equals (t, t');
   524     val ctxt' = Variable.auto_fixes eq ctxt;
   525   in Proof_Context.pretty_term_abbrev ctxt' eq end;
   526 
   527 fun pretty_class ctxt =
   528   Pretty.str o Proof_Context.extern_class ctxt o Proof_Context.read_class ctxt;
   529 
   530 fun pretty_type ctxt s =
   531   let val Type (name, _) = Proof_Context.read_type_name_proper ctxt false s
   532   in Pretty.str (Proof_Context.extern_type ctxt name) end;
   533 
   534 fun pretty_prf full ctxt = Proof_Syntax.pretty_proof_of ctxt full;
   535 
   536 fun pretty_theory ctxt (name, pos) =
   537   (case find_first (fn thy => Context.theory_name thy = name)
   538       (Theory.nodes_of (Proof_Context.theory_of ctxt)) of
   539     NONE => error ("No ancestor theory " ^ quote name ^ Position.here pos)
   540   | SOME thy => (Position.report pos (Theory.get_markup thy); Pretty.str name));
   541 
   542 
   543 (* default output *)
   544 
   545 val str_of_source = space_implode " " o map Token.unparse o #2 o #1 o Args.dest_src;
   546 
   547 fun maybe_pretty_source pretty ctxt src xs =
   548   map (pretty ctxt) xs  (*always pretty in order to exhibit errors!*)
   549   |> (if Config.get ctxt source then K [pretty_text ctxt (str_of_source src)] else I);
   550 
   551 fun output ctxt prts =
   552   prts
   553   |> (if Config.get ctxt quotes then map Pretty.quote else I)
   554   |> (if Config.get ctxt display then
   555     map (Output.output o Pretty.string_of o Pretty.indent (Config.get ctxt indent))
   556     #> space_implode "\\isasep\\isanewline%\n"
   557     #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   558   else
   559     map (Output.output o (if Config.get ctxt break then Pretty.string_of else Pretty.str_of))
   560     #> space_implode "\\isasep\\isanewline%\n"
   561     #> enclose "\\isa{" "}");
   562 
   563 
   564 
   565 (** concrete antiquotations **)
   566 
   567 (* basic entities *)
   568 
   569 local
   570 
   571 fun basic_entities name scan pretty = antiquotation name scan
   572   (fn {source, context, ...} => output context o maybe_pretty_source pretty context source);
   573 
   574 fun basic_entities_style name scan pretty = antiquotation name scan
   575   (fn {source, context, ...} => fn (style, xs) =>
   576     output context
   577       (maybe_pretty_source (fn ctxt => fn x => pretty ctxt (style, x)) context source xs));
   578 
   579 fun basic_entity name scan = basic_entities name (scan >> single);
   580 
   581 in
   582 
   583 val _ =
   584   Context.>> (Context.map_theory
   585    (basic_entities_style (Binding.name "thm") (Term_Style.parse -- Attrib.thms) pretty_thm_style #>
   586     basic_entity (Binding.name "prop") (Term_Style.parse -- Args.prop) pretty_term_style #>
   587     basic_entity (Binding.name "term") (Term_Style.parse -- Args.term) pretty_term_style #>
   588     basic_entity (Binding.name "term_type") (Term_Style.parse -- Args.term) pretty_term_typ #>
   589     basic_entity (Binding.name "typeof") (Term_Style.parse -- Args.term) pretty_term_typeof #>
   590     basic_entity (Binding.name "const") (Args.const_proper false) pretty_const #>
   591     basic_entity (Binding.name "abbrev") (Scan.lift Args.name_source) pretty_abbrev #>
   592     basic_entity (Binding.name "typ") Args.typ_abbrev Syntax.pretty_typ #>
   593     basic_entity (Binding.name "class") (Scan.lift Args.name_source) pretty_class #>
   594     basic_entity (Binding.name "type") (Scan.lift Args.name) pretty_type #>
   595     basic_entity (Binding.name "text") (Scan.lift Args.name) pretty_text #>
   596     basic_entities (Binding.name "prf") Attrib.thms (pretty_prf false) #>
   597     basic_entities (Binding.name "full_prf") Attrib.thms (pretty_prf true) #>
   598     basic_entity (Binding.name "theory") (Scan.lift (Parse.position Args.name)) pretty_theory #>
   599     basic_entities_style (Binding.name "thm_style")
   600       (Term_Style.parse_bare -- Attrib.thms) pretty_thm_style #>
   601     basic_entity (Binding.name "term_style")
   602       (Term_Style.parse_bare -- Args.term) pretty_term_style));
   603 
   604 end;
   605 
   606 
   607 (* goal state *)
   608 
   609 local
   610 
   611 fun proof_state state =
   612   (case try Toplevel.proof_of state of
   613     SOME prf => prf
   614   | _ => error "No proof state");
   615 
   616 fun goal_state name main_goal = antiquotation name (Scan.succeed ())
   617   (fn {state, context = ctxt, ...} => fn () => output ctxt
   618     [Pretty.chunks
   619       (Proof.pretty_goals main_goal (Proof.map_context (K ctxt) (proof_state state)))]);
   620 
   621 in
   622 
   623 val _ =
   624   Context.>> (Context.map_theory
   625    (goal_state (Binding.name "goals") true #>
   626     goal_state (Binding.name "subgoals") false));
   627 
   628 end;
   629 
   630 
   631 (* embedded lemma *)
   632 
   633 val _ = Keyword.define ("by", NONE);  (*overlap with command category*)
   634 
   635 val _ =
   636   Context.>> (Context.map_theory
   637    (antiquotation (Binding.name "lemma")
   638     (Args.prop -- Scan.lift (Args.$$$ "by" |-- Method.parse -- Scan.option Method.parse))
   639     (fn {source, context, ...} => fn (prop, methods) =>
   640       let
   641         val prop_src =
   642           (case Args.dest_src source of ((a, arg :: _), pos) => Args.src ((a, [arg]), pos));
   643         (* FIXME check proof!? *)
   644         val _ = context
   645           |> Proof.theorem NONE (K I) [[(prop, [])]]
   646           |> Proof.global_terminal_proof methods;
   647       in output context (maybe_pretty_source pretty_term context prop_src [prop]) end)));
   648 
   649 
   650 (* ML text *)
   651 
   652 val verb_text =
   653   split_lines
   654   #> map (space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|")
   655   #> space_implode "\\isasep\\isanewline%\n";
   656 
   657 local
   658 
   659 fun ml_text name ml = antiquotation name (Scan.lift Args.name_source_position)
   660   (fn {context, ...} => fn (txt, pos) =>
   661    (ML_Context.eval_in (SOME context) false pos (ml pos txt);
   662     Symbol_Pos.content (Symbol_Pos.explode (txt, pos))
   663     |> (if Config.get context quotes then quote else I)
   664     |> (if Config.get context display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
   665         else verb_text)));
   666 
   667 fun ml_enclose bg en pos txt =
   668   ML_Lex.read Position.none bg @ ML_Lex.read pos txt @ ML_Lex.read Position.none en;
   669 
   670 in
   671 
   672 val _ =
   673   Context.>> (Context.map_theory
   674    (ml_text (Binding.name "ML") (ml_enclose "fn _ => (" ");") #>
   675     ml_text (Binding.name "ML_op") (ml_enclose "fn _ => (op " ");") #>
   676     ml_text (Binding.name "ML_type") (ml_enclose "val _ = NONE : (" ") option;") #>
   677     ml_text (Binding.name "ML_struct")
   678       (ml_enclose "functor XXX() = struct structure XX = " " end;") #>
   679 
   680     ml_text (Binding.name "ML_functor")   (* FIXME formal treatment of functor name (!?) *)
   681       (fn pos => fn txt =>
   682         ML_Lex.read Position.none ("ML_Env.check_functor " ^
   683           ML_Syntax.print_string (Symbol_Pos.content (Symbol_Pos.explode (txt, pos))))) #>
   684 
   685     ml_text (Binding.name "ML_text") (K (K []))));
   686 
   687 end;
   688 
   689 end;