src/Pure/PIDE/resources.ML
author wenzelm
Thu Apr 13 12:19:28 2017 +0200 (2017-04-13 ago)
changeset 65476 a72ae9eb4462
parent 65474 5624e9694915
child 65478 7c40477e0a87
permissions -rw-r--r--
tuned signature (again);
     1 (*  Title:      Pure/PIDE/resources.ML
     2     Author:     Makarius
     3 
     4 Resources for theories and auxiliary files.
     5 *)
     6 
     7 signature RESOURCES =
     8 sig
     9   val set_session_base:
    10     {default_qualifier: string,
    11      global_theories: (string * string) list,
    12      loaded_theories: (string * string) list,
    13      known_theories: (string * string) list} -> unit
    14   val reset_session_base: unit -> unit
    15   val default_qualifier: unit -> string
    16   val global_theory: string -> string option
    17   val loaded_theory: string -> string option
    18   val known_theory: string -> Path.T option
    19   val master_directory: theory -> Path.T
    20   val imports_of: theory -> (string * Position.T) list
    21   val thy_path: Path.T -> Path.T
    22   val theory_qualifier: string -> string
    23   val import_name: string -> Path.T -> string ->
    24     {node_name: Path.T, master_dir: Path.T, theory_name: string}
    25   val check_thy: Path.T -> string ->
    26    {master: Path.T * SHA1.digest, text: string, theory_pos: Position.T,
    27     imports: (string * Position.T) list, keywords: Thy_Header.keywords}
    28   val parse_files: string -> (theory -> Token.file list) parser
    29   val provide: Path.T * SHA1.digest -> theory -> theory
    30   val provide_parse_files: string -> (theory -> Token.file list * theory) parser
    31   val loaded_files_current: theory -> bool
    32   val begin_theory: Path.T -> Thy_Header.header -> theory list -> theory
    33   val load_thy: bool -> HTML.symbols -> (Toplevel.transition -> Time.time) -> int ->
    34     Path.T -> Thy_Header.header -> Position.T -> string -> theory list ->
    35     theory * (unit -> unit) * int
    36 end;
    37 
    38 structure Resources: RESOURCES =
    39 struct
    40 
    41 (* session base *)
    42 
    43 val init_session_base =
    44   {default_qualifier = "Draft",
    45    global_theories = Symtab.empty: string Symtab.table,
    46    loaded_theories = Symtab.empty: string Symtab.table,
    47    known_theories = Symtab.empty: Path.T Symtab.table};
    48 
    49 val global_session_base =
    50   Synchronized.var "Sessions.base" init_session_base;
    51 
    52 fun set_session_base {default_qualifier, global_theories, loaded_theories, known_theories} =
    53   Synchronized.change global_session_base
    54     (fn _ =>
    55       {default_qualifier =
    56         if default_qualifier <> "" then default_qualifier
    57         else #default_qualifier init_session_base,
    58        global_theories = Symtab.make global_theories,
    59        loaded_theories = Symtab.make loaded_theories,
    60        known_theories = Symtab.make (map (apsnd Path.explode) known_theories)});
    61 
    62 fun reset_session_base () =
    63   Synchronized.change global_session_base (K init_session_base);
    64 
    65 fun get_session_base f = f (Synchronized.value global_session_base);
    66 
    67 fun default_qualifier () = get_session_base #default_qualifier;
    68 fun global_theory a = Symtab.lookup (get_session_base #global_theories) a;
    69 fun loaded_theory a = Symtab.lookup (get_session_base #loaded_theories) a;
    70 fun known_theory a = Symtab.lookup (get_session_base #known_theories) a;
    71 
    72 
    73 (* manage source files *)
    74 
    75 type files =
    76  {master_dir: Path.T,  (*master directory of theory source*)
    77   imports: (string * Position.T) list,  (*source specification of imports*)
    78   provided: (Path.T * SHA1.digest) list};  (*source path, digest*)
    79 
    80 fun make_files (master_dir, imports, provided): files =
    81  {master_dir = master_dir, imports = imports, provided = provided};
    82 
    83 structure Files = Theory_Data
    84 (
    85   type T = files;
    86   val empty = make_files (Path.current, [], []);
    87   fun extend _ = empty;
    88   fun merge _ = empty;
    89 );
    90 
    91 fun map_files f =
    92   Files.map (fn {master_dir, imports, provided} =>
    93     make_files (f (master_dir, imports, provided)));
    94 
    95 
    96 val master_directory = #master_dir o Files.get;
    97 val imports_of = #imports o Files.get;
    98 
    99 fun put_deps master_dir imports = map_files (fn _ => (master_dir, imports, []));
   100 
   101 
   102 (* theory files *)
   103 
   104 val thy_path = Path.ext "thy";
   105 
   106 fun theory_qualifier theory =
   107   (case global_theory theory of
   108     SOME qualifier => qualifier
   109   | NONE => Long_Name.qualifier theory);
   110 
   111 fun theory_name qualifier theory0 =
   112   (case loaded_theory theory0 of
   113     SOME theory => (true, theory)
   114   | NONE =>
   115       let val theory =
   116         if Long_Name.is_qualified theory0 orelse is_some (global_theory theory0)
   117           orelse true (* FIXME *) then theory0
   118         else Long_Name.qualify qualifier theory0
   119       in (false, theory) end);
   120 
   121 fun import_name qualifier dir s =
   122   (case theory_name qualifier (Thy_Header.import_name s) of
   123     (true, theory) =>
   124       {node_name = Path.basic theory, master_dir = Path.current, theory_name = theory}
   125   | (false, theory) =>
   126       let val node_name =
   127         (case known_theory theory of
   128           SOME node_name => node_name
   129         | NONE => File.full_path dir (thy_path (Path.expand (Path.explode s))))
   130       in {node_name = node_name, master_dir = Path.dir node_name, theory_name = theory} end);
   131 
   132 fun check_file dir file = File.check_file (File.full_path dir file);
   133 
   134 fun check_thy dir thy_name =
   135   let
   136     val thy_base_name = Long_Name.base_name thy_name;
   137     val master_file =
   138       (case known_theory thy_name of
   139         SOME known_path => check_file Path.current known_path
   140       | NONE => check_file dir (thy_path (Path.basic thy_base_name)));
   141     val text = File.read master_file;
   142 
   143     val {name = (name, pos), imports, keywords} =
   144       Thy_Header.read (Path.position master_file) text;
   145     val _ =
   146       thy_base_name <> name andalso
   147         error ("Bad theory name " ^ quote name ^
   148           " for file " ^ Path.print (Path.base master_file) ^ Position.here pos);
   149   in
   150    {master = (master_file, SHA1.digest text), text = text, theory_pos = pos,
   151     imports = imports, keywords = keywords}
   152   end;
   153 
   154 
   155 (* load files *)
   156 
   157 fun parse_files cmd =
   158   Scan.ahead Parse.not_eof -- Parse.path >> (fn (tok, name) => fn thy =>
   159     (case Token.get_files tok of
   160       [] =>
   161         let
   162           val keywords = Thy_Header.get_keywords thy;
   163           val master_dir = master_directory thy;
   164           val pos = Token.pos_of tok;
   165           val src_paths = Keyword.command_files keywords cmd (Path.explode name);
   166         in map (Command.read_file master_dir pos) src_paths end
   167     | files => map Exn.release files));
   168 
   169 fun provide (src_path, id) =
   170   map_files (fn (master_dir, imports, provided) =>
   171     if AList.defined (op =) provided src_path then
   172       error ("Duplicate use of source file: " ^ Path.print src_path)
   173     else (master_dir, imports, (src_path, id) :: provided));
   174 
   175 fun provide_parse_files cmd =
   176   parse_files cmd >> (fn files => fn thy =>
   177     let
   178       val fs = files thy;
   179       val thy' = fold (fn {src_path, digest, ...} => provide (src_path, digest)) fs thy;
   180     in (fs, thy') end);
   181 
   182 fun load_file thy src_path =
   183   let
   184     val full_path = check_file (master_directory thy) src_path;
   185     val text = File.read full_path;
   186     val id = SHA1.digest text;
   187   in ((full_path, id), text) end;
   188 
   189 fun loaded_files_current thy =
   190   #provided (Files.get thy) |>
   191     forall (fn (src_path, id) =>
   192       (case try (load_file thy) src_path of
   193         NONE => false
   194       | SOME ((_, id'), _) => id = id'));
   195 
   196 
   197 (* load theory *)
   198 
   199 fun begin_theory master_dir {name, imports, keywords} parents =
   200   Theory.begin_theory name parents
   201   |> put_deps master_dir imports
   202   |> Thy_Header.add_keywords keywords;
   203 
   204 fun excursion keywords master_dir last_timing init elements =
   205   let
   206     fun prepare_span st span =
   207       Command_Span.content span
   208       |> Command.read keywords (Command.read_thy st) master_dir init ([], ~1)
   209       |> (fn tr => Toplevel.put_timing (last_timing tr) tr);
   210 
   211     fun element_result span_elem (st, _) =
   212       let
   213         val elem = Thy_Syntax.map_element (prepare_span st) span_elem;
   214         val (results, st') = Toplevel.element_result keywords elem st;
   215         val pos' = Toplevel.pos_of (Thy_Syntax.last_element elem);
   216       in (results, (st', pos')) end;
   217 
   218     val (results, (end_state, end_pos)) =
   219       fold_map element_result elements (Toplevel.toplevel, Position.none);
   220 
   221     val thy = Toplevel.end_theory end_pos end_state;
   222   in (results, thy) end;
   223 
   224 fun load_thy document symbols last_timing update_time master_dir header text_pos text parents =
   225   let
   226     val (name, _) = #name header;
   227     val keywords =
   228       fold (curry Keyword.merge_keywords o Thy_Header.get_keywords) parents
   229         (Keyword.add_keywords (#keywords header) Keyword.empty_keywords);
   230 
   231     val toks = Token.explode keywords text_pos text;
   232     val spans = Outer_Syntax.parse_spans toks;
   233     val elements = Thy_Syntax.parse_elements keywords spans;
   234 
   235     fun init () =
   236       begin_theory master_dir header parents
   237       |> Present.begin_theory update_time
   238         (fn () => implode (map (HTML.present_span symbols keywords) spans));
   239 
   240     val (results, thy) =
   241       cond_timeit true ("theory " ^ quote name)
   242         (fn () => excursion keywords master_dir last_timing init elements);
   243 
   244     fun present () =
   245       let
   246         val res = filter_out (Toplevel.is_ignored o #1) (maps Toplevel.join_results results);
   247       in
   248         if exists (Toplevel.is_skipped_proof o #2) res then
   249           warning ("Cannot present theory with skipped proofs: " ^ quote name)
   250         else
   251           let val tex_source = Thy_Output.present_thy thy res toks |> Buffer.content;
   252           in if document then Present.theory_output name tex_source else () end
   253       end;
   254 
   255   in (thy, present, size text) end;
   256 
   257 
   258 (* antiquotations *)
   259 
   260 local
   261 
   262 fun err msg pos = error (msg ^ Position.here pos);
   263 
   264 fun check_path check_file ctxt dir (name, pos) =
   265   let
   266     val _ = Context_Position.report ctxt pos Markup.language_path;
   267 
   268     val path = Path.append dir (Path.explode name) handle ERROR msg => err msg pos;
   269     val _ = Path.expand path handle ERROR msg => err msg pos;
   270     val _ = Context_Position.report ctxt pos (Markup.path (Path.smart_implode path));
   271     val _ =
   272       (case check_file of
   273         NONE => path
   274       | SOME check => (check path handle ERROR msg => err msg pos));
   275   in path end;
   276 
   277 fun document_antiq check_file ctxt (name, pos) =
   278   let
   279     val dir = master_directory (Proof_Context.theory_of ctxt);
   280     val _ = check_path check_file ctxt dir (name, pos);
   281   in
   282     space_explode "/" name
   283     |> map Latex.output_ascii
   284     |> space_implode (Latex.output_ascii "/" ^ "\\discretionary{}{}{}")
   285     |> enclose "\\isatt{" "}"
   286   end;
   287 
   288 fun ML_antiq check_file ctxt (name, pos) =
   289   let val path = check_path check_file ctxt Path.current (name, pos);
   290   in "Path.explode " ^ ML_Syntax.print_string (Path.implode path) end;
   291 
   292 in
   293 
   294 val _ = Theory.setup
   295  (Thy_Output.antiquotation @{binding path} (Scan.lift (Parse.position Parse.path))
   296     (document_antiq NONE o #context) #>
   297   Thy_Output.antiquotation @{binding file} (Scan.lift (Parse.position Parse.path))
   298     (document_antiq (SOME File.check_file) o #context) #>
   299   Thy_Output.antiquotation @{binding dir} (Scan.lift (Parse.position Parse.path))
   300     (document_antiq (SOME File.check_dir) o #context) #>
   301   ML_Antiquotation.value @{binding path}
   302     (Args.context -- Scan.lift (Parse.position Parse.path)
   303       >> uncurry (ML_antiq NONE)) #>
   304   ML_Antiquotation.value @{binding file}
   305     (Args.context -- Scan.lift (Parse.position Parse.path)
   306       >> uncurry (ML_antiq (SOME File.check_file))) #>
   307   ML_Antiquotation.value @{binding dir}
   308     (Args.context -- Scan.lift (Parse.position Parse.path)
   309       >> uncurry (ML_antiq (SOME File.check_dir))));
   310 
   311 end;
   312 
   313 end;