src/Pure/proofterm.ML
author haftmann
Tue Oct 20 16:13:01 2009 +0200 (2009-10-20 ago)
changeset 33037 b22e44496dc2
parent 32810 f3466a5645fa
child 33038 8f9594c31de4
permissions -rw-r--r--
replaced old_style infixes eq_set, subset, union, inter and variants by generic versions
     1 (*  Title:      Pure/proofterm.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 LF style proof terms.
     5 *)
     6 
     7 infix 8 % %% %>;
     8 
     9 signature BASIC_PROOFTERM =
    10 sig
    11   val proofs: int Unsynchronized.ref
    12 
    13   datatype proof =
    14      MinProof
    15    | PBound of int
    16    | Abst of string * typ option * proof
    17    | AbsP of string * term option * proof
    18    | op % of proof * term option
    19    | op %% of proof * proof
    20    | Hyp of term
    21    | PAxm of string * term * typ list option
    22    | OfClass of typ * class
    23    | Oracle of string * term * typ list option
    24    | Promise of serial * term * typ list
    25    | PThm of serial * ((string * term * typ list option) * proof_body future)
    26   and proof_body = PBody of
    27     {oracles: (string * term) OrdList.T,
    28      thms: (serial * (string * term * proof_body future)) OrdList.T,
    29      proof: proof}
    30 
    31   val %> : proof * term -> proof
    32 end;
    33 
    34 signature PROOFTERM =
    35 sig
    36   include BASIC_PROOFTERM
    37 
    38   type oracle = string * term
    39   type pthm = serial * (string * term * proof_body future)
    40   val proof_of: proof_body -> proof
    41   val join_proof: proof_body future -> proof
    42   val fold_proof_atoms: bool -> (proof -> 'a -> 'a) -> proof list -> 'a -> 'a
    43   val fold_body_thms: (string * term * proof_body -> 'a -> 'a) -> proof_body list -> 'a -> 'a
    44   val join_bodies: proof_body list -> unit
    45   val status_of: proof_body list -> {failed: bool, oracle: bool, unfinished: bool}
    46 
    47   val oracle_ord: oracle * oracle -> order
    48   val thm_ord: pthm * pthm -> order
    49   val merge_oracles: oracle OrdList.T -> oracle OrdList.T -> oracle OrdList.T
    50   val merge_thms: pthm OrdList.T -> pthm OrdList.T -> pthm OrdList.T
    51   val all_oracles_of: proof_body -> oracle OrdList.T
    52   val approximate_proof_body: proof -> proof_body
    53 
    54   (** primitive operations **)
    55   val proof_combt: proof * term list -> proof
    56   val proof_combt': proof * term option list -> proof
    57   val proof_combP: proof * proof list -> proof
    58   val strip_combt: proof -> proof * term option list
    59   val strip_combP: proof -> proof * proof list
    60   val strip_thm: proof_body -> proof_body
    61   val map_proof_terms_option: (term -> term option) -> (typ -> typ option) -> proof -> proof
    62   val map_proof_terms: (term -> term) -> (typ -> typ) -> proof -> proof
    63   val fold_proof_terms: (term -> 'a -> 'a) -> (typ -> 'a -> 'a) -> proof -> 'a -> 'a
    64   val maxidx_proof: proof -> int -> int
    65   val size_of_proof: proof -> int
    66   val change_type: typ list option -> proof -> proof
    67   val prf_abstract_over: term -> proof -> proof
    68   val prf_incr_bv: int -> int -> int -> int -> proof -> proof
    69   val incr_pboundvars: int -> int -> proof -> proof
    70   val prf_loose_bvar1: proof -> int -> bool
    71   val prf_loose_Pbvar1: proof -> int -> bool
    72   val prf_add_loose_bnos: int -> int -> proof -> int list * int list -> int list * int list
    73   val norm_proof: Envir.env -> proof -> proof
    74   val norm_proof': Envir.env -> proof -> proof
    75   val prf_subst_bounds: term list -> proof -> proof
    76   val prf_subst_pbounds: proof list -> proof -> proof
    77   val freeze_thaw_prf: proof -> proof * (proof -> proof)
    78 
    79   (** proof terms for specific inference rules **)
    80   val implies_intr_proof: term -> proof -> proof
    81   val forall_intr_proof: term -> string -> proof -> proof
    82   val varify_proof: term -> (string * sort) list -> proof -> proof
    83   val freezeT: term -> proof -> proof
    84   val rotate_proof: term list -> term -> int -> proof -> proof
    85   val permute_prems_prf: term list -> int -> int -> proof -> proof
    86   val generalize: string list * string list -> int -> proof -> proof
    87   val instantiate: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
    88     -> proof -> proof
    89   val lift_proof: term -> int -> term -> proof -> proof
    90   val incr_indexes: int -> proof -> proof
    91   val assumption_proof: term list -> term -> int -> proof -> proof
    92   val bicompose_proof: bool -> term list -> term list -> term list -> term option ->
    93     int -> int -> proof -> proof -> proof
    94   val equality_axms: (string * term) list
    95   val reflexive_axm: proof
    96   val symmetric_axm: proof
    97   val transitive_axm: proof
    98   val equal_intr_axm: proof
    99   val equal_elim_axm: proof
   100   val abstract_rule_axm: proof
   101   val combination_axm: proof
   102   val reflexive: proof
   103   val symmetric: proof -> proof
   104   val transitive: term -> typ -> proof -> proof -> proof
   105   val abstract_rule: term -> string -> proof -> proof
   106   val combination: term -> term -> term -> term -> typ -> proof -> proof -> proof
   107   val equal_intr: term -> term -> proof -> proof -> proof
   108   val equal_elim: term -> term -> proof -> proof -> proof
   109   val axm_proof: string -> term -> proof
   110   val oracle_proof: string -> term -> oracle * proof
   111   val promise_proof: theory -> serial -> term -> proof
   112   val fulfill_proof: theory -> (serial * proof_body) list -> proof_body -> proof_body
   113   val thm_proof: theory -> string -> term list -> term ->
   114     (serial * proof_body future) list -> proof_body -> pthm * proof
   115   val get_name: term list -> term -> proof -> string
   116 
   117   (** rewriting on proof terms **)
   118   val add_prf_rrule: proof * proof -> theory -> theory
   119   val add_prf_rproc: (typ list -> proof -> proof option) -> theory -> theory
   120   val rewrite_proof: theory -> (proof * proof) list *
   121     (typ list -> proof -> proof option) list -> proof -> proof
   122   val rewrite_proof_notypes: (proof * proof) list *
   123     (typ list -> proof -> proof option) list -> proof -> proof
   124   val rew_proof: theory -> proof -> proof
   125 end
   126 
   127 structure Proofterm : PROOFTERM =
   128 struct
   129 
   130 (***** datatype proof *****)
   131 
   132 datatype proof =
   133    MinProof
   134  | PBound of int
   135  | Abst of string * typ option * proof
   136  | AbsP of string * term option * proof
   137  | op % of proof * term option
   138  | op %% of proof * proof
   139  | Hyp of term
   140  | PAxm of string * term * typ list option
   141  | OfClass of typ * class
   142  | Oracle of string * term * typ list option
   143  | Promise of serial * term * typ list
   144  | PThm of serial * ((string * term * typ list option) * proof_body future)
   145 and proof_body = PBody of
   146   {oracles: (string * term) OrdList.T,
   147    thms: (serial * (string * term * proof_body future)) OrdList.T,
   148    proof: proof};
   149 
   150 type oracle = string * term;
   151 type pthm = serial * (string * term * proof_body future);
   152 
   153 fun proof_of (PBody {proof, ...}) = proof;
   154 val join_proof = Future.join #> proof_of;
   155 
   156 
   157 (***** proof atoms *****)
   158 
   159 fun fold_proof_atoms all f =
   160   let
   161     fun app (Abst (_, _, prf)) = app prf
   162       | app (AbsP (_, _, prf)) = app prf
   163       | app (prf % _) = app prf
   164       | app (prf1 %% prf2) = app prf1 #> app prf2
   165       | app (prf as PThm (i, (_, body))) = (fn (x, seen) =>
   166           if Inttab.defined seen i then (x, seen)
   167           else
   168             let val (x', seen') =
   169               (if all then app (join_proof body) else I) (x, Inttab.update (i, ()) seen)
   170             in (f prf x', seen') end)
   171       | app prf = (fn (x, seen) => (f prf x, seen));
   172   in fn prfs => fn x => #1 (fold app prfs (x, Inttab.empty)) end;
   173 
   174 fun fold_body_thms f =
   175   let
   176     fun app (PBody {thms, ...}) =
   177      (Future.join_results (map (#3 o #2) thms);
   178       thms |> fold (fn (i, (name, prop, body)) => fn (x, seen) =>
   179         if Inttab.defined seen i then (x, seen)
   180         else
   181           let
   182             val body' = Future.join body;
   183             val (x', seen') = app body' (x, Inttab.update (i, ()) seen);
   184           in (f (name, prop, body') x', seen') end));
   185   in fn bodies => fn x => #1 (fold app bodies (x, Inttab.empty)) end;
   186 
   187 fun join_bodies bodies = fold_body_thms (fn _ => fn () => ()) bodies ();
   188 
   189 fun status_of bodies =
   190   let
   191     fun status (PBody {oracles, thms, ...}) x =
   192       let
   193         val ((oracle, unfinished, failed), seen) =
   194           (thms, x) |-> fold (fn (i, (_, _, body)) => fn (st, seen) =>
   195             if Inttab.defined seen i then (st, seen)
   196             else
   197               let val seen' = Inttab.update (i, ()) seen in
   198                 (case Future.peek body of
   199                   SOME (Exn.Result body') => status body' (st, seen')
   200                 | SOME (Exn.Exn _) =>
   201                     let val (oracle, unfinished, _) = st
   202                     in ((oracle, unfinished, true), seen') end
   203                 | NONE =>
   204                     let val (oracle, _, failed) = st
   205                     in ((oracle, true, failed), seen') end)
   206               end);
   207       in ((oracle orelse not (null oracles), unfinished, failed), seen) end;
   208     val (oracle, unfinished, failed) =
   209       #1 (fold status bodies ((false, false, false), Inttab.empty));
   210   in {oracle = oracle, unfinished = unfinished, failed = failed} end;
   211 
   212 
   213 (* proof body *)
   214 
   215 val oracle_ord = prod_ord fast_string_ord TermOrd.fast_term_ord;
   216 fun thm_ord ((i, _): pthm, (j, _)) = int_ord (j, i);
   217 
   218 val merge_oracles = OrdList.union oracle_ord;
   219 val merge_thms = OrdList.union thm_ord;
   220 
   221 val all_oracles_of =
   222   let
   223     fun collect (PBody {oracles, thms, ...}) =
   224      (Future.join_results (map (#3 o #2) thms);
   225       thms |> fold (fn (i, (_, _, body)) => fn (x, seen) =>
   226         if Inttab.defined seen i then (x, seen)
   227         else
   228           let
   229             val body' = Future.join body;
   230             val (x', seen') = collect body' (x, Inttab.update (i, ()) seen);
   231           in (merge_oracles oracles x', seen') end));
   232   in fn body => #1 (collect body ([], Inttab.empty)) end;
   233 
   234 fun approximate_proof_body prf =
   235   let
   236     val (oracles, thms) = fold_proof_atoms false
   237       (fn Oracle (s, prop, _) => apfst (cons (s, prop))
   238         | PThm (i, ((name, prop, _), body)) => apsnd (cons (i, (name, prop, body)))
   239         | _ => I) [prf] ([], []);
   240   in
   241     PBody
   242      {oracles = OrdList.make oracle_ord oracles,
   243       thms = OrdList.make thm_ord thms,
   244       proof = prf}
   245   end;
   246 
   247 
   248 (***** proof objects with different levels of detail *****)
   249 
   250 fun (prf %> t) = prf % SOME t;
   251 
   252 val proof_combt = Library.foldl (op %>);
   253 val proof_combt' = Library.foldl (op %);
   254 val proof_combP = Library.foldl (op %%);
   255 
   256 fun strip_combt prf =
   257     let fun stripc (prf % t, ts) = stripc (prf, t::ts)
   258           | stripc  x =  x
   259     in  stripc (prf, [])  end;
   260 
   261 fun strip_combP prf =
   262     let fun stripc (prf %% prf', prfs) = stripc (prf, prf'::prfs)
   263           | stripc  x =  x
   264     in  stripc (prf, [])  end;
   265 
   266 fun strip_thm (body as PBody {proof, ...}) =
   267   (case strip_combt (fst (strip_combP proof)) of
   268     (PThm (_, (_, body')), _) => Future.join body'
   269   | _ => body);
   270 
   271 val mk_Abst = fold_rev (fn (s, T:typ) => fn prf => Abst (s, NONE, prf));
   272 fun mk_AbsP (i, prf) = funpow i (fn prf => AbsP ("H", NONE, prf)) prf;
   273 
   274 fun map_proof_terms_option f g =
   275   let
   276     val term = Same.function f;
   277     val typ = Same.function g;
   278     val typs = Same.map typ;
   279 
   280     fun proof (Abst (s, T, prf)) =
   281           (Abst (s, Same.map_option typ T, Same.commit proof prf)
   282             handle Same.SAME => Abst (s, T, proof prf))
   283       | proof (AbsP (s, t, prf)) =
   284           (AbsP (s, Same.map_option term t, Same.commit proof prf)
   285             handle Same.SAME => AbsP (s, t, proof prf))
   286       | proof (prf % t) =
   287           (proof prf % Same.commit (Same.map_option term) t
   288             handle Same.SAME => prf % Same.map_option term t)
   289       | proof (prf1 %% prf2) =
   290           (proof prf1 %% Same.commit proof prf2
   291             handle Same.SAME => prf1 %% proof prf2)
   292       | proof (PAxm (a, prop, SOME Ts)) = PAxm (a, prop, SOME (typs Ts))
   293       | proof (OfClass (T, c)) = OfClass (typ T, c)
   294       | proof (Oracle (a, prop, SOME Ts)) = Oracle (a, prop, SOME (typs Ts))
   295       | proof (Promise (i, prop, Ts)) = Promise (i, prop, typs Ts)
   296       | proof (PThm (i, ((a, prop, SOME Ts), body))) =
   297           PThm (i, ((a, prop, SOME (typs Ts)), body))
   298       | proof _ = raise Same.SAME;
   299   in Same.commit proof end;
   300 
   301 fun same eq f x =
   302   let val x' = f x
   303   in if eq (x, x') then raise Same.SAME else x' end;
   304 
   305 fun map_proof_terms f g =
   306   map_proof_terms_option
   307    (fn t => SOME (same (op =) f t) handle Same.SAME => NONE)
   308    (fn T => SOME (same (op =) g T) handle Same.SAME => NONE);
   309 
   310 fun fold_proof_terms f g (Abst (_, SOME T, prf)) = g T #> fold_proof_terms f g prf
   311   | fold_proof_terms f g (Abst (_, NONE, prf)) = fold_proof_terms f g prf
   312   | fold_proof_terms f g (AbsP (_, SOME t, prf)) = f t #> fold_proof_terms f g prf
   313   | fold_proof_terms f g (AbsP (_, NONE, prf)) = fold_proof_terms f g prf
   314   | fold_proof_terms f g (prf % SOME t) = fold_proof_terms f g prf #> f t
   315   | fold_proof_terms f g (prf % NONE) = fold_proof_terms f g prf
   316   | fold_proof_terms f g (prf1 %% prf2) =
   317       fold_proof_terms f g prf1 #> fold_proof_terms f g prf2
   318   | fold_proof_terms _ g (PAxm (_, _, SOME Ts)) = fold g Ts
   319   | fold_proof_terms _ g (OfClass (T, _)) = g T
   320   | fold_proof_terms _ g (Oracle (_, _, SOME Ts)) = fold g Ts
   321   | fold_proof_terms _ g (Promise (_, _, Ts)) = fold g Ts
   322   | fold_proof_terms _ g (PThm (_, ((_, _, SOME Ts), _))) = fold g Ts
   323   | fold_proof_terms _ _ _ = I;
   324 
   325 fun maxidx_proof prf = fold_proof_terms Term.maxidx_term Term.maxidx_typ prf;
   326 
   327 fun size_of_proof (Abst (_, _, prf)) = 1 + size_of_proof prf
   328   | size_of_proof (AbsP (_, t, prf)) = 1 + size_of_proof prf
   329   | size_of_proof (prf % _) = 1 + size_of_proof prf
   330   | size_of_proof (prf1 %% prf2) = size_of_proof prf1 + size_of_proof prf2
   331   | size_of_proof _ = 1;
   332 
   333 fun change_type opTs (PAxm (name, prop, _)) = PAxm (name, prop, opTs)
   334   | change_type (SOME [T]) (OfClass (_, c)) = OfClass (T, c)
   335   | change_type opTs (Oracle (name, prop, _)) = Oracle (name, prop, opTs)
   336   | change_type opTs (Promise _) = error "change_type: unexpected promise"
   337   | change_type opTs (PThm (i, ((name, prop, _), body))) =
   338       PThm (i, ((name, prop, opTs), body))
   339   | change_type _ prf = prf;
   340 
   341 
   342 (***** utilities *****)
   343 
   344 fun strip_abs (_::Ts) (Abs (_, _, t)) = strip_abs Ts t
   345   | strip_abs _ t = t;
   346 
   347 fun mk_abs Ts t = Library.foldl (fn (t', T) => Abs ("", T, t')) (t, Ts);
   348 
   349 
   350 (*Abstraction of a proof term over its occurrences of v,
   351     which must contain no loose bound variables.
   352   The resulting proof term is ready to become the body of an Abst.*)
   353 
   354 fun prf_abstract_over v =
   355   let
   356     fun abst' lev u = if v aconv u then Bound lev else
   357       (case u of
   358          Abs (a, T, t) => Abs (a, T, abst' (lev + 1) t)
   359        | f $ t => (abst' lev f $ absth' lev t handle Same.SAME => f $ abst' lev t)
   360        | _ => raise Same.SAME)
   361     and absth' lev t = (abst' lev t handle Same.SAME => t);
   362 
   363     fun abst lev (AbsP (a, t, prf)) =
   364           (AbsP (a, Same.map_option (abst' lev) t, absth lev prf)
   365            handle Same.SAME => AbsP (a, t, abst lev prf))
   366       | abst lev (Abst (a, T, prf)) = Abst (a, T, abst (lev + 1) prf)
   367       | abst lev (prf1 %% prf2) = (abst lev prf1 %% absth lev prf2
   368           handle Same.SAME => prf1 %% abst lev prf2)
   369       | abst lev (prf % t) = (abst lev prf % Option.map (absth' lev) t
   370           handle Same.SAME => prf % Same.map_option (abst' lev) t)
   371       | abst _ _ = raise Same.SAME
   372     and absth lev prf = (abst lev prf handle Same.SAME => prf);
   373 
   374   in absth 0 end;
   375 
   376 
   377 (*increments a proof term's non-local bound variables
   378   required when moving a proof term within abstractions
   379      inc is  increment for bound variables
   380      lev is  level at which a bound variable is considered 'loose'*)
   381 
   382 fun incr_bv' inct tlev t = incr_bv (inct, tlev, t);
   383 
   384 fun prf_incr_bv' incP inct Plev tlev (PBound i) =
   385       if i >= Plev then PBound (i+incP) else raise Same.SAME
   386   | prf_incr_bv' incP inct Plev tlev (AbsP (a, t, body)) =
   387       (AbsP (a, Same.map_option (same (op =) (incr_bv' inct tlev)) t,
   388          prf_incr_bv incP inct (Plev+1) tlev body) handle Same.SAME =>
   389            AbsP (a, t, prf_incr_bv' incP inct (Plev+1) tlev body))
   390   | prf_incr_bv' incP inct Plev tlev (Abst (a, T, body)) =
   391       Abst (a, T, prf_incr_bv' incP inct Plev (tlev+1) body)
   392   | prf_incr_bv' incP inct Plev tlev (prf %% prf') =
   393       (prf_incr_bv' incP inct Plev tlev prf %% prf_incr_bv incP inct Plev tlev prf'
   394        handle Same.SAME => prf %% prf_incr_bv' incP inct Plev tlev prf')
   395   | prf_incr_bv' incP inct Plev tlev (prf % t) =
   396       (prf_incr_bv' incP inct Plev tlev prf % Option.map (incr_bv' inct tlev) t
   397        handle Same.SAME => prf % Same.map_option (same (op =) (incr_bv' inct tlev)) t)
   398   | prf_incr_bv' _ _ _ _ _ = raise Same.SAME
   399 and prf_incr_bv incP inct Plev tlev prf =
   400       (prf_incr_bv' incP inct Plev tlev prf handle Same.SAME => prf);
   401 
   402 fun incr_pboundvars  0 0 prf = prf
   403   | incr_pboundvars incP inct prf = prf_incr_bv incP inct 0 0 prf;
   404 
   405 
   406 fun prf_loose_bvar1 (prf1 %% prf2) k = prf_loose_bvar1 prf1 k orelse prf_loose_bvar1 prf2 k
   407   | prf_loose_bvar1 (prf % SOME t) k = prf_loose_bvar1 prf k orelse loose_bvar1 (t, k)
   408   | prf_loose_bvar1 (_ % NONE) _ = true
   409   | prf_loose_bvar1 (AbsP (_, SOME t, prf)) k = loose_bvar1 (t, k) orelse prf_loose_bvar1 prf k
   410   | prf_loose_bvar1 (AbsP (_, NONE, _)) k = true
   411   | prf_loose_bvar1 (Abst (_, _, prf)) k = prf_loose_bvar1 prf (k+1)
   412   | prf_loose_bvar1 _ _ = false;
   413 
   414 fun prf_loose_Pbvar1 (PBound i) k = i = k
   415   | prf_loose_Pbvar1 (prf1 %% prf2) k = prf_loose_Pbvar1 prf1 k orelse prf_loose_Pbvar1 prf2 k
   416   | prf_loose_Pbvar1 (prf % _) k = prf_loose_Pbvar1 prf k
   417   | prf_loose_Pbvar1 (AbsP (_, _, prf)) k = prf_loose_Pbvar1 prf (k+1)
   418   | prf_loose_Pbvar1 (Abst (_, _, prf)) k = prf_loose_Pbvar1 prf k
   419   | prf_loose_Pbvar1 _ _ = false;
   420 
   421 fun prf_add_loose_bnos plev tlev (PBound i) (is, js) =
   422       if i < plev then (is, js) else (insert (op =) (i-plev) is, js)
   423   | prf_add_loose_bnos plev tlev (prf1 %% prf2) p =
   424       prf_add_loose_bnos plev tlev prf2
   425         (prf_add_loose_bnos plev tlev prf1 p)
   426   | prf_add_loose_bnos plev tlev (prf % opt) (is, js) =
   427       prf_add_loose_bnos plev tlev prf (case opt of
   428           NONE => (is, insert (op =) ~1 js)
   429         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   430   | prf_add_loose_bnos plev tlev (AbsP (_, opt, prf)) (is, js) =
   431       prf_add_loose_bnos (plev+1) tlev prf (case opt of
   432           NONE => (is, insert (op =) ~1 js)
   433         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   434   | prf_add_loose_bnos plev tlev (Abst (_, _, prf)) p =
   435       prf_add_loose_bnos plev (tlev+1) prf p
   436   | prf_add_loose_bnos _ _ _ _ = ([], []);
   437 
   438 
   439 (**** substitutions ****)
   440 
   441 fun del_conflicting_tvars envT T = Term_Subst.instantiateT
   442   (map_filter (fn ixnS as (_, S) =>
   443      (Type.lookup envT ixnS; NONE) handle TYPE _ =>
   444         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.typ_tvars T)) T;
   445 
   446 fun del_conflicting_vars env t = Term_Subst.instantiate
   447   (map_filter (fn ixnS as (_, S) =>
   448      (Type.lookup (Envir.type_env env) ixnS; NONE) handle TYPE _ =>
   449         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.term_tvars t),
   450    map_filter (fn Var (ixnT as (_, T)) =>
   451      (Envir.lookup (env, ixnT); NONE) handle TYPE _ =>
   452         SOME (ixnT, Free ("dummy", T))) (OldTerm.term_vars t)) t;
   453 
   454 fun norm_proof env =
   455   let
   456     val envT = Envir.type_env env;
   457     fun msg s = warning ("type conflict in norm_proof:\n" ^ s);
   458     fun htype f t = f env t handle TYPE (s, _, _) =>
   459       (msg s; f env (del_conflicting_vars env t));
   460     fun htypeT f T = f envT T handle TYPE (s, _, _) =>
   461       (msg s; f envT (del_conflicting_tvars envT T));
   462     fun htypeTs f Ts = f envT Ts handle TYPE (s, _, _) =>
   463       (msg s; f envT (map (del_conflicting_tvars envT) Ts));
   464 
   465     fun norm (Abst (s, T, prf)) =
   466           (Abst (s, Same.map_option (htypeT Envir.norm_type_same) T, Same.commit norm prf)
   467             handle Same.SAME => Abst (s, T, norm prf))
   468       | norm (AbsP (s, t, prf)) =
   469           (AbsP (s, Same.map_option (htype Envir.norm_term_same) t, Same.commit norm prf)
   470             handle Same.SAME => AbsP (s, t, norm prf))
   471       | norm (prf % t) =
   472           (norm prf % Option.map (htype Envir.norm_term) t
   473             handle Same.SAME => prf % Same.map_option (htype Envir.norm_term_same) t)
   474       | norm (prf1 %% prf2) =
   475           (norm prf1 %% Same.commit norm prf2
   476             handle Same.SAME => prf1 %% norm prf2)
   477       | norm (PAxm (s, prop, Ts)) =
   478           PAxm (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   479       | norm (OfClass (T, c)) =
   480           OfClass (htypeT Envir.norm_type_same T, c)
   481       | norm (Oracle (s, prop, Ts)) =
   482           Oracle (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   483       | norm (Promise (i, prop, Ts)) =
   484           Promise (i, prop, htypeTs Envir.norm_types_same Ts)
   485       | norm (PThm (i, ((s, t, Ts), body))) =
   486           PThm (i, ((s, t, Same.map_option (htypeTs Envir.norm_types_same) Ts), body))
   487       | norm _ = raise Same.SAME;
   488   in Same.commit norm end;
   489 
   490 
   491 (***** Remove some types in proof term (to save space) *****)
   492 
   493 fun remove_types (Abs (s, _, t)) = Abs (s, dummyT, remove_types t)
   494   | remove_types (t $ u) = remove_types t $ remove_types u
   495   | remove_types (Const (s, _)) = Const (s, dummyT)
   496   | remove_types t = t;
   497 
   498 fun remove_types_env (Envir.Envir {maxidx, tenv, tyenv}) =
   499   Envir.Envir {maxidx = maxidx, tenv = Vartab.map (apsnd remove_types) tenv, tyenv = tyenv};
   500 
   501 fun norm_proof' env prf = norm_proof (remove_types_env env) prf;
   502 
   503 
   504 (**** substitution of bound variables ****)
   505 
   506 fun prf_subst_bounds args prf =
   507   let
   508     val n = length args;
   509     fun subst' lev (Bound i) =
   510          (if i<lev then raise Same.SAME    (*var is locally bound*)
   511           else  incr_boundvars lev (nth args (i-lev))
   512                   handle Subscript => Bound (i-n))  (*loose: change it*)
   513       | subst' lev (Abs (a, T, body)) = Abs (a, T,  subst' (lev+1) body)
   514       | subst' lev (f $ t) = (subst' lev f $ substh' lev t
   515           handle Same.SAME => f $ subst' lev t)
   516       | subst' _ _ = raise Same.SAME
   517     and substh' lev t = (subst' lev t handle Same.SAME => t);
   518 
   519     fun subst lev (AbsP (a, t, body)) =
   520         (AbsP (a, Same.map_option (subst' lev) t, substh lev body)
   521           handle Same.SAME => AbsP (a, t, subst lev body))
   522       | subst lev (Abst (a, T, body)) = Abst (a, T, subst (lev+1) body)
   523       | subst lev (prf %% prf') = (subst lev prf %% substh lev prf'
   524           handle Same.SAME => prf %% subst lev prf')
   525       | subst lev (prf % t) = (subst lev prf % Option.map (substh' lev) t
   526           handle Same.SAME => prf % Same.map_option (subst' lev) t)
   527       | subst _ _ = raise Same.SAME
   528     and substh lev prf = (subst lev prf handle Same.SAME => prf);
   529   in case args of [] => prf | _ => substh 0 prf end;
   530 
   531 fun prf_subst_pbounds args prf =
   532   let
   533     val n = length args;
   534     fun subst (PBound i) Plev tlev =
   535          (if i < Plev then raise Same.SAME    (*var is locally bound*)
   536           else incr_pboundvars Plev tlev (nth args (i-Plev))
   537                  handle Subscript => PBound (i-n)  (*loose: change it*))
   538       | subst (AbsP (a, t, body)) Plev tlev = AbsP (a, t, subst body (Plev+1) tlev)
   539       | subst (Abst (a, T, body)) Plev tlev = Abst (a, T, subst body Plev (tlev+1))
   540       | subst (prf %% prf') Plev tlev = (subst prf Plev tlev %% substh prf' Plev tlev
   541           handle Same.SAME => prf %% subst prf' Plev tlev)
   542       | subst (prf % t) Plev tlev = subst prf Plev tlev % t
   543       | subst  prf _ _ = raise Same.SAME
   544     and substh prf Plev tlev = (subst prf Plev tlev handle Same.SAME => prf)
   545   in case args of [] => prf | _ => substh prf 0 0 end;
   546 
   547 
   548 (**** Freezing and thawing of variables in proof terms ****)
   549 
   550 fun frzT names =
   551   map_type_tvar (fn (ixn, xs) => TFree ((the o AList.lookup (op =) names) ixn, xs));
   552 
   553 fun thawT names =
   554   map_type_tfree (fn (s, xs) => case AList.lookup (op =) names s of
   555       NONE => TFree (s, xs)
   556     | SOME ixn => TVar (ixn, xs));
   557 
   558 fun freeze names names' (t $ u) =
   559       freeze names names' t $ freeze names names' u
   560   | freeze names names' (Abs (s, T, t)) =
   561       Abs (s, frzT names' T, freeze names names' t)
   562   | freeze names names' (Const (s, T)) = Const (s, frzT names' T)
   563   | freeze names names' (Free (s, T)) = Free (s, frzT names' T)
   564   | freeze names names' (Var (ixn, T)) =
   565       Free ((the o AList.lookup (op =) names) ixn, frzT names' T)
   566   | freeze names names' t = t;
   567 
   568 fun thaw names names' (t $ u) =
   569       thaw names names' t $ thaw names names' u
   570   | thaw names names' (Abs (s, T, t)) =
   571       Abs (s, thawT names' T, thaw names names' t)
   572   | thaw names names' (Const (s, T)) = Const (s, thawT names' T)
   573   | thaw names names' (Free (s, T)) =
   574       let val T' = thawT names' T
   575       in case AList.lookup (op =) names s of
   576           NONE => Free (s, T')
   577         | SOME ixn => Var (ixn, T')
   578       end
   579   | thaw names names' (Var (ixn, T)) = Var (ixn, thawT names' T)
   580   | thaw names names' t = t;
   581 
   582 fun freeze_thaw_prf prf =
   583   let
   584     val (fs, Tfs, vs, Tvs) = fold_proof_terms
   585       (fn t => fn (fs, Tfs, vs, Tvs) =>
   586          (Term.add_free_names t fs, Term.add_tfree_names t Tfs,
   587           Term.add_var_names t vs, Term.add_tvar_names t Tvs))
   588       (fn T => fn (fs, Tfs, vs, Tvs) =>
   589          (fs, Term.add_tfree_namesT T Tfs,
   590           vs, Term.add_tvar_namesT T Tvs))
   591       prf ([], [], [], []);
   592     val names = vs ~~ Name.variant_list fs (map fst vs);
   593     val names' = Tvs ~~ Name.variant_list Tfs (map fst Tvs);
   594     val rnames = map swap names;
   595     val rnames' = map swap names';
   596   in
   597     (map_proof_terms (freeze names names') (frzT names') prf,
   598      map_proof_terms (thaw rnames rnames') (thawT rnames'))
   599   end;
   600 
   601 
   602 (***** implication introduction *****)
   603 
   604 fun implies_intr_proof h prf =
   605   let
   606     fun abshyp i (Hyp t) = if h aconv t then PBound i else raise Same.SAME
   607       | abshyp i (Abst (s, T, prf)) = Abst (s, T, abshyp i prf)
   608       | abshyp i (AbsP (s, t, prf)) = AbsP (s, t, abshyp (i + 1) prf)
   609       | abshyp i (prf % t) = abshyp i prf % t
   610       | abshyp i (prf1 %% prf2) =
   611           (abshyp i prf1 %% abshyph i prf2
   612             handle Same.SAME => prf1 %% abshyp i prf2)
   613       | abshyp _ _ = raise Same.SAME
   614     and abshyph i prf = (abshyp i prf handle Same.SAME => prf);
   615   in
   616     AbsP ("H", NONE (*h*), abshyph 0 prf)
   617   end;
   618 
   619 
   620 (***** forall introduction *****)
   621 
   622 fun forall_intr_proof x a prf = Abst (a, NONE, prf_abstract_over x prf);
   623 
   624 
   625 (***** varify *****)
   626 
   627 fun varify_proof t fixed prf =
   628   let
   629     val fs = Term.fold_types (Term.fold_atyps
   630       (fn TFree v => if member (op =) fixed v then I else insert (op =) v | _ => I)) t [];
   631     val used = Name.context
   632       |> fold_types (fold_atyps (fn TVar ((a, _), _) => Name.declare a | _ => I)) t;
   633     val fmap = fs ~~ #1 (Name.variants (map fst fs) used);
   634     fun thaw (f as (a, S)) =
   635       (case AList.lookup (op =) fmap f of
   636         NONE => TFree f
   637       | SOME b => TVar ((b, 0), S));
   638   in map_proof_terms (map_types (map_type_tfree thaw)) (map_type_tfree thaw) prf end;
   639 
   640 
   641 local
   642 
   643 fun new_name (ix, (pairs,used)) =
   644   let val v = Name.variant used (string_of_indexname ix)
   645   in  ((ix, v) :: pairs, v :: used)  end;
   646 
   647 fun freeze_one alist (ix, sort) = (case AList.lookup (op =) alist ix of
   648     NONE => TVar (ix, sort)
   649   | SOME name => TFree (name, sort));
   650 
   651 in
   652 
   653 fun freezeT t prf =
   654   let
   655     val used = OldTerm.it_term_types OldTerm.add_typ_tfree_names (t, [])
   656     and tvars = map #1 (OldTerm.it_term_types OldTerm.add_typ_tvars (t, []));
   657     val (alist, _) = List.foldr new_name ([], used) tvars;
   658   in
   659     (case alist of
   660       [] => prf (*nothing to do!*)
   661     | _ =>
   662       let val frzT = map_type_tvar (freeze_one alist)
   663       in map_proof_terms (map_types frzT) frzT prf end)
   664   end;
   665 
   666 end;
   667 
   668 
   669 (***** rotate assumptions *****)
   670 
   671 fun rotate_proof Bs Bi m prf =
   672   let
   673     val params = Term.strip_all_vars Bi;
   674     val asms = Logic.strip_imp_prems (Term.strip_all_body Bi);
   675     val i = length asms;
   676     val j = length Bs;
   677   in
   678     mk_AbsP (j+1, proof_combP (prf, map PBound
   679       (j downto 1) @ [mk_Abst params (mk_AbsP (i,
   680         proof_combP (proof_combt (PBound i, map Bound ((length params - 1) downto 0)),
   681           map PBound (((i-m-1) downto 0) @ ((i-1) downto (i-m))))))]))
   682   end;
   683 
   684 
   685 (***** permute premises *****)
   686 
   687 fun permute_prems_prf prems j k prf =
   688   let val n = length prems
   689   in mk_AbsP (n, proof_combP (prf,
   690     map PBound ((n-1 downto n-j) @ (k-1 downto 0) @ (n-j-1 downto k))))
   691   end;
   692 
   693 
   694 (***** generalization *****)
   695 
   696 fun generalize (tfrees, frees) idx =
   697   map_proof_terms_option
   698     (Term_Subst.generalize_option (tfrees, frees) idx)
   699     (Term_Subst.generalizeT_option tfrees idx);
   700 
   701 
   702 (***** instantiation *****)
   703 
   704 fun instantiate (instT, inst) =
   705   map_proof_terms_option
   706     (Term_Subst.instantiate_option (instT, map (apsnd remove_types) inst))
   707     (Term_Subst.instantiateT_option instT);
   708 
   709 
   710 (***** lifting *****)
   711 
   712 fun lift_proof Bi inc prop prf =
   713   let
   714     fun lift'' Us Ts t =
   715       strip_abs Ts (Logic.incr_indexes (Us, inc) (mk_abs Ts t));
   716 
   717     fun lift' Us Ts (Abst (s, T, prf)) =
   718           (Abst (s, Same.map_option (Logic.incr_tvar_same inc) T, lifth' Us (dummyT::Ts) prf)
   719            handle Same.SAME => Abst (s, T, lift' Us (dummyT::Ts) prf))
   720       | lift' Us Ts (AbsP (s, t, prf)) =
   721           (AbsP (s, Same.map_option (same (op =) (lift'' Us Ts)) t, lifth' Us Ts prf)
   722            handle Same.SAME => AbsP (s, t, lift' Us Ts prf))
   723       | lift' Us Ts (prf % t) = (lift' Us Ts prf % Option.map (lift'' Us Ts) t
   724           handle Same.SAME => prf % Same.map_option (same (op =) (lift'' Us Ts)) t)
   725       | lift' Us Ts (prf1 %% prf2) = (lift' Us Ts prf1 %% lifth' Us Ts prf2
   726           handle Same.SAME => prf1 %% lift' Us Ts prf2)
   727       | lift' _ _ (PAxm (s, prop, Ts)) =
   728           PAxm (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   729       | lift' _ _ (OfClass (T, c)) =
   730           OfClass (Logic.incr_tvar_same inc T, c)
   731       | lift' _ _ (Oracle (s, prop, Ts)) =
   732           Oracle (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   733       | lift' _ _ (Promise (i, prop, Ts)) =
   734           Promise (i, prop, Same.map (Logic.incr_tvar_same inc) Ts)
   735       | lift' _ _ (PThm (i, ((s, prop, Ts), body))) =
   736           PThm (i, ((s, prop, (Same.map_option o Same.map) (Logic.incr_tvar inc) Ts), body))
   737       | lift' _ _ _ = raise Same.SAME
   738     and lifth' Us Ts prf = (lift' Us Ts prf handle Same.SAME => prf);
   739 
   740     val ps = map (Logic.lift_all inc Bi) (Logic.strip_imp_prems prop);
   741     val k = length ps;
   742 
   743     fun mk_app b (i, j, prf) =
   744           if b then (i-1, j, prf %% PBound i) else (i, j-1, prf %> Bound j);
   745 
   746     fun lift Us bs i j (Const ("==>", _) $ A $ B) =
   747             AbsP ("H", NONE (*A*), lift Us (true::bs) (i+1) j B)
   748       | lift Us bs i j (Const ("all", _) $ Abs (a, T, t)) =
   749             Abst (a, NONE (*T*), lift (T::Us) (false::bs) i (j+1) t)
   750       | lift Us bs i j _ = proof_combP (lifth' (rev Us) [] prf,
   751             map (fn k => (#3 (fold_rev mk_app bs (i-1, j-1, PBound k))))
   752               (i + k - 1 downto i));
   753   in
   754     mk_AbsP (k, lift [] [] 0 0 Bi)
   755   end;
   756 
   757 fun incr_indexes i =
   758   map_proof_terms_option
   759     (Same.capture (Logic.incr_indexes_same ([], i)))
   760     (Same.capture (Logic.incr_tvar_same i));
   761 
   762 
   763 (***** proof by assumption *****)
   764 
   765 fun mk_asm_prf t i m =
   766   let
   767     fun imp_prf _ i 0 = PBound i
   768       | imp_prf (Const ("==>", _) $ A $ B) i m = AbsP ("H", NONE (*A*), imp_prf B (i+1) (m-1))
   769       | imp_prf _ i _ = PBound i;
   770     fun all_prf (Const ("all", _) $ Abs (a, T, t)) = Abst (a, NONE (*T*), all_prf t)
   771       | all_prf t = imp_prf t (~i) m
   772   in all_prf t end;
   773 
   774 fun assumption_proof Bs Bi n prf =
   775   mk_AbsP (length Bs, proof_combP (prf,
   776     map PBound (length Bs - 1 downto 0) @ [mk_asm_prf Bi n ~1]));
   777 
   778 
   779 (***** Composition of object rule with proof state *****)
   780 
   781 fun flatten_params_proof i j n (Const ("==>", _) $ A $ B, k) =
   782       AbsP ("H", NONE (*A*), flatten_params_proof (i+1) j n (B, k))
   783   | flatten_params_proof i j n (Const ("all", _) $ Abs (a, T, t), k) =
   784       Abst (a, NONE (*T*), flatten_params_proof i (j+1) n (t, k))
   785   | flatten_params_proof i j n (_, k) = proof_combP (proof_combt (PBound (k+i),
   786       map Bound (j-1 downto 0)), map PBound (remove (op =) (i-n) (i-1 downto 0)));
   787 
   788 fun bicompose_proof flatten Bs oldAs newAs A n m rprf sprf =
   789   let
   790     val la = length newAs;
   791     val lb = length Bs;
   792   in
   793     mk_AbsP (lb+la, proof_combP (sprf,
   794       map PBound (lb + la - 1 downto la)) %%
   795         proof_combP (rprf, (if n>0 then [mk_asm_prf (the A) n m] else []) @
   796           map (if flatten then flatten_params_proof 0 0 n else PBound o snd)
   797             (oldAs ~~ (la - 1 downto 0))))
   798   end;
   799 
   800 
   801 (***** axioms for equality *****)
   802 
   803 val aT = TFree ("'a", []);
   804 val bT = TFree ("'b", []);
   805 val x = Free ("x", aT);
   806 val y = Free ("y", aT);
   807 val z = Free ("z", aT);
   808 val A = Free ("A", propT);
   809 val B = Free ("B", propT);
   810 val f = Free ("f", aT --> bT);
   811 val g = Free ("g", aT --> bT);
   812 
   813 local open Logic in
   814 
   815 val equality_axms =
   816   [("reflexive", mk_equals (x, x)),
   817    ("symmetric", mk_implies (mk_equals (x, y), mk_equals (y, x))),
   818    ("transitive", list_implies ([mk_equals (x, y), mk_equals (y, z)], mk_equals (x, z))),
   819    ("equal_intr", list_implies ([mk_implies (A, B), mk_implies (B, A)], mk_equals (A, B))),
   820    ("equal_elim", list_implies ([mk_equals (A, B), A], B)),
   821    ("abstract_rule", mk_implies
   822       (all x (mk_equals (f $ x, g $ x)), mk_equals (lambda x (f $ x), lambda x (g $ x)))),
   823    ("combination", list_implies
   824       ([mk_equals (f, g), mk_equals (x, y)], mk_equals (f $ x, g $ y)))];
   825 
   826 val [reflexive_axm, symmetric_axm, transitive_axm, equal_intr_axm,
   827   equal_elim_axm, abstract_rule_axm, combination_axm] =
   828     map (fn (s, t) => PAxm ("Pure." ^ s, varify t, NONE)) equality_axms;
   829 
   830 end;
   831 
   832 val reflexive = reflexive_axm % NONE;
   833 
   834 fun symmetric (prf as PAxm ("Pure.reflexive", _, _) % _) = prf
   835   | symmetric prf = symmetric_axm % NONE % NONE %% prf;
   836 
   837 fun transitive _ _ (PAxm ("Pure.reflexive", _, _) % _) prf2 = prf2
   838   | transitive _ _ prf1 (PAxm ("Pure.reflexive", _, _) % _) = prf1
   839   | transitive u (Type ("prop", [])) prf1 prf2 =
   840       transitive_axm % NONE % SOME (remove_types u) % NONE %% prf1 %% prf2
   841   | transitive u T prf1 prf2 =
   842       transitive_axm % NONE % NONE % NONE %% prf1 %% prf2;
   843 
   844 fun abstract_rule x a prf =
   845   abstract_rule_axm % NONE % NONE %% forall_intr_proof x a prf;
   846 
   847 fun check_comb (PAxm ("Pure.combination", _, _) % f % g % _ % _ %% prf %% _) =
   848       is_some f orelse check_comb prf
   849   | check_comb (PAxm ("Pure.transitive", _, _) % _ % _ % _ %% prf1 %% prf2) =
   850       check_comb prf1 andalso check_comb prf2
   851   | check_comb (PAxm ("Pure.symmetric", _, _) % _ % _ %% prf) = check_comb prf
   852   | check_comb _ = false;
   853 
   854 fun combination f g t u (Type (_, [T, U])) prf1 prf2 =
   855   let
   856     val f = Envir.beta_norm f;
   857     val g = Envir.beta_norm g;
   858     val prf =  if check_comb prf1 then
   859         combination_axm % NONE % NONE
   860       else (case prf1 of
   861           PAxm ("Pure.reflexive", _, _) % _ =>
   862             combination_axm %> remove_types f % NONE
   863         | _ => combination_axm %> remove_types f %> remove_types g)
   864   in
   865     (case T of
   866        Type ("fun", _) => prf %
   867          (case head_of f of
   868             Abs _ => SOME (remove_types t)
   869           | Var _ => SOME (remove_types t)
   870           | _ => NONE) %
   871          (case head_of g of
   872             Abs _ => SOME (remove_types u)
   873           | Var _ => SOME (remove_types u)
   874           | _ => NONE) %% prf1 %% prf2
   875      | _ => prf % NONE % NONE %% prf1 %% prf2)
   876   end;
   877 
   878 fun equal_intr A B prf1 prf2 =
   879   equal_intr_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   880 
   881 fun equal_elim A B prf1 prf2 =
   882   equal_elim_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   883 
   884 
   885 (***** axioms and theorems *****)
   886 
   887 val proofs = Unsynchronized.ref 2;
   888 
   889 fun vars_of t = map Var (rev (Term.add_vars t []));
   890 fun frees_of t = map Free (rev (Term.add_frees t []));
   891 
   892 fun test_args _ [] = true
   893   | test_args is (Bound i :: ts) =
   894       not (member (op =) is i) andalso test_args (i :: is) ts
   895   | test_args _ _ = false;
   896 
   897 fun is_fun (Type ("fun", _)) = true
   898   | is_fun (TVar _) = true
   899   | is_fun _ = false;
   900 
   901 fun add_funvars Ts (vs, t) =
   902   if is_fun (fastype_of1 (Ts, t)) then
   903     gen_union (op =) (vs, map_filter (fn Var (ixn, T) =>
   904       if is_fun T then SOME ixn else NONE | _ => NONE) (vars_of t))
   905   else vs;
   906 
   907 fun add_npvars q p Ts (vs, Const ("==>", _) $ t $ u) =
   908       add_npvars q p Ts (add_npvars q (not p) Ts (vs, t), u)
   909   | add_npvars q p Ts (vs, Const ("all", Type (_, [Type (_, [T, _]), _])) $ t) =
   910       add_npvars q p Ts (vs, if p andalso q then betapply (t, Var (("",0), T)) else t)
   911   | add_npvars q p Ts (vs, Abs (_, T, t)) = add_npvars q p (T::Ts) (vs, t)
   912   | add_npvars _ _ Ts (vs, t) = add_npvars' Ts (vs, t)
   913 and add_npvars' Ts (vs, t) = (case strip_comb t of
   914     (Var (ixn, _), ts) => if test_args [] ts then vs
   915       else Library.foldl (add_npvars' Ts)
   916         (AList.update (op =) (ixn,
   917           Library.foldl (add_funvars Ts) ((these ooo AList.lookup) (op =) vs ixn, ts)) vs, ts)
   918   | (Abs (_, T, u), ts) => Library.foldl (add_npvars' (T::Ts)) (vs, u :: ts)
   919   | (_, ts) => Library.foldl (add_npvars' Ts) (vs, ts));
   920 
   921 fun prop_vars (Const ("==>", _) $ P $ Q) = gen_union (op =) (prop_vars P, prop_vars Q)
   922   | prop_vars (Const ("all", _) $ Abs (_, _, t)) = prop_vars t
   923   | prop_vars t = (case strip_comb t of
   924       (Var (ixn, _), _) => [ixn] | _ => []);
   925 
   926 fun is_proj t =
   927   let
   928     fun is_p i t = (case strip_comb t of
   929         (Bound j, []) => false
   930       | (Bound j, ts) => j >= i orelse exists (is_p i) ts
   931       | (Abs (_, _, u), _) => is_p (i+1) u
   932       | (_, ts) => exists (is_p i) ts)
   933   in (case strip_abs_body t of
   934         Bound _ => true
   935       | t' => is_p 0 t')
   936   end;
   937 
   938 fun needed_vars prop =
   939   gen_union (op =) (Library.foldl (gen_union (op =))
   940     ([], map (uncurry (insert (op =))) (add_npvars true true [] ([], prop))),
   941   prop_vars prop);
   942 
   943 fun gen_axm_proof c name prop =
   944   let
   945     val nvs = needed_vars prop;
   946     val args = map (fn (v as Var (ixn, _)) =>
   947         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
   948       map SOME (frees_of prop);
   949   in
   950     proof_combt' (c (name, prop, NONE), args)
   951   end;
   952 
   953 val axm_proof = gen_axm_proof PAxm;
   954 
   955 val dummy = Const (Term.dummy_patternN, dummyT);
   956 
   957 fun oracle_proof name prop =
   958   if ! proofs = 0 then ((name, dummy), Oracle (name, dummy, NONE))
   959   else ((name, prop), gen_axm_proof Oracle name prop);
   960 
   961 val shrink_proof =
   962   let
   963     fun shrink ls lev (prf as Abst (a, T, body)) =
   964           let val (b, is, ch, body') = shrink ls (lev+1) body
   965           in (b, is, ch, if ch then Abst (a, T, body') else prf) end
   966       | shrink ls lev (prf as AbsP (a, t, body)) =
   967           let val (b, is, ch, body') = shrink (lev::ls) lev body
   968           in (b orelse member (op =) is 0, map_filter (fn 0 => NONE | i => SOME (i-1)) is,
   969             ch, if ch then AbsP (a, t, body') else prf)
   970           end
   971       | shrink ls lev prf =
   972           let val (is, ch, _, prf') = shrink' ls lev [] [] prf
   973           in (false, is, ch, prf') end
   974     and shrink' ls lev ts prfs (prf as prf1 %% prf2) =
   975           let
   976             val p as (_, is', ch', prf') = shrink ls lev prf2;
   977             val (is, ch, ts', prf'') = shrink' ls lev ts (p::prfs) prf1
   978           in (gen_union (op =) (is, is'), ch orelse ch', ts',
   979               if ch orelse ch' then prf'' %% prf' else prf)
   980           end
   981       | shrink' ls lev ts prfs (prf as prf1 % t) =
   982           let val (is, ch, (ch', t')::ts', prf') = shrink' ls lev (t::ts) prfs prf1
   983           in (is, ch orelse ch', ts',
   984               if ch orelse ch' then prf' % t' else prf) end
   985       | shrink' ls lev ts prfs (prf as PBound i) =
   986           (if exists (fn SOME (Bound j) => lev-j <= nth ls i | _ => true) ts
   987              orelse has_duplicates (op =)
   988                (Library.foldl (fn (js, SOME (Bound j)) => j :: js | (js, _) => js) ([], ts))
   989              orelse exists #1 prfs then [i] else [], false, map (pair false) ts, prf)
   990       | shrink' ls lev ts prfs (prf as Hyp _) = ([], false, map (pair false) ts, prf)
   991       | shrink' ls lev ts prfs (prf as MinProof) = ([], false, map (pair false) ts, prf)
   992       | shrink' ls lev ts prfs (prf as OfClass _) = ([], false, map (pair false) ts, prf)
   993       | shrink' ls lev ts prfs prf =
   994           let
   995             val prop =
   996               (case prf of
   997                 PAxm (_, prop, _) => prop
   998               | Oracle (_, prop, _) => prop
   999               | Promise (_, prop, _) => prop
  1000               | PThm (_, ((_, prop, _), _)) => prop
  1001               | _ => error "shrink: proof not in normal form");
  1002             val vs = vars_of prop;
  1003             val (ts', ts'') = chop (length vs) ts;
  1004             val insts = Library.take (length ts', map (fst o dest_Var) vs) ~~ ts';
  1005             val nvs = Library.foldl (fn (ixns', (ixn, ixns)) =>
  1006               insert (op =) ixn (case AList.lookup (op =) insts ixn of
  1007                   SOME (SOME t) => if is_proj t then gen_union (op =) (ixns, ixns') else ixns'
  1008                 | _ => gen_union (op =) (ixns, ixns')))
  1009                   (needed prop ts'' prfs, add_npvars false true [] ([], prop));
  1010             val insts' = map
  1011               (fn (ixn, x as SOME _) => if member (op =) nvs ixn then (false, x) else (true, NONE)
  1012                 | (_, x) => (false, x)) insts
  1013           in ([], false, insts' @ map (pair false) ts'', prf) end
  1014     and needed (Const ("==>", _) $ t $ u) ts ((b, _, _, _)::prfs) =
  1015           gen_union (op =) (if b then map (fst o dest_Var) (vars_of t) else [], needed u ts prfs)
  1016       | needed (Var (ixn, _)) (_::_) _ = [ixn]
  1017       | needed _ _ _ = [];
  1018   in shrink end;
  1019 
  1020 
  1021 (**** Simple first order matching functions for terms and proofs ****)
  1022 
  1023 exception PMatch;
  1024 
  1025 (** see pattern.ML **)
  1026 
  1027 fun flt (i: int) = List.filter (fn n => n < i);
  1028 
  1029 fun fomatch Ts tymatch j =
  1030   let
  1031     fun mtch (instsp as (tyinsts, insts)) = fn
  1032         (Var (ixn, T), t)  =>
  1033           if j>0 andalso not (null (flt j (loose_bnos t)))
  1034           then raise PMatch
  1035           else (tymatch (tyinsts, fn () => (T, fastype_of1 (Ts, t))),
  1036             (ixn, t) :: insts)
  1037       | (Free (a, T), Free (b, U)) =>
  1038           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1039       | (Const (a, T), Const (b, U))  =>
  1040           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1041       | (f $ t, g $ u) => mtch (mtch instsp (f, g)) (t, u)
  1042       | (Bound i, Bound j) => if i=j then instsp else raise PMatch
  1043       | _ => raise PMatch
  1044   in mtch end;
  1045 
  1046 fun match_proof Ts tymatch =
  1047   let
  1048     fun optmatch _ inst (NONE, _) = inst
  1049       | optmatch _ _ (SOME _, NONE) = raise PMatch
  1050       | optmatch mtch inst (SOME x, SOME y) = mtch inst (x, y)
  1051 
  1052     fun matcht Ts j (pinst, tinst) (t, u) =
  1053       (pinst, fomatch Ts tymatch j tinst (t, Envir.beta_norm u));
  1054     fun matchT (pinst, (tyinsts, insts)) p =
  1055       (pinst, (tymatch (tyinsts, K p), insts));
  1056     fun matchTs inst (Ts, Us) = Library.foldl (uncurry matchT) (inst, Ts ~~ Us);
  1057 
  1058     fun mtch Ts i j (pinst, tinst) (Hyp (Var (ixn, _)), prf) =
  1059           if i = 0 andalso j = 0 then ((ixn, prf) :: pinst, tinst)
  1060           else (case apfst (flt i) (apsnd (flt j)
  1061                   (prf_add_loose_bnos 0 0 prf ([], []))) of
  1062               ([], []) => ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1063             | ([], _) => if j = 0 then
  1064                    ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1065                  else raise PMatch
  1066             | _ => raise PMatch)
  1067       | mtch Ts i j inst (prf1 % opt1, prf2 % opt2) =
  1068           optmatch (matcht Ts j) (mtch Ts i j inst (prf1, prf2)) (opt1, opt2)
  1069       | mtch Ts i j inst (prf1 %% prf2, prf1' %% prf2') =
  1070           mtch Ts i j (mtch Ts i j inst (prf1, prf1')) (prf2, prf2')
  1071       | mtch Ts i j inst (Abst (_, opT, prf1), Abst (_, opU, prf2)) =
  1072           mtch (the_default dummyT opU :: Ts) i (j+1)
  1073             (optmatch matchT inst (opT, opU)) (prf1, prf2)
  1074       | mtch Ts i j inst (prf1, Abst (_, opU, prf2)) =
  1075           mtch (the_default dummyT opU :: Ts) i (j+1) inst
  1076             (incr_pboundvars 0 1 prf1 %> Bound 0, prf2)
  1077       | mtch Ts i j inst (AbsP (_, opt, prf1), AbsP (_, opu, prf2)) =
  1078           mtch Ts (i+1) j (optmatch (matcht Ts j) inst (opt, opu)) (prf1, prf2)
  1079       | mtch Ts i j inst (prf1, AbsP (_, _, prf2)) =
  1080           mtch Ts (i+1) j inst (incr_pboundvars 1 0 prf1 %% PBound 0, prf2)
  1081       | mtch Ts i j inst (PAxm (s1, _, opTs), PAxm (s2, _, opUs)) =
  1082           if s1 = s2 then optmatch matchTs inst (opTs, opUs)
  1083           else raise PMatch
  1084       | mtch Ts i j inst (OfClass (T1, c1), OfClass (T2, c2)) =
  1085           if c1 = c2 then matchT inst (T1, T2)
  1086           else raise PMatch
  1087       | mtch Ts i j inst (PThm (_, ((name1, prop1, opTs), _)), PThm (_, ((name2, prop2, opUs), _))) =
  1088           if name1 = name2 andalso prop1 = prop2 then
  1089             optmatch matchTs inst (opTs, opUs)
  1090           else raise PMatch
  1091       | mtch _ _ _ inst (PBound i, PBound j) = if i = j then inst else raise PMatch
  1092       | mtch _ _ _ _ _ = raise PMatch
  1093   in mtch Ts 0 0 end;
  1094 
  1095 fun prf_subst (pinst, (tyinsts, insts)) =
  1096   let
  1097     val substT = Envir.subst_type_same tyinsts;
  1098     val substTs = Same.map substT;
  1099 
  1100     fun subst' lev (Var (xi, _)) =
  1101         (case AList.lookup (op =) insts xi of
  1102           NONE => raise Same.SAME
  1103         | SOME u => incr_boundvars lev u)
  1104       | subst' _ (Const (s, T)) = Const (s, substT T)
  1105       | subst' _ (Free (s, T)) = Free (s, substT T)
  1106       | subst' lev (Abs (a, T, body)) =
  1107           (Abs (a, substT T, Same.commit (subst' (lev + 1)) body)
  1108             handle Same.SAME => Abs (a, T, subst' (lev + 1) body))
  1109       | subst' lev (f $ t) =
  1110           (subst' lev f $ Same.commit (subst' lev) t
  1111             handle Same.SAME => f $ subst' lev t)
  1112       | subst' _ _ = raise Same.SAME;
  1113 
  1114     fun subst plev tlev (AbsP (a, t, body)) =
  1115           (AbsP (a, Same.map_option (subst' tlev) t, Same.commit (subst (plev + 1) tlev) body)
  1116             handle Same.SAME => AbsP (a, t, subst (plev + 1) tlev body))
  1117       | subst plev tlev (Abst (a, T, body)) =
  1118           (Abst (a, Same.map_option substT T, Same.commit (subst plev (tlev + 1)) body)
  1119             handle Same.SAME => Abst (a, T, subst plev (tlev + 1) body))
  1120       | subst plev tlev (prf %% prf') =
  1121           (subst plev tlev prf %% Same.commit (subst plev tlev) prf'
  1122             handle Same.SAME => prf %% subst plev tlev prf')
  1123       | subst plev tlev (prf % t) =
  1124           (subst plev tlev prf % Same.commit (Same.map_option (subst' tlev)) t
  1125             handle Same.SAME => prf % Same.map_option (subst' tlev) t)
  1126       | subst plev tlev (Hyp (Var (xi, _))) =
  1127           (case AList.lookup (op =) pinst xi of
  1128             NONE => raise Same.SAME
  1129           | SOME prf' => incr_pboundvars plev tlev prf')
  1130       | subst _ _ (PAxm (id, prop, Ts)) = PAxm (id, prop, Same.map_option substTs Ts)
  1131       | subst _ _ (OfClass (T, c)) = OfClass (substT T, c)
  1132       | subst _ _ (Oracle (id, prop, Ts)) = Oracle (id, prop, Same.map_option substTs Ts)
  1133       | subst _ _ (Promise (i, prop, Ts)) = Promise (i, prop, substTs Ts)
  1134       | subst _ _ (PThm (i, ((id, prop, Ts), body))) =
  1135           PThm (i, ((id, prop, Same.map_option substTs Ts), body))
  1136       | subst _ _ _ = raise Same.SAME;
  1137   in fn t => subst 0 0 t handle Same.SAME => t end;
  1138 
  1139 (*A fast unification filter: true unless the two terms cannot be unified.
  1140   Terms must be NORMAL.  Treats all Vars as distinct. *)
  1141 fun could_unify prf1 prf2 =
  1142   let
  1143     fun matchrands (prf1 %% prf2) (prf1' %% prf2') =
  1144           could_unify prf2 prf2' andalso matchrands prf1 prf1'
  1145       | matchrands (prf % SOME t) (prf' % SOME t') =
  1146           Term.could_unify (t, t') andalso matchrands prf prf'
  1147       | matchrands (prf % _) (prf' % _) = matchrands prf prf'
  1148       | matchrands _ _ = true
  1149 
  1150     fun head_of (prf %% _) = head_of prf
  1151       | head_of (prf % _) = head_of prf
  1152       | head_of prf = prf
  1153 
  1154   in case (head_of prf1, head_of prf2) of
  1155         (_, Hyp (Var _)) => true
  1156       | (Hyp (Var _), _) => true
  1157       | (PAxm (a, _, _), PAxm (b, _, _)) => a = b andalso matchrands prf1 prf2
  1158       | (OfClass (_, c), OfClass (_, d)) => c = d andalso matchrands prf1 prf2
  1159       | (PThm (_, ((a, propa, _), _)), PThm (_, ((b, propb, _), _))) =>
  1160           a = b andalso propa = propb andalso matchrands prf1 prf2
  1161       | (PBound i, PBound j) => i = j andalso matchrands prf1 prf2
  1162       | (AbsP _, _) =>  true   (*because of possible eta equality*)
  1163       | (Abst _, _) =>  true
  1164       | (_, AbsP _) =>  true
  1165       | (_, Abst _) =>  true
  1166       | _ => false
  1167   end;
  1168 
  1169 
  1170 (**** rewriting on proof terms ****)
  1171 
  1172 val skel0 = PBound 0;
  1173 
  1174 fun rewrite_prf tymatch (rules, procs) prf =
  1175   let
  1176     fun rew _ (Abst (_, _, body) % SOME t) = SOME (prf_subst_bounds [t] body, skel0)
  1177       | rew _ (AbsP (_, _, body) %% prf) = SOME (prf_subst_pbounds [prf] body, skel0)
  1178       | rew Ts prf = (case get_first (fn r => r Ts prf) procs of
  1179           SOME prf' => SOME (prf', skel0)
  1180         | NONE => get_first (fn (prf1, prf2) => SOME (prf_subst
  1181             (match_proof Ts tymatch ([], (Vartab.empty, [])) (prf1, prf)) prf2, prf2)
  1182                handle PMatch => NONE) (filter (could_unify prf o fst) rules));
  1183 
  1184     fun rew0 Ts (prf as AbsP (_, _, prf' %% PBound 0)) =
  1185           if prf_loose_Pbvar1 prf' 0 then rew Ts prf
  1186           else
  1187             let val prf'' = incr_pboundvars (~1) 0 prf'
  1188             in SOME (the_default (prf'', skel0) (rew Ts prf'')) end
  1189       | rew0 Ts (prf as Abst (_, _, prf' % SOME (Bound 0))) =
  1190           if prf_loose_bvar1 prf' 0 then rew Ts prf
  1191           else
  1192             let val prf'' = incr_pboundvars 0 (~1) prf'
  1193             in SOME (the_default (prf'', skel0) (rew Ts prf'')) end
  1194       | rew0 Ts prf = rew Ts prf;
  1195 
  1196     fun rew1 _ (Hyp (Var _)) _ = NONE
  1197       | rew1 Ts skel prf = (case rew2 Ts skel prf of
  1198           SOME prf1 => (case rew0 Ts prf1 of
  1199               SOME (prf2, skel') => SOME (the_default prf2 (rew1 Ts skel' prf2))
  1200             | NONE => SOME prf1)
  1201         | NONE => (case rew0 Ts prf of
  1202               SOME (prf1, skel') => SOME (the_default prf1 (rew1 Ts skel' prf1))
  1203             | NONE => NONE))
  1204 
  1205     and rew2 Ts skel (prf % SOME t) = (case prf of
  1206             Abst (_, _, body) =>
  1207               let val prf' = prf_subst_bounds [t] body
  1208               in SOME (the_default prf' (rew2 Ts skel0 prf')) end
  1209           | _ => (case rew1 Ts (case skel of skel' % _ => skel' | _ => skel0) prf of
  1210               SOME prf' => SOME (prf' % SOME t)
  1211             | NONE => NONE))
  1212       | rew2 Ts skel (prf % NONE) = Option.map (fn prf' => prf' % NONE)
  1213           (rew1 Ts (case skel of skel' % _ => skel' | _ => skel0) prf)
  1214       | rew2 Ts skel (prf1 %% prf2) = (case prf1 of
  1215             AbsP (_, _, body) =>
  1216               let val prf' = prf_subst_pbounds [prf2] body
  1217               in SOME (the_default prf' (rew2 Ts skel0 prf')) end
  1218           | _ =>
  1219             let val (skel1, skel2) = (case skel of
  1220                 skel1 %% skel2 => (skel1, skel2)
  1221               | _ => (skel0, skel0))
  1222             in case rew1 Ts skel1 prf1 of
  1223                 SOME prf1' => (case rew1 Ts skel2 prf2 of
  1224                     SOME prf2' => SOME (prf1' %% prf2')
  1225                   | NONE => SOME (prf1' %% prf2))
  1226               | NONE => (case rew1 Ts skel2 prf2 of
  1227                     SOME prf2' => SOME (prf1 %% prf2')
  1228                   | NONE => NONE)
  1229             end)
  1230       | rew2 Ts skel (Abst (s, T, prf)) = (case rew1 (the_default dummyT T :: Ts)
  1231               (case skel of Abst (_, _, skel') => skel' | _ => skel0) prf of
  1232             SOME prf' => SOME (Abst (s, T, prf'))
  1233           | NONE => NONE)
  1234       | rew2 Ts skel (AbsP (s, t, prf)) = (case rew1 Ts
  1235               (case skel of AbsP (_, _, skel') => skel' | _ => skel0) prf of
  1236             SOME prf' => SOME (AbsP (s, t, prf'))
  1237           | NONE => NONE)
  1238       | rew2 _ _ _ = NONE;
  1239 
  1240   in the_default prf (rew1 [] skel0 prf) end;
  1241 
  1242 fun rewrite_proof thy = rewrite_prf (fn (tyenv, f) =>
  1243   Sign.typ_match thy (f ()) tyenv handle Type.TYPE_MATCH => raise PMatch);
  1244 
  1245 fun rewrite_proof_notypes rews = rewrite_prf fst rews;
  1246 
  1247 
  1248 (**** theory data ****)
  1249 
  1250 structure ProofData = TheoryDataFun
  1251 (
  1252   type T = (stamp * (proof * proof)) list * (stamp * (typ list -> proof -> proof option)) list;
  1253 
  1254   val empty = ([], []);
  1255   val copy = I;
  1256   val extend = I;
  1257   fun merge _ ((rules1, procs1), (rules2, procs2)) : T =
  1258     (AList.merge (op =) (K true) (rules1, rules2),
  1259       AList.merge (op =) (K true) (procs1, procs2));
  1260 );
  1261 
  1262 fun get_data thy = let val (rules, procs) = ProofData.get thy in (map #2 rules, map #2 procs) end;
  1263 fun rew_proof thy = rewrite_prf fst (get_data thy);
  1264 
  1265 fun add_prf_rrule r = (ProofData.map o apfst) (cons (stamp (), r));
  1266 fun add_prf_rproc p = (ProofData.map o apsnd) (cons (stamp (), p));
  1267 
  1268 
  1269 (***** promises *****)
  1270 
  1271 fun promise_proof thy i prop =
  1272   let
  1273     val _ = prop |> Term.exists_subterm (fn t =>
  1274       (Term.is_Free t orelse Term.is_Var t) andalso
  1275         error ("promise_proof: illegal variable " ^ Syntax.string_of_term_global thy t));
  1276     val _ = prop |> Term.exists_type (Term.exists_subtype
  1277       (fn TFree (a, _) => error ("promise_proof: illegal type variable " ^ quote a)
  1278         | _ => false));
  1279   in Promise (i, prop, map TVar (Term.add_tvars prop [])) end;
  1280 
  1281 fun fulfill_proof _ [] body0 = body0
  1282   | fulfill_proof thy ps body0 =
  1283       let
  1284         val PBody {oracles = oracles0, thms = thms0, proof = proof0} = body0;
  1285         val oracles = fold (fn (_, PBody {oracles, ...}) => merge_oracles oracles) ps oracles0;
  1286         val thms = fold (fn (_, PBody {thms, ...}) => merge_thms thms) ps thms0;
  1287         val proofs = fold (fn (i, PBody {proof, ...}) => Inttab.update (i, proof)) ps Inttab.empty;
  1288 
  1289         fun fill (Promise (i, prop, Ts)) =
  1290             (case Inttab.lookup proofs i of
  1291               NONE => NONE
  1292             | SOME prf => SOME (instantiate (Term.add_tvars prop [] ~~ Ts, []) prf))
  1293           | fill _ = NONE;
  1294         val (rules, procs) = get_data thy;
  1295         val proof = rewrite_prf fst (rules, K fill :: procs) proof0;
  1296       in PBody {oracles = oracles, thms = thms, proof = proof} end;
  1297 
  1298 fun fulfill_proof_future _ [] body = Future.value body
  1299   | fulfill_proof_future thy promises body =
  1300       Future.fork_deps (map snd promises) (fn () =>
  1301         fulfill_proof thy (map (apsnd Future.join) promises) body);
  1302 
  1303 
  1304 (***** theorems *****)
  1305 
  1306 fun thm_proof thy name hyps concl promises body =
  1307   let
  1308     val PBody {oracles = oracles0, thms = thms0, proof = prf} = body;
  1309     val prop = Logic.list_implies (hyps, concl);
  1310     val nvs = needed_vars prop;
  1311     val args = map (fn (v as Var (ixn, _)) =>
  1312         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1313       map SOME (frees_of prop);
  1314 
  1315     val proof0 =
  1316       if ! proofs = 2 then
  1317         #4 (shrink_proof [] 0 (rew_proof thy (fold_rev implies_intr_proof hyps prf)))
  1318       else MinProof;
  1319     val body0 = PBody {oracles = oracles0, thms = thms0, proof = proof0};
  1320 
  1321     fun new_prf () = (serial (), name, prop, fulfill_proof_future thy promises body0);
  1322     val (i, name, prop, body') =
  1323       (case strip_combt (fst (strip_combP prf)) of
  1324         (PThm (i, ((old_name, prop', NONE), body')), args') =>
  1325           if (old_name = "" orelse old_name = name) andalso prop = prop' andalso args = args'
  1326           then (i, name, prop, body')
  1327           else new_prf ()
  1328       | _ => new_prf ());
  1329     val head = PThm (i, ((name, prop, NONE), body'));
  1330   in
  1331     ((i, (name, prop, body')), proof_combP (proof_combt' (head, args), map Hyp hyps))
  1332   end;
  1333 
  1334 fun get_name hyps prop prf =
  1335   let val prop = Logic.list_implies (hyps, prop) in
  1336     (case strip_combt (fst (strip_combP prf)) of
  1337       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1338     | _ => "")
  1339   end;
  1340 
  1341 end;
  1342 
  1343 structure Basic_Proofterm : BASIC_PROOFTERM = Proofterm;
  1344 open Basic_Proofterm;