src/Pure/Isar/toplevel.ML
author wenzelm
Thu Apr 16 15:22:44 2015 +0200 (2015-04-16 ago)
changeset 60099 d20ca79d50e4
parent 60096 96a4765ba7d1
child 60189 0d3a62127057
permissions -rw-r--r--
discontinued pointless warnings: commands are only defined inside a theory context;
     1 (*  Title:      Pure/Isar/toplevel.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Isabelle/Isar toplevel transactions.
     5 *)
     6 
     7 signature TOPLEVEL =
     8 sig
     9   exception UNDEF
    10   type state
    11   val toplevel: state
    12   val is_toplevel: state -> bool
    13   val is_theory: state -> bool
    14   val is_proof: state -> bool
    15   val is_skipped_proof: state -> bool
    16   val level: state -> int
    17   val presentation_context_of: state -> Proof.context
    18   val previous_context_of: state -> Proof.context option
    19   val context_of: state -> Proof.context
    20   val generic_theory_of: state -> generic_theory
    21   val theory_of: state -> theory
    22   val proof_of: state -> Proof.state
    23   val proof_position_of: state -> int
    24   val end_theory: Position.T -> state -> theory
    25   val pretty_context: state -> Pretty.T list
    26   val pretty_state: state -> Pretty.T list
    27   val print_state: state -> unit
    28   val pretty_abstract: state -> Pretty.T
    29   val profiling: int Unsynchronized.ref
    30   type transition
    31   val empty: transition
    32   val name_of: transition -> string
    33   val pos_of: transition -> Position.T
    34   val type_error: transition -> string
    35   val name: string -> transition -> transition
    36   val position: Position.T -> transition -> transition
    37   val init_theory: (unit -> theory) -> transition -> transition
    38   val is_init: transition -> bool
    39   val modify_init: (unit -> theory) -> transition -> transition
    40   val exit: transition -> transition
    41   val keep: (state -> unit) -> transition -> transition
    42   val keep': (bool -> state -> unit) -> transition -> transition
    43   val imperative: (unit -> unit) -> transition -> transition
    44   val ignored: Position.T -> transition
    45   val is_ignored: transition -> bool
    46   val malformed: Position.T -> string -> transition
    47   val generic_theory: (generic_theory -> generic_theory) -> transition -> transition
    48   val theory': (bool -> theory -> theory) -> transition -> transition
    49   val theory: (theory -> theory) -> transition -> transition
    50   val begin_local_theory: bool -> (theory -> local_theory) -> transition -> transition
    51   val end_local_theory: transition -> transition
    52   val open_target: (generic_theory -> local_theory) -> transition -> transition
    53   val close_target: transition -> transition
    54   val local_theory': (bool * Position.T) option -> (xstring * Position.T) option ->
    55     (bool -> local_theory -> local_theory) -> transition -> transition
    56   val local_theory: (bool * Position.T) option -> (xstring * Position.T) option ->
    57     (local_theory -> local_theory) -> transition -> transition
    58   val present_local_theory: (xstring * Position.T) option -> (state -> unit) ->
    59     transition -> transition
    60   val local_theory_to_proof': (bool * Position.T) option -> (xstring * Position.T) option ->
    61     (bool -> local_theory -> Proof.state) -> transition -> transition
    62   val local_theory_to_proof: (bool * Position.T) option -> (xstring * Position.T) option ->
    63     (local_theory -> Proof.state) -> transition -> transition
    64   val theory_to_proof: (theory -> Proof.state) -> transition -> transition
    65   val end_proof: (bool -> Proof.state -> Proof.context) -> transition -> transition
    66   val forget_proof: bool -> transition -> transition
    67   val proofs': (bool -> Proof.state -> Proof.state Seq.result Seq.seq) -> transition -> transition
    68   val proof': (bool -> Proof.state -> Proof.state) -> transition -> transition
    69   val proofs: (Proof.state -> Proof.state Seq.result Seq.seq) -> transition -> transition
    70   val proof: (Proof.state -> Proof.state) -> transition -> transition
    71   val actual_proof: (Proof_Node.T -> Proof_Node.T) -> transition -> transition
    72   val skip_proof: (int -> int) -> transition -> transition
    73   val skip_proof_to_theory: (int -> bool) -> transition -> transition
    74   val exec_id: Document_ID.exec -> transition -> transition
    75   val setmp_thread_position: transition -> ('a -> 'b) -> 'a -> 'b
    76   val add_hook: (transition -> state -> state -> unit) -> unit
    77   val get_timing: transition -> Time.time option
    78   val put_timing: Time.time option -> transition -> transition
    79   val transition: bool -> transition -> state -> state * (exn * string) option
    80   val command_errors: bool -> transition -> state -> Runtime.error list * state option
    81   val command_exception: bool -> transition -> state -> state
    82   val reset_theory: state -> state option
    83   val reset_proof: state -> state option
    84   type result
    85   val join_results: result -> (transition * state) list
    86   val element_result: Keyword.keywords -> transition Thy_Syntax.element -> state -> result * state
    87 end;
    88 
    89 structure Toplevel: TOPLEVEL =
    90 struct
    91 
    92 (** toplevel state **)
    93 
    94 exception UNDEF = Runtime.UNDEF;
    95 
    96 
    97 (* datatype node *)
    98 
    99 datatype node =
   100   Theory of generic_theory * Proof.context option
   101     (*theory with presentation context*) |
   102   Proof of Proof_Node.T * ((Proof.context -> generic_theory) * generic_theory)
   103     (*proof node, finish, original theory*) |
   104   Skipped_Proof of int * (generic_theory * generic_theory);
   105     (*proof depth, resulting theory, original theory*)
   106 
   107 val theory_node = fn Theory (gthy, _) => SOME gthy | _ => NONE;
   108 val proof_node = fn Proof (prf, _) => SOME prf | _ => NONE;
   109 val skipped_proof_node = fn Skipped_Proof _ => true | _ => false;
   110 
   111 fun cases_node f _ (Theory (gthy, _)) = f gthy
   112   | cases_node _ g (Proof (prf, _)) = g (Proof_Node.current prf)
   113   | cases_node f _ (Skipped_Proof (_, (gthy, _))) = f gthy;
   114 
   115 val context_node = cases_node Context.proof_of Proof.context_of;
   116 
   117 
   118 (* datatype state *)
   119 
   120 datatype state = State of node option * node option;  (*current, previous*)
   121 
   122 val toplevel = State (NONE, NONE);
   123 
   124 fun is_toplevel (State (NONE, _)) = true
   125   | is_toplevel _ = false;
   126 
   127 fun level (State (NONE, _)) = 0
   128   | level (State (SOME (Theory _), _)) = 0
   129   | level (State (SOME (Proof (prf, _)), _)) = Proof.level (Proof_Node.current prf)
   130   | level (State (SOME (Skipped_Proof (d, _)), _)) = d + 1;   (*different notion of proof depth!*)
   131 
   132 fun str_of_state (State (NONE, SOME (Theory (Context.Theory thy, _)))) =
   133       "at top level, result theory " ^ quote (Context.theory_name thy)
   134   | str_of_state (State (NONE, _)) = "at top level"
   135   | str_of_state (State (SOME (Theory (Context.Theory _, _)), _)) = "in theory mode"
   136   | str_of_state (State (SOME (Theory (Context.Proof _, _)), _)) = "in local theory mode"
   137   | str_of_state (State (SOME (Proof _), _)) = "in proof mode"
   138   | str_of_state (State (SOME (Skipped_Proof _), _)) = "in skipped proof mode";
   139 
   140 
   141 (* current node *)
   142 
   143 fun node_of (State (NONE, _)) = raise UNDEF
   144   | node_of (State (SOME node, _)) = node;
   145 
   146 fun is_theory state = not (is_toplevel state) andalso is_some (theory_node (node_of state));
   147 fun is_proof state = not (is_toplevel state) andalso is_some (proof_node (node_of state));
   148 fun is_skipped_proof state = not (is_toplevel state) andalso skipped_proof_node (node_of state);
   149 
   150 fun node_case f g state = cases_node f g (node_of state);
   151 
   152 fun presentation_context_of state =
   153   (case try node_of state of
   154     SOME (Theory (_, SOME ctxt)) => ctxt
   155   | SOME node => context_node node
   156   | NONE => raise UNDEF);
   157 
   158 fun previous_context_of (State (_, NONE)) = NONE
   159   | previous_context_of (State (_, SOME prev)) = SOME (context_node prev);
   160 
   161 val context_of = node_case Context.proof_of Proof.context_of;
   162 val generic_theory_of = node_case I (Context.Proof o Proof.context_of);
   163 val theory_of = node_case Context.theory_of Proof.theory_of;
   164 val proof_of = node_case (fn _ => error "No proof state") I;
   165 
   166 fun proof_position_of state =
   167   (case node_of state of
   168     Proof (prf, _) => Proof_Node.position prf
   169   | _ => ~1);
   170 
   171 fun end_theory _ (State (NONE, SOME (Theory (Context.Theory thy, _)))) = thy
   172   | end_theory pos (State (NONE, _)) = error ("Bad theory" ^ Position.here pos)
   173   | end_theory pos (State (SOME _, _)) = error ("Unfinished theory" ^ Position.here pos);
   174 
   175 
   176 (* print state *)
   177 
   178 fun pretty_context state =
   179   (case try node_of state of
   180     NONE => []
   181   | SOME node =>
   182       let
   183         val gthy =
   184           (case node of
   185             Theory (gthy, _) => gthy
   186           | Proof (_, (_, gthy)) => gthy
   187           | Skipped_Proof (_, (gthy, _)) => gthy);
   188         val lthy = Context.cases (Named_Target.theory_init) I gthy;
   189       in Local_Theory.pretty lthy end);
   190 
   191 fun pretty_state state =
   192   (case try node_of state of
   193     NONE => []
   194   | SOME (Theory _) => []
   195   | SOME (Proof (prf, _)) =>
   196       Proof.pretty_state (Proof_Node.position prf) (Proof_Node.current prf)
   197   | SOME (Skipped_Proof (d, _)) => [Pretty.str ("skipped proof: depth " ^ string_of_int d)]);
   198 
   199 val print_state = pretty_state #> Pretty.chunks #> Pretty.string_of #> Output.state;
   200 
   201 fun pretty_abstract state = Pretty.str ("<Isar " ^ str_of_state state ^ ">");
   202 
   203 
   204 
   205 (** toplevel transitions **)
   206 
   207 val profiling = Unsynchronized.ref 0;
   208 
   209 
   210 (* node transactions -- maintaining stable checkpoints *)
   211 
   212 exception FAILURE of state * exn;
   213 
   214 local
   215 
   216 fun reset_presentation (Theory (gthy, _)) = Theory (gthy, NONE)
   217   | reset_presentation node = node;
   218 
   219 fun map_theory f (Theory (gthy, ctxt)) =
   220       Theory (Context.mapping f (Local_Theory.raw_theory f) gthy, ctxt)
   221   | map_theory _ node = node;
   222 
   223 in
   224 
   225 fun apply_transaction f g node =
   226   let
   227     val cont_node = reset_presentation node;
   228     val context = cases_node I (Context.Proof o Proof.context_of) cont_node;
   229     fun state_error e nd = (State (SOME nd, SOME node), e);
   230 
   231     val (result, err) =
   232       cont_node
   233       |> Runtime.controlled_execution (SOME context) f
   234       |> state_error NONE
   235       handle exn => state_error (SOME exn) cont_node;
   236   in
   237     (case err of
   238       NONE => tap g result
   239     | SOME exn => raise FAILURE (result, exn))
   240   end;
   241 
   242 val exit_transaction =
   243   apply_transaction
   244     (fn Theory (Context.Theory thy, _) => Theory (Context.Theory (Theory.end_theory thy), NONE)
   245       | node => node) (K ())
   246   #> (fn State (node', _) => State (NONE, node'));
   247 
   248 end;
   249 
   250 
   251 (* primitive transitions *)
   252 
   253 datatype trans =
   254   Init of unit -> theory |               (*init theory*)
   255   Exit |                                 (*formal exit of theory*)
   256   Keep of bool -> state -> unit |        (*peek at state*)
   257   Transaction of (bool -> node -> node) * (state -> unit);  (*node transaction and presentation*)
   258 
   259 local
   260 
   261 fun apply_tr _ (Init f) (State (NONE, _)) =
   262       State (SOME (Theory (Context.Theory (Runtime.controlled_execution NONE f ()), NONE)), NONE)
   263   | apply_tr _ Exit (State (SOME (state as Theory (Context.Theory _, _)), _)) =
   264       exit_transaction state
   265   | apply_tr int (Keep f) state =
   266       Runtime.controlled_execution (try generic_theory_of state) (fn x => tap (f int) x) state
   267   | apply_tr int (Transaction (f, g)) (State (SOME state, _)) =
   268       apply_transaction (fn x => f int x) g state
   269   | apply_tr _ _ _ = raise UNDEF;
   270 
   271 fun apply_union _ [] state = raise FAILURE (state, UNDEF)
   272   | apply_union int (tr :: trs) state =
   273       apply_union int trs state
   274         handle Runtime.UNDEF => apply_tr int tr state
   275           | FAILURE (alt_state, UNDEF) => apply_tr int tr alt_state
   276           | exn as FAILURE _ => raise exn
   277           | exn => raise FAILURE (state, exn);
   278 
   279 in
   280 
   281 fun apply_trans int trs state = (apply_union int trs state, NONE)
   282   handle FAILURE (alt_state, exn) => (alt_state, SOME exn) | exn => (state, SOME exn);
   283 
   284 end;
   285 
   286 
   287 (* datatype transition *)
   288 
   289 datatype transition = Transition of
   290  {name: string,              (*command name*)
   291   pos: Position.T,           (*source position*)
   292   timing: Time.time option,  (*prescient timing information*)
   293   trans: trans list};        (*primitive transitions (union)*)
   294 
   295 fun make_transition (name, pos, timing, trans) =
   296   Transition {name = name, pos = pos, timing = timing, trans = trans};
   297 
   298 fun map_transition f (Transition {name, pos, timing, trans}) =
   299   make_transition (f (name, pos, timing, trans));
   300 
   301 val empty = make_transition ("", Position.none, NONE, []);
   302 
   303 
   304 (* diagnostics *)
   305 
   306 fun name_of (Transition {name, ...}) = name;
   307 fun pos_of (Transition {pos, ...}) = pos;
   308 
   309 fun command_msg msg tr =
   310   msg ^ "command " ^ quote (Markup.markup Markup.keyword1 (name_of tr)) ^
   311     Position.here (pos_of tr);
   312 
   313 fun at_command tr = command_msg "At " tr;
   314 fun type_error tr = command_msg "Bad context for " tr;
   315 
   316 
   317 (* modify transitions *)
   318 
   319 fun name name = map_transition (fn (_, pos, timing, trans) =>
   320   (name, pos, timing, trans));
   321 
   322 fun position pos = map_transition (fn (name, _, timing, trans) =>
   323   (name, pos, timing, trans));
   324 
   325 fun add_trans tr = map_transition (fn (name, pos, timing, trans) =>
   326   (name, pos, timing, tr :: trans));
   327 
   328 val reset_trans = map_transition (fn (name, pos, timing, _) =>
   329   (name, pos, timing, []));
   330 
   331 
   332 (* basic transitions *)
   333 
   334 fun init_theory f = add_trans (Init f);
   335 
   336 fun is_init (Transition {trans = [Init _], ...}) = true
   337   | is_init _ = false;
   338 
   339 fun modify_init f tr = if is_init tr then init_theory f (reset_trans tr) else tr;
   340 
   341 val exit = add_trans Exit;
   342 val keep' = add_trans o Keep;
   343 
   344 fun present_transaction f g = add_trans (Transaction (f, g));
   345 fun transaction f = present_transaction f (K ());
   346 
   347 fun keep f = add_trans (Keep (fn _ => f));
   348 fun imperative f = keep (fn _ => f ());
   349 
   350 fun ignored pos = empty |> name "<ignored>" |> position pos |> imperative I;
   351 fun is_ignored tr = name_of tr = "<ignored>";
   352 
   353 fun malformed pos msg =
   354   empty |> name "<malformed>" |> position pos |> imperative (fn () => error msg);
   355 
   356 
   357 (* theory transitions *)
   358 
   359 fun generic_theory f = transaction (fn _ =>
   360   (fn Theory (gthy, _) => Theory (f gthy, NONE)
   361     | _ => raise UNDEF));
   362 
   363 fun theory' f = transaction (fn int =>
   364   (fn Theory (Context.Theory thy, _) =>
   365       let val thy' = thy
   366         |> Sign.new_group
   367         |> f int
   368         |> Sign.reset_group;
   369       in Theory (Context.Theory thy', NONE) end
   370     | _ => raise UNDEF));
   371 
   372 fun theory f = theory' (K f);
   373 
   374 fun begin_local_theory begin f = transaction (fn _ =>
   375   (fn Theory (Context.Theory thy, _) =>
   376         let
   377           val lthy = f thy;
   378           val gthy = if begin then Context.Proof lthy else Context.Theory (Named_Target.exit lthy);
   379           val _ =
   380             if begin then
   381               Output.state (Pretty.string_of (Pretty.chunks (Local_Theory.pretty lthy)))
   382             else ();
   383         in Theory (gthy, SOME lthy) end
   384     | _ => raise UNDEF));
   385 
   386 val end_local_theory = transaction (fn _ =>
   387   (fn Theory (Context.Proof lthy, _) => Theory (Context.Theory (Named_Target.exit lthy), SOME lthy)
   388     | _ => raise UNDEF));
   389 
   390 fun open_target f = transaction (fn _ =>
   391   (fn Theory (gthy, _) =>
   392         let val lthy = f gthy
   393         in Theory (Context.Proof lthy, SOME lthy) end
   394     | _ => raise UNDEF));
   395 
   396 val close_target = transaction (fn _ =>
   397   (fn Theory (Context.Proof lthy, _) =>
   398         (case try Local_Theory.close_target lthy of
   399           SOME ctxt' =>
   400             let
   401               val gthy' =
   402                 if can Local_Theory.assert ctxt'
   403                 then Context.Proof ctxt'
   404                 else Context.Theory (Proof_Context.theory_of ctxt');
   405             in Theory (gthy', SOME lthy) end
   406         | NONE => raise UNDEF)
   407     | _ => raise UNDEF));
   408 
   409 fun restricted_context (SOME (strict, scope)) =
   410       Proof_Context.map_naming (Name_Space.restricted strict scope)
   411   | restricted_context NONE = I;
   412 
   413 fun local_theory' restricted target f = present_transaction (fn int =>
   414   (fn Theory (gthy, _) =>
   415         let
   416           val (finish, lthy) = Named_Target.switch target gthy;
   417           val lthy' = lthy
   418             |> restricted_context restricted
   419             |> Local_Theory.new_group
   420             |> f int
   421             |> Local_Theory.reset_group;
   422         in Theory (finish lthy', SOME lthy') end
   423     | _ => raise UNDEF))
   424   (K ());
   425 
   426 fun local_theory restricted target f = local_theory' restricted target (K f);
   427 
   428 fun present_local_theory target = present_transaction (fn int =>
   429   (fn Theory (gthy, _) =>
   430         let val (finish, lthy) = Named_Target.switch target gthy;
   431         in Theory (finish lthy, SOME lthy) end
   432     | _ => raise UNDEF));
   433 
   434 
   435 (* proof transitions *)
   436 
   437 fun end_proof f = transaction (fn int =>
   438   (fn Proof (prf, (finish, _)) =>
   439         let val state = Proof_Node.current prf in
   440           if can (Proof.assert_bottom true) state then
   441             let
   442               val ctxt' = f int state;
   443               val gthy' = finish ctxt';
   444             in Theory (gthy', SOME ctxt') end
   445           else raise UNDEF
   446         end
   447     | Skipped_Proof (0, (gthy, _)) => Theory (gthy, NONE)
   448     | _ => raise UNDEF));
   449 
   450 local
   451 
   452 fun begin_proof init = transaction (fn int =>
   453   (fn Theory (gthy, _) =>
   454     let
   455       val (finish, prf) = init int gthy;
   456       val skip = Goal.skip_proofs_enabled ();
   457       val schematic_goal = try Proof.schematic_goal prf;
   458       val _ =
   459         if skip andalso schematic_goal = SOME true then
   460           warning "Cannot skip proof of schematic goal statement"
   461         else ();
   462     in
   463       if skip andalso schematic_goal = SOME false then
   464         Skipped_Proof (0, (finish (Proof.global_skip_proof true prf), gthy))
   465       else Proof (Proof_Node.init prf, (finish, gthy))
   466     end
   467   | _ => raise UNDEF));
   468 
   469 in
   470 
   471 fun local_theory_to_proof' restricted target f = begin_proof
   472   (fn int => fn gthy =>
   473     let
   474       val (finish, lthy) = Named_Target.switch target gthy;
   475       val prf = lthy
   476         |> restricted_context restricted
   477         |> Local_Theory.new_group
   478         |> f int;
   479     in (finish o Local_Theory.reset_group, prf) end);
   480 
   481 fun local_theory_to_proof restricted target f =
   482   local_theory_to_proof' restricted target (K f);
   483 
   484 fun theory_to_proof f = begin_proof
   485   (fn _ => fn gthy =>
   486     (Context.Theory o Sign.reset_group o Sign.change_check o Proof_Context.theory_of,
   487       (case gthy of
   488         Context.Theory thy => f (Sign.new_group thy)
   489       | _ => raise UNDEF)));
   490 
   491 end;
   492 
   493 fun forget_proof strict = transaction (fn _ =>
   494   (fn Proof (prf, (_, orig_gthy)) =>
   495         if strict andalso not (Proof.has_bottom_goal (Proof_Node.current prf))
   496         then raise UNDEF else Theory (orig_gthy, NONE)
   497     | Skipped_Proof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   498     | _ => raise UNDEF));
   499 
   500 fun proofs' f = transaction (fn int =>
   501   (fn Proof (prf, x) => Proof (Proof_Node.applys (f int) prf, x)
   502     | skip as Skipped_Proof _ => skip
   503     | _ => raise UNDEF));
   504 
   505 fun proof' f = proofs' ((Seq.single o Seq.Result) oo f);
   506 val proofs = proofs' o K;
   507 val proof = proof' o K;
   508 
   509 fun actual_proof f = transaction (fn _ =>
   510   (fn Proof (prf, x) => Proof (f prf, x)
   511     | _ => raise UNDEF));
   512 
   513 fun skip_proof f = transaction (fn _ =>
   514   (fn Skipped_Proof (h, x) => Skipped_Proof (f h, x)
   515     | _ => raise UNDEF));
   516 
   517 fun skip_proof_to_theory pred = transaction (fn _ =>
   518   (fn Skipped_Proof (d, (gthy, _)) => if pred d then Theory (gthy, NONE) else raise UNDEF
   519     | _ => raise UNDEF));
   520 
   521 
   522 
   523 (** toplevel transactions **)
   524 
   525 (* runtime position *)
   526 
   527 fun exec_id id (tr as Transition {pos, ...}) =
   528   position (Position.put_id (Document_ID.print id) pos) tr;
   529 
   530 fun setmp_thread_position (Transition {pos, ...}) f x =
   531   Position.setmp_thread_data pos f x;
   532 
   533 
   534 (* post-transition hooks *)
   535 
   536 local
   537   val hooks =
   538     Synchronized.var "Toplevel.hooks" ([]: (transition -> state -> state -> unit) list);
   539 in
   540 
   541 fun add_hook hook = Synchronized.change hooks (cons hook);
   542 fun get_hooks () = Synchronized.value hooks;
   543 
   544 end;
   545 
   546 
   547 (* apply transitions *)
   548 
   549 fun get_timing (Transition {timing, ...}) = timing;
   550 fun put_timing timing = map_transition (fn (name, pos, _, trans) => (name, pos, timing, trans));
   551 
   552 local
   553 
   554 fun app int (tr as Transition {name, trans, ...}) =
   555   setmp_thread_position tr (fn state =>
   556     let
   557       val timing_start = Timing.start ();
   558 
   559       val (result, opt_err) =
   560          state |> (apply_trans int trans |> ! profiling > 0 ? profile (! profiling));
   561 
   562       val timing_result = Timing.result timing_start;
   563       val timing_props =
   564         Markup.command_timing :: (Markup.nameN, name_of tr) :: Position.properties_of (pos_of tr);
   565       val _ = Timing.protocol_message timing_props timing_result;
   566     in (result, Option.map (fn UNDEF => ERROR (type_error tr) | exn => exn) opt_err) end);
   567 
   568 in
   569 
   570 fun transition int tr st =
   571   let
   572     val (st', opt_err) = app int tr st;
   573     val opt_err' = opt_err |> Option.map
   574       (fn Runtime.EXCURSION_FAIL exn_info => exn_info
   575         | exn => (Runtime.exn_context (try context_of st) exn, at_command tr));
   576     val _ = get_hooks () |> List.app (fn f => (try (fn () => f tr st st') (); ()));
   577   in (st', opt_err') end;
   578 
   579 end;
   580 
   581 
   582 (* managed commands *)
   583 
   584 fun command_errors int tr st =
   585   (case transition int tr st of
   586     (st', NONE) => ([], SOME st')
   587   | (_, SOME (exn, _)) => (Runtime.exn_messages_ids exn, NONE));
   588 
   589 fun command_exception int tr st =
   590   (case transition int tr st of
   591     (st', NONE) => st'
   592   | (_, SOME (exn, info)) =>
   593       if Exn.is_interrupt exn then reraise exn
   594       else raise Runtime.EXCURSION_FAIL (exn, info));
   595 
   596 val command = command_exception false;
   597 
   598 
   599 (* reset state *)
   600 
   601 local
   602 
   603 fun reset_state check trans st =
   604   if check st then NONE
   605   else #2 (command_errors false (trans empty) st);
   606 
   607 in
   608 
   609 val reset_theory = reset_state is_theory (forget_proof false);
   610 
   611 val reset_proof =
   612   reset_state is_proof
   613     (transaction (fn _ =>
   614       (fn Theory (gthy, _) => Skipped_Proof (0, (gthy, gthy))
   615         | _ => raise UNDEF)));
   616 
   617 end;
   618 
   619 
   620 (* scheduled proof result *)
   621 
   622 datatype result =
   623   Result of transition * state |
   624   Result_List of result list |
   625   Result_Future of result future;
   626 
   627 fun join_results (Result x) = [x]
   628   | join_results (Result_List xs) = maps join_results xs
   629   | join_results (Result_Future x) = join_results (Future.join x);
   630 
   631 local
   632 
   633 structure Result = Proof_Data
   634 (
   635   type T = result;
   636   fun init _ = Result_List [];
   637 );
   638 
   639 val get_result = Result.get o Proof.context_of;
   640 val put_result = Proof.map_context o Result.put;
   641 
   642 fun timing_estimate include_head elem =
   643   let
   644     val trs = Thy_Syntax.flat_element elem |> not include_head ? tl;
   645     val timings = map get_timing trs;
   646   in
   647     if forall is_some timings then
   648       SOME (fold (curry Time.+ o the) timings Time.zeroTime)
   649     else NONE
   650   end;
   651 
   652 fun priority NONE = ~1
   653   | priority (SOME estimate) =
   654       Int.min (Real.floor (Real.max (Math.log10 (Time.toReal estimate), ~3.0)) - 3, ~1);
   655 
   656 fun proof_future_enabled estimate st =
   657   (case try proof_of st of
   658     NONE => false
   659   | SOME state =>
   660       not (Proof.is_relevant state) andalso
   661        (if can (Proof.assert_bottom true) state
   662         then Goal.future_enabled 1
   663         else
   664           (case estimate of
   665             NONE => Goal.future_enabled 2
   666           | SOME t => Goal.future_enabled_timing t)));
   667 
   668 fun atom_result keywords tr st =
   669   let
   670     val st' =
   671       if Goal.future_enabled 1 andalso Keyword.is_diag keywords (name_of tr) then
   672         (Execution.fork
   673           {name = "Toplevel.diag", pos = pos_of tr,
   674             pri = priority (timing_estimate true (Thy_Syntax.atom tr))}
   675           (fn () => command tr st); st)
   676       else command tr st;
   677   in (Result (tr, st'), st') end;
   678 
   679 in
   680 
   681 fun element_result keywords (Thy_Syntax.Element (tr, NONE)) st = atom_result keywords tr st
   682   | element_result keywords (elem as Thy_Syntax.Element (head_tr, SOME element_rest)) st =
   683       let
   684         val (head_result, st') = atom_result keywords head_tr st;
   685         val (body_elems, end_tr) = element_rest;
   686         val estimate = timing_estimate false elem;
   687       in
   688         if not (proof_future_enabled estimate st')
   689         then
   690           let
   691             val proof_trs = maps Thy_Syntax.flat_element body_elems @ [end_tr];
   692             val (proof_results, st'') = fold_map (atom_result keywords) proof_trs st';
   693           in (Result_List (head_result :: proof_results), st'') end
   694         else
   695           let
   696             val finish = Context.Theory o Proof_Context.theory_of;
   697 
   698             val future_proof =
   699               Proof.future_proof (fn state =>
   700                 Execution.fork
   701                   {name = "Toplevel.future_proof", pos = pos_of head_tr, pri = priority estimate}
   702                   (fn () =>
   703                     let
   704                       val State (SOME (Proof (prf, (_, orig_gthy))), prev) = st';
   705                       val prf' = Proof_Node.apply (K state) prf;
   706                       val (result, result_state) =
   707                         State (SOME (Proof (prf', (finish, orig_gthy))), prev)
   708                         |> fold_map (element_result keywords) body_elems ||> command end_tr;
   709                     in (Result_List result, presentation_context_of result_state) end))
   710               #> (fn (res, state') => state' |> put_result (Result_Future res));
   711 
   712             val forked_proof =
   713               proof (future_proof #>
   714                 (fn state => state |> Proof.local_done_proof |> put_result (get_result state))) o
   715               end_proof (fn _ => future_proof #>
   716                 (fn state => state |> Proof.global_done_proof |> Result.put (get_result state)));
   717 
   718             val st'' = st'
   719               |> command (head_tr |> reset_trans |> forked_proof);
   720             val end_result = Result (end_tr, st'');
   721             val result =
   722               Result_List [head_result, Result.get (presentation_context_of st''), end_result];
   723           in (result, st'') end
   724       end;
   725 
   726 end;
   727 
   728 end;