src/Pure/Isar/proof_context.ML
author haftmann
Wed Jan 21 16:47:32 2009 +0100 (2009-01-21 ago)
changeset 29581 b3b33e0298eb
parent 29318 6337d1cb2ba0
child 29606 fedb8be05f24
permissions -rw-r--r--
binding is alias for Binding.T
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The key concept of Isar proof contexts: elevates primitive local
     6 reasoning Gamma |- phi to a structured concept, with generic context
     7 elements.  See also structure Variable and Assumption.
     8 *)
     9 
    10 signature PROOF_CONTEXT =
    11 sig
    12   val theory_of: Proof.context -> theory
    13   val init: theory -> Proof.context
    14   type mode
    15   val mode_default: mode
    16   val mode_stmt: mode
    17   val mode_pattern: mode
    18   val mode_schematic: mode
    19   val mode_abbrev: mode
    20   val set_mode: mode -> Proof.context -> Proof.context
    21   val get_mode: Proof.context -> mode
    22   val restore_mode: Proof.context -> Proof.context -> Proof.context
    23   val abbrev_mode: Proof.context -> bool
    24   val set_stmt: bool -> Proof.context -> Proof.context
    25   val naming_of: Proof.context -> NameSpace.naming
    26   val full_name: Proof.context -> binding -> string
    27   val full_bname: Proof.context -> bstring -> string
    28   val consts_of: Proof.context -> Consts.T
    29   val const_syntax_name: Proof.context -> string -> string
    30   val the_const_constraint: Proof.context -> string -> typ
    31   val mk_const: Proof.context -> string * typ list -> term
    32   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    33   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    34   val facts_of: Proof.context -> Facts.T
    35   val transfer_syntax: theory -> Proof.context -> Proof.context
    36   val transfer: theory -> Proof.context -> Proof.context
    37   val theory: (theory -> theory) -> Proof.context -> Proof.context
    38   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    39   val extern_fact: Proof.context -> string -> xstring
    40   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    41   val pretty_thm_legacy: thm -> Pretty.T
    42   val pretty_thm: Proof.context -> thm -> Pretty.T
    43   val pretty_thms: Proof.context -> thm list -> Pretty.T
    44   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    45   val string_of_thm: Proof.context -> thm -> string
    46   val read_typ: Proof.context -> string -> typ
    47   val read_typ_syntax: Proof.context -> string -> typ
    48   val read_typ_abbrev: Proof.context -> string -> typ
    49   val cert_typ: Proof.context -> typ -> typ
    50   val cert_typ_syntax: Proof.context -> typ -> typ
    51   val cert_typ_abbrev: Proof.context -> typ -> typ
    52   val get_skolem: Proof.context -> string -> string
    53   val revert_skolem: Proof.context -> string -> string
    54   val infer_type: Proof.context -> string -> typ
    55   val inferred_param: string -> Proof.context -> typ * Proof.context
    56   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    57   val read_tyname: Proof.context -> string -> typ
    58   val read_const_proper: Proof.context -> string -> term
    59   val read_const: Proof.context -> string -> term
    60   val allow_dummies: Proof.context -> Proof.context
    61   val decode_term: Proof.context -> term -> term
    62   val standard_infer_types: Proof.context -> term list -> term list
    63   val read_term_pattern: Proof.context -> string -> term
    64   val read_term_schematic: Proof.context -> string -> term
    65   val read_term_abbrev: Proof.context -> string -> term
    66   val expand_abbrevs: Proof.context -> term -> term
    67   val cert_term: Proof.context -> term -> term
    68   val cert_prop: Proof.context -> term -> term
    69   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    70   val export: Proof.context -> Proof.context -> thm list -> thm list
    71   val export_morphism: Proof.context -> Proof.context -> morphism
    72   val norm_export_morphism: Proof.context -> Proof.context -> morphism
    73   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    74   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    75   val auto_bind_goal: term list -> Proof.context -> Proof.context
    76   val auto_bind_facts: term list -> Proof.context -> Proof.context
    77   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    78   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    79   val read_propp: Proof.context * (string * string list) list list
    80     -> Proof.context * (term * term list) list list
    81   val cert_propp: Proof.context * (term * term list) list list
    82     -> Proof.context * (term * term list) list list
    83   val read_propp_schematic: Proof.context * (string * string list) list list
    84     -> Proof.context * (term * term list) list list
    85   val cert_propp_schematic: Proof.context * (term * term list) list list
    86     -> Proof.context * (term * term list) list list
    87   val bind_propp: Proof.context * (string * string list) list list
    88     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    89   val bind_propp_i: Proof.context * (term * term list) list list
    90     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    91   val bind_propp_schematic: Proof.context * (string * string list) list list
    92     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    93   val bind_propp_schematic_i: Proof.context * (term * term list) list list
    94     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    95   val fact_tac: thm list -> int -> tactic
    96   val some_fact_tac: Proof.context -> int -> tactic
    97   val get_fact: Proof.context -> Facts.ref -> thm list
    98   val get_fact_single: Proof.context -> Facts.ref -> thm
    99   val get_thms: Proof.context -> xstring -> thm list
   100   val get_thm: Proof.context -> xstring -> thm
   101   val add_path: string -> Proof.context -> Proof.context
   102   val no_base_names: Proof.context -> Proof.context
   103   val qualified_names: Proof.context -> Proof.context
   104   val sticky_prefix: string -> Proof.context -> Proof.context
   105   val restore_naming: Proof.context -> Proof.context -> Proof.context
   106   val reset_naming: Proof.context -> Proof.context
   107   val note_thmss: string ->
   108     ((binding * attribute list) * (Facts.ref * attribute list) list) list ->
   109       Proof.context -> (string * thm list) list * Proof.context
   110   val note_thmss_i: string ->
   111     ((binding * attribute list) * (thm list * attribute list) list) list ->
   112       Proof.context -> (string * thm list) list * Proof.context
   113   val put_thms: bool -> string * thm list option -> Proof.context -> Proof.context
   114   val read_vars: (binding * string option * mixfix) list -> Proof.context ->
   115     (binding * typ option * mixfix) list * Proof.context
   116   val cert_vars: (binding * typ option * mixfix) list -> Proof.context ->
   117     (binding * typ option * mixfix) list * Proof.context
   118   val add_fixes: (binding * string option * mixfix) list ->
   119     Proof.context -> string list * Proof.context
   120   val add_fixes_i: (binding * typ option * mixfix) list ->
   121     Proof.context -> string list * Proof.context
   122   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   123   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   124   val add_assms: Assumption.export ->
   125     ((binding * attribute list) * (string * string list) list) list ->
   126     Proof.context -> (string * thm list) list * Proof.context
   127   val add_assms_i: Assumption.export ->
   128     ((binding * attribute list) * (term * term list) list) list ->
   129     Proof.context -> (string * thm list) list * Proof.context
   130   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   131   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   132   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   133   val notation: bool -> Syntax.mode -> (term * mixfix) list -> Proof.context -> Proof.context
   134   val target_notation: bool -> Syntax.mode -> (term * mixfix) list -> morphism ->
   135     Context.generic -> Context.generic
   136   val add_const_constraint: string * typ option -> Proof.context -> Proof.context
   137   val add_abbrev: string -> Properties.T ->
   138     binding * term -> Proof.context -> (term * term) * Proof.context
   139   val revert_abbrev: string -> string -> Proof.context -> Proof.context
   140   val verbose: bool ref
   141   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   142   val print_syntax: Proof.context -> unit
   143   val print_abbrevs: Proof.context -> unit
   144   val print_binds: Proof.context -> unit
   145   val print_lthms: Proof.context -> unit
   146   val print_cases: Proof.context -> unit
   147   val debug: bool ref
   148   val prems_limit: int ref
   149   val pretty_ctxt: Proof.context -> Pretty.T list
   150   val pretty_context: Proof.context -> Pretty.T list
   151   val query_type: Proof.context -> string -> Properties.T
   152   val query_const: Proof.context -> string -> Properties.T
   153   val query_class: Proof.context -> string -> Properties.T
   154 end;
   155 
   156 structure ProofContext: PROOF_CONTEXT =
   157 struct
   158 
   159 val theory_of = Context.theory_of_proof;
   160 val init = Context.init_proof;
   161 
   162 
   163 (** inner syntax mode **)
   164 
   165 datatype mode =
   166   Mode of
   167    {stmt: bool,                (*inner statement mode*)
   168     pattern: bool,             (*pattern binding schematic variables*)
   169     schematic: bool,           (*term referencing loose schematic variables*)
   170     abbrev: bool};             (*abbrev mode -- no normalization*)
   171 
   172 fun make_mode (stmt, pattern, schematic, abbrev) =
   173   Mode {stmt = stmt, pattern = pattern, schematic = schematic, abbrev = abbrev};
   174 
   175 val mode_default   = make_mode (false, false, false, false);
   176 val mode_stmt      = make_mode (true, false, false, false);
   177 val mode_pattern   = make_mode (false, true, false, false);
   178 val mode_schematic = make_mode (false, false, true, false);
   179 val mode_abbrev    = make_mode (false, false, false, true);
   180 
   181 
   182 
   183 (** Isar proof context information **)
   184 
   185 datatype ctxt =
   186   Ctxt of
   187    {mode: mode,                                       (*inner syntax mode*)
   188     naming: NameSpace.naming,                         (*local naming conventions*)
   189     syntax: LocalSyntax.T,                            (*local syntax*)
   190     consts: Consts.T * Consts.T,                      (*local/global consts*)
   191     facts: Facts.T,                                   (*local facts*)
   192     cases: (string * (RuleCases.T * bool)) list};     (*named case contexts*)
   193 
   194 fun make_ctxt (mode, naming, syntax, consts, facts, cases) =
   195   Ctxt {mode = mode, naming = naming, syntax = syntax,
   196     consts = consts, facts = facts, cases = cases};
   197 
   198 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   199 
   200 structure ContextData = ProofDataFun
   201 (
   202   type T = ctxt;
   203   fun init thy =
   204     make_ctxt (mode_default, local_naming, LocalSyntax.init thy,
   205       (Sign.consts_of thy, Sign.consts_of thy), Facts.empty, []);
   206 );
   207 
   208 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   209 
   210 fun map_context f =
   211   ContextData.map (fn Ctxt {mode, naming, syntax, consts, facts, cases} =>
   212     make_ctxt (f (mode, naming, syntax, consts, facts, cases)));
   213 
   214 fun set_mode mode = map_context (fn (_, naming, syntax, consts, facts, cases) =>
   215   (mode, naming, syntax, consts, facts, cases));
   216 
   217 fun map_mode f =
   218   map_context (fn (Mode {stmt, pattern, schematic, abbrev}, naming, syntax, consts, facts, cases) =>
   219     (make_mode (f (stmt, pattern, schematic, abbrev)), naming, syntax, consts, facts, cases));
   220 
   221 fun map_naming f =
   222   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   223     (mode, f naming, syntax, consts, facts, cases));
   224 
   225 fun map_syntax f =
   226   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   227     (mode, naming, f syntax, consts, facts, cases));
   228 
   229 fun map_consts f =
   230   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   231     (mode, naming, syntax, f consts, facts, cases));
   232 
   233 fun map_facts f =
   234   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   235     (mode, naming, syntax, consts, f facts, cases));
   236 
   237 fun map_cases f =
   238   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   239     (mode, naming, syntax, consts, facts, f cases));
   240 
   241 val get_mode = #mode o rep_context;
   242 val restore_mode = set_mode o get_mode;
   243 val abbrev_mode = get_mode #> (fn Mode {abbrev, ...} => abbrev);
   244 
   245 fun set_stmt stmt =
   246   map_mode (fn (_, pattern, schematic, abbrev) => (stmt, pattern, schematic, abbrev));
   247 
   248 val naming_of = #naming o rep_context;
   249 
   250 val full_name = NameSpace.full_name o naming_of;
   251 fun full_bname thy = NameSpace.full_name (naming_of thy) o Binding.name;
   252 
   253 val syntax_of = #syntax o rep_context;
   254 val syn_of = LocalSyntax.syn_of o syntax_of;
   255 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   256 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   257 
   258 val consts_of = #1 o #consts o rep_context;
   259 val const_syntax_name = Consts.syntax_name o consts_of;
   260 val the_const_constraint = Consts.the_constraint o consts_of;
   261 
   262 fun mk_const ctxt (c, Ts) = Const (c, Consts.instance (consts_of ctxt) (c, Ts));
   263 
   264 val facts_of = #facts o rep_context;
   265 val cases_of = #cases o rep_context;
   266 
   267 
   268 (* theory transfer *)
   269 
   270 fun transfer_syntax thy =
   271   map_syntax (LocalSyntax.rebuild thy) #>
   272   map_consts (fn consts as (local_consts, global_consts) =>
   273     let val thy_consts = Sign.consts_of thy in
   274       if Consts.eq_consts (thy_consts, global_consts) then consts
   275       else (Consts.merge (local_consts, thy_consts), thy_consts)
   276     end);
   277 
   278 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   279 
   280 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   281 
   282 fun theory_result f ctxt =
   283   let val (res, thy') = f (theory_of ctxt)
   284   in (res, ctxt |> transfer thy') end;
   285 
   286 
   287 
   288 (** pretty printing **)
   289 
   290 (* extern *)
   291 
   292 fun extern_fact ctxt name =
   293   let
   294     val local_facts = facts_of ctxt;
   295     val global_facts = PureThy.facts_of (theory_of ctxt);
   296   in
   297     if is_some (Facts.lookup (Context.Proof ctxt) local_facts name)
   298     then Facts.extern local_facts name
   299     else Facts.extern global_facts name
   300   end;
   301 
   302 
   303 (* pretty *)
   304 
   305 fun pretty_term_abbrev ctxt = Syntax.pretty_term (set_mode mode_abbrev ctxt);
   306 
   307 fun pretty_thm_legacy th =
   308   let val thy = Thm.theory_of_thm th
   309   in Display.pretty_thm_aux (Syntax.pp_global thy) true false [] th end;
   310 
   311 fun pretty_thm ctxt th =
   312   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   313   in Display.pretty_thm_aux (Syntax.pp ctxt) false true asms th end;
   314 
   315 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   316   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   317 
   318 fun pretty_fact_name ctxt a = Pretty.block
   319   [Pretty.markup (Markup.fact a) [Pretty.str (extern_fact ctxt a)], Pretty.str ":"];
   320 
   321 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   322   | pretty_fact ctxt (a, [th]) = Pretty.block
   323       [pretty_fact_name ctxt a, Pretty.brk 1, pretty_thm ctxt th]
   324   | pretty_fact ctxt (a, ths) = Pretty.block
   325       (Pretty.fbreaks (pretty_fact_name ctxt a :: map (pretty_thm ctxt) ths));
   326 
   327 val string_of_thm = Pretty.string_of oo pretty_thm;
   328 
   329 
   330 
   331 (** prepare types **)
   332 
   333 (* read_typ *)
   334 
   335 fun read_typ_mode mode ctxt s =
   336   Syntax.read_typ (Type.set_mode mode ctxt) s;
   337 
   338 val read_typ        = read_typ_mode Type.mode_default;
   339 val read_typ_syntax = read_typ_mode Type.mode_syntax;
   340 val read_typ_abbrev = read_typ_mode Type.mode_abbrev;
   341 
   342 
   343 (* cert_typ *)
   344 
   345 fun cert_typ_mode mode ctxt T =
   346   Sign.certify_typ_mode mode (theory_of ctxt) T
   347     handle TYPE (msg, _, _) => error msg;
   348 
   349 val cert_typ        = cert_typ_mode Type.mode_default;
   350 val cert_typ_syntax = cert_typ_mode Type.mode_syntax;
   351 val cert_typ_abbrev = cert_typ_mode Type.mode_abbrev;
   352 
   353 
   354 
   355 (** prepare variables **)
   356 
   357 (* internalize Skolem constants *)
   358 
   359 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   360 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   361 
   362 fun no_skolem internal x =
   363   if can Name.dest_skolem x then
   364     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   365   else if not internal andalso can Name.dest_internal x then
   366     error ("Illegal reference to internal variable: " ^ quote x)
   367   else x;
   368 
   369 
   370 (* revert Skolem constants -- if possible *)
   371 
   372 fun revert_skolem ctxt x =
   373   (case find_first (fn (_, y) => y = x) (Variable.fixes_of ctxt) of
   374     SOME (x', _) => if lookup_skolem ctxt x' = SOME x then x' else x
   375   | NONE => x);
   376 
   377 
   378 (* default token translations *)
   379 
   380 local
   381 
   382 fun free_or_skolem ctxt x =
   383   (if can Name.dest_skolem x then Pretty.mark Markup.skolem (Pretty.str (revert_skolem ctxt x))
   384    else Pretty.mark Markup.free (Pretty.str x))
   385   |> Pretty.mark
   386     (if Variable.is_fixed ctxt x orelse Syntax.is_pretty_global ctxt then Markup.fixed x
   387      else Markup.hilite);
   388 
   389 fun var_or_skolem _ s =
   390   (case Lexicon.read_variable s of
   391     SOME (x, i) =>
   392       (case try Name.dest_skolem x of
   393         NONE => Pretty.mark Markup.var (Pretty.str s)
   394       | SOME x' => Pretty.mark Markup.skolem
   395           (Pretty.str (setmp show_question_marks true Term.string_of_vname (x', i))))
   396   | NONE => Pretty.mark Markup.var (Pretty.str s));
   397 
   398 fun class_markup _ c =    (* FIXME authentic name *)
   399   Pretty.mark (Markup.tclassN, []) (Pretty.str c);
   400 
   401 fun plain_markup m _ s = Pretty.mark m (Pretty.str s);
   402 
   403 val token_trans =
   404  Syntax.tokentrans_mode ""
   405   [("class", class_markup),
   406    ("tfree", plain_markup Markup.tfree),
   407    ("tvar", plain_markup Markup.tvar),
   408    ("free", free_or_skolem),
   409    ("bound", plain_markup Markup.bound),
   410    ("var", var_or_skolem),
   411    ("numeral", plain_markup Markup.numeral),
   412    ("inner_string", plain_markup Markup.inner_string)];
   413 
   414 in val _ = Context.>> (Context.map_theory (Sign.add_tokentrfuns token_trans)) end;
   415 
   416 
   417 
   418 (** prepare terms and propositions **)
   419 
   420 (* inferred types of parameters *)
   421 
   422 fun infer_type ctxt x =
   423   Term.fastype_of (singleton (Syntax.check_terms (set_mode mode_schematic ctxt))
   424     (Free (x, dummyT)));
   425 
   426 fun inferred_param x ctxt =
   427   let val T = infer_type ctxt x
   428   in (T, ctxt |> Variable.declare_term (Free (x, T))) end;
   429 
   430 fun inferred_fixes ctxt =
   431   let
   432     val xs = rev (map #2 (Variable.fixes_of ctxt));
   433     val (Ts, ctxt') = fold_map inferred_param xs ctxt;
   434   in (xs ~~ Ts, ctxt') end;
   435 
   436 
   437 (* type and constant names *)
   438 
   439 local
   440 
   441 val token_content = Syntax.read_token #>> SymbolPos.content;
   442 
   443 fun prep_const_proper ctxt (c, pos) =
   444   let val t as (Const (d, _)) =
   445     (case Variable.lookup_const ctxt c of
   446       SOME d => Const (d, Consts.type_scheme (consts_of ctxt) d handle TYPE (msg, _, _) => error msg)
   447     | NONE => Consts.read_const (consts_of ctxt) c)
   448   in Position.report (Markup.const d) pos; t end;
   449 
   450 in
   451 
   452 fun read_tyname ctxt str =
   453   let
   454     val thy = theory_of ctxt;
   455     val (c, pos) = token_content str;
   456   in
   457     if Syntax.is_tid c then
   458      (Position.report Markup.tfree pos;
   459       TFree (c, the_default (Sign.defaultS thy) (Variable.def_sort ctxt (c, ~1))))
   460     else
   461       let
   462         val d = Sign.intern_type thy c;
   463         val _ = Position.report (Markup.tycon d) pos;
   464       in Type (d, replicate (Sign.arity_number thy d) dummyT) end
   465   end;
   466 
   467 fun read_const_proper ctxt = prep_const_proper ctxt o token_content;
   468 
   469 fun read_const ctxt str =
   470   let val (c, pos) = token_content str in
   471     (case (lookup_skolem ctxt c, Variable.is_const ctxt c) of
   472       (SOME x, false) =>
   473         (Position.report (Markup.name x
   474             (if can Name.dest_skolem x then Markup.skolem else Markup.free)) pos;
   475           Free (x, infer_type ctxt x))
   476     | _ => prep_const_proper ctxt (c, pos))
   477   end;
   478 
   479 end;
   480 
   481 
   482 (* read_term *)
   483 
   484 fun read_term_mode mode ctxt = Syntax.read_term (set_mode mode ctxt);
   485 
   486 val read_term_pattern   = read_term_mode mode_pattern;
   487 val read_term_schematic = read_term_mode mode_schematic;
   488 val read_term_abbrev    = read_term_mode mode_abbrev;
   489 
   490 
   491 (* local abbreviations *)
   492 
   493 val tsig_of = Sign.tsig_of o ProofContext.theory_of;
   494 
   495 local
   496 
   497 fun certify_consts ctxt = Consts.certify (Syntax.pp ctxt) (tsig_of ctxt)
   498   (not (abbrev_mode ctxt)) (consts_of ctxt);
   499 
   500 fun reject_schematic (Var (xi, _)) =
   501       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   502   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   503   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   504   | reject_schematic _ = ();
   505 
   506 fun expand_binds ctxt =
   507   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   508     if pattern then I
   509     else Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic)
   510   end;
   511 
   512 in
   513 
   514 fun expand_abbrevs ctxt = certify_consts ctxt #> expand_binds ctxt;
   515 
   516 end;
   517 
   518 
   519 fun contract_abbrevs ctxt t =
   520   let
   521     val thy = theory_of ctxt;
   522     val consts = consts_of ctxt;
   523     val Mode {abbrev, ...} = get_mode ctxt;
   524   in
   525     if abbrev orelse print_mode_active "no_abbrevs" orelse not (can Term.type_of t) then t
   526     else t |> Pattern.rewrite_term thy (Consts.abbrevs_of consts (print_mode_value () @ [""])) []
   527   end;
   528 
   529 
   530 (* patterns *)
   531 
   532 fun prepare_patternT ctxt =
   533   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   534     if pattern orelse schematic then I
   535     else Term.map_atyps
   536       (fn T as TVar (xi, _) =>
   537             if not (TypeInfer.is_param xi)
   538             then error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   539             else T
   540         | T => T)
   541   end;
   542 
   543 
   544 local
   545 
   546 structure AllowDummies = ProofDataFun(type T = bool fun init _ = false);
   547 
   548 fun check_dummies ctxt t =
   549   if AllowDummies.get ctxt then t
   550   else Term.no_dummy_patterns t handle TERM _ => error "Illegal dummy pattern(s) in term";
   551 
   552 fun prepare_dummies ts = #1 (fold_map Term.replace_dummy_patterns ts 1);
   553 
   554 in
   555 
   556 val allow_dummies = AllowDummies.put true;
   557 
   558 fun prepare_patterns ctxt =
   559   let val Mode {pattern, ...} = get_mode ctxt in
   560     TypeInfer.fixate_params (Variable.names_of ctxt) #>
   561     pattern ? Variable.polymorphic ctxt #>
   562     (map o Term.map_types) (prepare_patternT ctxt) #>
   563     (if pattern then prepare_dummies else map (check_dummies ctxt))
   564   end;
   565 
   566 end;
   567 
   568 
   569 (* decoding raw terms (syntax trees) *)
   570 
   571 (* types *)
   572 
   573 fun get_sort thy def_sort raw_env =
   574   let
   575     val tsig = Sign.tsig_of thy;
   576 
   577     fun eq ((xi, S), (xi', S')) =
   578       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   579     val env = distinct eq raw_env;
   580     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   581       | dups => error ("Inconsistent sort constraints for type variable(s) "
   582           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   583 
   584     fun get xi =
   585       (case (AList.lookup (op =) env xi, def_sort xi) of
   586         (NONE, NONE) => Type.defaultS tsig
   587       | (NONE, SOME S) => S
   588       | (SOME S, NONE) => S
   589       | (SOME S, SOME S') =>
   590           if Type.eq_sort tsig (S, S') then S'
   591           else error ("Sort constraint inconsistent with default for type variable " ^
   592             quote (Term.string_of_vname' xi)));
   593   in get end;
   594 
   595 local
   596 
   597 fun intern_skolem ctxt def_type x =
   598   let
   599     val _ = no_skolem false x;
   600     val sko = lookup_skolem ctxt x;
   601     val is_const = can (read_const_proper ctxt) x orelse NameSpace.is_qualified x;
   602     val is_declared = is_some (def_type (x, ~1));
   603   in
   604     if Variable.is_const ctxt x then NONE
   605     else if is_some sko then sko
   606     else if not is_const orelse is_declared then SOME x
   607     else NONE
   608   end;
   609 
   610 in
   611 
   612 fun term_context ctxt =
   613   let val thy = theory_of ctxt in
   614    {get_sort = get_sort thy (Variable.def_sort ctxt),
   615     map_const = fn a => ((true, #1 (Term.dest_Const (read_const_proper ctxt a)))
   616       handle ERROR _ => (false, Consts.intern (consts_of ctxt) a)),
   617     map_free = intern_skolem ctxt (Variable.def_type ctxt false),
   618     map_type = Sign.intern_tycons thy,
   619     map_sort = Sign.intern_sort thy}
   620   end;
   621 
   622 fun decode_term ctxt =
   623   let val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt
   624   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   625 
   626 end;
   627 
   628 
   629 (* certify terms *)
   630 
   631 local
   632 
   633 fun gen_cert prop ctxt t =
   634   t
   635   |> expand_abbrevs ctxt
   636   |> (fn t' => #1 (Sign.certify' prop (Syntax.pp ctxt) false (consts_of ctxt) (theory_of ctxt) t')
   637     handle TYPE (msg, _, _) => error msg
   638       | TERM (msg, _) => error msg);
   639 
   640 in
   641 
   642 val cert_term = gen_cert false;
   643 val cert_prop = gen_cert true;
   644 
   645 end;
   646 
   647 
   648 (* type checking/inference *)
   649 
   650 fun standard_infer_types ctxt ts =
   651   let val Mode {pattern, ...} = get_mode ctxt in
   652     TypeInfer.infer_types (Syntax.pp ctxt) (tsig_of ctxt) (Syntax.check_typs ctxt)
   653       (try (Consts.the_constraint (consts_of ctxt))) (Variable.def_type ctxt pattern)
   654       (Variable.names_of ctxt) (Variable.maxidx_of ctxt) ts
   655     handle TYPE (msg, _, _) => error msg
   656   end;
   657 
   658 local
   659 
   660 fun standard_typ_check ctxt =
   661   map (cert_typ_mode (Type.get_mode ctxt) ctxt) #>
   662   map (prepare_patternT ctxt);
   663 
   664 fun standard_term_check ctxt =
   665   standard_infer_types ctxt #>
   666   map (expand_abbrevs ctxt);
   667 
   668 fun standard_term_uncheck ctxt =
   669   map (contract_abbrevs ctxt);
   670 
   671 fun add eq what f = Context.>> (what (fn xs => fn ctxt =>
   672   let val xs' = f ctxt xs in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end));
   673 
   674 in
   675 
   676 val _ = add (op =) (Syntax.add_typ_check 0 "standard") standard_typ_check;
   677 val _ = add (op aconv) (Syntax.add_term_check 0 "standard") standard_term_check;
   678 val _ = add (op aconv) (Syntax.add_term_check 100 "fixate") prepare_patterns;
   679 
   680 val _ = add (op aconv) (Syntax.add_term_uncheck 0 "standard") standard_term_uncheck;
   681 
   682 end;
   683 
   684 
   685 
   686 (** inner syntax operations **)
   687 
   688 local
   689 
   690 fun parse_sort ctxt text =
   691   let
   692     val (syms, pos) = Syntax.parse_token Markup.sort text;
   693     val S = Syntax.standard_parse_sort ctxt (syn_of ctxt)
   694         (Sign.intern_sort (theory_of ctxt)) (syms, pos)
   695       handle ERROR msg => cat_error msg  ("Failed to parse sort" ^ Position.str_of pos)
   696   in S end;
   697 
   698 fun parse_typ ctxt text =
   699   let
   700     val thy = ProofContext.theory_of ctxt;
   701     val get_sort = get_sort thy (Variable.def_sort ctxt);
   702 
   703     val (syms, pos) = Syntax.parse_token Markup.typ text;
   704     val T = Sign.intern_tycons thy
   705         (Syntax.standard_parse_typ ctxt (syn_of ctxt) get_sort (Sign.intern_sort thy) (syms, pos))
   706       handle ERROR msg => cat_error msg  ("Failed to parse type" ^ Position.str_of pos);
   707   in T end;
   708 
   709 fun parse_term T ctxt text =
   710   let
   711     val thy = theory_of ctxt;
   712     val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt;
   713 
   714     val (T', _) = TypeInfer.paramify_dummies T 0;
   715     val (markup, kind) = if T' = propT then (Markup.prop, "proposition") else (Markup.term, "term");
   716     val (syms, pos) = Syntax.parse_token markup text;
   717 
   718     fun check t = (Syntax.check_term ctxt (TypeInfer.constrain T' t); NONE)
   719       handle ERROR msg => SOME msg;
   720     val t = Syntax.standard_parse_term (Syntax.pp ctxt) check get_sort map_const map_free
   721         map_type map_sort ctxt (Sign.is_logtype thy) (syn_of ctxt) T' (syms, pos)
   722       handle ERROR msg => cat_error msg  ("Failed to parse " ^ kind ^ Position.str_of pos);
   723   in t end;
   724 
   725 
   726 fun unparse_sort ctxt S =
   727   Syntax.standard_unparse_sort ctxt (syn_of ctxt) (Sign.extern_sort (theory_of ctxt) S);
   728 
   729 fun unparse_typ ctxt T =
   730   Syntax.standard_unparse_typ ctxt (syn_of ctxt) (Sign.extern_typ (theory_of ctxt) T);
   731 
   732 fun unparse_term ctxt t =
   733   let
   734     val thy = theory_of ctxt;
   735     val syntax = syntax_of ctxt;
   736     val consts = consts_of ctxt;
   737   in
   738     t
   739     |> Sign.extern_term (Consts.extern_early consts) thy
   740     |> LocalSyntax.extern_term syntax
   741     |> Syntax.standard_unparse_term (Consts.extern consts) ctxt (LocalSyntax.syn_of syntax)
   742         (not (PureThy.old_appl_syntax thy))
   743   end;
   744 
   745 in
   746 
   747 val _ = Syntax.install_operations
   748   {parse_sort = parse_sort,
   749    parse_typ = parse_typ,
   750    parse_term = parse_term dummyT,
   751    parse_prop = parse_term propT,
   752    unparse_sort = unparse_sort,
   753    unparse_typ = unparse_typ,
   754    unparse_term = unparse_term};
   755 
   756 end;
   757 
   758 
   759 
   760 (** export results **)
   761 
   762 fun common_export is_goal inner outer =
   763   map (Assumption.export is_goal inner outer) #>
   764   Variable.export inner outer;
   765 
   766 val goal_export = common_export true;
   767 val export = common_export false;
   768 
   769 fun export_morphism inner outer =
   770   Assumption.export_morphism inner outer $>
   771   Variable.export_morphism inner outer;
   772 
   773 fun norm_export_morphism inner outer =
   774   export_morphism inner outer $>
   775   Morphism.thm_morphism Goal.norm_result;
   776 
   777 
   778 
   779 (** bindings **)
   780 
   781 (* simult_matches *)
   782 
   783 fun simult_matches ctxt (t, pats) =
   784   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   785     NONE => error "Pattern match failed!"
   786   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   787 
   788 
   789 (* add_binds(_i) *)
   790 
   791 local
   792 
   793 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   794   ctxt
   795   |> Variable.add_binds [(xi, Option.map (prep (set_mode mode_default ctxt)) raw_t)];
   796 
   797 in
   798 
   799 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   800   | drop_schematic b = b;
   801 
   802 val add_binds = fold (gen_bind Syntax.read_term);
   803 val add_binds_i = fold (gen_bind cert_term);
   804 
   805 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   806 val auto_bind_goal = auto_bind AutoBind.goal;
   807 val auto_bind_facts = auto_bind AutoBind.facts;
   808 
   809 end;
   810 
   811 
   812 (* match_bind(_i) *)
   813 
   814 local
   815 
   816 fun gen_bind prep_terms gen raw_binds ctxt =
   817   let
   818     fun prep_bind (raw_pats, t) ctxt1 =
   819       let
   820         val T = Term.fastype_of t;
   821         val ctxt2 = Variable.declare_term t ctxt1;
   822         val pats = prep_terms (set_mode mode_pattern ctxt2) T raw_pats;
   823         val binds = simult_matches ctxt2 (t, pats);
   824       in (binds, ctxt2) end;
   825 
   826     val ts = prep_terms ctxt dummyT (map snd raw_binds);
   827     val (binds, ctxt') = apfst flat (fold_map prep_bind (map fst raw_binds ~~ ts) ctxt);
   828     val binds' =
   829       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   830       else binds;
   831     val binds'' = map (apsnd SOME) binds';
   832     val ctxt'' =
   833       tap (Variable.warn_extra_tfrees ctxt)
   834        (if gen then
   835           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   836         else ctxt' |> add_binds_i binds'');
   837   in (ts, ctxt'') end;
   838 
   839 in
   840 
   841 fun read_terms ctxt T =
   842   map (Syntax.parse_term ctxt #> TypeInfer.constrain T) #> Syntax.check_terms ctxt;
   843 
   844 val match_bind = gen_bind read_terms;
   845 val match_bind_i = gen_bind (fn ctxt => fn _ => map (cert_term ctxt));
   846 
   847 end;
   848 
   849 
   850 (* propositions with patterns *)
   851 
   852 local
   853 
   854 fun prep_propp mode prep_props (context, args) =
   855   let
   856     fun prep (_, raw_pats) (ctxt, prop :: props) =
   857       let val ctxt' = Variable.declare_term prop ctxt
   858       in ((prop, prep_props (set_mode mode_pattern ctxt') raw_pats), (ctxt', props)) end;
   859 
   860     val (propp, (context', _)) = (fold_map o fold_map) prep args
   861       (context, prep_props (set_mode mode context) (maps (map fst) args));
   862   in (context', propp) end;
   863 
   864 fun gen_bind_propp mode parse_prop (ctxt, raw_args) =
   865   let
   866     val (ctxt', args) = prep_propp mode parse_prop (ctxt, raw_args);
   867     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   868     val propss = map (map #1) args;
   869 
   870     (*generalize result: context evaluated now, binds added later*)
   871     val gen = Variable.exportT_terms ctxt' ctxt;
   872     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   873   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   874 
   875 in
   876 
   877 val read_propp           = prep_propp mode_default Syntax.read_props;
   878 val cert_propp           = prep_propp mode_default (map o cert_prop);
   879 val read_propp_schematic = prep_propp mode_schematic Syntax.read_props;
   880 val cert_propp_schematic = prep_propp mode_schematic (map o cert_prop);
   881 
   882 val bind_propp             = gen_bind_propp mode_default Syntax.read_props;
   883 val bind_propp_i           = gen_bind_propp mode_default (map o cert_prop);
   884 val bind_propp_schematic   = gen_bind_propp mode_schematic Syntax.read_props;
   885 val bind_propp_schematic_i = gen_bind_propp mode_schematic (map o cert_prop);
   886 
   887 end;
   888 
   889 
   890 
   891 (** theorems **)
   892 
   893 (* fact_tac *)
   894 
   895 fun comp_incr_tac [] _ = no_tac
   896   | comp_incr_tac (th :: ths) i =
   897       (fn st => Goal.compose_hhf_tac (Drule.incr_indexes st th) i st) APPEND comp_incr_tac ths i;
   898 
   899 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   900 
   901 fun potential_facts ctxt prop =
   902   Facts.could_unify (facts_of ctxt) (Term.strip_all_body prop);
   903 
   904 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) => fact_tac (potential_facts ctxt goal) i);
   905 
   906 
   907 (* get_thm(s) *)
   908 
   909 local
   910 
   911 fun retrieve_thms pick ctxt (Facts.Fact s) =
   912       let
   913         val (_, pos) = Syntax.read_token s;
   914         val prop = Syntax.read_prop (set_mode mode_default ctxt) s
   915           |> singleton (Variable.polymorphic ctxt);
   916 
   917         fun prove_fact th =
   918           Goal.prove ctxt [] [] prop (K (ALLGOALS (fact_tac [th])))
   919           |> Thm.default_position_of th;
   920         val res =
   921           (case get_first (try prove_fact) (potential_facts ctxt prop) of
   922             SOME res => res
   923           | NONE => error ("Failed to retrieve literal fact" ^ Position.str_of pos ^ ":\n" ^
   924               Syntax.string_of_term ctxt prop))
   925       in pick "" [res] end
   926   | retrieve_thms pick ctxt xthmref =
   927       let
   928         val thy = theory_of ctxt;
   929         val local_facts = facts_of ctxt;
   930         val thmref = Facts.map_name_of_ref (Facts.intern local_facts) xthmref;
   931         val name = Facts.name_of_ref thmref;
   932         val pos = Facts.pos_of_ref xthmref;
   933         val thms =
   934           if name = "" then [Thm.transfer thy Drule.dummy_thm]
   935           else
   936             (case Facts.lookup (Context.Proof ctxt) local_facts name of
   937               SOME (_, ths) => (Position.report (Markup.local_fact name) pos;
   938                 map (Thm.transfer thy) (Facts.select thmref ths))
   939             | NONE => PureThy.get_fact (Context.Proof ctxt) thy xthmref);
   940       in pick name thms end;
   941 
   942 in
   943 
   944 val get_fact = retrieve_thms (K I);
   945 val get_fact_single = retrieve_thms Facts.the_single;
   946 
   947 fun get_thms ctxt = get_fact ctxt o Facts.named;
   948 fun get_thm ctxt = get_fact_single ctxt o Facts.named;
   949 
   950 end;
   951 
   952 
   953 (* name space operations *)
   954 
   955 val add_path        = map_naming o NameSpace.add_path;
   956 val no_base_names   = map_naming NameSpace.no_base_names;
   957 val qualified_names = map_naming NameSpace.qualified_names;
   958 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   959 val restore_naming  = map_naming o K o naming_of;
   960 val reset_naming    = map_naming (K local_naming);
   961 
   962 
   963 (* facts *)
   964 
   965 local
   966 
   967 fun update_thms _ (b, NONE) ctxt = ctxt |> map_facts (Facts.del (full_name ctxt b))
   968   | update_thms do_props (b, SOME ths) ctxt = ctxt |> map_facts
   969       (Facts.add_local do_props (naming_of ctxt) (b, ths) #> snd);
   970 
   971 fun gen_note_thmss get k = fold_map (fn ((b, more_attrs), raw_facts) => fn ctxt =>
   972   let
   973     val pos = Binding.pos_of b;
   974     val name = full_name ctxt b;
   975     val _ = ContextPosition.report_visible ctxt (Markup.local_fact_decl name) pos;
   976 
   977     val facts = PureThy.name_thmss false pos name (map (apfst (get ctxt)) raw_facts);
   978     fun app (th, attrs) x =
   979       swap (foldl_map (Thm.proof_attributes (surround (Thm.kind k) (attrs @ more_attrs))) (x, th));
   980     val (res, ctxt') = fold_map app facts ctxt;
   981     val thms = PureThy.name_thms false false pos name (flat res);
   982     val Mode {stmt, ...} = get_mode ctxt;
   983   in ((name, thms), ctxt' |> update_thms stmt (b, SOME thms)) end);
   984 
   985 in
   986 
   987 fun note_thmss k = gen_note_thmss get_fact k;
   988 fun note_thmss_i k = gen_note_thmss (K I) k;
   989 
   990 fun put_thms do_props thms ctxt = ctxt
   991   |> map_naming (K local_naming)
   992   |> ContextPosition.set_visible false
   993   |> update_thms do_props (apfst Binding.name thms)
   994   |> ContextPosition.restore_visible ctxt
   995   |> restore_naming ctxt;
   996 
   997 end;
   998 
   999 
  1000 
  1001 (** parameters **)
  1002 
  1003 (* variables *)
  1004 
  1005 fun declare_var (x, opt_T, mx) ctxt =
  1006   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
  1007   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
  1008 
  1009 local
  1010 
  1011 fun prep_vars prep_typ internal =
  1012   fold_map (fn (raw_b, raw_T, raw_mx) => fn ctxt =>
  1013     let
  1014       val raw_x = Binding.base_name raw_b;
  1015       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
  1016       val _ = Syntax.is_identifier (no_skolem internal x) orelse
  1017         error ("Illegal variable name: " ^ quote x);
  1018 
  1019       fun cond_tvars T =
  1020         if internal then T
  1021         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
  1022       val opt_T = Option.map (cond_tvars o cert_typ ctxt o prep_typ ctxt) raw_T;
  1023       val var = (Binding.map_base (K x) raw_b, opt_T, mx);
  1024     in (var, ctxt |> declare_var (x, opt_T, mx) |> #2) end);
  1025 
  1026 in
  1027 
  1028 val read_vars = prep_vars Syntax.parse_typ false;
  1029 val cert_vars = prep_vars (K I) true;
  1030 
  1031 end;
  1032 
  1033 
  1034 (* authentic constants *)
  1035 
  1036 local
  1037 
  1038 fun const_ast_tr intern ctxt [Syntax.Variable c] =
  1039       let
  1040         val Const (c', _) = read_const_proper ctxt c;
  1041         val d = if intern then const_syntax_name ctxt c' else c;
  1042       in Syntax.Constant d end
  1043   | const_ast_tr _ _ asts = raise Syntax.AST ("const_ast_tr", asts);
  1044 
  1045 in
  1046 
  1047 val _ = Context.>> (Context.map_theory
  1048  (Sign.add_syntax
  1049    [("_context_const", "id => logic", Delimfix "CONST _"),
  1050     ("_context_const", "id => aprop", Delimfix "CONST _"),
  1051     ("_context_const", "longid => logic", Delimfix "CONST _"),
  1052     ("_context_const", "longid => aprop", Delimfix "CONST _"),
  1053     ("_context_xconst", "id => logic", Delimfix "XCONST _"),
  1054     ("_context_xconst", "id => aprop", Delimfix "XCONST _"),
  1055     ("_context_xconst", "longid => logic", Delimfix "XCONST _"),
  1056     ("_context_xconst", "longid => aprop", Delimfix "XCONST _")] #>
  1057   Sign.add_advanced_trfuns
  1058     ([("_context_const", const_ast_tr true), ("_context_xconst", const_ast_tr false)], [], [], [])));
  1059 
  1060 end;
  1061 
  1062 
  1063 (* notation *)
  1064 
  1065 local
  1066 
  1067 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
  1068   | const_syntax ctxt (Const (c, _), mx) =
  1069       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
  1070   | const_syntax _ _ = NONE;
  1071 
  1072 in
  1073 
  1074 fun notation add mode args ctxt =
  1075   ctxt |> map_syntax
  1076     (LocalSyntax.update_modesyntax (theory_of ctxt) add mode (map_filter (const_syntax ctxt) args));
  1077 
  1078 fun target_notation add mode args phi =
  1079   let val args' = filter (fn (t, _) => Type.similar_types (t, Morphism.term phi t)) args;
  1080   in Context.mapping (Sign.notation add mode args') (notation add mode args') end;
  1081 
  1082 end;
  1083 
  1084 
  1085 (* local constants *)
  1086 
  1087 fun add_const_constraint (c, opt_T) ctxt =
  1088   let
  1089     fun prepT raw_T =
  1090       let val T = cert_typ ctxt raw_T
  1091       in cert_term ctxt (Const (c, T)); T end;
  1092   in ctxt |> (map_consts o apfst) (Consts.constrain (c, Option.map prepT opt_T)) end;
  1093 
  1094 fun add_abbrev mode tags (b, raw_t) ctxt =
  1095   let
  1096     val t0 = cert_term (ctxt |> set_mode mode_abbrev) raw_t
  1097       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.display b));
  1098     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
  1099     val ((lhs, rhs), consts') = consts_of ctxt
  1100       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode tags (b, t);
  1101   in
  1102     ctxt
  1103     |> (map_consts o apfst) (K consts')
  1104     |> Variable.declare_term rhs
  1105     |> pair (lhs, rhs)
  1106   end;
  1107 
  1108 fun revert_abbrev mode c = (map_consts o apfst) (Consts.revert_abbrev mode c);
  1109 
  1110 
  1111 (* fixes *)
  1112 
  1113 local
  1114 
  1115 fun prep_mixfix (x, T, mx) =
  1116   if mx <> NoSyn andalso mx <> Structure andalso
  1117       (can Name.dest_internal x orelse can Name.dest_skolem x) then
  1118     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
  1119   else (true, (x, T, mx));
  1120 
  1121 fun gen_fixes prep raw_vars ctxt =
  1122   let
  1123     val (vars, _) = prep raw_vars ctxt;
  1124     val (xs', ctxt') = Variable.add_fixes (map (Binding.base_name o #1) vars) ctxt;
  1125     val ctxt'' =
  1126       ctxt'
  1127       |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
  1128       |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix);
  1129     val _ = (vars ~~ xs') |> List.app (fn ((b, _, _), x') =>
  1130       ContextPosition.report_visible ctxt (Markup.fixed_decl x') (Binding.pos_of b));
  1131   in (xs', ctxt'') end;
  1132 
  1133 in
  1134 
  1135 val add_fixes = gen_fixes read_vars;
  1136 val add_fixes_i = gen_fixes cert_vars;
  1137 
  1138 end;
  1139 
  1140 
  1141 (* fixes vs. frees *)
  1142 
  1143 fun auto_fixes (arg as (ctxt, (propss, x))) =
  1144   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
  1145 
  1146 fun bind_fixes xs ctxt =
  1147   let
  1148     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (Binding.name x, NONE, NoSyn)) xs);
  1149     fun bind (t as Free (x, T)) =
  1150           if member (op =) xs x then
  1151             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1152           else t
  1153       | bind (t $ u) = bind t $ bind u
  1154       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1155       | bind a = a;
  1156   in (bind, ctxt') end;
  1157 
  1158 
  1159 
  1160 (** assumptions **)
  1161 
  1162 local
  1163 
  1164 fun gen_assms prepp exp args ctxt =
  1165   let
  1166     val cert = Thm.cterm_of (theory_of ctxt);
  1167     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1168     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1169     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1170   in
  1171     ctxt2
  1172     |> auto_bind_facts (flat propss)
  1173     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1174   end;
  1175 
  1176 in
  1177 
  1178 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1179 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1180 
  1181 end;
  1182 
  1183 
  1184 
  1185 (** cases **)
  1186 
  1187 local
  1188 
  1189 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1190 
  1191 fun add_case _ ("", _) cases = cases
  1192   | add_case _ (name, NONE) cases = rem_case name cases
  1193   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1194 
  1195 fun prep_case name fxs c =
  1196   let
  1197     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1198       | replace [] ys = ys
  1199       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1200     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1201     val fixes' = replace fxs fixes;
  1202     val binds' = map drop_schematic binds;
  1203   in
  1204     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1205       null (fold (fold Term.add_vars o snd) assumes []) then
  1206         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1207     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1208   end;
  1209 
  1210 fun fix (x, T) ctxt =
  1211   let
  1212     val (bind, ctxt') = bind_fixes [x] ctxt;
  1213     val t = bind (Free (x, T));
  1214   in (t, ctxt' |> Variable.declare_constraints t) end;
  1215 
  1216 in
  1217 
  1218 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1219 
  1220 fun case_result c ctxt =
  1221   let
  1222     val RuleCases.Case {fixes, ...} = c;
  1223     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1224     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1225   in
  1226     ctxt'
  1227     |> add_binds_i (map drop_schematic binds)
  1228     |> add_cases true (map (apsnd SOME) cases)
  1229     |> pair (assumes, (binds, cases))
  1230   end;
  1231 
  1232 val apply_case = apfst fst oo case_result;
  1233 
  1234 fun get_case ctxt name xs =
  1235   (case AList.lookup (op =) (cases_of ctxt) name of
  1236     NONE => error ("Unknown case: " ^ quote name)
  1237   | SOME (c, _) => prep_case name xs c);
  1238 
  1239 end;
  1240 
  1241 
  1242 
  1243 (** print context information **)
  1244 
  1245 val debug = ref false;
  1246 
  1247 val verbose = ref false;
  1248 fun verb f x = if ! verbose then f (x ()) else [];
  1249 
  1250 fun setmp_verbose f x = Library.setmp verbose true f x;
  1251 
  1252 
  1253 (* local syntax *)
  1254 
  1255 val print_syntax = Syntax.print_syntax o syn_of;
  1256 
  1257 
  1258 (* abbreviations *)
  1259 
  1260 fun pretty_abbrevs show_globals ctxt =
  1261   let
  1262     val ((space, consts), (_, globals)) =
  1263       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1264     fun add_abbr (_, (_, NONE)) = I
  1265       | add_abbr (c, (T, SOME t)) =
  1266           if not show_globals andalso Symtab.defined globals c then I
  1267           else cons (c, Logic.mk_equals (Const (c, T), t));
  1268     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1269   in
  1270     if null abbrevs andalso not (! verbose) then []
  1271     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1272   end;
  1273 
  1274 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1275 
  1276 
  1277 (* term bindings *)
  1278 
  1279 fun pretty_binds ctxt =
  1280   let
  1281     val binds = Variable.binds_of ctxt;
  1282     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1283   in
  1284     if Vartab.is_empty binds andalso not (! verbose) then []
  1285     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1286   end;
  1287 
  1288 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1289 
  1290 
  1291 (* local theorems *)
  1292 
  1293 fun pretty_lthms ctxt =
  1294   let
  1295     val local_facts = facts_of ctxt;
  1296     val props = Facts.props local_facts;
  1297     val facts =
  1298       (if null props then [] else [("unnamed", props)]) @
  1299       Facts.dest_static [] local_facts;
  1300   in
  1301     if null facts andalso not (! verbose) then []
  1302     else [Pretty.big_list "facts:" (map #1 (sort_wrt (#1 o #2) (map (`(pretty_fact ctxt)) facts)))]
  1303   end;
  1304 
  1305 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1306 
  1307 
  1308 (* local contexts *)
  1309 
  1310 local
  1311 
  1312 fun pretty_case (name, (fixes, ((asms, (lets, cs)), ctxt))) =
  1313   let
  1314     val prt_term = Syntax.pretty_term ctxt;
  1315 
  1316     fun prt_let (xi, t) = Pretty.block
  1317       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1318         Pretty.quote (prt_term t)];
  1319 
  1320     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1321       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1322 
  1323     fun prt_sect _ _ _ [] = []
  1324       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1325             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1326   in
  1327     Pretty.block (Pretty.fbreaks
  1328       (Pretty.str (name ^ ":") ::
  1329         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1330         prt_sect "let" [Pretty.str "and"] prt_let
  1331           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1332         (if forall (null o #2) asms then []
  1333           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1334         prt_sect "subcases:" [] (Pretty.str o fst) cs))
  1335   end;
  1336 
  1337 in
  1338 
  1339 fun pretty_cases ctxt =
  1340   let
  1341     fun add_case (_, (_, false)) = I
  1342       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1343           cons (name, (fixes, case_result c ctxt));
  1344     val cases = fold add_case (cases_of ctxt) [];
  1345   in
  1346     if null cases andalso not (! verbose) then []
  1347     else [Pretty.big_list "cases:" (map pretty_case cases)]
  1348   end;
  1349 
  1350 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1351 
  1352 end;
  1353 
  1354 
  1355 (* core context *)
  1356 
  1357 val prems_limit = ref ~1;
  1358 
  1359 fun pretty_ctxt ctxt =
  1360   if ! prems_limit < 0 andalso not (! debug) then []
  1361   else
  1362     let
  1363       val prt_term = Syntax.pretty_term ctxt;
  1364 
  1365       (*structures*)
  1366       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1367       val prt_structs = if null structs then []
  1368         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1369           Pretty.commas (map Pretty.str structs))];
  1370 
  1371       (*fixes*)
  1372       fun prt_fix (x, x') =
  1373         if x = x' then Pretty.str x
  1374         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1375       val fixes =
  1376         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1377           (Variable.fixes_of ctxt));
  1378       val prt_fixes = if null fixes then []
  1379         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1380           Pretty.commas (map prt_fix fixes))];
  1381 
  1382       (*prems*)
  1383       val prems = Assumption.prems_of ctxt;
  1384       val len = length prems;
  1385       val suppressed = len - ! prems_limit;
  1386       val prt_prems = if null prems then []
  1387         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1388           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1389     in prt_structs @ prt_fixes @ prt_prems end;
  1390 
  1391 
  1392 (* main context *)
  1393 
  1394 fun pretty_context ctxt =
  1395   let
  1396     val prt_term = Syntax.pretty_term ctxt;
  1397     val prt_typ = Syntax.pretty_typ ctxt;
  1398     val prt_sort = Syntax.pretty_sort ctxt;
  1399 
  1400     (*theory*)
  1401     val pretty_thy = Pretty.block
  1402       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1403 
  1404     (*defaults*)
  1405     fun prt_atom prt prtT (x, X) = Pretty.block
  1406       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1407 
  1408     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1409       | prt_var xi = prt_term (Syntax.var xi);
  1410 
  1411     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1412       | prt_varT xi = prt_typ (TVar (xi, []));
  1413 
  1414     val prt_defT = prt_atom prt_var prt_typ;
  1415     val prt_defS = prt_atom prt_varT prt_sort;
  1416 
  1417     val (types, sorts) = Variable.constraints_of ctxt;
  1418   in
  1419     verb single (K pretty_thy) @
  1420     pretty_ctxt ctxt @
  1421     verb (pretty_abbrevs false) (K ctxt) @
  1422     verb pretty_binds (K ctxt) @
  1423     verb pretty_lthms (K ctxt) @
  1424     verb pretty_cases (K ctxt) @
  1425     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1426     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1427   end;
  1428 
  1429 
  1430 (* query meta data *)
  1431 
  1432 val query_type = Type.the_tags o tsig_of;
  1433 
  1434 fun query_const ctxt name =
  1435   Consts.the_tags (consts_of ctxt) name handle TYPE (msg, _, _) => error msg;
  1436 
  1437 fun query_class ctxt name = query_const ctxt (Logic.const_of_class name);
  1438 
  1439 end;