src/Pure/Isar/isar_cmd.ML
author wenzelm
Thu Oct 04 14:42:47 2007 +0200 (2007-10-04 ago)
changeset 24830 a7b3ab44d993
parent 24789 33b7fbc07361
child 24920 2a45e400fdad
permissions -rw-r--r--
moved Pure/Isar/induct_attrib.ML and Provers/induct_method.ML to Tools/induct.ML;
     1 (*  Title:      Pure/Isar/isar_cmd.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Derived Isar commands.
     6 *)
     7 
     8 signature ISAR_CMD =
     9 sig
    10   val generic_setup: string option -> theory -> theory
    11   val parse_ast_translation: bool * string -> theory -> theory
    12   val parse_translation: bool * string -> theory -> theory
    13   val print_translation: bool * string -> theory -> theory
    14   val typed_print_translation: bool * string -> theory -> theory
    15   val print_ast_translation: bool * string -> theory -> theory
    16   val token_translation: string -> theory -> theory
    17   val oracle: bstring -> string -> string -> theory -> theory
    18   val add_axioms: ((bstring * string) * Attrib.src list) list -> theory -> theory
    19   val add_defs: (bool * bool) * ((bstring * string) * Attrib.src list) list -> theory -> theory
    20   val apply_theorems: (thmref * Attrib.src list) list -> theory -> thm list * theory
    21   val apply_theorems_i: (thm list * attribute list) list -> theory -> thm list * theory
    22   val declaration: string -> local_theory -> local_theory
    23   val simproc_setup: string -> string list -> string -> string list -> local_theory -> local_theory
    24   val have: ((string * Attrib.src list) * (string * string list) list) list ->
    25     bool -> Proof.state -> Proof.state
    26   val hence: ((string * Attrib.src list) * (string * string list) list) list ->
    27     bool -> Proof.state -> Proof.state
    28   val show: ((string * Attrib.src list) * (string * string list) list) list ->
    29     bool -> Proof.state -> Proof.state
    30   val thus: ((string * Attrib.src list) * (string * string list) list) list ->
    31     bool -> Proof.state -> Proof.state
    32   val qed: Method.text option -> Toplevel.transition -> Toplevel.transition
    33   val terminal_proof: Method.text * Method.text option ->
    34     Toplevel.transition -> Toplevel.transition
    35   val default_proof: Toplevel.transition -> Toplevel.transition
    36   val immediate_proof: Toplevel.transition -> Toplevel.transition
    37   val done_proof: Toplevel.transition -> Toplevel.transition
    38   val skip_proof: Toplevel.transition -> Toplevel.transition
    39   val begin_theory: string -> string list -> (string * bool) list -> bool -> theory
    40   val end_theory: theory -> theory
    41   val kill_theory: string -> unit
    42   val theory: string * string list * (string * bool) list
    43     -> Toplevel.transition -> Toplevel.transition
    44   val welcome: Toplevel.transition -> Toplevel.transition
    45   val init_toplevel: Toplevel.transition -> Toplevel.transition
    46   val exit: Toplevel.transition -> Toplevel.transition
    47   val quit: Toplevel.transition -> Toplevel.transition
    48   val touch_child_thys: string -> Toplevel.transition -> Toplevel.transition
    49   val touch_thy: string -> Toplevel.transition -> Toplevel.transition
    50   val remove_thy: string -> Toplevel.transition -> Toplevel.transition
    51   val kill_thy: string -> Toplevel.transition -> Toplevel.transition
    52   val pr: string list * (int option * int option) -> Toplevel.transition -> Toplevel.transition
    53   val disable_pr: Toplevel.transition -> Toplevel.transition
    54   val enable_pr: Toplevel.transition -> Toplevel.transition
    55   val redo: Toplevel.transition -> Toplevel.transition
    56   val undos_proof: int -> Toplevel.transition -> Toplevel.transition
    57   val kill_proof_notify: (unit -> unit) -> Toplevel.transition -> Toplevel.transition
    58   val kill_proof: Toplevel.transition -> Toplevel.transition
    59   val undo_theory: Toplevel.transition -> Toplevel.transition
    60   val undo: Toplevel.transition -> Toplevel.transition
    61   val cannot_undo: string -> Toplevel.transition -> Toplevel.transition
    62   val kill: Toplevel.transition -> Toplevel.transition
    63   val back: Toplevel.transition -> Toplevel.transition
    64   val use: Path.T -> Toplevel.transition -> Toplevel.transition
    65   val use_mltext_theory: string -> Toplevel.transition -> Toplevel.transition
    66   val use_mltext: bool -> string -> Toplevel.transition -> Toplevel.transition
    67   val use_commit: Toplevel.transition -> Toplevel.transition
    68   val cd: Path.T -> Toplevel.transition -> Toplevel.transition
    69   val pwd: Toplevel.transition -> Toplevel.transition
    70   val use_thy: string -> Toplevel.transition -> Toplevel.transition
    71   val display_drafts: Path.T list -> Toplevel.transition -> Toplevel.transition
    72   val print_drafts: Path.T list -> Toplevel.transition -> Toplevel.transition
    73   val pretty_setmargin: int -> Toplevel.transition -> Toplevel.transition
    74   val print_context: Toplevel.transition -> Toplevel.transition
    75   val print_theory: bool -> Toplevel.transition -> Toplevel.transition
    76   val print_syntax: Toplevel.transition -> Toplevel.transition
    77   val print_abbrevs: Toplevel.transition -> Toplevel.transition
    78   val print_facts: Toplevel.transition -> Toplevel.transition
    79   val print_configs: Toplevel.transition -> Toplevel.transition
    80   val print_theorems: Toplevel.transition -> Toplevel.transition
    81   val print_locales: Toplevel.transition -> Toplevel.transition
    82   val print_locale: bool * (Locale.expr * Element.context list)
    83     -> Toplevel.transition -> Toplevel.transition
    84   val print_registrations: bool -> string -> Toplevel.transition -> Toplevel.transition
    85   val print_attributes: Toplevel.transition -> Toplevel.transition
    86   val print_simpset: Toplevel.transition -> Toplevel.transition
    87   val print_rules: Toplevel.transition -> Toplevel.transition
    88   val print_trans_rules: Toplevel.transition -> Toplevel.transition
    89   val print_methods: Toplevel.transition -> Toplevel.transition
    90   val print_antiquotations: Toplevel.transition -> Toplevel.transition
    91   val class_deps: Toplevel.transition -> Toplevel.transition
    92   val thy_deps: Toplevel.transition -> Toplevel.transition
    93   val thm_deps: (thmref * Attrib.src list) list -> Toplevel.transition -> Toplevel.transition
    94   val find_theorems: (int option * bool) * (bool * string FindTheorems.criterion) list
    95     -> Toplevel.transition -> Toplevel.transition
    96   val print_binds: Toplevel.transition -> Toplevel.transition
    97   val print_cases: Toplevel.transition -> Toplevel.transition
    98   val print_stmts: string list * (thmref * Attrib.src list) list
    99     -> Toplevel.transition -> Toplevel.transition
   100   val print_thms: string list * (thmref * Attrib.src list) list
   101     -> Toplevel.transition -> Toplevel.transition
   102   val print_prfs: bool -> string list * (thmref * Attrib.src list) list option
   103     -> Toplevel.transition -> Toplevel.transition
   104   val print_prop: (string list * string) -> Toplevel.transition -> Toplevel.transition
   105   val print_term: (string list * string) -> Toplevel.transition -> Toplevel.transition
   106   val print_type: (string list * string) -> Toplevel.transition -> Toplevel.transition
   107   val add_header: string * Position.T -> Toplevel.transition -> Toplevel.transition
   108   val add_chapter: xstring option * (string * Position.T) ->
   109     Toplevel.transition -> Toplevel.transition
   110   val add_section: xstring option * (string * Position.T) ->
   111     Toplevel.transition -> Toplevel.transition
   112   val add_subsection: xstring option * (string * Position.T) ->
   113     Toplevel.transition -> Toplevel.transition
   114   val add_subsubsection: xstring option * (string * Position.T) ->
   115     Toplevel.transition -> Toplevel.transition
   116   val add_text: xstring option * (string * Position.T) ->
   117     Toplevel.transition -> Toplevel.transition
   118   val add_text_raw: string * Position.T -> Toplevel.transition -> Toplevel.transition
   119   val add_sect: string * Position.T -> Toplevel.transition -> Toplevel.transition
   120   val add_subsect: string * Position.T -> Toplevel.transition -> Toplevel.transition
   121   val add_subsubsect: string * Position.T -> Toplevel.transition -> Toplevel.transition
   122   val add_txt: string * Position.T -> Toplevel.transition -> Toplevel.transition
   123   val add_txt_raw: string * Position.T -> Toplevel.transition -> Toplevel.transition
   124 end;
   125 
   126 structure IsarCmd: ISAR_CMD =
   127 struct
   128 
   129 
   130 (** theory declarations **)
   131 
   132 (* generic_setup *)
   133 
   134 fun generic_setup NONE = (fn thy => thy |> Context.setup ())
   135   | generic_setup (SOME txt) =
   136       ML_Context.use_let "val setup: theory -> theory" "Context.map_theory setup" txt
   137       |> Context.theory_map;
   138 
   139 
   140 (* translation functions *)
   141 
   142 local
   143 
   144 fun advancedT false = ""
   145   | advancedT true = "Proof.context -> ";
   146 
   147 fun advancedN false = ""
   148   | advancedN true = "advanced_";
   149 
   150 in
   151 
   152 fun parse_ast_translation (a, txt) =
   153   txt |> ML_Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   154       "Syntax.ast list -> Syntax.ast)) list")
   155     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], []))")
   156   |> Context.theory_map;
   157 
   158 fun parse_translation (a, txt) =
   159   txt |> ML_Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   160       "term list -> term)) list")
   161     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], []))")
   162   |> Context.theory_map;
   163 
   164 fun print_translation (a, txt) =
   165   txt |> ML_Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   166       "term list -> term)) list")
   167     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, []))")
   168   |> Context.theory_map;
   169 
   170 fun print_ast_translation (a, txt) =
   171   txt |> ML_Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   172       "Syntax.ast list -> Syntax.ast)) list")
   173     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation))")
   174   |> Context.theory_map;
   175 
   176 fun typed_print_translation (a, txt) =
   177   txt |> ML_Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   178       "bool -> typ -> term list -> term)) list")
   179     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation)")
   180   |> Context.theory_map;
   181 
   182 val token_translation =
   183   ML_Context.use_let "val token_translation: (string * string * (string -> output * int)) list"
   184     "Context.map_theory (Sign.add_tokentrfuns token_translation)"
   185   #> Context.theory_map;
   186 
   187 end;
   188 
   189 
   190 (* oracles *)
   191 
   192 fun oracle name typ oracle =
   193   let val txt =
   194     "local\n\
   195     \  type T = " ^ typ ^ ";\n\
   196     \  val oracle: theory -> T -> term = " ^ oracle ^ ";\n\
   197     \  val name = " ^ quote name ^ ";\n\
   198     \  exception Arg of T;\n\
   199     \  val _ = ML_Context.>> (Theory.add_oracle (name, fn (thy, Arg x) => oracle thy x));\n\
   200     \  val thy = ML_Context.the_context ();\n\
   201     \  val invoke_" ^ name ^ " = Thm.invoke_oracle_i thy (Sign.full_name thy name);\n\
   202     \in\n\
   203     \  fun " ^ name ^ " thy x = invoke_" ^ name ^ " (thy, Arg x);\n\
   204     \end;\n";
   205   in ML_Context.use_mltext_update txt false end
   206   |> Context.theory_map;
   207 
   208 
   209 (* axioms *)
   210 
   211 fun add_axms f args thy =
   212   f (map (fn (x, srcs) => (x, map (Attrib.attribute thy) srcs)) args) thy;
   213 
   214 val add_axioms = add_axms (snd oo PureThy.add_axioms);
   215 
   216 fun add_defs ((unchecked, overloaded), args) =
   217   add_axms
   218     (snd oo (if unchecked then PureThy.add_defs_unchecked else PureThy.add_defs) overloaded) args;
   219 
   220 
   221 (* facts *)
   222 
   223 fun apply_theorems args thy =
   224   let val facts = Attrib.map_facts (Attrib.attribute thy) [(("", []), args)]
   225   in apfst (maps snd) (PureThy.note_thmss "" facts thy) end;
   226 
   227 fun apply_theorems_i args = apfst (maps snd) o PureThy.note_thmss_i "" [(("", []), args)];
   228 
   229 
   230 (* declarations *)
   231 
   232 val declaration =
   233   ML_Context.use_let "val declaration: Morphism.declaration"
   234     "Context.map_proof (LocalTheory.declaration declaration)"
   235   #> Context.proof_map;
   236 
   237 
   238 (* simprocs *)
   239 
   240 fun simproc_setup name lhss proc identifier =
   241   ML_Context.use_let
   242     "val proc: Morphism.morphism -> Simplifier.simpset -> cterm -> thm option"
   243   ("Context.map_proof (Simplifier.def_simproc {name = " ^ ML_Syntax.print_string name ^ ", \
   244     \lhss = " ^ ML_Syntax.print_strings lhss ^ ", proc = proc, \
   245     \identifier = Library.maps ML_Context.thms " ^ ML_Syntax.print_strings identifier ^ "})") proc
   246   |> Context.proof_map;
   247 
   248 
   249 (* goals *)
   250 
   251 fun goal opt_chain goal stmt int =
   252   opt_chain #> goal NONE (K Seq.single) stmt int;
   253 
   254 val have = goal I Proof.have;
   255 val hence = goal Proof.chain Proof.have;
   256 val show = goal I Proof.show;
   257 val thus = goal Proof.chain Proof.show;
   258 
   259 
   260 (* local endings *)
   261 
   262 fun local_qed m = Toplevel.proofs (Proof.local_qed (m, true));
   263 val local_terminal_proof = Toplevel.proofs o Proof.local_terminal_proof;
   264 val local_default_proof = Toplevel.proofs Proof.local_default_proof;
   265 val local_immediate_proof = Toplevel.proofs Proof.local_immediate_proof;
   266 val local_done_proof = Toplevel.proofs Proof.local_done_proof;
   267 val local_skip_proof = Toplevel.proofs' Proof.local_skip_proof;
   268 
   269 val skip_local_qed =
   270   Toplevel.skip_proof (History.apply (fn i => if i > 1 then i - 1 else raise Toplevel.UNDEF));
   271 
   272 
   273 (* global endings *)
   274 
   275 fun global_qed m = Toplevel.end_proof (K (Proof.global_qed (m, true)));
   276 val global_terminal_proof = Toplevel.end_proof o K o Proof.global_terminal_proof;
   277 val global_default_proof = Toplevel.end_proof (K Proof.global_default_proof);
   278 val global_immediate_proof = Toplevel.end_proof (K Proof.global_immediate_proof);
   279 val global_skip_proof = Toplevel.end_proof Proof.global_skip_proof;
   280 val global_done_proof = Toplevel.end_proof (K Proof.global_done_proof);
   281 
   282 val skip_global_qed = Toplevel.skip_proof_to_theory (equal 1);
   283 
   284 
   285 (* common endings *)
   286 
   287 fun qed m = local_qed m o global_qed m o skip_local_qed o skip_global_qed;
   288 fun terminal_proof m = local_terminal_proof m o global_terminal_proof m;
   289 val default_proof = local_default_proof o global_default_proof;
   290 val immediate_proof = local_immediate_proof o global_immediate_proof;
   291 val done_proof = local_done_proof o global_done_proof;
   292 val skip_proof = local_skip_proof o global_skip_proof;
   293 
   294 
   295 (* init and exit *)
   296 
   297 fun begin_theory name imports uses =
   298   ThyInfo.begin_theory name imports (map (apfst Path.explode) uses);
   299 
   300 fun end_theory thy =
   301   if ThyInfo.check_known_thy (Context.theory_name thy) then ThyInfo.end_theory thy else thy;
   302 
   303 val kill_theory = ThyInfo.if_known_thy ThyInfo.remove_thy;
   304 
   305 fun theory (name, imports, uses) =
   306   Toplevel.init_theory (begin_theory name imports uses)
   307     (fn thy => (end_theory thy; ()))
   308     (kill_theory o Context.theory_name);
   309 
   310 val init_toplevel = Toplevel.imperative (fn () => raise Toplevel.RESTART);
   311 
   312 val welcome = Toplevel.imperative (writeln o Session.welcome);
   313 
   314 val exit = Toplevel.keep (fn state =>
   315  (CRITICAL (fn () => ML_Context.set_context (try Toplevel.generic_theory_of state));
   316   raise Toplevel.TERMINATE));
   317 
   318 val quit = Toplevel.imperative quit;
   319 
   320 
   321 (* touch theories *)
   322 
   323 fun touch_child_thys name = Toplevel.imperative (fn () => ThyInfo.touch_child_thys name);
   324 fun touch_thy name = Toplevel.imperative (fn () => ThyInfo.touch_thy name);
   325 fun remove_thy name = Toplevel.imperative (fn () => ThyInfo.remove_thy name);
   326 fun kill_thy name = Toplevel.imperative (fn () => kill_theory name);
   327 
   328 
   329 (* print state *)
   330 
   331 fun set_limit _ NONE = ()
   332   | set_limit r (SOME n) = r := n;
   333 
   334 fun pr (modes, (lim1, lim2)) = Toplevel.keep (fn state =>
   335   (set_limit goals_limit lim1; set_limit ProofContext.prems_limit lim2; Toplevel.quiet := false;
   336     PrintMode.with_modes modes (Toplevel.print_state true) state));
   337 
   338 val disable_pr = Toplevel.imperative (fn () => Toplevel.quiet := true);
   339 val enable_pr = Toplevel.imperative (fn () => Toplevel.quiet := false);
   340 
   341 
   342 (* history commands *)
   343 
   344 val redo =
   345   Toplevel.history History.redo o
   346   Toplevel.actual_proof ProofHistory.redo o
   347   Toplevel.skip_proof History.redo;
   348 
   349 fun undos_proof n =
   350   Toplevel.actual_proof (fn prf =>
   351     if ProofHistory.is_initial prf then raise Toplevel.UNDEF else funpow n ProofHistory.undo prf) o
   352   Toplevel.skip_proof (fn h =>
   353     if History.is_initial h then raise Toplevel.UNDEF else funpow n History.undo h);
   354 
   355 fun kill_proof_notify (f: unit -> unit) = Toplevel.history (fn hist =>
   356   if is_some (Toplevel.theory_node (History.current hist)) then raise Toplevel.UNDEF
   357   else (f (); History.undo hist));
   358 
   359 val kill_proof = kill_proof_notify (K ());
   360 
   361 val undo_theory = Toplevel.history (fn hist =>
   362   if History.is_initial hist then raise Toplevel.UNDEF else History.undo hist);
   363 
   364 val undo = Toplevel.kill o undo_theory o Toplevel.undo_exit o undos_proof 1;
   365 
   366 fun cannot_undo "end" = undo   (*ProofGeneral legacy*)
   367   | cannot_undo txt = Toplevel.imperative (fn () => error ("Cannot undo " ^ quote txt));
   368 
   369 val kill = Toplevel.kill o kill_proof;
   370 
   371 val back =
   372   Toplevel.actual_proof ProofHistory.back o
   373   Toplevel.skip_proof (History.apply I);
   374 
   375 
   376 (* use ML text *)
   377 
   378 fun use path = Toplevel.keep (fn state =>
   379   ML_Context.setmp (try Toplevel.generic_theory_of state) (ThyInfo.load_file false) path);
   380 
   381 (*passes changes of theory context*)
   382 val use_mltext_theory = Toplevel.theory' o (Context.theory_map oo ML_Context.use_mltext_update);
   383 
   384 (*ignore result theory context*)
   385 fun use_mltext v txt = Toplevel.keep' (fn verb => fn state =>
   386   (ML_Context.use_mltext txt (v andalso verb) (try Toplevel.generic_theory_of state)));
   387 
   388 val use_commit = Toplevel.imperative Secure.commit;
   389 
   390 
   391 (* current working directory *)
   392 
   393 fun cd path = Toplevel.imperative (fn () => (File.cd path));
   394 val pwd = Toplevel.imperative (fn () => writeln (Path.implode (File.pwd ())));
   395 
   396 
   397 (* load theory files *)
   398 
   399 fun use_thy name = Toplevel.imperative (fn () => ML_Context.save ThyInfo.use_thy name);
   400 
   401 
   402 (* present draft files *)
   403 
   404 fun display_drafts files = Toplevel.imperative (fn () =>
   405   let val outfile = File.shell_path (Present.drafts (getenv "ISABELLE_DOC_FORMAT") files)
   406   in File.isatool ("display -c " ^ outfile ^ " &"); () end);
   407 
   408 fun print_drafts files = Toplevel.imperative (fn () =>
   409   let val outfile = File.shell_path (Present.drafts "ps" files)
   410   in File.isatool ("print -c " ^ outfile); () end);
   411 
   412 
   413 (* pretty_setmargin *)
   414 
   415 fun pretty_setmargin n = Toplevel.imperative (fn () => Pretty.setmargin n);
   416 
   417 
   418 (* print parts of theory and proof context *)
   419 
   420 val print_context = Toplevel.keep Toplevel.print_state_context;
   421 
   422 fun print_theory verbose = Toplevel.unknown_theory o
   423   Toplevel.keep (Pretty.writeln o ProofDisplay.pretty_full_theory verbose o Toplevel.theory_of);
   424 
   425 val print_syntax = Toplevel.unknown_context o
   426   Toplevel.keep (ProofContext.print_syntax o Toplevel.context_of);
   427 
   428 val print_abbrevs = Toplevel.unknown_context o
   429   Toplevel.keep (ProofContext.print_abbrevs o Toplevel.context_of);
   430 
   431 val print_facts = Toplevel.unknown_context o Toplevel.keep (fn state =>
   432   ProofContext.setmp_verbose
   433     ProofContext.print_lthms (Toplevel.context_of state));
   434 
   435 val print_configs = Toplevel.unknown_context o Toplevel.keep (fn state =>
   436   Attrib.print_configs (Toplevel.context_of state));
   437 
   438 val print_theorems_proof = Toplevel.keep (fn state =>
   439   ProofContext.setmp_verbose
   440     ProofContext.print_lthms (Proof.context_of (Toplevel.proof_of state)));
   441 
   442 val print_theorems_theory = Toplevel.keep (fn state =>
   443   Toplevel.theory_of state |>
   444   (case Option.map Toplevel.theory_node (History.previous (Toplevel.node_history_of state)) of
   445     SOME (SOME prev_thy) => ProofDisplay.print_theorems_diff (Context.theory_of prev_thy)
   446   | _ => ProofDisplay.print_theorems));
   447 
   448 val print_theorems = Toplevel.unknown_context o print_theorems_theory o print_theorems_proof;
   449 
   450 val print_locales = Toplevel.unknown_theory o
   451   Toplevel.keep (Locale.print_locales o Toplevel.theory_of);
   452 
   453 fun print_locale (show_facts, (imports, body)) = Toplevel.unknown_theory o
   454   Toplevel.keep (fn state =>
   455     Locale.print_locale (Toplevel.theory_of state) show_facts imports body);
   456 
   457 fun print_registrations show_wits name = Toplevel.unknown_context o
   458   Toplevel.keep (Toplevel.node_case
   459       (Context.cases (Locale.print_registrations show_wits name o ProofContext.init)
   460         (Locale.print_registrations show_wits name))
   461     (Locale.print_registrations show_wits name o Proof.context_of));
   462 
   463 val print_attributes = Toplevel.unknown_theory o
   464   Toplevel.keep (Attrib.print_attributes o Toplevel.theory_of);
   465 
   466 val print_simpset = Toplevel.unknown_context o
   467   Toplevel.keep (Toplevel.node_case
   468     (Context.cases Simplifier.print_simpset Simplifier.print_local_simpset)
   469     (Simplifier.print_local_simpset o Proof.context_of));
   470 
   471 val print_rules = Toplevel.unknown_context o
   472   Toplevel.keep (ContextRules.print_rules o Toplevel.context_of);
   473 
   474 val print_trans_rules = Toplevel.unknown_context o
   475   Toplevel.keep (Calculation.print_rules o Toplevel.context_of);
   476 
   477 val print_methods = Toplevel.unknown_theory o
   478   Toplevel.keep (Method.print_methods o Toplevel.theory_of);
   479 
   480 val print_antiquotations = Toplevel.imperative ThyOutput.print_antiquotations;
   481 
   482 val thy_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   483   let
   484     val thy = Toplevel.theory_of state;
   485     val all_thys = sort ThyInfo.thy_ord (thy :: Theory.ancestors_of thy);
   486     val gr = all_thys |> map (fn node =>
   487       let
   488         val name = Context.theory_name node;
   489         val parents = map Context.theory_name (Theory.parents_of node);
   490         val dir = Present.session_name node;
   491         val unfold = not (ThyInfo.known_thy name andalso ThyInfo.is_finished name);
   492       in {name = name, ID = name, parents = parents, dir = dir, unfold = unfold, path = ""} end);
   493   in Present.display_graph gr end);
   494 
   495 val class_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   496   let
   497     val thy = Toplevel.theory_of state;
   498     val {classes = (space, algebra), ...} = Type.rep_tsig (Sign.tsig_of thy);
   499     val {classes, ...} = Sorts.rep_algebra algebra;
   500     fun entry (c, (i, (_, cs))) =
   501       (i, {name = NameSpace.extern space c, ID = c, parents = cs,
   502             dir = "", unfold = true, path = ""});
   503     val gr =
   504       Graph.fold (cons o entry) classes []
   505       |> sort (int_ord o pairself #1) |> map #2;
   506   in Present.display_graph gr end);
   507 
   508 
   509 (* retrieve theorems *)
   510 
   511 fun thm_deps args = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   512   ThmDeps.thm_deps (Proof.get_thmss (Toplevel.enter_proof_body state) args));
   513 
   514 fun find_theorems ((opt_lim, rem_dups), spec) =
   515   Toplevel.unknown_theory o Toplevel.keep (fn state =>
   516   let
   517     val proof_state = Toplevel.enter_proof_body state;
   518     val ctxt = Proof.context_of proof_state;
   519     val opt_goal = try Proof.get_goal proof_state |> Option.map (Thm.prop_of o #2 o #2);
   520   in FindTheorems.print_theorems ctxt opt_goal opt_lim rem_dups spec end);
   521 
   522 
   523 (* print proof context contents *)
   524 
   525 val print_binds = Toplevel.unknown_context o Toplevel.keep (fn state =>
   526   ProofContext.setmp_verbose ProofContext.print_binds (Toplevel.context_of state));
   527 
   528 val print_cases = Toplevel.unknown_context o Toplevel.keep (fn state =>
   529   ProofContext.setmp_verbose ProofContext.print_cases (Toplevel.context_of state));
   530 
   531 
   532 (* print theorems, terms, types etc. *)
   533 
   534 local
   535 
   536 fun string_of_stmts state args =
   537   Proof.get_thmss state args
   538   |> map (Element.pretty_statement (Proof.context_of state) Thm.theoremK)
   539   |> Pretty.chunks2 |> Pretty.string_of;
   540 
   541 fun string_of_thms state args =
   542   Pretty.string_of (ProofContext.pretty_thms (Proof.context_of state)
   543     (Proof.get_thmss state args));
   544 
   545 fun string_of_prfs full state arg =
   546   Pretty.string_of (case arg of
   547       NONE =>
   548         let
   549           val (ctxt, (_, thm)) = Proof.get_goal state;
   550           val {thy, der = (_, prf), ...} = Thm.rep_thm thm;
   551           val prop = Thm.full_prop_of thm;
   552           val prf' = Proofterm.rewrite_proof_notypes ([], []) prf
   553         in
   554           ProofContext.pretty_proof ctxt
   555             (if full then Reconstruct.reconstruct_proof thy prop prf' else prf')
   556         end
   557     | SOME args => Pretty.chunks
   558         (map (ProofContext.pretty_proof_of (Proof.context_of state) full)
   559           (Proof.get_thmss state args)));
   560 
   561 fun string_of_prop state s =
   562   let
   563     val ctxt = Proof.context_of state;
   564     val prop = Syntax.read_prop ctxt s;
   565   in Pretty.string_of (Pretty.quote (ProofContext.pretty_term ctxt prop)) end;
   566 
   567 fun string_of_term state s =
   568   let
   569     val ctxt = Proof.context_of state;
   570     val t = Syntax.read_term ctxt s;
   571     val T = Term.type_of t;
   572   in
   573     Pretty.string_of
   574       (Pretty.block [Pretty.quote (ProofContext.pretty_term ctxt t), Pretty.fbrk,
   575         Pretty.str "::", Pretty.brk 1, Pretty.quote (ProofContext.pretty_typ ctxt T)])
   576   end;
   577 
   578 fun string_of_type state s =
   579   let
   580     val ctxt = Proof.context_of state;
   581     val T = ProofContext.read_typ ctxt s;
   582   in Pretty.string_of (Pretty.quote (ProofContext.pretty_typ ctxt T)) end;
   583 
   584 fun print_item string_of (modes, arg) = Toplevel.keep (fn state =>
   585   PrintMode.with_modes modes (fn () =>
   586     writeln (string_of (Toplevel.enter_proof_body state) arg)) ());
   587 
   588 in
   589 
   590 val print_stmts = print_item string_of_stmts;
   591 val print_thms = print_item string_of_thms;
   592 val print_prfs = print_item o string_of_prfs;
   593 val print_prop = print_item string_of_prop;
   594 val print_term = print_item string_of_term;
   595 val print_type = print_item string_of_type;
   596 
   597 end;
   598 
   599 
   600 (* markup commands *)
   601 
   602 fun add_header s = Toplevel.keep' (fn int => fn state =>
   603   (if Toplevel.is_toplevel state then () else raise Toplevel.UNDEF;
   604    if int then OuterSyntax.check_text s NONE else ()));
   605 
   606 local
   607 
   608 fun present _ txt true node = OuterSyntax.check_text txt (SOME node)
   609   | present f (s, _) false node =
   610       ML_Context.setmp (try (Toplevel.cases_node I (Context.Proof o Proof.context_of)) node) f s;
   611 
   612 fun present_local_theory f (loc, txt) = Toplevel.present_local_theory loc (present f txt);
   613 fun present_proof f txt = Toplevel.print o Toplevel.present_proof (present f txt);
   614 
   615 in
   616 
   617 val add_chapter       = present_local_theory Present.section;
   618 val add_section       = present_local_theory Present.section;
   619 val add_subsection    = present_local_theory Present.subsection;
   620 val add_subsubsection = present_local_theory Present.subsubsection;
   621 val add_text          = present_local_theory (K ());
   622 fun add_text_raw txt  = present_local_theory (K ()) (NONE, txt);
   623 val add_txt           = present_proof (K ());
   624 val add_txt_raw       = add_txt;
   625 val add_sect          = add_txt;
   626 val add_subsect       = add_txt;
   627 val add_subsubsect    = add_txt;
   628 
   629 end;
   630 
   631 end;