src/Pure/PIDE/command.ML
author wenzelm
Fri Jul 05 17:09:28 2013 +0200 (2013-07-05 ago)
changeset 52533 a95440dcd59c
parent 52532 c81d76f7f63d
child 52534 341ae9cd4743
permissions -rw-r--r--
clarified type Command.eval;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   type span = Token.T list
    10   val range: span -> Position.range
    11   val proper_range: span -> Position.range
    12   type 'a memo
    13   val memo: (unit -> 'a) -> 'a memo
    14   val memo_value: 'a -> 'a memo
    15   val memo_eval: 'a memo -> 'a
    16   val memo_fork: Future.params -> 'a memo -> unit
    17   val memo_result: 'a memo -> 'a
    18   val memo_stable: 'a memo -> bool
    19   val read: span -> Toplevel.transition
    20   type eval_state =
    21     {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state}
    22   type eval = {exec_id: Document_ID.exec, eval: eval_state memo}
    23   val no_eval: eval
    24   val eval_result: eval -> eval_state
    25   val eval: span -> Toplevel.transition -> eval_state -> eval_state
    26   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    27   type print = {name: string, pri: int, exec_id: Document_ID.exec, print: unit memo}
    28   val print: string -> eval -> print list
    29   val print_function: {name: string, pri: int} -> (string -> print_fn option) -> unit
    30   type exec = eval * print list
    31   val no_exec: exec
    32   val exec_ids: exec -> Document_ID.exec list
    33   val exec_result: exec -> eval_state
    34   val exec_run: exec -> unit
    35   val stable_eval: eval -> bool
    36   val stable_print: print -> bool
    37 end;
    38 
    39 structure Command: COMMAND =
    40 struct
    41 
    42 (* source *)
    43 
    44 type span = Token.T list;
    45 
    46 val range = Token.position_range_of;
    47 val proper_range = Token.position_range_of o #1 o take_suffix Token.is_improper;
    48 
    49 
    50 (* memo results *)
    51 
    52 datatype 'a expr =
    53   Expr of unit -> 'a |
    54   Result of 'a Exn.result;
    55 
    56 abstype 'a memo = Memo of 'a expr Synchronized.var
    57 with
    58 
    59 fun memo e = Memo (Synchronized.var "Command.memo" (Expr e));
    60 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    61 
    62 fun memo_eval (Memo v) =
    63   (case Synchronized.value v of
    64     Result res => res
    65   | _ =>
    66       Synchronized.guarded_access v
    67         (fn Result res => SOME (res, Result res)
    68           | Expr e =>
    69               let val res = Exn.capture e ();  (*memoing of physical interrupts!*)
    70               in SOME (res, Result res) end))
    71   |> Exn.release;
    72 
    73 fun memo_fork params (Memo v) =
    74   (case Synchronized.value v of
    75     Result _ => ()
    76   | _ => ignore ((singleton o Future.forks) params (fn () => memo_eval (Memo v))));
    77 
    78 fun memo_result (Memo v) =
    79   (case Synchronized.value v of
    80     Result res => Exn.release res
    81   | _ => raise Fail "Unfinished memo result");
    82 
    83 fun memo_stable (Memo v) =
    84   (case Synchronized.value v of
    85     Expr _ => true
    86   | Result res => not (Exn.is_interrupt_exn res));
    87 
    88 end;
    89 
    90 
    91 (** main phases: read -- eval -- print **)
    92 
    93 (* read *)
    94 
    95 fun read span =
    96   let
    97     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
    98     val command_reports = Outer_Syntax.command_reports outer_syntax;
    99 
   100     val proper_range = Position.set_range (proper_range span);
   101     val pos =
   102       (case find_first Token.is_command span of
   103         SOME tok => Token.position_of tok
   104       | NONE => proper_range);
   105 
   106     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
   107     val _ = Position.reports_text (token_reports @ maps command_reports span);
   108   in
   109     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
   110     else
   111       (case Outer_Syntax.read_spans outer_syntax span of
   112         [tr] =>
   113           if Keyword.is_control (Toplevel.name_of tr) then
   114             Toplevel.malformed pos "Illegal control command"
   115           else tr
   116       | [] => Toplevel.ignored (Position.set_range (range span))
   117       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   118       handle ERROR msg => Toplevel.malformed proper_range msg
   119   end;
   120 
   121 
   122 (* eval *)
   123 
   124 type eval_state =
   125   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   126 val no_eval_state: eval_state =
   127   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   128 
   129 type eval = {exec_id: Document_ID.exec, eval: eval_state memo};
   130 
   131 val no_eval: eval = {exec_id = Document_ID.none, eval = memo_value no_eval_state};
   132 fun eval_result ({eval, ...}: eval) = memo_result eval;
   133 
   134 local
   135 
   136 fun run int tr st =
   137   if Goal.future_enabled () andalso Keyword.is_diag (Toplevel.name_of tr) then
   138     (Goal.fork_params {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   139       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   140   else Toplevel.command_errors int tr st;
   141 
   142 fun check_cmts span tr st' =
   143   Toplevel.setmp_thread_position tr
   144     (fn () =>
   145       Outer_Syntax.side_comments span |> maps (fn cmt =>
   146         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   147           handle exn => ML_Compiler.exn_messages_ids exn)) ();
   148 
   149 fun proof_status tr st =
   150   (case try Toplevel.proof_of st of
   151     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   152   | NONE => ());
   153 
   154 in
   155 
   156 fun eval span tr ({malformed, state = st, ...}: eval_state) =
   157   if malformed then
   158     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   159   else
   160     let
   161       val malformed' = Toplevel.is_malformed tr;
   162       val is_init = Toplevel.is_init tr;
   163       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   164 
   165       val _ = Multithreading.interrupted ();
   166       val _ = Toplevel.status tr Markup.running;
   167       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   168       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   169       val errs = errs1 @ errs2;
   170       val _ = Toplevel.status tr Markup.finished;
   171       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   172     in
   173       (case result of
   174         NONE =>
   175           let
   176             val _ = if null errs then Exn.interrupt () else ();
   177             val _ = Toplevel.status tr Markup.failed;
   178           in {failed = true, malformed = malformed', command = tr, state = st} end
   179       | SOME st' =>
   180           let
   181             val _ = proof_status tr st';
   182           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   183     end;
   184 
   185 end;
   186 
   187 
   188 (* print *)
   189 
   190 type print = {name: string, pri: int, exec_id: Document_ID.exec, print: unit memo};
   191 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   192 
   193 local
   194 
   195 type print_function = string * (int * (string -> print_fn option));
   196 val print_functions = Synchronized.var "Command.print_functions" ([]: print_function list);
   197 
   198 fun output_error tr exn =
   199   List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   200 
   201 fun print_error tr f x =
   202   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution) f x
   203     handle exn => output_error tr exn;
   204 
   205 in
   206 
   207 fun print command_name eval =
   208   rev (Synchronized.value print_functions) |> map_filter (fn (name, (pri, get_print_fn)) =>
   209     (case Exn.capture (Runtime.controlled_execution get_print_fn) command_name of
   210       Exn.Res NONE => NONE
   211     | Exn.Res (SOME print_fn) =>
   212         let
   213           val exec_id = Document_ID.make ();
   214           fun body () =
   215             let
   216               val {failed, command, state = st', ...} = eval_result eval;
   217               val tr = Toplevel.put_id exec_id command;
   218             in if failed then () else print_error tr (fn () => print_fn tr st') () end;
   219         in SOME {name = name, pri = pri, exec_id = exec_id, print = memo body} end
   220     | Exn.Exn exn =>
   221         let
   222           val exec_id = Document_ID.make ();
   223           fun body () =
   224             let
   225               val {command, ...} = eval_result eval;
   226               val tr = Toplevel.put_id exec_id command;
   227             in output_error tr exn end;
   228         in SOME {name = name, pri = pri, exec_id = exec_id, print = memo body} end));
   229 
   230 fun print_function {name, pri} f =
   231   Synchronized.change print_functions (fn funs =>
   232    (if not (AList.defined (op =) funs name) then ()
   233     else warning ("Redefining command print function: " ^ quote name);
   234     AList.update (op =) (name, (pri, f)) funs));
   235 
   236 end;
   237 
   238 val _ =
   239   print_function {name = "print_state", pri = 0} (fn command_name => SOME (fn tr => fn st' =>
   240     let
   241       val is_init = Keyword.is_theory_begin command_name;
   242       val is_proof = Keyword.is_proof command_name;
   243       val do_print =
   244         not is_init andalso
   245           (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   246     in if do_print then Toplevel.print_state false st' else () end));
   247 
   248 
   249 
   250 (** managed evaluation **)
   251 
   252 (* execution *)
   253 
   254 type exec = eval * print list;
   255 val no_exec: exec = (no_eval, []);
   256 
   257 fun exec_ids (({exec_id, ...}, prints): exec) = exec_id :: map #exec_id prints;
   258 
   259 fun exec_result (({eval, ...}, _): exec) = memo_result eval;
   260 
   261 fun exec_run (({eval, ...}, prints): exec) =
   262  (memo_eval eval;
   263   prints |> List.app (fn {name, pri, print, ...} =>
   264     memo_fork {name = name, group = NONE, deps = [], pri = pri, interrupts = true} print));
   265 
   266 
   267 (* stable situations after cancellation *)
   268 
   269 fun stable_goals exec_id =
   270   not (Par_Exn.is_interrupted (Future.join_results (Goal.peek_futures exec_id)));
   271 
   272 fun stable_eval ({exec_id, eval}: eval) =
   273   stable_goals exec_id andalso memo_stable eval;
   274 
   275 fun stable_print ({exec_id, print, ...}: print) =
   276   stable_goals exec_id andalso memo_stable print;
   277 
   278 end;
   279