src/Pure/Isar/expression.ML
author wenzelm
Thu Mar 12 13:18:42 2009 +0100 (2009-03-12 ago)
changeset 30469 de9e8f1d927c
parent 30468 0cf8f536ef98
child 30585 6b2ba4666336
permissions -rw-r--r--
renamed sticky_prefix to mandatory_path;
     1 (*  Title:      Pure/Isar/expression.ML
     2     Author:     Clemens Ballarin, TU Muenchen
     3 
     4 Locale expressions.
     5 *)
     6 
     7 signature EXPRESSION =
     8 sig
     9   (* Locale expressions *)
    10   datatype 'term map = Positional of 'term option list | Named of (string * 'term) list
    11   type 'term expr = (string * ((string * bool) * 'term map)) list
    12   type expression_i = term expr * (binding * typ option * mixfix) list
    13   type expression = string expr * (binding * string option * mixfix) list
    14 
    15   (* Processing of context statements *)
    16   val cert_statement: Element.context_i list -> (term * term list) list list ->
    17     Proof.context -> (term * term list) list list * Proof.context
    18   val read_statement: Element.context list -> (string * string list) list list ->
    19     Proof.context -> (term * term list) list list * Proof.context
    20 
    21   (* Declaring locales *)
    22   val cert_declaration: expression_i -> (Proof.context -> Proof.context) -> Element.context_i list ->
    23     Proof.context -> ((binding * typ option * mixfix) list * (string * morphism) list
    24       * Element.context_i list) * ((string * typ) list * Proof.context)
    25   val cert_read_declaration: expression_i -> (Proof.context -> Proof.context) -> Element.context list ->
    26     Proof.context -> ((binding * typ option * mixfix) list * (string * morphism) list
    27       * Element.context_i list) * ((string * typ) list * Proof.context)
    28       (*FIXME*)
    29   val read_declaration: expression -> (Proof.context -> Proof.context) -> Element.context list ->
    30     Proof.context -> ((binding * typ option * mixfix) list * (string * morphism) list
    31       * Element.context_i list) * ((string * typ) list * Proof.context)
    32   val add_locale: binding -> binding -> expression_i -> Element.context_i list ->
    33     theory -> string * local_theory
    34   val add_locale_cmd: binding -> binding -> expression -> Element.context list ->
    35     theory -> string * local_theory
    36 
    37   (* Interpretation *)
    38   val cert_goal_expression: expression_i -> Proof.context ->
    39     (term list list * (string * morphism) list * morphism) * Proof.context
    40   val read_goal_expression: expression -> Proof.context ->
    41     (term list list * (string * morphism) list * morphism) * Proof.context
    42   val sublocale: string -> expression_i -> theory -> Proof.state
    43   val sublocale_cmd: string -> expression -> theory -> Proof.state
    44   val interpretation: expression_i -> (Attrib.binding * term) list -> theory -> Proof.state
    45   val interpretation_cmd: expression -> (Attrib.binding * string) list -> theory -> Proof.state
    46   val interpret: expression_i -> bool -> Proof.state -> Proof.state
    47   val interpret_cmd: expression -> bool -> Proof.state -> Proof.state
    48 end;
    49 
    50 structure Expression : EXPRESSION =
    51 struct
    52 
    53 datatype ctxt = datatype Element.ctxt;
    54 
    55 
    56 (*** Expressions ***)
    57 
    58 datatype 'term map =
    59   Positional of 'term option list |
    60   Named of (string * 'term) list;
    61 
    62 type 'term expr = (string * ((string * bool) * 'term map)) list;
    63 
    64 type expression = string expr * (binding * string option * mixfix) list;
    65 type expression_i = term expr * (binding * typ option * mixfix) list;
    66 
    67 
    68 (** Internalise locale names in expr **)
    69 
    70 fun intern thy instances =  map (apfst (Locale.intern thy)) instances;
    71 
    72 
    73 (** Parameters of expression.
    74 
    75    Sanity check of instantiations and extraction of implicit parameters.
    76    The latter only occurs iff strict = false.
    77    Positional instantiations are extended to match full length of parameter list
    78    of instantiated locale. **)
    79 
    80 fun parameters_of thy strict (expr, fixed) =
    81   let
    82     fun reject_dups message xs =
    83       let val dups = duplicates (op =) xs
    84       in
    85         if null dups then () else error (message ^ commas dups)
    86       end;
    87 
    88     fun match_bind (n, b) = (n = Binding.name_of b);
    89     fun parm_eq ((b1, mx1: mixfix), (b2, mx2)) =
    90       Binding.eq_name (b1, b2) andalso
    91         (mx1 = mx2 orelse
    92           error ("Conflicting syntax for parameter " ^ quote (Binding.str_of b1) ^ " in expression"));
    93 
    94     fun params_loc loc =
    95       (Locale.params_of thy loc |> map (fn (p, _, mx) => (p, mx)), loc);
    96     fun params_inst (expr as (loc, (prfx, Positional insts))) =
    97           let
    98             val (ps, loc') = params_loc loc;
    99             val d = length ps - length insts;
   100             val insts' =
   101               if d < 0 then error ("More arguments than parameters in instantiation of locale " ^
   102                 quote (Locale.extern thy loc))
   103               else insts @ replicate d NONE;
   104             val ps' = (ps ~~ insts') |>
   105               map_filter (fn (p, NONE) => SOME p | (_, SOME _) => NONE);
   106           in (ps', (loc', (prfx, Positional insts'))) end
   107       | params_inst (expr as (loc, (prfx, Named insts))) =
   108           let
   109             val _ = reject_dups "Duplicate instantiation of the following parameter(s): "
   110               (map fst insts);
   111 
   112             val (ps, loc') = params_loc loc;
   113             val ps' = fold (fn (p, _) => fn ps =>
   114               if AList.defined match_bind ps p then AList.delete match_bind p ps
   115               else error (quote p ^" not a parameter of instantiated expression.")) insts ps;
   116           in (ps', (loc', (prfx, Named insts))) end;
   117     fun params_expr is =
   118           let
   119             val (is', ps') = fold_map (fn i => fn ps =>
   120               let
   121                 val (ps', i') = params_inst i;
   122                 val ps'' = distinct parm_eq (ps @ ps');
   123               in (i', ps'') end) is []
   124           in (ps', is') end;
   125 
   126     val (implicit, expr') = params_expr expr;
   127 
   128     val implicit' = map (#1 #> Binding.name_of) implicit;
   129     val fixed' = map (#1 #> Binding.name_of) fixed;
   130     val _ = reject_dups "Duplicate fixed parameter(s): " fixed';
   131     val implicit'' =
   132       if strict then []
   133       else
   134         let val _ = reject_dups
   135           "Parameter(s) declared simultaneously in expression and for clause: " (implicit' @ fixed')
   136         in map (fn (b, mx) => (b, NONE, mx)) implicit end;
   137 
   138   in (expr', implicit'' @ fixed) end;
   139 
   140 
   141 (** Read instantiation **)
   142 
   143 (* Parse positional or named instantiation *)
   144 
   145 local
   146 
   147 fun prep_inst prep_term ctxt parms (Positional insts) =
   148       (insts ~~ parms) |> map (fn
   149         (NONE, p) => Free (p, dummyT) |
   150         (SOME t, _) => prep_term ctxt t)
   151   | prep_inst prep_term ctxt parms (Named insts) =
   152       parms |> map (fn p => case AList.lookup (op =) insts p of
   153         SOME t => prep_term ctxt t |
   154         NONE => Free (p, dummyT));
   155 
   156 in
   157 
   158 fun parse_inst x = prep_inst Syntax.parse_term x;
   159 fun make_inst x = prep_inst (K I) x;
   160 
   161 end;
   162 
   163 
   164 (* Instantiation morphism *)
   165 
   166 fun inst_morph (parm_names, parm_types) ((prfx, strict), insts') ctxt =
   167   let
   168     (* parameters *)
   169     val type_parm_names = fold Term.add_tfreesT parm_types [] |> map fst;
   170 
   171     (* type inference and contexts *)
   172     val parm_types' = map (TypeInfer.paramify_vars o Logic.varifyT) parm_types;
   173     val type_parms = fold Term.add_tvarsT parm_types' [] |> map (Logic.mk_type o TVar);
   174     val arg = type_parms @ map2 TypeInfer.constrain parm_types' insts';
   175     val res = Syntax.check_terms ctxt arg;
   176     val ctxt' = ctxt |> fold Variable.auto_fixes res;
   177 
   178     (* instantiation *)
   179     val (type_parms'', res') = chop (length type_parms) res;
   180     val insts'' = (parm_names ~~ res') |> map_filter
   181       (fn (inst as (x, Free (y, _))) => if x = y then NONE else SOME inst |
   182         inst => SOME inst);
   183     val instT = Symtab.make (type_parm_names ~~ map Logic.dest_type type_parms'');
   184     val inst = Symtab.make insts'';
   185   in
   186     (Element.inst_morphism (ProofContext.theory_of ctxt) (instT, inst) $>
   187       Morphism.binding_morphism (Binding.prefix strict prfx), ctxt')
   188   end;
   189 
   190 
   191 (*** Locale processing ***)
   192 
   193 (** Parsing **)
   194 
   195 fun parse_elem prep_typ prep_term ctxt =
   196   Element.map_ctxt
   197    {binding = I,
   198     typ = prep_typ ctxt,
   199     term = prep_term (ProofContext.set_mode ProofContext.mode_schematic ctxt),
   200     pattern = prep_term (ProofContext.set_mode ProofContext.mode_pattern ctxt),
   201     fact = I,
   202     attrib = I};
   203 
   204 fun parse_concl prep_term ctxt concl =
   205   (map o map) (fn (t, ps) =>
   206     (prep_term (ProofContext.set_mode ProofContext.mode_schematic ctxt) t, (* FIXME ?? *)
   207       map (prep_term (ProofContext.set_mode ProofContext.mode_pattern ctxt)) ps)) concl;
   208 
   209 
   210 (** Simultaneous type inference: instantiations + elements + conclusion **)
   211 
   212 local
   213 
   214 fun mk_type T = (Logic.mk_type T, []);
   215 fun mk_term t = (t, []);
   216 fun mk_propp (p, pats) = (Syntax.type_constraint propT p, pats);
   217 
   218 fun dest_type (T, []) = Logic.dest_type T;
   219 fun dest_term (t, []) = t;
   220 fun dest_propp (p, pats) = (p, pats);
   221 
   222 fun extract_inst (_, (_, ts)) = map mk_term ts;
   223 fun restore_inst ((l, (p, _)), cs) = (l, (p, map dest_term cs));
   224 
   225 fun extract_elem (Fixes fixes) = map (#2 #> the_list #> map mk_type) fixes
   226   | extract_elem (Constrains csts) = map (#2 #> single #> map mk_type) csts
   227   | extract_elem (Assumes asms) = map (#2 #> map mk_propp) asms
   228   | extract_elem (Defines defs) = map (fn (_, (t, ps)) => [mk_propp (t, ps)]) defs
   229   | extract_elem (Notes _) = [];
   230 
   231 fun restore_elem (Fixes fixes, css) =
   232       (fixes ~~ css) |> map (fn ((x, _, mx), cs) =>
   233         (x, cs |> map dest_type |> try hd, mx)) |> Fixes
   234   | restore_elem (Constrains csts, css) =
   235       (csts ~~ css) |> map (fn ((x, _), cs) =>
   236         (x, cs |> map dest_type |> hd)) |> Constrains
   237   | restore_elem (Assumes asms, css) =
   238       (asms ~~ css) |> map (fn ((b, _), cs) => (b, map dest_propp cs)) |> Assumes
   239   | restore_elem (Defines defs, css) =
   240       (defs ~~ css) |> map (fn ((b, _), [c]) => (b, dest_propp c)) |> Defines
   241   | restore_elem (Notes notes, _) = Notes notes;
   242 
   243 fun check cs context =
   244   let
   245     fun prep (_, pats) (ctxt, t :: ts) =
   246       let val ctxt' = Variable.auto_fixes t ctxt
   247       in
   248         ((t, Syntax.check_props (ProofContext.set_mode ProofContext.mode_pattern ctxt') pats),
   249           (ctxt', ts))
   250       end
   251     val (cs', (context', _)) = fold_map prep cs
   252       (context, Syntax.check_terms
   253         (ProofContext.set_mode ProofContext.mode_schematic context) (map fst cs));
   254   in (cs', context') end;
   255 
   256 in
   257 
   258 fun check_autofix insts elems concl ctxt =
   259   let
   260     val inst_cs = map extract_inst insts;
   261     val elem_css = map extract_elem elems;
   262     val concl_cs = (map o map) mk_propp concl;
   263     (* Type inference *)
   264     val (inst_cs' :: css', ctxt') =
   265       (fold_burrow o fold_burrow) check (inst_cs :: elem_css @ [concl_cs]) ctxt;
   266     val (elem_css', [concl_cs']) = chop (length elem_css) css';
   267   in
   268     (map restore_inst (insts ~~ inst_cs'), map restore_elem (elems ~~ elem_css'),
   269       concl_cs', ctxt')
   270   end;
   271 
   272 end;
   273 
   274 
   275 (** Prepare locale elements **)
   276 
   277 fun declare_elem prep_vars (Fixes fixes) ctxt =
   278       let val (vars, _) = prep_vars fixes ctxt
   279       in ctxt |> ProofContext.add_fixes_i vars |> snd end
   280   | declare_elem prep_vars (Constrains csts) ctxt =
   281       ctxt |> prep_vars (map (fn (x, T) => (Binding.name x, SOME T, NoSyn)) csts) |> snd
   282   | declare_elem _ (Assumes _) ctxt = ctxt
   283   | declare_elem _ (Defines _) ctxt = ctxt
   284   | declare_elem _ (Notes _) ctxt = ctxt;
   285 
   286 (** Finish locale elements **)
   287 
   288 fun closeup _ _ false elem = elem
   289   | closeup ctxt parms true elem =
   290       let
   291         fun close_frees t =
   292           let
   293             val rev_frees =
   294               Term.fold_aterms (fn Free (x, T) =>
   295                 if AList.defined (op =) parms x then I else insert (op =) (x, T) | _ => I) t [];
   296           in Term.list_all_free (rev rev_frees, t) end; (* FIXME use fold Logic.all *)
   297   (* FIXME consider closing in syntactic phase *)
   298 
   299         fun no_binds [] = []
   300           | no_binds _ = error "Illegal term bindings in context element";
   301       in
   302         (case elem of
   303           Assumes asms => Assumes (asms |> map (fn (a, propps) =>
   304             (a, map (fn (t, ps) => (close_frees t, no_binds ps)) propps)))
   305         | Defines defs => Defines (defs |> map (fn ((name, atts), (t, ps)) =>
   306             let val ((c, _), t') = LocalDefs.cert_def ctxt (close_frees t)
   307             in ((Thm.def_binding_optional (Binding.name c) name, atts), (t', no_binds ps)) end))
   308         | e => e)
   309       end;
   310 
   311 fun finish_primitive parms _ (Fixes fixes) = Fixes (map (fn (binding, _, mx) =>
   312       let val x = Binding.name_of binding
   313       in (binding, AList.lookup (op =) parms x, mx) end) fixes)
   314   | finish_primitive _ _ (Constrains _) = Constrains []
   315   | finish_primitive _ close (Assumes asms) = close (Assumes asms)
   316   | finish_primitive _ close (Defines defs) = close (Defines defs)
   317   | finish_primitive _ _ (Notes facts) = Notes facts;
   318 
   319 fun finish_inst ctxt parms do_close (loc, (prfx, inst)) =
   320   let
   321     val thy = ProofContext.theory_of ctxt;
   322     val (parm_names, parm_types) = Locale.params_of thy loc |>
   323       map_split (fn (b, SOME T, _) => (Binding.name_of b, T));
   324     val (morph, _) = inst_morph (parm_names, parm_types) (prfx, inst) ctxt;
   325   in (loc, morph) end;
   326 
   327 fun finish_elem ctxt parms do_close elem =
   328   let
   329     val elem' = finish_primitive parms (closeup ctxt parms do_close) elem;
   330   in elem' end
   331 
   332 fun finish ctxt parms do_close insts elems =
   333   let
   334     val deps = map (finish_inst ctxt parms do_close) insts;
   335     val elems' = map (finish_elem ctxt parms do_close) elems;
   336   in (deps, elems') end;
   337 
   338 
   339 (** Process full context statement: instantiations + elements + conclusion **)
   340 
   341 (* Interleave incremental parsing and type inference over entire parsed stretch. *)
   342 
   343 local
   344 
   345 fun prep_full_context_statement parse_typ parse_prop prep_vars_elem prep_inst prep_vars_inst prep_expr
   346     strict do_close raw_import init_body raw_elems raw_concl ctxt1 =
   347   let
   348     val thy = ProofContext.theory_of ctxt1;
   349 
   350     val (raw_insts, fixed) = parameters_of thy strict (apfst (prep_expr thy) raw_import);
   351 
   352     fun prep_insts (loc, (prfx, inst)) (i, insts, ctxt) =
   353       let
   354         val (parm_names, parm_types) = Locale.params_of thy loc |>
   355           map_split (fn (b, SOME T, _) => (Binding.name_of b, T))
   356             (*FIXME return value of Locale.params_of has strange type*)
   357         val inst' = prep_inst ctxt parm_names inst;
   358         val parm_types' = map (TypeInfer.paramify_vars o
   359           Term.map_type_tvar (fn ((x, _), S) => TVar ((x, i), S)) o Logic.varifyT) parm_types;
   360         val inst'' = map2 TypeInfer.constrain parm_types' inst';
   361         val insts' = insts @ [(loc, (prfx, inst''))];
   362         val (insts'', _, _, ctxt' (* FIXME not used *) ) = check_autofix insts' [] [] ctxt;
   363         val inst''' = insts'' |> List.last |> snd |> snd;
   364         val (morph, _) = inst_morph (parm_names, parm_types) (prfx, inst''') ctxt;
   365         val ctxt'' = Locale.activate_declarations thy (loc, morph) ctxt;
   366       in (i+1, insts', ctxt'') end;
   367 
   368     fun prep_elem insts raw_elem (elems, ctxt) =
   369       let
   370         val ctxt' = declare_elem prep_vars_elem raw_elem ctxt;
   371         val elems' = elems @ [parse_elem parse_typ parse_prop ctxt' raw_elem];
   372         val (_, _, _, ctxt'') = check_autofix insts elems' [] ctxt';
   373       in (elems', ctxt') end;
   374 
   375     fun prep_concl raw_concl (insts, elems, ctxt) =
   376       let
   377         val concl = parse_concl parse_prop ctxt raw_concl;
   378       in check_autofix insts elems concl ctxt end;
   379 
   380     val fors = prep_vars_inst fixed ctxt1 |> fst;
   381     val ctxt2 = ctxt1 |> ProofContext.add_fixes_i fors |> snd;
   382     val (_, insts', ctxt3) = fold prep_insts raw_insts (0, [], ctxt2);
   383     val ctxt4 = init_body ctxt3;
   384     val (elems, ctxt5) = fold (prep_elem insts') raw_elems ([], ctxt4);
   385     val (insts, elems', concl, ctxt6) =
   386       prep_concl raw_concl (insts', elems, ctxt5);
   387 
   388     (* Retrieve parameter types *)
   389     val xs = fold (fn Fixes fixes => (fn ps => ps @ map (Binding.name_of o #1) fixes)
   390       | _ => fn ps => ps) (Fixes fors :: elems') [];
   391     val (Ts, ctxt7) = fold_map ProofContext.inferred_param xs ctxt6;
   392     val parms = xs ~~ Ts;  (* params from expression and elements *)
   393 
   394     val Fixes fors' = finish_primitive parms I (Fixes fors);
   395     val (deps, elems'') = finish ctxt6 parms do_close insts elems';
   396 
   397   in ((fors', deps, elems'', concl), (parms, ctxt7)) end
   398 
   399 in
   400 
   401 fun cert_full_context_statement x =
   402   prep_full_context_statement (K I) (K I) ProofContext.cert_vars
   403   make_inst ProofContext.cert_vars (K I) x;
   404 fun cert_read_full_context_statement x =
   405   prep_full_context_statement Syntax.parse_typ Syntax.parse_prop ProofContext.read_vars
   406   make_inst ProofContext.cert_vars (K I) x;
   407 fun read_full_context_statement x =
   408   prep_full_context_statement Syntax.parse_typ Syntax.parse_prop ProofContext.read_vars
   409   parse_inst ProofContext.read_vars intern x;
   410 
   411 end;
   412 
   413 
   414 (* Context statement: elements + conclusion *)
   415 
   416 local
   417 
   418 fun prep_statement prep activate raw_elems raw_concl context =
   419   let
   420      val ((_, _, elems, concl), _) =
   421        prep true false ([], []) I raw_elems raw_concl context;
   422      val (_, context') = context |>
   423        ProofContext.set_stmt true |>
   424        activate elems;
   425   in (concl, context') end;
   426 
   427 in
   428 
   429 fun cert_statement x = prep_statement cert_full_context_statement Element.activate_i x;
   430 fun read_statement x = prep_statement read_full_context_statement Element.activate x;
   431 
   432 end;
   433 
   434 
   435 (* Locale declaration: import + elements *)
   436 
   437 local
   438 
   439 fun prep_declaration prep activate raw_import init_body raw_elems context =
   440   let
   441     val ((fixed, deps, elems, _), (parms, ctxt')) =
   442       prep false true raw_import init_body raw_elems [] context ;
   443     (* Declare parameters and imported facts *)
   444     val context' = context |>
   445       ProofContext.add_fixes_i fixed |> snd |>
   446       fold Locale.activate_local_facts deps;
   447     val (elems', _) = context' |>
   448       ProofContext.set_stmt true |>
   449       activate elems;
   450   in ((fixed, deps, elems'), (parms, ctxt')) end;
   451 
   452 in
   453 
   454 fun cert_declaration x = prep_declaration cert_full_context_statement Element.activate_i x;
   455 fun cert_read_declaration x = prep_declaration cert_read_full_context_statement Element.activate x;
   456 fun read_declaration x = prep_declaration read_full_context_statement Element.activate x;
   457 
   458 end;
   459 
   460 
   461 (* Locale expression to set up a goal *)
   462 
   463 local
   464 
   465 fun props_of thy (name, morph) =
   466   let
   467     val (asm, defs) = Locale.specification_of thy name;
   468   in
   469     (case asm of NONE => defs | SOME asm => asm :: defs) |> map (Morphism.term morph)
   470   end;
   471 
   472 fun prep_goal_expression prep expression context =
   473   let
   474     val thy = ProofContext.theory_of context;
   475 
   476     val ((fixed, deps, _, _), _) =
   477       prep true true expression I [] [] context;
   478     (* proof obligations *)
   479     val propss = map (props_of thy) deps;
   480 
   481     val goal_ctxt = context |>
   482       ProofContext.add_fixes_i fixed |> snd |>
   483       (fold o fold) Variable.auto_fixes propss;
   484 
   485     val export = Variable.export_morphism goal_ctxt context;
   486     val exp_fact = Drule.zero_var_indexes_list o map Thm.strip_shyps o Morphism.fact export;
   487     val exp_term = TermSubst.zero_var_indexes o Morphism.term export;
   488     val exp_typ = Logic.type_map exp_term;
   489     val export' = Morphism.morphism {binding = I, typ = exp_typ, term = exp_term, fact = exp_fact};
   490   in ((propss, deps, export'), goal_ctxt) end;
   491 
   492 in
   493 
   494 fun cert_goal_expression x = prep_goal_expression cert_full_context_statement x;
   495 fun read_goal_expression x = prep_goal_expression read_full_context_statement x;
   496 
   497 end;
   498 
   499 
   500 (*** Locale declarations ***)
   501 
   502 (* extract specification text *)
   503 
   504 val norm_term = Envir.beta_norm oo Term.subst_atomic;
   505 
   506 fun bind_def ctxt eq (xs, env, eqs) =
   507   let
   508     val _ = LocalDefs.cert_def ctxt eq;
   509     val ((y, T), b) = LocalDefs.abs_def eq;
   510     val b' = norm_term env b;
   511     fun err msg = error (msg ^ ": " ^ quote y);
   512   in
   513     case filter (fn (Free (y', _), _) => y = y' | _ => false) env of
   514       [] => (Term.add_frees b' xs, (Free (y, T), b') :: env, eq :: eqs) |
   515       dups => if forall (fn (_, b'') => b' aconv b'') dups
   516         then (xs, env, eqs)
   517         else err "Attempt to redefine variable"
   518   end;
   519 
   520 (* text has the following structure:
   521        (((exts, exts'), (ints, ints')), (xs, env, defs))
   522    where
   523      exts: external assumptions (terms in assumes elements)
   524      exts': dito, normalised wrt. env
   525      ints: internal assumptions (terms in assumptions from insts)
   526      ints': dito, normalised wrt. env
   527      xs: the free variables in exts' and ints' and rhss of definitions,
   528        this includes parameters except defined parameters
   529      env: list of term pairs encoding substitutions, where the first term
   530        is a free variable; substitutions represent defines elements and
   531        the rhs is normalised wrt. the previous env
   532      defs: the equations from the defines elements
   533    *)
   534 
   535 fun eval_text _ _ (Fixes _) text = text
   536   | eval_text _ _ (Constrains _) text = text
   537   | eval_text _ is_ext (Assumes asms)
   538         (((exts, exts'), (ints, ints')), (xs, env, defs)) =
   539       let
   540         val ts = maps (map #1 o #2) asms;
   541         val ts' = map (norm_term env) ts;
   542         val spec' =
   543           if is_ext then ((exts @ ts, exts' @ ts'), (ints, ints'))
   544           else ((exts, exts'), (ints @ ts, ints' @ ts'));
   545       in (spec', (fold Term.add_frees ts' xs, env, defs)) end
   546   | eval_text ctxt _ (Defines defs) (spec, binds) =
   547       (spec, fold (bind_def ctxt o #1 o #2) defs binds)
   548   | eval_text _ _ (Notes _) text = text;
   549 
   550 fun eval_inst ctxt (loc, morph) text =
   551   let
   552     val thy = ProofContext.theory_of ctxt;
   553     val (asm, defs) = Locale.specification_of thy loc;
   554     val asm' = Option.map (Morphism.term morph) asm;
   555     val defs' = map (Morphism.term morph) defs;
   556     val text' = text |>
   557       (if is_some asm
   558         then eval_text ctxt false (Assumes [(Attrib.empty_binding, [(the asm', [])])])
   559         else I) |>
   560       (if not (null defs)
   561         then eval_text ctxt false (Defines (map (fn def => (Attrib.empty_binding, (def, []))) defs'))
   562         else I)
   563 (* FIXME clone from locale.ML *)
   564   in text' end;
   565 
   566 fun eval_elem ctxt elem text =
   567   let
   568     val text' = eval_text ctxt true elem text;
   569   in text' end;
   570 
   571 fun eval ctxt deps elems =
   572   let
   573     val text' = fold (eval_inst ctxt) deps ((([], []), ([], [])), ([], [], []));
   574     val ((spec, (_, _, defs))) = fold (eval_elem ctxt) elems text';
   575   in (spec, defs) end;
   576 
   577 (* axiomsN: name of theorem set with destruct rules for locale predicates,
   578      also name suffix of delta predicates and assumptions. *)
   579 
   580 val axiomsN = "axioms";
   581 
   582 local
   583 
   584 (* introN: name of theorems for introduction rules of locale and
   585      delta predicates *)
   586 
   587 val introN = "intro";
   588 
   589 fun atomize_spec thy ts =
   590   let
   591     val t = Logic.mk_conjunction_balanced ts;
   592     val body = ObjectLogic.atomize_term thy t;
   593     val bodyT = Term.fastype_of body;
   594   in
   595     if bodyT = propT then (t, propT, Thm.reflexive (Thm.cterm_of thy t))
   596     else (body, bodyT, ObjectLogic.atomize (Thm.cterm_of thy t))
   597   end;
   598 
   599 (* achieve plain syntax for locale predicates (without "PROP") *)
   600 
   601 fun aprop_tr' n c = (Syntax.constN ^ c, fn ctxt => fn args =>
   602   if length args = n then
   603     Syntax.const "_aprop" $
   604       Term.list_comb (Syntax.free (Consts.extern (ProofContext.consts_of ctxt) c), args)
   605   else raise Match);
   606 
   607 (* define one predicate including its intro rule and axioms
   608    - bname: predicate name
   609    - parms: locale parameters
   610    - defs: thms representing substitutions from defines elements
   611    - ts: terms representing locale assumptions (not normalised wrt. defs)
   612    - norm_ts: terms representing locale assumptions (normalised wrt. defs)
   613    - thy: the theory
   614 *)
   615 
   616 fun def_pred bname parms defs ts norm_ts thy =
   617   let
   618     val name = Sign.full_name thy bname;
   619 
   620     val (body, bodyT, body_eq) = atomize_spec thy norm_ts;
   621     val env = Term.add_free_names body [];
   622     val xs = filter (member (op =) env o #1) parms;
   623     val Ts = map #2 xs;
   624     val extraTs =
   625       (Term.add_tfrees body [] \\ fold Term.add_tfreesT Ts [])
   626       |> Library.sort_wrt #1 |> map TFree;
   627     val predT = map Term.itselfT extraTs ---> Ts ---> bodyT;
   628 
   629     val args = map Logic.mk_type extraTs @ map Free xs;
   630     val head = Term.list_comb (Const (name, predT), args);
   631     val statement = ObjectLogic.ensure_propT thy head;
   632 
   633     val ([pred_def], defs_thy) =
   634       thy
   635       |> bodyT = propT ? Sign.add_advanced_trfuns ([], [], [aprop_tr' (length args) name], [])
   636       |> Sign.declare_const [] ((bname, predT), NoSyn) |> snd
   637       |> PureThy.add_defs false
   638         [((Binding.map_name Thm.def_name bname, Logic.mk_equals (head, body)), [Thm.kind_internal])];
   639     val defs_ctxt = ProofContext.init defs_thy |> Variable.declare_term head;
   640 
   641     val cert = Thm.cterm_of defs_thy;
   642 
   643     val intro = Goal.prove_global defs_thy [] norm_ts statement (fn _ =>
   644       MetaSimplifier.rewrite_goals_tac [pred_def] THEN
   645       Tactic.compose_tac (false, body_eq RS Drule.equal_elim_rule1, 1) 1 THEN
   646       Tactic.compose_tac (false,
   647         Conjunction.intr_balanced (map (Thm.assume o cert) norm_ts), 0) 1);
   648 
   649     val conjuncts =
   650       (Drule.equal_elim_rule2 OF [body_eq,
   651         MetaSimplifier.rewrite_rule [pred_def] (Thm.assume (cert statement))])
   652       |> Conjunction.elim_balanced (length ts);
   653     val axioms = ts ~~ conjuncts |> map (fn (t, ax) =>
   654       Element.prove_witness defs_ctxt t
   655        (MetaSimplifier.rewrite_goals_tac defs THEN
   656         Tactic.compose_tac (false, ax, 0) 1));
   657   in ((statement, intro, axioms), defs_thy) end;
   658 
   659 in
   660 
   661 (* main predicate definition function *)
   662 
   663 fun define_preds pname parms (((exts, exts'), (ints, ints')), defs) thy =
   664   let
   665     val defs' = map (cterm_of thy #> Assumption.assume #> Drule.gen_all #> Drule.abs_def) defs;
   666 
   667     val (a_pred, a_intro, a_axioms, thy'') =
   668       if null exts then (NONE, NONE, [], thy)
   669       else
   670         let
   671           val aname = if null ints then pname else Binding.suffix_name ("_" ^ axiomsN) pname
   672           val ((statement, intro, axioms), thy') =
   673             thy
   674             |> def_pred aname parms defs' exts exts';
   675           val (_, thy'') =
   676             thy'
   677             |> Sign.mandatory_path (Binding.name_of aname)
   678             |> PureThy.note_thmss Thm.internalK
   679               [((Binding.name introN, []), [([intro], [Locale.unfold_attrib])])]
   680             ||> Sign.restore_naming thy';
   681           in (SOME statement, SOME intro, axioms, thy'') end;
   682     val (b_pred, b_intro, b_axioms, thy'''') =
   683       if null ints then (NONE, NONE, [], thy'')
   684       else
   685         let
   686           val ((statement, intro, axioms), thy''') =
   687             thy''
   688             |> def_pred pname parms defs' (ints @ the_list a_pred) (ints' @ the_list a_pred);
   689           val (_, thy'''') =
   690             thy'''
   691             |> Sign.mandatory_path (Binding.name_of pname)
   692             |> PureThy.note_thmss Thm.internalK
   693                  [((Binding.name introN, []), [([intro], [Locale.intro_attrib])]),
   694                   ((Binding.name axiomsN, []),
   695                     [(map (Drule.standard o Element.conclude_witness) axioms, [])])]
   696             ||> Sign.restore_naming thy''';
   697         in (SOME statement, SOME intro, axioms, thy'''') end;
   698   in ((a_pred, a_intro, a_axioms), (b_pred, b_intro, b_axioms), thy'''') end;
   699 
   700 end;
   701 
   702 
   703 local
   704 
   705 fun assumes_to_notes (Assumes asms) axms =
   706       fold_map (fn (a, spec) => fn axs =>
   707           let val (ps, qs) = chop (length spec) axs
   708           in ((a, [(ps, [])]), qs) end) asms axms
   709       |> apfst (curry Notes Thm.assumptionK)
   710   | assumes_to_notes e axms = (e, axms);
   711 
   712 fun defines_to_notes thy (Defines defs) =
   713       Notes (Thm.definitionK, map (fn (a, (def, _)) =>
   714         (a, [([Assumption.assume (cterm_of thy def)],
   715           [(Attrib.internal o K) Locale.witness_attrib])])) defs)
   716   | defines_to_notes _ e = e;
   717 
   718 fun gen_add_locale prep_decl
   719     bname raw_predicate_bname raw_import raw_body thy =
   720   let
   721     val name = Sign.full_name thy bname;
   722     val _ = Locale.defined thy name andalso
   723       error ("Duplicate definition of locale " ^ quote name);
   724 
   725     val ((fixed, deps, body_elems), (parms, ctxt')) =
   726       prep_decl raw_import I raw_body (ProofContext.init thy);
   727     val text as (((_, exts'), _), defs) = eval ctxt' deps body_elems;
   728 
   729     val predicate_bname =
   730       if Binding.is_empty raw_predicate_bname then bname
   731       else raw_predicate_bname;
   732     val ((a_statement, a_intro, a_axioms), (b_statement, b_intro, b_axioms), thy') =
   733       define_preds predicate_bname parms text thy;
   734 
   735     val extraTs = fold Term.add_tfrees exts' [] \\ fold Term.add_tfreesT (map snd parms) [];
   736     val _ =
   737       if null extraTs then ()
   738       else warning ("Additional type variable(s) in locale specification " ^ quote (Binding.str_of bname));
   739 
   740     val a_satisfy = Element.satisfy_morphism a_axioms;
   741     val b_satisfy = Element.satisfy_morphism b_axioms;
   742 
   743     val params = fixed @
   744       (body_elems |> map_filter (fn Fixes fixes => SOME fixes | _ => NONE) |> flat);
   745     val asm = if is_some b_statement then b_statement else a_statement;
   746 
   747     val notes =
   748         if is_some asm
   749         then [(Thm.internalK, [((Binding.suffix_name ("_" ^ axiomsN) bname, []),
   750           [([Assumption.assume (cterm_of thy' (the asm))],
   751             [(Attrib.internal o K) Locale.witness_attrib])])])]
   752         else [];
   753 
   754     val notes' = body_elems |>
   755       map (defines_to_notes thy') |>
   756       map (Element.morph_ctxt a_satisfy) |>
   757       (fn elems => fold_map assumes_to_notes elems (map Element.conclude_witness a_axioms)) |>
   758       fst |>
   759       map (Element.morph_ctxt b_satisfy) |>
   760       map_filter (fn Notes notes => SOME notes | _ => NONE);
   761 
   762     val deps' = map (fn (l, morph) => (l, morph $> b_satisfy)) deps;
   763     val axioms = map Element.conclude_witness b_axioms;
   764 
   765     val loc_ctxt = thy'
   766       |> Locale.register_locale bname (extraTs, params)
   767           (asm, rev defs) (a_intro, b_intro) axioms ([], [])
   768           (map (fn n => (n, stamp ())) notes |> rev) (map (fn d => (d, stamp ())) deps' |> rev)
   769       |> TheoryTarget.init (SOME name)
   770       |> fold (fn (kind, facts) => LocalTheory.notes kind facts #> snd) notes';
   771 
   772   in (name, loc_ctxt) end;
   773 
   774 in
   775 
   776 val add_locale = gen_add_locale cert_declaration;
   777 val add_locale_cmd = gen_add_locale read_declaration;
   778 
   779 end;
   780 
   781 
   782 (*** Interpretation ***)
   783 
   784 (** Interpretation between locales: declaring sublocale relationships **)
   785 
   786 local
   787 
   788 fun gen_sublocale prep_expr intern raw_target expression thy =
   789   let
   790     val target = intern thy raw_target;
   791     val target_ctxt = Locale.init target thy;
   792 
   793     val ((propss, deps, export), goal_ctxt) = prep_expr expression target_ctxt;
   794 
   795     fun after_qed witss = ProofContext.theory (
   796       fold2 (fn (name, morph) => fn wits => Locale.add_dependency target
   797         (name, morph $> Element.satisfy_morphism wits $> export)) deps witss #>
   798       (fn thy => fold_rev Locale.activate_global_facts
   799           (Locale.get_registrations thy) thy));
   800   in Element.witness_proof after_qed propss goal_ctxt end;
   801 
   802 in
   803 
   804 fun sublocale x = gen_sublocale cert_goal_expression (K I) x;
   805 fun sublocale_cmd x = gen_sublocale read_goal_expression Locale.intern x;
   806 
   807 end;
   808 
   809 
   810 (** Interpretation in theories **)
   811 
   812 local
   813 
   814 fun gen_interpretation prep_expr parse_prop prep_attr
   815     expression equations theory =
   816   let
   817     val ((propss, regs, export), expr_ctxt) = ProofContext.init theory
   818       |> prep_expr expression;
   819 
   820     val eqns = map (parse_prop expr_ctxt o snd) equations |> Syntax.check_terms expr_ctxt;
   821     val eq_attns = map ((apsnd o map) (prep_attr theory) o fst) equations;
   822     val goal_ctxt = fold Variable.auto_fixes eqns expr_ctxt;
   823     val export' = Variable.export_morphism goal_ctxt expr_ctxt;
   824 
   825     fun store_reg ((name, morph), wits) thy =
   826       let
   827         val wits' = map (Element.morph_witness export') wits;
   828         val morph' = morph $> Element.satisfy_morphism wits';
   829       in
   830         thy
   831         |> Locale.add_registration (name, (morph', export))
   832         |> pair (name, morph')
   833       end;
   834 
   835     fun store_eqns_activate regs [] thy =
   836           thy
   837           |> fold (fn (name, morph) =>
   838                Locale.activate_global_facts (name, morph $> export)) regs
   839       | store_eqns_activate regs eqs thy =
   840           let
   841             val eqs' = eqs |> map (Morphism.thm (export' $> export) #>
   842               LocalDefs.meta_rewrite_rule (ProofContext.init thy) #>
   843               Drule.abs_def);
   844             val eq_morph = Element.eq_morphism thy eqs';
   845             val eq_attns' = map ((apsnd o map) (Attrib.attribute_i thy)) eq_attns;
   846           in
   847             thy
   848             |> fold (fn (name, morph) =>
   849                 Locale.amend_registration eq_morph (name, morph) #>
   850                 Locale.activate_global_facts (name, morph $> eq_morph $> export)) regs
   851             |> PureThy.note_thmss Thm.lemmaK (eq_attns' ~~ map (fn eq => [([eq], [])]) eqs')
   852             |> snd
   853           end;
   854 
   855     fun after_qed wits eqs = ProofContext.theory (fold_map store_reg (regs ~~ wits)
   856         #-> (fn regs => store_eqns_activate regs eqs));
   857 
   858   in Element.witness_proof_eqs after_qed propss eqns goal_ctxt end;
   859 
   860 in
   861 
   862 fun interpretation x = gen_interpretation cert_goal_expression (K I) (K I) x;
   863 fun interpretation_cmd x = gen_interpretation read_goal_expression
   864   Syntax.parse_prop Attrib.intern_src x;
   865 
   866 end;
   867 
   868 
   869 (** Interpretation in proof contexts **)
   870 
   871 local
   872 
   873 fun gen_interpret prep_expr
   874     expression int state =
   875   let
   876     val _ = Proof.assert_forward_or_chain state;
   877     val ctxt = Proof.context_of state;
   878 
   879     val ((propss, regs, export), goal_ctxt) = prep_expr expression ctxt;
   880 
   881     fun store_reg (name, morph) thms =
   882       let
   883         val morph' = morph $> Element.satisfy_morphism thms $> export;
   884       in Locale.activate_local_facts (name, morph') end;
   885 
   886     fun after_qed wits =
   887       Proof.map_context (fold2 store_reg regs wits);
   888   in
   889     state
   890     |> Element.witness_local_proof after_qed "interpret" propss goal_ctxt int
   891   end;
   892 
   893 in
   894 
   895 fun interpret x = gen_interpret cert_goal_expression x;
   896 fun interpret_cmd x = gen_interpret read_goal_expression x;
   897 
   898 end;
   899 
   900 end;
   901