src/Pure/axclass.ML
author ballarin
Mon Aug 08 22:14:04 2005 +0200 (2005-08-08 ago)
changeset 17034 b4d9b87c102e
parent 16486 1a12cdb6ee6b
child 17041 dee6f7047cae
permissions -rw-r--r--
After_qed takes result argument.
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Axiomatic type class package.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val quiet_mode: bool ref
    11   val print_axclasses: theory -> unit
    12   val add_axclass: bstring * xstring list -> ((bstring * string) * Attrib.src list) list
    13     -> theory -> theory * {intro: thm, axioms: thm list}
    14   val add_axclass_i: bstring * class list -> ((bstring * term) * theory attribute list) list
    15     -> theory -> theory * {intro: thm, axioms: thm list}
    16   val add_classrel_thms: thm list -> theory -> theory
    17   val add_arity_thms: thm list -> theory -> theory
    18   val add_inst_subclass: xstring * xstring -> tactic -> theory -> theory
    19   val add_inst_subclass_i: class * class -> tactic -> theory -> theory
    20   val add_inst_arity: xstring * string list * string -> tactic -> theory -> theory
    21   val add_inst_arity_i: string * sort list * sort -> tactic -> theory -> theory
    22   val instance_subclass_proof: xstring * xstring -> bool -> theory -> ProofHistory.T
    23   val instance_subclass_proof_i: class * class -> bool -> theory -> ProofHistory.T
    24   val instance_arity_proof: xstring * string list * string -> bool -> theory -> ProofHistory.T
    25   val instance_arity_proof_i: string * sort list * sort -> bool -> theory -> ProofHistory.T
    26   val intro_classes_tac: thm list -> tactic
    27   val default_intro_classes_tac: thm list -> tactic
    28 
    29   (*legacy interfaces*)
    30   val axclass_tac: thm list -> tactic
    31   val add_inst_subclass_x: xstring * xstring -> string list -> thm list
    32     -> tactic option -> theory -> theory
    33   val add_inst_arity_x: xstring * string list * string -> string list
    34     -> thm list -> tactic option -> theory -> theory
    35 end;
    36 
    37 structure AxClass: AX_CLASS =
    38 struct
    39 
    40 
    41 (** utilities **)
    42 
    43 (* messages *)
    44 
    45 val quiet_mode = ref false;
    46 fun message s = if ! quiet_mode then () else writeln s;
    47 
    48 
    49 (* type vars *)
    50 
    51 fun map_typ_frees f (Type (t, tys)) = Type (t, map (map_typ_frees f) tys)
    52   | map_typ_frees f (TFree a) = f a
    53   | map_typ_frees _ a = a;
    54 
    55 val map_term_tfrees = map_term_types o map_typ_frees;
    56 
    57 fun aT S = TFree ("'a", S);
    58 
    59 fun dest_varT (TFree (x, S)) = ((x, ~1), S)
    60   | dest_varT (TVar xi_S) = xi_S
    61   | dest_varT T = raise TYPE ("dest_varT", [T], []);
    62 
    63 
    64 
    65 (** abstract syntax operations **)
    66 
    67 (* names *)
    68 
    69 fun intro_name c = c ^ "I";
    70 val introN = "intro";
    71 val axiomsN = "axioms";
    72 
    73 
    74 (* subclass relations as terms *)
    75 
    76 fun mk_classrel (c1, c2) = Logic.mk_inclass (aT [c1], c2);
    77 
    78 fun dest_classrel tm =
    79   let
    80     fun err () = raise TERM ("dest_classrel", [tm]);
    81 
    82     val (ty, c2) = Logic.dest_inclass tm handle TERM _ => err ();
    83     val c1 = (case dest_varT ty of (_, [c]) => c | _ => err ())
    84       handle TYPE _ => err ();
    85   in (c1, c2) end;
    86 
    87 
    88 (* arities as terms *)
    89 
    90 fun mk_arity (t, Ss, c) =
    91   let
    92     val tfrees = ListPair.map TFree (Term.invent_names [] "'a" (length Ss), Ss);
    93   in Logic.mk_inclass (Type (t, tfrees), c) end;
    94 
    95 fun mk_arities (t, Ss, S) = map (fn c => mk_arity (t, Ss, c)) S;
    96 
    97 fun dest_arity tm =
    98   let
    99     fun err () = raise TERM ("dest_arity", [tm]);
   100 
   101     val (ty, c) = Logic.dest_inclass tm handle TERM _ => err ();
   102     val (t, tvars) =
   103       (case ty of
   104         Type (t, tys) => (t, map dest_varT tys handle TYPE _ => err ())
   105       | _ => err ());
   106     val ss =
   107       if null (gen_duplicates eq_fst tvars)
   108       then map snd tvars else err ();
   109   in (t, ss, c) end;
   110 
   111 
   112 
   113 (** axclass info **)
   114 
   115 (* data kind 'Pure/axclasses' *)
   116 
   117 type axclass_info =
   118   {super_classes: class list,
   119     intro: thm,
   120     axioms: thm list};
   121 
   122 structure AxclassesData = TheoryDataFun
   123 (struct
   124   val name = "Pure/axclasses";
   125   type T = axclass_info Symtab.table;
   126 
   127   val empty = Symtab.empty;
   128   val copy = I;
   129   val extend = I;
   130   fun merge _ = Symtab.merge (K true);
   131 
   132   fun print thy tab =
   133     let
   134       fun pretty_class c cs = Pretty.block
   135         (Pretty.str (Sign.extern_class thy c) :: Pretty.str " <" :: Pretty.brk 1 ::
   136           Pretty.breaks (map (Pretty.str o Sign.extern_class thy) cs));
   137 
   138       fun pretty_thms name thms = Pretty.big_list (name ^ ":")
   139         (map (Display.pretty_thm_sg thy) thms);
   140 
   141       fun pretty_axclass (name, {super_classes, intro, axioms}) = Pretty.block (Pretty.fbreaks
   142         [pretty_class name super_classes, pretty_thms introN [intro], pretty_thms axiomsN axioms]);
   143     in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest tab))) end;
   144 end);
   145 
   146 val _ = Context.add_setup [AxclassesData.init];
   147 val print_axclasses = AxclassesData.print;
   148 
   149 
   150 (* get and put data *)
   151 
   152 fun lookup_axclass_info thy c = Symtab.lookup (AxclassesData.get thy, c);
   153 
   154 fun get_axclass_info thy c =
   155   (case lookup_axclass_info thy c of
   156     NONE => error ("Unknown axclass " ^ quote c)
   157   | SOME info => info);
   158 
   159 fun put_axclass_info c info thy =
   160   thy |> AxclassesData.put (Symtab.update ((c, info), AxclassesData.get thy));
   161 
   162 
   163 (* class_axms *)
   164 
   165 fun class_axms thy =
   166   let val classes = Sign.classes thy in
   167     map (Thm.class_triv thy) classes @
   168     List.mapPartial (Option.map #intro o lookup_axclass_info thy) classes
   169   end;
   170 
   171 
   172 
   173 (** add axiomatic type classes **)
   174 
   175 local
   176 
   177 fun err_bad_axsort ax c =
   178   error ("Sort constraint in axiom " ^ quote ax ^ " not supersort of " ^ quote c);
   179 
   180 fun err_bad_tfrees ax =
   181   error ("More than one type variable in axiom " ^ quote ax);
   182 
   183 fun ext_axclass prep_class prep_axm prep_att (bclass, raw_super_classes) raw_axioms_atts thy =
   184   let
   185     val class = Sign.full_name thy bclass;
   186     val super_classes = map (prep_class thy) raw_super_classes;
   187     val axms = map (prep_axm thy o fst) raw_axioms_atts;
   188     val atts = map (map (prep_att thy) o snd) raw_axioms_atts;
   189 
   190     (*declare class*)
   191     val class_thy =
   192       thy |> Theory.add_classes_i [(bclass, super_classes)];
   193 
   194     (*prepare abstract axioms*)
   195     fun abs_axm ax =
   196       if null (term_tfrees ax) then
   197         Logic.mk_implies (Logic.mk_inclass (aT [], class), ax)
   198       else map_term_tfrees (K (aT [class])) ax;
   199     val abs_axms = map (abs_axm o #2) axms;
   200 
   201     fun axm_sort (name, ax) =
   202       (case term_tfrees ax of
   203         [] => []
   204       | [(_, S)] => if Sign.subsort class_thy ([class], S) then S else err_bad_axsort name class
   205       | _ => err_bad_tfrees name);
   206     val axS = Sign.certify_sort class_thy (List.concat (map axm_sort axms));
   207 
   208     val int_axm = Logic.close_form o map_term_tfrees (K (aT axS));
   209     fun inclass c = Logic.mk_inclass (aT axS, c);
   210 
   211     val intro_axm = Logic.list_implies
   212       (map inclass super_classes @ map (int_axm o #2) axms, inclass class);
   213 
   214     (*declare axioms and rule*)
   215     val (axms_thy, ([intro], [axioms])) =
   216       class_thy
   217       |> Theory.add_path bclass
   218       |> PureThy.add_axioms_i [Thm.no_attributes (introN, intro_axm)]
   219       |>>> PureThy.add_axiomss_i [Thm.no_attributes (axiomsN, abs_axms)];
   220     val info = {super_classes = super_classes, intro = intro, axioms = axioms};
   221 
   222     (*store info*)
   223     val final_thy =
   224       axms_thy
   225       |> (#1 o PureThy.add_thms ((map #1 axms ~~ axioms) ~~ atts))
   226       |> Theory.restore_naming class_thy
   227       |> (#1 o PureThy.add_thms [Thm.no_attributes (intro_name bclass, intro)])
   228       |> put_axclass_info class info;
   229   in (final_thy, {intro = intro, axioms = axioms}) end;
   230 
   231 in
   232 
   233 val add_axclass = ext_axclass Sign.intern_class Theory.read_axm Attrib.global_attribute;
   234 val add_axclass_i = ext_axclass (K I) Theory.cert_axm (K I);
   235 
   236 end;
   237 
   238 
   239 
   240 (** proven class instantiation **)
   241 
   242 (* add thms to type signature *)
   243 
   244 fun add_classrel_thms thms thy =
   245   let
   246     fun prep_thm thm =
   247       let
   248         val prop = Drule.plain_prop_of (Thm.transfer thy thm);
   249         val (c1, c2) = dest_classrel prop handle TERM _ =>
   250           raise THM ("add_classrel_thms: not a class relation", 0, [thm]);
   251       in (c1, c2) end;
   252   in Theory.add_classrel_i (map prep_thm thms) thy end;
   253 
   254 fun add_arity_thms thms thy =
   255   let
   256     fun prep_thm thm =
   257       let
   258         val prop = Drule.plain_prop_of (Thm.transfer thy thm);
   259         val (t, ss, c) = dest_arity prop handle TERM _ =>
   260           raise THM ("add_arity_thms: not an arity", 0, [thm]);
   261       in (t, ss, [c]) end;
   262   in Theory.add_arities_i (map prep_thm thms) thy end;
   263 
   264 
   265 (* prepare classes and arities *)
   266 
   267 fun read_class thy c = Sign.certify_class thy (Sign.intern_class thy c);
   268 
   269 fun test_classrel thy cc = (Type.add_classrel (Sign.pp thy) [cc] (Sign.tsig_of thy); cc);
   270 fun cert_classrel thy = test_classrel thy o Library.pairself (Sign.certify_class thy);
   271 fun read_classrel thy = test_classrel thy o Library.pairself (read_class thy);
   272 
   273 fun test_arity thy ar = (Type.add_arities (Sign.pp thy) [ar] (Sign.tsig_of thy); ar);
   274 
   275 fun prep_arity prep_tycon prep_sort prep thy (t, Ss, x) =
   276   test_arity thy (prep_tycon thy t, map (prep_sort thy) Ss, prep thy x);
   277 
   278 val read_arity = prep_arity Sign.intern_type Sign.read_sort Sign.read_sort;
   279 val cert_arity = prep_arity (K I) Sign.certify_sort Sign.certify_sort;
   280 
   281 
   282 (* instance declarations -- tactical proof *)
   283 
   284 local
   285 
   286 fun ext_inst_subclass prep_classrel raw_cc tac thy =
   287   let
   288     val (c1, c2) = prep_classrel thy raw_cc;
   289     val txt = quote (Sign.string_of_classrel thy [c1, c2]);
   290     val _ = message ("Proving class inclusion " ^ txt ^ " ...");
   291     val th = Tactic.prove thy [] [] (mk_classrel (c1, c2)) (K tac) handle ERROR =>
   292       error ("The error(s) above occurred while trying to prove " ^ txt);
   293   in add_classrel_thms [th] thy end;
   294 
   295 fun ext_inst_arity prep_arity raw_arity tac thy =
   296   let
   297     val arity = prep_arity thy raw_arity;
   298     val txt = quote (Sign.string_of_arity thy arity);
   299     val _ = message ("Proving type arity " ^ txt ^ " ...");
   300     val props = (mk_arities arity);
   301     val ths = Tactic.prove_multi thy [] [] props
   302         (fn _ => Tactic.smart_conjunction_tac (length props) THEN tac)
   303       handle ERROR => error ("The error(s) above occurred while trying to prove " ^ txt);
   304   in add_arity_thms ths thy end;
   305 
   306 in
   307 
   308 val add_inst_subclass = ext_inst_subclass read_classrel;
   309 val add_inst_subclass_i = ext_inst_subclass cert_classrel;
   310 val add_inst_arity = ext_inst_arity read_arity;
   311 val add_inst_arity_i = ext_inst_arity cert_arity;
   312 
   313 end;
   314 
   315 
   316 (* instance declarations -- Isar proof *)
   317 
   318 local
   319 
   320 fun inst_proof mk_prop add_thms inst int theory =
   321   theory
   322   |> IsarThy.multi_theorem_i Drule.internalK (K I) ProofContext.export_standard
   323     ("", [fn (thy, th) => (add_thms [th] thy, th)]) []
   324     (map (fn t => (("", []), [(t, ([], []))])) (mk_prop theory inst)) int;
   325 
   326 in
   327 
   328 val instance_subclass_proof =
   329   inst_proof (single oo (mk_classrel oo read_classrel)) add_classrel_thms;
   330 val instance_subclass_proof_i =
   331   inst_proof (single oo (mk_classrel oo cert_classrel)) add_classrel_thms;
   332 val instance_arity_proof = inst_proof (mk_arities oo read_arity) add_arity_thms;
   333 val instance_arity_proof_i = inst_proof (mk_arities oo cert_arity) add_arity_thms;
   334 
   335 end;
   336 
   337 
   338 (* tactics and methods *)
   339 
   340 fun intro_classes_tac facts st =
   341   (ALLGOALS (Method.insert_tac facts THEN'
   342       REPEAT_ALL_NEW (resolve_tac (class_axms (Thm.theory_of_thm st))))
   343     THEN Tactic.distinct_subgoals_tac) st;
   344 
   345 fun default_intro_classes_tac [] = intro_classes_tac []
   346   | default_intro_classes_tac _ = Tactical.no_tac;    (*no error message!*)
   347 
   348 fun default_tac rules ctxt facts =
   349   HEADGOAL (Method.some_rule_tac rules ctxt facts) ORELSE
   350     default_intro_classes_tac facts;
   351 
   352 val _ = Context.add_setup [Method.add_methods
   353  [("intro_classes", Method.no_args (Method.METHOD intro_classes_tac),
   354    "back-chain introduction rules of axiomatic type classes"),
   355   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac), "apply some intro/elim rule")]];
   356 
   357 
   358 
   359 (** outer syntax **)
   360 
   361 local structure P = OuterParse and K = OuterSyntax.Keyword in
   362 
   363 val axclassP =
   364   OuterSyntax.command "axclass" "define axiomatic type class" K.thy_decl
   365     ((P.name -- Scan.optional ((P.$$$ "\\<subseteq>" || P.$$$ "<") |--
   366         P.!!! (P.list1 P.xname)) []) -- Scan.repeat P.spec_name
   367       >> (fn (cls, axs) => Toplevel.theory (#1 o add_axclass cls axs)));
   368 
   369 val instanceP =
   370   OuterSyntax.command "instance" "prove type arity or subclass relation" K.thy_goal
   371     ((P.xname -- ((P.$$$ "\\<subseteq>" || P.$$$ "<") |-- P.xname) >> instance_subclass_proof ||
   372       (P.xname -- (P.$$$ "::" |-- P.arity) >> P.triple2) >> instance_arity_proof)
   373       >> (Toplevel.print oo Toplevel.theory_to_proof));
   374 
   375 val _ = OuterSyntax.add_parsers [axclassP, instanceP];
   376 
   377 end;
   378 
   379 
   380 
   381 (** old-style instantiation proofs **)
   382 
   383 (* axclass_tac *)
   384 
   385 (*(1) repeatedly resolve goals of form "OFCLASS(ty, c_class)",
   386       try class_trivs first, then "cI" axioms
   387   (2) rewrite goals using user supplied definitions
   388   (3) repeatedly resolve goals with user supplied non-definitions*)
   389 
   390 val is_def = Logic.is_equals o #prop o rep_thm;
   391 
   392 fun axclass_tac thms =
   393   let
   394     val defs = List.filter is_def thms;
   395     val non_defs = filter_out is_def thms;
   396   in
   397     intro_classes_tac [] THEN
   398     TRY (rewrite_goals_tac defs) THEN
   399     TRY (REPEAT_FIRST (fn i => assume_tac i ORELSE resolve_tac non_defs i))
   400   end;
   401 
   402 
   403 (* instance declarations *)
   404 
   405 local
   406 
   407 fun prove mk_prop str_of thy prop thms usr_tac =
   408   (Tactic.prove thy [] [] (mk_prop prop)
   409       (K (axclass_tac thms THEN (if_none usr_tac all_tac)))
   410     handle ERROR => error ("The error(s) above occurred while trying to prove " ^
   411      quote (str_of thy prop))) |> Drule.standard;
   412 
   413 val prove_subclass = prove mk_classrel (fn thy => fn (c1, c2) =>
   414   Pretty.string_of_classrel (Sign.pp thy) [c1, c2]);
   415 
   416 val prove_arity = prove mk_arity (fn thy => fn (t, Ss, c) =>
   417   Pretty.string_of_arity (Sign.pp thy) (t, Ss, [c]));
   418 
   419 fun witnesses thy names thms =
   420   PureThy.get_thmss thy (map Name names) @
   421   thms @
   422   List.filter is_def (map snd (axioms_of thy));
   423 
   424 in
   425 
   426 fun add_inst_subclass_x raw_c1_c2 names thms usr_tac thy =
   427   let val (c1, c2) = read_classrel thy raw_c1_c2 in
   428     message ("Proving class inclusion " ^ quote (Sign.string_of_classrel thy [c1, c2]) ^ " ...");
   429     thy |> add_classrel_thms [prove_subclass thy (c1, c2) (witnesses thy names thms) usr_tac]
   430   end;
   431 
   432 fun add_inst_arity_x raw_arity names thms usr_tac thy =
   433   let
   434     val (t, Ss, cs) = read_arity thy raw_arity;
   435     val wthms = witnesses thy names thms;
   436     fun prove c =
   437      (message ("Proving type arity " ^
   438         quote (Sign.string_of_arity thy (t, Ss, [c])) ^ " ...");
   439         prove_arity thy (t, Ss, c) wthms usr_tac);
   440   in add_arity_thms (map prove cs) thy end;
   441 
   442 end;
   443 
   444 end;