src/Pure/PIDE/command.ML
author wenzelm
Sat May 03 22:47:43 2014 +0200 (2014-05-03 ago)
changeset 56843 b2bfcd8cda80
parent 56504 d71f4be7e287
child 56875 f6259d6fb565
permissions -rw-r--r--
support for path completion based on file-system content;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   type blob = (string * (SHA1.digest * string list) option) Exn.result
    10   val read_file: Path.T -> Position.T -> Path.T -> Token.file
    11   val read: (unit -> theory) -> Path.T -> blob list -> Token.T list -> Toplevel.transition
    12   type eval
    13   val eval_eq: eval * eval -> bool
    14   val eval_running: eval -> bool
    15   val eval_finished: eval -> bool
    16   val eval_result_state: eval -> Toplevel.state
    17   val eval: (unit -> theory) -> Path.T -> blob list -> Token.T list -> eval -> eval
    18   type print
    19   val print: bool -> (string * string list) list -> string ->
    20     eval -> print list -> print list option
    21   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    22   type print_function =
    23     {command_name: string, args: string list, exec_id: Document_ID.exec} ->
    24       {delay: Time.time option, pri: int, persistent: bool, strict: bool, print_fn: print_fn} option
    25   val print_function: string -> print_function -> unit
    26   val no_print_function: string -> unit
    27   type exec = eval * print list
    28   val no_exec: exec
    29   val exec_ids: exec option -> Document_ID.exec list
    30   val exec: Document_ID.execution -> exec -> unit
    31 end;
    32 
    33 structure Command: COMMAND =
    34 struct
    35 
    36 (** memo results **)
    37 
    38 datatype 'a expr =
    39   Expr of Document_ID.exec * (unit -> 'a) |
    40   Result of 'a Exn.result;
    41 
    42 abstype 'a memo = Memo of 'a expr Synchronized.var
    43 with
    44 
    45 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    46 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    47 
    48 fun memo_result (Memo v) =
    49   (case Synchronized.value v of
    50     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    51   | Result res => Exn.release res);
    52 
    53 fun memo_finished (Memo v) =
    54   (case Synchronized.value v of Expr _ => false | Result _ => true);
    55 
    56 fun memo_exec execution_id (Memo v) =
    57   Synchronized.timed_access v (K (SOME Time.zeroTime))
    58     (fn expr =>
    59       (case expr of
    60         Expr (exec_id, body) =>
    61           uninterruptible (fn restore_attributes => fn () =>
    62             let val group = Future.worker_subgroup () in
    63               if Execution.running execution_id exec_id [group] then
    64                 let
    65                   val res =
    66                     (body
    67                       |> restore_attributes
    68                       |> Future.task_context "Command.memo_exec" group
    69                       |> Exn.interruptible_capture) ();
    70                 in SOME ((), Result res) end
    71               else SOME ((), expr)
    72             end) ()
    73       | Result _ => SOME ((), expr)))
    74   |> (fn NONE => error "Conflicting command execution" | _ => ());
    75 
    76 fun memo_fork params execution_id (Memo v) =
    77   (case Synchronized.value v of
    78     Result _ => ()
    79   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    80 
    81 end;
    82 
    83 
    84 
    85 (** main phases of execution **)
    86 
    87 (* read *)
    88 
    89 type blob =
    90   (string * (SHA1.digest * string list) option) Exn.result;  (*file node name, digest, lines*)
    91 
    92 fun read_file_node file_node master_dir pos src_path =
    93   let
    94     val _ = Position.report pos Markup.language_path;
    95     val _ =
    96       (case try Url.explode file_node of
    97         NONE => ()
    98       | SOME (Url.File _) => ()
    99       | _ =>
   100          (Position.report pos (Markup.path file_node);
   101           error ("Prover cannot load remote file " ^
   102             Markup.markup (Markup.path file_node) (quote file_node) ^ Position.here pos)));
   103     val full_path = File.check_file (File.full_path master_dir src_path);
   104     val _ = Position.report pos (Markup.path (Path.implode full_path));
   105     val text = File.read full_path;
   106     val lines = split_lines text;
   107     val digest = SHA1.digest text;
   108   in {src_path = src_path, lines = lines, digest = digest, pos = Path.position full_path} end;
   109 
   110 val read_file = read_file_node "";
   111 
   112 local
   113 
   114 fun blob_file src_path lines digest file_node =
   115   let
   116     val file_pos =
   117       Position.file file_node |>
   118       (case Position.get_id (Position.thread_data ()) of
   119         NONE => I
   120       | SOME exec_id => Position.put_id exec_id);
   121   in {src_path = src_path, lines = lines, digest = digest, pos = file_pos} end
   122 
   123 fun resolve_files master_dir blobs toks =
   124   (case Thy_Syntax.parse_spans toks of
   125     [span] => span
   126       |> Thy_Syntax.resolve_files (fn cmd => fn (path, pos) =>
   127         let
   128           fun make_file src_path (Exn.Res (file_node, NONE)) =
   129                 Exn.interruptible_capture (fn () =>
   130                   read_file_node file_node master_dir pos src_path) ()
   131             | make_file src_path (Exn.Res (file_node, SOME (digest, lines))) =
   132                (Position.reports [(pos, Markup.language_path), (pos, Markup.path file_node)];
   133                 Exn.Res (blob_file src_path lines digest file_node))
   134             | make_file _ (Exn.Exn e) = Exn.Exn e;
   135           val src_paths = Keyword.command_files cmd path;
   136         in
   137           if null blobs then
   138             map2 make_file src_paths (map (K (Exn.Res ("", NONE))) src_paths)
   139           else if length src_paths = length blobs then
   140             map2 make_file src_paths blobs
   141           else error ("Misalignment of inlined files" ^ Position.here pos)
   142         end)
   143       |> Thy_Syntax.span_content
   144   | _ => toks);
   145 
   146 in
   147 
   148 fun read init master_dir blobs span =
   149   let
   150     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
   151     val command_reports = Outer_Syntax.command_reports outer_syntax;
   152 
   153     val proper_range = Token.range_of (#1 (take_suffix Token.is_improper span));
   154     val pos =
   155       (case find_first Token.is_command span of
   156         SOME tok => Token.pos_of tok
   157       | NONE => #1 proper_range);
   158 
   159     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
   160     val _ = Position.reports_text (token_reports @ maps command_reports span);
   161   in
   162     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
   163     else
   164       (case Outer_Syntax.read_spans outer_syntax (resolve_files master_dir blobs span) of
   165         [tr] =>
   166           if Keyword.is_control (Toplevel.name_of tr) then
   167             Toplevel.malformed pos "Illegal control command"
   168           else Toplevel.modify_init init tr
   169       | [] => Toplevel.ignored (#1 (Token.range_of span))
   170       | _ => Toplevel.malformed (#1 proper_range) "Exactly one command expected")
   171       handle ERROR msg => Toplevel.malformed (#1 proper_range) msg
   172   end;
   173 
   174 end;
   175 
   176 
   177 (* eval *)
   178 
   179 type eval_state =
   180   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   181 val init_eval_state =
   182   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   183 
   184 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   185 
   186 fun eval_exec_id (Eval {exec_id, ...}) = exec_id;
   187 val eval_eq = op = o pairself eval_exec_id;
   188 
   189 val eval_running = Execution.is_running_exec o eval_exec_id;
   190 fun eval_finished (Eval {eval_process, ...}) = memo_finished eval_process;
   191 
   192 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   193 val eval_result_state = #state o eval_result;
   194 
   195 local
   196 
   197 fun run int tr st =
   198   if Goal.future_enabled 1 andalso Keyword.is_diag (Toplevel.name_of tr) then
   199     (Execution.fork {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   200       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   201   else Toplevel.command_errors int tr st;
   202 
   203 fun check_cmts span tr st' =
   204   Toplevel.setmp_thread_position tr
   205     (fn () =>
   206       Outer_Syntax.side_comments span |> maps (fn cmt =>
   207         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   208           handle exn =>
   209             if Exn.is_interrupt exn then reraise exn
   210             else Runtime.exn_messages_ids exn)) ();
   211 
   212 fun report tr m =
   213   Toplevel.setmp_thread_position tr (fn () => Output.report [Markup.markup_only m]) ();
   214 
   215 fun status tr m =
   216   Toplevel.setmp_thread_position tr (fn () => Output.status (Markup.markup_only m)) ();
   217 
   218 fun proof_status tr st =
   219   (case try Toplevel.proof_of st of
   220     SOME prf => status tr (Proof.status_markup prf)
   221   | NONE => ());
   222 
   223 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   224   if malformed then
   225     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   226   else
   227     let
   228       val malformed' = Toplevel.is_malformed tr;
   229       val is_init = Toplevel.is_init tr;
   230       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   231 
   232       val _ = Multithreading.interrupted ();
   233       val _ = status tr Markup.running;
   234       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   235       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   236       val errs = errs1 @ errs2;
   237       val _ = List.app (Future.error_message (Toplevel.pos_of tr)) errs;
   238     in
   239       (case result of
   240         NONE =>
   241           let
   242             val _ = status tr Markup.failed;
   243             val _ = status tr Markup.finished;
   244             val _ = if null errs then (report tr Markup.bad; Exn.interrupt ()) else ();
   245           in {failed = true, malformed = malformed', command = tr, state = st} end
   246       | SOME st' =>
   247           let
   248             val _ = proof_status tr st';
   249             val _ = status tr Markup.finished;
   250           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   251     end;
   252 
   253 in
   254 
   255 fun eval init master_dir blobs span eval0 =
   256   let
   257     val exec_id = Document_ID.make ();
   258     fun process () =
   259       let
   260         val tr =
   261           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   262             (fn () => read init master_dir blobs span |> Toplevel.exec_id exec_id) ();
   263       in eval_state span tr (eval_result eval0) end;
   264   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   265 
   266 end;
   267 
   268 
   269 (* print *)
   270 
   271 datatype print = Print of
   272  {name: string, args: string list, delay: Time.time option, pri: int, persistent: bool,
   273   exec_id: Document_ID.exec, print_process: unit memo};
   274 
   275 fun print_exec_id (Print {exec_id, ...}) = exec_id;
   276 val print_eq = op = o pairself print_exec_id;
   277 
   278 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   279 
   280 type print_function =
   281   {command_name: string, args: string list, exec_id: Document_ID.exec} ->
   282     {delay: Time.time option, pri: int, persistent: bool, strict: bool, print_fn: print_fn} option;
   283 
   284 local
   285 
   286 val print_functions =
   287   Synchronized.var "Command.print_functions" ([]: (string * print_function) list);
   288 
   289 fun print_error tr opt_context e =
   290   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution opt_context) e ()
   291     handle exn =>
   292       if Exn.is_interrupt exn then reraise exn
   293       else List.app (Future.error_message (Toplevel.pos_of tr)) (Runtime.exn_messages_ids exn);
   294 
   295 fun print_finished (Print {print_process, ...}) = memo_finished print_process;
   296 
   297 fun print_persistent (Print {persistent, ...}) = persistent;
   298 
   299 val overlay_ord = prod_ord string_ord (list_ord string_ord);
   300 
   301 in
   302 
   303 fun print command_visible command_overlays command_name eval old_prints =
   304   let
   305     val print_functions = Synchronized.value print_functions;
   306 
   307     fun make_print name args {delay, pri, persistent, strict, print_fn} =
   308       let
   309         val exec_id = Document_ID.make ();
   310         fun process () =
   311           let
   312             val {failed, command, state = st', ...} = eval_result eval;
   313             val tr = Toplevel.exec_id exec_id command;
   314             val opt_context = try Toplevel.generic_theory_of st';
   315           in
   316             if failed andalso strict then ()
   317             else print_error tr opt_context (fn () => print_fn tr st')
   318           end;
   319       in
   320         Print {
   321           name = name, args = args, delay = delay, pri = pri, persistent = persistent,
   322           exec_id = exec_id, print_process = memo exec_id process}
   323       end;
   324 
   325     fun bad_print name args exn =
   326       make_print name args {delay = NONE, pri = 0, persistent = false,
   327         strict = false, print_fn = fn _ => fn _ => reraise exn};
   328 
   329     fun new_print name args get_pr =
   330       let
   331         val params = {command_name = command_name, args = args, exec_id = eval_exec_id eval};
   332       in
   333         (case Exn.capture (Runtime.controlled_execution NONE get_pr) params of
   334           Exn.Res NONE => NONE
   335         | Exn.Res (SOME pr) => SOME (make_print name args pr)
   336         | Exn.Exn exn => SOME (bad_print name args exn))
   337       end;
   338 
   339     fun get_print (a, b) =
   340       (case find_first (fn Print {name, args, ...} => name = a andalso args = b) old_prints of
   341         NONE =>
   342           (case AList.lookup (op =) print_functions a of
   343             NONE => SOME (bad_print a b (ERROR ("Missing print function " ^ quote a)))
   344           | SOME get_pr => new_print a b get_pr)
   345       | some => some);
   346 
   347     val new_prints =
   348       if command_visible then
   349         fold (fn (a, _) => cons (a, [])) print_functions command_overlays
   350         |> sort_distinct overlay_ord
   351         |> map_filter get_print
   352       else filter (fn print => print_finished print andalso print_persistent print) old_prints;
   353   in
   354     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   355   end;
   356 
   357 fun print_function name f =
   358   Synchronized.change print_functions (fn funs =>
   359    (if not (AList.defined (op =) funs name) then ()
   360     else warning ("Redefining command print function: " ^ quote name);
   361     AList.update (op =) (name, f) funs));
   362 
   363 fun no_print_function name =
   364   Synchronized.change print_functions (filter_out (equal name o #1));
   365 
   366 end;
   367 
   368 val _ =
   369   print_function "Execution.print"
   370     (fn {args, exec_id, ...} =>
   371       if null args then
   372         SOME {delay = NONE, pri = 1, persistent = false, strict = true,
   373           print_fn = fn _ => fn _ => Execution.fork_prints exec_id}
   374       else NONE);
   375 
   376 val _ =
   377   print_function "print_state"
   378     (fn {command_name, ...} =>
   379       SOME {delay = NONE, pri = 1, persistent = false, strict = true,
   380         print_fn = fn tr => fn st' =>
   381           let
   382             val is_init = Keyword.is_theory_begin command_name;
   383             val is_proof = Keyword.is_proof command_name;
   384             val do_print =
   385               not is_init andalso
   386                 (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   387           in if do_print then Toplevel.print_state false st' else () end});
   388 
   389 
   390 (* combined execution *)
   391 
   392 type exec = eval * print list;
   393 val no_exec: exec =
   394   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   395 
   396 fun exec_ids NONE = []
   397   | exec_ids (SOME (eval, prints)) = eval_exec_id eval :: map print_exec_id prints;
   398 
   399 local
   400 
   401 fun run_print execution_id (Print {name, delay, pri, print_process, ...}) =
   402   if Multithreading.enabled () orelse pri <= 0 then
   403     let
   404       val group = Future.worker_subgroup ();
   405       fun fork () =
   406         memo_fork {name = name, group = SOME group, deps = [], pri = pri, interrupts = true}
   407           execution_id print_process;
   408     in
   409       (case delay of
   410         NONE => fork ()
   411       | SOME d => ignore (Event_Timer.request (Time.+ (Time.now (), d)) fork))
   412     end
   413   else memo_exec execution_id print_process;
   414 
   415 in
   416 
   417 fun exec execution_id (Eval {eval_process, ...}, prints) =
   418   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   419 
   420 end;
   421 
   422 end;
   423