src/Pure/axclass.ML
author haftmann
Tue Jul 08 18:13:10 2008 +0200 (2008-07-08 ago)
changeset 27497 c683836fe908
parent 27397 1d8456c5d53d
child 27547 13199740ced6
permissions -rw-r--r--
refined arity property concept
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Type classes defined as predicates, associated with a record of
     6 parameters.
     7 *)
     8 
     9 signature AX_CLASS =
    10 sig
    11   val define_class: bstring * class list -> string list ->
    12     ((bstring * attribute list) * term list) list -> theory -> class * theory
    13   val add_classrel: thm -> theory -> theory
    14   val add_arity: thm -> theory -> theory
    15   val prove_classrel: class * class -> tactic -> theory -> theory
    16   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    17   val get_info: theory -> class ->
    18     {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    19   val class_intros: theory -> thm list
    20   val class_of_param: theory -> string -> class option
    21   val cert_classrel: theory -> class * class -> class * class
    22   val read_classrel: theory -> xstring * xstring -> class * class
    23   val axiomatize_class: bstring * class list -> theory -> theory
    24   val axiomatize_class_cmd: bstring * xstring list -> theory -> theory
    25   val axiomatize_classrel: (class * class) list -> theory -> theory
    26   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    27   val axiomatize_arity: arity -> theory -> theory
    28   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    29   val instance_name: string * class -> string
    30   val declare_overloaded: string * typ -> theory -> term * theory
    31   val define_overloaded: string -> string * term -> theory -> thm * theory
    32   val inst_tyco_of: theory -> string * typ -> string option
    33   val unoverload: theory -> thm -> thm
    34   val overload: theory -> thm -> thm
    35   val unoverload_conv: theory -> conv
    36   val overload_conv: theory -> conv
    37   val unoverload_const: theory -> string * typ -> string
    38   val param_of_inst: theory -> string * string -> string
    39   val inst_of_param: theory -> string -> (string * string) option
    40   val arity_property: theory -> class * string -> string -> string list
    41   type cache
    42   val of_sort: theory -> typ * sort -> cache -> thm list * cache  (*exception Sorts.CLASS_ERROR*)
    43   val cache: cache
    44   val introN: string
    45   val axiomsN: string
    46 end;
    47 
    48 structure AxClass: AX_CLASS =
    49 struct
    50 
    51 (** theory data **)
    52 
    53 (* class parameters (canonical order) *)
    54 
    55 type param = string * class;
    56 
    57 fun add_param pp ((x, c): param) params =
    58   (case AList.lookup (op =) params x of
    59     NONE => (x, c) :: params
    60   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    61       " for " ^ Pretty.string_of_sort pp [c] ^
    62       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    63 
    64 fun merge_params _ ([], qs) = qs
    65   | merge_params pp (ps, qs) =
    66       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    67 
    68 
    69 (* axclasses *)
    70 
    71 val introN = "intro";
    72 val superN = "super";
    73 val axiomsN = "axioms";
    74 
    75 datatype axclass = AxClass of
    76  {def: thm,
    77   intro: thm,
    78   axioms: thm list,
    79   params: (string * typ) list};
    80 
    81 type axclasses = axclass Symtab.table * param list;
    82 
    83 fun make_axclass ((def, intro, axioms), params) = AxClass
    84   {def = def, intro = intro, axioms = axioms, params = params};
    85 
    86 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    87   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    88 
    89 
    90 (* instances *)
    91 
    92 val classrel_prefix = "classrel_";
    93 val arity_prefix = "arity_";
    94 
    95 type instances =
    96   ((class * class) * thm) list *
    97   ((class * sort list) * thm) list Symtab.table;
    98 
    99 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
   100  (merge (eq_fst op =) (classrel1, classrel2),
   101   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
   102 
   103 
   104 (* instance parameters *)
   105 
   106 type inst_params =
   107   (string * thm) Symtab.table Symtab.table
   108     (*constant name ~> type constructor ~> (constant name, equation)*)
   109   * (string * string) Symtab.table; (*constant name ~> (constant name, type constructor)*)
   110 
   111 fun merge_inst_params ((const_param1, param_const1), (const_param2, param_const2)) =
   112   (Symtab.join  (K (Symtab.merge (K true))) (const_param1, const_param2),
   113     Symtab.merge (K true) (param_const1, param_const2));
   114 
   115 
   116 (* setup data *)
   117 
   118 structure AxClassData = TheoryDataFun
   119 (
   120   type T = axclasses * (instances * inst_params);
   121   val empty = ((Symtab.empty, []), (([], Symtab.empty), (Symtab.empty, Symtab.empty)));
   122   val copy = I;
   123   val extend = I;
   124   fun merge pp ((axclasses1, (instances1, inst_params1)), (axclasses2, (instances2, inst_params2))) =
   125     (merge_axclasses pp (axclasses1, axclasses2),
   126       (merge_instances (instances1, instances2), merge_inst_params (inst_params1, inst_params2)));
   127 );
   128 
   129 
   130 (* maintain axclasses *)
   131 
   132 val get_axclasses = #1 o AxClassData.get;
   133 val map_axclasses = AxClassData.map o apfst;
   134 
   135 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   136 
   137 fun get_info thy c =
   138   (case lookup_def thy c of
   139     SOME (AxClass info) => info
   140   | NONE => error ("No such axclass: " ^ quote c));
   141 
   142 fun class_intros thy =
   143   let
   144     fun add_intro c =
   145       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   146     val classes = Sign.all_classes thy;
   147   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   148 
   149 
   150 fun get_params thy pred =
   151   let val params = #2 (get_axclasses thy);
   152   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   153 
   154 fun params_of thy c = get_params thy (fn c' => c' = c);
   155 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   156 
   157 fun class_of_param thy = AList.lookup (op =) (#2 (get_axclasses thy));
   158 
   159 
   160 (* maintain instances *)
   161 
   162 fun instance_name (a, c) = NameSpace.base c ^ "_" ^ NameSpace.base a;
   163 
   164 val get_instances = #1 o #2 o AxClassData.get;
   165 val map_instances = AxClassData.map o apsnd o apfst;
   166 
   167 
   168 fun the_classrel thy (c1, c2) =
   169   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   170     SOME th => Thm.transfer thy th
   171   | NONE => error ("Unproven class relation " ^
   172       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   173 
   174 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   175   (insert (eq_fst op =) arg classrel, arities));
   176 
   177 
   178 fun the_arity thy a (c, Ss) =
   179   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss) of
   180     SOME th => Thm.transfer thy th
   181   | NONE => error ("Unproven type arity " ^
   182       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   183 
   184 fun arity_property thy (c, a) x =
   185   these (Symtab.lookup (snd (get_instances thy)) a)
   186   |> map_filter (fn ((c', _), th) => if c = c'
   187         then AList.lookup (op =) (Thm.get_tags th) x else NONE)
   188   |> rev;
   189 
   190 fun put_arity ((t, Ss, c), th) = map_instances (fn (classrel, arities) =>
   191   (classrel, arities |> Symtab.insert_list (eq_fst op =) (t, ((c, Ss), th))));
   192 
   193 
   194 
   195 
   196 (* maintain instance parameters *)
   197 
   198 val get_inst_params = #2 o #2 o AxClassData.get;
   199 val map_inst_params = AxClassData.map o apsnd o apsnd;
   200 
   201 fun get_inst_param thy (c, tyco) =
   202   (the o Symtab.lookup ((the o Symtab.lookup (fst (get_inst_params thy))) c)) tyco;
   203 
   204 fun add_inst_param (c, tyco) inst = (map_inst_params o apfst
   205       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   206   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   207 
   208 val inst_of_param = Symtab.lookup o snd o get_inst_params;
   209 val param_of_inst = fst oo get_inst_param;
   210 
   211 fun inst_thms thy = (Symtab.fold (Symtab.fold (cons o snd o snd) o snd) o fst)
   212   (get_inst_params thy) [];
   213 
   214 fun inst_tyco_of thy = try (fst o dest_Type o the_single o Sign.const_typargs thy);
   215 
   216 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   217 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   218 
   219 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   220 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   221 
   222 fun unoverload_const thy (c_ty as (c, _)) =
   223   case class_of_param thy c
   224    of SOME class => (case inst_tyco_of thy c_ty
   225        of SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   226         | NONE => c)
   227     | NONE => c;
   228 
   229 
   230 (** instances **)
   231 
   232 (* class relations *)
   233 
   234 fun cert_classrel thy raw_rel =
   235   let
   236     val string_of_sort = Syntax.string_of_sort_global thy;
   237     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   238     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   239     val _ =
   240       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   241         [] => ()
   242       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   243           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   244   in (c1, c2) end;
   245 
   246 fun read_classrel thy raw_rel =
   247   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
   248     handle TYPE (msg, _, _) => error msg;
   249 
   250 
   251 (* primitive rules *)
   252 
   253 fun add_classrel th thy =
   254   let
   255     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   256     val prop = Thm.plain_prop_of (Thm.transfer thy th);
   257     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   258     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   259   in
   260     thy
   261     |> Sign.primitive_classrel (c1, c2)
   262     |> put_classrel ((c1, c2), Drule.unconstrainTs th)
   263   end;
   264 
   265 fun add_arity th thy =
   266   let
   267     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   268     val prop = Thm.plain_prop_of (Thm.transfer thy th);
   269     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   270     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   271     val _ = case filter_out (fn c => can (get_inst_param thy) (c, t)) (params_of thy c)
   272      of [] => ()
   273       | cs => Output.legacy_feature
   274           ("Missing specifications for overloaded parameters " ^ commas_quote cs)
   275     val th' = th
   276       |> Drule.unconstrainTs
   277       |> (Thm.map_tags o AList.default (op =))
   278           (Markup.theory_nameN, Context.theory_name thy)
   279   in
   280     thy
   281     |> Sign.primitive_arity (t, Ss, [c])
   282     |> put_arity ((t, Ss, c), th')
   283   end;
   284 
   285 
   286 (* tactical proofs *)
   287 
   288 fun prove_classrel raw_rel tac thy =
   289   let
   290     val ctxt = ProofContext.init thy;
   291     val (c1, c2) = cert_classrel thy raw_rel;
   292     val th = Goal.prove ctxt [] []
   293         (Logic.mk_classrel (c1, c2)) (fn _ => tac) handle ERROR msg =>
   294       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   295         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   296   in
   297     thy
   298     |> PureThy.add_thms [((prefix classrel_prefix (Logic.name_classrel (c1, c2)), th), [])]
   299     |-> (fn [th'] => add_classrel th')
   300   end;
   301 
   302 fun prove_arity raw_arity tac thy =
   303   let
   304     val ctxt = ProofContext.init thy;
   305     val arity = Sign.cert_arity thy raw_arity;
   306     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   307     val props = Logic.mk_arities arity;
   308     val ths = Goal.prove_multi ctxt [] [] props
   309       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   310         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   311           quote (Syntax.string_of_arity ctxt arity));
   312   in
   313     thy
   314     |> PureThy.add_thms (map (rpair []) (names ~~ ths))
   315     |-> fold add_arity
   316   end;
   317 
   318 
   319 (* instance parameters and overloaded definitions *)
   320 
   321 (* declaration and definition of instances of overloaded constants *)
   322 
   323 fun declare_overloaded (c, T) thy =
   324   let
   325     val class = case class_of_param thy c
   326      of SOME class => class
   327       | NONE => error ("Not a class parameter: " ^ quote c);
   328     val tyco = case inst_tyco_of thy (c, T)
   329      of SOME tyco => tyco
   330       | NONE => error ("Illegal type for instantiation of class parameter: "
   331         ^ quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T));
   332     val name_inst = instance_name (tyco, class) ^ "_inst";
   333     val c' = NameSpace.base c ^ "_" ^ NameSpace.base tyco;
   334     val T' = Type.strip_sorts T;
   335   in
   336     thy
   337     |> Sign.sticky_prefix name_inst
   338     |> Sign.no_base_names
   339     |> Sign.declare_const [] (c', T', NoSyn)
   340     |-> (fn const' as Const (c'', _) => Thm.add_def false true
   341           (Thm.def_name c', Logic.mk_equals (Const (c, T'), const'))
   342     #>> Thm.varifyT
   343     #-> (fn thm => add_inst_param (c, tyco) (c'', thm)
   344     #> PureThy.note Thm.internalK (c', thm)
   345     #> snd
   346     #> Sign.restore_naming thy
   347     #> pair (Const (c, T))))
   348   end;
   349 
   350 fun define_overloaded name (c, t) thy =
   351   let
   352     val T = Term.fastype_of t;
   353     val SOME tyco = inst_tyco_of thy (c, T);
   354     val (c', eq) = get_inst_param thy (c, tyco);
   355     val prop = Logic.mk_equals (Const (c', T), t);
   356     val name' = Thm.def_name_optional
   357       (NameSpace.base c ^ "_" ^ NameSpace.base tyco) name;
   358   in
   359     thy
   360     |> Thm.add_def false false (name', prop)
   361     |>> (fn thm =>  Drule.transitive_thm OF [eq, thm])
   362   end;
   363 
   364 
   365 
   366 (** class definitions **)
   367 
   368 fun split_defined n eq =
   369   let
   370     val intro =
   371       (eq RS Drule.equal_elim_rule2)
   372       |> Conjunction.curry_balanced n
   373       |> n = 0 ? Thm.eq_assumption 1;
   374     val dests =
   375       if n = 0 then []
   376       else
   377         (eq RS Drule.equal_elim_rule1)
   378         |> BalancedTree.dest (fn th =>
   379           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   380   in (intro, dests) end;
   381 
   382 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   383   let
   384     val ctxt = ProofContext.init thy;
   385     val pp = Syntax.pp ctxt;
   386 
   387 
   388     (* class *)
   389 
   390     val bconst = Logic.const_of_class bclass;
   391     val class = Sign.full_name thy bclass;
   392     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   393 
   394     fun check_constraint (a, S) =
   395       if Sign.subsort thy (super, S) then ()
   396       else error ("Sort constraint of type variable " ^
   397         setmp show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   398         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   399 
   400 
   401     (* params *)
   402 
   403     val params = raw_params |> map (fn p =>
   404       let
   405         val T = Sign.the_const_type thy p;
   406         val _ =
   407           (case Term.add_tvarsT T [] of
   408             [((a, _), S)] => check_constraint (a, S)
   409           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   410         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   411       in (p, T') end);
   412 
   413 
   414     (* axioms *)
   415 
   416     fun prep_axiom t =
   417       (case Term.add_tfrees t [] of
   418         [(a, S)] => check_constraint (a, S)
   419       | [] => ()
   420       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   421       t
   422       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   423       |> Logic.close_form);
   424 
   425     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   426     val name_atts = map fst raw_specs;
   427 
   428 
   429     (* definition *)
   430 
   431     val conjs = map (curry Logic.mk_inclass (Term.aT [])) super @ flat axiomss;
   432     val class_eq =
   433       Logic.mk_equals (Logic.mk_inclass (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   434 
   435     val ([def], def_thy) =
   436       thy
   437       |> Sign.primitive_class (bclass, super)
   438       |> PureThy.add_defs_i false [((Thm.def_name bconst, class_eq), [])];
   439     val (raw_intro, (raw_classrel, raw_axioms)) =
   440       split_defined (length conjs) def ||> chop (length super);
   441 
   442 
   443     (* facts *)
   444 
   445     val class_triv = Thm.class_triv def_thy class;
   446     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   447       def_thy
   448       |> PureThy.note_thmss_qualified "" bconst
   449         [((introN, []), [([Drule.standard raw_intro], [])]),
   450          ((superN, []), [(map Drule.standard raw_classrel, [])]),
   451          ((axiomsN, []), [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])];
   452 
   453 
   454     (* result *)
   455 
   456     val axclass = make_axclass ((def, intro, axioms), params);
   457     val result_thy =
   458       facts_thy
   459       |> fold put_classrel (map (pair class) super ~~ classrel)
   460       |> Sign.add_path bconst
   461       |> PureThy.note_thmss_i "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   462       |> Sign.restore_naming facts_thy
   463       |> map_axclasses (fn (axclasses, parameters) =>
   464         (Symtab.update (class, axclass) axclasses,
   465           fold (fn (x, _) => add_param pp (x, class)) params parameters));
   466 
   467   in (class, result_thy) end;
   468 
   469 
   470 
   471 (** axiomatizations **)
   472 
   473 local
   474 
   475 fun axiomatize prep mk name add raw_args thy =
   476   let
   477     val args = prep thy raw_args;
   478     val specs = mk args;
   479     val names = name args;
   480   in thy |> PureThy.add_axioms_i (map (rpair []) (names ~~ specs)) |-> fold add end;
   481 
   482 fun ax_classrel prep =
   483   axiomatize (map o prep) (map Logic.mk_classrel)
   484     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   485 
   486 fun ax_arity prep =
   487   axiomatize prep Logic.mk_arities
   488     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   489 
   490 fun class_const c =
   491   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   492 
   493 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   494   let
   495     val class = Sign.full_name thy bclass;
   496     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   497   in
   498     thy
   499     |> Sign.primitive_class (bclass, super)
   500     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   501     |> Theory.add_deps "" (class_const class) (map class_const super)
   502   end;
   503 
   504 in
   505 
   506 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   507 val axiomatize_class_cmd = ax_class Sign.read_class read_classrel;
   508 val axiomatize_classrel = ax_classrel cert_classrel;
   509 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   510 val axiomatize_arity = ax_arity Sign.cert_arity;
   511 val axiomatize_arity_cmd = ax_arity Sign.read_arity;
   512 
   513 end;
   514 
   515 
   516 
   517 (** explicit derivations -- cached **)
   518 
   519 datatype cache = Types of (class * thm) list Typtab.table;
   520 
   521 local
   522 
   523 fun lookup_type (Types cache) = AList.lookup (op =) o Typtab.lookup_list cache;
   524 fun insert_type T der (Types cache) = Types (Typtab.insert_list (eq_fst op =) (T, der) cache);
   525 
   526 fun derive_type _ (_, []) = []
   527   | derive_type thy (typ, sort) =
   528       let
   529         val vars = Term.fold_atyps
   530             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
   531               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
   532               | _ => I) typ [];
   533         val hyps = vars
   534           |> map (fn (T, S) => (T, Drule.sort_triv thy (T, S) ~~ S));
   535         val ths = (typ, sort)
   536           |> Sorts.of_sort_derivation (Syntax.pp_global thy) (Sign.classes_of thy)
   537            {class_relation =
   538               fn (th, c1) => fn c2 => th RS the_classrel thy (c1, c2),
   539             type_constructor =
   540               fn a => fn dom => fn c =>
   541                 let val Ss = map (map snd) dom and ths = maps (map fst) dom
   542                 in ths MRS the_arity thy a (c, Ss) end,
   543             type_variable =
   544               the_default [] o AList.lookup (op =) hyps};
   545       in ths end;
   546 
   547 in
   548 
   549 fun of_sort thy (typ, sort) cache =
   550   let
   551     val sort' = filter (is_none o lookup_type cache typ) sort;
   552     val ths' = derive_type thy (typ, sort')
   553       handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
   554         Syntax.string_of_typ_global thy typ ^ " :: " ^ Syntax.string_of_sort_global thy sort');
   555     val cache' = cache |> fold (insert_type typ) (sort' ~~ ths');
   556     val ths =
   557       sort |> map (fn c =>
   558         Goal.finish (the (lookup_type cache' typ c) RS
   559           Goal.init (Thm.cterm_of thy (Logic.mk_inclass (typ, c))))
   560         |> Thm.adjust_maxidx_thm ~1);
   561   in (ths, cache') end;
   562 
   563 end;
   564 
   565 val cache = Types Typtab.empty;
   566 
   567 end;