src/Pure/Isar/toplevel.ML
author wenzelm
Sun Aug 08 19:36:31 2010 +0200 (2010-08-08 ago)
changeset 38236 d8c7be27e01d
parent 37977 3ceccd415145
child 38337 f6c1e169f51b
child 38350 480b2de9927c
permissions -rw-r--r--
explicitly distinguish Output.status (essential feedback) vs. Output.report (useful markup);
     1 (*  Title:      Pure/Isar/toplevel.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Isabelle/Isar toplevel transactions.
     5 *)
     6 
     7 signature TOPLEVEL =
     8 sig
     9   exception UNDEF
    10   type state
    11   val toplevel: state
    12   val is_toplevel: state -> bool
    13   val is_theory: state -> bool
    14   val is_proof: state -> bool
    15   val level: state -> int
    16   val presentation_context_of: state -> Proof.context
    17   val previous_context_of: state -> Proof.context option
    18   val context_of: state -> Proof.context
    19   val generic_theory_of: state -> generic_theory
    20   val theory_of: state -> theory
    21   val proof_of: state -> Proof.state
    22   val proof_position_of: state -> int
    23   val enter_proof_body: state -> Proof.state
    24   val end_theory: Position.T -> state -> theory
    25   val print_state_context: state -> unit
    26   val print_state: bool -> state -> unit
    27   val pretty_abstract: state -> Pretty.T
    28   val quiet: bool Unsynchronized.ref
    29   val debug: bool Unsynchronized.ref
    30   val interact: bool Unsynchronized.ref
    31   val timing: bool Unsynchronized.ref
    32   val profiling: int Unsynchronized.ref
    33   val skip_proofs: bool Unsynchronized.ref
    34   exception TERMINATE
    35   exception TOPLEVEL_ERROR
    36   val program: (unit -> 'a) -> 'a
    37   val thread: bool -> (unit -> unit) -> Thread.thread
    38   type transition
    39   val empty: transition
    40   val init_of: transition -> string option
    41   val name_of: transition -> string
    42   val pos_of: transition -> Position.T
    43   val str_of: transition -> string
    44   val name: string -> transition -> transition
    45   val position: Position.T -> transition -> transition
    46   val interactive: bool -> transition -> transition
    47   val print: transition -> transition
    48   val no_timing: transition -> transition
    49   val init_theory: string -> (unit -> theory) -> transition -> transition
    50   val modify_init: (unit -> theory) -> transition -> transition
    51   val exit: transition -> transition
    52   val keep: (state -> unit) -> transition -> transition
    53   val keep': (bool -> state -> unit) -> transition -> transition
    54   val imperative: (unit -> unit) -> transition -> transition
    55   val ignored: Position.T -> transition
    56   val malformed: Position.T -> string -> transition
    57   val theory: (theory -> theory) -> transition -> transition
    58   val generic_theory: (generic_theory -> generic_theory) -> transition -> transition
    59   val theory': (bool -> theory -> theory) -> transition -> transition
    60   val begin_local_theory: bool -> (theory -> local_theory) -> transition -> transition
    61   val end_local_theory: transition -> transition
    62   val local_theory': xstring option -> (bool -> local_theory -> local_theory) ->
    63     transition -> transition
    64   val local_theory: xstring option -> (local_theory -> local_theory) -> transition -> transition
    65   val present_local_theory: xstring option -> (state -> unit) -> transition -> transition
    66   val local_theory_to_proof': xstring option -> (bool -> local_theory -> Proof.state) ->
    67     transition -> transition
    68   val local_theory_to_proof: xstring option -> (local_theory -> Proof.state) ->
    69     transition -> transition
    70   val theory_to_proof: (theory -> Proof.state) -> transition -> transition
    71   val end_proof: (bool -> Proof.state -> Proof.context) -> transition -> transition
    72   val forget_proof: transition -> transition
    73   val present_proof: (state -> unit) -> transition -> transition
    74   val proofs': (bool -> Proof.state -> Proof.state Seq.seq) -> transition -> transition
    75   val proof': (bool -> Proof.state -> Proof.state) -> transition -> transition
    76   val proofs: (Proof.state -> Proof.state Seq.seq) -> transition -> transition
    77   val proof: (Proof.state -> Proof.state) -> transition -> transition
    78   val actual_proof: (Proof_Node.T -> Proof_Node.T) -> transition -> transition
    79   val skip_proof: (int -> int) -> transition -> transition
    80   val skip_proof_to_theory: (int -> bool) -> transition -> transition
    81   val get_id: transition -> string option
    82   val put_id: string -> transition -> transition
    83   val unknown_theory: transition -> transition
    84   val unknown_proof: transition -> transition
    85   val unknown_context: transition -> transition
    86   val setmp_thread_position: transition -> ('a -> 'b) -> 'a -> 'b
    87   val status: transition -> Markup.T -> unit
    88   val error_msg: transition -> exn * string -> unit
    89   val add_hook: (transition -> state -> state -> unit) -> unit
    90   val transition: bool -> transition -> state -> (state * (exn * string) option) option
    91   val run_command: string -> transition -> state -> state option
    92   val command: transition -> state -> state
    93   val excursion: (transition * transition list) list -> (transition * state) list lazy * theory
    94 end;
    95 
    96 structure Toplevel: TOPLEVEL =
    97 struct
    98 
    99 (** toplevel state **)
   100 
   101 exception UNDEF = Runtime.UNDEF;
   102 
   103 
   104 (* local theory wrappers *)
   105 
   106 val loc_init = Theory_Target.context_cmd;
   107 val loc_exit = Local_Theory.exit_global;
   108 
   109 fun loc_begin loc (Context.Theory thy) = loc_init (the_default "-" loc) thy
   110   | loc_begin NONE (Context.Proof lthy) = lthy
   111   | loc_begin (SOME loc) (Context.Proof lthy) = loc_init loc (loc_exit lthy);
   112 
   113 fun loc_finish _ (Context.Theory _) = Context.Theory o loc_exit
   114   | loc_finish NONE (Context.Proof _) = Context.Proof o Local_Theory.restore
   115   | loc_finish (SOME _) (Context.Proof lthy) = fn lthy' =>
   116       Context.Proof (Local_Theory.reinit (Local_Theory.raw_theory (K (loc_exit lthy')) lthy));
   117 
   118 
   119 (* datatype node *)
   120 
   121 datatype node =
   122   Theory of generic_theory * Proof.context option
   123     (*theory with presentation context*) |
   124   Proof of Proof_Node.T * ((Proof.context -> generic_theory) * generic_theory)
   125     (*proof node, finish, original theory*) |
   126   SkipProof of int * (generic_theory * generic_theory);
   127     (*proof depth, resulting theory, original theory*)
   128 
   129 val theory_node = fn Theory (gthy, _) => SOME gthy | _ => NONE;
   130 val proof_node = fn Proof (prf, _) => SOME prf | _ => NONE;
   131 
   132 fun cases_node f _ (Theory (gthy, _)) = f gthy
   133   | cases_node _ g (Proof (prf, _)) = g (Proof_Node.current prf)
   134   | cases_node f _ (SkipProof (_, (gthy, _))) = f gthy;
   135 
   136 val context_node = cases_node Context.proof_of Proof.context_of;
   137 
   138 
   139 (* datatype state *)
   140 
   141 datatype state = State of node option * node option;  (*current, previous*)
   142 
   143 val toplevel = State (NONE, NONE);
   144 
   145 fun is_toplevel (State (NONE, _)) = true
   146   | is_toplevel _ = false;
   147 
   148 fun level (State (NONE, _)) = 0
   149   | level (State (SOME (Theory _), _)) = 0
   150   | level (State (SOME (Proof (prf, _)), _)) = Proof.level (Proof_Node.current prf)
   151   | level (State (SOME (SkipProof (d, _)), _)) = d + 1;   (*different notion of proof depth!*)
   152 
   153 fun str_of_state (State (NONE, _)) = "at top level"
   154   | str_of_state (State (SOME (Theory (Context.Theory _, _)), _)) = "in theory mode"
   155   | str_of_state (State (SOME (Theory (Context.Proof _, _)), _)) = "in local theory mode"
   156   | str_of_state (State (SOME (Proof _), _)) = "in proof mode"
   157   | str_of_state (State (SOME (SkipProof _), _)) = "in skipped proof mode";
   158 
   159 
   160 (* current node *)
   161 
   162 fun node_of (State (NONE, _)) = raise UNDEF
   163   | node_of (State (SOME node, _)) = node;
   164 
   165 fun is_theory state = not (is_toplevel state) andalso is_some (theory_node (node_of state));
   166 fun is_proof state = not (is_toplevel state) andalso is_some (proof_node (node_of state));
   167 
   168 fun node_case f g state = cases_node f g (node_of state);
   169 
   170 fun presentation_context_of state =
   171   (case try node_of state of
   172     SOME (Theory (_, SOME ctxt)) => ctxt
   173   | SOME node => context_node node
   174   | NONE => raise UNDEF);
   175 
   176 fun previous_context_of (State (_, NONE)) = NONE
   177   | previous_context_of (State (_, SOME prev)) = SOME (context_node prev);
   178 
   179 val context_of = node_case Context.proof_of Proof.context_of;
   180 val generic_theory_of = node_case I (Context.Proof o Proof.context_of);
   181 val theory_of = node_case Context.theory_of Proof.theory_of;
   182 val proof_of = node_case (fn _ => raise UNDEF) I;
   183 
   184 fun proof_position_of state =
   185   (case node_of state of
   186     Proof (prf, _) => Proof_Node.position prf
   187   | _ => raise UNDEF);
   188 
   189 val enter_proof_body = node_case (Proof.init o Context.proof_of) Proof.enter_forward;
   190 
   191 fun end_theory _ (State (NONE, SOME (Theory (Context.Theory thy, _)))) = Theory.end_theory thy
   192   | end_theory pos _ = error ("Unfinished theory at end of input" ^ Position.str_of pos);
   193 
   194 
   195 (* print state *)
   196 
   197 val pretty_context = Local_Theory.pretty o Context.cases (Theory_Target.init NONE) I;
   198 
   199 fun print_state_context state =
   200   (case try node_of state of
   201     NONE => []
   202   | SOME (Theory (gthy, _)) => pretty_context gthy
   203   | SOME (Proof (_, (_, gthy))) => pretty_context gthy
   204   | SOME (SkipProof (_, (gthy, _))) => pretty_context gthy)
   205   |> Pretty.chunks |> Pretty.writeln;
   206 
   207 fun print_state prf_only state =
   208   (case try node_of state of
   209     NONE => []
   210   | SOME (Theory (gthy, _)) => if prf_only then [] else pretty_context gthy
   211   | SOME (Proof (prf, _)) =>
   212       Proof.pretty_state (Proof_Node.position prf) (Proof_Node.current prf)
   213   | SOME (SkipProof (d, _)) => [Pretty.str ("skipped proof: depth " ^ string_of_int d)])
   214   |> Pretty.markup_chunks Markup.state |> Pretty.writeln;
   215 
   216 fun pretty_abstract state = Pretty.str ("<Isar " ^ str_of_state state ^ ">");
   217 
   218 
   219 
   220 (** toplevel transitions **)
   221 
   222 val quiet = Unsynchronized.ref false;
   223 val debug = Output.debugging;
   224 val interact = Unsynchronized.ref false;
   225 val timing = Output.timing;
   226 val profiling = Unsynchronized.ref 0;
   227 val skip_proofs = Unsynchronized.ref false;
   228 
   229 exception TERMINATE = Runtime.TERMINATE;
   230 exception EXCURSION_FAIL = Runtime.EXCURSION_FAIL;
   231 exception TOPLEVEL_ERROR = Runtime.TOPLEVEL_ERROR;
   232 
   233 fun program body =
   234  (body
   235   |> Runtime.controlled_execution
   236   |> Runtime.toplevel_error (Output.error_msg o ML_Compiler.exn_message)) ();
   237 
   238 fun thread interrupts body =
   239   Thread.fork
   240     (((fn () => body () handle Exn.Interrupt => ())
   241         |> Runtime.debugging
   242         |> Runtime.toplevel_error
   243           (fn exn => priority ("## INTERNAL ERROR ##\n" ^ ML_Compiler.exn_message exn))),
   244       Simple_Thread.attributes interrupts);
   245 
   246 
   247 (* node transactions -- maintaining stable checkpoints *)
   248 
   249 exception FAILURE of state * exn;
   250 
   251 local
   252 
   253 fun reset_presentation (Theory (gthy, _)) = Theory (gthy, NONE)
   254   | reset_presentation node = node;
   255 
   256 fun is_draft_theory (Theory (gthy, _)) = Context.is_draft (Context.theory_of gthy)
   257   | is_draft_theory _ = false;
   258 
   259 fun is_stale state = Context.is_stale (theory_of state) handle Runtime.UNDEF => false;
   260 
   261 fun stale_error NONE = SOME (ERROR "Stale theory encountered after successful execution!")
   262   | stale_error some = some;
   263 
   264 fun map_theory f (Theory (gthy, ctxt)) =
   265       Theory (Context.mapping f (Local_Theory.raw_theory f) gthy, ctxt)
   266   | map_theory _ node = node;
   267 
   268 in
   269 
   270 fun apply_transaction f g node =
   271   let
   272     val _ = is_draft_theory node andalso error "Illegal draft theory in toplevel state";
   273     val cont_node = reset_presentation node;
   274     val back_node = map_theory (Theory.checkpoint o Theory.copy) cont_node;
   275     fun state_error e nd = (State (SOME nd, SOME node), e);
   276 
   277     val (result, err) =
   278       cont_node
   279       |> Runtime.controlled_execution f
   280       |> map_theory Theory.checkpoint
   281       |> state_error NONE
   282       handle exn => state_error (SOME exn) cont_node;
   283 
   284     val (result', err') =
   285       if is_stale result then state_error (stale_error err) back_node
   286       else (result, err);
   287   in
   288     (case err' of
   289       NONE => tap g result'
   290     | SOME exn => raise FAILURE (result', exn))
   291   end;
   292 
   293 end;
   294 
   295 
   296 (* primitive transitions *)
   297 
   298 datatype trans =
   299   Init of string * (unit -> theory) |    (*theory name, init*)
   300   Exit |                                 (*formal exit of theory*)
   301   Keep of bool -> state -> unit |        (*peek at state*)
   302   Transaction of (bool -> node -> node) * (state -> unit);  (*node transaction and presentation*)
   303 
   304 local
   305 
   306 fun apply_tr _ (Init (_, f)) (State (NONE, _)) =
   307       State (SOME (Theory (Context.Theory
   308           (Theory.checkpoint (Runtime.controlled_execution f ())), NONE)), NONE)
   309   | apply_tr _ Exit (State (prev as SOME (Theory (Context.Theory _, _)), _)) =
   310       State (NONE, prev)
   311   | apply_tr int (Keep f) state =
   312       Runtime.controlled_execution (fn x => tap (f int) x) state
   313   | apply_tr int (Transaction (f, g)) (State (SOME state, _)) =
   314       apply_transaction (fn x => f int x) g state
   315   | apply_tr _ _ _ = raise UNDEF;
   316 
   317 fun apply_union _ [] state = raise FAILURE (state, UNDEF)
   318   | apply_union int (tr :: trs) state =
   319       apply_union int trs state
   320         handle Runtime.UNDEF => apply_tr int tr state
   321           | FAILURE (alt_state, UNDEF) => apply_tr int tr alt_state
   322           | exn as FAILURE _ => raise exn
   323           | exn => raise FAILURE (state, exn);
   324 
   325 in
   326 
   327 fun apply_trans int trs state = (apply_union int trs state, NONE)
   328   handle FAILURE (alt_state, exn) => (alt_state, SOME exn) | exn => (state, SOME exn);
   329 
   330 end;
   331 
   332 
   333 (* datatype transition *)
   334 
   335 datatype transition = Transition of
   336  {name: string,              (*command name*)
   337   pos: Position.T,           (*source position*)
   338   int_only: bool,            (*interactive-only*)
   339   print: bool,               (*print result state*)
   340   no_timing: bool,           (*suppress timing*)
   341   trans: trans list};        (*primitive transitions (union)*)
   342 
   343 fun make_transition (name, pos, int_only, print, no_timing, trans) =
   344   Transition {name = name, pos = pos, int_only = int_only, print = print, no_timing = no_timing,
   345     trans = trans};
   346 
   347 fun map_transition f (Transition {name, pos, int_only, print, no_timing, trans}) =
   348   make_transition (f (name, pos, int_only, print, no_timing, trans));
   349 
   350 val empty = make_transition ("", Position.none, false, false, false, []);
   351 
   352 
   353 (* diagnostics *)
   354 
   355 fun init_of (Transition {trans = [Init (name, _)], ...}) = SOME name
   356   | init_of _ = NONE;
   357 
   358 fun name_of (Transition {name, ...}) = name;
   359 fun pos_of (Transition {pos, ...}) = pos;
   360 fun str_of tr = quote (name_of tr) ^ Position.str_of (pos_of tr);
   361 
   362 fun command_msg msg tr = msg ^ "command " ^ str_of tr;
   363 fun at_command tr = command_msg "At " tr ^ ".";
   364 
   365 fun type_error tr state =
   366   ERROR (command_msg "Illegal application of " tr ^ " " ^ str_of_state state);
   367 
   368 
   369 (* modify transitions *)
   370 
   371 fun name name = map_transition (fn (_, pos, int_only, print, no_timing, trans) =>
   372   (name, pos, int_only, print, no_timing, trans));
   373 
   374 fun position pos = map_transition (fn (name, _, int_only, print, no_timing, trans) =>
   375   (name, pos, int_only, print, no_timing, trans));
   376 
   377 fun interactive int_only = map_transition (fn (name, pos, _, print, no_timing, trans) =>
   378   (name, pos, int_only, print, no_timing, trans));
   379 
   380 val no_timing = map_transition (fn (name, pos, int_only, print, _, trans) =>
   381   (name, pos, int_only, print, true, trans));
   382 
   383 fun add_trans tr = map_transition (fn (name, pos, int_only, print, no_timing, trans) =>
   384   (name, pos, int_only, print, no_timing, tr :: trans));
   385 
   386 val reset_trans = map_transition (fn (name, pos, int_only, print, no_timing, _) =>
   387   (name, pos, int_only, print, no_timing, []));
   388 
   389 fun set_print print = map_transition (fn (name, pos, int_only, _, no_timing, trans) =>
   390   (name, pos, int_only, print, no_timing, trans));
   391 
   392 val print = set_print true;
   393 
   394 
   395 (* basic transitions *)
   396 
   397 fun init_theory name f = add_trans (Init (name, f));
   398 
   399 fun modify_init f tr =
   400   (case init_of tr of
   401     SOME name => init_theory name f (reset_trans tr)
   402   | NONE => tr);
   403 
   404 val exit = add_trans Exit;
   405 val keep' = add_trans o Keep;
   406 
   407 fun present_transaction f g = add_trans (Transaction (f, g));
   408 fun transaction f = present_transaction f (K ());
   409 
   410 fun keep f = add_trans (Keep (fn _ => f));
   411 fun imperative f = keep (fn _ => f ());
   412 
   413 fun ignored pos = empty |> name "<ignored>" |> position pos |> imperative I;
   414 fun malformed pos msg =
   415   empty |> name "<malformed>" |> position pos |> imperative (fn () => error msg);
   416 
   417 val unknown_theory = imperative (fn () => warning "Unknown theory context");
   418 val unknown_proof = imperative (fn () => warning "Unknown proof context");
   419 val unknown_context = imperative (fn () => warning "Unknown context");
   420 
   421 
   422 (* theory transitions *)
   423 
   424 fun generic_theory f = transaction (fn _ =>
   425   (fn Theory (gthy, _) => Theory (f gthy, NONE)
   426     | _ => raise UNDEF));
   427 
   428 fun theory' f = transaction (fn int =>
   429   (fn Theory (Context.Theory thy, _) =>
   430       let val thy' = thy
   431         |> Sign.new_group
   432         |> Theory.checkpoint
   433         |> f int
   434         |> Sign.reset_group;
   435       in Theory (Context.Theory thy', NONE) end
   436     | _ => raise UNDEF));
   437 
   438 fun theory f = theory' (K f);
   439 
   440 fun begin_local_theory begin f = transaction (fn _ =>
   441   (fn Theory (Context.Theory thy, _) =>
   442         let
   443           val lthy = f thy;
   444           val gthy = if begin then Context.Proof lthy else Context.Theory (loc_exit lthy);
   445         in Theory (gthy, SOME lthy) end
   446     | _ => raise UNDEF));
   447 
   448 val end_local_theory = transaction (fn _ =>
   449   (fn Theory (Context.Proof lthy, _) => Theory (Context.Theory (loc_exit lthy), SOME lthy)
   450     | _ => raise UNDEF));
   451 
   452 local
   453 
   454 fun local_theory_presentation loc f = present_transaction (fn int =>
   455   (fn Theory (gthy, _) =>
   456         let
   457           val finish = loc_finish loc gthy;
   458           val lthy' = loc_begin loc gthy
   459             |> Local_Theory.new_group
   460             |> f int
   461             |> Local_Theory.reset_group;
   462         in Theory (finish lthy', SOME lthy') end
   463     | _ => raise UNDEF));
   464 
   465 in
   466 
   467 fun local_theory' loc f = local_theory_presentation loc f (K ());
   468 fun local_theory loc f = local_theory' loc (K f);
   469 fun present_local_theory loc = local_theory_presentation loc (K I);
   470 
   471 end;
   472 
   473 
   474 (* proof transitions *)
   475 
   476 fun end_proof f = transaction (fn int =>
   477   (fn Proof (prf, (finish, _)) =>
   478         let val state = Proof_Node.current prf in
   479           if can (Proof.assert_bottom true) state then
   480             let
   481               val ctxt' = f int state;
   482               val gthy' = finish ctxt';
   483             in Theory (gthy', SOME ctxt') end
   484           else raise UNDEF
   485         end
   486     | SkipProof (0, (gthy, _)) => Theory (gthy, NONE)
   487     | _ => raise UNDEF));
   488 
   489 local
   490 
   491 fun begin_proof init finish = transaction (fn int =>
   492   (fn Theory (gthy, _) =>
   493     let
   494       val prf = init int gthy;
   495       val skip = ! skip_proofs;
   496       val schematic = Proof.schematic_goal prf;
   497     in
   498       if skip andalso schematic then
   499         warning "Cannot skip proof of schematic goal statement"
   500       else ();
   501       if skip andalso not schematic then
   502         SkipProof (0, (finish gthy (Proof.global_skip_proof int prf), gthy))
   503       else Proof (Proof_Node.init prf, (finish gthy, gthy))
   504     end
   505   | _ => raise UNDEF));
   506 
   507 in
   508 
   509 fun local_theory_to_proof' loc f = begin_proof
   510   (fn int => fn gthy => f int (Local_Theory.new_group (loc_begin loc gthy)))
   511   (fn gthy => loc_finish loc gthy o Local_Theory.reset_group);
   512 
   513 fun local_theory_to_proof loc f = local_theory_to_proof' loc (K f);
   514 
   515 fun theory_to_proof f = begin_proof
   516   (K (fn Context.Theory thy => f (Theory.checkpoint (Sign.new_group thy)) | _ => raise UNDEF))
   517   (K (Context.Theory o Sign.reset_group o ProofContext.theory_of));
   518 
   519 end;
   520 
   521 val forget_proof = transaction (fn _ =>
   522   (fn Proof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   523     | SkipProof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   524     | _ => raise UNDEF));
   525 
   526 val present_proof = present_transaction (fn _ =>
   527   (fn Proof (prf, x) => Proof (Proof_Node.apply I prf, x)
   528     | skip as SkipProof _ => skip
   529     | _ => raise UNDEF));
   530 
   531 fun proofs' f = transaction (fn int =>
   532   (fn Proof (prf, x) => Proof (Proof_Node.applys (f int) prf, x)
   533     | skip as SkipProof _ => skip
   534     | _ => raise UNDEF));
   535 
   536 fun proof' f = proofs' (Seq.single oo f);
   537 val proofs = proofs' o K;
   538 val proof = proof' o K;
   539 
   540 fun actual_proof f = transaction (fn _ =>
   541   (fn Proof (prf, x) => Proof (f prf, x)
   542     | _ => raise UNDEF));
   543 
   544 fun skip_proof f = transaction (fn _ =>
   545   (fn SkipProof (h, x) => SkipProof (f h, x)
   546     | _ => raise UNDEF));
   547 
   548 fun skip_proof_to_theory pred = transaction (fn _ =>
   549   (fn SkipProof (d, (gthy, _)) => if pred d then Theory (gthy, NONE) else raise UNDEF
   550     | _ => raise UNDEF));
   551 
   552 
   553 
   554 (** toplevel transactions **)
   555 
   556 (* identification *)
   557 
   558 fun get_id (Transition {pos, ...}) = Position.get_id pos;
   559 fun put_id id (tr as Transition {pos, ...}) = position (Position.put_id id pos) tr;
   560 
   561 
   562 (* thread position *)
   563 
   564 fun setmp_thread_position (Transition {pos, ...}) f x =
   565   Position.setmp_thread_data pos f x;
   566 
   567 fun status tr m =
   568   setmp_thread_position tr (fn () => Output.status (Markup.markup m "")) ();
   569 
   570 fun async_state (tr as Transition {print, ...}) st =
   571   if print then
   572     ignore
   573       (Future.fork (fn () =>
   574           setmp_thread_position tr (fn () => Future.status (fn () => print_state false st)) ()))
   575   else ();
   576 
   577 fun error_msg tr exn_info =
   578   setmp_thread_position tr (fn () =>
   579     Output.error_msg (ML_Compiler.exn_message (EXCURSION_FAIL exn_info))) ();
   580 
   581 
   582 (* post-transition hooks *)
   583 
   584 local
   585   val hooks = Unsynchronized.ref ([]: (transition -> state -> state -> unit) list);
   586 in
   587 
   588 fun add_hook f = CRITICAL (fn () => Unsynchronized.change hooks (cons f));
   589 fun get_hooks () = ! hooks;
   590 
   591 end;
   592 
   593 
   594 (* apply transitions *)
   595 
   596 local
   597 
   598 fun app int (tr as Transition {trans, print, no_timing, ...}) =
   599   setmp_thread_position tr (fn state =>
   600     let
   601       fun do_timing f x = (warning (command_msg "" tr); timeap f x);
   602       fun do_profiling f x = profile (! profiling) f x;
   603 
   604       val (result, status) =
   605          state |>
   606           (apply_trans int trans
   607             |> (! profiling > 0 andalso not no_timing) ? do_profiling
   608             |> (! profiling > 0 orelse ! timing andalso not no_timing) ? do_timing);
   609 
   610       val _ = if int andalso not (! quiet) andalso print then print_state false result else ();
   611     in (result, Option.map (fn UNDEF => type_error tr state | exn => exn) status) end);
   612 
   613 in
   614 
   615 fun transition int tr st =
   616   let
   617     val hooks = get_hooks ();
   618     fun apply_hooks st' = hooks |> List.app (fn f => (try (fn () => f tr st st') (); ()));
   619 
   620     val ctxt = try context_of st;
   621     val res =
   622       (case app int tr st of
   623         (_, SOME TERMINATE) => NONE
   624       | (st', SOME (EXCURSION_FAIL exn_info)) => SOME (st', SOME exn_info)
   625       | (st', SOME exn) => SOME (st', SOME (Runtime.exn_context ctxt exn, at_command tr))
   626       | (st', NONE) => SOME (st', NONE));
   627     val _ = (case res of SOME (st', NONE) => apply_hooks st' | _ => ());
   628   in res end;
   629 
   630 end;
   631 
   632 
   633 (* managed execution *)
   634 
   635 fun run_command thy_name tr st =
   636   (case
   637       (case init_of tr of
   638         SOME name => Exn.capture (fn () => Thy_Header.consistent_name thy_name name) ()
   639       | NONE => Exn.Result ()) of
   640     Exn.Result () =>
   641       let val int = is_some (init_of tr) in
   642         (case transition int tr st of
   643           SOME (st', NONE) =>
   644             (status tr Markup.finished; if int then () else async_state tr st'; SOME st')
   645         | SOME (_, SOME (exn as Exn.Interrupt, _)) => reraise exn
   646         | SOME (_, SOME exn_info) => (error_msg tr exn_info; status tr Markup.failed; NONE)
   647         | NONE => (error_msg tr (TERMINATE, at_command tr); status tr Markup.failed; NONE))
   648       end
   649   | Exn.Exn exn => (error_msg tr (exn, at_command tr); status tr Markup.failed; NONE));
   650 
   651 
   652 (* nested commands *)
   653 
   654 fun command tr st =
   655   (case transition (! interact) tr st of
   656     SOME (st', NONE) => st'
   657   | SOME (_, SOME exn_info) => raise EXCURSION_FAIL exn_info
   658   | NONE => raise EXCURSION_FAIL (TERMINATE, at_command tr));
   659 
   660 fun command_result tr st =
   661   let val st' = command tr st
   662   in (st', st') end;
   663 
   664 
   665 (* excursion of units, consisting of commands with proof *)
   666 
   667 structure States = Proof_Data
   668 (
   669   type T = state list future option;
   670   fun init _ = NONE;
   671 );
   672 
   673 fun proof_result immediate (tr, proof_trs) st =
   674   let val st' = command tr st in
   675     if immediate orelse
   676       null proof_trs orelse
   677       Keyword.is_schematic_goal (name_of tr) orelse
   678       exists (Keyword.is_qed_global o name_of) proof_trs orelse
   679       not (can proof_of st') orelse
   680       Proof.is_relevant (proof_of st')
   681     then
   682       let val (states, st'') = fold_map command_result proof_trs st'
   683       in (Lazy.value ((tr, st') :: (proof_trs ~~ states)), st'') end
   684     else
   685       let
   686         val (body_trs, end_tr) = split_last proof_trs;
   687         val finish = Context.Theory o ProofContext.theory_of;
   688 
   689         val future_proof = Proof.global_future_proof
   690           (fn prf =>
   691             Future.fork_pri ~1 (fn () =>
   692               let val (states, result_state) =
   693                 (case st' of State (SOME (Proof (_, (_, orig_gthy))), prev)
   694                   => State (SOME (Proof (Proof_Node.init prf, (finish, orig_gthy))), prev))
   695                 |> fold_map command_result body_trs
   696                 ||> command (end_tr |> set_print false);
   697               in (states, presentation_context_of result_state) end))
   698           #> (fn (states, ctxt) => States.put (SOME states) ctxt);
   699 
   700         val st'' = st' |> command (end_tr |> reset_trans |> end_proof (K future_proof));
   701 
   702         val states =
   703           (case States.get (presentation_context_of st'') of
   704             NONE => raise Fail ("No future states for " ^ name_of tr ^ Position.str_of (pos_of tr))
   705           | SOME states => states);
   706         val result = Lazy.lazy
   707           (fn () => (tr, st') :: (body_trs ~~ Future.join states) @ [(end_tr, st'')]);
   708 
   709       in (result, st'') end
   710   end;
   711 
   712 fun excursion input =
   713   let
   714     val end_pos = if null input then error "No input" else pos_of (fst (List.last input));
   715     val immediate = not (Goal.future_enabled ());
   716     val (results, end_state) = fold_map (proof_result immediate) input toplevel;
   717     val thy = end_theory end_pos end_state;
   718   in (Lazy.lazy (fn () => maps Lazy.force results), thy) end;
   719 
   720 end;