src/Pure/Tools/build.ML
author wenzelm
Thu Jun 27 23:17:26 2013 +0200 (2013-06-27 ago)
changeset 52470 dedd7952a62c
parent 52104 250cd2a9308d
child 52487 48bc24467008
permissions -rw-r--r--
manage option "proofs" within theory context -- with minor overhead for primitive inferences;
     1 (*  Title:      Pure/Tools/build.ML
     2     Author:     Makarius
     3 
     4 Build Isabelle sessions.
     5 *)
     6 
     7 signature BUILD =
     8 sig
     9   val build: string -> unit
    10 end;
    11 
    12 structure Build: BUILD =
    13 struct
    14 
    15 (* command timings *)
    16 
    17 type timings = ((string * Time.time) Inttab.table) Symtab.table;  (*file -> offset -> name * time *)
    18 
    19 val empty_timings: timings = Symtab.empty;
    20 
    21 fun update_timings props =
    22   (case Markup.parse_command_timing_properties props of
    23     SOME ({file, offset, name}, time) =>
    24       Symtab.map_default (file, Inttab.empty)
    25         (Inttab.map_default (offset, (name, time)) (fn (_, t) => (name, Time.+ (t, time))))
    26   | NONE => I);
    27 
    28 fun approximative_id name pos =
    29   (case (Position.file_of pos, Position.offset_of pos) of
    30     (SOME file, SOME offset) =>
    31       if name = "" then NONE else SOME {file = file, offset = offset, name = name}
    32   | _ => NONE);
    33 
    34 fun lookup_timings timings tr =
    35   (case approximative_id (Toplevel.name_of tr) (Toplevel.pos_of tr) of
    36     SOME {file, offset, name} =>
    37       (case Symtab.lookup timings file of
    38         SOME offsets =>
    39           (case Inttab.lookup offsets offset of
    40             SOME (name', time) => if name = name' then SOME time else NONE
    41           | NONE => NONE)
    42       | NONE => NONE)
    43   | NONE => NONE);
    44 
    45 
    46 (* session timing *)
    47 
    48 fun session_timing name verbose f x =
    49   let
    50     val start = Timing.start ();
    51     val y = f x;
    52     val timing = Timing.result start;
    53 
    54     val threads = string_of_int (Multithreading.max_threads_value ());
    55     val factor = Time.toReal (#cpu timing) / Time.toReal (#elapsed timing)
    56       |> Real.fmt (StringCvt.FIX (SOME 2));
    57 
    58     val timing_props =
    59       [("threads", threads)] @ Markup.timing_properties timing @ [("factor", factor)];
    60     val _ = writeln ("\fTiming = " ^ YXML.string_of_body (XML.Encode.properties timing_props));
    61     val _ =
    62       if verbose then
    63         Output.physical_stderr ("Timing " ^ name ^ " (" ^
    64           threads ^ " threads, " ^ Timing.message timing ^ ", factor " ^ factor ^ ")\n")
    65       else ();
    66   in y end;
    67 
    68 
    69 (* protocol messages *)
    70 
    71 fun inline_message a args =
    72   writeln ("\f" ^ a ^ " = " ^ YXML.string_of_body (XML.Encode.properties args));
    73 
    74 fun protocol_message props output =
    75   (case props of
    76     function :: args =>
    77       if function = Markup.ML_statistics orelse function = Markup.task_statistics then
    78         inline_message (#2 function) args
    79       else if function = Markup.command_timing then
    80         let
    81           val name = the_default "" (Properties.get args Markup.nameN);
    82           val pos = Position.of_properties args;
    83           val {elapsed, ...} = Markup.parse_timing_properties args;
    84         in
    85           (case approximative_id name pos of
    86             SOME id => inline_message (#2 function) (Markup.command_timing_properties id elapsed)
    87           | NONE => ())
    88         end
    89       else
    90         (case Markup.dest_loading_theory props of
    91           SOME name => writeln ("\floading_theory = " ^ name)
    92         | NONE => raise Output.Protocol_Message props)
    93   | [] => raise Output.Protocol_Message props);
    94 
    95 
    96 (* build *)
    97 
    98 local
    99 
   100 fun no_document options =
   101   (case Options.string options "document" of "" => true | "false" => true | _ => false);
   102 
   103 fun use_theories last_timing options =
   104   Thy_Info.use_theories {last_timing = last_timing, master_dir = Path.current}
   105     |> Unsynchronized.setmp print_mode
   106         (space_explode "," (Options.string options "print_mode") @ print_mode_value ())
   107     |> Unsynchronized.setmp Goal.parallel_proofs (Options.int options "parallel_proofs")
   108     |> Unsynchronized.setmp Multithreading.trace (Options.int options "threads_trace")
   109     |> Unsynchronized.setmp Multithreading.max_threads (Options.int options "threads")
   110     |> Unsynchronized.setmp Future.ML_statistics true
   111     |> no_document options ? Present.no_document
   112     |> Unsynchronized.setmp Goal.skip_proofs (Options.bool options "skip_proofs")
   113     |> Unsynchronized.setmp Pretty.margin_default (Options.int options "pretty_margin")
   114     |> Unsynchronized.setmp Toplevel.timing (Options.bool options "timing");
   115 
   116 fun use_theories_condition last_timing (options, thys) =
   117   let val condition = space_explode "," (Options.string options "condition") in
   118     (case filter_out (can getenv_strict) condition of
   119       [] =>
   120         (Options.set_default options;
   121          use_theories last_timing options (map (rpair Position.none) thys))
   122     | conds =>
   123         Output.physical_stderr ("Skipping theories " ^ commas_quote thys ^
   124           " (undefined " ^ commas conds ^ ")\n"))
   125   end;
   126 
   127 in
   128 
   129 fun build args_file = Command_Line.tool (fn () =>
   130     let
   131       val (command_timings, (do_output, (options, (verbose, (browser_info,
   132           (parent_name, (chapter, (name, theories)))))))) =
   133         File.read (Path.explode args_file) |> YXML.parse_body |>
   134           let open XML.Decode in
   135             pair (list properties) (pair bool (pair Options.decode (pair bool (pair string
   136               (pair string (pair string (pair string
   137                 ((list (pair Options.decode (list string)))))))))))
   138           end;
   139 
   140       val _ = Options.set_default options;
   141 
   142       val document_variants =
   143         map Present.read_variant (space_explode ":" (Options.string options "document_variants"));
   144       val _ =
   145         (case duplicates (op =) (map fst document_variants) of
   146           [] => ()
   147         | dups => error ("Duplicate document variants: " ^ commas_quote dups));
   148 
   149       val _ = writeln ("\fSession.name = " ^ name);
   150       val _ =
   151         Session.init do_output
   152           (Options.bool options "browser_info")
   153           (Path.explode browser_info)
   154           (Options.string options "document")
   155           (Options.bool options "document_graph")
   156           (Options.string options "document_output")
   157           document_variants
   158           parent_name (chapter, name)
   159           (false, "")
   160           verbose;
   161 
   162       val last_timing = lookup_timings (fold update_timings command_timings empty_timings);
   163 
   164       val res1 =
   165         theories |>
   166           (List.app (use_theories_condition last_timing)
   167             |> session_timing name verbose
   168             |> Unsynchronized.setmp Output.Private_Hooks.protocol_message_fn protocol_message
   169             |> Unsynchronized.setmp Multithreading.max_threads (Options.int options "threads")
   170             |> Exn.capture);
   171       val res2 = Exn.capture Session.finish ();
   172       val _ = Par_Exn.release_all [res1, res2];
   173 
   174       val _ = Options.reset_default ();
   175       val _ = if do_output then () else exit 0;
   176     in 0 end);
   177 
   178 end;
   179 
   180 end;