src/Pure/axclass.ML
author wenzelm
Wed Oct 28 16:25:27 2009 +0100 (2009-10-28 ago)
changeset 33278 ba9f52f56356
parent 33173 b8ca12f6681a
child 33315 784c1b09d485
permissions -rw-r--r--
conceal internal bindings;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val define_class: binding * class list -> string list ->
    11     (Thm.binding * term list) list -> theory -> class * theory
    12   val add_classrel: thm -> theory -> theory
    13   val add_arity: thm -> theory -> theory
    14   val prove_classrel: class * class -> tactic -> theory -> theory
    15   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    16   val get_info: theory -> class ->
    17     {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    18   val class_intros: theory -> thm list
    19   val class_of_param: theory -> string -> class option
    20   val cert_classrel: theory -> class * class -> class * class
    21   val read_classrel: theory -> xstring * xstring -> class * class
    22   val axiomatize_class: binding * class list -> theory -> theory
    23   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    24   val axiomatize_classrel: (class * class) list -> theory -> theory
    25   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    26   val axiomatize_arity: arity -> theory -> theory
    27   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    28   val instance_name: string * class -> string
    29   val declare_overloaded: string * typ -> theory -> term * theory
    30   val define_overloaded: binding -> string * term -> theory -> thm * theory
    31   val unoverload: theory -> thm -> thm
    32   val overload: theory -> thm -> thm
    33   val unoverload_conv: theory -> conv
    34   val overload_conv: theory -> conv
    35   val unoverload_const: theory -> string * typ -> string
    36   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    37   val param_of_inst: theory -> string * string -> string
    38   val inst_of_param: theory -> string -> (string * string) option
    39   val thynames_of_arity: theory -> class * string -> string list
    40   type cache
    41   val of_sort: theory -> typ * sort -> cache -> thm list * cache  (*exception Sorts.CLASS_ERROR*)
    42   val cache: cache
    43   val introN: string
    44   val axiomsN: string
    45 end;
    46 
    47 structure AxClass: AX_CLASS =
    48 struct
    49 
    50 (** theory data **)
    51 
    52 (* class parameters (canonical order) *)
    53 
    54 type param = string * class;
    55 
    56 fun add_param pp ((x, c): param) params =
    57   (case AList.lookup (op =) params x of
    58     NONE => (x, c) :: params
    59   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    60       " for " ^ Pretty.string_of_sort pp [c] ^
    61       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    62 
    63 fun merge_params _ ([], qs) = qs
    64   | merge_params pp (ps, qs) =
    65       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    66 
    67 
    68 (* axclasses *)
    69 
    70 val introN = "intro";
    71 val superN = "super";
    72 val axiomsN = "axioms";
    73 
    74 datatype axclass = AxClass of
    75  {def: thm,
    76   intro: thm,
    77   axioms: thm list,
    78   params: (string * typ) list};
    79 
    80 type axclasses = axclass Symtab.table * param list;
    81 
    82 fun make_axclass ((def, intro, axioms), params) = AxClass
    83   {def = def, intro = intro, axioms = axioms, params = params};
    84 
    85 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    86   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    87 
    88 
    89 (* instances *)
    90 
    91 val classrel_prefix = "classrel_";
    92 val arity_prefix = "arity_";
    93 
    94 type instances =
    95   ((class * class) * thm) list *  (*classrel theorems*)
    96   ((class * sort list) * (thm * string)) list Symtab.table;  (*arity theorems with theory name*)
    97 
    98 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    99  (merge (eq_fst op =) (classrel1, classrel2),
   100   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
   101 
   102 
   103 (* instance parameters *)
   104 
   105 type inst_params =
   106   (string * thm) Symtab.table Symtab.table
   107     (*constant name ~> type constructor ~> (constant name, equation)*)
   108   * (string * string) Symtab.table; (*constant name ~> (constant name, type constructor)*)
   109 
   110 fun merge_inst_params ((const_param1, param_const1), (const_param2, param_const2)) =
   111   (Symtab.join  (K (Symtab.merge (K true))) (const_param1, const_param2),
   112     Symtab.merge (K true) (param_const1, param_const2));
   113 
   114 
   115 (* setup data *)
   116 
   117 structure AxClassData = TheoryDataFun
   118 (
   119   type T = axclasses * (instances * inst_params);
   120   val empty = ((Symtab.empty, []), (([], Symtab.empty), (Symtab.empty, Symtab.empty)));
   121   val copy = I;
   122   val extend = I;
   123   fun merge pp ((axclasses1, (instances1, inst_params1)), (axclasses2, (instances2, inst_params2))) =
   124     (merge_axclasses pp (axclasses1, axclasses2),
   125       (merge_instances (instances1, instances2), merge_inst_params (inst_params1, inst_params2)));
   126 );
   127 
   128 
   129 (* maintain axclasses *)
   130 
   131 val get_axclasses = #1 o AxClassData.get;
   132 val map_axclasses = AxClassData.map o apfst;
   133 
   134 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   135 
   136 fun get_info thy c =
   137   (case lookup_def thy c of
   138     SOME (AxClass info) => info
   139   | NONE => error ("No such axclass: " ^ quote c));
   140 
   141 fun class_intros thy =
   142   let
   143     fun add_intro c =
   144       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   145     val classes = Sign.all_classes thy;
   146   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   147 
   148 
   149 fun get_params thy pred =
   150   let val params = #2 (get_axclasses thy);
   151   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   152 
   153 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   154 
   155 fun class_of_param thy = AList.lookup (op =) (#2 (get_axclasses thy));
   156 
   157 
   158 (* maintain instances *)
   159 
   160 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   161 
   162 val get_instances = #1 o #2 o AxClassData.get;
   163 val map_instances = AxClassData.map o apsnd o apfst;
   164 
   165 
   166 fun the_classrel thy (c1, c2) =
   167   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   168     SOME th => Thm.transfer thy th
   169   | NONE => error ("Unproven class relation " ^
   170       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   171 
   172 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   173   (insert (eq_fst op =) arg classrel, arities));
   174 
   175 
   176 fun the_arity thy a (c, Ss) =
   177   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss) of
   178     SOME (th, _) => Thm.transfer thy th
   179   | NONE => error ("Unproven type arity " ^
   180       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   181 
   182 fun thynames_of_arity thy (c, a) =
   183   Symtab.lookup_list (#2 (get_instances thy)) a
   184   |> map_filter (fn ((c', _), (_, name)) => if c = c' then SOME name else NONE)
   185   |> rev;
   186 
   187 fun insert_arity_completions thy (t, ((c, Ss), (th, thy_name))) arities =
   188   let
   189     val algebra = Sign.classes_of thy;
   190     val super_class_completions =
   191       Sign.super_classes thy c
   192       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) => c1 = c2
   193           andalso Sorts.sorts_le algebra (Ss2, Ss)) (Symtab.lookup_list arities t));
   194     val completions = map (fn c1 => (Sorts.weaken algebra
   195       (fn (th, c2) => fn c3 => th RS the_classrel thy (c2, c3)) (th, c) c1
   196         |> Thm.close_derivation, c1)) super_class_completions;
   197     val arities' = fold (fn (th1, c1) => Symtab.cons_list (t, ((c1, Ss), (th1, thy_name))))
   198       completions arities;
   199   in (null completions, arities') end;
   200 
   201 fun put_arity ((t, Ss, c), th) thy =
   202   let
   203     val arity' = (t, ((c, Ss), (th, Context.theory_name thy)));
   204   in
   205     thy
   206     |> map_instances (fn (classrel, arities) => (classrel,
   207       arities
   208       |> Symtab.insert_list (eq_fst op =) arity'
   209       |> insert_arity_completions thy arity'
   210       |> snd))
   211   end;
   212 
   213 fun complete_arities thy =
   214   let
   215     val arities = snd (get_instances thy);
   216     val (finished, arities') = arities
   217       |> fold_map (insert_arity_completions thy) (Symtab.dest_list arities);
   218   in
   219     if forall I finished then NONE
   220     else SOME (thy |> map_instances (fn (classrel, _) => (classrel, arities')))
   221   end;
   222 
   223 val _ = Context.>> (Context.map_theory (Theory.at_begin complete_arities));
   224 
   225 
   226 (* maintain instance parameters *)
   227 
   228 val get_inst_params = #2 o #2 o AxClassData.get;
   229 val map_inst_params = AxClassData.map o apsnd o apsnd;
   230 
   231 fun get_inst_param thy (c, tyco) =
   232   case Symtab.lookup ((the_default Symtab.empty o Symtab.lookup (fst (get_inst_params thy))) c) tyco
   233    of SOME c' => c'
   234     | NONE => error ("No instance parameter for constant " ^ quote c
   235         ^ " on type constructor " ^ quote tyco);
   236 
   237 fun add_inst_param (c, tyco) inst = (map_inst_params o apfst
   238       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   239   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   240 
   241 val inst_of_param = Symtab.lookup o snd o get_inst_params;
   242 val param_of_inst = fst oo get_inst_param;
   243 
   244 fun inst_thms thy = (Symtab.fold (Symtab.fold (cons o snd o snd) o snd) o fst)
   245   (get_inst_params thy) [];
   246 
   247 fun get_inst_tyco consts = try (fst o dest_Type o the_single o Consts.typargs consts);
   248 
   249 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   250 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   251 
   252 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   253 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   254 
   255 fun lookup_inst_param consts params (c, T) = case get_inst_tyco consts (c, T)
   256  of SOME tyco => AList.lookup (op =) params (c, tyco)
   257   | NONE => NONE;
   258 
   259 fun unoverload_const thy (c_ty as (c, _)) =
   260   case class_of_param thy c
   261    of SOME class (* FIXME unused? *) =>
   262      (case get_inst_tyco (Sign.consts_of thy) c_ty
   263        of SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   264         | NONE => c)
   265     | NONE => c;
   266 
   267 
   268 (** instances **)
   269 
   270 (* class relations *)
   271 
   272 fun cert_classrel thy raw_rel =
   273   let
   274     val string_of_sort = Syntax.string_of_sort_global thy;
   275     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   276     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   277     val _ =
   278       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   279         [] => ()
   280       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   281           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   282   in (c1, c2) end;
   283 
   284 fun read_classrel thy raw_rel =
   285   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
   286     handle TYPE (msg, _, _) => error msg;
   287 
   288 
   289 (* declaration and definition of instances of overloaded constants *)
   290 
   291 fun inst_tyco_of thy (c, T) = case get_inst_tyco (Sign.consts_of thy) (c, T)
   292  of SOME tyco => tyco
   293   | NONE => error ("Illegal type for instantiation of class parameter: "
   294       ^ quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T));
   295 
   296 fun declare_overloaded (c, T) thy =
   297   let
   298     val class = case class_of_param thy c
   299      of SOME class => class
   300       | NONE => error ("Not a class parameter: " ^ quote c);
   301     val tyco = inst_tyco_of thy (c, T);
   302     val name_inst = instance_name (tyco, class) ^ "_inst";
   303     val c' = Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco;
   304     val T' = Type.strip_sorts T;
   305   in
   306     thy
   307     |> Sign.mandatory_path name_inst
   308     |> Sign.declare_const ((Binding.name c', T'), NoSyn)
   309     |-> (fn const' as Const (c'', _) =>
   310       Thm.add_def false true
   311         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   312       #>> Thm.varifyT
   313       #-> (fn thm => add_inst_param (c, tyco) (c'', thm)
   314       #> PureThy.add_thm ((Binding.conceal (Binding.name c'), thm), [Thm.kind_internal])
   315       #> snd
   316       #> Sign.restore_naming thy
   317       #> pair (Const (c, T))))
   318   end;
   319 
   320 fun define_overloaded b (c, t) thy =
   321   let
   322     val T = Term.fastype_of t;
   323     val tyco = inst_tyco_of thy (c, T);
   324     val (c', eq) = get_inst_param thy (c, tyco);
   325     val prop = Logic.mk_equals (Const (c', T), t);
   326     val b' = Thm.def_binding_optional
   327       (Binding.name (Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco)) b;
   328   in
   329     thy
   330     |> Thm.add_def false false (b', prop)
   331     |>> (fn thm =>  Drule.transitive_thm OF [eq, thm])
   332   end;
   333 
   334 
   335 (* primitive rules *)
   336 
   337 fun add_classrel raw_th thy =
   338   let
   339     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   340     val prop = Thm.plain_prop_of th;
   341     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   342     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   343     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   344   in
   345     thy
   346     |> Sign.primitive_classrel (c1, c2)
   347     |> put_classrel ((c1, c2), Thm.close_derivation (Drule.unconstrainTs th))
   348     |> perhaps complete_arities
   349   end;
   350 
   351 fun add_arity raw_th thy =
   352   let
   353     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   354     val prop = Thm.plain_prop_of th;
   355     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   356     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   357     val T = Type (t, map TFree (Name.names Name.context Name.aT Ss));
   358     val missing_params = Sign.complete_sort thy [c]
   359       |> maps (these o Option.map #params o try (get_info thy))
   360       |> filter_out (fn (const, _) => can (get_inst_param thy) (const, t))
   361       |> (map o apsnd o map_atyps) (K T);
   362     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   363   in
   364     thy
   365     |> fold (snd oo declare_overloaded) missing_params
   366     |> Sign.primitive_arity (t, Ss, [c])
   367     |> put_arity ((t, Ss, c), Thm.close_derivation (Drule.unconstrainTs th))
   368   end;
   369 
   370 
   371 (* tactical proofs *)
   372 
   373 fun prove_classrel raw_rel tac thy =
   374   let
   375     val ctxt = ProofContext.init thy;
   376     val (c1, c2) = cert_classrel thy raw_rel;
   377     val th = Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   378       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   379         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   380   in
   381     thy
   382     |> PureThy.add_thms [((Binding.name
   383         (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th), [])]
   384     |-> (fn [th'] => add_classrel th')
   385   end;
   386 
   387 fun prove_arity raw_arity tac thy =
   388   let
   389     val ctxt = ProofContext.init thy;
   390     val arity = Sign.cert_arity thy raw_arity;
   391     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   392     val props = Logic.mk_arities arity;
   393     val ths = Goal.prove_multi ctxt [] [] props
   394       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   395         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   396           quote (Syntax.string_of_arity ctxt arity));
   397   in
   398     thy
   399     |> PureThy.add_thms (map (rpair []) (map Binding.name names ~~ ths))
   400     |-> fold add_arity
   401   end;
   402 
   403 
   404 
   405 (** class definitions **)
   406 
   407 fun split_defined n eq =
   408   let
   409     val intro =
   410       (eq RS Drule.equal_elim_rule2)
   411       |> Conjunction.curry_balanced n
   412       |> n = 0 ? Thm.eq_assumption 1;
   413     val dests =
   414       if n = 0 then []
   415       else
   416         (eq RS Drule.equal_elim_rule1)
   417         |> Balanced_Tree.dest (fn th =>
   418           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   419   in (intro, dests) end;
   420 
   421 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   422   let
   423     val ctxt = ProofContext.init thy;
   424     val pp = Syntax.pp ctxt;
   425 
   426 
   427     (* class *)
   428 
   429     val bconst = Binding.map_name Logic.const_of_class bclass;
   430     val class = Sign.full_name thy bclass;
   431     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   432 
   433     fun check_constraint (a, S) =
   434       if Sign.subsort thy (super, S) then ()
   435       else error ("Sort constraint of type variable " ^
   436         setmp_CRITICAL show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   437         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   438 
   439 
   440     (* params *)
   441 
   442     val params = raw_params |> map (fn p =>
   443       let
   444         val T = Sign.the_const_type thy p;
   445         val _ =
   446           (case Term.add_tvarsT T [] of
   447             [((a, _), S)] => check_constraint (a, S)
   448           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   449         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   450       in (p, T') end);
   451 
   452 
   453     (* axioms *)
   454 
   455     fun prep_axiom t =
   456       (case Term.add_tfrees t [] of
   457         [(a, S)] => check_constraint (a, S)
   458       | [] => ()
   459       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   460       t
   461       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   462       |> Logic.close_form);
   463 
   464     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   465     val name_atts = map fst raw_specs;
   466 
   467 
   468     (* definition *)
   469 
   470     val conjs = map (curry Logic.mk_of_class (Term.aT [])) super @ flat axiomss;
   471     val class_eq =
   472       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   473 
   474     val ([def], def_thy) =
   475       thy
   476       |> Sign.primitive_class (bclass, super)
   477       |> PureThy.add_defs false [((Binding.map_name Thm.def_name bconst, class_eq), [])];
   478     val (raw_intro, (raw_classrel, raw_axioms)) =
   479       split_defined (length conjs) def ||> chop (length super);
   480 
   481 
   482     (* facts *)
   483 
   484     val class_triv = Thm.class_triv def_thy class;
   485     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   486       def_thy
   487       |> Sign.mandatory_path (Binding.name_of bconst)
   488       |> PureThy.note_thmss ""
   489         [((Binding.name introN, []), [([Drule.standard raw_intro], [])]),
   490          ((Binding.name superN, []), [(map Drule.standard raw_classrel, [])]),
   491          ((Binding.name axiomsN, []),
   492            [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])]
   493       ||> Sign.restore_naming def_thy;
   494 
   495 
   496     (* result *)
   497 
   498     val axclass = make_axclass ((def, intro, axioms), params);
   499     val result_thy =
   500       facts_thy
   501       |> fold put_classrel (map (pair class) super ~~ classrel)
   502       |> Sign.add_path (Binding.name_of bconst)
   503       |> PureThy.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   504       |> Sign.restore_naming facts_thy
   505       |> map_axclasses (fn (axclasses, parameters) =>
   506         (Symtab.update (class, axclass) axclasses,
   507           fold (fn (x, _) => add_param pp (x, class)) params parameters));
   508 
   509   in (class, result_thy) end;
   510 
   511 
   512 
   513 (** axiomatizations **)
   514 
   515 local
   516 
   517 fun axiomatize prep mk name add raw_args thy =
   518   let
   519     val args = prep thy raw_args;
   520     val specs = mk args;
   521     val names = name args;
   522   in
   523     thy
   524     |> PureThy.add_axioms (map (rpair []) (map Binding.name names ~~ specs))
   525     |-> fold add
   526   end;
   527 
   528 fun ax_classrel prep =
   529   axiomatize (map o prep) (map Logic.mk_classrel)
   530     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   531 
   532 fun ax_arity prep =
   533   axiomatize prep Logic.mk_arities
   534     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   535 
   536 fun class_const c =
   537   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   538 
   539 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   540   let
   541     val class = Sign.full_name thy bclass;
   542     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   543   in
   544     thy
   545     |> Sign.primitive_class (bclass, super)
   546     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   547     |> Theory.add_deps "" (class_const class) (map class_const super)
   548   end;
   549 
   550 in
   551 
   552 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   553 val axiomatize_class_cmd = ax_class Sign.read_class read_classrel;
   554 val axiomatize_classrel = ax_classrel cert_classrel;
   555 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   556 val axiomatize_arity = ax_arity Sign.cert_arity;
   557 val axiomatize_arity_cmd = ax_arity Sign.read_arity;
   558 
   559 end;
   560 
   561 
   562 
   563 (** explicit derivations -- cached **)
   564 
   565 datatype cache = Types of (class * thm) list Typtab.table;
   566 
   567 local
   568 
   569 fun lookup_type (Types cache) = AList.lookup (op =) o Typtab.lookup_list cache;
   570 fun insert_type T der (Types cache) = Types (Typtab.insert_list (eq_fst op =) (T, der) cache);
   571 
   572 fun derive_type _ (_, []) = []
   573   | derive_type thy (typ, sort) =
   574       let
   575         val certT = Thm.ctyp_of thy;
   576         val vars = Term.fold_atyps
   577             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
   578               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
   579               | _ => I) typ [];
   580         val hyps = vars
   581           |> map (fn (T, S) => (T, Thm.of_sort (certT T, S) ~~ S));
   582         val ths = (typ, sort)
   583           |> Sorts.of_sort_derivation (Sign.classes_of thy)
   584            {class_relation =
   585               fn (th, c1) => fn c2 => th RS the_classrel thy (c1, c2),
   586             type_constructor =
   587               fn a => fn dom => fn c =>
   588                 let val Ss = map (map snd) dom and ths = maps (map fst) dom
   589                 in ths MRS the_arity thy a (c, Ss) end,
   590             type_variable =
   591               the_default [] o AList.lookup (op =) hyps};
   592       in ths end;
   593 
   594 in
   595 
   596 fun of_sort thy (typ, sort) cache =
   597   let
   598     val sort' = filter (is_none o lookup_type cache typ) sort;
   599     val ths' = derive_type thy (typ, sort')
   600       handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
   601         Syntax.string_of_typ_global thy typ ^ " :: " ^ Syntax.string_of_sort_global thy sort');
   602     val cache' = cache |> fold (insert_type typ) (sort' ~~ ths');
   603     val ths =
   604       sort |> map (fn c =>
   605         Goal.finish
   606           (Syntax.init_pretty_global thy)
   607           (the (lookup_type cache' typ c) RS
   608             Goal.init (Thm.cterm_of thy (Logic.mk_of_class (typ, c))))
   609         |> Thm.adjust_maxidx_thm ~1);
   610   in (ths, cache') end;
   611 
   612 end;
   613 
   614 val cache = Types Typtab.empty;
   615 
   616 end;