src/Pure/axclass.ML
author wenzelm
Mon Apr 18 14:05:39 2011 +0200 (2011-04-18 ago)
changeset 42389 b2c6033fc7e4
parent 42383 0ae4ad40d7b5
child 43329 84472e198515
permissions -rw-r--r--
pass plain Proof.context for pretty printing;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.  Proven class relations and type arities.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   type info = {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    11   val get_info: theory -> class -> info
    12   val class_of_param: theory -> string -> class option
    13   val instance_name: string * class -> string
    14   val thynames_of_arity: theory -> class * string -> string list
    15   val param_of_inst: theory -> string * string -> string
    16   val inst_of_param: theory -> string -> (string * string) option
    17   val unoverload: theory -> thm -> thm
    18   val overload: theory -> thm -> thm
    19   val unoverload_conv: theory -> conv
    20   val overload_conv: theory -> conv
    21   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    22   val unoverload_const: theory -> string * typ -> string
    23   val cert_classrel: theory -> class * class -> class * class
    24   val read_classrel: theory -> xstring * xstring -> class * class
    25   val declare_overloaded: string * typ -> theory -> term * theory
    26   val define_overloaded: binding -> string * term -> theory -> thm * theory
    27   val add_classrel: thm -> theory -> theory
    28   val add_arity: thm -> theory -> theory
    29   val prove_classrel: class * class -> tactic -> theory -> theory
    30   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    31   val define_class: binding * class list -> string list ->
    32     (Thm.binding * term list) list -> theory -> class * theory
    33   val axiomatize_class: binding * class list -> theory -> theory
    34   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    35   val axiomatize_classrel: (class * class) list -> theory -> theory
    36   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    37   val axiomatize_arity: arity -> theory -> theory
    38   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    39 end;
    40 
    41 structure AxClass: AX_CLASS =
    42 struct
    43 
    44 (** theory data **)
    45 
    46 (* axclass info *)
    47 
    48 type info =
    49  {def: thm,
    50   intro: thm,
    51   axioms: thm list,
    52   params: (string * typ) list};
    53 
    54 fun make_axclass (def, intro, axioms, params): info =
    55   {def = def, intro = intro, axioms = axioms, params = params};
    56 
    57 
    58 (* class parameters (canonical order) *)
    59 
    60 type param = string * class;
    61 
    62 fun add_param ctxt ((x, c): param) params =
    63   (case AList.lookup (op =) params x of
    64     NONE => (x, c) :: params
    65   | SOME c' =>
    66       error ("Duplicate class parameter " ^ quote x ^ " for " ^ Syntax.string_of_sort ctxt [c] ^
    67         (if c = c' then "" else " and " ^ Syntax.string_of_sort ctxt [c'])));
    68 
    69 
    70 (* setup data *)
    71 
    72 datatype data = Data of
    73  {axclasses: info Symtab.table,
    74   params: param list,
    75   proven_classrels: thm Symreltab.table,
    76   proven_arities: ((class * sort list) * (thm * string)) list Symtab.table,
    77     (*arity theorems with theory name*)
    78   inst_params:
    79     (string * thm) Symtab.table Symtab.table *
    80       (*constant name ~> type constructor ~> (constant name, equation)*)
    81     (string * string) Symtab.table (*constant name ~> (constant name, type constructor)*),
    82   diff_classrels: (class * class) list};
    83 
    84 fun make_data
    85     (axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels) =
    86   Data {axclasses = axclasses, params = params, proven_classrels = proven_classrels,
    87     proven_arities = proven_arities, inst_params = inst_params,
    88     diff_classrels = diff_classrels};
    89 
    90 fun diff_table tab1 tab2 =
    91   Symreltab.fold (fn (x, _) => if Symreltab.defined tab2 x then I else cons x) tab1 [];
    92 
    93 structure Data = Theory_Data_PP
    94 (
    95   type T = data;
    96   val empty =
    97     make_data (Symtab.empty, [], Symreltab.empty, Symtab.empty, (Symtab.empty, Symtab.empty), []);
    98   val extend = I;
    99   fun merge pp
   100       (Data {axclasses = axclasses1, params = params1, proven_classrels = proven_classrels1,
   101         proven_arities = proven_arities1, inst_params = inst_params1,
   102         diff_classrels = diff_classrels1},
   103        Data {axclasses = axclasses2, params = params2, proven_classrels = proven_classrels2,
   104         proven_arities = proven_arities2, inst_params = inst_params2,
   105         diff_classrels = diff_classrels2}) =
   106     let
   107       val ctxt = Syntax.init_pretty pp;
   108 
   109       val axclasses' = Symtab.merge (K true) (axclasses1, axclasses2);
   110       val params' =
   111         if null params1 then params2
   112         else
   113           fold_rev (fn p => if member (op =) params1 p then I else add_param ctxt p)
   114             params2 params1;
   115 
   116       (*transitive closure of classrels and arity completion is done in Theory.at_begin hook*)
   117       val proven_classrels' = Symreltab.join (K #1) (proven_classrels1, proven_classrels2);
   118       val proven_arities' =
   119         Symtab.join (K (Library.merge (eq_fst op =))) (proven_arities1, proven_arities2);
   120 
   121       val diff_classrels' =
   122         diff_table proven_classrels1 proven_classrels2 @
   123         diff_table proven_classrels2 proven_classrels1 @
   124         diff_classrels1 @ diff_classrels2;
   125 
   126       val inst_params' =
   127         (Symtab.join (K (Symtab.merge (K true))) (#1 inst_params1, #1 inst_params2),
   128           Symtab.merge (K true) (#2 inst_params1, #2 inst_params2));
   129     in
   130       make_data
   131         (axclasses', params', proven_classrels', proven_arities', inst_params', diff_classrels')
   132     end;
   133 );
   134 
   135 fun map_data f =
   136   Data.map (fn Data {axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels} =>
   137     make_data (f (axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels)));
   138 
   139 fun map_axclasses f =
   140   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels) =>
   141     (f axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels));
   142 
   143 fun map_params f =
   144   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels) =>
   145     (axclasses, f params, proven_classrels, proven_arities, inst_params, diff_classrels));
   146 
   147 fun map_proven_classrels f =
   148   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels) =>
   149     (axclasses, params, f proven_classrels, proven_arities, inst_params, diff_classrels));
   150 
   151 fun map_proven_arities f =
   152   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels) =>
   153     (axclasses, params, proven_classrels, f proven_arities, inst_params, diff_classrels));
   154 
   155 fun map_inst_params f =
   156   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_classrels) =>
   157     (axclasses, params, proven_classrels, proven_arities, f inst_params, diff_classrels));
   158 
   159 val clear_diff_classrels =
   160   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, _) =>
   161     (axclasses, params, proven_classrels, proven_arities, inst_params, []));
   162 
   163 val rep_data = Data.get #> (fn Data args => args);
   164 
   165 val axclasses_of = #axclasses o rep_data;
   166 val params_of = #params o rep_data;
   167 val proven_classrels_of = #proven_classrels o rep_data;
   168 val proven_arities_of = #proven_arities o rep_data;
   169 val inst_params_of = #inst_params o rep_data;
   170 val diff_classrels_of = #diff_classrels o rep_data;
   171 
   172 
   173 (* axclasses with parameters *)
   174 
   175 fun get_info thy c =
   176   (case Symtab.lookup (axclasses_of thy) c of
   177     SOME info => info
   178   | NONE => error ("No such axclass: " ^ quote c));
   179 
   180 fun all_params_of thy S =
   181   let val params = params_of thy;
   182   in fold (fn (x, c) => if Sign.subsort thy (S, [c]) then cons x else I) params [] end;
   183 
   184 fun class_of_param thy = AList.lookup (op =) (params_of thy);
   185 
   186 
   187 (* maintain instances *)
   188 
   189 val classrel_prefix = "classrel_";
   190 val arity_prefix = "arity_";
   191 
   192 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   193 
   194 
   195 infix 0 RSO;
   196 
   197 fun (SOME a) RSO (SOME b) = SOME (a RS b)
   198   | x RSO NONE = x
   199   | NONE RSO y = y;
   200 
   201 fun the_classrel thy (c1, c2) =
   202   (case Symreltab.lookup (proven_classrels_of thy) (c1, c2) of
   203     SOME thm => thm
   204   | NONE => error ("Unproven class relation " ^
   205       Syntax.string_of_classrel (Proof_Context.init_global thy) [c1, c2]));  (* FIXME stale thy (!?) *)
   206 
   207 fun put_trancl_classrel ((c1, c2), th) thy =
   208   let
   209     val classes = Sorts.classes_of (Sign.classes_of thy);
   210     val classrels = proven_classrels_of thy;
   211 
   212     fun reflcl_classrel (c1', c2') =
   213       if c1' = c2' then NONE else SOME (Thm.transfer thy (the_classrel thy (c1', c2')));
   214     fun gen_classrel (c1_pred, c2_succ) =
   215       let
   216         val th' =
   217           the ((reflcl_classrel (c1_pred, c1) RSO SOME th) RSO reflcl_classrel (c2, c2_succ))
   218           |> Drule.instantiate' [SOME (ctyp_of thy (TVar ((Name.aT, 0), [])))] []
   219           |> Thm.close_derivation;
   220       in ((c1_pred, c2_succ), th') end;
   221 
   222     val new_classrels =
   223       Library.map_product pair (c1 :: Graph.imm_preds classes c1) (c2 :: Graph.imm_succs classes c2)
   224       |> filter_out ((op =) orf Symreltab.defined classrels)
   225       |> map gen_classrel;
   226     val needed = not (null new_classrels);
   227   in
   228     (needed,
   229       if needed then map_proven_classrels (fold Symreltab.update new_classrels) thy
   230       else thy)
   231   end;
   232 
   233 fun complete_classrels thy =
   234   let
   235     val classrels = proven_classrels_of thy;
   236     val diff_classrels = diff_classrels_of thy;
   237     val (needed, thy') = (false, thy) |>
   238       fold (fn rel => fn (needed, thy) =>
   239           put_trancl_classrel (rel, Symreltab.lookup classrels rel |> the) thy
   240           |>> (fn b => needed orelse b))
   241         diff_classrels;
   242   in
   243     if null diff_classrels then NONE
   244     else SOME (clear_diff_classrels thy')
   245   end;
   246 
   247 
   248 fun the_arity thy (a, Ss, c) =
   249   (case AList.lookup (op =) (Symtab.lookup_list (proven_arities_of thy) a) (c, Ss) of
   250     SOME (thm, _) => thm
   251   | NONE => error ("Unproven type arity " ^
   252       Syntax.string_of_arity (Proof_Context.init_global thy) (a, Ss, [c])));  (* FIXME stale thy (!?) *)
   253 
   254 fun thynames_of_arity thy (c, a) =
   255   Symtab.lookup_list (proven_arities_of thy) a
   256   |> map_filter (fn ((c', _), (_, name)) => if c = c' then SOME name else NONE)
   257   |> rev;
   258 
   259 fun insert_arity_completions thy t ((c, Ss), ((th, thy_name))) (finished, arities) =
   260   let
   261     val algebra = Sign.classes_of thy;
   262     val ars = Symtab.lookup_list arities t;
   263     val super_class_completions =
   264       Sign.super_classes thy c
   265       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) =>
   266             c1 = c2 andalso Sorts.sorts_le algebra (Ss2, Ss)) ars);
   267 
   268     val names = Name.invents Name.context Name.aT (length Ss);
   269     val std_vars = map (fn a => SOME (ctyp_of thy (TVar ((a, 0), [])))) names;
   270 
   271     val completions = super_class_completions |> map (fn c1 =>
   272       let
   273         val th1 =
   274           (th RS Thm.transfer thy (the_classrel thy (c, c1)))
   275           |> Drule.instantiate' std_vars []
   276           |> Thm.close_derivation;
   277       in ((th1, thy_name), c1) end);
   278 
   279     val finished' = finished andalso null completions;
   280     val arities' = fold (fn (th, c1) => Symtab.cons_list (t, ((c1, Ss), th))) completions arities;
   281   in (finished', arities') end;
   282 
   283 fun put_arity ((t, Ss, c), th) thy =
   284   let val ar = ((c, Ss), (th, Context.theory_name thy)) in
   285     thy
   286     |> map_proven_arities
   287       (Symtab.insert_list (eq_fst op =) (t, ar) #>
   288        curry (insert_arity_completions thy t ar) true #> #2)
   289   end;
   290 
   291 fun complete_arities thy =
   292   let
   293     val arities = proven_arities_of thy;
   294     val (finished, arities') =
   295       Symtab.fold (fn (t, ars) => fold (insert_arity_completions thy t) ars) arities (true, arities);
   296   in
   297     if finished then NONE
   298     else SOME (map_proven_arities (K arities') thy)
   299   end;
   300 
   301 val _ = Context.>> (Context.map_theory
   302   (Theory.at_begin complete_classrels #>
   303    Theory.at_begin complete_arities));
   304 
   305 val _ = Proofterm.install_axclass_proofs
   306   {classrel_proof = Thm.proof_of oo the_classrel,
   307    arity_proof = Thm.proof_of oo the_arity};
   308 
   309 
   310 (* maintain instance parameters *)
   311 
   312 fun get_inst_param thy (c, tyco) =
   313   (case Symtab.lookup (the_default Symtab.empty (Symtab.lookup (#1 (inst_params_of thy)) c)) tyco of
   314     SOME c' => c'
   315   | NONE => error ("No instance parameter for constant " ^ quote c ^ " on type " ^ quote tyco));
   316 
   317 fun add_inst_param (c, tyco) inst =
   318   (map_inst_params o apfst o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   319   #> (map_inst_params o apsnd) (Symtab.update_new (#1 inst, (c, tyco)));
   320 
   321 val inst_of_param = Symtab.lookup o #2 o inst_params_of;
   322 val param_of_inst = #1 oo get_inst_param;
   323 
   324 fun inst_thms thy =
   325   Symtab.fold (Symtab.fold (cons o #2 o #2) o #2) (#1 (inst_params_of thy)) [];
   326 
   327 fun get_inst_tyco consts = try (#1 o dest_Type o the_single o Consts.typargs consts);
   328 
   329 fun unoverload thy = Raw_Simplifier.simplify true (inst_thms thy);
   330 fun overload thy = Raw_Simplifier.simplify true (map Thm.symmetric (inst_thms thy));
   331 
   332 fun unoverload_conv thy = Raw_Simplifier.rewrite true (inst_thms thy);
   333 fun overload_conv thy = Raw_Simplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   334 
   335 fun lookup_inst_param consts params (c, T) =
   336   (case get_inst_tyco consts (c, T) of
   337     SOME tyco => AList.lookup (op =) params (c, tyco)
   338   | NONE => NONE);
   339 
   340 fun unoverload_const thy (c_ty as (c, _)) =
   341   if is_some (class_of_param thy c) then
   342     (case get_inst_tyco (Sign.consts_of thy) c_ty of
   343       SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   344     | NONE => c)
   345   else c;
   346 
   347 
   348 
   349 (** instances **)
   350 
   351 (* class relations *)
   352 
   353 fun cert_classrel thy raw_rel =
   354   let
   355     val string_of_sort = Syntax.string_of_sort_global thy;
   356     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   357     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   358     val _ =
   359       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   360         [] => ()
   361       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   362           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   363   in (c1, c2) end;
   364 
   365 fun read_classrel thy raw_rel =
   366   cert_classrel thy (pairself (Proof_Context.read_class (Proof_Context.init_global thy)) raw_rel)
   367     handle TYPE (msg, _, _) => error msg;
   368 
   369 
   370 (* declaration and definition of instances of overloaded constants *)
   371 
   372 fun inst_tyco_of thy (c, T) =
   373   (case get_inst_tyco (Sign.consts_of thy) (c, T) of
   374     SOME tyco => tyco
   375   | NONE => error ("Illegal type for instantiation of class parameter: " ^
   376       quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T)));
   377 
   378 fun declare_overloaded (c, T) thy =
   379   let
   380     val class =
   381       (case class_of_param thy c of
   382         SOME class => class
   383       | NONE => error ("Not a class parameter: " ^ quote c));
   384     val tyco = inst_tyco_of thy (c, T);
   385     val name_inst = instance_name (tyco, class) ^ "_inst";
   386     val c' = instance_name (tyco, c);
   387     val T' = Type.strip_sorts T;
   388   in
   389     thy
   390     |> Sign.qualified_path true (Binding.name name_inst)
   391     |> Sign.declare_const_global ((Binding.name c', T'), NoSyn)
   392     |-> (fn const' as Const (c'', _) =>
   393       Thm.add_def_global false true
   394         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   395       #>> apsnd Thm.varifyT_global
   396       #-> (fn (_, thm) => add_inst_param (c, tyco) (c'', thm)
   397         #> Global_Theory.add_thm ((Binding.conceal (Binding.name c'), thm), [])
   398         #> #2
   399         #> pair (Const (c, T))))
   400     ||> Sign.restore_naming thy
   401   end;
   402 
   403 fun define_overloaded b (c, t) thy =
   404   let
   405     val T = Term.fastype_of t;
   406     val tyco = inst_tyco_of thy (c, T);
   407     val (c', eq) = get_inst_param thy (c, tyco);
   408     val prop = Logic.mk_equals (Const (c', T), t);
   409     val b' = Thm.def_binding_optional (Binding.name (instance_name (tyco, c))) b;
   410   in
   411     thy
   412     |> Thm.add_def_global false false (b', prop)
   413     |>> (fn (_, thm) => Drule.transitive_thm OF [eq, thm])
   414   end;
   415 
   416 
   417 (* primitive rules *)
   418 
   419 fun add_classrel raw_th thy =
   420   let
   421     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   422     val prop = Thm.plain_prop_of th;
   423     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   424     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   425     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   426     val (th', thy') = Global_Theory.store_thm
   427       (Binding.name (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th) thy;
   428     val th'' = th'
   429       |> Thm.unconstrainT
   430       |> Drule.instantiate' [SOME (ctyp_of thy' (TVar ((Name.aT, 0), [])))] [];
   431   in
   432     thy'
   433     |> Sign.primitive_classrel (c1, c2)
   434     |> (#2 oo put_trancl_classrel) ((c1, c2), th'')
   435     |> perhaps complete_arities
   436   end;
   437 
   438 fun add_arity raw_th thy =
   439   let
   440     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   441     val prop = Thm.plain_prop_of th;
   442     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   443     val arity as (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   444 
   445     val (th', thy') = Global_Theory.store_thm
   446       (Binding.name (prefix arity_prefix (Logic.name_arity arity)), th) thy;
   447 
   448     val args = Name.names Name.context Name.aT Ss;
   449     val T = Type (t, map TFree args);
   450     val std_vars = map (fn (a, S) => SOME (ctyp_of thy' (TVar ((a, 0), [])))) args;
   451 
   452     val missing_params = Sign.complete_sort thy' [c]
   453       |> maps (these o Option.map #params o try (get_info thy'))
   454       |> filter_out (fn (const, _) => can (get_inst_param thy') (const, t))
   455       |> (map o apsnd o map_atyps) (K T);
   456     val th'' = th'
   457       |> Thm.unconstrainT
   458       |> Drule.instantiate' std_vars [];
   459   in
   460     thy'
   461     |> fold (#2 oo declare_overloaded) missing_params
   462     |> Sign.primitive_arity (t, Ss, [c])
   463     |> put_arity ((t, Ss, c), th'')
   464   end;
   465 
   466 
   467 (* tactical proofs *)
   468 
   469 fun prove_classrel raw_rel tac thy =
   470   let
   471     val ctxt = Proof_Context.init_global thy;
   472     val (c1, c2) = cert_classrel thy raw_rel;
   473     val th = Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   474       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   475         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   476   in
   477     thy |> add_classrel th
   478   end;
   479 
   480 fun prove_arity raw_arity tac thy =
   481   let
   482     val ctxt = Proof_Context.init_global thy;
   483     val arity = Proof_Context.cert_arity ctxt raw_arity;
   484     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   485     val props = Logic.mk_arities arity;
   486     val ths = Goal.prove_multi ctxt [] [] props
   487       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   488         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   489           quote (Syntax.string_of_arity ctxt arity));
   490   in
   491     thy |> fold add_arity ths
   492   end;
   493 
   494 
   495 
   496 (** class definitions **)
   497 
   498 fun split_defined n eq =
   499   let
   500     val intro =
   501       (eq RS Drule.equal_elim_rule2)
   502       |> Conjunction.curry_balanced n
   503       |> n = 0 ? Thm.eq_assumption 1;
   504     val dests =
   505       if n = 0 then []
   506       else
   507         (eq RS Drule.equal_elim_rule1)
   508         |> Balanced_Tree.dest (fn th =>
   509           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   510   in (intro, dests) end;
   511 
   512 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   513   let
   514     val ctxt = Syntax.init_pretty_global thy;
   515 
   516 
   517     (* class *)
   518 
   519     val bconst = Binding.map_name Logic.const_of_class bclass;
   520     val class = Sign.full_name thy bclass;
   521     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   522 
   523     fun check_constraint (a, S) =
   524       if Sign.subsort thy (super, S) then ()
   525       else error ("Sort constraint of type variable " ^
   526         Syntax.string_of_typ (Config.put show_sorts true ctxt) (TFree (a, S)) ^
   527         " needs to be weaker than " ^ Syntax.string_of_sort ctxt super);
   528 
   529 
   530     (* params *)
   531 
   532     val params = raw_params |> map (fn p =>
   533       let
   534         val T = Sign.the_const_type thy p;
   535         val _ =
   536           (case Term.add_tvarsT T [] of
   537             [((a, _), S)] => check_constraint (a, S)
   538           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   539         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   540       in (p, T') end);
   541 
   542 
   543     (* axioms *)
   544 
   545     fun prep_axiom t =
   546       (case Term.add_tfrees t [] of
   547         [(a, S)] => check_constraint (a, S)
   548       | [] => ()
   549       | _ => error ("Multiple type variables in class axiom:\n" ^ Syntax.string_of_term ctxt t);
   550       t
   551       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   552       |> Logic.close_form);
   553 
   554     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   555     val name_atts = map fst raw_specs;
   556 
   557 
   558     (* definition *)
   559 
   560     val conjs = Logic.mk_of_sort (Term.aT [], super) @ flat axiomss;
   561     val class_eq =
   562       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   563 
   564     val ([def], def_thy) =
   565       thy
   566       |> Sign.primitive_class (bclass, super)
   567       |> Global_Theory.add_defs false [((Thm.def_binding bconst, class_eq), [])];
   568     val (raw_intro, (raw_classrel, raw_axioms)) =
   569       split_defined (length conjs) def ||> chop (length super);
   570 
   571 
   572     (* facts *)
   573 
   574     val class_triv = Thm.class_triv def_thy class;
   575     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   576       def_thy
   577       |> Sign.qualified_path true bconst
   578       |> Global_Theory.note_thmss ""
   579         [((Binding.name "intro", []), [([Drule.export_without_context raw_intro], [])]),
   580          ((Binding.name "super", []), [(map Drule.export_without_context raw_classrel, [])]),
   581          ((Binding.name "axioms", []),
   582            [(map (fn th => Drule.export_without_context (class_triv RS th)) raw_axioms, [])])]
   583       ||> Sign.restore_naming def_thy;
   584 
   585 
   586     (* result *)
   587 
   588     val axclass = make_axclass (def, intro, axioms, params);
   589     val result_thy =
   590       facts_thy
   591       |> fold (#2 oo put_trancl_classrel) (map (pair class) super ~~ classrel)
   592       |> Sign.qualified_path false bconst
   593       |> Global_Theory.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms))
   594       |> #2
   595       |> Sign.restore_naming facts_thy
   596       |> map_axclasses (Symtab.update (class, axclass))
   597       |> map_params (fold (fn (x, _) => add_param ctxt (x, class)) params);
   598 
   599   in (class, result_thy) end;
   600 
   601 
   602 
   603 (** axiomatizations **)
   604 
   605 local
   606 
   607 (*old-style axioms*)
   608 fun axiomatize prep mk name add raw_args thy =
   609   let
   610     val args = prep thy raw_args;
   611     val specs = mk args;
   612     val names = name args;
   613   in
   614     thy
   615     |> fold_map Thm.add_axiom_global (map Binding.name names ~~ specs)
   616     |-> fold (add o Drule.export_without_context o snd)
   617   end;
   618 
   619 fun ax_classrel prep =
   620   axiomatize (map o prep) (map Logic.mk_classrel)
   621     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   622 
   623 fun ax_arity prep =
   624   axiomatize (prep o Proof_Context.init_global) Logic.mk_arities
   625     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   626 
   627 fun class_const c =
   628   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   629 
   630 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   631   let
   632     val class = Sign.full_name thy bclass;
   633     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   634   in
   635     thy
   636     |> Sign.primitive_class (bclass, super)
   637     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   638     |> Theory.add_deps_global "" (class_const class) (map class_const super)
   639   end;
   640 
   641 in
   642 
   643 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   644 val axiomatize_class_cmd =
   645   ax_class (Proof_Context.read_class o Proof_Context.init_global) read_classrel;
   646 val axiomatize_classrel = ax_classrel cert_classrel;
   647 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   648 val axiomatize_arity = ax_arity Proof_Context.cert_arity;
   649 val axiomatize_arity_cmd = ax_arity Proof_Context.read_arity;
   650 
   651 end;
   652 
   653 end;