src/Pure/proofterm.ML
author wenzelm
Sat Aug 20 16:06:27 2011 +0200 (2011-08-20 ago)
changeset 44331 aa9c1e9ef2ce
parent 44330 b28e091f683a
child 44332 e10f6b873f88
permissions -rw-r--r--
clarified fulfill_norm_proof: no join_thms yet;
clarified priority of fulfill_proof_future, which is followed by explicit join_thms;
explicit Thm.future_body_of without join yet;
tuned Thm.future_result: join_promises without fulfill_norm_proof;
     1 (*  Title:      Pure/proofterm.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 LF style proof terms.
     5 *)
     6 
     7 infix 8 % %% %>;
     8 
     9 signature BASIC_PROOFTERM =
    10 sig
    11   val proofs: int Unsynchronized.ref
    12 
    13   datatype proof =
    14      MinProof
    15    | PBound of int
    16    | Abst of string * typ option * proof
    17    | AbsP of string * term option * proof
    18    | op % of proof * term option
    19    | op %% of proof * proof
    20    | Hyp of term
    21    | PAxm of string * term * typ list option
    22    | OfClass of typ * class
    23    | Oracle of string * term * typ list option
    24    | Promise of serial * term * typ list
    25    | PThm of serial * ((string * term * typ list option) * proof_body future)
    26   and proof_body = PBody of
    27     {oracles: (string * term) Ord_List.T,
    28      thms: (serial * (string * term * proof_body future)) Ord_List.T,
    29      proof: proof}
    30 
    31   val %> : proof * term -> proof
    32 end;
    33 
    34 signature PROOFTERM =
    35 sig
    36   include BASIC_PROOFTERM
    37 
    38   type oracle = string * term
    39   type pthm = serial * (string * term * proof_body future)
    40   val check_body_thms: proof_body -> proof_body future
    41   val proof_of: proof_body -> proof
    42   val join_proof: proof_body future -> proof
    43   val fold_proof_atoms: bool -> (proof -> 'a -> 'a) -> proof list -> 'a -> 'a
    44   val fold_body_thms: (string * term * proof_body -> 'a -> 'a) -> proof_body list -> 'a -> 'a
    45   val status_of: proof_body list -> {failed: bool, oracle: bool, unfinished: bool}
    46 
    47   val oracle_ord: oracle * oracle -> order
    48   val thm_ord: pthm * pthm -> order
    49   val merge_oracles: oracle Ord_List.T -> oracle Ord_List.T -> oracle Ord_List.T
    50   val merge_thms: pthm Ord_List.T -> pthm Ord_List.T -> pthm Ord_List.T
    51   val all_oracles_of: proof_body -> oracle Ord_List.T
    52   val approximate_proof_body: proof -> proof_body
    53 
    54   (** primitive operations **)
    55   val proofs_enabled: unit -> bool
    56   val proof_combt: proof * term list -> proof
    57   val proof_combt': proof * term option list -> proof
    58   val proof_combP: proof * proof list -> proof
    59   val strip_combt: proof -> proof * term option list
    60   val strip_combP: proof -> proof * proof list
    61   val strip_thm: proof_body -> proof_body
    62   val map_proof_same: term Same.operation -> typ Same.operation
    63     -> (typ * class -> proof) -> proof Same.operation
    64   val map_proof_terms_same: term Same.operation -> typ Same.operation -> proof Same.operation
    65   val map_proof_types_same: typ Same.operation -> proof Same.operation
    66   val map_proof_terms: (term -> term) -> (typ -> typ) -> proof -> proof
    67   val map_proof_types: (typ -> typ) -> proof -> proof
    68   val fold_proof_terms: (term -> 'a -> 'a) -> (typ -> 'a -> 'a) -> proof -> 'a -> 'a
    69   val maxidx_proof: proof -> int -> int
    70   val size_of_proof: proof -> int
    71   val change_type: typ list option -> proof -> proof
    72   val prf_abstract_over: term -> proof -> proof
    73   val prf_incr_bv: int -> int -> int -> int -> proof -> proof
    74   val incr_pboundvars: int -> int -> proof -> proof
    75   val prf_loose_bvar1: proof -> int -> bool
    76   val prf_loose_Pbvar1: proof -> int -> bool
    77   val prf_add_loose_bnos: int -> int -> proof -> int list * int list -> int list * int list
    78   val norm_proof: Envir.env -> proof -> proof
    79   val norm_proof': Envir.env -> proof -> proof
    80   val prf_subst_bounds: term list -> proof -> proof
    81   val prf_subst_pbounds: proof list -> proof -> proof
    82   val freeze_thaw_prf: proof -> proof * (proof -> proof)
    83 
    84   (** proof terms for specific inference rules **)
    85   val implies_intr_proof: term -> proof -> proof
    86   val implies_intr_proof': term -> proof -> proof
    87   val forall_intr_proof: term -> string -> proof -> proof
    88   val forall_intr_proof': term -> proof -> proof
    89   val varify_proof: term -> (string * sort) list -> proof -> proof
    90   val legacy_freezeT: term -> proof -> proof
    91   val rotate_proof: term list -> term -> int -> proof -> proof
    92   val permute_prems_proof: term list -> int -> int -> proof -> proof
    93   val generalize: string list * string list -> int -> proof -> proof
    94   val instantiate: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
    95     -> proof -> proof
    96   val lift_proof: term -> int -> term -> proof -> proof
    97   val incr_indexes: int -> proof -> proof
    98   val assumption_proof: term list -> term -> int -> proof -> proof
    99   val bicompose_proof: bool -> term list -> term list -> term list -> term option ->
   100     int -> int -> proof -> proof -> proof
   101   val equality_axms: (string * term) list
   102   val reflexive_axm: proof
   103   val symmetric_axm: proof
   104   val transitive_axm: proof
   105   val equal_intr_axm: proof
   106   val equal_elim_axm: proof
   107   val abstract_rule_axm: proof
   108   val combination_axm: proof
   109   val reflexive: proof
   110   val symmetric: proof -> proof
   111   val transitive: term -> typ -> proof -> proof -> proof
   112   val abstract_rule: term -> string -> proof -> proof
   113   val combination: term -> term -> term -> term -> typ -> proof -> proof -> proof
   114   val equal_intr: term -> term -> proof -> proof -> proof
   115   val equal_elim: term -> term -> proof -> proof -> proof
   116   val strip_shyps_proof: Sorts.algebra -> (typ * sort) list -> (typ * sort) list ->
   117     sort list -> proof -> proof
   118   val classrel_proof: theory -> class * class -> proof
   119   val arity_proof: theory -> string * sort list * class -> proof
   120   val of_sort_proof: theory -> (typ * class -> proof) -> typ * sort -> proof list
   121   val install_axclass_proofs:
   122    {classrel_proof: theory -> class * class -> proof,
   123     arity_proof: theory -> string * sort list * class -> proof} -> unit
   124   val axm_proof: string -> term -> proof
   125   val oracle_proof: string -> term -> oracle * proof
   126 
   127   (** rewriting on proof terms **)
   128   val add_prf_rrule: proof * proof -> theory -> theory
   129   val add_prf_rproc: (typ list -> term option list -> proof -> (proof * proof) option) -> theory -> theory
   130   val no_skel: proof
   131   val normal_skel: proof
   132   val rewrite_proof: theory -> (proof * proof) list *
   133     (typ list -> term option list -> proof -> (proof * proof) option) list -> proof -> proof
   134   val rewrite_proof_notypes: (proof * proof) list *
   135     (typ list -> term option list -> proof -> (proof * proof) option) list -> proof -> proof
   136   val rew_proof: theory -> proof -> proof
   137 
   138   val promise_proof: theory -> serial -> term -> proof
   139   val fulfill_norm_proof: theory -> (serial * proof_body) list -> proof_body -> proof_body
   140   val thm_proof: theory -> string -> sort list -> term list -> term ->
   141     (serial * proof_body future) list -> proof_body -> pthm * proof
   142   val unconstrain_thm_proof: theory -> sort list -> term ->
   143     (serial * proof_body future) list -> proof_body -> pthm * proof
   144   val get_name: sort list -> term list -> term -> proof -> string
   145   val guess_name: proof -> string
   146 end
   147 
   148 structure Proofterm : PROOFTERM =
   149 struct
   150 
   151 (***** datatype proof *****)
   152 
   153 datatype proof =
   154    MinProof
   155  | PBound of int
   156  | Abst of string * typ option * proof
   157  | AbsP of string * term option * proof
   158  | op % of proof * term option
   159  | op %% of proof * proof
   160  | Hyp of term
   161  | PAxm of string * term * typ list option
   162  | OfClass of typ * class
   163  | Oracle of string * term * typ list option
   164  | Promise of serial * term * typ list
   165  | PThm of serial * ((string * term * typ list option) * proof_body future)
   166 and proof_body = PBody of
   167   {oracles: (string * term) Ord_List.T,
   168    thms: (serial * (string * term * proof_body future)) Ord_List.T,
   169    proof: proof};
   170 
   171 type oracle = string * term;
   172 type pthm = serial * (string * term * proof_body future);
   173 
   174 fun join_thms (thms: pthm list) = ignore (Future.joins (map (#3 o #2) thms));
   175 
   176 fun check_body_thms (body as PBody {thms, ...}) =
   177   (singleton o Future.cond_forks)
   178     {name = "Proofterm.check_body_thms", group = NONE,
   179       deps = map (Future.task_of o #3 o #2) thms, pri = ~1, interrupts = true}
   180     (fn () => (join_thms thms; body));
   181 
   182 fun proof_of (PBody {proof, ...}) = proof;
   183 val join_proof = Future.join #> proof_of;
   184 
   185 
   186 (***** proof atoms *****)
   187 
   188 fun fold_proof_atoms all f =
   189   let
   190     fun app (Abst (_, _, prf)) = app prf
   191       | app (AbsP (_, _, prf)) = app prf
   192       | app (prf % _) = app prf
   193       | app (prf1 %% prf2) = app prf1 #> app prf2
   194       | app (prf as PThm (i, (_, body))) = (fn (x, seen) =>
   195           if Inttab.defined seen i then (x, seen)
   196           else
   197             let val (x', seen') =
   198               (if all then app (join_proof body) else I) (x, Inttab.update (i, ()) seen)
   199             in (f prf x', seen') end)
   200       | app prf = (fn (x, seen) => (f prf x, seen));
   201   in fn prfs => fn x => #1 (fold app prfs (x, Inttab.empty)) end;
   202 
   203 fun fold_body_thms f =
   204   let
   205     fun app (PBody {thms, ...}) =
   206       tap join_thms thms |> fold (fn (i, (name, prop, body)) => fn (x, seen) =>
   207         if Inttab.defined seen i then (x, seen)
   208         else
   209           let
   210             val body' = Future.join body;
   211             val (x', seen') = app body' (x, Inttab.update (i, ()) seen);
   212           in (f (name, prop, body') x', seen') end);
   213   in fn bodies => fn x => #1 (fold app bodies (x, Inttab.empty)) end;
   214 
   215 fun status_of bodies =
   216   let
   217     fun status (PBody {oracles, thms, ...}) x =
   218       let
   219         val ((oracle, unfinished, failed), seen) =
   220           (thms, x) |-> fold (fn (i, (_, _, body)) => fn (st, seen) =>
   221             if Inttab.defined seen i then (st, seen)
   222             else
   223               let val seen' = Inttab.update (i, ()) seen in
   224                 (case Future.peek body of
   225                   SOME (Exn.Res body') => status body' (st, seen')
   226                 | SOME (Exn.Exn _) =>
   227                     let val (oracle, unfinished, _) = st
   228                     in ((oracle, unfinished, true), seen') end
   229                 | NONE =>
   230                     let val (oracle, _, failed) = st
   231                     in ((oracle, true, failed), seen') end)
   232               end);
   233       in ((oracle orelse not (null oracles), unfinished, failed), seen) end;
   234     val (oracle, unfinished, failed) =
   235       #1 (fold status bodies ((false, false, false), Inttab.empty));
   236   in {oracle = oracle, unfinished = unfinished, failed = failed} end;
   237 
   238 
   239 (* proof body *)
   240 
   241 val oracle_ord = prod_ord fast_string_ord Term_Ord.fast_term_ord;
   242 fun thm_ord ((i, _): pthm, (j, _)) = int_ord (j, i);
   243 
   244 val merge_oracles = Ord_List.union oracle_ord;
   245 val merge_thms = Ord_List.union thm_ord;
   246 
   247 val all_oracles_of =
   248   let
   249     fun collect (PBody {oracles, thms, ...}) =
   250       tap join_thms thms |> fold (fn (i, (_, _, body)) => fn (x, seen) =>
   251         if Inttab.defined seen i then (x, seen)
   252         else
   253           let
   254             val body' = Future.join body;
   255             val (x', seen') = collect body' (x, Inttab.update (i, ()) seen);
   256           in (merge_oracles oracles x', seen') end);
   257   in fn body => #1 (collect body ([], Inttab.empty)) end;
   258 
   259 fun approximate_proof_body prf =
   260   let
   261     val (oracles, thms) = fold_proof_atoms false
   262       (fn Oracle (s, prop, _) => apfst (cons (s, prop))
   263         | PThm (i, ((name, prop, _), body)) => apsnd (cons (i, (name, prop, body)))
   264         | _ => I) [prf] ([], []);
   265   in
   266     PBody
   267      {oracles = Ord_List.make oracle_ord oracles,
   268       thms = Ord_List.make thm_ord thms,
   269       proof = prf}
   270   end;
   271 
   272 
   273 (***** proof objects with different levels of detail *****)
   274 
   275 fun (prf %> t) = prf % SOME t;
   276 
   277 val proof_combt = Library.foldl (op %>);
   278 val proof_combt' = Library.foldl (op %);
   279 val proof_combP = Library.foldl (op %%);
   280 
   281 fun strip_combt prf =
   282     let fun stripc (prf % t, ts) = stripc (prf, t::ts)
   283           | stripc  x =  x
   284     in  stripc (prf, [])  end;
   285 
   286 fun strip_combP prf =
   287     let fun stripc (prf %% prf', prfs) = stripc (prf, prf'::prfs)
   288           | stripc  x =  x
   289     in  stripc (prf, [])  end;
   290 
   291 fun strip_thm (body as PBody {proof, ...}) =
   292   (case strip_combt (fst (strip_combP proof)) of
   293     (PThm (_, (_, body')), _) => Future.join body'
   294   | _ => body);
   295 
   296 val mk_Abst = fold_rev (fn (s, T:typ) => fn prf => Abst (s, NONE, prf));
   297 fun mk_AbsP (i, prf) = funpow i (fn prf => AbsP ("H", NONE, prf)) prf;
   298 
   299 fun map_proof_same term typ ofclass =
   300   let
   301     val typs = Same.map typ;
   302 
   303     fun proof (Abst (s, T, prf)) =
   304           (Abst (s, Same.map_option typ T, Same.commit proof prf)
   305             handle Same.SAME => Abst (s, T, proof prf))
   306       | proof (AbsP (s, t, prf)) =
   307           (AbsP (s, Same.map_option term t, Same.commit proof prf)
   308             handle Same.SAME => AbsP (s, t, proof prf))
   309       | proof (prf % t) =
   310           (proof prf % Same.commit (Same.map_option term) t
   311             handle Same.SAME => prf % Same.map_option term t)
   312       | proof (prf1 %% prf2) =
   313           (proof prf1 %% Same.commit proof prf2
   314             handle Same.SAME => prf1 %% proof prf2)
   315       | proof (PAxm (a, prop, SOME Ts)) = PAxm (a, prop, SOME (typs Ts))
   316       | proof (OfClass T_c) = ofclass T_c
   317       | proof (Oracle (a, prop, SOME Ts)) = Oracle (a, prop, SOME (typs Ts))
   318       | proof (Promise (i, prop, Ts)) = Promise (i, prop, typs Ts)
   319       | proof (PThm (i, ((a, prop, SOME Ts), body))) =
   320           PThm (i, ((a, prop, SOME (typs Ts)), body))
   321       | proof _ = raise Same.SAME;
   322   in proof end;
   323 
   324 fun map_proof_terms_same term typ = map_proof_same term typ (fn (T, c) => OfClass (typ T, c));
   325 fun map_proof_types_same typ = map_proof_terms_same (Term_Subst.map_types_same typ) typ;
   326 
   327 fun same eq f x =
   328   let val x' = f x
   329   in if eq (x, x') then raise Same.SAME else x' end;
   330 
   331 fun map_proof_terms f g = Same.commit (map_proof_terms_same (same (op =) f) (same (op =) g));
   332 fun map_proof_types f = Same.commit (map_proof_types_same (same (op =) f));
   333 
   334 fun fold_proof_terms f g (Abst (_, SOME T, prf)) = g T #> fold_proof_terms f g prf
   335   | fold_proof_terms f g (Abst (_, NONE, prf)) = fold_proof_terms f g prf
   336   | fold_proof_terms f g (AbsP (_, SOME t, prf)) = f t #> fold_proof_terms f g prf
   337   | fold_proof_terms f g (AbsP (_, NONE, prf)) = fold_proof_terms f g prf
   338   | fold_proof_terms f g (prf % SOME t) = fold_proof_terms f g prf #> f t
   339   | fold_proof_terms f g (prf % NONE) = fold_proof_terms f g prf
   340   | fold_proof_terms f g (prf1 %% prf2) =
   341       fold_proof_terms f g prf1 #> fold_proof_terms f g prf2
   342   | fold_proof_terms _ g (PAxm (_, _, SOME Ts)) = fold g Ts
   343   | fold_proof_terms _ g (OfClass (T, _)) = g T
   344   | fold_proof_terms _ g (Oracle (_, _, SOME Ts)) = fold g Ts
   345   | fold_proof_terms _ g (Promise (_, _, Ts)) = fold g Ts
   346   | fold_proof_terms _ g (PThm (_, ((_, _, SOME Ts), _))) = fold g Ts
   347   | fold_proof_terms _ _ _ = I;
   348 
   349 fun maxidx_proof prf = fold_proof_terms Term.maxidx_term Term.maxidx_typ prf;
   350 
   351 fun size_of_proof (Abst (_, _, prf)) = 1 + size_of_proof prf
   352   | size_of_proof (AbsP (_, t, prf)) = 1 + size_of_proof prf
   353   | size_of_proof (prf % _) = 1 + size_of_proof prf
   354   | size_of_proof (prf1 %% prf2) = size_of_proof prf1 + size_of_proof prf2
   355   | size_of_proof _ = 1;
   356 
   357 fun change_type opTs (PAxm (name, prop, _)) = PAxm (name, prop, opTs)
   358   | change_type (SOME [T]) (OfClass (_, c)) = OfClass (T, c)
   359   | change_type opTs (Oracle (name, prop, _)) = Oracle (name, prop, opTs)
   360   | change_type opTs (Promise _) = raise Fail "change_type: unexpected promise"
   361   | change_type opTs (PThm (i, ((name, prop, _), body))) =
   362       PThm (i, ((name, prop, opTs), body))
   363   | change_type _ prf = prf;
   364 
   365 
   366 (***** utilities *****)
   367 
   368 fun strip_abs (_::Ts) (Abs (_, _, t)) = strip_abs Ts t
   369   | strip_abs _ t = t;
   370 
   371 fun mk_abs Ts t = Library.foldl (fn (t', T) => Abs ("", T, t')) (t, Ts);
   372 
   373 
   374 (*Abstraction of a proof term over its occurrences of v,
   375     which must contain no loose bound variables.
   376   The resulting proof term is ready to become the body of an Abst.*)
   377 
   378 fun prf_abstract_over v =
   379   let
   380     fun abst' lev u = if v aconv u then Bound lev else
   381       (case u of
   382          Abs (a, T, t) => Abs (a, T, abst' (lev + 1) t)
   383        | f $ t => (abst' lev f $ absth' lev t handle Same.SAME => f $ abst' lev t)
   384        | _ => raise Same.SAME)
   385     and absth' lev t = (abst' lev t handle Same.SAME => t);
   386 
   387     fun abst lev (AbsP (a, t, prf)) =
   388           (AbsP (a, Same.map_option (abst' lev) t, absth lev prf)
   389            handle Same.SAME => AbsP (a, t, abst lev prf))
   390       | abst lev (Abst (a, T, prf)) = Abst (a, T, abst (lev + 1) prf)
   391       | abst lev (prf1 %% prf2) = (abst lev prf1 %% absth lev prf2
   392           handle Same.SAME => prf1 %% abst lev prf2)
   393       | abst lev (prf % t) = (abst lev prf % Option.map (absth' lev) t
   394           handle Same.SAME => prf % Same.map_option (abst' lev) t)
   395       | abst _ _ = raise Same.SAME
   396     and absth lev prf = (abst lev prf handle Same.SAME => prf);
   397 
   398   in absth 0 end;
   399 
   400 
   401 (*increments a proof term's non-local bound variables
   402   required when moving a proof term within abstractions
   403      inc is  increment for bound variables
   404      lev is  level at which a bound variable is considered 'loose'*)
   405 
   406 fun incr_bv' inct tlev t = incr_bv (inct, tlev, t);
   407 
   408 fun prf_incr_bv' incP inct Plev tlev (PBound i) =
   409       if i >= Plev then PBound (i+incP) else raise Same.SAME
   410   | prf_incr_bv' incP inct Plev tlev (AbsP (a, t, body)) =
   411       (AbsP (a, Same.map_option (same (op =) (incr_bv' inct tlev)) t,
   412          prf_incr_bv incP inct (Plev+1) tlev body) handle Same.SAME =>
   413            AbsP (a, t, prf_incr_bv' incP inct (Plev+1) tlev body))
   414   | prf_incr_bv' incP inct Plev tlev (Abst (a, T, body)) =
   415       Abst (a, T, prf_incr_bv' incP inct Plev (tlev+1) body)
   416   | prf_incr_bv' incP inct Plev tlev (prf %% prf') =
   417       (prf_incr_bv' incP inct Plev tlev prf %% prf_incr_bv incP inct Plev tlev prf'
   418        handle Same.SAME => prf %% prf_incr_bv' incP inct Plev tlev prf')
   419   | prf_incr_bv' incP inct Plev tlev (prf % t) =
   420       (prf_incr_bv' incP inct Plev tlev prf % Option.map (incr_bv' inct tlev) t
   421        handle Same.SAME => prf % Same.map_option (same (op =) (incr_bv' inct tlev)) t)
   422   | prf_incr_bv' _ _ _ _ _ = raise Same.SAME
   423 and prf_incr_bv incP inct Plev tlev prf =
   424       (prf_incr_bv' incP inct Plev tlev prf handle Same.SAME => prf);
   425 
   426 fun incr_pboundvars  0 0 prf = prf
   427   | incr_pboundvars incP inct prf = prf_incr_bv incP inct 0 0 prf;
   428 
   429 
   430 fun prf_loose_bvar1 (prf1 %% prf2) k = prf_loose_bvar1 prf1 k orelse prf_loose_bvar1 prf2 k
   431   | prf_loose_bvar1 (prf % SOME t) k = prf_loose_bvar1 prf k orelse loose_bvar1 (t, k)
   432   | prf_loose_bvar1 (_ % NONE) _ = true
   433   | prf_loose_bvar1 (AbsP (_, SOME t, prf)) k = loose_bvar1 (t, k) orelse prf_loose_bvar1 prf k
   434   | prf_loose_bvar1 (AbsP (_, NONE, _)) k = true
   435   | prf_loose_bvar1 (Abst (_, _, prf)) k = prf_loose_bvar1 prf (k+1)
   436   | prf_loose_bvar1 _ _ = false;
   437 
   438 fun prf_loose_Pbvar1 (PBound i) k = i = k
   439   | prf_loose_Pbvar1 (prf1 %% prf2) k = prf_loose_Pbvar1 prf1 k orelse prf_loose_Pbvar1 prf2 k
   440   | prf_loose_Pbvar1 (prf % _) k = prf_loose_Pbvar1 prf k
   441   | prf_loose_Pbvar1 (AbsP (_, _, prf)) k = prf_loose_Pbvar1 prf (k+1)
   442   | prf_loose_Pbvar1 (Abst (_, _, prf)) k = prf_loose_Pbvar1 prf k
   443   | prf_loose_Pbvar1 _ _ = false;
   444 
   445 fun prf_add_loose_bnos plev tlev (PBound i) (is, js) =
   446       if i < plev then (is, js) else (insert (op =) (i-plev) is, js)
   447   | prf_add_loose_bnos plev tlev (prf1 %% prf2) p =
   448       prf_add_loose_bnos plev tlev prf2
   449         (prf_add_loose_bnos plev tlev prf1 p)
   450   | prf_add_loose_bnos plev tlev (prf % opt) (is, js) =
   451       prf_add_loose_bnos plev tlev prf (case opt of
   452           NONE => (is, insert (op =) ~1 js)
   453         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   454   | prf_add_loose_bnos plev tlev (AbsP (_, opt, prf)) (is, js) =
   455       prf_add_loose_bnos (plev+1) tlev prf (case opt of
   456           NONE => (is, insert (op =) ~1 js)
   457         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   458   | prf_add_loose_bnos plev tlev (Abst (_, _, prf)) p =
   459       prf_add_loose_bnos plev (tlev+1) prf p
   460   | prf_add_loose_bnos _ _ _ _ = ([], []);
   461 
   462 
   463 (**** substitutions ****)
   464 
   465 fun del_conflicting_tvars envT T = Term_Subst.instantiateT
   466   (map_filter (fn ixnS as (_, S) =>
   467      (Type.lookup envT ixnS; NONE) handle TYPE _ =>
   468         SOME (ixnS, TFree ("'dummy", S))) (Term.add_tvarsT T [])) T;
   469 
   470 fun del_conflicting_vars env t = Term_Subst.instantiate
   471   (map_filter (fn ixnS as (_, S) =>
   472      (Type.lookup (Envir.type_env env) ixnS; NONE) handle TYPE _ =>
   473         SOME (ixnS, TFree ("'dummy", S))) (Term.add_tvars t []),
   474    map_filter (fn (ixnT as (_, T)) =>
   475      (Envir.lookup (env, ixnT); NONE) handle TYPE _ =>
   476         SOME (ixnT, Free ("dummy", T))) (Term.add_vars t [])) t;
   477 
   478 fun norm_proof env =
   479   let
   480     val envT = Envir.type_env env;
   481     fun msg s = warning ("type conflict in norm_proof:\n" ^ s);
   482     fun htype f t = f env t handle TYPE (s, _, _) =>
   483       (msg s; f env (del_conflicting_vars env t));
   484     fun htypeT f T = f envT T handle TYPE (s, _, _) =>
   485       (msg s; f envT (del_conflicting_tvars envT T));
   486     fun htypeTs f Ts = f envT Ts handle TYPE (s, _, _) =>
   487       (msg s; f envT (map (del_conflicting_tvars envT) Ts));
   488 
   489     fun norm (Abst (s, T, prf)) =
   490           (Abst (s, Same.map_option (htypeT Envir.norm_type_same) T, Same.commit norm prf)
   491             handle Same.SAME => Abst (s, T, norm prf))
   492       | norm (AbsP (s, t, prf)) =
   493           (AbsP (s, Same.map_option (htype Envir.norm_term_same) t, Same.commit norm prf)
   494             handle Same.SAME => AbsP (s, t, norm prf))
   495       | norm (prf % t) =
   496           (norm prf % Option.map (htype Envir.norm_term) t
   497             handle Same.SAME => prf % Same.map_option (htype Envir.norm_term_same) t)
   498       | norm (prf1 %% prf2) =
   499           (norm prf1 %% Same.commit norm prf2
   500             handle Same.SAME => prf1 %% norm prf2)
   501       | norm (PAxm (s, prop, Ts)) =
   502           PAxm (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   503       | norm (OfClass (T, c)) =
   504           OfClass (htypeT Envir.norm_type_same T, c)
   505       | norm (Oracle (s, prop, Ts)) =
   506           Oracle (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   507       | norm (Promise (i, prop, Ts)) =
   508           Promise (i, prop, htypeTs Envir.norm_types_same Ts)
   509       | norm (PThm (i, ((s, t, Ts), body))) =
   510           PThm (i, ((s, t, Same.map_option (htypeTs Envir.norm_types_same) Ts), body))
   511       | norm _ = raise Same.SAME;
   512   in Same.commit norm end;
   513 
   514 
   515 (***** Remove some types in proof term (to save space) *****)
   516 
   517 fun remove_types (Abs (s, _, t)) = Abs (s, dummyT, remove_types t)
   518   | remove_types (t $ u) = remove_types t $ remove_types u
   519   | remove_types (Const (s, _)) = Const (s, dummyT)
   520   | remove_types t = t;
   521 
   522 fun remove_types_env (Envir.Envir {maxidx, tenv, tyenv}) =
   523   Envir.Envir {maxidx = maxidx, tenv = Vartab.map (K (apsnd remove_types)) tenv, tyenv = tyenv};
   524 
   525 fun norm_proof' env prf = norm_proof (remove_types_env env) prf;
   526 
   527 
   528 (**** substitution of bound variables ****)
   529 
   530 fun prf_subst_bounds args prf =
   531   let
   532     val n = length args;
   533     fun subst' lev (Bound i) =
   534          (if i<lev then raise Same.SAME    (*var is locally bound*)
   535           else  incr_boundvars lev (nth args (i-lev))
   536                   handle General.Subscript => Bound (i-n))  (*loose: change it*)
   537       | subst' lev (Abs (a, T, body)) = Abs (a, T,  subst' (lev+1) body)
   538       | subst' lev (f $ t) = (subst' lev f $ substh' lev t
   539           handle Same.SAME => f $ subst' lev t)
   540       | subst' _ _ = raise Same.SAME
   541     and substh' lev t = (subst' lev t handle Same.SAME => t);
   542 
   543     fun subst lev (AbsP (a, t, body)) =
   544         (AbsP (a, Same.map_option (subst' lev) t, substh lev body)
   545           handle Same.SAME => AbsP (a, t, subst lev body))
   546       | subst lev (Abst (a, T, body)) = Abst (a, T, subst (lev+1) body)
   547       | subst lev (prf %% prf') = (subst lev prf %% substh lev prf'
   548           handle Same.SAME => prf %% subst lev prf')
   549       | subst lev (prf % t) = (subst lev prf % Option.map (substh' lev) t
   550           handle Same.SAME => prf % Same.map_option (subst' lev) t)
   551       | subst _ _ = raise Same.SAME
   552     and substh lev prf = (subst lev prf handle Same.SAME => prf);
   553   in case args of [] => prf | _ => substh 0 prf end;
   554 
   555 fun prf_subst_pbounds args prf =
   556   let
   557     val n = length args;
   558     fun subst (PBound i) Plev tlev =
   559          (if i < Plev then raise Same.SAME    (*var is locally bound*)
   560           else incr_pboundvars Plev tlev (nth args (i-Plev))
   561                  handle General.Subscript => PBound (i-n)  (*loose: change it*))
   562       | subst (AbsP (a, t, body)) Plev tlev = AbsP (a, t, subst body (Plev+1) tlev)
   563       | subst (Abst (a, T, body)) Plev tlev = Abst (a, T, subst body Plev (tlev+1))
   564       | subst (prf %% prf') Plev tlev = (subst prf Plev tlev %% substh prf' Plev tlev
   565           handle Same.SAME => prf %% subst prf' Plev tlev)
   566       | subst (prf % t) Plev tlev = subst prf Plev tlev % t
   567       | subst  prf _ _ = raise Same.SAME
   568     and substh prf Plev tlev = (subst prf Plev tlev handle Same.SAME => prf)
   569   in case args of [] => prf | _ => substh prf 0 0 end;
   570 
   571 
   572 (**** Freezing and thawing of variables in proof terms ****)
   573 
   574 local
   575 
   576 fun frzT names =
   577   map_type_tvar (fn (ixn, S) => TFree (the (AList.lookup (op =) names ixn), S));
   578 
   579 fun thawT names =
   580   map_type_tfree (fn (a, S) =>
   581     (case AList.lookup (op =) names a of
   582       NONE => TFree (a, S)
   583     | SOME ixn => TVar (ixn, S)));
   584 
   585 fun freeze names names' (t $ u) =
   586       freeze names names' t $ freeze names names' u
   587   | freeze names names' (Abs (s, T, t)) =
   588       Abs (s, frzT names' T, freeze names names' t)
   589   | freeze names names' (Const (s, T)) = Const (s, frzT names' T)
   590   | freeze names names' (Free (s, T)) = Free (s, frzT names' T)
   591   | freeze names names' (Var (ixn, T)) =
   592       Free (the (AList.lookup (op =) names ixn), frzT names' T)
   593   | freeze names names' t = t;
   594 
   595 fun thaw names names' (t $ u) =
   596       thaw names names' t $ thaw names names' u
   597   | thaw names names' (Abs (s, T, t)) =
   598       Abs (s, thawT names' T, thaw names names' t)
   599   | thaw names names' (Const (s, T)) = Const (s, thawT names' T)
   600   | thaw names names' (Free (s, T)) =
   601       let val T' = thawT names' T in
   602         (case AList.lookup (op =) names s of
   603           NONE => Free (s, T')
   604         | SOME ixn => Var (ixn, T'))
   605       end
   606   | thaw names names' (Var (ixn, T)) = Var (ixn, thawT names' T)
   607   | thaw names names' t = t;
   608 
   609 in
   610 
   611 fun freeze_thaw_prf prf =
   612   let
   613     val (fs, Tfs, vs, Tvs) = fold_proof_terms
   614       (fn t => fn (fs, Tfs, vs, Tvs) =>
   615          (Term.add_free_names t fs, Term.add_tfree_names t Tfs,
   616           Term.add_var_names t vs, Term.add_tvar_names t Tvs))
   617       (fn T => fn (fs, Tfs, vs, Tvs) =>
   618          (fs, Term.add_tfree_namesT T Tfs,
   619           vs, Term.add_tvar_namesT T Tvs))
   620       prf ([], [], [], []);
   621     val names = vs ~~ Name.variant_list fs (map fst vs);
   622     val names' = Tvs ~~ Name.variant_list Tfs (map fst Tvs);
   623     val rnames = map swap names;
   624     val rnames' = map swap names';
   625   in
   626     (map_proof_terms (freeze names names') (frzT names') prf,
   627      map_proof_terms (thaw rnames rnames') (thawT rnames'))
   628   end;
   629 
   630 end;
   631 
   632 
   633 (***** implication introduction *****)
   634 
   635 fun gen_implies_intr_proof f h prf =
   636   let
   637     fun abshyp i (Hyp t) = if h aconv t then PBound i else raise Same.SAME
   638       | abshyp i (Abst (s, T, prf)) = Abst (s, T, abshyp i prf)
   639       | abshyp i (AbsP (s, t, prf)) = AbsP (s, t, abshyp (i + 1) prf)
   640       | abshyp i (prf % t) = abshyp i prf % t
   641       | abshyp i (prf1 %% prf2) =
   642           (abshyp i prf1 %% abshyph i prf2
   643             handle Same.SAME => prf1 %% abshyp i prf2)
   644       | abshyp _ _ = raise Same.SAME
   645     and abshyph i prf = (abshyp i prf handle Same.SAME => prf);
   646   in
   647     AbsP ("H", f h, abshyph 0 prf)
   648   end;
   649 
   650 val implies_intr_proof = gen_implies_intr_proof (K NONE);
   651 val implies_intr_proof' = gen_implies_intr_proof SOME;
   652 
   653 
   654 (***** forall introduction *****)
   655 
   656 fun forall_intr_proof x a prf = Abst (a, NONE, prf_abstract_over x prf);
   657 
   658 fun forall_intr_proof' t prf =
   659   let val (a, T) = (case t of Var ((a, _), T) => (a, T) | Free p => p)
   660   in Abst (a, SOME T, prf_abstract_over t prf) end;
   661 
   662 
   663 (***** varify *****)
   664 
   665 fun varify_proof t fixed prf =
   666   let
   667     val fs = Term.fold_types (Term.fold_atyps
   668       (fn TFree v => if member (op =) fixed v then I else insert (op =) v | _ => I)) t [];
   669     val used = Name.context
   670       |> fold_types (fold_atyps (fn TVar ((a, _), _) => Name.declare a | _ => I)) t;
   671     val fmap = fs ~~ #1 (fold_map Name.variant (map fst fs) used);
   672     fun thaw (f as (a, S)) =
   673       (case AList.lookup (op =) fmap f of
   674         NONE => TFree f
   675       | SOME b => TVar ((b, 0), S));
   676   in map_proof_terms (map_types (map_type_tfree thaw)) (map_type_tfree thaw) prf end;
   677 
   678 
   679 local
   680 
   681 fun new_name ix (pairs, used) =
   682   let val v = singleton (Name.variant_list used) (string_of_indexname ix)
   683   in ((ix, v) :: pairs, v :: used) end;
   684 
   685 fun freeze_one alist (ix, sort) =
   686   (case AList.lookup (op =) alist ix of
   687     NONE => TVar (ix, sort)
   688   | SOME name => TFree (name, sort));
   689 
   690 in
   691 
   692 fun legacy_freezeT t prf =
   693   let
   694     val used = Term.add_tfree_names t [];
   695     val (alist, _) = fold_rev new_name (map #1 (Term.add_tvars t [])) ([], used);
   696   in
   697     (case alist of
   698       [] => prf (*nothing to do!*)
   699     | _ =>
   700         let val frzT = map_type_tvar (freeze_one alist)
   701         in map_proof_terms (map_types frzT) frzT prf end)
   702   end;
   703 
   704 end;
   705 
   706 
   707 (***** rotate assumptions *****)
   708 
   709 fun rotate_proof Bs Bi m prf =
   710   let
   711     val params = Term.strip_all_vars Bi;
   712     val asms = Logic.strip_imp_prems (Term.strip_all_body Bi);
   713     val i = length asms;
   714     val j = length Bs;
   715   in
   716     mk_AbsP (j+1, proof_combP (prf, map PBound
   717       (j downto 1) @ [mk_Abst params (mk_AbsP (i,
   718         proof_combP (proof_combt (PBound i, map Bound ((length params - 1) downto 0)),
   719           map PBound (((i-m-1) downto 0) @ ((i-1) downto (i-m))))))]))
   720   end;
   721 
   722 
   723 (***** permute premises *****)
   724 
   725 fun permute_prems_proof prems j k prf =
   726   let val n = length prems
   727   in mk_AbsP (n, proof_combP (prf,
   728     map PBound ((n-1 downto n-j) @ (k-1 downto 0) @ (n-j-1 downto k))))
   729   end;
   730 
   731 
   732 (***** generalization *****)
   733 
   734 fun generalize (tfrees, frees) idx =
   735   Same.commit (map_proof_terms_same
   736     (Term_Subst.generalize_same (tfrees, frees) idx)
   737     (Term_Subst.generalizeT_same tfrees idx));
   738 
   739 
   740 (***** instantiation *****)
   741 
   742 fun instantiate (instT, inst) =
   743   Same.commit (map_proof_terms_same
   744     (Term_Subst.instantiate_same (instT, map (apsnd remove_types) inst))
   745     (Term_Subst.instantiateT_same instT));
   746 
   747 
   748 (***** lifting *****)
   749 
   750 fun lift_proof Bi inc prop prf =
   751   let
   752     fun lift'' Us Ts t =
   753       strip_abs Ts (Logic.incr_indexes (Us, inc) (mk_abs Ts t));
   754 
   755     fun lift' Us Ts (Abst (s, T, prf)) =
   756           (Abst (s, Same.map_option (Logic.incr_tvar_same inc) T, lifth' Us (dummyT::Ts) prf)
   757            handle Same.SAME => Abst (s, T, lift' Us (dummyT::Ts) prf))
   758       | lift' Us Ts (AbsP (s, t, prf)) =
   759           (AbsP (s, Same.map_option (same (op =) (lift'' Us Ts)) t, lifth' Us Ts prf)
   760            handle Same.SAME => AbsP (s, t, lift' Us Ts prf))
   761       | lift' Us Ts (prf % t) = (lift' Us Ts prf % Option.map (lift'' Us Ts) t
   762           handle Same.SAME => prf % Same.map_option (same (op =) (lift'' Us Ts)) t)
   763       | lift' Us Ts (prf1 %% prf2) = (lift' Us Ts prf1 %% lifth' Us Ts prf2
   764           handle Same.SAME => prf1 %% lift' Us Ts prf2)
   765       | lift' _ _ (PAxm (s, prop, Ts)) =
   766           PAxm (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   767       | lift' _ _ (OfClass (T, c)) =
   768           OfClass (Logic.incr_tvar_same inc T, c)
   769       | lift' _ _ (Oracle (s, prop, Ts)) =
   770           Oracle (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   771       | lift' _ _ (Promise (i, prop, Ts)) =
   772           Promise (i, prop, Same.map (Logic.incr_tvar_same inc) Ts)
   773       | lift' _ _ (PThm (i, ((s, prop, Ts), body))) =
   774           PThm (i, ((s, prop, (Same.map_option o Same.map) (Logic.incr_tvar inc) Ts), body))
   775       | lift' _ _ _ = raise Same.SAME
   776     and lifth' Us Ts prf = (lift' Us Ts prf handle Same.SAME => prf);
   777 
   778     val ps = map (Logic.lift_all inc Bi) (Logic.strip_imp_prems prop);
   779     val k = length ps;
   780 
   781     fun mk_app b (i, j, prf) =
   782           if b then (i-1, j, prf %% PBound i) else (i, j-1, prf %> Bound j);
   783 
   784     fun lift Us bs i j (Const ("==>", _) $ A $ B) =
   785             AbsP ("H", NONE (*A*), lift Us (true::bs) (i+1) j B)
   786       | lift Us bs i j (Const ("all", _) $ Abs (a, T, t)) =
   787             Abst (a, NONE (*T*), lift (T::Us) (false::bs) i (j+1) t)
   788       | lift Us bs i j _ = proof_combP (lifth' (rev Us) [] prf,
   789             map (fn k => (#3 (fold_rev mk_app bs (i-1, j-1, PBound k))))
   790               (i + k - 1 downto i));
   791   in
   792     mk_AbsP (k, lift [] [] 0 0 Bi)
   793   end;
   794 
   795 fun incr_indexes i =
   796   Same.commit (map_proof_terms_same
   797     (Logic.incr_indexes_same ([], i)) (Logic.incr_tvar_same i));
   798 
   799 
   800 (***** proof by assumption *****)
   801 
   802 fun mk_asm_prf t i m =
   803   let
   804     fun imp_prf _ i 0 = PBound i
   805       | imp_prf (Const ("==>", _) $ A $ B) i m = AbsP ("H", NONE (*A*), imp_prf B (i+1) (m-1))
   806       | imp_prf _ i _ = PBound i;
   807     fun all_prf (Const ("all", _) $ Abs (a, T, t)) = Abst (a, NONE (*T*), all_prf t)
   808       | all_prf t = imp_prf t (~i) m
   809   in all_prf t end;
   810 
   811 fun assumption_proof Bs Bi n prf =
   812   mk_AbsP (length Bs, proof_combP (prf,
   813     map PBound (length Bs - 1 downto 0) @ [mk_asm_prf Bi n ~1]));
   814 
   815 
   816 (***** Composition of object rule with proof state *****)
   817 
   818 fun flatten_params_proof i j n (Const ("==>", _) $ A $ B, k) =
   819       AbsP ("H", NONE (*A*), flatten_params_proof (i+1) j n (B, k))
   820   | flatten_params_proof i j n (Const ("all", _) $ Abs (a, T, t), k) =
   821       Abst (a, NONE (*T*), flatten_params_proof i (j+1) n (t, k))
   822   | flatten_params_proof i j n (_, k) = proof_combP (proof_combt (PBound (k+i),
   823       map Bound (j-1 downto 0)), map PBound (remove (op =) (i-n) (i-1 downto 0)));
   824 
   825 fun bicompose_proof flatten Bs oldAs newAs A n m rprf sprf =
   826   let
   827     val la = length newAs;
   828     val lb = length Bs;
   829   in
   830     mk_AbsP (lb+la, proof_combP (sprf,
   831       map PBound (lb + la - 1 downto la)) %%
   832         proof_combP (rprf, (if n>0 then [mk_asm_prf (the A) n m] else []) @
   833           map (if flatten then flatten_params_proof 0 0 n else PBound o snd)
   834             (oldAs ~~ (la - 1 downto 0))))
   835   end;
   836 
   837 
   838 (***** axioms for equality *****)
   839 
   840 val aT = TFree ("'a", []);
   841 val bT = TFree ("'b", []);
   842 val x = Free ("x", aT);
   843 val y = Free ("y", aT);
   844 val z = Free ("z", aT);
   845 val A = Free ("A", propT);
   846 val B = Free ("B", propT);
   847 val f = Free ("f", aT --> bT);
   848 val g = Free ("g", aT --> bT);
   849 
   850 val equality_axms =
   851  [("reflexive", Logic.mk_equals (x, x)),
   852   ("symmetric", Logic.mk_implies (Logic.mk_equals (x, y), Logic.mk_equals (y, x))),
   853   ("transitive",
   854     Logic.list_implies ([Logic.mk_equals (x, y), Logic.mk_equals (y, z)], Logic.mk_equals (x, z))),
   855   ("equal_intr",
   856     Logic.list_implies ([Logic.mk_implies (A, B), Logic.mk_implies (B, A)], Logic.mk_equals (A, B))),
   857   ("equal_elim", Logic.list_implies ([Logic.mk_equals (A, B), A], B)),
   858   ("abstract_rule",
   859     Logic.mk_implies
   860       (Logic.all x
   861         (Logic.mk_equals (f $ x, g $ x)), Logic.mk_equals (lambda x (f $ x), lambda x (g $ x)))),
   862   ("combination", Logic.list_implies
   863     ([Logic.mk_equals (f, g), Logic.mk_equals (x, y)], Logic.mk_equals (f $ x, g $ y)))];
   864 
   865 val [reflexive_axm, symmetric_axm, transitive_axm, equal_intr_axm,
   866   equal_elim_axm, abstract_rule_axm, combination_axm] =
   867     map (fn (s, t) => PAxm ("Pure." ^ s, Logic.varify_global t, NONE)) equality_axms;
   868 
   869 val reflexive = reflexive_axm % NONE;
   870 
   871 fun symmetric (prf as PAxm ("Pure.reflexive", _, _) % _) = prf
   872   | symmetric prf = symmetric_axm % NONE % NONE %% prf;
   873 
   874 fun transitive _ _ (PAxm ("Pure.reflexive", _, _) % _) prf2 = prf2
   875   | transitive _ _ prf1 (PAxm ("Pure.reflexive", _, _) % _) = prf1
   876   | transitive u (Type ("prop", [])) prf1 prf2 =
   877       transitive_axm % NONE % SOME (remove_types u) % NONE %% prf1 %% prf2
   878   | transitive u T prf1 prf2 =
   879       transitive_axm % NONE % NONE % NONE %% prf1 %% prf2;
   880 
   881 fun abstract_rule x a prf =
   882   abstract_rule_axm % NONE % NONE %% forall_intr_proof x a prf;
   883 
   884 fun check_comb (PAxm ("Pure.combination", _, _) % f % g % _ % _ %% prf %% _) =
   885       is_some f orelse check_comb prf
   886   | check_comb (PAxm ("Pure.transitive", _, _) % _ % _ % _ %% prf1 %% prf2) =
   887       check_comb prf1 andalso check_comb prf2
   888   | check_comb (PAxm ("Pure.symmetric", _, _) % _ % _ %% prf) = check_comb prf
   889   | check_comb _ = false;
   890 
   891 fun combination f g t u (Type (_, [T, U])) prf1 prf2 =
   892   let
   893     val f = Envir.beta_norm f;
   894     val g = Envir.beta_norm g;
   895     val prf =
   896       if check_comb prf1 then
   897         combination_axm % NONE % NONE
   898       else
   899         (case prf1 of
   900           PAxm ("Pure.reflexive", _, _) % _ =>
   901             combination_axm %> remove_types f % NONE
   902         | _ => combination_axm %> remove_types f %> remove_types g)
   903   in
   904     (case T of
   905       Type ("fun", _) => prf %
   906         (case head_of f of
   907           Abs _ => SOME (remove_types t)
   908         | Var _ => SOME (remove_types t)
   909         | _ => NONE) %
   910         (case head_of g of
   911            Abs _ => SOME (remove_types u)
   912         | Var _ => SOME (remove_types u)
   913         | _ => NONE) %% prf1 %% prf2
   914      | _ => prf % NONE % NONE %% prf1 %% prf2)
   915   end;
   916 
   917 fun equal_intr A B prf1 prf2 =
   918   equal_intr_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   919 
   920 fun equal_elim A B prf1 prf2 =
   921   equal_elim_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   922 
   923 
   924 (**** type classes ****)
   925 
   926 fun strip_shyps_proof algebra present witnessed extra_sorts prf =
   927   let
   928     fun get S2 (T, S1) = if Sorts.sort_le algebra (S1, S2) then SOME T else NONE;
   929     val extra = map (fn S => (TFree ("'dummy", S), S)) extra_sorts;
   930     val replacements = present @ extra @ witnessed;
   931     fun replace T =
   932       if exists (fn (T', _) => T' = T) present then raise Same.SAME
   933       else
   934         (case get_first (get (Type.sort_of_atyp T)) replacements of
   935           SOME T' => T'
   936         | NONE => raise Fail "strip_shyps_proof: bad type variable in proof term");
   937   in Same.commit (map_proof_types_same (Term_Subst.map_atypsT_same replace)) prf end;
   938 
   939 
   940 local
   941 
   942 type axclass_proofs =
   943  {classrel_proof: theory -> class * class -> proof,
   944   arity_proof: theory -> string * sort list * class -> proof};
   945 
   946 val axclass_proofs: axclass_proofs Single_Assignment.var =
   947   Single_Assignment.var "Proofterm.axclass_proofs";
   948 
   949 fun axclass_proof which thy x =
   950   (case Single_Assignment.peek axclass_proofs of
   951     NONE => raise Fail "Axclass proof operations not installed"
   952   | SOME prfs => which prfs thy x);
   953 
   954 in
   955 
   956 val classrel_proof = axclass_proof #classrel_proof;
   957 val arity_proof = axclass_proof #arity_proof;
   958 
   959 fun install_axclass_proofs prfs = Single_Assignment.assign axclass_proofs prfs;
   960 
   961 end;
   962 
   963 
   964 local
   965 
   966 fun canonical_instance typs =
   967   let
   968     val names = Name.invent Name.context Name.aT (length typs);
   969     val instT = map2 (fn a => fn T => (((a, 0), []), Type.strip_sorts T)) names typs;
   970   in instantiate (instT, []) end;
   971 
   972 in
   973 
   974 fun of_sort_proof thy hyps =
   975   Sorts.of_sort_derivation (Sign.classes_of thy)
   976    {class_relation = fn typ => fn (prf, c1) => fn c2 =>
   977       if c1 = c2 then prf
   978       else canonical_instance [typ] (classrel_proof thy (c1, c2)) %% prf,
   979     type_constructor = fn (a, typs) => fn dom => fn c =>
   980       let val Ss = map (map snd) dom and prfs = maps (map fst) dom
   981       in proof_combP (canonical_instance typs (arity_proof thy (a, Ss, c)), prfs) end,
   982     type_variable = fn typ => map (fn c => (hyps (typ, c), c)) (Type.sort_of_atyp typ)};
   983 
   984 end;
   985 
   986 
   987 (***** axioms and theorems *****)
   988 
   989 val proofs = Unsynchronized.ref 2;
   990 fun proofs_enabled () = ! proofs >= 2;
   991 
   992 fun vars_of t = map Var (rev (Term.add_vars t []));
   993 fun frees_of t = map Free (rev (Term.add_frees t []));
   994 
   995 fun test_args _ [] = true
   996   | test_args is (Bound i :: ts) =
   997       not (member (op =) is i) andalso test_args (i :: is) ts
   998   | test_args _ _ = false;
   999 
  1000 fun is_fun (Type ("fun", _)) = true
  1001   | is_fun (TVar _) = true
  1002   | is_fun _ = false;
  1003 
  1004 fun add_funvars Ts (vs, t) =
  1005   if is_fun (fastype_of1 (Ts, t)) then
  1006     union (op =) vs (map_filter (fn Var (ixn, T) =>
  1007       if is_fun T then SOME ixn else NONE | _ => NONE) (vars_of t))
  1008   else vs;
  1009 
  1010 fun add_npvars q p Ts (vs, Const ("==>", _) $ t $ u) =
  1011       add_npvars q p Ts (add_npvars q (not p) Ts (vs, t), u)
  1012   | add_npvars q p Ts (vs, Const ("all", Type (_, [Type (_, [T, _]), _])) $ t) =
  1013       add_npvars q p Ts (vs, if p andalso q then betapply (t, Var (("",0), T)) else t)
  1014   | add_npvars q p Ts (vs, Abs (_, T, t)) = add_npvars q p (T::Ts) (vs, t)
  1015   | add_npvars _ _ Ts (vs, t) = add_npvars' Ts (vs, t)
  1016 and add_npvars' Ts (vs, t) = (case strip_comb t of
  1017     (Var (ixn, _), ts) => if test_args [] ts then vs
  1018       else Library.foldl (add_npvars' Ts)
  1019         (AList.update (op =) (ixn,
  1020           Library.foldl (add_funvars Ts) ((these ooo AList.lookup) (op =) vs ixn, ts)) vs, ts)
  1021   | (Abs (_, T, u), ts) => Library.foldl (add_npvars' (T::Ts)) (vs, u :: ts)
  1022   | (_, ts) => Library.foldl (add_npvars' Ts) (vs, ts));
  1023 
  1024 fun prop_vars (Const ("==>", _) $ P $ Q) = union (op =) (prop_vars P) (prop_vars Q)
  1025   | prop_vars (Const ("all", _) $ Abs (_, _, t)) = prop_vars t
  1026   | prop_vars t = (case strip_comb t of
  1027       (Var (ixn, _), _) => [ixn] | _ => []);
  1028 
  1029 fun is_proj t =
  1030   let
  1031     fun is_p i t = (case strip_comb t of
  1032         (Bound j, []) => false
  1033       | (Bound j, ts) => j >= i orelse exists (is_p i) ts
  1034       | (Abs (_, _, u), _) => is_p (i+1) u
  1035       | (_, ts) => exists (is_p i) ts)
  1036   in (case strip_abs_body t of
  1037         Bound _ => true
  1038       | t' => is_p 0 t')
  1039   end;
  1040 
  1041 fun needed_vars prop =
  1042   union (op =) (Library.foldl (uncurry (union (op =)))
  1043     ([], map (uncurry (insert (op =))) (add_npvars true true [] ([], prop))))
  1044   (prop_vars prop);
  1045 
  1046 fun gen_axm_proof c name prop =
  1047   let
  1048     val nvs = needed_vars prop;
  1049     val args = map (fn (v as Var (ixn, _)) =>
  1050         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1051       map SOME (frees_of prop);
  1052   in
  1053     proof_combt' (c (name, prop, NONE), args)
  1054   end;
  1055 
  1056 val axm_proof = gen_axm_proof PAxm;
  1057 
  1058 val dummy = Const (Term.dummy_patternN, dummyT);
  1059 
  1060 fun oracle_proof name prop =
  1061   if ! proofs = 0 then ((name, dummy), Oracle (name, dummy, NONE))
  1062   else ((name, prop), gen_axm_proof Oracle name prop);
  1063 
  1064 fun shrink_proof thy =
  1065   let
  1066     val (typ, term) = Term_Sharing.init thy;
  1067 
  1068     fun shrink ls lev (prf as Abst (a, T, body)) =
  1069           let val (b, is, ch, body') = shrink ls (lev+1) body
  1070           in (b, is, ch, if ch then Abst (a, Option.map typ T, body') else prf) end
  1071       | shrink ls lev (prf as AbsP (a, t, body)) =
  1072           let val (b, is, ch, body') = shrink (lev::ls) lev body
  1073           in (b orelse member (op =) is 0, map_filter (fn 0 => NONE | i => SOME (i-1)) is,
  1074             ch, if ch then AbsP (a, Option.map term t, body') else prf)
  1075           end
  1076       | shrink ls lev prf =
  1077           let val (is, ch, _, prf') = shrink' ls lev [] [] prf
  1078           in (false, is, ch, prf') end
  1079     and shrink' ls lev ts prfs (prf as prf1 %% prf2) =
  1080           let
  1081             val p as (_, is', ch', prf') = shrink ls lev prf2;
  1082             val (is, ch, ts', prf'') = shrink' ls lev ts (p::prfs) prf1
  1083           in (union (op =) is is', ch orelse ch', ts',
  1084               if ch orelse ch' then prf'' %% prf' else prf)
  1085           end
  1086       | shrink' ls lev ts prfs (prf as prf1 % t) =
  1087           let val (is, ch, (ch', t')::ts', prf') = shrink' ls lev (t::ts) prfs prf1
  1088           in (is, ch orelse ch', ts',
  1089               if ch orelse ch' then prf' % Option.map term t' else prf) end
  1090       | shrink' ls lev ts prfs (prf as PBound i) =
  1091           (if exists (fn SOME (Bound j) => lev-j <= nth ls i | _ => true) ts
  1092              orelse has_duplicates (op =)
  1093                (Library.foldl (fn (js, SOME (Bound j)) => j :: js | (js, _) => js) ([], ts))
  1094              orelse exists #1 prfs then [i] else [], false, map (pair false) ts, prf)
  1095       | shrink' ls lev ts prfs (Hyp t) = ([], false, map (pair false) ts, Hyp (term t))
  1096       | shrink' ls lev ts prfs (prf as MinProof) = ([], false, map (pair false) ts, prf)
  1097       | shrink' ls lev ts prfs (prf as OfClass _) = ([], false, map (pair false) ts, prf)
  1098       | shrink' ls lev ts prfs prf =
  1099           let
  1100             val prop =
  1101               (case prf of
  1102                 PAxm (_, prop, _) => prop
  1103               | Oracle (_, prop, _) => prop
  1104               | Promise (_, prop, _) => prop
  1105               | PThm (_, ((_, prop, _), _)) => prop
  1106               | _ => raise Fail "shrink: proof not in normal form");
  1107             val vs = vars_of prop;
  1108             val (ts', ts'') = chop (length vs) ts;
  1109             val insts = take (length ts') (map (fst o dest_Var) vs) ~~ ts';
  1110             val nvs = Library.foldl (fn (ixns', (ixn, ixns)) =>
  1111               insert (op =) ixn (case AList.lookup (op =) insts ixn of
  1112                   SOME (SOME t) => if is_proj t then union (op =) ixns ixns' else ixns'
  1113                 | _ => union (op =) ixns ixns'))
  1114                   (needed prop ts'' prfs, add_npvars false true [] ([], prop));
  1115             val insts' = map
  1116               (fn (ixn, x as SOME _) => if member (op =) nvs ixn then (false, x) else (true, NONE)
  1117                 | (_, x) => (false, x)) insts
  1118           in ([], false, insts' @ map (pair false) ts'', prf) end
  1119     and needed (Const ("==>", _) $ t $ u) ts ((b, _, _, _)::prfs) =
  1120           union (op =) (if b then map (fst o dest_Var) (vars_of t) else []) (needed u ts prfs)
  1121       | needed (Var (ixn, _)) (_::_) _ = [ixn]
  1122       | needed _ _ _ = [];
  1123   in shrink end;
  1124 
  1125 
  1126 (**** Simple first order matching functions for terms and proofs ****)
  1127 
  1128 exception PMatch;
  1129 
  1130 (** see pattern.ML **)
  1131 
  1132 fun flt (i: int) = filter (fn n => n < i);
  1133 
  1134 fun fomatch Ts tymatch j instsp p =
  1135   let
  1136     fun mtch (instsp as (tyinsts, insts)) = fn
  1137         (Var (ixn, T), t)  =>
  1138           if j>0 andalso not (null (flt j (loose_bnos t)))
  1139           then raise PMatch
  1140           else (tymatch (tyinsts, fn () => (T, fastype_of1 (Ts, t))),
  1141             (ixn, t) :: insts)
  1142       | (Free (a, T), Free (b, U)) =>
  1143           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1144       | (Const (a, T), Const (b, U))  =>
  1145           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1146       | (f $ t, g $ u) => mtch (mtch instsp (f, g)) (t, u)
  1147       | (Bound i, Bound j) => if i=j then instsp else raise PMatch
  1148       | _ => raise PMatch
  1149   in mtch instsp (pairself Envir.beta_eta_contract p) end;
  1150 
  1151 fun match_proof Ts tymatch =
  1152   let
  1153     fun optmatch _ inst (NONE, _) = inst
  1154       | optmatch _ _ (SOME _, NONE) = raise PMatch
  1155       | optmatch mtch inst (SOME x, SOME y) = mtch inst (x, y)
  1156 
  1157     fun matcht Ts j (pinst, tinst) (t, u) =
  1158       (pinst, fomatch Ts tymatch j tinst (t, Envir.beta_norm u));
  1159     fun matchT (pinst, (tyinsts, insts)) p =
  1160       (pinst, (tymatch (tyinsts, K p), insts));
  1161     fun matchTs inst (Ts, Us) = Library.foldl (uncurry matchT) (inst, Ts ~~ Us);
  1162 
  1163     fun mtch Ts i j (pinst, tinst) (Hyp (Var (ixn, _)), prf) =
  1164           if i = 0 andalso j = 0 then ((ixn, prf) :: pinst, tinst)
  1165           else (case apfst (flt i) (apsnd (flt j)
  1166                   (prf_add_loose_bnos 0 0 prf ([], []))) of
  1167               ([], []) => ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1168             | ([], _) => if j = 0 then
  1169                    ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1170                  else raise PMatch
  1171             | _ => raise PMatch)
  1172       | mtch Ts i j inst (prf1 % opt1, prf2 % opt2) =
  1173           optmatch (matcht Ts j) (mtch Ts i j inst (prf1, prf2)) (opt1, opt2)
  1174       | mtch Ts i j inst (prf1 %% prf2, prf1' %% prf2') =
  1175           mtch Ts i j (mtch Ts i j inst (prf1, prf1')) (prf2, prf2')
  1176       | mtch Ts i j inst (Abst (_, opT, prf1), Abst (_, opU, prf2)) =
  1177           mtch (the_default dummyT opU :: Ts) i (j+1)
  1178             (optmatch matchT inst (opT, opU)) (prf1, prf2)
  1179       | mtch Ts i j inst (prf1, Abst (_, opU, prf2)) =
  1180           mtch (the_default dummyT opU :: Ts) i (j+1) inst
  1181             (incr_pboundvars 0 1 prf1 %> Bound 0, prf2)
  1182       | mtch Ts i j inst (AbsP (_, opt, prf1), AbsP (_, opu, prf2)) =
  1183           mtch Ts (i+1) j (optmatch (matcht Ts j) inst (opt, opu)) (prf1, prf2)
  1184       | mtch Ts i j inst (prf1, AbsP (_, _, prf2)) =
  1185           mtch Ts (i+1) j inst (incr_pboundvars 1 0 prf1 %% PBound 0, prf2)
  1186       | mtch Ts i j inst (PAxm (s1, _, opTs), PAxm (s2, _, opUs)) =
  1187           if s1 = s2 then optmatch matchTs inst (opTs, opUs)
  1188           else raise PMatch
  1189       | mtch Ts i j inst (OfClass (T1, c1), OfClass (T2, c2)) =
  1190           if c1 = c2 then matchT inst (T1, T2)
  1191           else raise PMatch
  1192       | mtch Ts i j inst (PThm (_, ((name1, prop1, opTs), _)), PThm (_, ((name2, prop2, opUs), _))) =
  1193           if name1 = name2 andalso prop1 = prop2 then
  1194             optmatch matchTs inst (opTs, opUs)
  1195           else raise PMatch
  1196       | mtch _ _ _ inst (PBound i, PBound j) = if i = j then inst else raise PMatch
  1197       | mtch _ _ _ _ _ = raise PMatch
  1198   in mtch Ts 0 0 end;
  1199 
  1200 fun prf_subst (pinst, (tyinsts, insts)) =
  1201   let
  1202     val substT = Envir.subst_type_same tyinsts;
  1203     val substTs = Same.map substT;
  1204 
  1205     fun subst' lev (Var (xi, _)) =
  1206         (case AList.lookup (op =) insts xi of
  1207           NONE => raise Same.SAME
  1208         | SOME u => incr_boundvars lev u)
  1209       | subst' _ (Const (s, T)) = Const (s, substT T)
  1210       | subst' _ (Free (s, T)) = Free (s, substT T)
  1211       | subst' lev (Abs (a, T, body)) =
  1212           (Abs (a, substT T, Same.commit (subst' (lev + 1)) body)
  1213             handle Same.SAME => Abs (a, T, subst' (lev + 1) body))
  1214       | subst' lev (f $ t) =
  1215           (subst' lev f $ Same.commit (subst' lev) t
  1216             handle Same.SAME => f $ subst' lev t)
  1217       | subst' _ _ = raise Same.SAME;
  1218 
  1219     fun subst plev tlev (AbsP (a, t, body)) =
  1220           (AbsP (a, Same.map_option (subst' tlev) t, Same.commit (subst (plev + 1) tlev) body)
  1221             handle Same.SAME => AbsP (a, t, subst (plev + 1) tlev body))
  1222       | subst plev tlev (Abst (a, T, body)) =
  1223           (Abst (a, Same.map_option substT T, Same.commit (subst plev (tlev + 1)) body)
  1224             handle Same.SAME => Abst (a, T, subst plev (tlev + 1) body))
  1225       | subst plev tlev (prf %% prf') =
  1226           (subst plev tlev prf %% Same.commit (subst plev tlev) prf'
  1227             handle Same.SAME => prf %% subst plev tlev prf')
  1228       | subst plev tlev (prf % t) =
  1229           (subst plev tlev prf % Same.commit (Same.map_option (subst' tlev)) t
  1230             handle Same.SAME => prf % Same.map_option (subst' tlev) t)
  1231       | subst plev tlev (Hyp (Var (xi, _))) =
  1232           (case AList.lookup (op =) pinst xi of
  1233             NONE => raise Same.SAME
  1234           | SOME prf' => incr_pboundvars plev tlev prf')
  1235       | subst _ _ (PAxm (id, prop, Ts)) = PAxm (id, prop, Same.map_option substTs Ts)
  1236       | subst _ _ (OfClass (T, c)) = OfClass (substT T, c)
  1237       | subst _ _ (Oracle (id, prop, Ts)) = Oracle (id, prop, Same.map_option substTs Ts)
  1238       | subst _ _ (Promise (i, prop, Ts)) = Promise (i, prop, substTs Ts)
  1239       | subst _ _ (PThm (i, ((id, prop, Ts), body))) =
  1240           PThm (i, ((id, prop, Same.map_option substTs Ts), body))
  1241       | subst _ _ _ = raise Same.SAME;
  1242   in fn t => subst 0 0 t handle Same.SAME => t end;
  1243 
  1244 (*A fast unification filter: true unless the two terms cannot be unified.
  1245   Terms must be NORMAL.  Treats all Vars as distinct. *)
  1246 fun could_unify prf1 prf2 =
  1247   let
  1248     fun matchrands (prf1 %% prf2) (prf1' %% prf2') =
  1249           could_unify prf2 prf2' andalso matchrands prf1 prf1'
  1250       | matchrands (prf % SOME t) (prf' % SOME t') =
  1251           Term.could_unify (t, t') andalso matchrands prf prf'
  1252       | matchrands (prf % _) (prf' % _) = matchrands prf prf'
  1253       | matchrands _ _ = true
  1254 
  1255     fun head_of (prf %% _) = head_of prf
  1256       | head_of (prf % _) = head_of prf
  1257       | head_of prf = prf
  1258 
  1259   in case (head_of prf1, head_of prf2) of
  1260         (_, Hyp (Var _)) => true
  1261       | (Hyp (Var _), _) => true
  1262       | (PAxm (a, _, _), PAxm (b, _, _)) => a = b andalso matchrands prf1 prf2
  1263       | (OfClass (_, c), OfClass (_, d)) => c = d andalso matchrands prf1 prf2
  1264       | (PThm (_, ((a, propa, _), _)), PThm (_, ((b, propb, _), _))) =>
  1265           a = b andalso propa = propb andalso matchrands prf1 prf2
  1266       | (PBound i, PBound j) => i = j andalso matchrands prf1 prf2
  1267       | (AbsP _, _) =>  true   (*because of possible eta equality*)
  1268       | (Abst _, _) =>  true
  1269       | (_, AbsP _) =>  true
  1270       | (_, Abst _) =>  true
  1271       | _ => false
  1272   end;
  1273 
  1274 
  1275 (**** rewriting on proof terms ****)
  1276 
  1277 val no_skel = PBound 0;
  1278 val normal_skel = Hyp (Var ((Name.uu, 0), propT));
  1279 
  1280 fun rewrite_prf tymatch (rules, procs) prf =
  1281   let
  1282     fun rew _ _ (Abst (_, _, body) % SOME t) = SOME (prf_subst_bounds [t] body, no_skel)
  1283       | rew _ _ (AbsP (_, _, body) %% prf) = SOME (prf_subst_pbounds [prf] body, no_skel)
  1284       | rew Ts hs prf =
  1285           (case get_first (fn r => r Ts hs prf) procs of
  1286             NONE => get_first (fn (prf1, prf2) => SOME (prf_subst
  1287               (match_proof Ts tymatch ([], (Vartab.empty, [])) (prf1, prf)) prf2, prf2)
  1288                  handle PMatch => NONE) (filter (could_unify prf o fst) rules)
  1289           | some => some);
  1290 
  1291     fun rew0 Ts hs (prf as AbsP (_, _, prf' %% PBound 0)) =
  1292           if prf_loose_Pbvar1 prf' 0 then rew Ts hs prf
  1293           else
  1294             let val prf'' = incr_pboundvars (~1) 0 prf'
  1295             in SOME (the_default (prf'', no_skel) (rew Ts hs prf'')) end
  1296       | rew0 Ts hs (prf as Abst (_, _, prf' % SOME (Bound 0))) =
  1297           if prf_loose_bvar1 prf' 0 then rew Ts hs prf
  1298           else
  1299             let val prf'' = incr_pboundvars 0 (~1) prf'
  1300             in SOME (the_default (prf'', no_skel) (rew Ts hs prf'')) end
  1301       | rew0 Ts hs prf = rew Ts hs prf;
  1302 
  1303     fun rew1 _ _ (Hyp (Var _)) _ = NONE
  1304       | rew1 Ts hs skel prf = (case rew2 Ts hs skel prf of
  1305           SOME prf1 => (case rew0 Ts hs prf1 of
  1306               SOME (prf2, skel') => SOME (the_default prf2 (rew1 Ts hs skel' prf2))
  1307             | NONE => SOME prf1)
  1308         | NONE => (case rew0 Ts hs prf of
  1309               SOME (prf1, skel') => SOME (the_default prf1 (rew1 Ts hs skel' prf1))
  1310             | NONE => NONE))
  1311 
  1312     and rew2 Ts hs skel (prf % SOME t) = (case prf of
  1313             Abst (_, _, body) =>
  1314               let val prf' = prf_subst_bounds [t] body
  1315               in SOME (the_default prf' (rew2 Ts hs no_skel prf')) end
  1316           | _ => (case rew1 Ts hs (case skel of skel' % _ => skel' | _ => no_skel) prf of
  1317               SOME prf' => SOME (prf' % SOME t)
  1318             | NONE => NONE))
  1319       | rew2 Ts hs skel (prf % NONE) = Option.map (fn prf' => prf' % NONE)
  1320           (rew1 Ts hs (case skel of skel' % _ => skel' | _ => no_skel) prf)
  1321       | rew2 Ts hs skel (prf1 %% prf2) = (case prf1 of
  1322             AbsP (_, _, body) =>
  1323               let val prf' = prf_subst_pbounds [prf2] body
  1324               in SOME (the_default prf' (rew2 Ts hs no_skel prf')) end
  1325           | _ =>
  1326             let val (skel1, skel2) = (case skel of
  1327                 skel1 %% skel2 => (skel1, skel2)
  1328               | _ => (no_skel, no_skel))
  1329             in case rew1 Ts hs skel1 prf1 of
  1330                 SOME prf1' => (case rew1 Ts hs skel2 prf2 of
  1331                     SOME prf2' => SOME (prf1' %% prf2')
  1332                   | NONE => SOME (prf1' %% prf2))
  1333               | NONE => (case rew1 Ts hs skel2 prf2 of
  1334                     SOME prf2' => SOME (prf1 %% prf2')
  1335                   | NONE => NONE)
  1336             end)
  1337       | rew2 Ts hs skel (Abst (s, T, prf)) = (case rew1 (the_default dummyT T :: Ts) hs
  1338               (case skel of Abst (_, _, skel') => skel' | _ => no_skel) prf of
  1339             SOME prf' => SOME (Abst (s, T, prf'))
  1340           | NONE => NONE)
  1341       | rew2 Ts hs skel (AbsP (s, t, prf)) = (case rew1 Ts (t :: hs)
  1342               (case skel of AbsP (_, _, skel') => skel' | _ => no_skel) prf of
  1343             SOME prf' => SOME (AbsP (s, t, prf'))
  1344           | NONE => NONE)
  1345       | rew2 _ _ _ _ = NONE;
  1346 
  1347   in the_default prf (rew1 [] [] no_skel prf) end;
  1348 
  1349 fun rewrite_proof thy = rewrite_prf (fn (tyenv, f) =>
  1350   Sign.typ_match thy (f ()) tyenv handle Type.TYPE_MATCH => raise PMatch);
  1351 
  1352 fun rewrite_proof_notypes rews = rewrite_prf fst rews;
  1353 
  1354 
  1355 (**** theory data ****)
  1356 
  1357 structure Data = Theory_Data
  1358 (
  1359   type T =
  1360     (stamp * (proof * proof)) list *
  1361     (stamp * (typ list -> term option list -> proof -> (proof * proof) option)) list;
  1362 
  1363   val empty = ([], []);
  1364   val extend = I;
  1365   fun merge ((rules1, procs1), (rules2, procs2)) : T =
  1366     (AList.merge (op =) (K true) (rules1, rules2),
  1367       AList.merge (op =) (K true) (procs1, procs2));
  1368 );
  1369 
  1370 fun get_data thy = let val (rules, procs) = Data.get thy in (map #2 rules, map #2 procs) end;
  1371 fun rew_proof thy = rewrite_prf fst (get_data thy);
  1372 
  1373 fun add_prf_rrule r = (Data.map o apfst) (cons (stamp (), r));
  1374 fun add_prf_rproc p = (Data.map o apsnd) (cons (stamp (), p));
  1375 
  1376 
  1377 (***** promises *****)
  1378 
  1379 fun promise_proof thy i prop =
  1380   let
  1381     val _ = prop |> Term.exists_subterm (fn t =>
  1382       (Term.is_Free t orelse Term.is_Var t) andalso
  1383         raise Fail ("promise_proof: illegal variable " ^ Syntax.string_of_term_global thy t));
  1384     val _ = prop |> Term.exists_type (Term.exists_subtype
  1385       (fn TFree (a, _) => raise Fail ("promise_proof: illegal type variable " ^ quote a)
  1386         | _ => false));
  1387   in Promise (i, prop, map TVar (Term.add_tvars prop [])) end;
  1388 
  1389 fun fulfill_norm_proof thy ps body0 =
  1390   let
  1391     val PBody {oracles = oracles0, thms = thms0, proof = proof0} = body0;
  1392     val oracles = fold (fn (_, PBody {oracles, ...}) => merge_oracles oracles) ps oracles0;
  1393     val thms = fold (fn (_, PBody {thms, ...}) => merge_thms thms) ps thms0;
  1394     val proofs = fold (fn (i, PBody {proof, ...}) => Inttab.update (i, proof)) ps Inttab.empty;
  1395 
  1396     fun fill (Promise (i, prop, Ts)) =
  1397           (case Inttab.lookup proofs i of
  1398             NONE => NONE
  1399           | SOME prf => SOME (instantiate (Term.add_tvars prop [] ~~ Ts, []) prf, normal_skel))
  1400       | fill _ = NONE;
  1401     val (rules, procs) = get_data thy;
  1402     val proof = rewrite_prf fst (rules, K (K fill) :: procs) proof0;
  1403   in PBody {oracles = oracles, thms = thms, proof = proof} end;
  1404 
  1405 fun fulfill_proof_future _ [] postproc body = Future.map postproc body
  1406   | fulfill_proof_future thy promises postproc body =
  1407       (singleton o Future.forks)
  1408         {name = "Proofterm.fulfill_proof_future", group = NONE,
  1409           deps = Future.task_of body :: map (Future.task_of o snd) promises, pri = ~1,
  1410           interrupts = true}
  1411         (fn () =>
  1412           postproc (fulfill_norm_proof thy (map (apsnd Future.join) promises) (Future.join body)));
  1413 
  1414 
  1415 (***** abstraction over sort constraints *****)
  1416 
  1417 fun unconstrainT_prf thy (atyp_map, constraints) =
  1418   let
  1419     fun hyp_map hyp =
  1420       (case AList.lookup (op =) constraints hyp of
  1421         SOME t => Hyp t
  1422       | NONE => raise Fail "unconstrainT_prf: missing constraint");
  1423 
  1424     val typ = Term_Subst.map_atypsT_same (Type.strip_sorts o atyp_map);
  1425     fun ofclass (ty, c) =
  1426       let val ty' = Term.map_atyps atyp_map ty;
  1427       in the_single (of_sort_proof thy hyp_map (ty', [c])) end;
  1428   in
  1429     Same.commit (map_proof_same (Term_Subst.map_types_same typ) typ ofclass)
  1430     #> fold_rev (implies_intr_proof o snd) constraints
  1431   end;
  1432 
  1433 fun unconstrainT_body thy constrs (PBody {oracles, thms, proof}) =
  1434   PBody
  1435    {oracles = oracles,  (* FIXME merge (!), unconstrain (!?!) *)
  1436     thms = thms,  (* FIXME merge (!) *)
  1437     proof = unconstrainT_prf thy constrs proof};
  1438 
  1439 
  1440 (***** theorems *****)
  1441 
  1442 fun prepare_thm_proof thy name shyps hyps concl promises body =
  1443   let
  1444     val PBody {oracles = oracles0, thms = thms0, proof = prf} = body;
  1445     val prop = Logic.list_implies (hyps, concl);
  1446     val nvs = needed_vars prop;
  1447     val args = map (fn (v as Var (ixn, _)) =>
  1448         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1449       map SOME (frees_of prop);
  1450 
  1451     val ((atyp_map, constraints, outer_constraints), prop1) = Logic.unconstrainT shyps prop;
  1452     val postproc = unconstrainT_body thy (atyp_map, constraints);
  1453     val args1 =
  1454       (map o Option.map o Term.map_types o Term.map_atyps)
  1455         (Type.strip_sorts o atyp_map) args;
  1456     val argsP = map OfClass outer_constraints @ map Hyp hyps;
  1457 
  1458     fun full_proof0 () =
  1459       #4 (shrink_proof thy [] 0 (rew_proof thy (fold_rev implies_intr_proof hyps prf)));
  1460 
  1461     fun make_body0 proof0 = PBody {oracles = oracles0, thms = thms0, proof = proof0};
  1462     val body0 =
  1463       if not (proofs_enabled ()) then Future.value (make_body0 MinProof)
  1464       else
  1465         (singleton o Future.cond_forks)
  1466           {name = "Proofterm.prepare_thm_proof", group = NONE,
  1467             deps = [], pri = ~1, interrupts = true}
  1468           (make_body0 o full_proof0);
  1469 
  1470     fun new_prf () =
  1471       let
  1472         val body' = body0
  1473           |> fulfill_proof_future thy promises postproc
  1474           |> Future.map (fn body as PBody {thms, ...} => (join_thms thms; body));
  1475       in (serial (), body') end;
  1476 
  1477     val (i, body') =
  1478       (*non-deterministic, depends on unknown promises*)
  1479       (case strip_combt (fst (strip_combP prf)) of
  1480         (PThm (i, ((old_name, prop', NONE), body')), args') =>
  1481           if (old_name = "" orelse old_name = name) andalso prop1 = prop' andalso args = args'
  1482           then (i, body')
  1483           else new_prf ()
  1484       | _ => new_prf ());
  1485     val head = PThm (i, ((name, prop1, NONE), body'));
  1486   in ((i, (name, prop1, body')), head, args, argsP, args1) end;
  1487 
  1488 fun thm_proof thy name shyps hyps concl promises body =
  1489   let val (pthm, head, args, argsP, _) = prepare_thm_proof thy name shyps hyps concl promises body
  1490   in (pthm, proof_combP (proof_combt' (head, args), argsP)) end;
  1491 
  1492 fun unconstrain_thm_proof thy shyps concl promises body =
  1493   let
  1494     val (pthm, head, _, _, args) = prepare_thm_proof thy "" shyps [] concl promises body
  1495   in (pthm, proof_combt' (head, args)) end;
  1496 
  1497 
  1498 fun get_name shyps hyps prop prf =
  1499   let val (_, prop) = Logic.unconstrainT shyps (Logic.list_implies (hyps, prop)) in
  1500     (case strip_combt (fst (strip_combP prf)) of
  1501       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1502     | _ => "")
  1503   end;
  1504 
  1505 fun guess_name (PThm (_, ((name, _, _), _))) = name
  1506   | guess_name (prf %% Hyp _) = guess_name prf
  1507   | guess_name (prf %% OfClass _) = guess_name prf
  1508   | guess_name (prf % NONE) = guess_name prf
  1509   | guess_name (prf % SOME (Var _)) = guess_name prf
  1510   | guess_name _ = "";
  1511 
  1512 end;
  1513 
  1514 structure Basic_Proofterm : BASIC_PROOFTERM = Proofterm;
  1515 open Basic_Proofterm;