src/Pure/Isar/toplevel.ML
author wenzelm
Tue Nov 10 23:18:03 2009 +0100 (2009-11-10 ago)
changeset 33604 d4220df6fde2
parent 33553 35f2b30593a8
child 33671 4b0f2599ed48
permissions -rw-r--r--
Toplevel.thread provides Isar-style exception output;
     1 (*  Title:      Pure/Isar/toplevel.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Isabelle/Isar toplevel transactions.
     5 *)
     6 
     7 signature TOPLEVEL =
     8 sig
     9   exception UNDEF
    10   type generic_theory
    11   type state
    12   val toplevel: state
    13   val is_toplevel: state -> bool
    14   val is_theory: state -> bool
    15   val is_proof: state -> bool
    16   val level: state -> int
    17   val presentation_context_of: state -> Proof.context
    18   val previous_context_of: state -> Proof.context option
    19   val context_of: state -> Proof.context
    20   val generic_theory_of: state -> generic_theory
    21   val theory_of: state -> theory
    22   val proof_of: state -> Proof.state
    23   val proof_position_of: state -> int
    24   val enter_proof_body: state -> Proof.state
    25   val print_state_context: state -> unit
    26   val print_state: bool -> state -> unit
    27   val quiet: bool Unsynchronized.ref
    28   val debug: bool Unsynchronized.ref
    29   val interact: bool Unsynchronized.ref
    30   val timing: bool Unsynchronized.ref
    31   val profiling: int Unsynchronized.ref
    32   val skip_proofs: bool Unsynchronized.ref
    33   exception TERMINATE
    34   exception TOPLEVEL_ERROR
    35   val program: (unit -> 'a) -> 'a
    36   val thread: bool -> (unit -> unit) -> Thread.thread
    37   type transition
    38   val empty: transition
    39   val init_of: transition -> string option
    40   val name_of: transition -> string
    41   val pos_of: transition -> Position.T
    42   val str_of: transition -> string
    43   val name: string -> transition -> transition
    44   val position: Position.T -> transition -> transition
    45   val interactive: bool -> transition -> transition
    46   val print: transition -> transition
    47   val no_timing: transition -> transition
    48   val init_theory: string -> (bool -> theory) -> (theory -> unit) -> transition -> transition
    49   val exit: transition -> transition
    50   val keep: (state -> unit) -> transition -> transition
    51   val keep': (bool -> state -> unit) -> transition -> transition
    52   val imperative: (unit -> unit) -> transition -> transition
    53   val ignored: Position.T -> transition
    54   val malformed: Position.T -> string -> transition
    55   val theory: (theory -> theory) -> transition -> transition
    56   val generic_theory: (generic_theory -> generic_theory) -> transition -> transition
    57   val theory': (bool -> theory -> theory) -> transition -> transition
    58   val begin_local_theory: bool -> (theory -> local_theory) -> transition -> transition
    59   val end_local_theory: transition -> transition
    60   val local_theory': xstring option -> (bool -> local_theory -> local_theory) ->
    61     transition -> transition
    62   val local_theory: xstring option -> (local_theory -> local_theory) -> transition -> transition
    63   val present_local_theory: xstring option -> (state -> unit) -> transition -> transition
    64   val local_theory_to_proof': xstring option -> (bool -> local_theory -> Proof.state) ->
    65     transition -> transition
    66   val local_theory_to_proof: xstring option -> (local_theory -> Proof.state) ->
    67     transition -> transition
    68   val theory_to_proof: (theory -> Proof.state) -> transition -> transition
    69   val end_proof: (bool -> Proof.state -> Proof.context) -> transition -> transition
    70   val forget_proof: transition -> transition
    71   val present_proof: (state -> unit) -> transition -> transition
    72   val proofs': (bool -> Proof.state -> Proof.state Seq.seq) -> transition -> transition
    73   val proof': (bool -> Proof.state -> Proof.state) -> transition -> transition
    74   val proofs: (Proof.state -> Proof.state Seq.seq) -> transition -> transition
    75   val proof: (Proof.state -> Proof.state) -> transition -> transition
    76   val actual_proof: (Proof_Node.T -> Proof_Node.T) -> transition -> transition
    77   val skip_proof: (int -> int) -> transition -> transition
    78   val skip_proof_to_theory: (int -> bool) -> transition -> transition
    79   val get_id: transition -> string option
    80   val put_id: string -> transition -> transition
    81   val unknown_theory: transition -> transition
    82   val unknown_proof: transition -> transition
    83   val unknown_context: transition -> transition
    84   val setmp_thread_position: transition -> ('a -> 'b) -> 'a -> 'b
    85   val status: transition -> Markup.T -> unit
    86   val error_msg: transition -> exn * string -> unit
    87   val add_hook: (transition -> state -> state -> unit) -> unit
    88   val transition: bool -> transition -> state -> (state * (exn * string) option) option
    89   val commit_exit: Position.T -> transition
    90   val command: transition -> state -> state
    91   val run_command: string -> transition -> state -> state option
    92   val excursion: (transition * transition list) list -> (transition * state) list lazy
    93 end;
    94 
    95 structure Toplevel: TOPLEVEL =
    96 struct
    97 
    98 (** toplevel state **)
    99 
   100 exception UNDEF = Runtime.UNDEF;
   101 
   102 
   103 (* local theory wrappers *)
   104 
   105 type generic_theory = Context.generic;    (*theory or local_theory*)
   106 
   107 val loc_init = Theory_Target.context;
   108 val loc_exit = LocalTheory.exit_global;
   109 
   110 fun loc_begin loc (Context.Theory thy) = loc_init (the_default "-" loc) thy
   111   | loc_begin NONE (Context.Proof lthy) = lthy
   112   | loc_begin (SOME loc) (Context.Proof lthy) = loc_init loc (loc_exit lthy);
   113 
   114 fun loc_finish _ (Context.Theory _) = Context.Theory o loc_exit
   115   | loc_finish NONE (Context.Proof _) = Context.Proof o LocalTheory.restore
   116   | loc_finish (SOME _) (Context.Proof lthy) = fn lthy' =>
   117       Context.Proof (LocalTheory.reinit (LocalTheory.raw_theory (K (loc_exit lthy')) lthy));
   118 
   119 
   120 (* datatype node *)
   121 
   122 datatype node =
   123   Theory of generic_theory * Proof.context option
   124     (*theory with presentation context*) |
   125   Proof of Proof_Node.T * ((Proof.context -> generic_theory) * generic_theory)
   126     (*proof node, finish, original theory*) |
   127   SkipProof of int * (generic_theory * generic_theory);
   128     (*proof depth, resulting theory, original theory*)
   129 
   130 val theory_node = fn Theory (gthy, _) => SOME gthy | _ => NONE;
   131 val proof_node = fn Proof (prf, _) => SOME prf | _ => NONE;
   132 
   133 fun cases_node f _ (Theory (gthy, _)) = f gthy
   134   | cases_node _ g (Proof (prf, _)) = g (Proof_Node.current prf)
   135   | cases_node f _ (SkipProof (_, (gthy, _))) = f gthy;
   136 
   137 val context_node = cases_node Context.proof_of Proof.context_of;
   138 
   139 
   140 (* datatype state *)
   141 
   142 type node_info = node * (theory -> unit);  (*node with exit operation*)
   143 datatype state = State of node_info option * node_info option;  (*current, previous*)
   144 
   145 val toplevel = State (NONE, NONE);
   146 
   147 fun is_toplevel (State (NONE, _)) = true
   148   | is_toplevel _ = false;
   149 
   150 fun level (State (NONE, _)) = 0
   151   | level (State (SOME (Theory _, _), _)) = 0
   152   | level (State (SOME (Proof (prf, _), _), _)) = Proof.level (Proof_Node.current prf)
   153   | level (State (SOME (SkipProof (d, _), _), _)) = d + 1;   (*different notion of proof depth!*)
   154 
   155 fun str_of_state (State (NONE, _)) = "at top level"
   156   | str_of_state (State (SOME (Theory (Context.Theory _, _), _), _)) = "in theory mode"
   157   | str_of_state (State (SOME (Theory (Context.Proof _, _), _), _)) = "in local theory mode"
   158   | str_of_state (State (SOME (Proof _, _), _)) = "in proof mode"
   159   | str_of_state (State (SOME (SkipProof _, _), _)) = "in skipped proof mode";
   160 
   161 
   162 (* current node *)
   163 
   164 fun node_of (State (NONE, _)) = raise UNDEF
   165   | node_of (State (SOME (node, _), _)) = node;
   166 
   167 fun is_theory state = not (is_toplevel state) andalso is_some (theory_node (node_of state));
   168 fun is_proof state = not (is_toplevel state) andalso is_some (proof_node (node_of state));
   169 
   170 fun node_case f g state = cases_node f g (node_of state);
   171 
   172 fun presentation_context_of state =
   173   (case try node_of state of
   174     SOME (Theory (_, SOME ctxt)) => ctxt
   175   | SOME node => context_node node
   176   | NONE => raise UNDEF);
   177 
   178 fun previous_context_of (State (_, NONE)) = NONE
   179   | previous_context_of (State (_, SOME (prev, _))) = SOME (context_node prev);
   180 
   181 val context_of = node_case Context.proof_of Proof.context_of;
   182 val generic_theory_of = node_case I (Context.Proof o Proof.context_of);
   183 val theory_of = node_case Context.theory_of Proof.theory_of;
   184 val proof_of = node_case (fn _ => raise UNDEF) I;
   185 
   186 fun proof_position_of state =
   187   (case node_of state of
   188     Proof (prf, _) => Proof_Node.position prf
   189   | _ => raise UNDEF);
   190 
   191 val enter_proof_body = node_case (Proof.init o Context.proof_of) Proof.enter_forward;
   192 
   193 
   194 (* print state *)
   195 
   196 val pretty_context = LocalTheory.pretty o Context.cases (Theory_Target.init NONE) I;
   197 
   198 fun print_state_context state =
   199   (case try node_of state of
   200     NONE => []
   201   | SOME (Theory (gthy, _)) => pretty_context gthy
   202   | SOME (Proof (_, (_, gthy))) => pretty_context gthy
   203   | SOME (SkipProof (_, (gthy, _))) => pretty_context gthy)
   204   |> Pretty.chunks |> Pretty.writeln;
   205 
   206 fun print_state prf_only state =
   207   (case try node_of state of
   208     NONE => []
   209   | SOME (Theory (gthy, _)) => if prf_only then [] else pretty_context gthy
   210   | SOME (Proof (prf, _)) =>
   211       Proof.pretty_state (Proof_Node.position prf) (Proof_Node.current prf)
   212   | SOME (SkipProof (d, _)) => [Pretty.str ("skipped proof: depth " ^ string_of_int d)])
   213   |> Pretty.markup_chunks Markup.state |> Pretty.writeln;
   214 
   215 
   216 
   217 (** toplevel transitions **)
   218 
   219 val quiet = Unsynchronized.ref false;
   220 val debug = Output.debugging;
   221 val interact = Unsynchronized.ref false;
   222 val timing = Output.timing;
   223 val profiling = Unsynchronized.ref 0;
   224 val skip_proofs = Unsynchronized.ref false;
   225 
   226 exception TERMINATE = Runtime.TERMINATE;
   227 exception EXCURSION_FAIL = Runtime.EXCURSION_FAIL;
   228 exception TOPLEVEL_ERROR = Runtime.TOPLEVEL_ERROR;
   229 
   230 fun program body =
   231  (body
   232   |> Runtime.controlled_execution
   233   |> Runtime.toplevel_error (Output.error_msg o ML_Compiler.exn_message)) ();
   234 
   235 fun thread interrupts body =
   236   Thread.fork
   237     (((fn () => body () handle Exn.Interrupt => ())
   238         |> Runtime.debugging
   239         |> Runtime.toplevel_error
   240           (fn exn => priority ("## INTERNAL ERROR ##\n" ^ ML_Compiler.exn_message exn))),
   241       SimpleThread.attributes interrupts);
   242 
   243 
   244 (* node transactions -- maintaining stable checkpoints *)
   245 
   246 exception FAILURE of state * exn;
   247 
   248 local
   249 
   250 fun reset_presentation (Theory (gthy, _)) = Theory (gthy, NONE)
   251   | reset_presentation node = node;
   252 
   253 fun is_draft_theory (Theory (gthy, _)) = Context.is_draft (Context.theory_of gthy)
   254   | is_draft_theory _ = false;
   255 
   256 fun is_stale state = Context.is_stale (theory_of state) handle Runtime.UNDEF => false;
   257 
   258 fun stale_error NONE = SOME (ERROR "Stale theory encountered after successful execution!")
   259   | stale_error some = some;
   260 
   261 fun map_theory f (Theory (gthy, ctxt)) =
   262       Theory (Context.mapping f (LocalTheory.raw_theory f) gthy, ctxt)
   263   | map_theory _ node = node;
   264 
   265 in
   266 
   267 fun apply_transaction f g (node, exit) =
   268   let
   269     val _ = is_draft_theory node andalso error "Illegal draft theory in toplevel state";
   270     val cont_node = reset_presentation node;
   271     val back_node = map_theory (Theory.checkpoint o Theory.copy) cont_node;
   272     fun state_error e nd = (State (SOME (nd, exit), SOME (node, exit)), e);
   273 
   274     val (result, err) =
   275       cont_node
   276       |> Runtime.controlled_execution f
   277       |> map_theory Theory.checkpoint
   278       |> state_error NONE
   279       handle exn => state_error (SOME exn) cont_node;
   280 
   281     val (result', err') =
   282       if is_stale result then state_error (stale_error err) back_node
   283       else (result, err);
   284   in
   285     (case err' of
   286       NONE => tap g result'
   287     | SOME exn => raise FAILURE (result', exn))
   288   end;
   289 
   290 end;
   291 
   292 
   293 (* primitive transitions *)
   294 
   295 datatype trans =
   296   Init of string * (bool -> theory) * (theory -> unit) | (*theory name, init, exit*)
   297   Exit |                                         (*formal exit of theory -- without committing*)
   298   CommitExit |                                   (*exit and commit final theory*)
   299   Keep of bool -> state -> unit |                (*peek at state*)
   300   Transaction of (bool -> node -> node) * (state -> unit);  (*node transaction and presentation*)
   301 
   302 local
   303 
   304 fun apply_tr int (Init (_, f, exit)) (State (NONE, _)) =
   305       State (SOME (Theory (Context.Theory (Theory.checkpoint (f int)), NONE), exit), NONE)
   306   | apply_tr _ Exit (State (prev as SOME (Theory (Context.Theory _, _), _), _)) =
   307       State (NONE, prev)
   308   | apply_tr _ CommitExit (State (NONE, SOME (Theory (Context.Theory thy, _), exit))) =
   309       (Runtime.controlled_execution exit thy; toplevel)
   310   | apply_tr int (Keep f) state =
   311       Runtime.controlled_execution (fn x => tap (f int) x) state
   312   | apply_tr int (Transaction (f, g)) (State (SOME state, _)) =
   313       apply_transaction (fn x => f int x) g state
   314   | apply_tr _ _ _ = raise UNDEF;
   315 
   316 fun apply_union _ [] state = raise FAILURE (state, UNDEF)
   317   | apply_union int (tr :: trs) state =
   318       apply_union int trs state
   319         handle Runtime.UNDEF => apply_tr int tr state
   320           | FAILURE (alt_state, UNDEF) => apply_tr int tr alt_state
   321           | exn as FAILURE _ => raise exn
   322           | exn => raise FAILURE (state, exn);
   323 
   324 in
   325 
   326 fun apply_trans int trs state = (apply_union int trs state, NONE)
   327   handle FAILURE (alt_state, exn) => (alt_state, SOME exn) | exn => (state, SOME exn);
   328 
   329 end;
   330 
   331 
   332 (* datatype transition *)
   333 
   334 datatype transition = Transition of
   335  {name: string,              (*command name*)
   336   pos: Position.T,           (*source position*)
   337   int_only: bool,            (*interactive-only*)
   338   print: bool,               (*print result state*)
   339   no_timing: bool,           (*suppress timing*)
   340   trans: trans list};        (*primitive transitions (union)*)
   341 
   342 fun make_transition (name, pos, int_only, print, no_timing, trans) =
   343   Transition {name = name, pos = pos, int_only = int_only, print = print, no_timing = no_timing,
   344     trans = trans};
   345 
   346 fun map_transition f (Transition {name, pos, int_only, print, no_timing, trans}) =
   347   make_transition (f (name, pos, int_only, print, no_timing, trans));
   348 
   349 val empty = make_transition ("", Position.none, false, false, false, []);
   350 
   351 
   352 (* diagnostics *)
   353 
   354 fun init_of (Transition {trans = [Init (name, _, _)], ...}) = SOME name
   355   | init_of _ = NONE;
   356 
   357 fun name_of (Transition {name, ...}) = name;
   358 fun pos_of (Transition {pos, ...}) = pos;
   359 fun str_of tr = quote (name_of tr) ^ Position.str_of (pos_of tr);
   360 
   361 fun command_msg msg tr = msg ^ "command " ^ str_of tr;
   362 fun at_command tr = command_msg "At " tr ^ ".";
   363 
   364 fun type_error tr state =
   365   ERROR (command_msg "Illegal application of " tr ^ " " ^ str_of_state state);
   366 
   367 
   368 (* modify transitions *)
   369 
   370 fun name name = map_transition (fn (_, pos, int_only, print, no_timing, trans) =>
   371   (name, pos, int_only, print, no_timing, trans));
   372 
   373 fun position pos = map_transition (fn (name, _, int_only, print, no_timing, trans) =>
   374   (name, pos, int_only, print, no_timing, trans));
   375 
   376 fun interactive int_only = map_transition (fn (name, pos, _, print, no_timing, trans) =>
   377   (name, pos, int_only, print, no_timing, trans));
   378 
   379 val no_timing = map_transition (fn (name, pos, int_only, print, _, trans) =>
   380   (name, pos, int_only, print, true, trans));
   381 
   382 fun add_trans tr = map_transition (fn (name, pos, int_only, print, no_timing, trans) =>
   383   (name, pos, int_only, print, no_timing, tr :: trans));
   384 
   385 val reset_trans = map_transition (fn (name, pos, int_only, print, no_timing, _) =>
   386   (name, pos, int_only, print, no_timing, []));
   387 
   388 fun set_print print = map_transition (fn (name, pos, int_only, _, no_timing, trans) =>
   389   (name, pos, int_only, print, no_timing, trans));
   390 
   391 val print = set_print true;
   392 
   393 
   394 (* basic transitions *)
   395 
   396 fun init_theory name f exit = add_trans (Init (name, f, exit));
   397 val exit = add_trans Exit;
   398 val keep' = add_trans o Keep;
   399 
   400 fun present_transaction f g = add_trans (Transaction (f, g));
   401 fun transaction f = present_transaction f (K ());
   402 
   403 fun keep f = add_trans (Keep (fn _ => f));
   404 fun imperative f = keep (fn _ => f ());
   405 
   406 fun ignored pos = empty |> name "<ignored>" |> position pos |> imperative I;
   407 fun malformed pos msg =
   408   empty |> name "<malformed>" |> position pos |> imperative (fn () => error msg);
   409 
   410 val unknown_theory = imperative (fn () => warning "Unknown theory context");
   411 val unknown_proof = imperative (fn () => warning "Unknown proof context");
   412 val unknown_context = imperative (fn () => warning "Unknown context");
   413 
   414 
   415 (* theory transitions *)
   416 
   417 fun generic_theory f = transaction (fn _ =>
   418   (fn Theory (gthy, _) => Theory (f gthy, NONE)
   419     | _ => raise UNDEF));
   420 
   421 fun theory' f = transaction (fn int =>
   422   (fn Theory (Context.Theory thy, _) => Theory (Context.Theory (f int thy), NONE)
   423     | _ => raise UNDEF));
   424 
   425 fun theory f = theory' (K f);
   426 
   427 fun begin_local_theory begin f = transaction (fn _ =>
   428   (fn Theory (Context.Theory thy, _) =>
   429         let
   430           val lthy = f thy;
   431           val gthy = if begin then Context.Proof lthy else Context.Theory (loc_exit lthy);
   432         in Theory (gthy, SOME lthy) end
   433     | _ => raise UNDEF));
   434 
   435 val end_local_theory = transaction (fn _ =>
   436   (fn Theory (Context.Proof lthy, _) => Theory (Context.Theory (loc_exit lthy), SOME lthy)
   437     | _ => raise UNDEF));
   438 
   439 local
   440 
   441 fun local_theory_presentation loc f = present_transaction (fn int =>
   442   (fn Theory (gthy, _) =>
   443         let
   444           val finish = loc_finish loc gthy;
   445           val lthy' = f int (loc_begin loc gthy);
   446         in Theory (finish lthy', SOME lthy') end
   447     | _ => raise UNDEF));
   448 
   449 in
   450 
   451 fun local_theory' loc f = local_theory_presentation loc f (K ());
   452 fun local_theory loc f = local_theory' loc (K f);
   453 fun present_local_theory loc = local_theory_presentation loc (K I);
   454 
   455 end;
   456 
   457 
   458 (* proof transitions *)
   459 
   460 fun end_proof f = transaction (fn int =>
   461   (fn Proof (prf, (finish, _)) =>
   462         let val state = Proof_Node.current prf in
   463           if can (Proof.assert_bottom true) state then
   464             let
   465               val ctxt' = f int state;
   466               val gthy' = finish ctxt';
   467             in Theory (gthy', SOME ctxt') end
   468           else raise UNDEF
   469         end
   470     | SkipProof (0, (gthy, _)) => Theory (gthy, NONE)
   471     | _ => raise UNDEF));
   472 
   473 local
   474 
   475 fun begin_proof init finish = transaction (fn int =>
   476   (fn Theory (gthy, _) =>
   477     let
   478       val prf = init int gthy;
   479       val skip = ! skip_proofs;
   480       val schematic = Proof.schematic_goal prf;
   481     in
   482       if skip andalso schematic then
   483         warning "Cannot skip proof of schematic goal statement"
   484       else ();
   485       if skip andalso not schematic then
   486         SkipProof (0, (finish gthy (Proof.global_skip_proof int prf), gthy))
   487       else Proof (Proof_Node.init prf, (finish gthy, gthy))
   488     end
   489   | _ => raise UNDEF));
   490 
   491 in
   492 
   493 fun local_theory_to_proof' loc f = begin_proof
   494   (fn int => fn gthy => f int (loc_begin loc gthy))
   495   (loc_finish loc);
   496 
   497 fun local_theory_to_proof loc f = local_theory_to_proof' loc (K f);
   498 
   499 fun theory_to_proof f = begin_proof
   500   (K (fn Context.Theory thy => f thy | _ => raise UNDEF))
   501   (K (Context.Theory o ProofContext.theory_of));
   502 
   503 end;
   504 
   505 val forget_proof = transaction (fn _ =>
   506   (fn Proof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   507     | SkipProof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   508     | _ => raise UNDEF));
   509 
   510 val present_proof = present_transaction (fn _ =>
   511   (fn Proof (prf, x) => Proof (Proof_Node.apply I prf, x)
   512     | skip as SkipProof _ => skip
   513     | _ => raise UNDEF));
   514 
   515 fun proofs' f = transaction (fn int =>
   516   (fn Proof (prf, x) => Proof (Proof_Node.applys (f int) prf, x)
   517     | skip as SkipProof _ => skip
   518     | _ => raise UNDEF));
   519 
   520 fun proof' f = proofs' (Seq.single oo f);
   521 val proofs = proofs' o K;
   522 val proof = proof' o K;
   523 
   524 fun actual_proof f = transaction (fn _ =>
   525   (fn Proof (prf, x) => Proof (f prf, x)
   526     | _ => raise UNDEF));
   527 
   528 fun skip_proof f = transaction (fn _ =>
   529   (fn SkipProof (h, x) => SkipProof (f h, x)
   530     | _ => raise UNDEF));
   531 
   532 fun skip_proof_to_theory pred = transaction (fn _ =>
   533   (fn SkipProof (d, (gthy, _)) => if pred d then Theory (gthy, NONE) else raise UNDEF
   534   | _ => raise UNDEF));
   535 
   536 
   537 
   538 (** toplevel transactions **)
   539 
   540 (* identification *)
   541 
   542 fun get_id (Transition {pos, ...}) = Position.get_id pos;
   543 fun put_id id (tr as Transition {pos, ...}) = position (Position.put_id id pos) tr;
   544 
   545 
   546 (* thread position *)
   547 
   548 fun setmp_thread_position (Transition {pos, ...}) f x =
   549   Position.setmp_thread_data pos f x;
   550 
   551 fun status tr m =
   552   setmp_thread_position tr (fn () => Output.status (Markup.markup m "")) ();
   553 
   554 fun error_msg tr exn_info =
   555   setmp_thread_position tr (fn () =>
   556     Output.error_msg (ML_Compiler.exn_message (EXCURSION_FAIL exn_info))) ();
   557 
   558 
   559 (* post-transition hooks *)
   560 
   561 local val hooks = Unsynchronized.ref ([]: (transition -> state -> state -> unit) list) in
   562 
   563 fun add_hook f = CRITICAL (fn () => Unsynchronized.change hooks (cons f));
   564 fun get_hooks () = ! hooks;
   565 
   566 end;
   567 
   568 
   569 (* apply transitions *)
   570 
   571 local
   572 
   573 fun app int (tr as Transition {trans, print, no_timing, ...}) =
   574   setmp_thread_position tr (fn state =>
   575     let
   576       fun do_timing f x = (warning (command_msg "" tr); timeap f x);
   577       fun do_profiling f x = profile (! profiling) f x;
   578 
   579       val (result, status) =
   580          state |> (apply_trans int trans
   581           |> (if ! profiling > 0 andalso not no_timing then do_profiling else I)
   582           |> (if ! profiling > 0 orelse ! timing andalso not no_timing then do_timing else I));
   583 
   584       val _ = if int andalso not (! quiet) andalso print then print_state false result else ();
   585     in (result, Option.map (fn UNDEF => type_error tr state | exn => exn) status) end);
   586 
   587 in
   588 
   589 fun transition int tr st =
   590   let
   591     val hooks = get_hooks ();
   592     fun apply_hooks st' = hooks |> List.app (fn f => (try (fn () => f tr st st') (); ()));
   593 
   594     val ctxt = try context_of st;
   595     val res =
   596       (case app int tr st of
   597         (_, SOME TERMINATE) => NONE
   598       | (st', SOME (EXCURSION_FAIL exn_info)) => SOME (st', SOME exn_info)
   599       | (st', SOME exn) => SOME (st', SOME (Runtime.exn_context ctxt exn, at_command tr))
   600       | (st', NONE) => SOME (st', NONE));
   601     val _ = (case res of SOME (st', NONE) => apply_hooks st' | _ => ());
   602   in res end;
   603 
   604 end;
   605 
   606 
   607 (* commit final exit *)
   608 
   609 fun commit_exit pos =
   610   name "end" empty
   611   |> position pos
   612   |> add_trans CommitExit
   613   |> imperative (fn () => warning "Expected to find finished theory");
   614 
   615 
   616 (* nested commands *)
   617 
   618 fun command tr st =
   619   (case transition (! interact) tr st of
   620     SOME (st', NONE) => st'
   621   | SOME (_, SOME exn_info) => raise EXCURSION_FAIL exn_info
   622   | NONE => raise EXCURSION_FAIL (TERMINATE, at_command tr));
   623 
   624 fun command_result tr st =
   625   let val st' = command tr st
   626   in (st', st') end;
   627 
   628 fun run_command thy_name tr st =
   629   (case
   630       (case init_of tr of
   631         SOME name => Exn.capture (fn () => ThyLoad.check_name thy_name name) ()
   632       | NONE => Exn.Result ()) of
   633     Exn.Result () =>
   634       (case transition true tr st of
   635         SOME (st', NONE) => (status tr Markup.finished; SOME st')
   636       | SOME (_, SOME exn_info) => (error_msg tr exn_info; status tr Markup.failed; NONE)
   637       | NONE => (error_msg tr (TERMINATE, at_command tr); status tr Markup.failed; NONE))
   638   | Exn.Exn exn => (error_msg tr (exn, at_command tr); status tr Markup.failed; NONE));
   639 
   640 
   641 (* excursion of units, consisting of commands with proof *)
   642 
   643 structure States = Proof_Data
   644 (
   645   type T = state list future option;
   646   fun init _ = NONE;
   647 );
   648 
   649 fun proof_result immediate (tr, proof_trs) st =
   650   let val st' = command tr st in
   651     if immediate orelse null proof_trs orelse
   652       not (can proof_of st') orelse Proof.is_relevant (proof_of st')
   653     then
   654       let val (states, st'') = fold_map command_result proof_trs st'
   655       in (Lazy.value ((tr, st') :: (proof_trs ~~ states)), st'') end
   656     else
   657       let
   658         val (body_trs, end_tr) = split_last proof_trs;
   659         val finish = Context.Theory o ProofContext.theory_of;
   660 
   661         val future_proof = Proof.global_future_proof
   662           (fn prf =>
   663             Future.fork_pri ~1 (fn () =>
   664               let val (states, result_state) =
   665                 (case st' of State (SOME (Proof (_, (_, orig_gthy)), exit), prev)
   666                   => State (SOME (Proof (Proof_Node.init prf, (finish, orig_gthy)), exit), prev))
   667                 |> fold_map command_result body_trs
   668                 ||> command (end_tr |> set_print false);
   669               in (states, presentation_context_of result_state) end))
   670           #> (fn (states, ctxt) => States.put (SOME states) ctxt);
   671 
   672         val st'' = st' |> command (end_tr |> reset_trans |> end_proof (K future_proof));
   673 
   674         val states =
   675           (case States.get (presentation_context_of st'') of
   676             NONE => sys_error ("No future states for " ^ name_of tr ^ Position.str_of (pos_of tr))
   677           | SOME states => states);
   678         val result = Lazy.lazy
   679           (fn () => (tr, st') :: (body_trs ~~ Future.join states) @ [(end_tr, st'')]);
   680 
   681       in (result, st'') end
   682   end;
   683 
   684 fun excursion input =
   685   let
   686     val end_pos = if null input then error "No input" else pos_of (fst (List.last input));
   687 
   688     val immediate = not (Goal.future_enabled ());
   689     val (results, end_state) = fold_map (proof_result immediate) input toplevel;
   690     val _ =
   691       (case end_state of
   692         State (NONE, SOME (Theory (Context.Theory _, _), _)) =>
   693           command (commit_exit end_pos) end_state
   694       | _ => error "Unfinished development at end of input");
   695   in Lazy.lazy (fn () => maps Lazy.force results) end;
   696 
   697 end;