src/Pure/Isar/context_rules.ML
author wenzelm
Sat Apr 27 20:50:20 2013 +0200 (2013-04-27 ago)
changeset 51798 ad3a241def73
parent 51584 98029ceda8ce
child 53171 a5e54d4d9081
permissions -rw-r--r--
uniform Proof.context for hyp_subst_tac;
     1 (*  Title:      Pure/Isar/context_rules.ML
     2     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     3 
     4 Declarations of intro/elim/dest rules in Pure (see also
     5 Provers/classical.ML for a more specialized version of the same idea).
     6 *)
     7 
     8 signature CONTEXT_RULES =
     9 sig
    10   type netpair = ((int * int) * (bool * thm)) Net.net * ((int * int) * (bool * thm)) Net.net
    11   val netpair_bang: Proof.context -> netpair
    12   val netpair: Proof.context -> netpair
    13   val orderlist: ((int * int) * 'a) list -> 'a list
    14   val find_rules_netpair: bool -> thm list -> term -> netpair -> thm list
    15   val find_rules: bool -> thm list -> term -> Proof.context -> thm list list
    16   val print_rules: Proof.context -> unit
    17   val addSWrapper: (Proof.context -> (int -> tactic) -> int -> tactic) -> theory -> theory
    18   val addWrapper: (Proof.context -> (int -> tactic) -> int -> tactic) -> theory -> theory
    19   val Swrap: Proof.context -> (int -> tactic) -> int -> tactic
    20   val wrap: Proof.context -> (int -> tactic) -> int -> tactic
    21   val intro_bang: int option -> attribute
    22   val elim_bang: int option -> attribute
    23   val dest_bang: int option -> attribute
    24   val intro: int option -> attribute
    25   val elim: int option -> attribute
    26   val dest: int option -> attribute
    27   val intro_query: int option -> attribute
    28   val elim_query: int option -> attribute
    29   val dest_query: int option -> attribute
    30   val rule_del: attribute
    31   val add: (int option -> attribute) -> (int option -> attribute) -> (int option -> attribute) ->
    32     attribute context_parser
    33 end;
    34 
    35 structure Context_Rules: CONTEXT_RULES =
    36 struct
    37 
    38 
    39 (** rule declaration contexts **)
    40 
    41 (* rule kinds *)
    42 
    43 val intro_bangK = (0, false);
    44 val elim_bangK = (0, true);
    45 val introK = (1, false);
    46 val elimK = (1, true);
    47 val intro_queryK = (2, false);
    48 val elim_queryK = (2, true);
    49 
    50 val kind_names =
    51  [(intro_bangK, "safe introduction rules (intro!)"),
    52   (elim_bangK, "safe elimination rules (elim!)"),
    53   (introK, "introduction rules (intro)"),
    54   (elimK, "elimination rules (elim)"),
    55   (intro_queryK, "extra introduction rules (intro?)"),
    56   (elim_queryK, "extra elimination rules (elim?)")];
    57 
    58 val rule_kinds = map #1 kind_names;
    59 val rule_indexes = distinct (op =) (map #1 rule_kinds);
    60 
    61 
    62 (* context data *)
    63 
    64 type netpair = ((int * int) * (bool * thm)) Net.net * ((int * int) * (bool * thm)) Net.net;
    65 val empty_netpairs: netpair list = replicate (length rule_indexes) (Net.empty, Net.empty);
    66 
    67 datatype rules = Rules of
    68  {next: int,
    69   rules: (int * ((int * bool) * thm)) list,
    70   netpairs: netpair list,
    71   wrappers:
    72     ((Proof.context -> (int -> tactic) -> int -> tactic) * stamp) list *
    73     ((Proof.context -> (int -> tactic) -> int -> tactic) * stamp) list};
    74 
    75 fun make_rules next rules netpairs wrappers =
    76   Rules {next = next, rules = rules, netpairs = netpairs, wrappers = wrappers};
    77 
    78 fun add_rule (i, b) opt_w th (Rules {next, rules, netpairs, wrappers}) =
    79   let val w = (case opt_w of SOME w => w | NONE => Tactic.subgoals_of_brl (b, th)) in
    80     make_rules (next - 1) ((w, ((i, b), th)) :: rules)
    81       (nth_map i (Tactic.insert_tagged_brl ((w, next), (b, th))) netpairs) wrappers
    82   end;
    83 
    84 fun del_rule0 th (rs as Rules {next, rules, netpairs, wrappers}) =
    85   let
    86     fun eq_th (_, (_, th')) = Thm.eq_thm_prop (th, th');
    87     fun del b netpair = Tactic.delete_tagged_brl (b, th) netpair handle Net.DELETE => netpair;
    88   in
    89     if not (exists eq_th rules) then rs
    90     else make_rules next (filter_out eq_th rules) (map (del false o del true) netpairs) wrappers
    91   end;
    92 
    93 fun del_rule th = del_rule0 th o del_rule0 (Tactic.make_elim th);
    94 
    95 structure Rules = Generic_Data
    96 (
    97   type T = rules;
    98   val empty = make_rules ~1 [] empty_netpairs ([], []);
    99   val extend = I;
   100   fun merge
   101     (Rules {rules = rules1, wrappers = (ws1, ws1'), ...},
   102       Rules {rules = rules2, wrappers = (ws2, ws2'), ...}) =
   103     let
   104       val wrappers =
   105         (Library.merge (eq_snd (op =)) (ws1, ws2), Library.merge (eq_snd (op =)) (ws1', ws2'));
   106       val rules = Library.merge (fn ((_, (k1, th1)), (_, (k2, th2))) =>
   107           k1 = k2 andalso Thm.eq_thm_prop (th1, th2)) (rules1, rules2);
   108       val next = ~ (length rules);
   109       val netpairs = fold (fn (n, (w, ((i, b), th))) =>
   110           nth_map i (Tactic.insert_tagged_brl ((w, n), (b, th))))
   111         (next upto ~1 ~~ rules) empty_netpairs;
   112     in make_rules (next - 1) rules netpairs wrappers end;
   113 );
   114 
   115 fun print_rules ctxt =
   116   let
   117     val Rules {rules, ...} = Rules.get (Context.Proof ctxt);
   118     fun prt_kind (i, b) =
   119       Pretty.big_list ((the o AList.lookup (op =) kind_names) (i, b) ^ ":")
   120         (map_filter (fn (_, (k, th)) =>
   121             if k = (i, b) then SOME (Display.pretty_thm_item ctxt th) else NONE)
   122           (sort (int_ord o pairself fst) rules));
   123   in Pretty.writeln (Pretty.chunks (map prt_kind rule_kinds)) end;
   124 
   125 
   126 (* access data *)
   127 
   128 fun netpairs ctxt = let val Rules {netpairs, ...} = Rules.get (Context.Proof ctxt) in netpairs end;
   129 val netpair_bang = hd o netpairs;
   130 val netpair = hd o tl o netpairs;
   131 
   132 
   133 (* retrieving rules *)
   134 
   135 fun untaglist [] = []
   136   | untaglist [(_ : int * int, x)] = [x]
   137   | untaglist ((k, x) :: (rest as (k', _) :: _)) =
   138       if k = k' then untaglist rest
   139       else x :: untaglist rest;
   140 
   141 fun orderlist brls =
   142   untaglist (sort (prod_ord int_ord int_ord o pairself fst) brls);
   143 
   144 fun orderlist_no_weight brls =
   145   untaglist (sort (int_ord o pairself (snd o fst)) brls);
   146 
   147 fun may_unify weighted t net =
   148   map snd ((if weighted then orderlist else orderlist_no_weight) (Net.unify_term net t));
   149 
   150 fun find_erules _ [] = K []
   151   | find_erules w (fact :: _) = may_unify w (Logic.strip_assums_concl (Thm.prop_of fact));
   152 
   153 fun find_irules w goal = may_unify w (Logic.strip_assums_concl goal);
   154 
   155 fun find_rules_netpair weighted facts goal (inet, enet) =
   156   find_erules weighted facts enet @ find_irules weighted goal inet;
   157 
   158 fun find_rules weighted facts goals =
   159   map (find_rules_netpair weighted facts goals) o netpairs;
   160 
   161 
   162 (* wrappers *)
   163 
   164 fun gen_add_wrapper upd w =
   165   Context.theory_map (Rules.map (fn Rules {next, rules, netpairs, wrappers} =>
   166     make_rules next rules netpairs (upd (fn ws => (w, stamp ()) :: ws) wrappers)));
   167 
   168 val addSWrapper = gen_add_wrapper Library.apfst;
   169 val addWrapper = gen_add_wrapper Library.apsnd;
   170 
   171 
   172 fun gen_wrap which ctxt =
   173   let val Rules {wrappers, ...} = Rules.get (Context.Proof ctxt)
   174   in fold_rev (fn (w, _) => w ctxt) (which wrappers) end;
   175 
   176 val Swrap = gen_wrap #1;
   177 val wrap = gen_wrap #2;
   178 
   179 
   180 
   181 (** attributes **)
   182 
   183 (* add and del rules *)
   184 
   185 
   186 val rule_del = Thm.declaration_attribute (fn th => Rules.map (del_rule th));
   187 
   188 fun rule_add k view opt_w =
   189   Thm.declaration_attribute (fn th => Rules.map (add_rule k opt_w (view th) o del_rule th));
   190 
   191 val intro_bang  = rule_add intro_bangK I;
   192 val elim_bang   = rule_add elim_bangK I;
   193 val dest_bang   = rule_add elim_bangK Tactic.make_elim;
   194 val intro       = rule_add introK I;
   195 val elim        = rule_add elimK I;
   196 val dest        = rule_add elimK Tactic.make_elim;
   197 val intro_query = rule_add intro_queryK I;
   198 val elim_query  = rule_add elim_queryK I;
   199 val dest_query  = rule_add elim_queryK Tactic.make_elim;
   200 
   201 val _ = Context.>> (Context.map_theory
   202   (snd o Global_Theory.add_thms [((Binding.empty, Drule.equal_intr_rule), [intro_query NONE])]));
   203 
   204 
   205 (* concrete syntax *)
   206 
   207 fun add a b c x =
   208   (Scan.lift ((Args.bang >> K a || Args.query >> K c || Scan.succeed b) --
   209     Scan.option Parse.nat) >> (fn (f, n) => f n)) x;
   210 
   211 val _ = Context.>> (Context.map_theory
   212  (Attrib.setup (Binding.name "intro") (add intro_bang intro intro_query)
   213     "declaration of introduction rule" #>
   214   Attrib.setup (Binding.name "elim") (add elim_bang elim elim_query)
   215     "declaration of elimination rule" #>
   216   Attrib.setup (Binding.name "dest") (add dest_bang dest dest_query)
   217     "declaration of destruction rule" #>
   218   Attrib.setup (Binding.name "rule") (Scan.lift Args.del >> K rule_del)
   219     "remove declaration of intro/elim/dest rule"));
   220 
   221 end;