src/Pure/Isar/proof_context.ML
author haftmann
Fri Dec 05 18:43:42 2008 +0100 (2008-12-05 ago)
changeset 29006 abe0f11cfa4e
parent 28965 1de908189869
child 29318 6337d1cb2ba0
permissions -rw-r--r--
Name.name_of -> Binding.base_name
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The key concept of Isar proof contexts: elevates primitive local
     6 reasoning Gamma |- phi to a structured concept, with generic context
     7 elements.  See also structure Variable and Assumption.
     8 *)
     9 
    10 signature PROOF_CONTEXT =
    11 sig
    12   val theory_of: Proof.context -> theory
    13   val init: theory -> Proof.context
    14   type mode
    15   val mode_default: mode
    16   val mode_stmt: mode
    17   val mode_pattern: mode
    18   val mode_schematic: mode
    19   val mode_abbrev: mode
    20   val set_mode: mode -> Proof.context -> Proof.context
    21   val get_mode: Proof.context -> mode
    22   val restore_mode: Proof.context -> Proof.context -> Proof.context
    23   val abbrev_mode: Proof.context -> bool
    24   val set_stmt: bool -> Proof.context -> Proof.context
    25   val naming_of: Proof.context -> NameSpace.naming
    26   val full_name: Proof.context -> Binding.T -> string
    27   val full_bname: Proof.context -> bstring -> string
    28   val consts_of: Proof.context -> Consts.T
    29   val const_syntax_name: Proof.context -> string -> string
    30   val the_const_constraint: Proof.context -> string -> typ
    31   val mk_const: Proof.context -> string * typ list -> term
    32   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    33   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    34   val facts_of: Proof.context -> Facts.T
    35   val transfer_syntax: theory -> Proof.context -> Proof.context
    36   val transfer: theory -> Proof.context -> Proof.context
    37   val theory: (theory -> theory) -> Proof.context -> Proof.context
    38   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    39   val extern_fact: Proof.context -> string -> xstring
    40   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    41   val pretty_thm_legacy: thm -> Pretty.T
    42   val pretty_thm: Proof.context -> thm -> Pretty.T
    43   val pretty_thms: Proof.context -> thm list -> Pretty.T
    44   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    45   val string_of_thm: Proof.context -> thm -> string
    46   val read_typ: Proof.context -> string -> typ
    47   val read_typ_syntax: Proof.context -> string -> typ
    48   val read_typ_abbrev: Proof.context -> string -> typ
    49   val cert_typ: Proof.context -> typ -> typ
    50   val cert_typ_syntax: Proof.context -> typ -> typ
    51   val cert_typ_abbrev: Proof.context -> typ -> typ
    52   val get_skolem: Proof.context -> string -> string
    53   val revert_skolem: Proof.context -> string -> string
    54   val infer_type: Proof.context -> string -> typ
    55   val inferred_param: string -> Proof.context -> typ * Proof.context
    56   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    57   val read_tyname: Proof.context -> string -> typ
    58   val read_const_proper: Proof.context -> string -> term
    59   val read_const: Proof.context -> string -> term
    60   val allow_dummies: Proof.context -> Proof.context
    61   val decode_term: Proof.context -> term -> term
    62   val standard_infer_types: Proof.context -> term list -> term list
    63   val read_term_pattern: Proof.context -> string -> term
    64   val read_term_schematic: Proof.context -> string -> term
    65   val read_term_abbrev: Proof.context -> string -> term
    66   val expand_abbrevs: Proof.context -> term -> term
    67   val cert_term: Proof.context -> term -> term
    68   val cert_prop: Proof.context -> term -> term
    69   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    70   val export: Proof.context -> Proof.context -> thm list -> thm list
    71   val export_morphism: Proof.context -> Proof.context -> morphism
    72   val norm_export_morphism: Proof.context -> Proof.context -> morphism
    73   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    74   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    75   val auto_bind_goal: term list -> Proof.context -> Proof.context
    76   val auto_bind_facts: term list -> Proof.context -> Proof.context
    77   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    78   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    79   val read_propp: Proof.context * (string * string list) list list
    80     -> Proof.context * (term * term list) list list
    81   val cert_propp: Proof.context * (term * term list) list list
    82     -> Proof.context * (term * term list) list list
    83   val read_propp_schematic: Proof.context * (string * string list) list list
    84     -> Proof.context * (term * term list) list list
    85   val cert_propp_schematic: Proof.context * (term * term list) list list
    86     -> Proof.context * (term * term list) list list
    87   val bind_propp: Proof.context * (string * string list) list list
    88     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    89   val bind_propp_i: Proof.context * (term * term list) list list
    90     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    91   val bind_propp_schematic: Proof.context * (string * string list) list list
    92     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    93   val bind_propp_schematic_i: Proof.context * (term * term list) list list
    94     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    95   val fact_tac: thm list -> int -> tactic
    96   val some_fact_tac: Proof.context -> int -> tactic
    97   val get_fact: Proof.context -> Facts.ref -> thm list
    98   val get_fact_single: Proof.context -> Facts.ref -> thm
    99   val get_thms: Proof.context -> xstring -> thm list
   100   val get_thm: Proof.context -> xstring -> thm
   101   val add_path: string -> Proof.context -> Proof.context
   102   val no_base_names: Proof.context -> Proof.context
   103   val qualified_names: Proof.context -> Proof.context
   104   val sticky_prefix: string -> Proof.context -> Proof.context
   105   val restore_naming: Proof.context -> Proof.context -> Proof.context
   106   val reset_naming: Proof.context -> Proof.context
   107   val note_thmss: string ->
   108     ((Binding.T * attribute list) * (Facts.ref * attribute list) list) list ->
   109       Proof.context -> (string * thm list) list * Proof.context
   110   val note_thmss_i: string ->
   111     ((Binding.T * attribute list) * (thm list * attribute list) list) list ->
   112       Proof.context -> (string * thm list) list * Proof.context
   113   val put_thms: bool -> string * thm list option -> Proof.context -> Proof.context
   114   val read_vars: (Binding.T * string option * mixfix) list -> Proof.context ->
   115     (Binding.T * typ option * mixfix) list * Proof.context
   116   val cert_vars: (Binding.T * typ option * mixfix) list -> Proof.context ->
   117     (Binding.T * typ option * mixfix) list * Proof.context
   118   val add_fixes: (Binding.T * string option * mixfix) list ->
   119     Proof.context -> string list * Proof.context
   120   val add_fixes_i: (Binding.T * typ option * mixfix) list ->
   121     Proof.context -> string list * Proof.context
   122   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   123   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   124   val add_assms: Assumption.export ->
   125     ((Binding.T * attribute list) * (string * string list) list) list ->
   126     Proof.context -> (string * thm list) list * Proof.context
   127   val add_assms_i: Assumption.export ->
   128     ((Binding.T * attribute list) * (term * term list) list) list ->
   129     Proof.context -> (string * thm list) list * Proof.context
   130   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   131   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   132   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   133   val notation: bool -> Syntax.mode -> (term * mixfix) list -> Proof.context -> Proof.context
   134   val target_notation: bool -> Syntax.mode -> (term * mixfix) list -> morphism ->
   135     Context.generic -> Context.generic
   136   val add_const_constraint: string * typ option -> Proof.context -> Proof.context
   137   val add_abbrev: string -> Properties.T ->
   138     Binding.T * term -> Proof.context -> (term * term) * Proof.context
   139   val revert_abbrev: string -> string -> Proof.context -> Proof.context
   140   val verbose: bool ref
   141   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   142   val print_syntax: Proof.context -> unit
   143   val print_abbrevs: Proof.context -> unit
   144   val print_binds: Proof.context -> unit
   145   val print_lthms: Proof.context -> unit
   146   val print_cases: Proof.context -> unit
   147   val debug: bool ref
   148   val prems_limit: int ref
   149   val pretty_ctxt: Proof.context -> Pretty.T list
   150   val pretty_context: Proof.context -> Pretty.T list
   151   val query_type: Proof.context -> string -> Properties.T
   152   val query_const: Proof.context -> string -> Properties.T
   153   val query_class: Proof.context -> string -> Properties.T
   154 end;
   155 
   156 structure ProofContext: PROOF_CONTEXT =
   157 struct
   158 
   159 val theory_of = Context.theory_of_proof;
   160 val init = Context.init_proof;
   161 
   162 
   163 (** inner syntax mode **)
   164 
   165 datatype mode =
   166   Mode of
   167    {stmt: bool,                (*inner statement mode*)
   168     pattern: bool,             (*pattern binding schematic variables*)
   169     schematic: bool,           (*term referencing loose schematic variables*)
   170     abbrev: bool};             (*abbrev mode -- no normalization*)
   171 
   172 fun make_mode (stmt, pattern, schematic, abbrev) =
   173   Mode {stmt = stmt, pattern = pattern, schematic = schematic, abbrev = abbrev};
   174 
   175 val mode_default   = make_mode (false, false, false, false);
   176 val mode_stmt      = make_mode (true, false, false, false);
   177 val mode_pattern   = make_mode (false, true, false, false);
   178 val mode_schematic = make_mode (false, false, true, false);
   179 val mode_abbrev    = make_mode (false, false, false, true);
   180 
   181 
   182 
   183 (** Isar proof context information **)
   184 
   185 datatype ctxt =
   186   Ctxt of
   187    {mode: mode,                                       (*inner syntax mode*)
   188     naming: NameSpace.naming,                         (*local naming conventions*)
   189     syntax: LocalSyntax.T,                            (*local syntax*)
   190     consts: Consts.T * Consts.T,                      (*local/global consts*)
   191     facts: Facts.T,                                   (*local facts*)
   192     cases: (string * (RuleCases.T * bool)) list};     (*named case contexts*)
   193 
   194 fun make_ctxt (mode, naming, syntax, consts, facts, cases) =
   195   Ctxt {mode = mode, naming = naming, syntax = syntax,
   196     consts = consts, facts = facts, cases = cases};
   197 
   198 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   199 
   200 structure ContextData = ProofDataFun
   201 (
   202   type T = ctxt;
   203   fun init thy =
   204     make_ctxt (mode_default, local_naming, LocalSyntax.init thy,
   205       (Sign.consts_of thy, Sign.consts_of thy), Facts.empty, []);
   206 );
   207 
   208 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   209 
   210 fun map_context f =
   211   ContextData.map (fn Ctxt {mode, naming, syntax, consts, facts, cases} =>
   212     make_ctxt (f (mode, naming, syntax, consts, facts, cases)));
   213 
   214 fun set_mode mode = map_context (fn (_, naming, syntax, consts, facts, cases) =>
   215   (mode, naming, syntax, consts, facts, cases));
   216 
   217 fun map_mode f =
   218   map_context (fn (Mode {stmt, pattern, schematic, abbrev}, naming, syntax, consts, facts, cases) =>
   219     (make_mode (f (stmt, pattern, schematic, abbrev)), naming, syntax, consts, facts, cases));
   220 
   221 fun map_naming f =
   222   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   223     (mode, f naming, syntax, consts, facts, cases));
   224 
   225 fun map_syntax f =
   226   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   227     (mode, naming, f syntax, consts, facts, cases));
   228 
   229 fun map_consts f =
   230   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   231     (mode, naming, syntax, f consts, facts, cases));
   232 
   233 fun map_facts f =
   234   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   235     (mode, naming, syntax, consts, f facts, cases));
   236 
   237 fun map_cases f =
   238   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   239     (mode, naming, syntax, consts, facts, f cases));
   240 
   241 val get_mode = #mode o rep_context;
   242 val restore_mode = set_mode o get_mode;
   243 val abbrev_mode = get_mode #> (fn Mode {abbrev, ...} => abbrev);
   244 
   245 fun set_stmt stmt =
   246   map_mode (fn (_, pattern, schematic, abbrev) => (stmt, pattern, schematic, abbrev));
   247 
   248 val naming_of = #naming o rep_context;
   249 
   250 val full_name = NameSpace.full_name o naming_of;
   251 fun full_bname thy = NameSpace.full_name (naming_of thy) o Binding.name;
   252 
   253 val syntax_of = #syntax o rep_context;
   254 val syn_of = LocalSyntax.syn_of o syntax_of;
   255 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   256 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   257 
   258 val consts_of = #1 o #consts o rep_context;
   259 val const_syntax_name = Consts.syntax_name o consts_of;
   260 val the_const_constraint = Consts.the_constraint o consts_of;
   261 
   262 fun mk_const ctxt (c, Ts) = Const (c, Consts.instance (consts_of ctxt) (c, Ts));
   263 
   264 val facts_of = #facts o rep_context;
   265 val cases_of = #cases o rep_context;
   266 
   267 
   268 (* theory transfer *)
   269 
   270 fun transfer_syntax thy =
   271   map_syntax (LocalSyntax.rebuild thy) #>
   272   map_consts (fn consts as (local_consts, global_consts) =>
   273     let val thy_consts = Sign.consts_of thy in
   274       if Consts.eq_consts (thy_consts, global_consts) then consts
   275       else (Consts.merge (local_consts, thy_consts), thy_consts)
   276     end);
   277 
   278 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   279 
   280 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   281 
   282 fun theory_result f ctxt =
   283   let val (res, thy') = f (theory_of ctxt)
   284   in (res, ctxt |> transfer thy') end;
   285 
   286 
   287 
   288 (** pretty printing **)
   289 
   290 (* extern *)
   291 
   292 fun extern_fact ctxt name =
   293   let
   294     val local_facts = facts_of ctxt;
   295     val global_facts = PureThy.facts_of (theory_of ctxt);
   296   in
   297     if is_some (Facts.lookup (Context.Proof ctxt) local_facts name)
   298     then Facts.extern local_facts name
   299     else Facts.extern global_facts name
   300   end;
   301 
   302 
   303 (* pretty *)
   304 
   305 fun pretty_term_abbrev ctxt = Syntax.pretty_term (set_mode mode_abbrev ctxt);
   306 
   307 fun pretty_thm_legacy th =
   308   let val thy = Thm.theory_of_thm th
   309   in Display.pretty_thm_aux (Syntax.pp_global thy) true false [] th end;
   310 
   311 fun pretty_thm ctxt th =
   312   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   313   in Display.pretty_thm_aux (Syntax.pp ctxt) false true asms th end;
   314 
   315 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   316   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   317 
   318 fun pretty_fact_name ctxt a = Pretty.block
   319   [Pretty.markup (Markup.fact a) [Pretty.str (extern_fact ctxt a)], Pretty.str ":"];
   320 
   321 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   322   | pretty_fact ctxt (a, [th]) = Pretty.block
   323       [pretty_fact_name ctxt a, Pretty.brk 1, pretty_thm ctxt th]
   324   | pretty_fact ctxt (a, ths) = Pretty.block
   325       (Pretty.fbreaks (pretty_fact_name ctxt a :: map (pretty_thm ctxt) ths));
   326 
   327 val string_of_thm = Pretty.string_of oo pretty_thm;
   328 
   329 
   330 
   331 (** prepare types **)
   332 
   333 (* read_typ *)
   334 
   335 fun read_typ_mode mode ctxt s =
   336   Syntax.read_typ (Type.set_mode mode ctxt) s;
   337 
   338 val read_typ        = read_typ_mode Type.mode_default;
   339 val read_typ_syntax = read_typ_mode Type.mode_syntax;
   340 val read_typ_abbrev = read_typ_mode Type.mode_abbrev;
   341 
   342 
   343 (* cert_typ *)
   344 
   345 fun cert_typ_mode mode ctxt T =
   346   Sign.certify_typ_mode mode (theory_of ctxt) T
   347     handle TYPE (msg, _, _) => error msg;
   348 
   349 val cert_typ        = cert_typ_mode Type.mode_default;
   350 val cert_typ_syntax = cert_typ_mode Type.mode_syntax;
   351 val cert_typ_abbrev = cert_typ_mode Type.mode_abbrev;
   352 
   353 
   354 
   355 (** prepare variables **)
   356 
   357 (* internalize Skolem constants *)
   358 
   359 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   360 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   361 
   362 fun no_skolem internal x =
   363   if can Name.dest_skolem x then
   364     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   365   else if not internal andalso can Name.dest_internal x then
   366     error ("Illegal reference to internal variable: " ^ quote x)
   367   else x;
   368 
   369 
   370 (* revert Skolem constants -- if possible *)
   371 
   372 fun revert_skolem ctxt x =
   373   (case find_first (fn (_, y) => y = x) (Variable.fixes_of ctxt) of
   374     SOME (x', _) => if lookup_skolem ctxt x' = SOME x then x' else x
   375   | NONE => x);
   376 
   377 
   378 (* default token translations *)
   379 
   380 local
   381 
   382 fun free_or_skolem ctxt x =
   383   (if can Name.dest_skolem x then Pretty.mark Markup.skolem (Pretty.str (revert_skolem ctxt x))
   384    else Pretty.mark Markup.free (Pretty.str x))
   385   |> Pretty.mark
   386     (if Variable.is_fixed ctxt x orelse Syntax.is_pretty_global ctxt then Markup.fixed x
   387      else Markup.hilite);
   388 
   389 fun var_or_skolem _ s =
   390   (case Lexicon.read_variable s of
   391     SOME (x, i) =>
   392       (case try Name.dest_skolem x of
   393         NONE => Pretty.mark Markup.var (Pretty.str s)
   394       | SOME x' => Pretty.mark Markup.skolem
   395           (Pretty.str (setmp show_question_marks true Term.string_of_vname (x', i))))
   396   | NONE => Pretty.mark Markup.var (Pretty.str s));
   397 
   398 fun class_markup _ c =    (* FIXME authentic name *)
   399   Pretty.mark (Markup.tclassN, []) (Pretty.str c);
   400 
   401 fun plain_markup m _ s = Pretty.mark m (Pretty.str s);
   402 
   403 val token_trans =
   404  Syntax.tokentrans_mode ""
   405   [("class", class_markup),
   406    ("tfree", plain_markup Markup.tfree),
   407    ("tvar", plain_markup Markup.tvar),
   408    ("free", free_or_skolem),
   409    ("bound", plain_markup Markup.bound),
   410    ("var", var_or_skolem),
   411    ("num", plain_markup Markup.num),
   412    ("xnum", plain_markup Markup.xnum),
   413    ("xstr", plain_markup Markup.xstr)];
   414 
   415 in val _ = Context.>> (Context.map_theory (Sign.add_tokentrfuns token_trans)) end;
   416 
   417 
   418 
   419 (** prepare terms and propositions **)
   420 
   421 (* inferred types of parameters *)
   422 
   423 fun infer_type ctxt x =
   424   Term.fastype_of (singleton (Syntax.check_terms (set_mode mode_schematic ctxt))
   425     (Free (x, dummyT)));
   426 
   427 fun inferred_param x ctxt =
   428   let val T = infer_type ctxt x
   429   in (T, ctxt |> Variable.declare_term (Free (x, T))) end;
   430 
   431 fun inferred_fixes ctxt =
   432   let
   433     val xs = rev (map #2 (Variable.fixes_of ctxt));
   434     val (Ts, ctxt') = fold_map inferred_param xs ctxt;
   435   in (xs ~~ Ts, ctxt') end;
   436 
   437 
   438 (* type and constant names *)
   439 
   440 local
   441 
   442 val token_content = Syntax.read_token #>> SymbolPos.content;
   443 
   444 fun prep_const_proper ctxt (c, pos) =
   445   let val t as (Const (d, _)) =
   446     (case Variable.lookup_const ctxt c of
   447       SOME d => Const (d, Consts.type_scheme (consts_of ctxt) d handle TYPE (msg, _, _) => error msg)
   448     | NONE => Consts.read_const (consts_of ctxt) c)
   449   in Position.report (Markup.const d) pos; t end;
   450 
   451 in
   452 
   453 fun read_tyname ctxt str =
   454   let
   455     val thy = theory_of ctxt;
   456     val (c, pos) = token_content str;
   457   in
   458     if Syntax.is_tid c then
   459      (Position.report Markup.tfree pos;
   460       TFree (c, the_default (Sign.defaultS thy) (Variable.def_sort ctxt (c, ~1))))
   461     else
   462       let
   463         val d = Sign.intern_type thy c;
   464         val _ = Position.report (Markup.tycon d) pos;
   465       in Type (d, replicate (Sign.arity_number thy d) dummyT) end
   466   end;
   467 
   468 fun read_const_proper ctxt = prep_const_proper ctxt o token_content;
   469 
   470 fun read_const ctxt str =
   471   let val (c, pos) = token_content str in
   472     (case (lookup_skolem ctxt c, Variable.is_const ctxt c) of
   473       (SOME x, false) =>
   474         (Position.report (Markup.name x
   475             (if can Name.dest_skolem x then Markup.skolem else Markup.free)) pos;
   476           Free (x, infer_type ctxt x))
   477     | _ => prep_const_proper ctxt (c, pos))
   478   end;
   479 
   480 end;
   481 
   482 
   483 (* read_term *)
   484 
   485 fun read_term_mode mode ctxt = Syntax.read_term (set_mode mode ctxt);
   486 
   487 val read_term_pattern   = read_term_mode mode_pattern;
   488 val read_term_schematic = read_term_mode mode_schematic;
   489 val read_term_abbrev    = read_term_mode mode_abbrev;
   490 
   491 
   492 (* local abbreviations *)
   493 
   494 val tsig_of = Sign.tsig_of o ProofContext.theory_of;
   495 
   496 local
   497 
   498 fun certify_consts ctxt = Consts.certify (Syntax.pp ctxt) (tsig_of ctxt)
   499   (not (abbrev_mode ctxt)) (consts_of ctxt);
   500 
   501 fun reject_schematic (Var (xi, _)) =
   502       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   503   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   504   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   505   | reject_schematic _ = ();
   506 
   507 fun expand_binds ctxt =
   508   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   509     if pattern then I
   510     else Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic)
   511   end;
   512 
   513 in
   514 
   515 fun expand_abbrevs ctxt = certify_consts ctxt #> expand_binds ctxt;
   516 
   517 end;
   518 
   519 
   520 fun contract_abbrevs ctxt t =
   521   let
   522     val thy = theory_of ctxt;
   523     val consts = consts_of ctxt;
   524     val Mode {abbrev, ...} = get_mode ctxt;
   525   in
   526     if abbrev orelse print_mode_active "no_abbrevs" orelse not (can Term.type_of t) then t
   527     else t |> Pattern.rewrite_term thy (Consts.abbrevs_of consts (print_mode_value () @ [""])) []
   528   end;
   529 
   530 
   531 (* patterns *)
   532 
   533 fun prepare_patternT ctxt =
   534   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   535     if pattern orelse schematic then I
   536     else Term.map_atyps
   537       (fn T as TVar (xi, _) =>
   538             if not (TypeInfer.is_param xi)
   539             then error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   540             else T
   541         | T => T)
   542   end;
   543 
   544 
   545 local
   546 
   547 structure AllowDummies = ProofDataFun(type T = bool fun init _ = false);
   548 
   549 fun check_dummies ctxt t =
   550   if AllowDummies.get ctxt then t
   551   else Term.no_dummy_patterns t handle TERM _ => error "Illegal dummy pattern(s) in term";
   552 
   553 fun prepare_dummies ts = #1 (fold_map Term.replace_dummy_patterns ts 1);
   554 
   555 in
   556 
   557 val allow_dummies = AllowDummies.put true;
   558 
   559 fun prepare_patterns ctxt =
   560   let val Mode {pattern, ...} = get_mode ctxt in
   561     TypeInfer.fixate_params (Variable.names_of ctxt) #>
   562     pattern ? Variable.polymorphic ctxt #>
   563     (map o Term.map_types) (prepare_patternT ctxt) #>
   564     (if pattern then prepare_dummies else map (check_dummies ctxt))
   565   end;
   566 
   567 end;
   568 
   569 
   570 (* decoding raw terms (syntax trees) *)
   571 
   572 (* types *)
   573 
   574 fun get_sort thy def_sort raw_env =
   575   let
   576     val tsig = Sign.tsig_of thy;
   577 
   578     fun eq ((xi, S), (xi', S')) =
   579       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   580     val env = distinct eq raw_env;
   581     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   582       | dups => error ("Inconsistent sort constraints for type variable(s) "
   583           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   584 
   585     fun get xi =
   586       (case (AList.lookup (op =) env xi, def_sort xi) of
   587         (NONE, NONE) => Type.defaultS tsig
   588       | (NONE, SOME S) => S
   589       | (SOME S, NONE) => S
   590       | (SOME S, SOME S') =>
   591           if Type.eq_sort tsig (S, S') then S'
   592           else error ("Sort constraint inconsistent with default for type variable " ^
   593             quote (Term.string_of_vname' xi)));
   594   in get end;
   595 
   596 local
   597 
   598 fun intern_skolem ctxt def_type x =
   599   let
   600     val _ = no_skolem false x;
   601     val sko = lookup_skolem ctxt x;
   602     val is_const = can (read_const_proper ctxt) x orelse NameSpace.is_qualified x;
   603     val is_declared = is_some (def_type (x, ~1));
   604   in
   605     if Variable.is_const ctxt x then NONE
   606     else if is_some sko then sko
   607     else if not is_const orelse is_declared then SOME x
   608     else NONE
   609   end;
   610 
   611 in
   612 
   613 fun term_context ctxt =
   614   let val thy = theory_of ctxt in
   615    {get_sort = get_sort thy (Variable.def_sort ctxt),
   616     map_const = fn a => ((true, #1 (Term.dest_Const (read_const_proper ctxt a)))
   617       handle ERROR _ => (false, Consts.intern (consts_of ctxt) a)),
   618     map_free = intern_skolem ctxt (Variable.def_type ctxt false),
   619     map_type = Sign.intern_tycons thy,
   620     map_sort = Sign.intern_sort thy}
   621   end;
   622 
   623 fun decode_term ctxt =
   624   let val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt
   625   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   626 
   627 end;
   628 
   629 
   630 (* certify terms *)
   631 
   632 local
   633 
   634 fun gen_cert prop ctxt t =
   635   t
   636   |> expand_abbrevs ctxt
   637   |> (fn t' => #1 (Sign.certify' prop (Syntax.pp ctxt) false (consts_of ctxt) (theory_of ctxt) t')
   638     handle TYPE (msg, _, _) => error msg
   639       | TERM (msg, _) => error msg);
   640 
   641 in
   642 
   643 val cert_term = gen_cert false;
   644 val cert_prop = gen_cert true;
   645 
   646 end;
   647 
   648 
   649 (* type checking/inference *)
   650 
   651 fun standard_infer_types ctxt ts =
   652   let val Mode {pattern, ...} = get_mode ctxt in
   653     TypeInfer.infer_types (Syntax.pp ctxt) (tsig_of ctxt) (Syntax.check_typs ctxt)
   654       (try (Consts.the_constraint (consts_of ctxt))) (Variable.def_type ctxt pattern)
   655       (Variable.names_of ctxt) (Variable.maxidx_of ctxt) ts
   656     handle TYPE (msg, _, _) => error msg
   657   end;
   658 
   659 local
   660 
   661 fun standard_typ_check ctxt =
   662   map (cert_typ_mode (Type.get_mode ctxt) ctxt) #>
   663   map (prepare_patternT ctxt);
   664 
   665 fun standard_term_check ctxt =
   666   standard_infer_types ctxt #>
   667   map (expand_abbrevs ctxt);
   668 
   669 fun standard_term_uncheck ctxt =
   670   map (contract_abbrevs ctxt);
   671 
   672 fun add eq what f = Context.>> (what (fn xs => fn ctxt =>
   673   let val xs' = f ctxt xs in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end));
   674 
   675 in
   676 
   677 val _ = add (op =) (Syntax.add_typ_check 0 "standard") standard_typ_check;
   678 val _ = add (op aconv) (Syntax.add_term_check 0 "standard") standard_term_check;
   679 val _ = add (op aconv) (Syntax.add_term_check 100 "fixate") prepare_patterns;
   680 
   681 val _ = add (op aconv) (Syntax.add_term_uncheck 0 "standard") standard_term_uncheck;
   682 
   683 end;
   684 
   685 
   686 
   687 (** inner syntax operations **)
   688 
   689 local
   690 
   691 fun parse_sort ctxt text =
   692   let
   693     val (syms, pos) = Syntax.parse_token Markup.sort text;
   694     val S = Syntax.standard_parse_sort ctxt (syn_of ctxt)
   695         (Sign.intern_sort (theory_of ctxt)) (syms, pos)
   696       handle ERROR msg => cat_error msg  ("Failed to parse sort" ^ Position.str_of pos)
   697   in S end;
   698 
   699 fun parse_typ ctxt text =
   700   let
   701     val thy = ProofContext.theory_of ctxt;
   702     val get_sort = get_sort thy (Variable.def_sort ctxt);
   703 
   704     val (syms, pos) = Syntax.parse_token Markup.typ text;
   705     val T = Sign.intern_tycons thy
   706         (Syntax.standard_parse_typ ctxt (syn_of ctxt) get_sort (Sign.intern_sort thy) (syms, pos))
   707       handle ERROR msg => cat_error msg  ("Failed to parse type" ^ Position.str_of pos);
   708   in T end;
   709 
   710 fun parse_term T ctxt text =
   711   let
   712     val thy = theory_of ctxt;
   713     val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt;
   714 
   715     val (T', _) = TypeInfer.paramify_dummies T 0;
   716     val (markup, kind) = if T' = propT then (Markup.prop, "proposition") else (Markup.term, "term");
   717     val (syms, pos) = Syntax.parse_token markup text;
   718 
   719     fun check t = (Syntax.check_term ctxt (TypeInfer.constrain T' t); NONE)
   720       handle ERROR msg => SOME msg;
   721     val t = Syntax.standard_parse_term (Syntax.pp ctxt) check get_sort map_const map_free
   722         map_type map_sort ctxt (Sign.is_logtype thy) (syn_of ctxt) T' (syms, pos)
   723       handle ERROR msg => cat_error msg  ("Failed to parse " ^ kind ^ Position.str_of pos);
   724   in t end;
   725 
   726 
   727 fun unparse_sort ctxt S =
   728   Syntax.standard_unparse_sort ctxt (syn_of ctxt) (Sign.extern_sort (theory_of ctxt) S);
   729 
   730 fun unparse_typ ctxt T =
   731   Syntax.standard_unparse_typ ctxt (syn_of ctxt) (Sign.extern_typ (theory_of ctxt) T);
   732 
   733 fun unparse_term ctxt t =
   734   let
   735     val thy = theory_of ctxt;
   736     val syntax = syntax_of ctxt;
   737     val consts = consts_of ctxt;
   738   in
   739     t
   740     |> Sign.extern_term (Consts.extern_early consts) thy
   741     |> LocalSyntax.extern_term syntax
   742     |> Syntax.standard_unparse_term (Consts.extern consts) ctxt (LocalSyntax.syn_of syntax)
   743         (not (PureThy.old_appl_syntax thy))
   744   end;
   745 
   746 in
   747 
   748 val _ = Syntax.install_operations
   749   {parse_sort = parse_sort,
   750    parse_typ = parse_typ,
   751    parse_term = parse_term dummyT,
   752    parse_prop = parse_term propT,
   753    unparse_sort = unparse_sort,
   754    unparse_typ = unparse_typ,
   755    unparse_term = unparse_term};
   756 
   757 end;
   758 
   759 
   760 
   761 (** export results **)
   762 
   763 fun common_export is_goal inner outer =
   764   map (Assumption.export is_goal inner outer) #>
   765   Variable.export inner outer;
   766 
   767 val goal_export = common_export true;
   768 val export = common_export false;
   769 
   770 fun export_morphism inner outer =
   771   Assumption.export_morphism inner outer $>
   772   Variable.export_morphism inner outer;
   773 
   774 fun norm_export_morphism inner outer =
   775   export_morphism inner outer $>
   776   Morphism.thm_morphism Goal.norm_result;
   777 
   778 
   779 
   780 (** bindings **)
   781 
   782 (* simult_matches *)
   783 
   784 fun simult_matches ctxt (t, pats) =
   785   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   786     NONE => error "Pattern match failed!"
   787   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   788 
   789 
   790 (* add_binds(_i) *)
   791 
   792 local
   793 
   794 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   795   ctxt
   796   |> Variable.add_binds [(xi, Option.map (prep (set_mode mode_default ctxt)) raw_t)];
   797 
   798 in
   799 
   800 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   801   | drop_schematic b = b;
   802 
   803 val add_binds = fold (gen_bind Syntax.read_term);
   804 val add_binds_i = fold (gen_bind cert_term);
   805 
   806 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   807 val auto_bind_goal = auto_bind AutoBind.goal;
   808 val auto_bind_facts = auto_bind AutoBind.facts;
   809 
   810 end;
   811 
   812 
   813 (* match_bind(_i) *)
   814 
   815 local
   816 
   817 fun gen_bind prep_terms gen raw_binds ctxt =
   818   let
   819     fun prep_bind (raw_pats, t) ctxt1 =
   820       let
   821         val T = Term.fastype_of t;
   822         val ctxt2 = Variable.declare_term t ctxt1;
   823         val pats = prep_terms (set_mode mode_pattern ctxt2) T raw_pats;
   824         val binds = simult_matches ctxt2 (t, pats);
   825       in (binds, ctxt2) end;
   826 
   827     val ts = prep_terms ctxt dummyT (map snd raw_binds);
   828     val (binds, ctxt') = apfst flat (fold_map prep_bind (map fst raw_binds ~~ ts) ctxt);
   829     val binds' =
   830       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   831       else binds;
   832     val binds'' = map (apsnd SOME) binds';
   833     val ctxt'' =
   834       tap (Variable.warn_extra_tfrees ctxt)
   835        (if gen then
   836           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   837         else ctxt' |> add_binds_i binds'');
   838   in (ts, ctxt'') end;
   839 
   840 in
   841 
   842 fun read_terms ctxt T =
   843   map (Syntax.parse_term ctxt #> TypeInfer.constrain T) #> Syntax.check_terms ctxt;
   844 
   845 val match_bind = gen_bind read_terms;
   846 val match_bind_i = gen_bind (fn ctxt => fn _ => map (cert_term ctxt));
   847 
   848 end;
   849 
   850 
   851 (* propositions with patterns *)
   852 
   853 local
   854 
   855 fun prep_propp mode prep_props (context, args) =
   856   let
   857     fun prep (_, raw_pats) (ctxt, prop :: props) =
   858       let val ctxt' = Variable.declare_term prop ctxt
   859       in ((prop, prep_props (set_mode mode_pattern ctxt') raw_pats), (ctxt', props)) end;
   860 
   861     val (propp, (context', _)) = (fold_map o fold_map) prep args
   862       (context, prep_props (set_mode mode context) (maps (map fst) args));
   863   in (context', propp) end;
   864 
   865 fun gen_bind_propp mode parse_prop (ctxt, raw_args) =
   866   let
   867     val (ctxt', args) = prep_propp mode parse_prop (ctxt, raw_args);
   868     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   869     val propss = map (map #1) args;
   870 
   871     (*generalize result: context evaluated now, binds added later*)
   872     val gen = Variable.exportT_terms ctxt' ctxt;
   873     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   874   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   875 
   876 in
   877 
   878 val read_propp           = prep_propp mode_default Syntax.read_props;
   879 val cert_propp           = prep_propp mode_default (map o cert_prop);
   880 val read_propp_schematic = prep_propp mode_schematic Syntax.read_props;
   881 val cert_propp_schematic = prep_propp mode_schematic (map o cert_prop);
   882 
   883 val bind_propp             = gen_bind_propp mode_default Syntax.read_props;
   884 val bind_propp_i           = gen_bind_propp mode_default (map o cert_prop);
   885 val bind_propp_schematic   = gen_bind_propp mode_schematic Syntax.read_props;
   886 val bind_propp_schematic_i = gen_bind_propp mode_schematic (map o cert_prop);
   887 
   888 end;
   889 
   890 
   891 
   892 (** theorems **)
   893 
   894 (* fact_tac *)
   895 
   896 fun comp_incr_tac [] _ = no_tac
   897   | comp_incr_tac (th :: ths) i =
   898       (fn st => Goal.compose_hhf_tac (Drule.incr_indexes st th) i st) APPEND comp_incr_tac ths i;
   899 
   900 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   901 
   902 fun potential_facts ctxt prop =
   903   Facts.could_unify (facts_of ctxt) (Term.strip_all_body prop);
   904 
   905 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) => fact_tac (potential_facts ctxt goal) i);
   906 
   907 
   908 (* get_thm(s) *)
   909 
   910 local
   911 
   912 fun retrieve_thms pick ctxt (Facts.Fact s) =
   913       let
   914         val (_, pos) = Syntax.read_token s;
   915         val prop = Syntax.read_prop (set_mode mode_default ctxt) s
   916           |> singleton (Variable.polymorphic ctxt);
   917 
   918         fun prove_fact th =
   919           Goal.prove ctxt [] [] prop (K (ALLGOALS (fact_tac [th])))
   920           |> Thm.default_position_of th;
   921         val res =
   922           (case get_first (try prove_fact) (potential_facts ctxt prop) of
   923             SOME res => res
   924           | NONE => error ("Failed to retrieve literal fact" ^ Position.str_of pos ^ ":\n" ^
   925               Syntax.string_of_term ctxt prop))
   926       in pick "" [res] end
   927   | retrieve_thms pick ctxt xthmref =
   928       let
   929         val thy = theory_of ctxt;
   930         val local_facts = facts_of ctxt;
   931         val thmref = Facts.map_name_of_ref (Facts.intern local_facts) xthmref;
   932         val name = Facts.name_of_ref thmref;
   933         val pos = Facts.pos_of_ref xthmref;
   934         val thms =
   935           if name = "" then [Thm.transfer thy Drule.dummy_thm]
   936           else
   937             (case Facts.lookup (Context.Proof ctxt) local_facts name of
   938               SOME (_, ths) => (Position.report (Markup.local_fact name) pos;
   939                 map (Thm.transfer thy) (Facts.select thmref ths))
   940             | NONE => PureThy.get_fact (Context.Proof ctxt) thy xthmref);
   941       in pick name thms end;
   942 
   943 in
   944 
   945 val get_fact = retrieve_thms (K I);
   946 val get_fact_single = retrieve_thms Facts.the_single;
   947 
   948 fun get_thms ctxt = get_fact ctxt o Facts.named;
   949 fun get_thm ctxt = get_fact_single ctxt o Facts.named;
   950 
   951 end;
   952 
   953 
   954 (* name space operations *)
   955 
   956 val add_path        = map_naming o NameSpace.add_path;
   957 val no_base_names   = map_naming NameSpace.no_base_names;
   958 val qualified_names = map_naming NameSpace.qualified_names;
   959 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   960 val restore_naming  = map_naming o K o naming_of;
   961 val reset_naming    = map_naming (K local_naming);
   962 
   963 
   964 (* facts *)
   965 
   966 local
   967 
   968 fun update_thms _ (b, NONE) ctxt = ctxt |> map_facts (Facts.del (full_name ctxt b))
   969   | update_thms do_props (b, SOME ths) ctxt = ctxt |> map_facts
   970       (Facts.add_local do_props (naming_of ctxt) (b, ths) #> snd);
   971 
   972 fun gen_note_thmss get k = fold_map (fn ((b, more_attrs), raw_facts) => fn ctxt =>
   973   let
   974     val pos = Binding.pos_of b;
   975     val name = full_name ctxt b;
   976     val _ = ContextPosition.report_visible ctxt (Markup.local_fact_decl name) pos;
   977 
   978     val facts = PureThy.name_thmss false pos name (map (apfst (get ctxt)) raw_facts);
   979     fun app (th, attrs) x =
   980       swap (foldl_map (Thm.proof_attributes (surround (Thm.kind k) (attrs @ more_attrs))) (x, th));
   981     val (res, ctxt') = fold_map app facts ctxt;
   982     val thms = PureThy.name_thms false false pos name (flat res);
   983     val Mode {stmt, ...} = get_mode ctxt;
   984   in ((name, thms), ctxt' |> update_thms stmt (b, SOME thms)) end);
   985 
   986 in
   987 
   988 fun note_thmss k = gen_note_thmss get_fact k;
   989 fun note_thmss_i k = gen_note_thmss (K I) k;
   990 
   991 fun put_thms do_props thms ctxt = ctxt
   992   |> map_naming (K local_naming)
   993   |> ContextPosition.set_visible false
   994   |> update_thms do_props (apfst Binding.name thms)
   995   |> ContextPosition.restore_visible ctxt
   996   |> restore_naming ctxt;
   997 
   998 end;
   999 
  1000 
  1001 
  1002 (** parameters **)
  1003 
  1004 (* variables *)
  1005 
  1006 fun declare_var (x, opt_T, mx) ctxt =
  1007   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
  1008   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
  1009 
  1010 local
  1011 
  1012 fun prep_vars prep_typ internal =
  1013   fold_map (fn (raw_b, raw_T, raw_mx) => fn ctxt =>
  1014     let
  1015       val raw_x = Binding.base_name raw_b;
  1016       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
  1017       val _ = Syntax.is_identifier (no_skolem internal x) orelse
  1018         error ("Illegal variable name: " ^ quote x);
  1019 
  1020       fun cond_tvars T =
  1021         if internal then T
  1022         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
  1023       val opt_T = Option.map (cond_tvars o cert_typ ctxt o prep_typ ctxt) raw_T;
  1024       val var = (Binding.map_base (K x) raw_b, opt_T, mx);
  1025     in (var, ctxt |> declare_var (x, opt_T, mx) |> #2) end);
  1026 
  1027 in
  1028 
  1029 val read_vars = prep_vars Syntax.parse_typ false;
  1030 val cert_vars = prep_vars (K I) true;
  1031 
  1032 end;
  1033 
  1034 
  1035 (* authentic constants *)
  1036 
  1037 local
  1038 
  1039 fun const_ast_tr intern ctxt [Syntax.Variable c] =
  1040       let
  1041         val Const (c', _) = read_const_proper ctxt c;
  1042         val d = if intern then const_syntax_name ctxt c' else c;
  1043       in Syntax.Constant d end
  1044   | const_ast_tr _ _ asts = raise Syntax.AST ("const_ast_tr", asts);
  1045 
  1046 in
  1047 
  1048 val _ = Context.>> (Context.map_theory
  1049  (Sign.add_syntax
  1050    [("_context_const", "id => logic", Delimfix "CONST _"),
  1051     ("_context_const", "id => aprop", Delimfix "CONST _"),
  1052     ("_context_const", "longid => logic", Delimfix "CONST _"),
  1053     ("_context_const", "longid => aprop", Delimfix "CONST _"),
  1054     ("_context_xconst", "id => logic", Delimfix "XCONST _"),
  1055     ("_context_xconst", "id => aprop", Delimfix "XCONST _"),
  1056     ("_context_xconst", "longid => logic", Delimfix "XCONST _"),
  1057     ("_context_xconst", "longid => aprop", Delimfix "XCONST _")] #>
  1058   Sign.add_advanced_trfuns
  1059     ([("_context_const", const_ast_tr true), ("_context_xconst", const_ast_tr false)], [], [], [])));
  1060 
  1061 end;
  1062 
  1063 
  1064 (* notation *)
  1065 
  1066 local
  1067 
  1068 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
  1069   | const_syntax ctxt (Const (c, _), mx) =
  1070       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
  1071   | const_syntax _ _ = NONE;
  1072 
  1073 in
  1074 
  1075 fun notation add mode args ctxt =
  1076   ctxt |> map_syntax
  1077     (LocalSyntax.update_modesyntax (theory_of ctxt) add mode (map_filter (const_syntax ctxt) args));
  1078 
  1079 fun target_notation add mode args phi =
  1080   let val args' = filter (fn (t, _) => Type.similar_types (t, Morphism.term phi t)) args;
  1081   in Context.mapping (Sign.notation add mode args') (notation add mode args') end;
  1082 
  1083 end;
  1084 
  1085 
  1086 (* local constants *)
  1087 
  1088 fun add_const_constraint (c, opt_T) ctxt =
  1089   let
  1090     fun prepT raw_T =
  1091       let val T = cert_typ ctxt raw_T
  1092       in cert_term ctxt (Const (c, T)); T end;
  1093   in ctxt |> (map_consts o apfst) (Consts.constrain (c, Option.map prepT opt_T)) end;
  1094 
  1095 fun add_abbrev mode tags (b, raw_t) ctxt =
  1096   let
  1097     val t0 = cert_term (ctxt |> set_mode mode_abbrev) raw_t
  1098       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.display b));
  1099     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
  1100     val ((lhs, rhs), consts') = consts_of ctxt
  1101       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode tags (b, t);
  1102   in
  1103     ctxt
  1104     |> (map_consts o apfst) (K consts')
  1105     |> Variable.declare_term rhs
  1106     |> pair (lhs, rhs)
  1107   end;
  1108 
  1109 fun revert_abbrev mode c = (map_consts o apfst) (Consts.revert_abbrev mode c);
  1110 
  1111 
  1112 (* fixes *)
  1113 
  1114 local
  1115 
  1116 fun prep_mixfix (x, T, mx) =
  1117   if mx <> NoSyn andalso mx <> Structure andalso
  1118       (can Name.dest_internal x orelse can Name.dest_skolem x) then
  1119     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
  1120   else (true, (x, T, mx));
  1121 
  1122 fun gen_fixes prep raw_vars ctxt =
  1123   let
  1124     val (vars, _) = prep raw_vars ctxt;
  1125     val (xs', ctxt') = Variable.add_fixes (map (Binding.base_name o #1) vars) ctxt;
  1126     val ctxt'' =
  1127       ctxt'
  1128       |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
  1129       |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix);
  1130     val _ = (vars ~~ xs') |> List.app (fn ((b, _, _), x') =>
  1131       ContextPosition.report_visible ctxt (Markup.fixed_decl x') (Binding.pos_of b));
  1132   in (xs', ctxt'') end;
  1133 
  1134 in
  1135 
  1136 val add_fixes = gen_fixes read_vars;
  1137 val add_fixes_i = gen_fixes cert_vars;
  1138 
  1139 end;
  1140 
  1141 
  1142 (* fixes vs. frees *)
  1143 
  1144 fun auto_fixes (arg as (ctxt, (propss, x))) =
  1145   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
  1146 
  1147 fun bind_fixes xs ctxt =
  1148   let
  1149     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (Binding.name x, NONE, NoSyn)) xs);
  1150     fun bind (t as Free (x, T)) =
  1151           if member (op =) xs x then
  1152             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1153           else t
  1154       | bind (t $ u) = bind t $ bind u
  1155       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1156       | bind a = a;
  1157   in (bind, ctxt') end;
  1158 
  1159 
  1160 
  1161 (** assumptions **)
  1162 
  1163 local
  1164 
  1165 fun gen_assms prepp exp args ctxt =
  1166   let
  1167     val cert = Thm.cterm_of (theory_of ctxt);
  1168     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1169     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1170     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1171   in
  1172     ctxt2
  1173     |> auto_bind_facts (flat propss)
  1174     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1175   end;
  1176 
  1177 in
  1178 
  1179 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1180 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1181 
  1182 end;
  1183 
  1184 
  1185 
  1186 (** cases **)
  1187 
  1188 local
  1189 
  1190 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1191 
  1192 fun add_case _ ("", _) cases = cases
  1193   | add_case _ (name, NONE) cases = rem_case name cases
  1194   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1195 
  1196 fun prep_case name fxs c =
  1197   let
  1198     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1199       | replace [] ys = ys
  1200       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1201     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1202     val fixes' = replace fxs fixes;
  1203     val binds' = map drop_schematic binds;
  1204   in
  1205     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1206       null (fold (fold Term.add_vars o snd) assumes []) then
  1207         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1208     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1209   end;
  1210 
  1211 fun fix (x, T) ctxt =
  1212   let
  1213     val (bind, ctxt') = bind_fixes [x] ctxt;
  1214     val t = bind (Free (x, T));
  1215   in (t, ctxt' |> Variable.declare_constraints t) end;
  1216 
  1217 in
  1218 
  1219 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1220 
  1221 fun case_result c ctxt =
  1222   let
  1223     val RuleCases.Case {fixes, ...} = c;
  1224     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1225     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1226   in
  1227     ctxt'
  1228     |> add_binds_i (map drop_schematic binds)
  1229     |> add_cases true (map (apsnd SOME) cases)
  1230     |> pair (assumes, (binds, cases))
  1231   end;
  1232 
  1233 val apply_case = apfst fst oo case_result;
  1234 
  1235 fun get_case ctxt name xs =
  1236   (case AList.lookup (op =) (cases_of ctxt) name of
  1237     NONE => error ("Unknown case: " ^ quote name)
  1238   | SOME (c, _) => prep_case name xs c);
  1239 
  1240 end;
  1241 
  1242 
  1243 
  1244 (** print context information **)
  1245 
  1246 val debug = ref false;
  1247 
  1248 val verbose = ref false;
  1249 fun verb f x = if ! verbose then f (x ()) else [];
  1250 
  1251 fun setmp_verbose f x = Library.setmp verbose true f x;
  1252 
  1253 
  1254 (* local syntax *)
  1255 
  1256 val print_syntax = Syntax.print_syntax o syn_of;
  1257 
  1258 
  1259 (* abbreviations *)
  1260 
  1261 fun pretty_abbrevs show_globals ctxt =
  1262   let
  1263     val ((space, consts), (_, globals)) =
  1264       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1265     fun add_abbr (_, (_, NONE)) = I
  1266       | add_abbr (c, (T, SOME t)) =
  1267           if not show_globals andalso Symtab.defined globals c then I
  1268           else cons (c, Logic.mk_equals (Const (c, T), t));
  1269     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1270   in
  1271     if null abbrevs andalso not (! verbose) then []
  1272     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1273   end;
  1274 
  1275 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1276 
  1277 
  1278 (* term bindings *)
  1279 
  1280 fun pretty_binds ctxt =
  1281   let
  1282     val binds = Variable.binds_of ctxt;
  1283     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1284   in
  1285     if Vartab.is_empty binds andalso not (! verbose) then []
  1286     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1287   end;
  1288 
  1289 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1290 
  1291 
  1292 (* local theorems *)
  1293 
  1294 fun pretty_lthms ctxt =
  1295   let
  1296     val local_facts = facts_of ctxt;
  1297     val props = Facts.props local_facts;
  1298     val facts =
  1299       (if null props then [] else [("unnamed", props)]) @
  1300       Facts.dest_static [] local_facts;
  1301   in
  1302     if null facts andalso not (! verbose) then []
  1303     else [Pretty.big_list "facts:" (map #1 (sort_wrt (#1 o #2) (map (`(pretty_fact ctxt)) facts)))]
  1304   end;
  1305 
  1306 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1307 
  1308 
  1309 (* local contexts *)
  1310 
  1311 local
  1312 
  1313 fun pretty_case (name, (fixes, ((asms, (lets, cs)), ctxt))) =
  1314   let
  1315     val prt_term = Syntax.pretty_term ctxt;
  1316 
  1317     fun prt_let (xi, t) = Pretty.block
  1318       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1319         Pretty.quote (prt_term t)];
  1320 
  1321     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1322       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1323 
  1324     fun prt_sect _ _ _ [] = []
  1325       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1326             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1327   in
  1328     Pretty.block (Pretty.fbreaks
  1329       (Pretty.str (name ^ ":") ::
  1330         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1331         prt_sect "let" [Pretty.str "and"] prt_let
  1332           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1333         (if forall (null o #2) asms then []
  1334           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1335         prt_sect "subcases:" [] (Pretty.str o fst) cs))
  1336   end;
  1337 
  1338 in
  1339 
  1340 fun pretty_cases ctxt =
  1341   let
  1342     fun add_case (_, (_, false)) = I
  1343       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1344           cons (name, (fixes, case_result c ctxt));
  1345     val cases = fold add_case (cases_of ctxt) [];
  1346   in
  1347     if null cases andalso not (! verbose) then []
  1348     else [Pretty.big_list "cases:" (map pretty_case cases)]
  1349   end;
  1350 
  1351 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1352 
  1353 end;
  1354 
  1355 
  1356 (* core context *)
  1357 
  1358 val prems_limit = ref ~1;
  1359 
  1360 fun pretty_ctxt ctxt =
  1361   if ! prems_limit < 0 andalso not (! debug) then []
  1362   else
  1363     let
  1364       val prt_term = Syntax.pretty_term ctxt;
  1365 
  1366       (*structures*)
  1367       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1368       val prt_structs = if null structs then []
  1369         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1370           Pretty.commas (map Pretty.str structs))];
  1371 
  1372       (*fixes*)
  1373       fun prt_fix (x, x') =
  1374         if x = x' then Pretty.str x
  1375         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1376       val fixes =
  1377         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1378           (Variable.fixes_of ctxt));
  1379       val prt_fixes = if null fixes then []
  1380         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1381           Pretty.commas (map prt_fix fixes))];
  1382 
  1383       (*prems*)
  1384       val prems = Assumption.prems_of ctxt;
  1385       val len = length prems;
  1386       val suppressed = len - ! prems_limit;
  1387       val prt_prems = if null prems then []
  1388         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1389           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1390     in prt_structs @ prt_fixes @ prt_prems end;
  1391 
  1392 
  1393 (* main context *)
  1394 
  1395 fun pretty_context ctxt =
  1396   let
  1397     val prt_term = Syntax.pretty_term ctxt;
  1398     val prt_typ = Syntax.pretty_typ ctxt;
  1399     val prt_sort = Syntax.pretty_sort ctxt;
  1400 
  1401     (*theory*)
  1402     val pretty_thy = Pretty.block
  1403       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1404 
  1405     (*defaults*)
  1406     fun prt_atom prt prtT (x, X) = Pretty.block
  1407       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1408 
  1409     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1410       | prt_var xi = prt_term (Syntax.var xi);
  1411 
  1412     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1413       | prt_varT xi = prt_typ (TVar (xi, []));
  1414 
  1415     val prt_defT = prt_atom prt_var prt_typ;
  1416     val prt_defS = prt_atom prt_varT prt_sort;
  1417 
  1418     val (types, sorts) = Variable.constraints_of ctxt;
  1419   in
  1420     verb single (K pretty_thy) @
  1421     pretty_ctxt ctxt @
  1422     verb (pretty_abbrevs false) (K ctxt) @
  1423     verb pretty_binds (K ctxt) @
  1424     verb pretty_lthms (K ctxt) @
  1425     verb pretty_cases (K ctxt) @
  1426     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1427     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1428   end;
  1429 
  1430 
  1431 (* query meta data *)
  1432 
  1433 val query_type = Type.the_tags o tsig_of;
  1434 
  1435 fun query_const ctxt name =
  1436   Consts.the_tags (consts_of ctxt) name handle TYPE (msg, _, _) => error msg;
  1437 
  1438 fun query_class ctxt name = query_const ctxt (Logic.const_of_class name);
  1439 
  1440 end;