src/ZF/CardinalArith.ML
author paulson
Wed Dec 24 10:02:30 1997 +0100 (1997-12-24 ago)
changeset 4477 b3e5857d8d99
parent 4312 63844406913c
child 5067 62b6288e6005
permissions -rw-r--r--
New Auto_tac (by Oheimb), and new syntax (without parens), and expandshort
     1 (*  Title:      ZF/CardinalArith.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1994  University of Cambridge
     5 
     6 Cardinal arithmetic -- WITHOUT the Axiom of Choice
     7 
     8 Note: Could omit proving the algebraic laws for cardinal addition and
     9 multiplication.  On finite cardinals these operations coincide with
    10 addition and multiplication of natural numbers; on infinite cardinals they
    11 coincide with union (maximum).  Either way we get most laws for free.
    12 *)
    13 
    14 open CardinalArith;
    15 
    16 (*** Cardinal addition ***)
    17 
    18 (** Cardinal addition is commutative **)
    19 
    20 goalw CardinalArith.thy [eqpoll_def] "A+B eqpoll B+A";
    21 by (rtac exI 1);
    22 by (res_inst_tac [("c", "case(Inr, Inl)"), ("d", "case(Inr, Inl)")] 
    23     lam_bijective 1);
    24 by (safe_tac (claset() addSEs [sumE]));
    25 by (ALLGOALS (Asm_simp_tac));
    26 qed "sum_commute_eqpoll";
    27 
    28 goalw CardinalArith.thy [cadd_def] "i |+| j = j |+| i";
    29 by (rtac (sum_commute_eqpoll RS cardinal_cong) 1);
    30 qed "cadd_commute";
    31 
    32 (** Cardinal addition is associative **)
    33 
    34 goalw CardinalArith.thy [eqpoll_def] "(A+B)+C eqpoll A+(B+C)";
    35 by (rtac exI 1);
    36 by (rtac sum_assoc_bij 1);
    37 qed "sum_assoc_eqpoll";
    38 
    39 (*Unconditional version requires AC*)
    40 goalw CardinalArith.thy [cadd_def]
    41     "!!i j k. [| well_ord(i,ri); well_ord(j,rj); well_ord(k,rk) |] ==>  \
    42 \             (i |+| j) |+| k = i |+| (j |+| k)";
    43 by (rtac cardinal_cong 1);
    44 by (rtac ([well_ord_cardinal_eqpoll, eqpoll_refl] MRS sum_eqpoll_cong RS
    45           eqpoll_trans) 1);
    46 by (rtac (sum_assoc_eqpoll RS eqpoll_trans) 2);
    47 by (rtac ([eqpoll_refl, well_ord_cardinal_eqpoll] MRS sum_eqpoll_cong RS
    48           eqpoll_sym) 2);
    49 by (REPEAT (ares_tac [well_ord_radd] 1));
    50 qed "well_ord_cadd_assoc";
    51 
    52 (** 0 is the identity for addition **)
    53 
    54 goalw CardinalArith.thy [eqpoll_def] "0+A eqpoll A";
    55 by (rtac exI 1);
    56 by (rtac bij_0_sum 1);
    57 qed "sum_0_eqpoll";
    58 
    59 goalw CardinalArith.thy [cadd_def] "!!K. Card(K) ==> 0 |+| K = K";
    60 by (asm_simp_tac (simpset() addsimps [sum_0_eqpoll RS cardinal_cong, 
    61 				      Card_cardinal_eq]) 1);
    62 qed "cadd_0";
    63 
    64 (** Addition by another cardinal **)
    65 
    66 goalw CardinalArith.thy [lepoll_def, inj_def] "A lepoll A+B";
    67 by (res_inst_tac [("x", "lam x:A. Inl(x)")] exI 1);
    68 by (asm_simp_tac (simpset() addsimps [lam_type]) 1);
    69 qed "sum_lepoll_self";
    70 
    71 (*Could probably weaken the premises to well_ord(K,r), or removing using AC*)
    72 goalw CardinalArith.thy [cadd_def]
    73     "!!K. [| Card(K);  Ord(L) |] ==> K le (K |+| L)";
    74 by (rtac ([Card_cardinal_le, well_ord_lepoll_imp_Card_le] MRS le_trans) 1);
    75 by (rtac sum_lepoll_self 3);
    76 by (REPEAT (ares_tac [well_ord_radd, well_ord_Memrel, Card_is_Ord] 1));
    77 qed "cadd_le_self";
    78 
    79 (** Monotonicity of addition **)
    80 
    81 goalw CardinalArith.thy [lepoll_def]
    82      "!!A B C D. [| A lepoll C;  B lepoll D |] ==> A + B  lepoll  C + D";
    83 by (REPEAT (etac exE 1));
    84 by (res_inst_tac [("x", "lam z:A+B. case(%w. Inl(f`w), %y. Inr(fa`y), z)")] 
    85     exI 1);
    86 by (res_inst_tac 
    87       [("d", "case(%w. Inl(converse(f)`w), %y. Inr(converse(fa)`y))")] 
    88       lam_injective 1);
    89 by (typechk_tac ([inj_is_fun, case_type, InlI, InrI] @ ZF_typechecks));
    90 by (etac sumE 1);
    91 by (ALLGOALS (asm_simp_tac (simpset() addsimps [left_inverse])));
    92 qed "sum_lepoll_mono";
    93 
    94 goalw CardinalArith.thy [cadd_def]
    95     "!!K. [| K' le K;  L' le L |] ==> (K' |+| L') le (K |+| L)";
    96 by (safe_tac (claset() addSDs [le_subset_iff RS iffD1]));
    97 by (rtac well_ord_lepoll_imp_Card_le 1);
    98 by (REPEAT (ares_tac [sum_lepoll_mono, subset_imp_lepoll] 2));
    99 by (REPEAT (ares_tac [well_ord_radd, well_ord_Memrel] 1));
   100 qed "cadd_le_mono";
   101 
   102 (** Addition of finite cardinals is "ordinary" addition **)
   103 
   104 goalw CardinalArith.thy [eqpoll_def] "succ(A)+B eqpoll succ(A+B)";
   105 by (rtac exI 1);
   106 by (res_inst_tac [("c", "%z. if(z=Inl(A),A+B,z)"), 
   107                   ("d", "%z. if(z=A+B,Inl(A),z)")] 
   108     lam_bijective 1);
   109 by (ALLGOALS
   110     (asm_simp_tac (simpset() addsimps [succI2, mem_imp_not_eq]
   111                              setloop eresolve_tac [sumE,succE])));
   112 qed "sum_succ_eqpoll";
   113 
   114 (*Pulling the  succ(...)  outside the |...| requires m, n: nat  *)
   115 (*Unconditional version requires AC*)
   116 goalw CardinalArith.thy [cadd_def]
   117     "!!m n. [| Ord(m);  Ord(n) |] ==> succ(m) |+| n = |succ(m |+| n)|";
   118 by (rtac (sum_succ_eqpoll RS cardinal_cong RS trans) 1);
   119 by (rtac (succ_eqpoll_cong RS cardinal_cong) 1);
   120 by (rtac (well_ord_cardinal_eqpoll RS eqpoll_sym) 1);
   121 by (REPEAT (ares_tac [well_ord_radd, well_ord_Memrel] 1));
   122 qed "cadd_succ_lemma";
   123 
   124 val [mnat,nnat] = goal CardinalArith.thy
   125     "[| m: nat;  n: nat |] ==> m |+| n = m#+n";
   126 by (cut_facts_tac [nnat] 1);
   127 by (nat_ind_tac "m" [mnat] 1);
   128 by (asm_simp_tac (simpset() addsimps [nat_into_Card RS cadd_0]) 1);
   129 by (asm_simp_tac (simpset() addsimps [nat_into_Ord, cadd_succ_lemma,
   130 				      nat_into_Card RS Card_cardinal_eq]) 1);
   131 qed "nat_cadd_eq_add";
   132 
   133 
   134 (*** Cardinal multiplication ***)
   135 
   136 (** Cardinal multiplication is commutative **)
   137 
   138 (*Easier to prove the two directions separately*)
   139 goalw CardinalArith.thy [eqpoll_def] "A*B eqpoll B*A";
   140 by (rtac exI 1);
   141 by (res_inst_tac [("c", "%<x,y>.<y,x>"), ("d", "%<x,y>.<y,x>")] 
   142     lam_bijective 1);
   143 by Safe_tac;
   144 by (ALLGOALS (Asm_simp_tac));
   145 qed "prod_commute_eqpoll";
   146 
   147 goalw CardinalArith.thy [cmult_def] "i |*| j = j |*| i";
   148 by (rtac (prod_commute_eqpoll RS cardinal_cong) 1);
   149 qed "cmult_commute";
   150 
   151 (** Cardinal multiplication is associative **)
   152 
   153 goalw CardinalArith.thy [eqpoll_def] "(A*B)*C eqpoll A*(B*C)";
   154 by (rtac exI 1);
   155 by (rtac prod_assoc_bij 1);
   156 qed "prod_assoc_eqpoll";
   157 
   158 (*Unconditional version requires AC*)
   159 goalw CardinalArith.thy [cmult_def]
   160     "!!i j k. [| well_ord(i,ri); well_ord(j,rj); well_ord(k,rk) |] ==>  \
   161 \             (i |*| j) |*| k = i |*| (j |*| k)";
   162 by (rtac cardinal_cong 1);
   163 by (rtac ([well_ord_cardinal_eqpoll, eqpoll_refl] MRS prod_eqpoll_cong RS
   164           eqpoll_trans) 1);
   165 by (rtac (prod_assoc_eqpoll RS eqpoll_trans) 2);
   166 by (rtac ([eqpoll_refl, well_ord_cardinal_eqpoll] MRS prod_eqpoll_cong RS
   167           eqpoll_sym) 2);
   168 by (REPEAT (ares_tac [well_ord_rmult] 1));
   169 qed "well_ord_cmult_assoc";
   170 
   171 (** Cardinal multiplication distributes over addition **)
   172 
   173 goalw CardinalArith.thy [eqpoll_def] "(A+B)*C eqpoll (A*C)+(B*C)";
   174 by (rtac exI 1);
   175 by (rtac sum_prod_distrib_bij 1);
   176 qed "sum_prod_distrib_eqpoll";
   177 
   178 goalw CardinalArith.thy [cadd_def, cmult_def]
   179     "!!i j k. [| well_ord(i,ri); well_ord(j,rj); well_ord(k,rk) |] ==>  \
   180 \             (i |+| j) |*| k = (i |*| k) |+| (j |*| k)";
   181 by (rtac cardinal_cong 1);
   182 by (rtac ([well_ord_cardinal_eqpoll, eqpoll_refl] MRS prod_eqpoll_cong RS
   183           eqpoll_trans) 1);
   184 by (rtac (sum_prod_distrib_eqpoll RS eqpoll_trans) 2);
   185 by (rtac ([well_ord_cardinal_eqpoll, well_ord_cardinal_eqpoll] MRS 
   186 	  sum_eqpoll_cong RS eqpoll_sym) 2);
   187 by (REPEAT (ares_tac [well_ord_rmult, well_ord_radd] 1));
   188 qed "well_ord_cadd_cmult_distrib";
   189 
   190 (** Multiplication by 0 yields 0 **)
   191 
   192 goalw CardinalArith.thy [eqpoll_def] "0*A eqpoll 0";
   193 by (rtac exI 1);
   194 by (rtac lam_bijective 1);
   195 by Safe_tac;
   196 qed "prod_0_eqpoll";
   197 
   198 goalw CardinalArith.thy [cmult_def] "0 |*| i = 0";
   199 by (asm_simp_tac (simpset() addsimps [prod_0_eqpoll RS cardinal_cong, 
   200 				      Card_0 RS Card_cardinal_eq]) 1);
   201 qed "cmult_0";
   202 
   203 (** 1 is the identity for multiplication **)
   204 
   205 goalw CardinalArith.thy [eqpoll_def] "{x}*A eqpoll A";
   206 by (rtac exI 1);
   207 by (resolve_tac [singleton_prod_bij RS bij_converse_bij] 1);
   208 qed "prod_singleton_eqpoll";
   209 
   210 goalw CardinalArith.thy [cmult_def, succ_def] "!!K. Card(K) ==> 1 |*| K = K";
   211 by (asm_simp_tac (simpset() addsimps [prod_singleton_eqpoll RS cardinal_cong, 
   212 				      Card_cardinal_eq]) 1);
   213 qed "cmult_1";
   214 
   215 (*** Some inequalities for multiplication ***)
   216 
   217 goalw CardinalArith.thy [lepoll_def, inj_def] "A lepoll A*A";
   218 by (res_inst_tac [("x", "lam x:A. <x,x>")] exI 1);
   219 by (simp_tac (simpset() addsimps [lam_type]) 1);
   220 qed "prod_square_lepoll";
   221 
   222 (*Could probably weaken the premise to well_ord(K,r), or remove using AC*)
   223 goalw CardinalArith.thy [cmult_def] "!!K. Card(K) ==> K le K |*| K";
   224 by (rtac le_trans 1);
   225 by (rtac well_ord_lepoll_imp_Card_le 2);
   226 by (rtac prod_square_lepoll 3);
   227 by (REPEAT (ares_tac [well_ord_rmult, well_ord_Memrel, Card_is_Ord] 2));
   228 by (asm_simp_tac (simpset() 
   229 		  addsimps [le_refl, Card_is_Ord, Card_cardinal_eq]) 1);
   230 qed "cmult_square_le";
   231 
   232 (** Multiplication by a non-zero cardinal **)
   233 
   234 goalw CardinalArith.thy [lepoll_def, inj_def] "!!b. b: B ==> A lepoll A*B";
   235 by (res_inst_tac [("x", "lam x:A. <x,b>")] exI 1);
   236 by (asm_simp_tac (simpset() addsimps [lam_type]) 1);
   237 qed "prod_lepoll_self";
   238 
   239 (*Could probably weaken the premises to well_ord(K,r), or removing using AC*)
   240 goalw CardinalArith.thy [cmult_def]
   241     "!!K. [| Card(K);  Ord(L);  0<L |] ==> K le (K |*| L)";
   242 by (rtac ([Card_cardinal_le, well_ord_lepoll_imp_Card_le] MRS le_trans) 1);
   243 by (rtac prod_lepoll_self 3);
   244 by (REPEAT (ares_tac [well_ord_rmult, well_ord_Memrel, Card_is_Ord, ltD] 1));
   245 qed "cmult_le_self";
   246 
   247 (** Monotonicity of multiplication **)
   248 
   249 goalw CardinalArith.thy [lepoll_def]
   250      "!!A B C D. [| A lepoll C;  B lepoll D |] ==> A * B  lepoll  C * D";
   251 by (REPEAT (etac exE 1));
   252 by (res_inst_tac [("x", "lam <w,y>:A*B. <f`w, fa`y>")] exI 1);
   253 by (res_inst_tac [("d", "%<w,y>.<converse(f)`w, converse(fa)`y>")] 
   254                   lam_injective 1);
   255 by (typechk_tac (inj_is_fun::ZF_typechecks));
   256 by (etac SigmaE 1);
   257 by (asm_simp_tac (simpset() addsimps [left_inverse]) 1);
   258 qed "prod_lepoll_mono";
   259 
   260 goalw CardinalArith.thy [cmult_def]
   261     "!!K. [| K' le K;  L' le L |] ==> (K' |*| L') le (K |*| L)";
   262 by (safe_tac (claset() addSDs [le_subset_iff RS iffD1]));
   263 by (rtac well_ord_lepoll_imp_Card_le 1);
   264 by (REPEAT (ares_tac [prod_lepoll_mono, subset_imp_lepoll] 2));
   265 by (REPEAT (ares_tac [well_ord_rmult, well_ord_Memrel] 1));
   266 qed "cmult_le_mono";
   267 
   268 (*** Multiplication of finite cardinals is "ordinary" multiplication ***)
   269 
   270 goalw CardinalArith.thy [eqpoll_def] "succ(A)*B eqpoll B + A*B";
   271 by (rtac exI 1);
   272 by (res_inst_tac [("c", "%<x,y>. if(x=A, Inl(y), Inr(<x,y>))"), 
   273                   ("d", "case(%y. <A,y>, %z. z)")] 
   274     lam_bijective 1);
   275 by (safe_tac (claset() addSEs [sumE]));
   276 by (ALLGOALS
   277     (asm_simp_tac (simpset() addsimps [succI2, if_type, mem_imp_not_eq])));
   278 qed "prod_succ_eqpoll";
   279 
   280 (*Unconditional version requires AC*)
   281 goalw CardinalArith.thy [cmult_def, cadd_def]
   282     "!!m n. [| Ord(m);  Ord(n) |] ==> succ(m) |*| n = n |+| (m |*| n)";
   283 by (rtac (prod_succ_eqpoll RS cardinal_cong RS trans) 1);
   284 by (rtac (cardinal_cong RS sym) 1);
   285 by (rtac ([eqpoll_refl, well_ord_cardinal_eqpoll] MRS sum_eqpoll_cong) 1);
   286 by (REPEAT (ares_tac [well_ord_rmult, well_ord_Memrel] 1));
   287 qed "cmult_succ_lemma";
   288 
   289 val [mnat,nnat] = goal CardinalArith.thy
   290     "[| m: nat;  n: nat |] ==> m |*| n = m#*n";
   291 by (cut_facts_tac [nnat] 1);
   292 by (nat_ind_tac "m" [mnat] 1);
   293 by (asm_simp_tac (simpset() addsimps [cmult_0]) 1);
   294 by (asm_simp_tac (simpset() addsimps [nat_into_Ord, cmult_succ_lemma,
   295 				      nat_cadd_eq_add]) 1);
   296 qed "nat_cmult_eq_mult";
   297 
   298 goal CardinalArith.thy "!!m n. Card(n) ==> 2 |*| n = n |+| n";
   299 by (asm_simp_tac 
   300     (simpset() addsimps [Ord_0, Ord_succ, cmult_0, cmult_succ_lemma, 
   301 			 Card_is_Ord, cadd_0,
   302 			 read_instantiate [("j","0")] cadd_commute]) 1);
   303 qed "cmult_2";
   304 
   305 
   306 (*** Infinite Cardinals are Limit Ordinals ***)
   307 
   308 (*This proof is modelled upon one assuming nat<=A, with injection
   309   lam z:cons(u,A). if(z=u, 0, if(z : nat, succ(z), z))  and inverse
   310   %y. if(y:nat, nat_case(u,%z.z,y), y).  If f: inj(nat,A) then
   311   range(f) behaves like the natural numbers.*)
   312 goalw CardinalArith.thy [lepoll_def]
   313     "!!i. nat lepoll A ==> cons(u,A) lepoll A";
   314 by (etac exE 1);
   315 by (res_inst_tac [("x",
   316     "lam z:cons(u,A). if(z=u, f`0,      \
   317 \                        if(z: range(f), f`succ(converse(f)`z), z))")] exI 1);
   318 by (res_inst_tac [("d", "%y. if(y: range(f),    \
   319 \                               nat_case(u, %z. f`z, converse(f)`y), y)")] 
   320     lam_injective 1);
   321 by (fast_tac (claset() addSIs [if_type, nat_succI, apply_type]
   322                       addIs  [inj_is_fun, inj_converse_fun]) 1);
   323 by (asm_simp_tac 
   324     (simpset() addsimps [inj_is_fun RS apply_rangeI,
   325 			 inj_converse_fun RS apply_rangeI,
   326 			 inj_converse_fun RS apply_funtype,
   327 			 left_inverse, right_inverse, nat_0I, nat_succI, 
   328 			 nat_case_0, nat_case_succ]
   329                setloop split_tac [expand_if]) 1);
   330 qed "nat_cons_lepoll";
   331 
   332 goal CardinalArith.thy "!!i. nat lepoll A ==> cons(u,A) eqpoll A";
   333 by (etac (nat_cons_lepoll RS eqpollI) 1);
   334 by (rtac (subset_consI RS subset_imp_lepoll) 1);
   335 qed "nat_cons_eqpoll";
   336 
   337 (*Specialized version required below*)
   338 goalw CardinalArith.thy [succ_def] "!!i. nat <= A ==> succ(A) eqpoll A";
   339 by (eresolve_tac [subset_imp_lepoll RS nat_cons_eqpoll] 1);
   340 qed "nat_succ_eqpoll";
   341 
   342 goalw CardinalArith.thy [InfCard_def] "InfCard(nat)";
   343 by (blast_tac (claset() addIs [Card_nat, le_refl, Card_is_Ord]) 1);
   344 qed "InfCard_nat";
   345 
   346 goalw CardinalArith.thy [InfCard_def] "!!K. InfCard(K) ==> Card(K)";
   347 by (etac conjunct1 1);
   348 qed "InfCard_is_Card";
   349 
   350 goalw CardinalArith.thy [InfCard_def]
   351     "!!K L. [| InfCard(K);  Card(L) |] ==> InfCard(K Un L)";
   352 by (asm_simp_tac (simpset() addsimps [Card_Un, Un_upper1_le RSN (2,le_trans), 
   353 				      Card_is_Ord]) 1);
   354 qed "InfCard_Un";
   355 
   356 (*Kunen's Lemma 10.11*)
   357 goalw CardinalArith.thy [InfCard_def] "!!K. InfCard(K) ==> Limit(K)";
   358 by (etac conjE 1);
   359 by (forward_tac [Card_is_Ord] 1);
   360 by (rtac (ltI RS non_succ_LimitI) 1);
   361 by (etac ([asm_rl, nat_0I] MRS (le_imp_subset RS subsetD)) 1);
   362 by (safe_tac (claset() addSDs [Limit_nat RS Limit_le_succD]));
   363 by (rewtac Card_def);
   364 by (dtac trans 1);
   365 by (etac (le_imp_subset RS nat_succ_eqpoll RS cardinal_cong) 1);
   366 by (etac (Ord_cardinal_le RS lt_trans2 RS lt_irrefl) 1);
   367 by (REPEAT (ares_tac [le_eqI, Ord_cardinal] 1));
   368 qed "InfCard_is_Limit";
   369 
   370 
   371 (*** An infinite cardinal equals its square (Kunen, Thm 10.12, page 29) ***)
   372 
   373 (*A general fact about ordermap*)
   374 goalw Cardinal.thy [eqpoll_def]
   375     "!!A. [| well_ord(A,r);  x:A |] ==> ordermap(A,r)`x eqpoll pred(A,x,r)";
   376 by (rtac exI 1);
   377 by (asm_simp_tac (simpset() addsimps [ordermap_eq_image, well_ord_is_wf]) 1);
   378 by (etac (ordermap_bij RS bij_is_inj RS restrict_bij RS bij_converse_bij) 1);
   379 by (rtac pred_subset 1);
   380 qed "ordermap_eqpoll_pred";
   381 
   382 (** Establishing the well-ordering **)
   383 
   384 goalw CardinalArith.thy [inj_def]
   385  "!!K. Ord(K) ==> (lam <x,y>:K*K. <x Un y, x, y>) : inj(K*K, K*K*K)";
   386 by (fast_tac (claset() addss (simpset())
   387                        addIs [lam_type, Un_least_lt RS ltD, ltI]) 1);
   388 qed "csquare_lam_inj";
   389 
   390 goalw CardinalArith.thy [csquare_rel_def]
   391  "!!K. Ord(K) ==> well_ord(K*K, csquare_rel(K))";
   392 by (rtac (csquare_lam_inj RS well_ord_rvimage) 1);
   393 by (REPEAT (ares_tac [well_ord_rmult, well_ord_Memrel] 1));
   394 qed "well_ord_csquare";
   395 
   396 (** Characterising initial segments of the well-ordering **)
   397 
   398 goalw CardinalArith.thy [csquare_rel_def]
   399  "!!K. [| x<K;  y<K;  z<K |] ==> \
   400 \      <<x,y>, <z,z>> : csquare_rel(K) --> x le z & y le z";
   401 by (REPEAT (etac ltE 1));
   402 by (asm_simp_tac (simpset() addsimps [rvimage_iff, rmult_iff, Memrel_iff,
   403 				      Un_absorb, Un_least_mem_iff, ltD]) 1);
   404 by (safe_tac (claset() addSEs [mem_irrefl] 
   405                        addSIs [Un_upper1_le, Un_upper2_le]));
   406 by (ALLGOALS (asm_simp_tac (simpset() addsimps [lt_def, succI2, Ord_succ])));
   407 qed_spec_mp "csquareD";
   408 
   409 goalw CardinalArith.thy [pred_def]
   410  "!!K. z<K ==> pred(K*K, <z,z>, csquare_rel(K)) <= succ(z)*succ(z)";
   411 by (safe_tac (claset_of ZF.thy addSEs [SigmaE]));  (*avoids using succCI,...*)
   412 by (rtac (csquareD RS conjE) 1);
   413 by (rewtac lt_def);
   414 by (assume_tac 4);
   415 by (ALLGOALS Blast_tac);
   416 qed "pred_csquare_subset";
   417 
   418 goalw CardinalArith.thy [csquare_rel_def]
   419  "!!K. [| x<z;  y<z;  z<K |] ==>  <<x,y>, <z,z>> : csquare_rel(K)";
   420 by (subgoals_tac ["x<K", "y<K"] 1);
   421 by (REPEAT (eresolve_tac [asm_rl, lt_trans] 2));
   422 by (REPEAT (etac ltE 1));
   423 by (asm_simp_tac (simpset() addsimps [rvimage_iff, rmult_iff, Memrel_iff,
   424 				      Un_absorb, Un_least_mem_iff, ltD]) 1);
   425 qed "csquare_ltI";
   426 
   427 (*Part of the traditional proof.  UNUSED since it's harder to prove & apply *)
   428 goalw CardinalArith.thy [csquare_rel_def]
   429  "!!K. [| x le z;  y le z;  z<K |] ==> \
   430 \      <<x,y>, <z,z>> : csquare_rel(K) | x=z & y=z";
   431 by (subgoals_tac ["x<K", "y<K"] 1);
   432 by (REPEAT (eresolve_tac [asm_rl, lt_trans1] 2));
   433 by (REPEAT (etac ltE 1));
   434 by (asm_simp_tac (simpset() addsimps [rvimage_iff, rmult_iff, Memrel_iff,
   435 				      Un_absorb, Un_least_mem_iff, ltD]) 1);
   436 by (REPEAT_FIRST (etac succE));
   437 by (ALLGOALS
   438     (asm_simp_tac (simpset() addsimps [subset_Un_iff RS iff_sym, 
   439 				       subset_Un_iff2 RS iff_sym, OrdmemD])));
   440 qed "csquare_or_eqI";
   441 
   442 (** The cardinality of initial segments **)
   443 
   444 goal CardinalArith.thy
   445     "!!K. [| Limit(K);  x<K;  y<K;  z=succ(x Un y) |] ==> \
   446 \         ordermap(K*K, csquare_rel(K)) ` <x,y> <               \
   447 \         ordermap(K*K, csquare_rel(K)) ` <z,z>";
   448 by (subgoals_tac ["z<K", "well_ord(K*K, csquare_rel(K))"] 1);
   449 by (etac (Limit_is_Ord RS well_ord_csquare) 2);
   450 by (blast_tac (claset() addSIs [Un_least_lt, Limit_has_succ]) 2);
   451 by (rtac (csquare_ltI RS ordermap_mono RS ltI) 1);
   452 by (etac well_ord_is_wf 4);
   453 by (ALLGOALS 
   454     (blast_tac (claset() addSIs [Un_upper1_le, Un_upper2_le, Ord_ordermap] 
   455                          addSEs [ltE])));
   456 qed "ordermap_z_lt";
   457 
   458 (*Kunen: "each <x,y>: K*K has no more than z*z predecessors..." (page 29) *)
   459 goalw CardinalArith.thy [cmult_def]
   460   "!!K. [| Limit(K);  x<K;  y<K;  z=succ(x Un y) |] ==> \
   461 \       | ordermap(K*K, csquare_rel(K)) ` <x,y> | le  |succ(z)| |*| |succ(z)|";
   462 by (rtac (well_ord_rmult RS well_ord_lepoll_imp_Card_le) 1);
   463 by (REPEAT (ares_tac [Ord_cardinal, well_ord_Memrel] 1));
   464 by (subgoals_tac ["z<K"] 1);
   465 by (blast_tac (claset() addSIs [Un_least_lt, Limit_has_succ]) 2);
   466 by (rtac (ordermap_z_lt RS leI RS le_imp_lepoll RS lepoll_trans) 1);
   467 by (REPEAT_SOME assume_tac);
   468 by (rtac (ordermap_eqpoll_pred RS eqpoll_imp_lepoll RS lepoll_trans) 1);
   469 by (etac (Limit_is_Ord RS well_ord_csquare) 1);
   470 by (blast_tac (claset() addIs [ltD]) 1);
   471 by (rtac (pred_csquare_subset RS subset_imp_lepoll RS lepoll_trans) 1 THEN
   472     assume_tac 1);
   473 by (REPEAT_FIRST (etac ltE));
   474 by (rtac (prod_eqpoll_cong RS eqpoll_sym RS eqpoll_imp_lepoll) 1);
   475 by (REPEAT_FIRST (etac (Ord_succ RS Ord_cardinal_eqpoll)));
   476 qed "ordermap_csquare_le";
   477 
   478 (*Kunen: "... so the order type <= K" *)
   479 goal CardinalArith.thy
   480     "!!K. [| InfCard(K);  ALL y:K. InfCard(y) --> y |*| y = y |]  ==>  \
   481 \         ordertype(K*K, csquare_rel(K)) le K";
   482 by (forward_tac [InfCard_is_Card RS Card_is_Ord] 1);
   483 by (rtac all_lt_imp_le 1);
   484 by (assume_tac 1);
   485 by (etac (well_ord_csquare RS Ord_ordertype) 1);
   486 by (rtac Card_lt_imp_lt 1);
   487 by (etac InfCard_is_Card 3);
   488 by (etac ltE 2 THEN assume_tac 2);
   489 by (asm_full_simp_tac (simpset() addsimps [ordertype_unfold]) 1);
   490 by (safe_tac (claset() addSEs [ltE]));
   491 by (subgoals_tac ["Ord(xb)", "Ord(y)"] 1);
   492 by (REPEAT (eresolve_tac [asm_rl, Ord_in_Ord] 2));
   493 by (rtac (InfCard_is_Limit RS ordermap_csquare_le RS lt_trans1) 1  THEN
   494     REPEAT (ares_tac [refl] 1 ORELSE etac ltI 1));
   495 by (res_inst_tac [("i","xb Un y"), ("j","nat")] Ord_linear2 1  THEN
   496     REPEAT (ares_tac [Ord_Un, Ord_nat] 1));
   497 (*the finite case: xb Un y < nat *)
   498 by (res_inst_tac [("j", "nat")] lt_trans2 1);
   499 by (asm_full_simp_tac (simpset() addsimps [InfCard_def]) 2);
   500 by (asm_full_simp_tac
   501     (simpset() addsimps [lt_def, nat_cmult_eq_mult, nat_succI, mult_type,
   502 			 nat_into_Card RS Card_cardinal_eq, Ord_nat]) 1);
   503 (*case nat le (xb Un y) *)
   504 by (asm_full_simp_tac
   505     (simpset() addsimps [le_imp_subset RS nat_succ_eqpoll RS cardinal_cong,
   506 			 le_succ_iff, InfCard_def, Card_cardinal, Un_least_lt, 
   507 			 Ord_Un, ltI, nat_le_cardinal,
   508 			 Ord_cardinal_le RS lt_trans1 RS ltD]) 1);
   509 qed "ordertype_csquare_le";
   510 
   511 (*Main result: Kunen's Theorem 10.12*)
   512 goal CardinalArith.thy "!!K. InfCard(K) ==> K |*| K = K";
   513 by (forward_tac [InfCard_is_Card RS Card_is_Ord] 1);
   514 by (etac rev_mp 1);
   515 by (trans_ind_tac "K" [] 1);
   516 by (rtac impI 1);
   517 by (rtac le_anti_sym 1);
   518 by (etac (InfCard_is_Card RS cmult_square_le) 2);
   519 by (rtac (ordertype_csquare_le RSN (2, le_trans)) 1);
   520 by (assume_tac 2);
   521 by (assume_tac 2);
   522 by (asm_simp_tac 
   523     (simpset() addsimps [cmult_def, Ord_cardinal_le,
   524 			 well_ord_csquare RS ordermap_bij RS 
   525 			 bij_imp_eqpoll RS cardinal_cong,
   526 			 well_ord_csquare RS Ord_ordertype]) 1);
   527 qed "InfCard_csquare_eq";
   528 
   529 (*Corollary for arbitrary well-ordered sets (all sets, assuming AC)*)
   530 goal CardinalArith.thy
   531     "!!A. [| well_ord(A,r);  InfCard(|A|) |] ==> A*A eqpoll A";
   532 by (resolve_tac [prod_eqpoll_cong RS eqpoll_trans] 1);
   533 by (REPEAT (etac (well_ord_cardinal_eqpoll RS eqpoll_sym) 1));
   534 by (rtac well_ord_cardinal_eqE 1);
   535 by (REPEAT (ares_tac [Ord_cardinal, well_ord_rmult, well_ord_Memrel] 1));
   536 by (asm_simp_tac (simpset() 
   537 		  addsimps [symmetric cmult_def, InfCard_csquare_eq]) 1);
   538 qed "well_ord_InfCard_square_eq";
   539 
   540 (** Toward's Kunen's Corollary 10.13 (1) **)
   541 
   542 goal CardinalArith.thy "!!K. [| InfCard(K);  L le K;  0<L |] ==> K |*| L = K";
   543 by (rtac le_anti_sym 1);
   544 by (etac ltE 2 THEN
   545     REPEAT (ares_tac [cmult_le_self, InfCard_is_Card] 2));
   546 by (forward_tac [InfCard_is_Card RS Card_is_Ord RS le_refl] 1);
   547 by (resolve_tac [cmult_le_mono RS le_trans] 1 THEN REPEAT (assume_tac 1));
   548 by (asm_simp_tac (simpset() addsimps [InfCard_csquare_eq]) 1);
   549 qed "InfCard_le_cmult_eq";
   550 
   551 (*Corollary 10.13 (1), for cardinal multiplication*)
   552 goal CardinalArith.thy
   553     "!!K. [| InfCard(K);  InfCard(L) |] ==> K |*| L = K Un L";
   554 by (res_inst_tac [("i","K"),("j","L")] Ord_linear_le 1);
   555 by (typechk_tac [InfCard_is_Card, Card_is_Ord]);
   556 by (resolve_tac [cmult_commute RS ssubst] 1);
   557 by (resolve_tac [Un_commute RS ssubst] 1);
   558 by (ALLGOALS
   559     (asm_simp_tac 
   560      (simpset() addsimps [InfCard_is_Limit RS Limit_has_0, InfCard_le_cmult_eq,
   561 			  subset_Un_iff2 RS iffD1, le_imp_subset])));
   562 qed "InfCard_cmult_eq";
   563 
   564 (*This proof appear to be the simplest!*)
   565 goal CardinalArith.thy "!!K. InfCard(K) ==> K |+| K = K";
   566 by (asm_simp_tac
   567     (simpset() addsimps [cmult_2 RS sym, InfCard_is_Card, cmult_commute]) 1);
   568 by (rtac InfCard_le_cmult_eq 1);
   569 by (typechk_tac [Ord_0, le_refl, leI]);
   570 by (typechk_tac [InfCard_is_Limit, Limit_has_0, Limit_has_succ]);
   571 qed "InfCard_cdouble_eq";
   572 
   573 (*Corollary 10.13 (1), for cardinal addition*)
   574 goal CardinalArith.thy "!!K. [| InfCard(K);  L le K |] ==> K |+| L = K";
   575 by (rtac le_anti_sym 1);
   576 by (etac ltE 2 THEN
   577     REPEAT (ares_tac [cadd_le_self, InfCard_is_Card] 2));
   578 by (forward_tac [InfCard_is_Card RS Card_is_Ord RS le_refl] 1);
   579 by (resolve_tac [cadd_le_mono RS le_trans] 1 THEN REPEAT (assume_tac 1));
   580 by (asm_simp_tac (simpset() addsimps [InfCard_cdouble_eq]) 1);
   581 qed "InfCard_le_cadd_eq";
   582 
   583 goal CardinalArith.thy
   584     "!!K. [| InfCard(K);  InfCard(L) |] ==> K |+| L = K Un L";
   585 by (res_inst_tac [("i","K"),("j","L")] Ord_linear_le 1);
   586 by (typechk_tac [InfCard_is_Card, Card_is_Ord]);
   587 by (resolve_tac [cadd_commute RS ssubst] 1);
   588 by (resolve_tac [Un_commute RS ssubst] 1);
   589 by (ALLGOALS
   590     (asm_simp_tac 
   591      (simpset() addsimps [InfCard_le_cadd_eq,
   592 			  subset_Un_iff2 RS iffD1, le_imp_subset])));
   593 qed "InfCard_cadd_eq";
   594 
   595 (*The other part, Corollary 10.13 (2), refers to the cardinality of the set
   596   of all n-tuples of elements of K.  A better version for the Isabelle theory
   597   might be  InfCard(K) ==> |list(K)| = K.
   598 *)
   599 
   600 (*** For every cardinal number there exists a greater one
   601      [Kunen's Theorem 10.16, which would be trivial using AC] ***)
   602 
   603 goalw CardinalArith.thy [jump_cardinal_def] "Ord(jump_cardinal(K))";
   604 by (rtac (Ord_is_Transset RSN (2,OrdI)) 1);
   605 by (blast_tac (claset() addSIs [Ord_ordertype]) 2);
   606 by (rewtac Transset_def);
   607 by (safe_tac subset_cs);
   608 by (asm_full_simp_tac (simpset() addsimps [ordertype_pred_unfold]) 1);
   609 by Safe_tac;
   610 by (rtac UN_I 1);
   611 by (rtac ReplaceI 2);
   612 by (ALLGOALS (blast_tac (claset() addIs [well_ord_subset] addSEs [predE])));
   613 qed "Ord_jump_cardinal";
   614 
   615 (*Allows selective unfolding.  Less work than deriving intro/elim rules*)
   616 goalw CardinalArith.thy [jump_cardinal_def]
   617      "i : jump_cardinal(K) <->   \
   618 \         (EX r X. r <= K*K & X <= K & well_ord(X,r) & i = ordertype(X,r))";
   619 by (fast_tac subset_cs 1);      (*It's vital to avoid reasoning about <=*)
   620 qed "jump_cardinal_iff";
   621 
   622 (*The easy part of Theorem 10.16: jump_cardinal(K) exceeds K*)
   623 goal CardinalArith.thy "!!K. Ord(K) ==> K < jump_cardinal(K)";
   624 by (resolve_tac [Ord_jump_cardinal RSN (2,ltI)] 1);
   625 by (resolve_tac [jump_cardinal_iff RS iffD2] 1);
   626 by (REPEAT_FIRST (ares_tac [exI, conjI, well_ord_Memrel]));
   627 by (rtac subset_refl 2);
   628 by (asm_simp_tac (simpset() addsimps [Memrel_def, subset_iff]) 1);
   629 by (asm_simp_tac (simpset() addsimps [ordertype_Memrel]) 1);
   630 qed "K_lt_jump_cardinal";
   631 
   632 (*The proof by contradiction: the bijection f yields a wellordering of X
   633   whose ordertype is jump_cardinal(K).  *)
   634 goal CardinalArith.thy
   635     "!!K. [| well_ord(X,r);  r <= K * K;  X <= K;       \
   636 \            f : bij(ordertype(X,r), jump_cardinal(K))  \
   637 \         |] ==> jump_cardinal(K) : jump_cardinal(K)";
   638 by (subgoal_tac "f O ordermap(X,r): bij(X, jump_cardinal(K))" 1);
   639 by (REPEAT (ares_tac [comp_bij, ordermap_bij] 2));
   640 by (resolve_tac [jump_cardinal_iff RS iffD2] 1);
   641 by (REPEAT_FIRST (resolve_tac [exI, conjI]));
   642 by (rtac ([rvimage_type, Sigma_mono] MRS subset_trans) 1);
   643 by (REPEAT (assume_tac 1));
   644 by (etac (bij_is_inj RS well_ord_rvimage) 1);
   645 by (rtac (Ord_jump_cardinal RS well_ord_Memrel) 1);
   646 by (asm_simp_tac
   647     (simpset() addsimps [well_ord_Memrel RSN (2, bij_ordertype_vimage), 
   648 			 ordertype_Memrel, Ord_jump_cardinal]) 1);
   649 qed "Card_jump_cardinal_lemma";
   650 
   651 (*The hard part of Theorem 10.16: jump_cardinal(K) is itself a cardinal*)
   652 goal CardinalArith.thy "Card(jump_cardinal(K))";
   653 by (rtac (Ord_jump_cardinal RS CardI) 1);
   654 by (rewtac eqpoll_def);
   655 by (safe_tac (claset() addSDs [ltD, jump_cardinal_iff RS iffD1]));
   656 by (REPEAT (ares_tac [Card_jump_cardinal_lemma RS mem_irrefl] 1));
   657 qed "Card_jump_cardinal";
   658 
   659 (*** Basic properties of successor cardinals ***)
   660 
   661 goalw CardinalArith.thy [csucc_def]
   662     "!!K. Ord(K) ==> Card(csucc(K)) & K < csucc(K)";
   663 by (rtac LeastI 1);
   664 by (REPEAT (ares_tac [conjI, Card_jump_cardinal, K_lt_jump_cardinal,
   665                       Ord_jump_cardinal] 1));
   666 qed "csucc_basic";
   667 
   668 bind_thm ("Card_csucc", csucc_basic RS conjunct1);
   669 
   670 bind_thm ("lt_csucc", csucc_basic RS conjunct2);
   671 
   672 goal CardinalArith.thy "!!K. Ord(K) ==> 0 < csucc(K)";
   673 by (resolve_tac [[Ord_0_le, lt_csucc] MRS lt_trans1] 1);
   674 by (REPEAT (assume_tac 1));
   675 qed "Ord_0_lt_csucc";
   676 
   677 goalw CardinalArith.thy [csucc_def]
   678     "!!K L. [| Card(L);  K<L |] ==> csucc(K) le L";
   679 by (rtac Least_le 1);
   680 by (REPEAT (ares_tac [conjI, Card_is_Ord] 1));
   681 qed "csucc_le";
   682 
   683 goal CardinalArith.thy
   684     "!!K. [| Ord(i); Card(K) |] ==> i < csucc(K) <-> |i| le K";
   685 by (rtac iffI 1);
   686 by (rtac Card_lt_imp_lt 2);
   687 by (etac lt_trans1 2);
   688 by (REPEAT (ares_tac [lt_csucc, Card_csucc, Card_is_Ord] 2));
   689 by (resolve_tac [notI RS not_lt_imp_le] 1);
   690 by (resolve_tac [Card_cardinal RS csucc_le RS lt_trans1 RS lt_irrefl] 1);
   691 by (assume_tac 1);
   692 by (resolve_tac [Ord_cardinal_le RS lt_trans1] 1);
   693 by (REPEAT (ares_tac [Ord_cardinal] 1
   694      ORELSE eresolve_tac [ltE, Card_is_Ord] 1));
   695 qed "lt_csucc_iff";
   696 
   697 goal CardinalArith.thy
   698     "!!K' K. [| Card(K'); Card(K) |] ==> K' < csucc(K) <-> K' le K";
   699 by (asm_simp_tac 
   700     (simpset() addsimps [lt_csucc_iff, Card_cardinal_eq, Card_is_Ord]) 1);
   701 qed "Card_lt_csucc_iff";
   702 
   703 goalw CardinalArith.thy [InfCard_def]
   704     "!!K. InfCard(K) ==> InfCard(csucc(K))";
   705 by (asm_simp_tac (simpset() addsimps [Card_csucc, Card_is_Ord, 
   706 				      lt_csucc RS leI RSN (2,le_trans)]) 1);
   707 qed "InfCard_csucc";
   708 
   709 
   710 (*** Finite sets ***)
   711 
   712 goal CardinalArith.thy
   713     "!!n. n: nat ==> ALL A. A eqpoll n --> A : Fin(A)";
   714 by (etac nat_induct 1);
   715 by (simp_tac (simpset() addsimps (eqpoll_0_iff::Fin.intrs)) 1);
   716 by (Clarify_tac 1);
   717 by (subgoal_tac "EX u. u:A" 1);
   718 by (etac exE 1);
   719 by (resolve_tac [Diff_sing_eqpoll RS revcut_rl] 1);
   720 by (assume_tac 2);
   721 by (assume_tac 1);
   722 by (res_inst_tac [("b", "A")] (cons_Diff RS subst) 1);
   723 by (assume_tac 1);
   724 by (resolve_tac [Fin.consI] 1);
   725 by (Blast_tac 1);
   726 by (blast_tac (claset() addIs [subset_consI  RS Fin_mono RS subsetD]) 1); 
   727 (*Now for the lemma assumed above*)
   728 by (rewtac eqpoll_def);
   729 by (blast_tac (claset() addIs [bij_converse_bij RS bij_is_fun RS apply_type]) 1);
   730 val lemma = result();
   731 
   732 goalw CardinalArith.thy [Finite_def] "!!A. Finite(A) ==> A : Fin(A)";
   733 by (blast_tac (claset() addIs [lemma RS spec RS mp]) 1);
   734 qed "Finite_into_Fin";
   735 
   736 goal CardinalArith.thy "!!A. A : Fin(U) ==> Finite(A)";
   737 by (fast_tac (claset() addSIs [Finite_0, Finite_cons] addEs [Fin.induct]) 1);
   738 qed "Fin_into_Finite";
   739 
   740 goal CardinalArith.thy "Finite(A) <-> A : Fin(A)";
   741 by (blast_tac (claset() addIs [Finite_into_Fin, Fin_into_Finite]) 1);
   742 qed "Finite_Fin_iff";
   743 
   744 goal CardinalArith.thy
   745     "!!A. [| Finite(A); Finite(B) |] ==> Finite(A Un B)";
   746 by (blast_tac (claset() addSIs [Fin_into_Finite, Fin_UnI] 
   747                         addSDs [Finite_into_Fin]
   748                         addIs  [Un_upper1 RS Fin_mono RS subsetD,
   749 	 		        Un_upper2 RS Fin_mono RS subsetD]) 1);
   750 qed "Finite_Un";
   751 
   752 
   753 (** Removing elements from a finite set decreases its cardinality **)
   754 
   755 goal CardinalArith.thy
   756     "!!A. A: Fin(U) ==> x~:A --> ~ cons(x,A) lepoll A";
   757 by (etac Fin_induct 1);
   758 by (simp_tac (simpset() addsimps [lepoll_0_iff]) 1);
   759 by (subgoal_tac "cons(x,cons(xa,y)) = cons(xa,cons(x,y))" 1);
   760 by (Asm_simp_tac 1);
   761 by (blast_tac (claset() addSDs [cons_lepoll_consD]) 1);
   762 by (Blast_tac 1);
   763 qed "Fin_imp_not_cons_lepoll";
   764 
   765 goal CardinalArith.thy
   766     "!!a A. [| Finite(A);  a~:A |] ==> |cons(a,A)| = succ(|A|)";
   767 by (rewtac cardinal_def);
   768 by (rtac Least_equality 1);
   769 by (fold_tac [cardinal_def]);
   770 by (simp_tac (simpset() addsimps [succ_def]) 1);
   771 by (blast_tac (claset() addIs [cons_eqpoll_cong, well_ord_cardinal_eqpoll] 
   772                         addSEs [mem_irrefl]
   773                         addSDs [Finite_imp_well_ord]) 1);
   774 by (blast_tac (claset() addIs [Ord_succ, Card_cardinal, Card_is_Ord]) 1);
   775 by (rtac notI 1);
   776 by (resolve_tac [Finite_into_Fin RS Fin_imp_not_cons_lepoll RS mp RS notE] 1);
   777 by (assume_tac 1);
   778 by (assume_tac 1);
   779 by (eresolve_tac [eqpoll_sym RS eqpoll_imp_lepoll RS lepoll_trans] 1);
   780 by (eresolve_tac [le_imp_lepoll RS lepoll_trans] 1);
   781 by (blast_tac (claset() addIs [well_ord_cardinal_eqpoll RS eqpoll_imp_lepoll] 
   782                     addSDs [Finite_imp_well_ord]) 1);
   783 qed "Finite_imp_cardinal_cons";
   784 
   785 
   786 goal CardinalArith.thy "!!a A. [| Finite(A);  a:A |] ==> succ(|A-{a}|) = |A|";
   787 by (res_inst_tac [("b", "A")] (cons_Diff RS subst) 1);
   788 by (assume_tac 1);
   789 by (asm_simp_tac (simpset() addsimps [Finite_imp_cardinal_cons,
   790                                   Diff_subset RS subset_Finite]) 1);
   791 by (asm_simp_tac (simpset() addsimps [cons_Diff]) 1);
   792 qed "Finite_imp_succ_cardinal_Diff";
   793 
   794 goal CardinalArith.thy "!!a A. [| Finite(A);  a:A |] ==> |A-{a}| < |A|";
   795 by (rtac succ_leE 1);
   796 by (asm_simp_tac (simpset() addsimps [Finite_imp_succ_cardinal_Diff, 
   797 				      Ord_cardinal RS le_refl]) 1);
   798 qed "Finite_imp_cardinal_Diff";
   799 
   800 
   801 (** Theorems by Krzysztof Grabczewski, proofs by lcp **)
   802 
   803 val nat_implies_well_ord =
   804   (transfer CardinalArith.thy nat_into_Ord) RS well_ord_Memrel;
   805 
   806 goal CardinalArith.thy "!!m n. [| m:nat; n:nat |] ==> m + n eqpoll m #+ n";
   807 by (rtac eqpoll_trans 1);
   808 by (resolve_tac [well_ord_radd RS well_ord_cardinal_eqpoll RS eqpoll_sym] 1);
   809 by (REPEAT (etac nat_implies_well_ord 1));
   810 by (asm_simp_tac (simpset() 
   811 		  addsimps [nat_cadd_eq_add RS sym, cadd_def, eqpoll_refl]) 1);
   812 qed "nat_sum_eqpoll_sum";
   813 
   814 goal Nat.thy "!!m. [| m le n; n:nat |] ==> m:nat";
   815 by (blast_tac (claset() addSIs [nat_succI] addSDs [lt_nat_in_nat]) 1);
   816 qed "le_in_nat";
   817