src/Pure/Isar/toplevel.ML
author wenzelm
Mon Dec 21 14:18:57 2015 +0100 (2015-12-21 ago)
changeset 61886 d4c89ea5e6dc
parent 61208 19118f9b939d
child 62239 6ee95b93fbed
permissions -rw-r--r--
discontinued built-in profiling: avoid danger of conflicting invocations (multithreading etc.);
     1 (*  Title:      Pure/Isar/toplevel.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Isabelle/Isar toplevel transactions.
     5 *)
     6 
     7 signature TOPLEVEL =
     8 sig
     9   exception UNDEF
    10   type state
    11   val toplevel: state
    12   val is_toplevel: state -> bool
    13   val is_theory: state -> bool
    14   val is_proof: state -> bool
    15   val is_skipped_proof: state -> bool
    16   val level: state -> int
    17   val presentation_context_of: state -> Proof.context
    18   val previous_context_of: state -> Proof.context option
    19   val context_of: state -> Proof.context
    20   val generic_theory_of: state -> generic_theory
    21   val theory_of: state -> theory
    22   val proof_of: state -> Proof.state
    23   val proof_position_of: state -> int
    24   val end_theory: Position.T -> state -> theory
    25   val pretty_context: state -> Pretty.T list
    26   val pretty_state: state -> Pretty.T list
    27   val string_of_state: state -> string
    28   val pretty_abstract: state -> Pretty.T
    29   type transition
    30   val empty: transition
    31   val name_of: transition -> string
    32   val pos_of: transition -> Position.T
    33   val type_error: transition -> string
    34   val name: string -> transition -> transition
    35   val position: Position.T -> transition -> transition
    36   val init_theory: (unit -> theory) -> transition -> transition
    37   val is_init: transition -> bool
    38   val modify_init: (unit -> theory) -> transition -> transition
    39   val exit: transition -> transition
    40   val keep: (state -> unit) -> transition -> transition
    41   val keep': (bool -> state -> unit) -> transition -> transition
    42   val keep_proof: (state -> unit) -> transition -> transition
    43   val ignored: Position.T -> transition
    44   val is_ignored: transition -> bool
    45   val malformed: Position.T -> string -> transition
    46   val generic_theory: (generic_theory -> generic_theory) -> transition -> transition
    47   val theory': (bool -> theory -> theory) -> transition -> transition
    48   val theory: (theory -> theory) -> transition -> transition
    49   val begin_local_theory: bool -> (theory -> local_theory) -> transition -> transition
    50   val end_local_theory: transition -> transition
    51   val open_target: (generic_theory -> local_theory) -> transition -> transition
    52   val close_target: transition -> transition
    53   val local_theory': (bool * Position.T) option -> (xstring * Position.T) option ->
    54     (bool -> local_theory -> local_theory) -> transition -> transition
    55   val local_theory: (bool * Position.T) option -> (xstring * Position.T) option ->
    56     (local_theory -> local_theory) -> transition -> transition
    57   val present_local_theory: (xstring * Position.T) option -> (state -> unit) ->
    58     transition -> transition
    59   val local_theory_to_proof': (bool * Position.T) option -> (xstring * Position.T) option ->
    60     (bool -> local_theory -> Proof.state) -> transition -> transition
    61   val local_theory_to_proof: (bool * Position.T) option -> (xstring * Position.T) option ->
    62     (local_theory -> Proof.state) -> transition -> transition
    63   val theory_to_proof: (theory -> Proof.state) -> transition -> transition
    64   val end_proof: (bool -> Proof.state -> Proof.context) -> transition -> transition
    65   val forget_proof: bool -> transition -> transition
    66   val proofs': (bool -> Proof.state -> Proof.state Seq.result Seq.seq) -> transition -> transition
    67   val proof': (bool -> Proof.state -> Proof.state) -> transition -> transition
    68   val proofs: (Proof.state -> Proof.state Seq.result Seq.seq) -> transition -> transition
    69   val proof: (Proof.state -> Proof.state) -> transition -> transition
    70   val actual_proof: (Proof_Node.T -> Proof_Node.T) -> transition -> transition
    71   val skip_proof: (unit -> unit) -> transition -> transition
    72   val skip_proof_open: transition -> transition
    73   val skip_proof_close: transition -> transition
    74   val exec_id: Document_ID.exec -> transition -> transition
    75   val setmp_thread_position: transition -> ('a -> 'b) -> 'a -> 'b
    76   val add_hook: (transition -> state -> state -> unit) -> unit
    77   val get_timing: transition -> Time.time option
    78   val put_timing: Time.time option -> transition -> transition
    79   val transition: bool -> transition -> state -> state * (exn * string) option
    80   val command_errors: bool -> transition -> state -> Runtime.error list * state option
    81   val command_exception: bool -> transition -> state -> state
    82   val reset_theory: state -> state option
    83   val reset_proof: state -> state option
    84   type result
    85   val join_results: result -> (transition * state) list
    86   val element_result: Keyword.keywords -> transition Thy_Syntax.element -> state -> result * state
    87 end;
    88 
    89 structure Toplevel: TOPLEVEL =
    90 struct
    91 
    92 (** toplevel state **)
    93 
    94 exception UNDEF = Runtime.UNDEF;
    95 
    96 
    97 (* datatype node *)
    98 
    99 datatype node =
   100   Theory of generic_theory * Proof.context option
   101     (*theory with presentation context*) |
   102   Proof of Proof_Node.T * ((Proof.context -> generic_theory) * generic_theory)
   103     (*proof node, finish, original theory*) |
   104   Skipped_Proof of int * (generic_theory * generic_theory);
   105     (*proof depth, resulting theory, original theory*)
   106 
   107 val theory_node = fn Theory (gthy, _) => SOME gthy | _ => NONE;
   108 val proof_node = fn Proof (prf, _) => SOME prf | _ => NONE;
   109 val skipped_proof_node = fn Skipped_Proof _ => true | _ => false;
   110 
   111 fun cases_node f _ (Theory (gthy, _)) = f gthy
   112   | cases_node _ g (Proof (prf, _)) = g (Proof_Node.current prf)
   113   | cases_node f _ (Skipped_Proof (_, (gthy, _))) = f gthy;
   114 
   115 val context_node = cases_node Context.proof_of Proof.context_of;
   116 
   117 
   118 (* datatype state *)
   119 
   120 datatype state = State of node option * node option;  (*current, previous*)
   121 
   122 val toplevel = State (NONE, NONE);
   123 
   124 fun is_toplevel (State (NONE, _)) = true
   125   | is_toplevel _ = false;
   126 
   127 fun level (State (NONE, _)) = 0
   128   | level (State (SOME (Theory _), _)) = 0
   129   | level (State (SOME (Proof (prf, _)), _)) = Proof.level (Proof_Node.current prf)
   130   | level (State (SOME (Skipped_Proof (d, _)), _)) = d + 1;   (*different notion of proof depth!*)
   131 
   132 fun str_of_state (State (NONE, SOME (Theory (Context.Theory thy, _)))) =
   133       "at top level, result theory " ^ quote (Context.theory_name thy)
   134   | str_of_state (State (NONE, _)) = "at top level"
   135   | str_of_state (State (SOME (Theory (Context.Theory _, _)), _)) = "in theory mode"
   136   | str_of_state (State (SOME (Theory (Context.Proof _, _)), _)) = "in local theory mode"
   137   | str_of_state (State (SOME (Proof _), _)) = "in proof mode"
   138   | str_of_state (State (SOME (Skipped_Proof _), _)) = "in skipped proof mode";
   139 
   140 
   141 (* current node *)
   142 
   143 fun node_of (State (NONE, _)) = raise UNDEF
   144   | node_of (State (SOME node, _)) = node;
   145 
   146 fun is_theory state = not (is_toplevel state) andalso is_some (theory_node (node_of state));
   147 fun is_proof state = not (is_toplevel state) andalso is_some (proof_node (node_of state));
   148 fun is_skipped_proof state = not (is_toplevel state) andalso skipped_proof_node (node_of state);
   149 
   150 fun node_case f g state = cases_node f g (node_of state);
   151 
   152 fun presentation_context_of state =
   153   (case try node_of state of
   154     SOME (Theory (_, SOME ctxt)) => ctxt
   155   | SOME node => context_node node
   156   | NONE => raise UNDEF);
   157 
   158 fun previous_context_of (State (_, NONE)) = NONE
   159   | previous_context_of (State (_, SOME prev)) = SOME (context_node prev);
   160 
   161 val context_of = node_case Context.proof_of Proof.context_of;
   162 val generic_theory_of = node_case I (Context.Proof o Proof.context_of);
   163 val theory_of = node_case Context.theory_of Proof.theory_of;
   164 val proof_of = node_case (fn _ => error "No proof state") I;
   165 
   166 fun proof_position_of state =
   167   (case node_of state of
   168     Proof (prf, _) => Proof_Node.position prf
   169   | _ => ~1);
   170 
   171 fun end_theory _ (State (NONE, SOME (Theory (Context.Theory thy, _)))) = thy
   172   | end_theory pos (State (NONE, _)) = error ("Bad theory" ^ Position.here pos)
   173   | end_theory pos (State (SOME _, _)) = error ("Unfinished theory" ^ Position.here pos);
   174 
   175 
   176 (* print state *)
   177 
   178 fun pretty_context state =
   179   (case try node_of state of
   180     NONE => []
   181   | SOME node =>
   182       let
   183         val gthy =
   184           (case node of
   185             Theory (gthy, _) => gthy
   186           | Proof (_, (_, gthy)) => gthy
   187           | Skipped_Proof (_, (gthy, _)) => gthy);
   188         val lthy = Context.cases (Named_Target.theory_init) I gthy;
   189       in Local_Theory.pretty lthy end);
   190 
   191 fun pretty_state state =
   192   (case try node_of state of
   193     NONE => []
   194   | SOME (Theory _) => []
   195   | SOME (Proof (prf, _)) => Proof.pretty_state (Proof_Node.current prf)
   196   | SOME (Skipped_Proof (d, _)) => [Pretty.str ("skipped proof: depth " ^ string_of_int d)]);
   197 
   198 val string_of_state = pretty_state #> Pretty.chunks #> Pretty.string_of;
   199 
   200 fun pretty_abstract state = Pretty.str ("<Isar " ^ str_of_state state ^ ">");
   201 
   202 
   203 
   204 (** toplevel transitions **)
   205 
   206 (* node transactions -- maintaining stable checkpoints *)
   207 
   208 exception FAILURE of state * exn;
   209 
   210 local
   211 
   212 fun reset_presentation (Theory (gthy, _)) = Theory (gthy, NONE)
   213   | reset_presentation node = node;
   214 
   215 fun map_theory f (Theory (gthy, ctxt)) =
   216       Theory (Context.mapping f (Local_Theory.raw_theory f) gthy, ctxt)
   217   | map_theory _ node = node;
   218 
   219 in
   220 
   221 fun apply_transaction f g node =
   222   let
   223     val cont_node = reset_presentation node;
   224     val context = cases_node I (Context.Proof o Proof.context_of) cont_node;
   225     fun state_error e nd = (State (SOME nd, SOME node), e);
   226 
   227     val (result, err) =
   228       cont_node
   229       |> Runtime.controlled_execution (SOME context) f
   230       |> state_error NONE
   231       handle exn => state_error (SOME exn) cont_node;
   232   in
   233     (case err of
   234       NONE => tap g result
   235     | SOME exn => raise FAILURE (result, exn))
   236   end;
   237 
   238 val exit_transaction =
   239   apply_transaction
   240     (fn Theory (Context.Theory thy, _) => Theory (Context.Theory (Theory.end_theory thy), NONE)
   241       | node => node) (K ())
   242   #> (fn State (node', _) => State (NONE, node'));
   243 
   244 end;
   245 
   246 
   247 (* primitive transitions *)
   248 
   249 datatype trans =
   250   Init of unit -> theory |               (*init theory*)
   251   Exit |                                 (*formal exit of theory*)
   252   Keep of bool -> state -> unit |        (*peek at state*)
   253   Transaction of (bool -> node -> node) * (state -> unit);  (*node transaction and presentation*)
   254 
   255 local
   256 
   257 fun apply_tr _ (Init f) (State (NONE, _)) =
   258       State (SOME (Theory (Context.Theory (Runtime.controlled_execution NONE f ()), NONE)), NONE)
   259   | apply_tr _ Exit (State (SOME (state as Theory (Context.Theory _, _)), _)) =
   260       exit_transaction state
   261   | apply_tr int (Keep f) state =
   262       Runtime.controlled_execution (try generic_theory_of state) (fn x => tap (f int) x) state
   263   | apply_tr int (Transaction (f, g)) (State (SOME state, _)) =
   264       apply_transaction (fn x => f int x) g state
   265   | apply_tr _ _ _ = raise UNDEF;
   266 
   267 fun apply_union _ [] state = raise FAILURE (state, UNDEF)
   268   | apply_union int (tr :: trs) state =
   269       apply_union int trs state
   270         handle Runtime.UNDEF => apply_tr int tr state
   271           | FAILURE (alt_state, UNDEF) => apply_tr int tr alt_state
   272           | exn as FAILURE _ => raise exn
   273           | exn => raise FAILURE (state, exn);
   274 
   275 in
   276 
   277 fun apply_trans int trs state = (apply_union int trs state, NONE)
   278   handle FAILURE (alt_state, exn) => (alt_state, SOME exn) | exn => (state, SOME exn);
   279 
   280 end;
   281 
   282 
   283 (* datatype transition *)
   284 
   285 datatype transition = Transition of
   286  {name: string,              (*command name*)
   287   pos: Position.T,           (*source position*)
   288   timing: Time.time option,  (*prescient timing information*)
   289   trans: trans list};        (*primitive transitions (union)*)
   290 
   291 fun make_transition (name, pos, timing, trans) =
   292   Transition {name = name, pos = pos, timing = timing, trans = trans};
   293 
   294 fun map_transition f (Transition {name, pos, timing, trans}) =
   295   make_transition (f (name, pos, timing, trans));
   296 
   297 val empty = make_transition ("", Position.none, NONE, []);
   298 
   299 
   300 (* diagnostics *)
   301 
   302 fun name_of (Transition {name, ...}) = name;
   303 fun pos_of (Transition {pos, ...}) = pos;
   304 
   305 fun command_msg msg tr =
   306   msg ^ "command " ^ quote (Markup.markup Markup.keyword1 (name_of tr)) ^
   307     Position.here (pos_of tr);
   308 
   309 fun at_command tr = command_msg "At " tr;
   310 fun type_error tr = command_msg "Bad context for " tr;
   311 
   312 
   313 (* modify transitions *)
   314 
   315 fun name name = map_transition (fn (_, pos, timing, trans) =>
   316   (name, pos, timing, trans));
   317 
   318 fun position pos = map_transition (fn (name, _, timing, trans) =>
   319   (name, pos, timing, trans));
   320 
   321 fun add_trans tr = map_transition (fn (name, pos, timing, trans) =>
   322   (name, pos, timing, tr :: trans));
   323 
   324 val reset_trans = map_transition (fn (name, pos, timing, _) =>
   325   (name, pos, timing, []));
   326 
   327 
   328 (* basic transitions *)
   329 
   330 fun init_theory f = add_trans (Init f);
   331 
   332 fun is_init (Transition {trans = [Init _], ...}) = true
   333   | is_init _ = false;
   334 
   335 fun modify_init f tr = if is_init tr then init_theory f (reset_trans tr) else tr;
   336 
   337 val exit = add_trans Exit;
   338 val keep' = add_trans o Keep;
   339 
   340 fun present_transaction f g = add_trans (Transaction (f, g));
   341 fun transaction f = present_transaction f (K ());
   342 
   343 fun keep f = add_trans (Keep (fn _ => f));
   344 
   345 fun keep_proof f =
   346   keep (fn st =>
   347     if is_proof st then f st
   348     else if is_skipped_proof st then ()
   349     else warning "No proof state");
   350 
   351 fun ignored pos = empty |> name "<ignored>" |> position pos |> keep (fn _ => ());
   352 fun is_ignored tr = name_of tr = "<ignored>";
   353 
   354 fun malformed pos msg =
   355   empty |> name "<malformed>" |> position pos |> keep (fn _ => error msg);
   356 
   357 
   358 (* theory transitions *)
   359 
   360 fun generic_theory f = transaction (fn _ =>
   361   (fn Theory (gthy, _) => Theory (f gthy, NONE)
   362     | _ => raise UNDEF));
   363 
   364 fun theory' f = transaction (fn int =>
   365   (fn Theory (Context.Theory thy, _) =>
   366       let val thy' = thy
   367         |> Sign.new_group
   368         |> f int
   369         |> Sign.reset_group;
   370       in Theory (Context.Theory thy', NONE) end
   371     | _ => raise UNDEF));
   372 
   373 fun theory f = theory' (K f);
   374 
   375 fun begin_local_theory begin f = transaction (fn _ =>
   376   (fn Theory (Context.Theory thy, _) =>
   377         let
   378           val lthy = f thy;
   379           val gthy = if begin then Context.Proof lthy else Context.Theory (Named_Target.exit lthy);
   380           val _ =
   381             (case Local_Theory.pretty lthy of
   382               [] => ()
   383             | prts => Output.state (Pretty.string_of (Pretty.chunks prts)));
   384         in Theory (gthy, SOME lthy) end
   385     | _ => raise UNDEF));
   386 
   387 val end_local_theory = transaction (fn _ =>
   388   (fn Theory (Context.Proof lthy, _) => Theory (Context.Theory (Named_Target.exit lthy), SOME lthy)
   389     | _ => raise UNDEF));
   390 
   391 fun open_target f = transaction (fn _ =>
   392   (fn Theory (gthy, _) =>
   393         let val lthy = f gthy
   394         in Theory (Context.Proof lthy, SOME lthy) end
   395     | _ => raise UNDEF));
   396 
   397 val close_target = transaction (fn _ =>
   398   (fn Theory (Context.Proof lthy, _) =>
   399         (case try Local_Theory.close_target lthy of
   400           SOME ctxt' =>
   401             let
   402               val gthy' =
   403                 if can Local_Theory.assert ctxt'
   404                 then Context.Proof ctxt'
   405                 else Context.Theory (Proof_Context.theory_of ctxt');
   406             in Theory (gthy', SOME lthy) end
   407         | NONE => raise UNDEF)
   408     | _ => raise UNDEF));
   409 
   410 fun restricted_context (SOME (strict, scope)) =
   411       Proof_Context.map_naming (Name_Space.restricted strict scope)
   412   | restricted_context NONE = I;
   413 
   414 fun local_theory' restricted target f = present_transaction (fn int =>
   415   (fn Theory (gthy, _) =>
   416         let
   417           val (finish, lthy) = Named_Target.switch target gthy;
   418           val lthy' = lthy
   419             |> restricted_context restricted
   420             |> Local_Theory.new_group
   421             |> f int
   422             |> Local_Theory.reset_group;
   423         in Theory (finish lthy', SOME lthy') end
   424     | _ => raise UNDEF))
   425   (K ());
   426 
   427 fun local_theory restricted target f = local_theory' restricted target (K f);
   428 
   429 fun present_local_theory target = present_transaction (fn int =>
   430   (fn Theory (gthy, _) =>
   431         let val (finish, lthy) = Named_Target.switch target gthy;
   432         in Theory (finish lthy, SOME lthy) end
   433     | _ => raise UNDEF));
   434 
   435 
   436 (* proof transitions *)
   437 
   438 fun end_proof f = transaction (fn int =>
   439   (fn Proof (prf, (finish, _)) =>
   440         let val state = Proof_Node.current prf in
   441           if can (Proof.assert_bottom true) state then
   442             let
   443               val ctxt' = f int state;
   444               val gthy' = finish ctxt';
   445             in Theory (gthy', SOME ctxt') end
   446           else raise UNDEF
   447         end
   448     | Skipped_Proof (0, (gthy, _)) => Theory (gthy, NONE)
   449     | _ => raise UNDEF));
   450 
   451 local
   452 
   453 fun begin_proof init = transaction (fn int =>
   454   (fn Theory (gthy, _) =>
   455     let
   456       val (finish, prf) = init int gthy;
   457       val skip = Goal.skip_proofs_enabled ();
   458       val schematic_goal = try Proof.schematic_goal prf;
   459       val _ =
   460         if skip andalso schematic_goal = SOME true then
   461           warning "Cannot skip proof of schematic goal statement"
   462         else ();
   463     in
   464       if skip andalso schematic_goal = SOME false then
   465         Skipped_Proof (0, (finish (Proof.global_skip_proof true prf), gthy))
   466       else Proof (Proof_Node.init prf, (finish, gthy))
   467     end
   468   | _ => raise UNDEF));
   469 
   470 in
   471 
   472 fun local_theory_to_proof' restricted target f = begin_proof
   473   (fn int => fn gthy =>
   474     let
   475       val (finish, lthy) = Named_Target.switch target gthy;
   476       val prf = lthy
   477         |> restricted_context restricted
   478         |> Local_Theory.new_group
   479         |> f int;
   480     in (finish o Local_Theory.reset_group, prf) end);
   481 
   482 fun local_theory_to_proof restricted target f =
   483   local_theory_to_proof' restricted target (K f);
   484 
   485 fun theory_to_proof f = begin_proof
   486   (fn _ => fn gthy =>
   487     (Context.Theory o Sign.reset_group o Sign.change_check o Proof_Context.theory_of,
   488       (case gthy of
   489         Context.Theory thy => f (Sign.new_group thy)
   490       | _ => raise UNDEF)));
   491 
   492 end;
   493 
   494 fun forget_proof strict = transaction (fn _ =>
   495   (fn Proof (prf, (_, orig_gthy)) =>
   496         if strict andalso not (Proof.has_bottom_goal (Proof_Node.current prf))
   497         then raise UNDEF else Theory (orig_gthy, NONE)
   498     | Skipped_Proof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   499     | _ => raise UNDEF));
   500 
   501 fun proofs' f = transaction (fn int =>
   502   (fn Proof (prf, x) => Proof (Proof_Node.applys (f int) prf, x)
   503     | skip as Skipped_Proof _ => skip
   504     | _ => raise UNDEF));
   505 
   506 fun proof' f = proofs' ((Seq.single o Seq.Result) oo f);
   507 val proofs = proofs' o K;
   508 val proof = proof' o K;
   509 
   510 
   511 (* skipped proofs *)
   512 
   513 fun actual_proof f = transaction (fn _ =>
   514   (fn Proof (prf, x) => Proof (f prf, x)
   515     | _ => raise UNDEF));
   516 
   517 fun skip_proof f = transaction (fn _ =>
   518   (fn skip as Skipped_Proof _ => (f (); skip)
   519     | _ => raise UNDEF));
   520 
   521 val skip_proof_open = transaction (fn _ =>
   522   (fn Skipped_Proof (d, x) => Skipped_Proof (d + 1, x)
   523     | _ => raise UNDEF));
   524 
   525 val skip_proof_close = transaction (fn _ =>
   526   (fn Skipped_Proof (0, (gthy, _)) => Theory (gthy, NONE)
   527     | Skipped_Proof (d, x) => Skipped_Proof (d - 1, x)
   528     | _ => raise UNDEF));
   529 
   530 
   531 
   532 (** toplevel transactions **)
   533 
   534 (* runtime position *)
   535 
   536 fun exec_id id (tr as Transition {pos, ...}) =
   537   position (Position.put_id (Document_ID.print id) pos) tr;
   538 
   539 fun setmp_thread_position (Transition {pos, ...}) f x =
   540   Position.setmp_thread_data pos f x;
   541 
   542 
   543 (* post-transition hooks *)
   544 
   545 local
   546   val hooks =
   547     Synchronized.var "Toplevel.hooks" ([]: (transition -> state -> state -> unit) list);
   548 in
   549 
   550 fun add_hook hook = Synchronized.change hooks (cons hook);
   551 fun get_hooks () = Synchronized.value hooks;
   552 
   553 end;
   554 
   555 
   556 (* apply transitions *)
   557 
   558 fun get_timing (Transition {timing, ...}) = timing;
   559 fun put_timing timing = map_transition (fn (name, pos, _, trans) => (name, pos, timing, trans));
   560 
   561 local
   562 
   563 fun app int (tr as Transition {name, trans, ...}) =
   564   setmp_thread_position tr (fn state =>
   565     let
   566       val timing_start = Timing.start ();
   567       val (result, opt_err) = apply_trans int trans state;
   568       val timing_result = Timing.result timing_start;
   569       val timing_props =
   570         Markup.command_timing :: (Markup.nameN, name_of tr) :: Position.properties_of (pos_of tr);
   571       val _ = Timing.protocol_message timing_props timing_result;
   572     in (result, Option.map (fn UNDEF => ERROR (type_error tr) | exn => exn) opt_err) end);
   573 
   574 in
   575 
   576 fun transition int tr st =
   577   let
   578     val (st', opt_err) =
   579       Context.setmp_thread_data (try (Context.Proof o presentation_context_of) st)
   580         (fn () => app int tr st) ();
   581     val opt_err' = opt_err |> Option.map
   582       (fn Runtime.EXCURSION_FAIL exn_info => exn_info
   583         | exn => (Runtime.exn_context (try context_of st) exn, at_command tr));
   584     val _ = get_hooks () |> List.app (fn f => (try (fn () => f tr st st') (); ()));
   585   in (st', opt_err') end;
   586 
   587 end;
   588 
   589 
   590 (* managed commands *)
   591 
   592 fun command_errors int tr st =
   593   (case transition int tr st of
   594     (st', NONE) => ([], SOME st')
   595   | (_, SOME (exn, _)) => (Runtime.exn_messages_ids exn, NONE));
   596 
   597 fun command_exception int tr st =
   598   (case transition int tr st of
   599     (st', NONE) => st'
   600   | (_, SOME (exn, info)) =>
   601       if Exn.is_interrupt exn then reraise exn
   602       else raise Runtime.EXCURSION_FAIL (exn, info));
   603 
   604 val command = command_exception false;
   605 
   606 
   607 (* reset state *)
   608 
   609 local
   610 
   611 fun reset_state check trans st =
   612   if check st then NONE
   613   else #2 (command_errors false (trans empty) st);
   614 
   615 in
   616 
   617 val reset_theory = reset_state is_theory (forget_proof false);
   618 
   619 val reset_proof =
   620   reset_state is_proof
   621     (transaction (fn _ =>
   622       (fn Theory (gthy, _) => Skipped_Proof (0, (gthy, gthy))
   623         | _ => raise UNDEF)));
   624 
   625 end;
   626 
   627 
   628 (* scheduled proof result *)
   629 
   630 datatype result =
   631   Result of transition * state |
   632   Result_List of result list |
   633   Result_Future of result future;
   634 
   635 fun join_results (Result x) = [x]
   636   | join_results (Result_List xs) = maps join_results xs
   637   | join_results (Result_Future x) = join_results (Future.join x);
   638 
   639 local
   640 
   641 structure Result = Proof_Data
   642 (
   643   type T = result;
   644   fun init _ = Result_List [];
   645 );
   646 
   647 val get_result = Result.get o Proof.context_of;
   648 val put_result = Proof.map_context o Result.put;
   649 
   650 fun timing_estimate include_head elem =
   651   let
   652     val trs = Thy_Syntax.flat_element elem |> not include_head ? tl;
   653     val timings = map get_timing trs;
   654   in
   655     if forall is_some timings then
   656       SOME (fold (curry Time.+ o the) timings Time.zeroTime)
   657     else NONE
   658   end;
   659 
   660 fun priority NONE = ~1
   661   | priority (SOME estimate) =
   662       Int.min (Real.floor (Real.max (Math.log10 (Time.toReal estimate), ~3.0)) - 3, ~1);
   663 
   664 fun proof_future_enabled estimate st =
   665   (case try proof_of st of
   666     NONE => false
   667   | SOME state =>
   668       not (Proof.is_relevant state) andalso
   669        (if can (Proof.assert_bottom true) state
   670         then Goal.future_enabled 1
   671         else
   672           (case estimate of
   673             NONE => Goal.future_enabled 2
   674           | SOME t => Goal.future_enabled_timing t)));
   675 
   676 fun atom_result keywords tr st =
   677   let
   678     val st' =
   679       if Goal.future_enabled 1 andalso Keyword.is_diag keywords (name_of tr) then
   680         (Execution.fork
   681           {name = "Toplevel.diag", pos = pos_of tr,
   682             pri = priority (timing_estimate true (Thy_Syntax.atom tr))}
   683           (fn () => command tr st); st)
   684       else command tr st;
   685   in (Result (tr, st'), st') end;
   686 
   687 in
   688 
   689 fun element_result keywords (Thy_Syntax.Element (tr, NONE)) st = atom_result keywords tr st
   690   | element_result keywords (elem as Thy_Syntax.Element (head_tr, SOME element_rest)) st =
   691       let
   692         val (head_result, st') = atom_result keywords head_tr st;
   693         val (body_elems, end_tr) = element_rest;
   694         val estimate = timing_estimate false elem;
   695       in
   696         if not (proof_future_enabled estimate st')
   697         then
   698           let
   699             val proof_trs = maps Thy_Syntax.flat_element body_elems @ [end_tr];
   700             val (proof_results, st'') = fold_map (atom_result keywords) proof_trs st';
   701           in (Result_List (head_result :: proof_results), st'') end
   702         else
   703           let
   704             val finish = Context.Theory o Proof_Context.theory_of;
   705 
   706             val future_proof =
   707               Proof.future_proof (fn state =>
   708                 Execution.fork
   709                   {name = "Toplevel.future_proof", pos = pos_of head_tr, pri = priority estimate}
   710                   (fn () =>
   711                     let
   712                       val State (SOME (Proof (prf, (_, orig_gthy))), prev) = st';
   713                       val prf' = Proof_Node.apply (K state) prf;
   714                       val (result, result_state) =
   715                         State (SOME (Proof (prf', (finish, orig_gthy))), prev)
   716                         |> fold_map (element_result keywords) body_elems ||> command end_tr;
   717                     in (Result_List result, presentation_context_of result_state) end))
   718               #> (fn (res, state') => state' |> put_result (Result_Future res));
   719 
   720             val forked_proof =
   721               proof (future_proof #>
   722                 (fn state => state |> Proof.local_done_proof |> put_result (get_result state))) o
   723               end_proof (fn _ => future_proof #>
   724                 (fn state => state |> Proof.global_done_proof |> Result.put (get_result state)));
   725 
   726             val st'' = st'
   727               |> command (head_tr |> reset_trans |> forked_proof);
   728             val end_result = Result (end_tr, st'');
   729             val result =
   730               Result_List [head_result, Result.get (presentation_context_of st''), end_result];
   731           in (result, st'') end
   732       end;
   733 
   734 end;
   735 
   736 end;