src/Pure/Isar/proof_context.ML
author wenzelm
Thu Mar 12 13:18:42 2009 +0100 (2009-03-12 ago)
changeset 30469 de9e8f1d927c
parent 30438 c2d49315b93b
child 30473 e0b66c11e7e4
permissions -rw-r--r--
renamed sticky_prefix to mandatory_path;
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The key concept of Isar proof contexts: elevates primitive local
     5 reasoning Gamma |- phi to a structured concept, with generic context
     6 elements.  See also structure Variable and Assumption.
     7 *)
     8 
     9 signature PROOF_CONTEXT =
    10 sig
    11   val theory_of: Proof.context -> theory
    12   val init: theory -> Proof.context
    13   type mode
    14   val mode_default: mode
    15   val mode_stmt: mode
    16   val mode_pattern: mode
    17   val mode_schematic: mode
    18   val mode_abbrev: mode
    19   val set_mode: mode -> Proof.context -> Proof.context
    20   val get_mode: Proof.context -> mode
    21   val restore_mode: Proof.context -> Proof.context -> Proof.context
    22   val abbrev_mode: Proof.context -> bool
    23   val set_stmt: bool -> Proof.context -> Proof.context
    24   val naming_of: Proof.context -> NameSpace.naming
    25   val full_name: Proof.context -> binding -> string
    26   val consts_of: Proof.context -> Consts.T
    27   val const_syntax_name: Proof.context -> string -> string
    28   val the_const_constraint: Proof.context -> string -> typ
    29   val mk_const: Proof.context -> string * typ list -> term
    30   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    31   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    32   val facts_of: Proof.context -> Facts.T
    33   val transfer_syntax: theory -> Proof.context -> Proof.context
    34   val transfer: theory -> Proof.context -> Proof.context
    35   val theory: (theory -> theory) -> Proof.context -> Proof.context
    36   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    37   val extern_fact: Proof.context -> string -> xstring
    38   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    39   val pretty_thm_legacy: thm -> Pretty.T
    40   val pretty_thm: Proof.context -> thm -> Pretty.T
    41   val pretty_thms: Proof.context -> thm list -> Pretty.T
    42   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    43   val string_of_thm: Proof.context -> thm -> string
    44   val read_typ: Proof.context -> string -> typ
    45   val read_typ_syntax: Proof.context -> string -> typ
    46   val read_typ_abbrev: Proof.context -> string -> typ
    47   val cert_typ: Proof.context -> typ -> typ
    48   val cert_typ_syntax: Proof.context -> typ -> typ
    49   val cert_typ_abbrev: Proof.context -> typ -> typ
    50   val get_skolem: Proof.context -> string -> string
    51   val revert_skolem: Proof.context -> string -> string
    52   val infer_type: Proof.context -> string -> typ
    53   val inferred_param: string -> Proof.context -> typ * Proof.context
    54   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    55   val read_tyname: Proof.context -> string -> typ
    56   val read_const_proper: Proof.context -> string -> term
    57   val read_const: Proof.context -> string -> term
    58   val allow_dummies: Proof.context -> Proof.context
    59   val decode_term: Proof.context -> term -> term
    60   val standard_infer_types: Proof.context -> term list -> term list
    61   val read_term_pattern: Proof.context -> string -> term
    62   val read_term_schematic: Proof.context -> string -> term
    63   val read_term_abbrev: Proof.context -> string -> term
    64   val expand_abbrevs: Proof.context -> term -> term
    65   val cert_term: Proof.context -> term -> term
    66   val cert_prop: Proof.context -> term -> term
    67   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    68   val export: Proof.context -> Proof.context -> thm list -> thm list
    69   val export_morphism: Proof.context -> Proof.context -> morphism
    70   val norm_export_morphism: Proof.context -> Proof.context -> morphism
    71   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    72   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    73   val auto_bind_goal: term list -> Proof.context -> Proof.context
    74   val auto_bind_facts: term list -> Proof.context -> Proof.context
    75   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    76   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    77   val read_propp: Proof.context * (string * string list) list list
    78     -> Proof.context * (term * term list) list list
    79   val cert_propp: Proof.context * (term * term list) list list
    80     -> Proof.context * (term * term list) list list
    81   val read_propp_schematic: Proof.context * (string * string list) list list
    82     -> Proof.context * (term * term list) list list
    83   val cert_propp_schematic: Proof.context * (term * term list) list list
    84     -> Proof.context * (term * term list) list list
    85   val bind_propp: Proof.context * (string * string list) list list
    86     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    87   val bind_propp_i: Proof.context * (term * term list) list list
    88     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    89   val bind_propp_schematic: Proof.context * (string * string list) list list
    90     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    91   val bind_propp_schematic_i: Proof.context * (term * term list) list list
    92     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    93   val fact_tac: thm list -> int -> tactic
    94   val some_fact_tac: Proof.context -> int -> tactic
    95   val get_fact: Proof.context -> Facts.ref -> thm list
    96   val get_fact_single: Proof.context -> Facts.ref -> thm
    97   val get_thms: Proof.context -> xstring -> thm list
    98   val get_thm: Proof.context -> xstring -> thm
    99   val add_path: string -> Proof.context -> Proof.context
   100   val mandatory_path: string -> Proof.context -> Proof.context
   101   val restore_naming: Proof.context -> Proof.context -> Proof.context
   102   val reset_naming: Proof.context -> Proof.context
   103   val note_thmss: string -> (Thm.binding * (Facts.ref * attribute list) list) list ->
   104     Proof.context -> (string * thm list) list * Proof.context
   105   val note_thmss_i: string -> (Thm.binding * (thm list * attribute list) list) list ->
   106     Proof.context -> (string * thm list) list * Proof.context
   107   val put_thms: bool -> string * thm list option -> Proof.context -> Proof.context
   108   val read_vars: (binding * string option * mixfix) list -> Proof.context ->
   109     (binding * typ option * mixfix) list * Proof.context
   110   val cert_vars: (binding * typ option * mixfix) list -> Proof.context ->
   111     (binding * typ option * mixfix) list * Proof.context
   112   val add_fixes: (binding * string option * mixfix) list ->
   113     Proof.context -> string list * Proof.context
   114   val add_fixes_i: (binding * typ option * mixfix) list ->
   115     Proof.context -> string list * Proof.context
   116   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   117   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   118   val add_assms: Assumption.export ->
   119     (Thm.binding * (string * string list) list) list ->
   120     Proof.context -> (string * thm list) list * Proof.context
   121   val add_assms_i: Assumption.export ->
   122     (Thm.binding * (term * term list) list) list ->
   123     Proof.context -> (string * thm list) list * Proof.context
   124   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   125   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   126   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   127   val notation: bool -> Syntax.mode -> (term * mixfix) list -> Proof.context -> Proof.context
   128   val target_notation: bool -> Syntax.mode -> (term * mixfix) list -> morphism ->
   129     Context.generic -> Context.generic
   130   val add_const_constraint: string * typ option -> Proof.context -> Proof.context
   131   val add_abbrev: string -> Properties.T ->
   132     binding * term -> Proof.context -> (term * term) * Proof.context
   133   val revert_abbrev: string -> string -> Proof.context -> Proof.context
   134   val verbose: bool ref
   135   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   136   val print_syntax: Proof.context -> unit
   137   val print_abbrevs: Proof.context -> unit
   138   val print_binds: Proof.context -> unit
   139   val print_lthms: Proof.context -> unit
   140   val print_cases: Proof.context -> unit
   141   val debug: bool ref
   142   val prems_limit: int ref
   143   val pretty_ctxt: Proof.context -> Pretty.T list
   144   val pretty_context: Proof.context -> Pretty.T list
   145   val query_type: Proof.context -> string -> Properties.T
   146   val query_const: Proof.context -> string -> Properties.T
   147   val query_class: Proof.context -> string -> Properties.T
   148 end;
   149 
   150 structure ProofContext: PROOF_CONTEXT =
   151 struct
   152 
   153 val theory_of = Context.theory_of_proof;
   154 val init = Context.init_proof;
   155 
   156 
   157 (** inner syntax mode **)
   158 
   159 datatype mode =
   160   Mode of
   161    {stmt: bool,                (*inner statement mode*)
   162     pattern: bool,             (*pattern binding schematic variables*)
   163     schematic: bool,           (*term referencing loose schematic variables*)
   164     abbrev: bool};             (*abbrev mode -- no normalization*)
   165 
   166 fun make_mode (stmt, pattern, schematic, abbrev) =
   167   Mode {stmt = stmt, pattern = pattern, schematic = schematic, abbrev = abbrev};
   168 
   169 val mode_default   = make_mode (false, false, false, false);
   170 val mode_stmt      = make_mode (true, false, false, false);
   171 val mode_pattern   = make_mode (false, true, false, false);
   172 val mode_schematic = make_mode (false, false, true, false);
   173 val mode_abbrev    = make_mode (false, false, false, true);
   174 
   175 
   176 
   177 (** Isar proof context information **)
   178 
   179 datatype ctxt =
   180   Ctxt of
   181    {mode: mode,                                       (*inner syntax mode*)
   182     naming: NameSpace.naming,                         (*local naming conventions*)
   183     syntax: LocalSyntax.T,                            (*local syntax*)
   184     consts: Consts.T * Consts.T,                      (*local/global consts*)
   185     facts: Facts.T,                                   (*local facts*)
   186     cases: (string * (RuleCases.T * bool)) list};     (*named case contexts*)
   187 
   188 fun make_ctxt (mode, naming, syntax, consts, facts, cases) =
   189   Ctxt {mode = mode, naming = naming, syntax = syntax,
   190     consts = consts, facts = facts, cases = cases};
   191 
   192 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   193 
   194 structure ContextData = ProofDataFun
   195 (
   196   type T = ctxt;
   197   fun init thy =
   198     make_ctxt (mode_default, local_naming, LocalSyntax.init thy,
   199       (Sign.consts_of thy, Sign.consts_of thy), Facts.empty, []);
   200 );
   201 
   202 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   203 
   204 fun map_context f =
   205   ContextData.map (fn Ctxt {mode, naming, syntax, consts, facts, cases} =>
   206     make_ctxt (f (mode, naming, syntax, consts, facts, cases)));
   207 
   208 fun set_mode mode = map_context (fn (_, naming, syntax, consts, facts, cases) =>
   209   (mode, naming, syntax, consts, facts, cases));
   210 
   211 fun map_mode f =
   212   map_context (fn (Mode {stmt, pattern, schematic, abbrev}, naming, syntax, consts, facts, cases) =>
   213     (make_mode (f (stmt, pattern, schematic, abbrev)), naming, syntax, consts, facts, cases));
   214 
   215 fun map_naming f =
   216   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   217     (mode, f naming, syntax, consts, facts, cases));
   218 
   219 fun map_syntax f =
   220   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   221     (mode, naming, f syntax, consts, facts, cases));
   222 
   223 fun map_consts f =
   224   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   225     (mode, naming, syntax, f consts, facts, cases));
   226 
   227 fun map_facts f =
   228   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   229     (mode, naming, syntax, consts, f facts, cases));
   230 
   231 fun map_cases f =
   232   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   233     (mode, naming, syntax, consts, facts, f cases));
   234 
   235 val get_mode = #mode o rep_context;
   236 val restore_mode = set_mode o get_mode;
   237 val abbrev_mode = get_mode #> (fn Mode {abbrev, ...} => abbrev);
   238 
   239 fun set_stmt stmt =
   240   map_mode (fn (_, pattern, schematic, abbrev) => (stmt, pattern, schematic, abbrev));
   241 
   242 val naming_of = #naming o rep_context;
   243 val full_name = NameSpace.full_name o naming_of;
   244 
   245 val syntax_of = #syntax o rep_context;
   246 val syn_of = LocalSyntax.syn_of o syntax_of;
   247 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   248 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   249 
   250 val consts_of = #1 o #consts o rep_context;
   251 val const_syntax_name = Consts.syntax_name o consts_of;
   252 val the_const_constraint = Consts.the_constraint o consts_of;
   253 
   254 fun mk_const ctxt (c, Ts) = Const (c, Consts.instance (consts_of ctxt) (c, Ts));
   255 
   256 val facts_of = #facts o rep_context;
   257 val cases_of = #cases o rep_context;
   258 
   259 
   260 (* theory transfer *)
   261 
   262 fun transfer_syntax thy =
   263   map_syntax (LocalSyntax.rebuild thy) #>
   264   map_consts (fn consts as (local_consts, global_consts) =>
   265     let val thy_consts = Sign.consts_of thy in
   266       if Consts.eq_consts (thy_consts, global_consts) then consts
   267       else (Consts.merge (local_consts, thy_consts), thy_consts)
   268     end);
   269 
   270 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   271 
   272 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   273 
   274 fun theory_result f ctxt =
   275   let val (res, thy') = f (theory_of ctxt)
   276   in (res, ctxt |> transfer thy') end;
   277 
   278 
   279 
   280 (** pretty printing **)
   281 
   282 (* extern *)
   283 
   284 fun extern_fact ctxt name =
   285   let
   286     val local_facts = facts_of ctxt;
   287     val global_facts = PureThy.facts_of (theory_of ctxt);
   288   in
   289     if is_some (Facts.lookup (Context.Proof ctxt) local_facts name)
   290     then Facts.extern local_facts name
   291     else Facts.extern global_facts name
   292   end;
   293 
   294 
   295 (* pretty *)
   296 
   297 fun pretty_term_abbrev ctxt = Syntax.pretty_term (set_mode mode_abbrev ctxt);
   298 
   299 fun pretty_thm_legacy th =
   300   let val thy = Thm.theory_of_thm th
   301   in Display.pretty_thm_aux (Syntax.pp_global thy) true false [] th end;
   302 
   303 fun pretty_thm ctxt th =
   304   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   305   in Display.pretty_thm_aux (Syntax.pp ctxt) false true asms th end;
   306 
   307 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   308   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   309 
   310 fun pretty_fact_name ctxt a = Pretty.block
   311   [Pretty.markup (Markup.fact a) [Pretty.str (extern_fact ctxt a)], Pretty.str ":"];
   312 
   313 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   314   | pretty_fact ctxt (a, [th]) = Pretty.block
   315       [pretty_fact_name ctxt a, Pretty.brk 1, pretty_thm ctxt th]
   316   | pretty_fact ctxt (a, ths) = Pretty.block
   317       (Pretty.fbreaks (pretty_fact_name ctxt a :: map (pretty_thm ctxt) ths));
   318 
   319 val string_of_thm = Pretty.string_of oo pretty_thm;
   320 
   321 
   322 
   323 (** prepare types **)
   324 
   325 (* read_typ *)
   326 
   327 fun read_typ_mode mode ctxt s =
   328   Syntax.read_typ (Type.set_mode mode ctxt) s;
   329 
   330 val read_typ        = read_typ_mode Type.mode_default;
   331 val read_typ_syntax = read_typ_mode Type.mode_syntax;
   332 val read_typ_abbrev = read_typ_mode Type.mode_abbrev;
   333 
   334 
   335 (* cert_typ *)
   336 
   337 fun cert_typ_mode mode ctxt T =
   338   Sign.certify_typ_mode mode (theory_of ctxt) T
   339     handle TYPE (msg, _, _) => error msg;
   340 
   341 val cert_typ        = cert_typ_mode Type.mode_default;
   342 val cert_typ_syntax = cert_typ_mode Type.mode_syntax;
   343 val cert_typ_abbrev = cert_typ_mode Type.mode_abbrev;
   344 
   345 
   346 
   347 (** prepare variables **)
   348 
   349 (* internalize Skolem constants *)
   350 
   351 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   352 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   353 
   354 fun no_skolem internal x =
   355   if can Name.dest_skolem x then
   356     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   357   else if not internal andalso can Name.dest_internal x then
   358     error ("Illegal reference to internal variable: " ^ quote x)
   359   else x;
   360 
   361 
   362 (* revert Skolem constants -- if possible *)
   363 
   364 fun revert_skolem ctxt x =
   365   (case find_first (fn (_, y) => y = x) (Variable.fixes_of ctxt) of
   366     SOME (x', _) => if lookup_skolem ctxt x' = SOME x then x' else x
   367   | NONE => x);
   368 
   369 
   370 (* default token translations *)
   371 
   372 local
   373 
   374 fun free_or_skolem ctxt x =
   375   (if can Name.dest_skolem x then Pretty.mark Markup.skolem (Pretty.str (revert_skolem ctxt x))
   376    else Pretty.mark Markup.free (Pretty.str x))
   377   |> Pretty.mark
   378     (if Variable.is_fixed ctxt x orelse Syntax.is_pretty_global ctxt then Markup.fixed x
   379      else Markup.hilite);
   380 
   381 fun var_or_skolem _ s =
   382   (case Lexicon.read_variable s of
   383     SOME (x, i) =>
   384       (case try Name.dest_skolem x of
   385         NONE => Pretty.mark Markup.var (Pretty.str s)
   386       | SOME x' => Pretty.mark Markup.skolem
   387           (Pretty.str (setmp show_question_marks true Term.string_of_vname (x', i))))
   388   | NONE => Pretty.mark Markup.var (Pretty.str s));
   389 
   390 fun class_markup _ c =    (* FIXME authentic name *)
   391   Pretty.mark (Markup.tclassN, []) (Pretty.str c);
   392 
   393 fun plain_markup m _ s = Pretty.mark m (Pretty.str s);
   394 
   395 val token_trans =
   396  Syntax.tokentrans_mode ""
   397   [("class", class_markup),
   398    ("tfree", plain_markup Markup.tfree),
   399    ("tvar", plain_markup Markup.tvar),
   400    ("free", free_or_skolem),
   401    ("bound", plain_markup Markup.bound),
   402    ("var", var_or_skolem),
   403    ("numeral", plain_markup Markup.numeral),
   404    ("inner_string", plain_markup Markup.inner_string)];
   405 
   406 in val _ = Context.>> (Context.map_theory (Sign.add_tokentrfuns token_trans)) end;
   407 
   408 
   409 
   410 (** prepare terms and propositions **)
   411 
   412 (* inferred types of parameters *)
   413 
   414 fun infer_type ctxt x =
   415   Term.fastype_of (singleton (Syntax.check_terms (set_mode mode_schematic ctxt))
   416     (Free (x, dummyT)));
   417 
   418 fun inferred_param x ctxt =
   419   let val T = infer_type ctxt x
   420   in (T, ctxt |> Variable.declare_term (Free (x, T))) end;
   421 
   422 fun inferred_fixes ctxt =
   423   let
   424     val xs = rev (map #2 (Variable.fixes_of ctxt));
   425     val (Ts, ctxt') = fold_map inferred_param xs ctxt;
   426   in (xs ~~ Ts, ctxt') end;
   427 
   428 
   429 (* type and constant names *)
   430 
   431 local
   432 
   433 val token_content = Syntax.read_token #>> SymbolPos.content;
   434 
   435 fun prep_const_proper ctxt (c, pos) =
   436   let val t as (Const (d, _)) =
   437     (case Variable.lookup_const ctxt c of
   438       SOME d => Const (d, Consts.type_scheme (consts_of ctxt) d handle TYPE (msg, _, _) => error msg)
   439     | NONE => Consts.read_const (consts_of ctxt) c)
   440   in Position.report (Markup.const d) pos; t end;
   441 
   442 in
   443 
   444 fun read_tyname ctxt str =
   445   let
   446     val thy = theory_of ctxt;
   447     val (c, pos) = token_content str;
   448   in
   449     if Syntax.is_tid c then
   450      (Position.report Markup.tfree pos;
   451       TFree (c, the_default (Sign.defaultS thy) (Variable.def_sort ctxt (c, ~1))))
   452     else
   453       let
   454         val d = Sign.intern_type thy c;
   455         val _ = Position.report (Markup.tycon d) pos;
   456       in Type (d, replicate (Sign.arity_number thy d) dummyT) end
   457   end;
   458 
   459 fun read_const_proper ctxt = prep_const_proper ctxt o token_content;
   460 
   461 fun read_const ctxt str =
   462   let val (c, pos) = token_content str in
   463     (case (lookup_skolem ctxt c, Variable.is_const ctxt c) of
   464       (SOME x, false) =>
   465         (Position.report (Markup.name x
   466             (if can Name.dest_skolem x then Markup.skolem else Markup.free)) pos;
   467           Free (x, infer_type ctxt x))
   468     | _ => prep_const_proper ctxt (c, pos))
   469   end;
   470 
   471 end;
   472 
   473 
   474 (* read_term *)
   475 
   476 fun read_term_mode mode ctxt = Syntax.read_term (set_mode mode ctxt);
   477 
   478 val read_term_pattern   = read_term_mode mode_pattern;
   479 val read_term_schematic = read_term_mode mode_schematic;
   480 val read_term_abbrev    = read_term_mode mode_abbrev;
   481 
   482 
   483 (* local abbreviations *)
   484 
   485 val tsig_of = Sign.tsig_of o ProofContext.theory_of;
   486 
   487 local
   488 
   489 fun certify_consts ctxt = Consts.certify (Syntax.pp ctxt) (tsig_of ctxt)
   490   (not (abbrev_mode ctxt)) (consts_of ctxt);
   491 
   492 fun reject_schematic (Var (xi, _)) =
   493       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   494   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   495   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   496   | reject_schematic _ = ();
   497 
   498 fun expand_binds ctxt =
   499   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   500     if pattern then I
   501     else Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic)
   502   end;
   503 
   504 in
   505 
   506 fun expand_abbrevs ctxt = certify_consts ctxt #> expand_binds ctxt;
   507 
   508 end;
   509 
   510 
   511 fun contract_abbrevs ctxt t =
   512   let
   513     val thy = theory_of ctxt;
   514     val consts = consts_of ctxt;
   515     val Mode {abbrev, ...} = get_mode ctxt;
   516   in
   517     if abbrev orelse print_mode_active "no_abbrevs" orelse not (can Term.type_of t) then t
   518     else t |> Pattern.rewrite_term thy (Consts.abbrevs_of consts (print_mode_value () @ [""])) []
   519   end;
   520 
   521 
   522 (* patterns *)
   523 
   524 fun prepare_patternT ctxt =
   525   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   526     if pattern orelse schematic then I
   527     else Term.map_atyps
   528       (fn T as TVar (xi, _) =>
   529             if not (TypeInfer.is_param xi)
   530             then error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   531             else T
   532         | T => T)
   533   end;
   534 
   535 
   536 local
   537 
   538 structure AllowDummies = ProofDataFun(type T = bool fun init _ = false);
   539 
   540 fun check_dummies ctxt t =
   541   if AllowDummies.get ctxt then t
   542   else Term.no_dummy_patterns t handle TERM _ => error "Illegal dummy pattern(s) in term";
   543 
   544 fun prepare_dummies ts = #1 (fold_map Term.replace_dummy_patterns ts 1);
   545 
   546 in
   547 
   548 val allow_dummies = AllowDummies.put true;
   549 
   550 fun prepare_patterns ctxt =
   551   let val Mode {pattern, ...} = get_mode ctxt in
   552     TypeInfer.fixate_params (Variable.names_of ctxt) #>
   553     pattern ? Variable.polymorphic ctxt #>
   554     (map o Term.map_types) (prepare_patternT ctxt) #>
   555     (if pattern then prepare_dummies else map (check_dummies ctxt))
   556   end;
   557 
   558 end;
   559 
   560 
   561 (* decoding raw terms (syntax trees) *)
   562 
   563 (* types *)
   564 
   565 fun get_sort thy def_sort raw_env =
   566   let
   567     val tsig = Sign.tsig_of thy;
   568 
   569     fun eq ((xi, S), (xi', S')) =
   570       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   571     val env = distinct eq raw_env;
   572     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   573       | dups => error ("Inconsistent sort constraints for type variable(s) "
   574           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   575 
   576     fun get xi =
   577       (case (AList.lookup (op =) env xi, def_sort xi) of
   578         (NONE, NONE) => Type.defaultS tsig
   579       | (NONE, SOME S) => S
   580       | (SOME S, NONE) => S
   581       | (SOME S, SOME S') =>
   582           if Type.eq_sort tsig (S, S') then S'
   583           else error ("Sort constraint inconsistent with default for type variable " ^
   584             quote (Term.string_of_vname' xi)));
   585   in get end;
   586 
   587 local
   588 
   589 fun intern_skolem ctxt def_type x =
   590   let
   591     val _ = no_skolem false x;
   592     val sko = lookup_skolem ctxt x;
   593     val is_const = can (read_const_proper ctxt) x orelse Long_Name.is_qualified x;
   594     val is_declared = is_some (def_type (x, ~1));
   595   in
   596     if Variable.is_const ctxt x then NONE
   597     else if is_some sko then sko
   598     else if not is_const orelse is_declared then SOME x
   599     else NONE
   600   end;
   601 
   602 in
   603 
   604 fun term_context ctxt =
   605   let val thy = theory_of ctxt in
   606    {get_sort = get_sort thy (Variable.def_sort ctxt),
   607     map_const = fn a => ((true, #1 (Term.dest_Const (read_const_proper ctxt a)))
   608       handle ERROR _ => (false, Consts.intern (consts_of ctxt) a)),
   609     map_free = intern_skolem ctxt (Variable.def_type ctxt false),
   610     map_type = Sign.intern_tycons thy,
   611     map_sort = Sign.intern_sort thy}
   612   end;
   613 
   614 fun decode_term ctxt =
   615   let val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt
   616   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   617 
   618 end;
   619 
   620 
   621 (* certify terms *)
   622 
   623 local
   624 
   625 fun gen_cert prop ctxt t =
   626   t
   627   |> expand_abbrevs ctxt
   628   |> (fn t' => #1 (Sign.certify' prop (Syntax.pp ctxt) false (consts_of ctxt) (theory_of ctxt) t')
   629     handle TYPE (msg, _, _) => error msg
   630       | TERM (msg, _) => error msg);
   631 
   632 in
   633 
   634 val cert_term = gen_cert false;
   635 val cert_prop = gen_cert true;
   636 
   637 end;
   638 
   639 
   640 (* type checking/inference *)
   641 
   642 fun standard_infer_types ctxt ts =
   643   let val Mode {pattern, ...} = get_mode ctxt in
   644     TypeInfer.infer_types (Syntax.pp ctxt) (tsig_of ctxt) (Syntax.check_typs ctxt)
   645       (try (Consts.the_constraint (consts_of ctxt))) (Variable.def_type ctxt pattern)
   646       (Variable.names_of ctxt) (Variable.maxidx_of ctxt) ts
   647     handle TYPE (msg, _, _) => error msg
   648   end;
   649 
   650 local
   651 
   652 fun standard_typ_check ctxt =
   653   map (cert_typ_mode (Type.get_mode ctxt) ctxt) #>
   654   map (prepare_patternT ctxt);
   655 
   656 fun standard_term_check ctxt =
   657   standard_infer_types ctxt #>
   658   map (expand_abbrevs ctxt);
   659 
   660 fun standard_term_uncheck ctxt =
   661   map (contract_abbrevs ctxt);
   662 
   663 fun add eq what f = Context.>> (what (fn xs => fn ctxt =>
   664   let val xs' = f ctxt xs in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end));
   665 
   666 in
   667 
   668 val _ = add (op =) (Syntax.add_typ_check 0 "standard") standard_typ_check;
   669 val _ = add (op aconv) (Syntax.add_term_check 0 "standard") standard_term_check;
   670 val _ = add (op aconv) (Syntax.add_term_check 100 "fixate") prepare_patterns;
   671 
   672 val _ = add (op aconv) (Syntax.add_term_uncheck 0 "standard") standard_term_uncheck;
   673 
   674 end;
   675 
   676 
   677 
   678 (** inner syntax operations **)
   679 
   680 local
   681 
   682 fun parse_sort ctxt text =
   683   let
   684     val (syms, pos) = Syntax.parse_token Markup.sort text;
   685     val S = Syntax.standard_parse_sort ctxt (syn_of ctxt)
   686         (Sign.intern_sort (theory_of ctxt)) (syms, pos)
   687       handle ERROR msg => cat_error msg  ("Failed to parse sort" ^ Position.str_of pos)
   688   in S end;
   689 
   690 fun parse_typ ctxt text =
   691   let
   692     val thy = ProofContext.theory_of ctxt;
   693     val get_sort = get_sort thy (Variable.def_sort ctxt);
   694 
   695     val (syms, pos) = Syntax.parse_token Markup.typ text;
   696     val T = Sign.intern_tycons thy
   697         (Syntax.standard_parse_typ ctxt (syn_of ctxt) get_sort (Sign.intern_sort thy) (syms, pos))
   698       handle ERROR msg => cat_error msg  ("Failed to parse type" ^ Position.str_of pos);
   699   in T end;
   700 
   701 fun parse_term T ctxt text =
   702   let
   703     val thy = theory_of ctxt;
   704     val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt;
   705 
   706     val (T', _) = TypeInfer.paramify_dummies T 0;
   707     val (markup, kind) = if T' = propT then (Markup.prop, "proposition") else (Markup.term, "term");
   708     val (syms, pos) = Syntax.parse_token markup text;
   709 
   710     fun check t = (Syntax.check_term ctxt (TypeInfer.constrain T' t); NONE)
   711       handle ERROR msg => SOME msg;
   712     val t = Syntax.standard_parse_term (Syntax.pp ctxt) check get_sort map_const map_free
   713         map_type map_sort ctxt (Sign.is_logtype thy) (syn_of ctxt) T' (syms, pos)
   714       handle ERROR msg => cat_error msg  ("Failed to parse " ^ kind ^ Position.str_of pos);
   715   in t end;
   716 
   717 
   718 fun unparse_sort ctxt S =
   719   Syntax.standard_unparse_sort ctxt (syn_of ctxt) (Sign.extern_sort (theory_of ctxt) S);
   720 
   721 fun unparse_typ ctxt T =
   722   Syntax.standard_unparse_typ ctxt (syn_of ctxt) (Sign.extern_typ (theory_of ctxt) T);
   723 
   724 fun unparse_term ctxt t =
   725   let
   726     val thy = theory_of ctxt;
   727     val syntax = syntax_of ctxt;
   728     val consts = consts_of ctxt;
   729   in
   730     t
   731     |> Sign.extern_term (Consts.extern_early consts) thy
   732     |> LocalSyntax.extern_term syntax
   733     |> Syntax.standard_unparse_term (Consts.extern consts) ctxt (LocalSyntax.syn_of syntax)
   734         (not (PureThy.old_appl_syntax thy))
   735   end;
   736 
   737 in
   738 
   739 val _ = Syntax.install_operations
   740   {parse_sort = parse_sort,
   741    parse_typ = parse_typ,
   742    parse_term = parse_term dummyT,
   743    parse_prop = parse_term propT,
   744    unparse_sort = unparse_sort,
   745    unparse_typ = unparse_typ,
   746    unparse_term = unparse_term};
   747 
   748 end;
   749 
   750 
   751 
   752 (** export results **)
   753 
   754 fun common_export is_goal inner outer =
   755   map (Assumption.export is_goal inner outer) #>
   756   Variable.export inner outer;
   757 
   758 val goal_export = common_export true;
   759 val export = common_export false;
   760 
   761 fun export_morphism inner outer =
   762   Assumption.export_morphism inner outer $>
   763   Variable.export_morphism inner outer;
   764 
   765 fun norm_export_morphism inner outer =
   766   export_morphism inner outer $>
   767   Morphism.thm_morphism Goal.norm_result;
   768 
   769 
   770 
   771 (** bindings **)
   772 
   773 (* simult_matches *)
   774 
   775 fun simult_matches ctxt (t, pats) =
   776   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   777     NONE => error "Pattern match failed!"
   778   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   779 
   780 
   781 (* add_binds(_i) *)
   782 
   783 local
   784 
   785 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   786   ctxt
   787   |> Variable.add_binds [(xi, Option.map (prep (set_mode mode_default ctxt)) raw_t)];
   788 
   789 in
   790 
   791 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   792   | drop_schematic b = b;
   793 
   794 val add_binds = fold (gen_bind Syntax.read_term);
   795 val add_binds_i = fold (gen_bind cert_term);
   796 
   797 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   798 val auto_bind_goal = auto_bind AutoBind.goal;
   799 val auto_bind_facts = auto_bind AutoBind.facts;
   800 
   801 end;
   802 
   803 
   804 (* match_bind(_i) *)
   805 
   806 local
   807 
   808 fun gen_bind prep_terms gen raw_binds ctxt =
   809   let
   810     fun prep_bind (raw_pats, t) ctxt1 =
   811       let
   812         val T = Term.fastype_of t;
   813         val ctxt2 = Variable.declare_term t ctxt1;
   814         val pats = prep_terms (set_mode mode_pattern ctxt2) T raw_pats;
   815         val binds = simult_matches ctxt2 (t, pats);
   816       in (binds, ctxt2) end;
   817 
   818     val ts = prep_terms ctxt dummyT (map snd raw_binds);
   819     val (binds, ctxt') = apfst flat (fold_map prep_bind (map fst raw_binds ~~ ts) ctxt);
   820     val binds' =
   821       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   822       else binds;
   823     val binds'' = map (apsnd SOME) binds';
   824     val ctxt'' =
   825       tap (Variable.warn_extra_tfrees ctxt)
   826        (if gen then
   827           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   828         else ctxt' |> add_binds_i binds'');
   829   in (ts, ctxt'') end;
   830 
   831 in
   832 
   833 fun read_terms ctxt T =
   834   map (Syntax.parse_term ctxt #> TypeInfer.constrain T) #> Syntax.check_terms ctxt;
   835 
   836 val match_bind = gen_bind read_terms;
   837 val match_bind_i = gen_bind (fn ctxt => fn _ => map (cert_term ctxt));
   838 
   839 end;
   840 
   841 
   842 (* propositions with patterns *)
   843 
   844 local
   845 
   846 fun prep_propp mode prep_props (context, args) =
   847   let
   848     fun prep (_, raw_pats) (ctxt, prop :: props) =
   849       let val ctxt' = Variable.declare_term prop ctxt
   850       in ((prop, prep_props (set_mode mode_pattern ctxt') raw_pats), (ctxt', props)) end;
   851 
   852     val (propp, (context', _)) = (fold_map o fold_map) prep args
   853       (context, prep_props (set_mode mode context) (maps (map fst) args));
   854   in (context', propp) end;
   855 
   856 fun gen_bind_propp mode parse_prop (ctxt, raw_args) =
   857   let
   858     val (ctxt', args) = prep_propp mode parse_prop (ctxt, raw_args);
   859     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   860     val propss = map (map #1) args;
   861 
   862     (*generalize result: context evaluated now, binds added later*)
   863     val gen = Variable.exportT_terms ctxt' ctxt;
   864     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   865   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   866 
   867 in
   868 
   869 val read_propp           = prep_propp mode_default Syntax.read_props;
   870 val cert_propp           = prep_propp mode_default (map o cert_prop);
   871 val read_propp_schematic = prep_propp mode_schematic Syntax.read_props;
   872 val cert_propp_schematic = prep_propp mode_schematic (map o cert_prop);
   873 
   874 val bind_propp             = gen_bind_propp mode_default Syntax.read_props;
   875 val bind_propp_i           = gen_bind_propp mode_default (map o cert_prop);
   876 val bind_propp_schematic   = gen_bind_propp mode_schematic Syntax.read_props;
   877 val bind_propp_schematic_i = gen_bind_propp mode_schematic (map o cert_prop);
   878 
   879 end;
   880 
   881 
   882 
   883 (** theorems **)
   884 
   885 (* fact_tac *)
   886 
   887 fun comp_incr_tac [] _ = no_tac
   888   | comp_incr_tac (th :: ths) i =
   889       (fn st => Goal.compose_hhf_tac (Drule.incr_indexes st th) i st) APPEND comp_incr_tac ths i;
   890 
   891 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   892 
   893 fun potential_facts ctxt prop =
   894   Facts.could_unify (facts_of ctxt) (Term.strip_all_body prop);
   895 
   896 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) => fact_tac (potential_facts ctxt goal) i);
   897 
   898 
   899 (* get_thm(s) *)
   900 
   901 local
   902 
   903 fun retrieve_thms pick ctxt (Facts.Fact s) =
   904       let
   905         val (_, pos) = Syntax.read_token s;
   906         val prop = Syntax.read_prop (set_mode mode_default ctxt) s
   907           |> singleton (Variable.polymorphic ctxt);
   908 
   909         fun prove_fact th =
   910           Goal.prove ctxt [] [] prop (K (ALLGOALS (fact_tac [th])))
   911           |> Thm.default_position_of th;
   912         val res =
   913           (case get_first (try prove_fact) (potential_facts ctxt prop) of
   914             SOME res => res
   915           | NONE => error ("Failed to retrieve literal fact" ^ Position.str_of pos ^ ":\n" ^
   916               Syntax.string_of_term ctxt prop))
   917       in pick "" [res] end
   918   | retrieve_thms pick ctxt xthmref =
   919       let
   920         val thy = theory_of ctxt;
   921         val local_facts = facts_of ctxt;
   922         val thmref = Facts.map_name_of_ref (Facts.intern local_facts) xthmref;
   923         val name = Facts.name_of_ref thmref;
   924         val pos = Facts.pos_of_ref xthmref;
   925         val thms =
   926           if name = "" then [Thm.transfer thy Drule.dummy_thm]
   927           else
   928             (case Facts.lookup (Context.Proof ctxt) local_facts name of
   929               SOME (_, ths) => (Position.report (Markup.local_fact name) pos;
   930                 map (Thm.transfer thy) (Facts.select thmref ths))
   931             | NONE => PureThy.get_fact (Context.Proof ctxt) thy xthmref);
   932       in pick name thms end;
   933 
   934 in
   935 
   936 val get_fact = retrieve_thms (K I);
   937 val get_fact_single = retrieve_thms Facts.the_single;
   938 
   939 fun get_thms ctxt = get_fact ctxt o Facts.named;
   940 fun get_thm ctxt = get_fact_single ctxt o Facts.named;
   941 
   942 end;
   943 
   944 
   945 (* name space operations *)
   946 
   947 val add_path        = map_naming o NameSpace.add_path;
   948 val mandatory_path  = map_naming o NameSpace.mandatory_path;
   949 val restore_naming  = map_naming o K o naming_of;
   950 val reset_naming    = map_naming (K local_naming);
   951 
   952 
   953 (* facts *)
   954 
   955 local
   956 
   957 fun update_thms _ (b, NONE) ctxt = ctxt |> map_facts (Facts.del (full_name ctxt b))
   958   | update_thms do_props (b, SOME ths) ctxt = ctxt |> map_facts
   959       (Facts.add_local do_props (naming_of ctxt) (b, ths) #> snd);
   960 
   961 fun gen_note_thmss get k = fold_map (fn ((b, more_attrs), raw_facts) => fn ctxt =>
   962   let
   963     val pos = Binding.pos_of b;
   964     val name = full_name ctxt b;
   965     val _ = ContextPosition.report_visible ctxt (Markup.local_fact_decl name) pos;
   966 
   967     val facts = PureThy.name_thmss false pos name (map (apfst (get ctxt)) raw_facts);
   968     fun app (th, attrs) x =
   969       swap (Library.foldl_map (Thm.proof_attributes (surround (Thm.kind k) (attrs @ more_attrs))) (x, th));
   970     val (res, ctxt') = fold_map app facts ctxt;
   971     val thms = PureThy.name_thms false false pos name (flat res);
   972     val Mode {stmt, ...} = get_mode ctxt;
   973   in ((name, thms), ctxt' |> update_thms stmt (b, SOME thms)) end);
   974 
   975 in
   976 
   977 fun note_thmss k = gen_note_thmss get_fact k;
   978 fun note_thmss_i k = gen_note_thmss (K I) k;
   979 
   980 fun put_thms do_props thms ctxt = ctxt
   981   |> map_naming (K local_naming)
   982   |> ContextPosition.set_visible false
   983   |> update_thms do_props (apfst Binding.name thms)
   984   |> ContextPosition.restore_visible ctxt
   985   |> restore_naming ctxt;
   986 
   987 end;
   988 
   989 
   990 
   991 (** parameters **)
   992 
   993 (* variables *)
   994 
   995 fun declare_var (x, opt_T, mx) ctxt =
   996   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
   997   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
   998 
   999 local
  1000 
  1001 fun prep_vars prep_typ internal =
  1002   fold_map (fn (raw_b, raw_T, raw_mx) => fn ctxt =>
  1003     let
  1004       val raw_x = Binding.name_of raw_b;
  1005       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
  1006       val _ = Syntax.is_identifier (no_skolem internal x) orelse
  1007         error ("Illegal variable name: " ^ quote x);
  1008 
  1009       fun cond_tvars T =
  1010         if internal then T
  1011         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
  1012       val opt_T = Option.map (cond_tvars o cert_typ ctxt o prep_typ ctxt) raw_T;
  1013       val var = (Binding.map_name (K x) raw_b, opt_T, mx);
  1014     in (var, ctxt |> declare_var (x, opt_T, mx) |> #2) end);
  1015 
  1016 in
  1017 
  1018 val read_vars = prep_vars Syntax.parse_typ false;
  1019 val cert_vars = prep_vars (K I) true;
  1020 
  1021 end;
  1022 
  1023 
  1024 (* authentic constants *)
  1025 
  1026 local
  1027 
  1028 fun const_ast_tr intern ctxt [Syntax.Variable c] =
  1029       let
  1030         val Const (c', _) = read_const_proper ctxt c;
  1031         val d = if intern then const_syntax_name ctxt c' else c;
  1032       in Syntax.Constant d end
  1033   | const_ast_tr _ _ asts = raise Syntax.AST ("const_ast_tr", asts);
  1034 
  1035 in
  1036 
  1037 val _ = Context.>> (Context.map_theory
  1038  (Sign.add_syntax
  1039    [("_context_const", "id => logic", Delimfix "CONST _"),
  1040     ("_context_const", "id => aprop", Delimfix "CONST _"),
  1041     ("_context_const", "longid => logic", Delimfix "CONST _"),
  1042     ("_context_const", "longid => aprop", Delimfix "CONST _"),
  1043     ("_context_xconst", "id => logic", Delimfix "XCONST _"),
  1044     ("_context_xconst", "id => aprop", Delimfix "XCONST _"),
  1045     ("_context_xconst", "longid => logic", Delimfix "XCONST _"),
  1046     ("_context_xconst", "longid => aprop", Delimfix "XCONST _")] #>
  1047   Sign.add_advanced_trfuns
  1048     ([("_context_const", const_ast_tr true), ("_context_xconst", const_ast_tr false)], [], [], [])));
  1049 
  1050 end;
  1051 
  1052 
  1053 (* notation *)
  1054 
  1055 local
  1056 
  1057 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
  1058   | const_syntax ctxt (Const (c, _), mx) =
  1059       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
  1060   | const_syntax _ _ = NONE;
  1061 
  1062 in
  1063 
  1064 fun notation add mode args ctxt =
  1065   ctxt |> map_syntax
  1066     (LocalSyntax.update_modesyntax (theory_of ctxt) add mode (map_filter (const_syntax ctxt) args));
  1067 
  1068 fun target_notation add mode args phi =
  1069   let val args' = filter (fn (t, _) => Type.similar_types (t, Morphism.term phi t)) args;
  1070   in Context.mapping (Sign.notation add mode args') (notation add mode args') end;
  1071 
  1072 end;
  1073 
  1074 
  1075 (* local constants *)
  1076 
  1077 fun add_const_constraint (c, opt_T) ctxt =
  1078   let
  1079     fun prepT raw_T =
  1080       let val T = cert_typ ctxt raw_T
  1081       in cert_term ctxt (Const (c, T)); T end;
  1082   in ctxt |> (map_consts o apfst) (Consts.constrain (c, Option.map prepT opt_T)) end;
  1083 
  1084 fun add_abbrev mode tags (b, raw_t) ctxt =
  1085   let
  1086     val t0 = cert_term (ctxt |> set_mode mode_abbrev) raw_t
  1087       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
  1088     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
  1089     val ((lhs, rhs), consts') = consts_of ctxt
  1090       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode tags (b, t);
  1091   in
  1092     ctxt
  1093     |> (map_consts o apfst) (K consts')
  1094     |> Variable.declare_term rhs
  1095     |> pair (lhs, rhs)
  1096   end;
  1097 
  1098 fun revert_abbrev mode c = (map_consts o apfst) (Consts.revert_abbrev mode c);
  1099 
  1100 
  1101 (* fixes *)
  1102 
  1103 local
  1104 
  1105 fun prep_mixfix (x, T, mx) =
  1106   if mx <> NoSyn andalso mx <> Structure andalso
  1107       (can Name.dest_internal x orelse can Name.dest_skolem x) then
  1108     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
  1109   else (true, (x, T, mx));
  1110 
  1111 fun gen_fixes prep raw_vars ctxt =
  1112   let
  1113     val (vars, _) = prep raw_vars ctxt;
  1114     val (xs', ctxt') = Variable.add_fixes (map (Binding.name_of o #1) vars) ctxt;
  1115     val ctxt'' =
  1116       ctxt'
  1117       |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
  1118       |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix);
  1119     val _ = (vars ~~ xs') |> List.app (fn ((b, _, _), x') =>
  1120       ContextPosition.report_visible ctxt (Markup.fixed_decl x') (Binding.pos_of b));
  1121   in (xs', ctxt'') end;
  1122 
  1123 in
  1124 
  1125 val add_fixes = gen_fixes read_vars;
  1126 val add_fixes_i = gen_fixes cert_vars;
  1127 
  1128 end;
  1129 
  1130 
  1131 (* fixes vs. frees *)
  1132 
  1133 fun auto_fixes (arg as (ctxt, (propss, x))) =
  1134   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
  1135 
  1136 fun bind_fixes xs ctxt =
  1137   let
  1138     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (Binding.name x, NONE, NoSyn)) xs);
  1139     fun bind (t as Free (x, T)) =
  1140           if member (op =) xs x then
  1141             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1142           else t
  1143       | bind (t $ u) = bind t $ bind u
  1144       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1145       | bind a = a;
  1146   in (bind, ctxt') end;
  1147 
  1148 
  1149 
  1150 (** assumptions **)
  1151 
  1152 local
  1153 
  1154 fun gen_assms prepp exp args ctxt =
  1155   let
  1156     val cert = Thm.cterm_of (theory_of ctxt);
  1157     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1158     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1159     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1160   in
  1161     ctxt2
  1162     |> auto_bind_facts (flat propss)
  1163     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1164   end;
  1165 
  1166 in
  1167 
  1168 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1169 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1170 
  1171 end;
  1172 
  1173 
  1174 
  1175 (** cases **)
  1176 
  1177 local
  1178 
  1179 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1180 
  1181 fun add_case _ ("", _) cases = cases
  1182   | add_case _ (name, NONE) cases = rem_case name cases
  1183   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1184 
  1185 fun prep_case name fxs c =
  1186   let
  1187     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1188       | replace [] ys = ys
  1189       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1190     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1191     val fixes' = replace fxs fixes;
  1192     val binds' = map drop_schematic binds;
  1193   in
  1194     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1195       null (fold (fold Term.add_vars o snd) assumes []) then
  1196         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1197     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1198   end;
  1199 
  1200 fun fix (x, T) ctxt =
  1201   let
  1202     val (bind, ctxt') = bind_fixes [x] ctxt;
  1203     val t = bind (Free (x, T));
  1204   in (t, ctxt' |> Variable.declare_constraints t) end;
  1205 
  1206 in
  1207 
  1208 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1209 
  1210 fun case_result c ctxt =
  1211   let
  1212     val RuleCases.Case {fixes, ...} = c;
  1213     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1214     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1215   in
  1216     ctxt'
  1217     |> add_binds_i (map drop_schematic binds)
  1218     |> add_cases true (map (apsnd SOME) cases)
  1219     |> pair (assumes, (binds, cases))
  1220   end;
  1221 
  1222 val apply_case = apfst fst oo case_result;
  1223 
  1224 fun get_case ctxt name xs =
  1225   (case AList.lookup (op =) (cases_of ctxt) name of
  1226     NONE => error ("Unknown case: " ^ quote name)
  1227   | SOME (c, _) => prep_case name xs c);
  1228 
  1229 end;
  1230 
  1231 
  1232 
  1233 (** print context information **)
  1234 
  1235 val debug = ref false;
  1236 
  1237 val verbose = ref false;
  1238 fun verb f x = if ! verbose then f (x ()) else [];
  1239 
  1240 fun setmp_verbose f x = Library.setmp verbose true f x;
  1241 
  1242 
  1243 (* local syntax *)
  1244 
  1245 val print_syntax = Syntax.print_syntax o syn_of;
  1246 
  1247 
  1248 (* abbreviations *)
  1249 
  1250 fun pretty_abbrevs show_globals ctxt =
  1251   let
  1252     val ((space, consts), (_, globals)) =
  1253       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1254     fun add_abbr (_, (_, NONE)) = I
  1255       | add_abbr (c, (T, SOME t)) =
  1256           if not show_globals andalso Symtab.defined globals c then I
  1257           else cons (c, Logic.mk_equals (Const (c, T), t));
  1258     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1259   in
  1260     if null abbrevs andalso not (! verbose) then []
  1261     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1262   end;
  1263 
  1264 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1265 
  1266 
  1267 (* term bindings *)
  1268 
  1269 fun pretty_binds ctxt =
  1270   let
  1271     val binds = Variable.binds_of ctxt;
  1272     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1273   in
  1274     if Vartab.is_empty binds andalso not (! verbose) then []
  1275     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1276   end;
  1277 
  1278 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1279 
  1280 
  1281 (* local theorems *)
  1282 
  1283 fun pretty_lthms ctxt =
  1284   let
  1285     val local_facts = facts_of ctxt;
  1286     val props = Facts.props local_facts;
  1287     val facts =
  1288       (if null props then [] else [("unnamed", props)]) @
  1289       Facts.dest_static [] local_facts;
  1290   in
  1291     if null facts andalso not (! verbose) then []
  1292     else [Pretty.big_list "facts:" (map #1 (sort_wrt (#1 o #2) (map (`(pretty_fact ctxt)) facts)))]
  1293   end;
  1294 
  1295 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1296 
  1297 
  1298 (* local contexts *)
  1299 
  1300 local
  1301 
  1302 fun pretty_case (name, (fixes, ((asms, (lets, cs)), ctxt))) =
  1303   let
  1304     val prt_term = Syntax.pretty_term ctxt;
  1305 
  1306     fun prt_let (xi, t) = Pretty.block
  1307       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1308         Pretty.quote (prt_term t)];
  1309 
  1310     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1311       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1312 
  1313     fun prt_sect _ _ _ [] = []
  1314       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1315             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1316   in
  1317     Pretty.block (Pretty.fbreaks
  1318       (Pretty.str (name ^ ":") ::
  1319         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1320         prt_sect "let" [Pretty.str "and"] prt_let
  1321           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1322         (if forall (null o #2) asms then []
  1323           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1324         prt_sect "subcases:" [] (Pretty.str o fst) cs))
  1325   end;
  1326 
  1327 in
  1328 
  1329 fun pretty_cases ctxt =
  1330   let
  1331     fun add_case (_, (_, false)) = I
  1332       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1333           cons (name, (fixes, case_result c ctxt));
  1334     val cases = fold add_case (cases_of ctxt) [];
  1335   in
  1336     if null cases andalso not (! verbose) then []
  1337     else [Pretty.big_list "cases:" (map pretty_case cases)]
  1338   end;
  1339 
  1340 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1341 
  1342 end;
  1343 
  1344 
  1345 (* core context *)
  1346 
  1347 val prems_limit = ref ~1;
  1348 
  1349 fun pretty_ctxt ctxt =
  1350   if ! prems_limit < 0 andalso not (! debug) then []
  1351   else
  1352     let
  1353       val prt_term = Syntax.pretty_term ctxt;
  1354 
  1355       (*structures*)
  1356       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1357       val prt_structs = if null structs then []
  1358         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1359           Pretty.commas (map Pretty.str structs))];
  1360 
  1361       (*fixes*)
  1362       fun prt_fix (x, x') =
  1363         if x = x' then Pretty.str x
  1364         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1365       val fixes =
  1366         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1367           (Variable.fixes_of ctxt));
  1368       val prt_fixes = if null fixes then []
  1369         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1370           Pretty.commas (map prt_fix fixes))];
  1371 
  1372       (*prems*)
  1373       val prems = Assumption.prems_of ctxt;
  1374       val len = length prems;
  1375       val suppressed = len - ! prems_limit;
  1376       val prt_prems = if null prems then []
  1377         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1378           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1379     in prt_structs @ prt_fixes @ prt_prems end;
  1380 
  1381 
  1382 (* main context *)
  1383 
  1384 fun pretty_context ctxt =
  1385   let
  1386     val prt_term = Syntax.pretty_term ctxt;
  1387     val prt_typ = Syntax.pretty_typ ctxt;
  1388     val prt_sort = Syntax.pretty_sort ctxt;
  1389 
  1390     (*theory*)
  1391     val pretty_thy = Pretty.block
  1392       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1393 
  1394     (*defaults*)
  1395     fun prt_atom prt prtT (x, X) = Pretty.block
  1396       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1397 
  1398     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1399       | prt_var xi = prt_term (Syntax.var xi);
  1400 
  1401     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1402       | prt_varT xi = prt_typ (TVar (xi, []));
  1403 
  1404     val prt_defT = prt_atom prt_var prt_typ;
  1405     val prt_defS = prt_atom prt_varT prt_sort;
  1406 
  1407     val (types, sorts) = Variable.constraints_of ctxt;
  1408   in
  1409     verb single (K pretty_thy) @
  1410     pretty_ctxt ctxt @
  1411     verb (pretty_abbrevs false) (K ctxt) @
  1412     verb pretty_binds (K ctxt) @
  1413     verb pretty_lthms (K ctxt) @
  1414     verb pretty_cases (K ctxt) @
  1415     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1416     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1417   end;
  1418 
  1419 
  1420 (* query meta data *)
  1421 
  1422 val query_type = Type.the_tags o tsig_of;
  1423 
  1424 fun query_const ctxt name =
  1425   Consts.the_tags (consts_of ctxt) name handle TYPE (msg, _, _) => error msg;
  1426 
  1427 fun query_class ctxt name = query_const ctxt (Logic.const_of_class name);
  1428 
  1429 end;