src/Pure/Isar/isar_cmd.ML
author wenzelm
Sun Nov 02 16:59:40 2014 +0100 (2014-11-02 ago)
changeset 58875 ab1c65b015c3
parent 58868 c5e1cce7ace3
child 58928 23d0ffd48006
permissions -rw-r--r--
clarified legacy command;
     1 (*  Title:      Pure/Isar/isar_cmd.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Miscellaneous Isar commands.
     5 *)
     6 
     7 signature ISAR_CMD =
     8 sig
     9   val global_setup: Symbol_Pos.source -> theory -> theory
    10   val local_setup: Symbol_Pos.source -> Proof.context -> Proof.context
    11   val parse_ast_translation: Symbol_Pos.source -> theory -> theory
    12   val parse_translation: Symbol_Pos.source -> theory -> theory
    13   val print_translation: Symbol_Pos.source -> theory -> theory
    14   val typed_print_translation: Symbol_Pos.source -> theory -> theory
    15   val print_ast_translation: Symbol_Pos.source -> theory -> theory
    16   val translations: (xstring * string) Syntax.trrule list -> theory -> theory
    17   val no_translations: (xstring * string) Syntax.trrule list -> theory -> theory
    18   val oracle: bstring * Position.T -> Symbol_Pos.source -> theory -> theory
    19   val add_defs: (bool * bool) * ((binding * string) * Token.src list) list -> theory -> theory
    20   val declaration: {syntax: bool, pervasive: bool} ->
    21     Symbol_Pos.source -> local_theory -> local_theory
    22   val simproc_setup: string * Position.T -> string list -> Symbol_Pos.source ->
    23     string list -> local_theory -> local_theory
    24   val have: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    25   val hence: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    26   val show: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    27   val thus: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    28   val qed: Method.text_range option -> Toplevel.transition -> Toplevel.transition
    29   val terminal_proof: Method.text_range * Method.text_range option ->
    30     Toplevel.transition -> Toplevel.transition
    31   val default_proof: Toplevel.transition -> Toplevel.transition
    32   val immediate_proof: Toplevel.transition -> Toplevel.transition
    33   val done_proof: Toplevel.transition -> Toplevel.transition
    34   val skip_proof: Toplevel.transition -> Toplevel.transition
    35   val ml_diag: bool -> Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    36   val diag_state: Proof.context -> Toplevel.state
    37   val diag_goal: Proof.context -> {context: Proof.context, facts: thm list, goal: thm}
    38   val pretty_theorems: bool -> Toplevel.state -> Pretty.T list
    39   val thy_deps: Toplevel.transition -> Toplevel.transition
    40   val locale_deps: Toplevel.transition -> Toplevel.transition
    41   val print_stmts: string list * (Facts.ref * Token.src list) list
    42     -> Toplevel.transition -> Toplevel.transition
    43   val print_thms: string list * (Facts.ref * Token.src list) list
    44     -> Toplevel.transition -> Toplevel.transition
    45   val print_prfs: bool -> string list * (Facts.ref * Token.src list) list option
    46     -> Toplevel.transition -> Toplevel.transition
    47   val print_prop: (string list * string) -> Toplevel.transition -> Toplevel.transition
    48   val print_term: (string list * string) -> Toplevel.transition -> Toplevel.transition
    49   val print_type: (string list * (string * string option)) ->
    50     Toplevel.transition -> Toplevel.transition
    51   val local_theory_markup: (xstring * Position.T) option * Symbol_Pos.source ->
    52     Toplevel.transition -> Toplevel.transition
    53   val proof_markup: Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    54   val header_markup: Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    55   val heading_markup: (xstring * Position.T) option * Symbol_Pos.source ->
    56     Toplevel.transition -> Toplevel.transition
    57 end;
    58 
    59 structure Isar_Cmd: ISAR_CMD =
    60 struct
    61 
    62 
    63 (** theory declarations **)
    64 
    65 (* generic setup *)
    66 
    67 fun global_setup source =
    68   ML_Lex.read_source false source
    69   |> ML_Context.expression (#pos source) "val setup: theory -> theory" "Context.map_theory setup"
    70   |> Context.theory_map;
    71 
    72 fun local_setup source =
    73   ML_Lex.read_source false source
    74   |> ML_Context.expression (#pos source) "val setup: local_theory -> local_theory" "Context.map_proof setup"
    75   |> Context.proof_map;
    76 
    77 
    78 (* translation functions *)
    79 
    80 fun parse_ast_translation source =
    81   ML_Lex.read_source false source
    82   |> ML_Context.expression (#pos source)
    83     "val parse_ast_translation: (string * (Proof.context -> Ast.ast list -> Ast.ast)) list"
    84     "Context.map_theory (Sign.parse_ast_translation parse_ast_translation)"
    85   |> Context.theory_map;
    86 
    87 fun parse_translation source =
    88   ML_Lex.read_source false source
    89   |> ML_Context.expression (#pos source)
    90     "val parse_translation: (string * (Proof.context -> term list -> term)) list"
    91     "Context.map_theory (Sign.parse_translation parse_translation)"
    92   |> Context.theory_map;
    93 
    94 fun print_translation source =
    95   ML_Lex.read_source false source
    96   |> ML_Context.expression (#pos source)
    97     "val print_translation: (string * (Proof.context -> term list -> term)) list"
    98     "Context.map_theory (Sign.print_translation print_translation)"
    99   |> Context.theory_map;
   100 
   101 fun typed_print_translation source =
   102   ML_Lex.read_source false source
   103   |> ML_Context.expression (#pos source)
   104     "val typed_print_translation: (string * (Proof.context -> typ -> term list -> term)) list"
   105     "Context.map_theory (Sign.typed_print_translation typed_print_translation)"
   106   |> Context.theory_map;
   107 
   108 fun print_ast_translation source =
   109   ML_Lex.read_source false source
   110   |> ML_Context.expression (#pos source)
   111     "val print_ast_translation: (string * (Proof.context -> Ast.ast list -> Ast.ast)) list"
   112     "Context.map_theory (Sign.print_ast_translation print_ast_translation)"
   113   |> Context.theory_map;
   114 
   115 
   116 (* translation rules *)
   117 
   118 fun read_trrules thy raw_rules =
   119   let
   120     val ctxt = Proof_Context.init_global thy;
   121     val read_root =
   122       #1 o dest_Type o Proof_Context.read_type_name {proper = true, strict = false} ctxt;
   123   in
   124     raw_rules
   125     |> map (Syntax.map_trrule (fn (r, s) => Syntax_Phases.parse_ast_pattern ctxt (read_root r, s)))
   126   end;
   127 
   128 fun translations args thy = Sign.add_trrules (read_trrules thy args) thy;
   129 fun no_translations args thy = Sign.del_trrules (read_trrules thy args) thy;
   130 
   131 
   132 (* oracles *)
   133 
   134 fun oracle (name, pos) source =
   135   let
   136     val body = ML_Lex.read_source false source;
   137     val ants =
   138       ML_Lex.read Position.none
   139        ("local\n\
   140         \  val binding = " ^ ML_Syntax.make_binding (name, pos) ^ ";\n\
   141         \  val body = ") @ body @ ML_Lex.read Position.none (";\n\
   142         \in\n\
   143         \  val " ^ name ^
   144         " = snd (Context.>>> (Context.map_theory_result (Thm.add_oracle (binding, body))));\n\
   145         \end;\n");
   146   in
   147     Context.theory_map
   148       (ML_Context.exec (fn () => ML_Context.eval ML_Compiler.flags (#pos source) ants))
   149   end;
   150 
   151 
   152 (* old-style defs *)
   153 
   154 fun add_defs ((unchecked, overloaded), args) thy =
   155  (legacy_feature "Old 'defs' command -- use 'definition' (with 'overloading') instead";
   156   thy |>
   157     (if unchecked then Global_Theory.add_defs_unchecked_cmd else Global_Theory.add_defs_cmd)
   158       overloaded
   159       (map (fn ((b, ax), srcs) => ((b, ax), map (Attrib.attribute_cmd_global thy) srcs)) args)
   160   |> snd);
   161 
   162 
   163 (* declarations *)
   164 
   165 fun declaration {syntax, pervasive} source =
   166   ML_Lex.read_source false source
   167   |> ML_Context.expression (#pos source)
   168     "val declaration: Morphism.declaration"
   169     ("Context.map_proof (Local_Theory.declaration {syntax = " ^ Bool.toString syntax ^ ", \
   170       \pervasive = " ^ Bool.toString pervasive ^ "} declaration)")
   171   |> Context.proof_map;
   172 
   173 
   174 (* simprocs *)
   175 
   176 fun simproc_setup name lhss source identifier =
   177   ML_Lex.read_source false source
   178   |> ML_Context.expression (#pos source)
   179     "val proc: Morphism.morphism -> Proof.context -> cterm -> thm option"
   180     ("Context.map_proof (Simplifier.def_simproc_cmd {name = " ^ ML_Syntax.make_binding name ^ ", \
   181       \lhss = " ^ ML_Syntax.print_strings lhss ^ ", proc = proc, \
   182       \identifier = Library.maps ML_Context.thms " ^ ML_Syntax.print_strings identifier ^ "})")
   183   |> Context.proof_map;
   184 
   185 
   186 (* goals *)
   187 
   188 fun goal opt_chain goal stmt int =
   189   opt_chain #> goal NONE (K I) stmt int;
   190 
   191 val have = goal I Proof.have_cmd;
   192 val hence = goal Proof.chain Proof.have_cmd;
   193 val show = goal I Proof.show_cmd;
   194 val thus = goal Proof.chain Proof.show_cmd;
   195 
   196 
   197 (* local endings *)
   198 
   199 fun local_qed m = Toplevel.proof (Proof.local_qed (m, true));
   200 val local_terminal_proof = Toplevel.proof' o Proof.local_future_terminal_proof;
   201 val local_default_proof = Toplevel.proof Proof.local_default_proof;
   202 val local_immediate_proof = Toplevel.proof Proof.local_immediate_proof;
   203 val local_done_proof = Toplevel.proof Proof.local_done_proof;
   204 val local_skip_proof = Toplevel.proof' Proof.local_skip_proof;
   205 
   206 val skip_local_qed = Toplevel.skip_proof (fn i => if i > 1 then i - 1 else raise Toplevel.UNDEF);
   207 
   208 
   209 (* global endings *)
   210 
   211 fun global_qed m = Toplevel.end_proof (K (Proof.global_qed (m, true)));
   212 val global_terminal_proof = Toplevel.end_proof o Proof.global_future_terminal_proof;
   213 val global_default_proof = Toplevel.end_proof (K Proof.global_default_proof);
   214 val global_immediate_proof = Toplevel.end_proof (K Proof.global_immediate_proof);
   215 val global_skip_proof = Toplevel.end_proof Proof.global_skip_proof;
   216 val global_done_proof = Toplevel.end_proof (K Proof.global_done_proof);
   217 
   218 val skip_global_qed = Toplevel.skip_proof_to_theory (fn n => n = 1);
   219 
   220 
   221 (* common endings *)
   222 
   223 fun qed m = local_qed m o global_qed m o skip_local_qed o skip_global_qed;
   224 fun terminal_proof m = local_terminal_proof m o global_terminal_proof m;
   225 val default_proof = local_default_proof o global_default_proof;
   226 val immediate_proof = local_immediate_proof o global_immediate_proof;
   227 val done_proof = local_done_proof o global_done_proof;
   228 val skip_proof = local_skip_proof o global_skip_proof;
   229 
   230 
   231 (* diagnostic ML evaluation *)
   232 
   233 structure Diag_State = Proof_Data
   234 (
   235   type T = Toplevel.state;
   236   fun init _ = Toplevel.toplevel;
   237 );
   238 
   239 fun ml_diag verbose source = Toplevel.keep (fn state =>
   240   let
   241     val opt_ctxt =
   242       try Toplevel.generic_theory_of state
   243       |> Option.map (Context.proof_of #> Diag_State.put state);
   244     val flags = ML_Compiler.verbose verbose ML_Compiler.flags;
   245   in ML_Context.eval_source_in opt_ctxt flags source end);
   246 
   247 val diag_state = Diag_State.get;
   248 
   249 fun diag_goal ctxt =
   250   Proof.goal (Toplevel.proof_of (diag_state ctxt))
   251     handle Toplevel.UNDEF => error "No goal present";
   252 
   253 val _ = Theory.setup
   254   (ML_Antiquotation.value (Binding.qualify true "Isar" @{binding state})
   255     (Scan.succeed "Isar_Cmd.diag_state ML_context") #>
   256    ML_Antiquotation.value (Binding.qualify true "Isar" @{binding goal})
   257     (Scan.succeed "Isar_Cmd.diag_goal ML_context"));
   258 
   259 
   260 (* theorems of theory or proof context *)
   261 
   262 fun pretty_theorems verbose st =
   263   if Toplevel.is_proof st then
   264     Proof_Context.pretty_local_facts (Toplevel.context_of st) verbose
   265   else
   266     let
   267       val thy = Toplevel.theory_of st;
   268       val prev_thys =
   269         (case Toplevel.previous_context_of st of
   270           SOME prev => [Proof_Context.theory_of prev]
   271         | NONE => Theory.parents_of thy);
   272     in Proof_Display.pretty_theorems_diff verbose prev_thys thy end;
   273 
   274 
   275 (* display dependencies *)
   276 
   277 val thy_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   278   let
   279     val thy = Toplevel.theory_of state;
   280     val thy_session = Present.session_name thy;
   281 
   282     val gr = rev (Theory.nodes_of thy) |> map (fn node =>
   283       let
   284         val name = Context.theory_name node;
   285         val parents = map Context.theory_name (Theory.parents_of node);
   286         val session = Present.session_name node;
   287         val unfold = (session = thy_session);
   288       in
   289        {name = name, ID = name, parents = parents, dir = session,
   290         unfold = unfold, path = "", content = []}
   291       end);
   292   in Graph_Display.display_graph gr end);
   293 
   294 val locale_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   295   let
   296     val thy = Toplevel.theory_of state;
   297     val gr = Locale.pretty_locale_deps thy |> map (fn {name, parents, body} =>
   298      {name = Locale.extern thy name, ID = name, parents = parents,
   299       dir = "", unfold = true, path = "", content = [body]});
   300   in Graph_Display.display_graph gr end);
   301 
   302 
   303 (* print theorems, terms, types etc. *)
   304 
   305 local
   306 
   307 fun string_of_stmts ctxt args =
   308   Attrib.eval_thms ctxt args
   309   |> map (Element.pretty_statement ctxt Thm.theoremK)
   310   |> Pretty.chunks2 |> Pretty.string_of;
   311 
   312 fun string_of_thms ctxt args =
   313   Pretty.string_of (Proof_Context.pretty_fact ctxt ("", Attrib.eval_thms ctxt args));
   314 
   315 fun string_of_prfs full state arg =
   316   Pretty.string_of
   317     (case arg of
   318       NONE =>
   319         let
   320           val {context = ctxt, goal = thm} = Proof.simple_goal (Toplevel.proof_of state);
   321           val thy = Proof_Context.theory_of ctxt;
   322           val prf = Thm.proof_of thm;
   323           val prop = Thm.full_prop_of thm;
   324           val prf' = Proofterm.rewrite_proof_notypes ([], []) prf;
   325         in
   326           Proof_Syntax.pretty_proof ctxt
   327             (if full then Reconstruct.reconstruct_proof thy prop prf' else prf')
   328         end
   329     | SOME srcs =>
   330         let val ctxt = Toplevel.context_of state
   331         in map (Proof_Syntax.pretty_proof_of ctxt full) (Attrib.eval_thms ctxt srcs) end
   332         |> Pretty.chunks);
   333 
   334 fun string_of_prop ctxt s =
   335   let
   336     val prop = Syntax.read_prop ctxt s;
   337     val ctxt' = Variable.auto_fixes prop ctxt;
   338   in Pretty.string_of (Pretty.quote (Syntax.pretty_term ctxt' prop)) end;
   339 
   340 fun string_of_term ctxt s =
   341   let
   342     val t = Syntax.read_term ctxt s;
   343     val T = Term.type_of t;
   344     val ctxt' = Variable.auto_fixes t ctxt;
   345   in
   346     Pretty.string_of
   347       (Pretty.block [Pretty.quote (Syntax.pretty_term ctxt' t), Pretty.fbrk,
   348         Pretty.str "::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ ctxt' T)])
   349   end;
   350 
   351 fun string_of_type ctxt (s, NONE) =
   352       let val T = Syntax.read_typ ctxt s
   353       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt T)) end
   354   | string_of_type ctxt (s1, SOME s2) =
   355       let
   356         val ctxt' = Config.put show_sorts true ctxt;
   357         val raw_T = Syntax.parse_typ ctxt' s1;
   358         val S = Syntax.read_sort ctxt' s2;
   359         val T =
   360           Syntax.check_term ctxt'
   361             (Logic.mk_type raw_T |> Type.constraint (Term.itselfT (Type_Infer.anyT S)))
   362           |> Logic.dest_type;
   363       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt' T)) end;
   364 
   365 fun print_item string_of (modes, arg) = Toplevel.keep (fn state =>
   366   Print_Mode.with_modes modes (fn () => writeln (string_of state arg)) ());
   367 
   368 in
   369 
   370 val print_stmts = print_item (string_of_stmts o Toplevel.context_of);
   371 val print_thms = print_item (string_of_thms o Toplevel.context_of);
   372 val print_prfs = print_item o string_of_prfs;
   373 val print_prop = print_item (string_of_prop o Toplevel.context_of);
   374 val print_term = print_item (string_of_term o Toplevel.context_of);
   375 val print_type = print_item (string_of_type o Toplevel.context_of);
   376 
   377 end;
   378 
   379 
   380 (* markup commands *)
   381 
   382 fun local_theory_markup (loc, txt) = Toplevel.present_local_theory loc (Thy_Output.check_text txt);
   383 val proof_markup = Toplevel.present_proof o Thy_Output.check_text;
   384 
   385 fun reject_target NONE = ()
   386   | reject_target (SOME (_, pos)) =
   387       error ("Illegal target specification -- not a theory context" ^ Position.here pos);
   388 
   389 fun header_markup txt =
   390   Toplevel.keep (fn state =>
   391     if Toplevel.is_toplevel state then
   392      (legacy_feature "Obsolete 'header' command -- use 'chapter', 'section' etc. instead";
   393       Thy_Output.check_text txt state)
   394     else raise Toplevel.UNDEF);
   395 
   396 fun heading_markup (loc, txt) =
   397   Toplevel.keep (fn state =>
   398     if Toplevel.is_toplevel state then (reject_target loc; Thy_Output.check_text txt state)
   399     else raise Toplevel.UNDEF) o
   400   local_theory_markup (loc, txt) o
   401   Toplevel.present_proof (fn state => (reject_target loc; Thy_Output.check_text txt state));
   402 
   403 end;