src/Pure/PIDE/command.ML
author wenzelm
Fri Jul 12 12:18:17 2013 +0200 (2013-07-12 ago)
changeset 52609 c8f8c29193de
parent 52607 33a133d50616
child 52619 70d5f2f7d27f
permissions -rw-r--r--
clarified memo_exec: plain synchronized access without any special tricks;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   val read: (unit -> theory) -> Token.T list -> Toplevel.transition
    10   type eval
    11   val eval_eq: eval * eval -> bool
    12   val eval_result_state: eval -> Toplevel.state
    13   val eval_stable: eval -> bool
    14   val eval: (unit -> theory) -> Token.T list -> eval -> eval
    15   type print
    16   val print: bool -> string -> eval -> print list -> print list option
    17   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    18   val print_function: {name: string, pri: int, persistent: bool} ->
    19     ({command_name: string} -> print_fn option) -> unit
    20   val no_print_function: string -> unit
    21   type exec = eval * print list
    22   val no_exec: exec
    23   val exec_ids: exec option -> Document_ID.exec list
    24   val exec: Document_ID.execution -> exec -> unit
    25 end;
    26 
    27 structure Command: COMMAND =
    28 struct
    29 
    30 (** memo results -- including physical interrupts! **)
    31 
    32 datatype 'a expr =
    33   Expr of Document_ID.exec * (unit -> 'a) |
    34   Result of 'a Exn.result;
    35 
    36 abstype 'a memo = Memo of 'a expr Synchronized.var
    37 with
    38 
    39 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    40 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    41 
    42 fun memo_result (Memo v) =
    43   (case Synchronized.value v of
    44     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    45   | Result res => Exn.release res);
    46 
    47 fun memo_stable (Memo v) =
    48   (case Synchronized.value v of
    49    Expr _ => true
    50  | Result res => not (Exn.is_interrupt_exn res));
    51 
    52 fun memo_exec execution_id (Memo v) =
    53   Synchronized.guarded_access v
    54     (fn expr =>
    55       (case expr of
    56         Result res => SOME (res, expr)
    57       | Expr (exec_id, e) =>
    58           uninterruptible (fn restore_attributes => fn () =>
    59             if Execution.running execution_id exec_id then
    60               let
    61                 val res = Exn.capture (restore_attributes e) ();
    62                 val _ = Execution.finished exec_id;
    63               in SOME (res, Result res) end
    64             else SOME (Exn.interrupt_exn, expr)) ()))
    65   |> Exn.release |> ignore;
    66 
    67 fun memo_fork params execution_id (Memo v) =
    68   (case Synchronized.value v of
    69     Result _ => ()
    70   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    71 
    72 end;
    73 
    74 
    75 
    76 (** main phases of execution **)
    77 
    78 (* read *)
    79 
    80 fun read init span =
    81   let
    82     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
    83     val command_reports = Outer_Syntax.command_reports outer_syntax;
    84 
    85     val proper_range =
    86       Position.set_range (Token.position_range_of (#1 (take_suffix Token.is_improper span)));
    87     val pos =
    88       (case find_first Token.is_command span of
    89         SOME tok => Token.position_of tok
    90       | NONE => proper_range);
    91 
    92     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
    93     val _ = Position.reports_text (token_reports @ maps command_reports span);
    94   in
    95     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
    96     else
    97       (case Outer_Syntax.read_spans outer_syntax span of
    98         [tr] =>
    99           if Keyword.is_control (Toplevel.name_of tr) then
   100             Toplevel.malformed pos "Illegal control command"
   101           else Toplevel.modify_init init tr
   102       | [] => Toplevel.ignored (Position.set_range (Token.position_range_of span))
   103       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   104       handle ERROR msg => Toplevel.malformed proper_range msg
   105   end;
   106 
   107 
   108 (* eval *)
   109 
   110 type eval_state =
   111   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   112 val init_eval_state =
   113   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   114 
   115 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   116 
   117 fun eval_eq (Eval {exec_id, ...}, Eval {exec_id = exec_id', ...}) = exec_id = exec_id';
   118 
   119 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   120 val eval_result_state = #state o eval_result;
   121 
   122 fun eval_stable (Eval {exec_id, eval_process}) =
   123   Goal.stable_futures exec_id andalso memo_stable eval_process;
   124 
   125 local
   126 
   127 fun run int tr st =
   128   if Goal.future_enabled () andalso Keyword.is_diag (Toplevel.name_of tr) then
   129     (Goal.fork_params {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   130       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   131   else Toplevel.command_errors int tr st;
   132 
   133 fun check_cmts span tr st' =
   134   Toplevel.setmp_thread_position tr
   135     (fn () =>
   136       Outer_Syntax.side_comments span |> maps (fn cmt =>
   137         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   138           handle exn => ML_Compiler.exn_messages_ids exn)) ();
   139 
   140 fun proof_status tr st =
   141   (case try Toplevel.proof_of st of
   142     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   143   | NONE => ());
   144 
   145 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   146   if malformed then
   147     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   148   else
   149     let
   150       val malformed' = Toplevel.is_malformed tr;
   151       val is_init = Toplevel.is_init tr;
   152       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   153 
   154       val _ = Multithreading.interrupted ();
   155       val _ = Toplevel.status tr Markup.running;
   156       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   157       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   158       val errs = errs1 @ errs2;
   159       val _ = Toplevel.status tr Markup.finished;
   160       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   161     in
   162       (case result of
   163         NONE =>
   164           let
   165             val _ = if null errs then Exn.interrupt () else ();
   166             val _ = Toplevel.status tr Markup.failed;
   167           in {failed = true, malformed = malformed', command = tr, state = st} end
   168       | SOME st' =>
   169           let
   170             val _ = proof_status tr st';
   171           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   172     end;
   173 
   174 in
   175 
   176 fun eval init span eval0 =
   177   let
   178     val exec_id = Document_ID.make ();
   179     fun process () =
   180       let
   181         val tr =
   182           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   183             (fn () => read init span |> Toplevel.exec_id exec_id) ();
   184       in eval_state span tr (eval_result eval0) end;
   185   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   186 
   187 end;
   188 
   189 
   190 (* print *)
   191 
   192 datatype print = Print of
   193  {name: string, pri: int, persistent: bool,
   194   exec_id: Document_ID.exec, print_process: unit memo};
   195 
   196 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   197 
   198 local
   199 
   200 type print_function = string * (int * bool * ({command_name: string} -> print_fn option));
   201 val print_functions = Synchronized.var "Command.print_functions" ([]: print_function list);
   202 
   203 fun print_error tr e =
   204   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution) e () handle exn =>
   205     List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   206 
   207 fun print_eq (Print {exec_id, ...}, Print {exec_id = exec_id', ...}) = exec_id = exec_id';
   208 
   209 fun print_stable (Print {exec_id, print_process, ...}) =
   210   Goal.stable_futures exec_id andalso memo_stable print_process;
   211 
   212 fun print_persistent (Print {persistent, ...}) = persistent;
   213 
   214 in
   215 
   216 fun print command_visible command_name eval old_prints =
   217   let
   218     fun new_print (name, (pri, persistent, get_fn)) =
   219       let
   220         fun make_print strict print_fn =
   221           let
   222             val exec_id = Document_ID.make ();
   223             fun process () =
   224               let
   225                 val {failed, command, state = st', ...} = eval_result eval;
   226                 val tr = Toplevel.exec_id exec_id command;
   227               in
   228                 if failed andalso not strict then ()
   229                 else print_error tr (fn () => print_fn tr st')
   230               end;
   231           in
   232            Print {
   233              name = name, pri = pri, persistent = persistent,
   234              exec_id = exec_id, print_process = memo exec_id process}
   235           end;
   236       in
   237         (case Exn.capture (Runtime.controlled_execution get_fn) {command_name = command_name} of
   238           Exn.Res NONE => NONE
   239         | Exn.Res (SOME print_fn) => SOME (make_print false print_fn)
   240         | Exn.Exn exn => SOME (make_print true (fn _ => fn _ => reraise exn)))
   241       end;
   242 
   243     val new_prints =
   244       if command_visible then
   245         rev (Synchronized.value print_functions) |> map_filter (fn pr =>
   246           (case find_first (fn Print {name, ...} => name = fst pr) old_prints of
   247             SOME print => if print_stable print then SOME print else new_print pr
   248           | NONE => new_print pr))
   249       else filter (fn print => print_persistent print andalso print_stable print) old_prints;
   250   in
   251     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   252   end;
   253 
   254 fun print_function {name, pri, persistent} f =
   255   Synchronized.change print_functions (fn funs =>
   256    (if not (AList.defined (op =) funs name) then ()
   257     else warning ("Redefining command print function: " ^ quote name);
   258     AList.update (op =) (name, (pri, persistent, f)) funs));
   259 
   260 fun no_print_function name =
   261   Synchronized.change print_functions (filter_out (equal name o #1));
   262 
   263 end;
   264 
   265 val _ =
   266   print_function {name = "print_state", pri = 0, persistent = true}
   267     (fn {command_name} => SOME (fn tr => fn st' =>
   268       let
   269         val is_init = Keyword.is_theory_begin command_name;
   270         val is_proof = Keyword.is_proof command_name;
   271         val do_print =
   272           not is_init andalso
   273             (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   274       in if do_print then Toplevel.print_state false st' else () end));
   275 
   276 
   277 (* combined execution *)
   278 
   279 type exec = eval * print list;
   280 val no_exec: exec =
   281   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   282 
   283 fun exec_ids NONE = []
   284   | exec_ids (SOME (Eval {exec_id, ...}, prints)) =
   285       exec_id :: map (fn Print {exec_id, ...} => exec_id) prints;
   286 
   287 local
   288 
   289 fun run_print execution_id (Print {name, pri, print_process, ...}) =
   290   (if Multithreading.enabled () then
   291     memo_fork {name = name, group = NONE, deps = [], pri = pri, interrupts = true}
   292   else memo_exec) execution_id print_process;
   293 
   294 in
   295 
   296 fun exec execution_id (Eval {eval_process, ...}, prints) =
   297   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   298 
   299 end;
   300 
   301 end;
   302