src/Pure/PIDE/command.ML
author wenzelm
Thu Jul 11 15:56:12 2013 +0200 (2013-07-11 ago)
changeset 52598 cad097fb46de
parent 52596 40298d383463
child 52600 75afb82daf5c
permissions -rw-r--r--
disallow concurrent execution attempt explicitly -- it should never happen due to management of singleton execution;
tuned error messages: prefer plain "error" as in document.ML;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   type eval_process
    10   type eval = {exec_id: Document_ID.exec, eval_process: eval_process}
    11   val eval_result_state: eval -> Toplevel.state
    12   val eval_same: eval * eval -> bool
    13   type print_process
    14   type print =
    15    {name: string, pri: int, persistent: bool,
    16     exec_id: Document_ID.exec, print_process: print_process}
    17   type exec = eval * print list
    18   val no_exec: exec
    19   val exec_ids: exec option -> Document_ID.exec list
    20   val read: (unit -> theory) -> Token.T list -> Toplevel.transition
    21   val eval: (unit -> theory) -> Token.T list -> eval -> eval
    22   val print: bool -> string -> eval -> print list -> print list option
    23   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    24   val print_function: {name: string, pri: int, persistent: bool} ->
    25     ({command_name: string} -> print_fn option) -> unit
    26   val no_print_function: string -> unit
    27   val execute: exec -> unit
    28 end;
    29 
    30 structure Command: COMMAND =
    31 struct
    32 
    33 (** memo results -- including physical interrupts! **)
    34 
    35 datatype 'a expr =
    36   Expr of Document_ID.exec * (unit -> 'a) |
    37   Result of 'a Exn.result;
    38 
    39 abstype 'a memo = Memo of 'a expr Synchronized.var
    40 with
    41 
    42 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    43 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    44 
    45 fun memo_result (Memo v) =
    46   (case Synchronized.value v of
    47     Result res => Exn.release res
    48   | Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id));
    49 
    50 fun memo_exec (Memo v) =
    51   (case Synchronized.value v of
    52     Result res => res
    53   | Expr (exec_id, _) =>
    54       Synchronized.timed_access v (fn _ => SOME Time.zeroTime)
    55         (fn Result res => SOME (res, Result res)
    56           | Expr (exec_id, e) =>
    57               uninterruptible (fn restore_attributes => fn () =>
    58                 let
    59                   val _ = Exec.running exec_id;
    60                   val res = Exn.capture (restore_attributes e) ();
    61                   val _ =
    62                     if Exn.is_interrupt_exn res
    63                     then Exec.canceled exec_id
    64                     else Exec.finished exec_id;
    65                 in SOME (res, Result res) end) ())
    66       |> (fn NONE => error ("Concurrent execution attempt: " ^ Document_ID.print exec_id)
    67            | SOME res => res))
    68   |> Exn.release;
    69 
    70 fun memo_fork params (Memo v) =
    71   (case Synchronized.value v of
    72     Result _ => ()
    73   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec (Memo v))));
    74 
    75 end;
    76 
    77 
    78 
    79 (** main phases of execution **)
    80 
    81 (* type definitions *)
    82 
    83 type eval_state =
    84   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
    85 val init_eval_state =
    86   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
    87 
    88 type eval_process = eval_state memo;
    89 type eval = {exec_id: Document_ID.exec, eval_process: eval_process};
    90 
    91 fun eval_result ({eval_process, ...}: eval) = memo_result eval_process;
    92 val eval_result_state = #state o eval_result;
    93 
    94 fun eval_same ({exec_id, ...}: eval, {exec_id = exec_id', ...}: eval) =
    95   exec_id = exec_id' andalso Exec.is_stable exec_id;
    96 
    97 type print_process = unit memo;
    98 type print =
    99  {name: string, pri: int, persistent: bool,
   100   exec_id: Document_ID.exec, print_process: print_process};
   101 
   102 type exec = eval * print list;
   103 val no_exec: exec = ({exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   104 
   105 fun exec_ids (NONE: exec option) = []
   106   | exec_ids (SOME ({exec_id, ...}, prints)) = exec_id :: map #exec_id prints;
   107 
   108 
   109 (* read *)
   110 
   111 fun read init span =
   112   let
   113     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
   114     val command_reports = Outer_Syntax.command_reports outer_syntax;
   115 
   116     val proper_range =
   117       Position.set_range (Token.position_range_of (#1 (take_suffix Token.is_improper span)));
   118     val pos =
   119       (case find_first Token.is_command span of
   120         SOME tok => Token.position_of tok
   121       | NONE => proper_range);
   122 
   123     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
   124     val _ = Position.reports_text (token_reports @ maps command_reports span);
   125   in
   126     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
   127     else
   128       (case Outer_Syntax.read_spans outer_syntax span of
   129         [tr] =>
   130           if Keyword.is_control (Toplevel.name_of tr) then
   131             Toplevel.malformed pos "Illegal control command"
   132           else Toplevel.modify_init init tr
   133       | [] => Toplevel.ignored (Position.set_range (Token.position_range_of span))
   134       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   135       handle ERROR msg => Toplevel.malformed proper_range msg
   136   end;
   137 
   138 
   139 (* eval *)
   140 
   141 local
   142 
   143 fun run int tr st =
   144   if Goal.future_enabled () andalso Keyword.is_diag (Toplevel.name_of tr) then
   145     (Goal.fork_params {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   146       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   147   else Toplevel.command_errors int tr st;
   148 
   149 fun check_cmts span tr st' =
   150   Toplevel.setmp_thread_position tr
   151     (fn () =>
   152       Outer_Syntax.side_comments span |> maps (fn cmt =>
   153         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   154           handle exn => ML_Compiler.exn_messages_ids exn)) ();
   155 
   156 fun proof_status tr st =
   157   (case try Toplevel.proof_of st of
   158     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   159   | NONE => ());
   160 
   161 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   162   if malformed then
   163     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   164   else
   165     let
   166       val malformed' = Toplevel.is_malformed tr;
   167       val is_init = Toplevel.is_init tr;
   168       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   169 
   170       val _ = Multithreading.interrupted ();
   171       val _ = Toplevel.status tr Markup.running;
   172       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   173       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   174       val errs = errs1 @ errs2;
   175       val _ = Toplevel.status tr Markup.finished;
   176       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   177     in
   178       (case result of
   179         NONE =>
   180           let
   181             val _ = if null errs then Exn.interrupt () else ();
   182             val _ = Toplevel.status tr Markup.failed;
   183           in {failed = true, malformed = malformed', command = tr, state = st} end
   184       | SOME st' =>
   185           let
   186             val _ = proof_status tr st';
   187           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   188     end;
   189 
   190 in
   191 
   192 fun eval init span eval0 =
   193   let
   194     val exec_id = Document_ID.make ();
   195     fun process () =
   196       let
   197         val tr =
   198           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   199             (fn () => read init span |> Toplevel.exec_id exec_id) ();
   200       in eval_state span tr (eval_result eval0) end;
   201   in {exec_id = exec_id, eval_process = memo exec_id process} end;
   202 
   203 end;
   204 
   205 
   206 (* print *)
   207 
   208 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   209 
   210 local
   211 
   212 type print_function = string * (int * bool * ({command_name: string} -> print_fn option));
   213 val print_functions = Synchronized.var "Command.print_functions" ([]: print_function list);
   214 
   215 fun print_error tr e =
   216   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution) e () handle exn =>
   217     List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   218 
   219 fun print_stable (print: print) = Exec.is_stable (#exec_id print);
   220 
   221 in
   222 
   223 fun print command_visible command_name eval old_prints =
   224   let
   225     fun new_print (name, (pri, persistent, get_fn)) =
   226       let
   227         fun make_print strict print_fn =
   228           let
   229             val exec_id = Document_ID.make ();
   230             fun process () =
   231               let
   232                 val {failed, command, state = st', ...} = eval_result eval;
   233                 val tr = Toplevel.exec_id exec_id command;
   234               in
   235                 if failed andalso not strict then ()
   236                 else print_error tr (fn () => print_fn tr st')
   237               end;
   238           in
   239            {name = name, pri = pri, persistent = persistent,
   240             exec_id = exec_id, print_process = memo exec_id process}
   241           end;
   242       in
   243         (case Exn.capture (Runtime.controlled_execution get_fn) {command_name = command_name} of
   244           Exn.Res NONE => NONE
   245         | Exn.Res (SOME print_fn) => SOME (make_print false print_fn)
   246         | Exn.Exn exn => SOME (make_print true (fn _ => fn _ => reraise exn)))
   247       end;
   248 
   249     val new_prints =
   250       if command_visible then
   251         rev (Synchronized.value print_functions) |> map_filter (fn pr =>
   252           (case find_first (equal (fst pr) o #name) old_prints of
   253             SOME print => if print_stable print then SOME print else new_print pr
   254           | NONE => new_print pr))
   255       else filter (fn print => #persistent print andalso print_stable print) old_prints;
   256   in
   257     if eq_list (op = o pairself #exec_id) (old_prints, new_prints) then NONE
   258     else SOME new_prints
   259   end;
   260 
   261 fun print_function {name, pri, persistent} f =
   262   Synchronized.change print_functions (fn funs =>
   263    (if not (AList.defined (op =) funs name) then ()
   264     else warning ("Redefining command print function: " ^ quote name);
   265     AList.update (op =) (name, (pri, persistent, f)) funs));
   266 
   267 fun no_print_function name =
   268   Synchronized.change print_functions (filter_out (equal name o #1));
   269 
   270 end;
   271 
   272 val _ =
   273   print_function {name = "print_state", pri = 0, persistent = true}
   274     (fn {command_name} => SOME (fn tr => fn st' =>
   275       let
   276         val is_init = Keyword.is_theory_begin command_name;
   277         val is_proof = Keyword.is_proof command_name;
   278         val do_print =
   279           not is_init andalso
   280             (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   281       in if do_print then Toplevel.print_state false st' else () end));
   282 
   283 
   284 (* combined execution process *)
   285 
   286 fun run_print ({name, pri, print_process, ...}: print) =
   287   (if Multithreading.enabled () then
   288     memo_fork {name = name, group = NONE, deps = [], pri = pri, interrupts = true}
   289   else memo_exec) print_process;
   290 
   291 fun execute (({eval_process, ...}, prints): exec) =
   292   (memo_exec eval_process; List.app run_print prints);
   293 
   294 end;
   295